qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 #include <common/mutators/mutator/overkill/oknex.qh>
  66
  67 STATIC_METHOD(Client, Add, void(Client this, int _team))
  68 {
  69     ClientConnect(this);
  70     TRANSMUTE(Player, this);
  71     this.frame = 12; // 7
  72     this.team = _team;
  73     PutClientInServer(this);
  74 }
  75
  76 void PutObserverInServer(entity this);
  77
  78 STATIC_METHOD(Client, Remove, void(Client this))
  79 {
  80     TRANSMUTE(Observer, this);
  81     PutClientInServer(this);
  82     ClientDisconnect(this);
  83 }
  84
  85 void send_CSQC_teamnagger() {
  86         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  87 }
  88
  89 int CountSpectators(entity player, entity to)
  90 {
  91         if(!player) { return 0; } // not sure how, but best to be safe
  92
  93         int spec_count = 0;
  94
  95         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  96         {
  97                 spec_count++;
  98         });
  99
 100         return spec_count;
 101 }
 102
 103 void WriteSpectators(entity player, entity to)
 104 {
 105         if(!player) { return; } // not sure how, but best to be safe
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 WriteByte(MSG_ENTITY, num_for_edict(it));
 110         });
 111 }
 112
 113 bool ClientData_Send(entity this, entity to, int sf)
 114 {
 115         assert(to == this.owner, return false);
 116
 117         entity e = to;
 118         if (IS_SPEC(e)) e = e.enemy;
 119
 120         sf = 0;
 121         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 122         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 123         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 124         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 125
 126         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 127         WriteByte(MSG_ENTITY, sf);
 128
 129         if (sf & BIT(1))
 130                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 131
 132         if(sf & BIT(4))
 133         {
 134                 float specs = CountSpectators(e, to);
 135                 WriteByte(MSG_ENTITY, specs);
 136                 WriteSpectators(e, to);
 137         }
 138
 139         return true;
 140 }
 141
 142 void ClientData_Attach(entity this)
 143 {
 144         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 145         CS(this).clientdata.drawonlytoclient = this;
 146         CS(this).clientdata.owner = this;
 147 }
 148
 149 void ClientData_Detach(entity this)
 150 {
 151         delete(CS(this).clientdata);
 152         CS(this).clientdata = NULL;
 153 }
 154
 155 void ClientData_Touch(entity e)
 156 {
 157         CS(e).clientdata.SendFlags = 1;
 158
 159         // make it spectatable
 160         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 161 }
 162
 163 void SetSpectatee(entity this, entity spectatee);
 164 void SetSpectatee_status(entity this, int spectatee_num);
 165
 166
 167 /*
 168 =============
 169 CheckPlayerModel
 170
 171 Checks if the argument string can be a valid playermodel.
 172 Returns a valid one in doubt.
 173 =============
 174 */
 175 string FallbackPlayerModel;
 176 string CheckPlayerModel(string plyermodel) {
 177         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 178         {
 179                 // note: we cannot summon Don Strunzone here, some player may
 180                 // still have the model string set. In case anyone manages how
 181                 // to change a cvar default, we'll have a small leak here.
 182                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 183         }
 184         // only in right path
 185         if( substring(plyermodel,0,14) != "models/player/")
 186                 return FallbackPlayerModel;
 187         // only good file extensions
 188         if(substring(plyermodel,-4,4) != ".zym")
 189         if(substring(plyermodel,-4,4) != ".dpm")
 190         if(substring(plyermodel,-4,4) != ".iqm")
 191         if(substring(plyermodel,-4,4) != ".md3")
 192         if(substring(plyermodel,-4,4) != ".psk")
 193                 return FallbackPlayerModel;
 194         // forbid the LOD models
 195         if(substring(plyermodel, -9,5) == "_lod1")
 196                 return FallbackPlayerModel;
 197         if(substring(plyermodel, -9,5) == "_lod2")
 198                 return FallbackPlayerModel;
 199         if(plyermodel != strtolower(plyermodel))
 200                 return FallbackPlayerModel;
 201         // also, restrict to server models
 202         if(autocvar_sv_servermodelsonly)
 203         {
 204                 if(!fexists(plyermodel))
 205                         return FallbackPlayerModel;
 206         }
 207         return plyermodel;
 208 }
 209
 210 void setplayermodel(entity e, string modelname)
 211 {
 212         precache_model(modelname);
 213         _setmodel(e, modelname);
 214         player_setupanimsformodel(e);
 215         if(!autocvar_g_debug_globalsounds)
 216                 UpdatePlayerSounds(e);
 217 }
 218
 219 void FixPlayermodel(entity player);
 220 /** putting a client as observer in the server */
 221 void PutObserverInServer(entity this)
 222 {
 223     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 224         PlayerState_detach(this);
 225
 226         if (IS_PLAYER(this))
 227         {
 228                 if(this.health >= 1)
 229                 {
 230                         // despawn effect
 231                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 232                 }
 233
 234                 // was a player, recount votes and ready status
 235                 if(IS_REAL_CLIENT(this))
 236                 {
 237                         if (vote_called) { VoteCount(false); }
 238                         ReadyCount();
 239                 }
 240     }
 241
 242     {
 243         entity spot = SelectSpawnPoint(this, true);
 244         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 245         this.angles = vec2(spot.angles);
 246         this.fixangle = true;
 247         // offset it so that the spectator spawns higher off the ground, looks better this way
 248         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 249         if (IS_REAL_CLIENT(this))
 250         {
 251             msg_entity = this;
 252             WriteByte(MSG_ONE, SVC_SETVIEW);
 253             WriteEntity(MSG_ONE, this);
 254         }
 255         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 256         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 257         if(!autocvar_g_debug_globalsounds)
 258         {
 259                 // needed for player sounds
 260                 this.model = "";
 261                 FixPlayermodel(this);
 262         }
 263         setmodel(this, MDL_Null);
 264         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 265         this.view_ofs = '0 0 0';
 266     }
 267
 268     RemoveGrapplingHooks(this);
 269         Portal_ClearAll(this);
 270         Unfreeze(this);
 271         SetSpectatee(this, NULL);
 272
 273         if (this.alivetime)
 274         {
 275                 if (!warmup_stage)
 276                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 277                 this.alivetime = 0;
 278         }
 279
 280         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 281
 282         WaypointSprite_PlayerDead(this);
 283
 284         if (mutator_returnvalue) {
 285             // mutator prevents resetting teams+score
 286         } else {
 287                 int oldteam = this.team;
 288                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 289                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 290         this.frags = FRAGS_SPECTATOR;
 291         PlayerScore_Clear(this);  // clear scores when needed
 292     }
 293
 294         if (CS(this).killcount != FRAGS_SPECTATOR)
 295         {
 296                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 297                 if(!game_stopped)
 298                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 299                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 300
 301                 if(!CS(this).just_joined)
 302                         LogTeamchange(this.playerid, -1, 4);
 303                 else
 304                         CS(this).just_joined = false;
 305         }
 306
 307         accuracy_resend(this);
 308
 309         CS(this).spectatortime = time;
 310         if(this.bot_attack)
 311                 IL_REMOVE(g_bot_targets, this);
 312         this.bot_attack = false;
 313         if(this.monster_attack)
 314                 IL_REMOVE(g_monster_targets, this);
 315         this.monster_attack = false;
 316     STAT(HUD, this) = HUD_NORMAL;
 317         TRANSMUTE(Observer, this);
 318         this.iscreature = false;
 319         this.teleportable = TELEPORT_SIMPLE;
 320         if(this.damagedbycontents)
 321                 IL_REMOVE(g_damagedbycontents, this);
 322         this.damagedbycontents = false;
 323         this.health = FRAGS_SPECTATOR;
 324         SetSpectatee_status(this, etof(this));
 325         this.takedamage = DAMAGE_NO;
 326         this.solid = SOLID_NOT;
 327         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 328         this.flags = FL_CLIENT | FL_NOTARGET;
 329         this.armorvalue = 666;
 330         this.effects = 0;
 331         this.armorvalue = autocvar_g_balance_armor_start;
 332         this.pauserotarmor_finished = 0;
 333         this.pauserothealth_finished = 0;
 334         this.pauseregen_finished = 0;
 335         this.damageforcescale = 0;
 336         this.death_time = 0;
 337         this.respawn_flags = 0;
 338         this.respawn_time = 0;
 339         STAT(RESPAWN_TIME, this) = 0;
 340         this.alpha = 0;
 341         this.scale = 0;
 342         this.fade_time = 0;
 343         this.pain_frame = 0;
 344         this.pain_finished = 0;
 345         this.strength_finished = 0;
 346         this.invincible_finished = 0;
 347         this.superweapons_finished = 0;
 348         this.dphitcontentsmask = 0;
 349         this.pushltime = 0;
 350         this.istypefrag = 0;
 351         setthink(this, func_null);
 352         this.nextthink = 0;
 353         this.deadflag = DEAD_NO;
 354         this.crouch = false;
 355         STAT(REVIVE_PROGRESS, this) = 0;
 356         this.revival_time = 0;
 357
 358         this.items = 0;
 359         this.weapons = '0 0 0';
 360         this.drawonlytoclient = this;
 361
 362         this.viewloc = NULL;
 363
 364         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 365
 366         this.weaponmodel = "";
 367         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 368         {
 369                 this.weaponentities[slot] = NULL;
 370         }
 371         this.exteriorweaponentity = NULL;
 372         CS(this).killcount = FRAGS_SPECTATOR;
 373         this.velocity = '0 0 0';
 374         this.avelocity = '0 0 0';
 375         this.punchangle = '0 0 0';
 376         this.punchvector = '0 0 0';
 377         this.oldvelocity = this.velocity;
 378         this.fire_endtime = -1;
 379         this.event_damage = func_null;
 380
 381         for(int slot = 0; slot < MAX_AXH; ++slot)
 382         {
 383                 entity axh = this.(AuxiliaryXhair[slot]);
 384                 this.(AuxiliaryXhair[slot]) = NULL;
 385
 386                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 387                         delete(axh);
 388         }
 389 }
 390
 391 int player_getspecies(entity this)
 392 {
 393         get_model_parameters(this.model, this.skin);
 394         int s = get_model_parameters_species;
 395         get_model_parameters(string_null, 0);
 396         if (s < 0) return SPECIES_HUMAN;
 397         return s;
 398 }
 399
 400 .float model_randomizer;
 401 void FixPlayermodel(entity player)
 402 {
 403         string defaultmodel = "";
 404         int defaultskin = 0;
 405         if(autocvar_sv_defaultcharacter)
 406         {
 407                 if(teamplay)
 408                 {
 409                         switch(player.team)
 410                         {
 411                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 412                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 413                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 414                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 415                         }
 416                 }
 417
 418                 if(defaultmodel == "")
 419                 {
 420                         defaultmodel = autocvar_sv_defaultplayermodel;
 421                         defaultskin = autocvar_sv_defaultplayerskin;
 422                 }
 423
 424                 int n = tokenize_console(defaultmodel);
 425                 if(n > 0)
 426                 {
 427                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 428                         // However, do NOT randomize if the player-selected model is in the list.
 429                         for (int i = 0; i < n; ++i)
 430                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 431                                         defaultmodel = argv(i);
 432                 }
 433
 434                 int i = strstrofs(defaultmodel, ":", 0);
 435                 if(i >= 0)
 436                 {
 437                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 438                         defaultmodel = substring(defaultmodel, 0, i);
 439                 }
 440         }
 441         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 442         {
 443                 if(teamplay)
 444                 {
 445                         switch(player.team)
 446                         {
 447                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 448                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 449                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 450                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 451                         }
 452                 }
 453
 454                 if(!defaultskin)
 455                         defaultskin = autocvar_sv_defaultplayerskin;
 456         }
 457
 458         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 459         defaultmodel = M_ARGV(0, string);
 460         defaultskin = M_ARGV(1, int);
 461
 462         bool chmdl = false;
 463         int oldskin;
 464         if(defaultmodel != "")
 465         {
 466                 if (defaultmodel != player.model)
 467                 {
 468                         vector m1 = player.mins;
 469                         vector m2 = player.maxs;
 470                         setplayermodel (player, defaultmodel);
 471                         setsize (player, m1, m2);
 472                         chmdl = true;
 473                 }
 474
 475                 oldskin = player.skin;
 476                 player.skin = defaultskin;
 477         } else {
 478                 if (player.playermodel != player.model || player.playermodel == "")
 479                 {
 480                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 481                         vector m1 = player.mins;
 482                         vector m2 = player.maxs;
 483                         setplayermodel (player, player.playermodel);
 484                         setsize (player, m1, m2);
 485                         chmdl = true;
 486                 }
 487
 488                 if(!autocvar_sv_defaultcharacterskin)
 489                 {
 490                         oldskin = player.skin;
 491                         player.skin = stof(player.playerskin);
 492                 }
 493                 else
 494                 {
 495                         oldskin = player.skin;
 496                         player.skin = defaultskin;
 497                 }
 498         }
 499
 500         if(chmdl || oldskin != player.skin) // model or skin has changed
 501         {
 502                 player.species = player_getspecies(player); // update species
 503                 if(!autocvar_g_debug_globalsounds)
 504                         UpdatePlayerSounds(player); // update skin sounds
 505         }
 506
 507         if(!teamplay)
 508                 if(strlen(autocvar_sv_defaultplayercolors))
 509                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 510                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 511 }
 512
 513 void PutPlayerInServer(entity this)
 514 {
 515         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 516
 517         PlayerState_attach(this);
 518         accuracy_resend(this);
 519
 520         if (this.team < 0)
 521                 JoinBestTeam(this, true);
 522
 523         entity spot = SelectSpawnPoint(this, false);
 524         if (!spot) {
 525                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 526                 return; // spawn failed
 527         }
 528
 529         TRANSMUTE(Player, this);
 530
 531         CS(this).wasplayer = true;
 532         this.iscreature = true;
 533         this.teleportable = TELEPORT_NORMAL;
 534         if(!this.damagedbycontents)
 535                 IL_PUSH(g_damagedbycontents, this);
 536         this.damagedbycontents = true;
 537         set_movetype(this, MOVETYPE_WALK);
 538         this.solid = SOLID_SLIDEBOX;
 539         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 540         if (autocvar_g_playerclip_collisions)
 541                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 542         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 543                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 544         this.frags = FRAGS_PLAYER;
 545         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 546         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 547         if (autocvar__notarget)
 548                 this.flags |= FL_NOTARGET;
 549         this.takedamage = DAMAGE_AIM;
 550         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 551
 552         if (warmup_stage) {
 553                 this.ammo_shells = warmup_start_ammo_shells;
 554                 this.ammo_nails = warmup_start_ammo_nails;
 555                 this.ammo_rockets = warmup_start_ammo_rockets;
 556                 this.ammo_cells = warmup_start_ammo_cells;
 557                 this.ammo_plasma = warmup_start_ammo_plasma;
 558                 this.ammo_fuel = warmup_start_ammo_fuel;
 559                 this.health = warmup_start_health;
 560                 this.armorvalue = warmup_start_armorvalue;
 561                 this.weapons = WARMUP_START_WEAPONS;
 562         } else {
 563                 this.ammo_shells = start_ammo_shells;
 564                 this.ammo_nails = start_ammo_nails;
 565                 this.ammo_rockets = start_ammo_rockets;
 566                 this.ammo_cells = start_ammo_cells;
 567                 this.ammo_plasma = start_ammo_plasma;
 568                 this.ammo_fuel = start_ammo_fuel;
 569                 this.health = start_health;
 570                 this.armorvalue = start_armorvalue;
 571                 this.weapons = start_weapons;
 572                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 573                 {
 574                         GiveRandomWeapons(this, random_start_weapons_count,
 575                                 autocvar_g_random_start_weapons, random_start_ammo);
 576                 }
 577         }
 578         SetSpectatee_status(this, 0);
 579
 580         PS(this).dual_weapons = '0 0 0';
 581
 582         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 583
 584         this.items = start_items;
 585
 586         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 587         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 588         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 589         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 590         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 591         if (!sv_ready_restart_after_countdown && time < game_starttime)
 592         {
 593                 float f = game_starttime - time;
 594                 this.spawnshieldtime += f;
 595                 this.pauserotarmor_finished += f;
 596                 this.pauserothealth_finished += f;
 597                 this.pauseregen_finished += f;
 598         }
 599
 600         this.damageforcescale = 2;
 601         this.death_time = 0;
 602         this.respawn_flags = 0;
 603         this.respawn_time = 0;
 604         STAT(RESPAWN_TIME, this) = 0;
 605         this.scale = autocvar_sv_player_scale;
 606         this.fade_time = 0;
 607         this.pain_frame = 0;
 608         this.pain_finished = 0;
 609         this.pushltime = 0;
 610         setthink(this, func_null); // players have no think function
 611         this.nextthink = 0;
 612         this.dmg_team = 0;
 613         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 614
 615         this.deadflag = DEAD_NO;
 616
 617         this.angles = spot.angles;
 618         this.angles_z = 0; // never spawn tilted even if the spot says to
 619         if (IS_BOT_CLIENT(this))
 620                 this.v_angle = this.angles;
 621         this.fixangle = true; // turn this way immediately
 622         this.oldvelocity = this.velocity = '0 0 0';
 623         this.avelocity = '0 0 0';
 624         this.punchangle = '0 0 0';
 625         this.punchvector = '0 0 0';
 626
 627         this.strength_finished = 0;
 628         this.invincible_finished = 0;
 629         this.fire_endtime = -1;
 630         STAT(REVIVE_PROGRESS, this) = 0;
 631         this.revival_time = 0;
 632
 633         this.air_finished = time + 12;
 634         this.waterlevel = WATERLEVEL_NONE;
 635         this.watertype = CONTENT_EMPTY;
 636
 637         entity spawnevent = new_pure(spawnevent);
 638         spawnevent.owner = this;
 639         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 640
 641         // Cut off any still running player sounds.
 642         stopsound(this, CH_PLAYER_SINGLE);
 643
 644         this.model = "";
 645         FixPlayermodel(this);
 646         this.drawonlytoclient = NULL;
 647
 648         this.viewloc = NULL;
 649
 650         for(int slot = 0; slot < MAX_AXH; ++slot)
 651         {
 652                 entity axh = this.(AuxiliaryXhair[slot]);
 653                 this.(AuxiliaryXhair[slot]) = NULL;
 654
 655                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 656                         delete(axh);
 657         }
 658
 659         this.spawnpoint_targ = NULL;
 660
 661         this.crouch = false;
 662         this.view_ofs = STAT(PL_VIEW_OFS, this);
 663         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 664         this.spawnorigin = spot.origin;
 665         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 666         // don't reset back to last position, even if new position is stuck in solid
 667         this.oldorigin = this.origin;
 668         if(this.conveyor)
 669                 IL_REMOVE(g_conveyed, this);
 670         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 671         STAT(HUD, this) = HUD_NORMAL;
 672
 673         this.event_damage = PlayerDamage;
 674
 675         if(!this.bot_attack)
 676                 IL_PUSH(g_bot_targets, this);
 677         this.bot_attack = true;
 678         if(!this.monster_attack)
 679                 IL_PUSH(g_monster_targets, this);
 680         this.monster_attack = true;
 681         navigation_dynamicgoal_init(this, false);
 682
 683         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 684
 685         // player was spectator
 686         if (CS(this).killcount == FRAGS_SPECTATOR) {
 687                 PlayerScore_Clear(this);
 688                 CS(this).killcount = 0;
 689                 CS(this).startplaytime = time;
 690         }
 691
 692         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 693         {
 694                 .entity weaponentity = weaponentities[slot];
 695                 entity oldwep = this.(weaponentity);
 696                 CL_SpawnWeaponentity(this, weaponentity);
 697                 if(oldwep && oldwep.owner == this)
 698                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 699         }
 700         this.alpha = default_player_alpha;
 701         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 702         this.exteriorweaponentity.alpha = default_weapon_alpha;
 703
 704         this.speedrunning = false;
 705
 706         target_voicescript_clear(this);
 707
 708         // reset fields the weapons may use
 709         FOREACH(Weapons, true, {
 710                 it.wr_resetplayer(it, this);
 711                         // reload all reloadable weapons
 712                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 713                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 714                         {
 715                                 .entity weaponentity = weaponentities[slot];
 716                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 717                         }
 718                 }
 719         });
 720
 721         {
 722                 string s = spot.target;
 723                 spot.target = string_null;
 724                 SUB_UseTargets(spot, this, NULL);
 725                 spot.target = s;
 726         }
 727
 728         Unfreeze(this);
 729
 730         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 731
 732         if (autocvar_spawn_debug)
 733         {
 734                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 735                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 736         }
 737
 738         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 739         {
 740                 .entity weaponentity = weaponentities[slot];
 741                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 742                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 743                 else
 744                         this.(weaponentity).m_switchweapon = WEP_Null;
 745                 this.(weaponentity).m_weapon = WEP_Null;
 746                 this.(weaponentity).weaponname = "";
 747                 this.(weaponentity).m_switchingweapon = WEP_Null;
 748                 this.(weaponentity).cnt = -1;
 749         }
 750
 751         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 752
 753         if (!warmup_stage && !this.alivetime)
 754                 this.alivetime = time;
 755
 756         antilag_clear(this, CS(this));
 757 }
 758
 759 /** Called when a client spawns in the server */
 760 void PutClientInServer(entity this)
 761 {
 762         if (IS_BOT_CLIENT(this)) {
 763                 TRANSMUTE(Player, this);
 764         } else if (IS_REAL_CLIENT(this)) {
 765                 msg_entity = this;
 766                 WriteByte(MSG_ONE, SVC_SETVIEW);
 767                 WriteEntity(MSG_ONE, this);
 768         }
 769         if (game_stopped)
 770                 TRANSMUTE(Observer, this);
 771
 772         SetSpectatee(this, NULL);
 773
 774         // reset player keys
 775         if(PS(this))
 776                 PS(this).itemkeys = 0;
 777
 778         MUTATOR_CALLHOOK(PutClientInServer, this);
 779
 780         if (IS_OBSERVER(this)) {
 781                 PutObserverInServer(this);
 782         } else if (IS_PLAYER(this)) {
 783                 PutPlayerInServer(this);
 784         }
 785 }
 786
 787 void ClientInit_misc(entity this);
 788
 789 // TODO do we need all these fields, or should we stop autodetecting runtime
 790 // changes and just have a console command to update this?
 791 bool ClientInit_SendEntity(entity this, entity to, int sf)
 792 {
 793         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 794         return = true;
 795         msg_entity = to;
 796         // MSG_INIT replacement
 797         // TODO: make easier to use
 798         Registry_send_all();
 799         W_PROP_reload(MSG_ONE, to);
 800         ClientInit_misc(this);
 801         MUTATOR_CALLHOOK(Ent_Init);
 802 }
 803 void ClientInit_misc(entity this)
 804 {
 805         int channel = MSG_ONE;
 806         WriteHeader(channel, ENT_CLIENT_INIT);
 807         WriteByte(channel, g_nexball_meter_period * 32);
 808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 810         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 811         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 814         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 815         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 816
 817         if(sv_foginterval && world.fog != "")
 818                 WriteString(channel, world.fog);
 819         else
 820                 WriteString(channel, "");
 821         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 822         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 823         WriteByte(channel, serverflags);
 824         WriteCoord(channel, autocvar_g_trueaim_minrange);
 825 }
 826
 827 void ClientInit_CheckUpdate(entity this)
 828 {
 829         this.nextthink = time;
 830         if(this.count != autocvar_g_balance_armor_blockpercent)
 831         {
 832                 this.count = autocvar_g_balance_armor_blockpercent;
 833                 this.SendFlags |= 1;
 834         }
 835         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 836         {
 837                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 838                 this.SendFlags |= 1;
 839         }
 840 }
 841
 842 void ClientInit_Spawn()
 843 {
 844         entity e = new_pure(clientinit);
 845         setthink(e, ClientInit_CheckUpdate);
 846         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 847
 848         ClientInit_CheckUpdate(e);
 849 }
 850
 851 /*
 852 =============
 853 SetNewParms
 854 =============
 855 */
 856 void SetNewParms ()
 857 {
 858         // initialize parms for a new player
 859         parm1 = -(86400 * 366);
 860
 861         MUTATOR_CALLHOOK(SetNewParms);
 862 }
 863
 864 /*
 865 =============
 866 SetChangeParms
 867 =============
 868 */
 869 void SetChangeParms (entity this)
 870 {
 871         // save parms for level change
 872         parm1 = CS(this).parm_idlesince - time;
 873
 874         MUTATOR_CALLHOOK(SetChangeParms);
 875 }
 876
 877 /*
 878 =============
 879 DecodeLevelParms
 880 =============
 881 */
 882 void DecodeLevelParms(entity this)
 883 {
 884         // load parms
 885         CS(this).parm_idlesince = parm1;
 886         if (CS(this).parm_idlesince == -(86400 * 366))
 887                 CS(this).parm_idlesince = time;
 888
 889         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 890         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 891
 892         MUTATOR_CALLHOOK(DecodeLevelParms);
 893 }
 894
 895 /*
 896 =============
 897 ClientKill
 898
 899 Called when a client types 'kill' in the console
 900 =============
 901 */
 902
 903 .float clientkill_nexttime;
 904 void ClientKill_Now_TeamChange(entity this)
 905 {
 906         if(this.killindicator_teamchange == -1)
 907         {
 908                 JoinBestTeam( this, true );
 909         }
 910         else if(this.killindicator_teamchange == -2)
 911         {
 912                 if(blockSpectators)
 913                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 914                 PutObserverInServer(this);
 915         }
 916         else
 917                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 918         this.killindicator_teamchange = 0;
 919 }
 920
 921 void ClientKill_Now(entity this)
 922 {
 923         if(this.vehicle)
 924         {
 925             vehicles_exit(this.vehicle, VHEF_RELEASE);
 926             if(!this.killindicator_teamchange)
 927             {
 928             this.vehicle_health = -1;
 929             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 930             }
 931         }
 932
 933         if(this.killindicator && !wasfreed(this.killindicator))
 934                 delete(this.killindicator);
 935
 936         this.killindicator = NULL;
 937
 938         if(this.killindicator_teamchange)
 939                 ClientKill_Now_TeamChange(this);
 940
 941         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 942         {
 943                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 944         }
 945
 946         // now I am sure the player IS dead
 947 }
 948 void KillIndicator_Think(entity this)
 949 {
 950         if (game_stopped)
 951         {
 952                 this.owner.killindicator = NULL;
 953                 delete(this);
 954                 return;
 955         }
 956
 957         if (this.owner.alpha < 0 && !this.owner.vehicle)
 958         {
 959                 this.owner.killindicator = NULL;
 960                 delete(this);
 961                 return;
 962         }
 963
 964         if(this.cnt <= 0)
 965         {
 966                 ClientKill_Now(this.owner);
 967                 return;
 968         }
 969     else if(this.health == 1) // health == 1 means that it's silent
 970     {
 971         this.nextthink = time + 1;
 972         this.cnt -= 1;
 973     }
 974         else
 975         {
 976                 if(this.cnt <= 10)
 977                         setmodel(this, MDL_NUM(this.cnt));
 978                 if(IS_REAL_CLIENT(this.owner))
 979                 {
 980                         if(this.cnt <= 10)
 981                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 982                 }
 983                 this.nextthink = time + 1;
 984                 this.cnt -= 1;
 985         }
 986 }
 987
 988 float clientkilltime;
 989 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 990 {
 991         float killtime;
 992         float starttime;
 993
 994         if (game_stopped)
 995                 return;
 996
 997         killtime = autocvar_g_balance_kill_delay;
 998
 999     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1000         return;
1001     killtime = M_ARGV(1, float);
1002
1003         this.killindicator_teamchange = targetteam;
1004
1005     if(!this.killindicator)
1006         {
1007                 if(!IS_DEAD(this))
1008                 {
1009                         killtime = max(killtime, this.clientkill_nexttime - time);
1010                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1011                 }
1012
1013                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1014                 {
1015                         ClientKill_Now(this);
1016                 }
1017                 else
1018                 {
1019                         starttime = max(time, clientkilltime);
1020
1021                         this.killindicator = spawn();
1022                         this.killindicator.owner = this;
1023                         this.killindicator.scale = 0.5;
1024                         setattachment(this.killindicator, this, "");
1025                         setorigin(this.killindicator, '0 0 52');
1026                         setthink(this.killindicator, KillIndicator_Think);
1027                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1028                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1029                         this.killindicator.cnt = ceil(killtime);
1030                         this.killindicator.count = bound(0, ceil(killtime), 10);
1031                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1032
1033                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1034                         {
1035                                 it.killindicator = spawn();
1036                                 it.killindicator.owner = it;
1037                                 it.killindicator.scale = 0.5;
1038                                 setattachment(it.killindicator, it, "");
1039                                 setorigin(it.killindicator, '0 0 52');
1040                                 setthink(it.killindicator, KillIndicator_Think);
1041                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1042                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1043                                 it.killindicator.cnt = ceil(killtime);
1044                         });
1045                         this.lip = 0;
1046                 }
1047         }
1048         if(this.killindicator)
1049         {
1050                 if(targetteam == 0) // just die
1051                 {
1052                         this.killindicator.colormod = '0 0 0';
1053                         if(IS_REAL_CLIENT(this))
1054                         if(this.killindicator.cnt > 0)
1055                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1056                 }
1057                 else if(targetteam == -1) // auto
1058                 {
1059                         this.killindicator.colormod = '0 1 0';
1060                         if(IS_REAL_CLIENT(this))
1061                         if(this.killindicator.cnt > 0)
1062                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1063                 }
1064                 else if(targetteam == -2) // spectate
1065                 {
1066                         this.killindicator.colormod = '0.5 0.5 0.5';
1067                         if(IS_REAL_CLIENT(this))
1068                         if(this.killindicator.cnt > 0)
1069                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1070                 }
1071                 else
1072                 {
1073                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1074                         if(IS_REAL_CLIENT(this))
1075                         if(this.killindicator.cnt > 0)
1076                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1077                 }
1078         }
1079
1080 }
1081
1082 void ClientKill (entity this)
1083 {
1084         if(game_stopped) return;
1085         if(this.player_blocked) return;
1086         if(STAT(FROZEN, this)) return;
1087
1088         ClientKill_TeamChange(this, 0);
1089 }
1090
1091 void FixClientCvars(entity e)
1092 {
1093         // send prediction settings to the client
1094         stuffcmd(e, "\nin_bindmap 0 0\n");
1095         if(autocvar_g_antilag == 3) // client side hitscan
1096                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1097         if(autocvar_sv_gentle)
1098                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1099
1100         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1101         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1102
1103         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1104
1105         MUTATOR_CALLHOOK(FixClientCvars, e);
1106 }
1107
1108 bool findinlist_abbrev(string tofind, string list)
1109 {
1110         if(list == "" || tofind == "")
1111                 return false; // empty list or search, just return
1112
1113         // this function allows abbreviated strings!
1114         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1115         {
1116                 return true;
1117         });
1118
1119         return false;
1120 }
1121
1122 bool PlayerInIPList(entity p, string iplist)
1123 {
1124         // some safety checks (never allow local?)
1125         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1126                 return false;
1127
1128         return findinlist_abbrev(p.netaddress, iplist);
1129 }
1130
1131 bool PlayerInIDList(entity p, string idlist)
1132 {
1133         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1134         if(!p.crypto_idfp)
1135                 return false;
1136
1137         return findinlist_abbrev(p.crypto_idfp, idlist);
1138 }
1139
1140 bool PlayerInList(entity player, string list)
1141 {
1142         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1143 }
1144
1145 #ifdef DP_EXT_PRECONNECT
1146 /*
1147 =============
1148 ClientPreConnect
1149
1150 Called once (not at each match start) when a client begins a connection to the server
1151 =============
1152 */
1153 void ClientPreConnect(entity this)
1154 {
1155         if(autocvar_sv_eventlog)
1156         {
1157                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1158                         this.playerid,
1159                         etof(this),
1160                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1161                 ));
1162         }
1163 }
1164 #endif
1165
1166 /**
1167 =============
1168 ClientConnect
1169
1170 Called when a client connects to the server
1171 =============
1172 */
1173 void ClientConnect(entity this)
1174 {
1175         if (Ban_MaybeEnforceBanOnce(this)) return;
1176         assert(!IS_CLIENT(this), return);
1177         this.flags |= FL_CLIENT;
1178         assert(player_count >= 0, player_count = 0);
1179
1180 #ifdef WATERMARK
1181         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1182 #endif
1183         TRANSMUTE(Client, this);
1184         CS(this).version_nagtime = time + 10 + random() * 10;
1185
1186         // identify the right forced team
1187         if (autocvar_g_campaign)
1188         {
1189                 if (IS_REAL_CLIENT(this)) // only players, not bots
1190                 {
1191                         switch (autocvar_g_campaign_forceteam)
1192                         {
1193                                 case 1: this.team_forced = NUM_TEAM_1; break;
1194                                 case 2: this.team_forced = NUM_TEAM_2; break;
1195                                 case 3: this.team_forced = NUM_TEAM_3; break;
1196                                 case 4: this.team_forced = NUM_TEAM_4; break;
1197                                 default: this.team_forced = 0;
1198                         }
1199                 }
1200         }
1201         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1202         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1203         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1204         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1205         else switch (autocvar_g_forced_team_otherwise)
1206         {
1207                 default: this.team_forced = 0; break;
1208                 case "red": this.team_forced = NUM_TEAM_1; break;
1209                 case "blue": this.team_forced = NUM_TEAM_2; break;
1210                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1211                 case "pink": this.team_forced = NUM_TEAM_4; break;
1212                 case "spectate":
1213                 case "spectator":
1214                         this.team_forced = -1;
1215                         break;
1216         }
1217         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1218
1219         int playerid_save = this.playerid;
1220         this.playerid = 0; // silent
1221         JoinBestTeam(this, false); // if the team number is valid, keep it
1222         this.playerid = playerid_save;
1223
1224         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1225                 TRANSMUTE(Observer, this);
1226         } else {
1227                 if (!teamplay || autocvar_g_balance_teams) {
1228                         TRANSMUTE(Player, this);
1229                         campaign_bots_may_start = true;
1230                 } else {
1231                         TRANSMUTE(Observer, this); // do it anyway
1232                 }
1233         }
1234
1235         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1236
1237         // always track bots, don't ask for cl_allow_uidtracking
1238         if (IS_BOT_CLIENT(this))
1239                 PlayerStats_GameReport_AddPlayer(this);
1240         else
1241                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1242
1243         if (autocvar_sv_eventlog)
1244                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1245
1246         LogTeamchange(this.playerid, this.team, 1);
1247
1248         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1249
1250         if(teamplay && IS_PLAYER(this))
1251                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1252         else
1253                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1254
1255         stuffcmd(this, clientstuff, "\n");
1256         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1257
1258         FixClientCvars(this);
1259
1260         // get version info from player
1261         stuffcmd(this, "cmd clientversion $gameversion\n");
1262
1263         // notify about available teams
1264         if (teamplay)
1265         {
1266                 CheckAllowedTeams(this);
1267                 int t = 0;
1268                 if (c1 >= 0) t |= BIT(0);
1269                 if (c2 >= 0) t |= BIT(1);
1270                 if (c3 >= 0) t |= BIT(2);
1271                 if (c4 >= 0) t |= BIT(3);
1272                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1273         }
1274         else
1275         {
1276                 stuffcmd(this, "set _teams_available 0\n");
1277         }
1278
1279         bot_relinkplayerlist();
1280
1281         CS(this).spectatortime = time;
1282         if (blockSpectators)
1283         {
1284                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1285         }
1286
1287         CS(this).jointime = time;
1288
1289         if (IS_REAL_CLIENT(this))
1290         {
1291                 if (g_weaponarena_weapons == WEPSET(TUBA))
1292                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1293         }
1294
1295         if (!sv_foginterval && world.fog != "")
1296                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1297
1298         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1299                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1300                         send_CSQC_teamnagger();
1301
1302         CSQCMODEL_AUTOINIT(this);
1303
1304         CS(this).model_randomizer = random();
1305
1306         if (IS_REAL_CLIENT(this))
1307                 sv_notice_join(this);
1308
1309         // update physics stats (players can spawn before physics runs)
1310         Physics_UpdateStats(this);
1311
1312         IL_EACH(g_initforplayer, it.init_for_player, {
1313                 it.init_for_player(it, this);
1314         });
1315
1316         Handicap_Initialize(this);
1317
1318         MUTATOR_CALLHOOK(ClientConnect, this);
1319
1320         if (IS_REAL_CLIENT(this))
1321         {
1322                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1323                 {
1324                         CS(this).motd_actived_time = -1;
1325                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1326                 }
1327         }
1328 }
1329 /*
1330 =============
1331 ClientDisconnect
1332
1333 Called when a client disconnects from the server
1334 =============
1335 */
1336 .entity chatbubbleentity;
1337 void ReadyCount();
1338 void ClientDisconnect(entity this)
1339 {
1340         assert(IS_CLIENT(this), return);
1341
1342         PlayerStats_GameReport_FinalizePlayer(this);
1343         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1344         if (CS(this).active_minigame) part_minigame(this);
1345         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1346
1347         if (autocvar_sv_eventlog)
1348                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1349
1350         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1351
1352         if(IS_SPEC(this))
1353                 SetSpectatee(this, NULL);
1354
1355     MUTATOR_CALLHOOK(ClientDisconnect, this);
1356
1357         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1358         strfree(CS(this).weaponorder_byimpulse);
1359         ClientState_detach(this);
1360
1361         Portal_ClearAll(this);
1362
1363         Unfreeze(this);
1364
1365         RemoveGrapplingHooks(this);
1366
1367         // Here, everything has been done that requires this player to be a client.
1368
1369         this.flags &= ~FL_CLIENT;
1370
1371         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1372         if (this.killindicator) delete(this.killindicator);
1373
1374         WaypointSprite_PlayerGone(this);
1375
1376         bot_relinkplayerlist();
1377
1378         strfree(this.clientstatus);
1379         if (this.personal) delete(this.personal);
1380
1381         this.playerid = 0;
1382         ReadyCount();
1383         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1384
1385         ONREMOVE(this);
1386 }
1387
1388 void ChatBubbleThink(entity this)
1389 {
1390         this.nextthink = time;
1391         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1392         {
1393                 if(this.owner) // but why can that ever be NULL?
1394                         this.owner.chatbubbleentity = NULL;
1395                 delete(this);
1396                 return;
1397         }
1398
1399         this.mdl = "";
1400
1401         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1402         {
1403                 if ( CS(this.owner).active_minigame )
1404                         this.mdl = "models/sprites/minigame_busy.iqm";
1405                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1406                         this.mdl = "models/misc/chatbubble.spr";
1407         }
1408
1409         if ( this.model != this.mdl )
1410                 _setmodel(this, this.mdl);
1411
1412 }
1413
1414 void UpdateChatBubble(entity this)
1415 {
1416         if (this.alpha < 0)
1417                 return;
1418         // spawn a chatbubble entity if needed
1419         if (!this.chatbubbleentity)
1420         {
1421                 this.chatbubbleentity = new(chatbubbleentity);
1422                 this.chatbubbleentity.owner = this;
1423                 this.chatbubbleentity.exteriormodeltoclient = this;
1424                 setthink(this.chatbubbleentity, ChatBubbleThink);
1425                 this.chatbubbleentity.nextthink = time;
1426                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1427                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1428                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1429                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1430                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1431                 //this.chatbubbleentity.model = "";
1432                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1433         }
1434 }
1435
1436
1437 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1438 // added to the model skins
1439 /*void UpdateColorModHack()
1440 {
1441         float c;
1442         c = this.clientcolors & 15;
1443         // LordHavoc: only bothering to support white, green, red, yellow, blue
1444              if (!teamplay) this.colormod = '0 0 0';
1445         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1446         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1447         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1448         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1449         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1450         else this.colormod = '1 1 1';
1451 }*/
1452
1453 void respawn(entity this)
1454 {
1455         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1456         {
1457                 this.solid = SOLID_NOT;
1458                 this.takedamage = DAMAGE_NO;
1459                 set_movetype(this, MOVETYPE_FLY);
1460                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1461                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1462                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1463                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1464                 if(autocvar_g_respawn_ghosts_maxtime)
1465                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1466         }
1467
1468         CopyBody(this, 1);
1469
1470         this.effects |= EF_NODRAW; // prevent another CopyBody
1471         PutClientInServer(this);
1472 }
1473
1474 void play_countdown(entity this, float finished, Sound samp)
1475 {
1476     TC(Sound, samp);
1477         if(IS_REAL_CLIENT(this))
1478                 if(floor(finished - time - frametime) != floor(finished - time))
1479                         if(finished - time < 6)
1480                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1481 }
1482
1483 void player_powerups(entity this)
1484 {
1485         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1486         int items_prev = this.items;
1487
1488         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1489                 this.modelflags |= MF_ROCKET;
1490         else
1491                 this.modelflags &= ~MF_ROCKET;
1492
1493         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1494
1495         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1496                 return;
1497
1498         Fire_ApplyDamage(this);
1499         Fire_ApplyEffect(this);
1500
1501         if (!autocvar_g_instagib)
1502         {
1503                 if (this.items & ITEM_Strength.m_itemid)
1504                 {
1505                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1506                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1507                         if (time > this.strength_finished)
1508                         {
1509                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1510                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1511                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1512                         }
1513                 }
1514                 else
1515                 {
1516                         if (time < this.strength_finished)
1517                         {
1518                                 this.items = this.items | ITEM_Strength.m_itemid;
1519                                 if(!g_cts)
1520                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1521                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1522                         }
1523                 }
1524                 if (this.items & ITEM_Shield.m_itemid)
1525                 {
1526                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1527                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1528                         if (time > this.invincible_finished)
1529                         {
1530                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1531                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1532                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1533                         }
1534                 }
1535                 else
1536                 {
1537                         if (time < this.invincible_finished)
1538                         {
1539                                 this.items = this.items | ITEM_Shield.m_itemid;
1540                                 if(!g_cts)
1541                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1542                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1543                         }
1544                 }
1545                 if (this.items & IT_SUPERWEAPON)
1546                 {
1547                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1548                         {
1549                                 this.superweapons_finished = 0;
1550                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1551                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1552                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1553                         }
1554                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1555                         {
1556                                 // don't let them run out
1557                         }
1558                         else
1559                         {
1560                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1561                                 if (time > this.superweapons_finished)
1562                                 {
1563                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1564                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1565                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1566                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1567                                 }
1568                         }
1569                 }
1570                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1571                 {
1572                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1573                         {
1574                                 this.items = this.items | IT_SUPERWEAPON;
1575                                 if(!g_cts)
1576                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1577                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1578                         }
1579                         else
1580                         {
1581                                 this.superweapons_finished = 0;
1582                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1583                         }
1584                 }
1585                 else
1586                 {
1587                         this.superweapons_finished = 0;
1588                 }
1589         }
1590
1591         if(autocvar_g_nodepthtestplayers)
1592                 this.effects = this.effects | EF_NODEPTHTEST;
1593
1594         if(autocvar_g_fullbrightplayers)
1595                 this.effects = this.effects | EF_FULLBRIGHT;
1596
1597         if (time >= game_starttime)
1598         if (time < this.spawnshieldtime)
1599                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1600
1601         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1602 }
1603
1604 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1605 {
1606         if(current > stable)
1607                 return current;
1608         else if(current > stable - 0.25) // when close enough, "snap"
1609                 return stable;
1610         else
1611                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1612 }
1613
1614 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1615 {
1616         if(current < stable)
1617                 return current;
1618         else if(current < stable + 0.25) // when close enough, "snap"
1619                 return stable;
1620         else
1621                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1622 }
1623
1624 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1625 {
1626         if(current > rotstable)
1627         {
1628                 if(rotframetime > 0)
1629                 {
1630                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1631                         current = max(rotstable, current - rotlinear * rotframetime);
1632                 }
1633         }
1634         else if(current < regenstable)
1635         {
1636                 if(regenframetime > 0)
1637                 {
1638                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1639                         current = min(regenstable, current + regenlinear * regenframetime);
1640                 }
1641         }
1642
1643         if(current > limit)
1644                 current = limit;
1645
1646         return current;
1647 }
1648
1649 void player_regen(entity this)
1650 {
1651         float max_mod, regen_mod, rot_mod, limit_mod;
1652         max_mod = regen_mod = rot_mod = limit_mod = 1;
1653
1654         float regen_health = autocvar_g_balance_health_regen;
1655         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1656         float regen_health_rot = autocvar_g_balance_health_rot;
1657         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1658         float regen_health_stable = autocvar_g_balance_health_regenstable;
1659         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1660         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1661                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1662         max_mod = M_ARGV(1, float);
1663         regen_mod = M_ARGV(2, float);
1664         rot_mod = M_ARGV(3, float);
1665         limit_mod = M_ARGV(4, float);
1666         regen_health = M_ARGV(5, float);
1667         regen_health_linear = M_ARGV(6, float);
1668         regen_health_rot = M_ARGV(7, float);
1669         regen_health_rotlinear = M_ARGV(8, float);
1670         regen_health_stable = M_ARGV(9, float);
1671         regen_health_rotstable = M_ARGV(10, float);
1672
1673         if(!mutator_returnvalue)
1674         if(!STAT(FROZEN, this))
1675         {
1676                 float mina, maxa, limith, limita;
1677                 maxa = autocvar_g_balance_armor_rotstable;
1678                 mina = autocvar_g_balance_armor_regenstable;
1679                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1680                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1681
1682                 regen_health_rotstable = regen_health_rotstable * max_mod;
1683                 regen_health_stable = regen_health_stable * max_mod;
1684                 limith = limith * limit_mod;
1685                 limita = limita * limit_mod;
1686
1687                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1688                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1689         }
1690
1691         // if player rotted to death...  die!
1692         // check this outside above checks, as player may still be able to rot to death
1693         if(this.health < 1)
1694         {
1695                 if(this.vehicle)
1696                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1697                 if(this.event_damage)
1698                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1699         }
1700
1701         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1702         {
1703                 float minf, maxf, limitf;
1704
1705                 maxf = autocvar_g_balance_fuel_rotstable;
1706                 minf = autocvar_g_balance_fuel_regenstable;
1707                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1708
1709                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1710         }
1711         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1712         // TODO: Remove this hack when all code uses GivePlayerHealth and
1713         // GivePlayerArmor.
1714         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1715         {
1716                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1717         }
1718         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1719         {
1720                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1721         }
1722         // End hack.
1723 }
1724
1725 bool zoomstate_set;
1726 void SetZoomState(entity this, float newzoom)
1727 {
1728         if(newzoom != CS(this).zoomstate)
1729         {
1730                 CS(this).zoomstate = newzoom;
1731                 ClientData_Touch(this);
1732         }
1733         zoomstate_set = true;
1734 }
1735
1736 void GetPressedKeys(entity this)
1737 {
1738         MUTATOR_CALLHOOK(GetPressedKeys, this);
1739         int keys = STAT(PRESSED_KEYS, this);
1740         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1741         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1742         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1743         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1744
1745         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1746         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1747         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1748         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1749         CS(this).pressedkeys = keys; // store for other users
1750
1751         STAT(PRESSED_KEYS, this) = keys;
1752 }
1753
1754 /*
1755 ======================
1756 spectate mode routines
1757 ======================
1758 */
1759
1760 void SpectateCopy(entity this, entity spectatee)
1761 {
1762     TC(Client, this); TC(Client, spectatee);
1763
1764         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1765         PS(this) = PS(spectatee);
1766         this.armortype = spectatee.armortype;
1767         this.armorvalue = spectatee.armorvalue;
1768         this.ammo_cells = spectatee.ammo_cells;
1769         this.ammo_plasma = spectatee.ammo_plasma;
1770         this.ammo_shells = spectatee.ammo_shells;
1771         this.ammo_nails = spectatee.ammo_nails;
1772         this.ammo_rockets = spectatee.ammo_rockets;
1773         this.ammo_fuel = spectatee.ammo_fuel;
1774         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1775         this.health = spectatee.health;
1776         CS(this).impulse = 0;
1777         this.items = spectatee.items;
1778         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1779         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1780         this.strength_finished = spectatee.strength_finished;
1781         this.invincible_finished = spectatee.invincible_finished;
1782         this.superweapons_finished = spectatee.superweapons_finished;
1783         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1784         this.weapons = spectatee.weapons;
1785         this.punchangle = spectatee.punchangle;
1786         this.view_ofs = spectatee.view_ofs;
1787         this.velocity = spectatee.velocity;
1788         this.dmg_take = spectatee.dmg_take;
1789         this.dmg_save = spectatee.dmg_save;
1790         this.dmg_inflictor = spectatee.dmg_inflictor;
1791         this.v_angle = spectatee.v_angle;
1792         this.angles = spectatee.v_angle;
1793         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1794         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1795         this.viewloc = spectatee.viewloc;
1796         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1797                 this.fixangle = true;
1798         setorigin(this, spectatee.origin);
1799         setsize(this, spectatee.mins, spectatee.maxs);
1800         SetZoomState(this, CS(spectatee).zoomstate);
1801
1802     anticheat_spectatecopy(this, spectatee);
1803         STAT(HUD, this) = STAT(HUD, spectatee);
1804         if(spectatee.vehicle)
1805     {
1806         this.angles = spectatee.v_angle;
1807
1808         //this.fixangle = false;
1809         //this.velocity = spectatee.vehicle.velocity;
1810         this.vehicle_health = spectatee.vehicle_health;
1811         this.vehicle_shield = spectatee.vehicle_shield;
1812         this.vehicle_energy = spectatee.vehicle_energy;
1813         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1814         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1815         this.vehicle_reload1 = spectatee.vehicle_reload1;
1816         this.vehicle_reload2 = spectatee.vehicle_reload2;
1817
1818         //msg_entity = this;
1819
1820        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1821             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1822            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1823            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1824
1825         //WriteByte (MSG_ONE, SVC_SETVIEW);
1826         //    WriteEntity(MSG_ONE, this);
1827         //makevectors(spectatee.v_angle);
1828         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1829     }
1830 }
1831
1832 bool SpectateUpdate(entity this)
1833 {
1834         if(!this.enemy)
1835                 return false;
1836
1837         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1838         {
1839                 SetSpectatee(this, NULL);
1840                 return false;
1841         }
1842
1843         SpectateCopy(this, this.enemy);
1844
1845         return true;
1846 }
1847
1848 bool SpectateSet(entity this)
1849 {
1850         if(!IS_PLAYER(this.enemy))
1851                 return false;
1852
1853         ClientData_Touch(this.enemy);
1854
1855         msg_entity = this;
1856         WriteByte(MSG_ONE, SVC_SETVIEW);
1857         WriteEntity(MSG_ONE, this.enemy);
1858         set_movetype(this, MOVETYPE_NONE);
1859         accuracy_resend(this);
1860
1861         if(!SpectateUpdate(this))
1862                 PutObserverInServer(this);
1863
1864         return true;
1865 }
1866
1867 void SetSpectatee_status(entity this, int spectatee_num)
1868 {
1869         int oldspectatee_status = CS(this).spectatee_status;
1870         CS(this).spectatee_status = spectatee_num;
1871
1872         if (CS(this).spectatee_status != oldspectatee_status)
1873         {
1874                 ClientData_Touch(this);
1875                 if (g_race || g_cts) race_InitSpectator();
1876         }
1877 }
1878
1879 void SetSpectatee(entity this, entity spectatee)
1880 {
1881         if(IS_BOT_CLIENT(this))
1882                 return; // bots abuse .enemy, this code is useless to them
1883
1884         entity old_spectatee = this.enemy;
1885
1886         this.enemy = spectatee;
1887
1888         // WEAPONTODO
1889         // these are required to fix the spectator bug with arc
1890         if(old_spectatee)
1891         {
1892                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1893                 {
1894                         .entity weaponentity = weaponentities[slot];
1895                         if(old_spectatee.(weaponentity).arc_beam)
1896                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1897                 }
1898         }
1899         if(this.enemy)
1900         {
1901                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1902                 {
1903                         .entity weaponentity = weaponentities[slot];
1904                         if(this.enemy.(weaponentity).arc_beam)
1905                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1906                 }
1907         }
1908
1909         if (this.enemy)
1910                 SetSpectatee_status(this, etof(this.enemy));
1911
1912         // needed to update spectator list
1913         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1914 }
1915
1916 bool Spectate(entity this, entity pl)
1917 {
1918         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1919                 return false;
1920         pl = M_ARGV(1, entity);
1921
1922         SetSpectatee(this, pl);
1923         return SpectateSet(this);
1924 }
1925
1926 bool SpectateNext(entity this)
1927 {
1928         entity ent = find(this.enemy, classname, STR_PLAYER);
1929
1930         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1931                 ent = M_ARGV(1, entity);
1932         else if (!ent)
1933                 ent = find(ent, classname, STR_PLAYER);
1934
1935         if(ent) { SetSpectatee(this, ent); }
1936
1937         return SpectateSet(this);
1938 }
1939
1940 bool SpectatePrev(entity this)
1941 {
1942         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1943         entity ent = findchain(classname, STR_PLAYER);
1944         if (!ent) // no player
1945                 return false;
1946
1947         entity first = ent;
1948         // skip players until current spectated player
1949         if(this.enemy)
1950         while(ent && ent != this.enemy)
1951                 ent = ent.chain;
1952
1953         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1954         {
1955                 case MUT_SPECPREV_FOUND:
1956                     ent = M_ARGV(1, entity);
1957                     break;
1958                 case MUT_SPECPREV_RETURN:
1959                     return true;
1960                 case MUT_SPECPREV_CONTINUE:
1961                 default:
1962                 {
1963                         if(ent.chain)
1964                                 ent = ent.chain;
1965                         else
1966                                 ent = first;
1967                         break;
1968                 }
1969         }
1970
1971         SetSpectatee(this, ent);
1972         return SpectateSet(this);
1973 }
1974
1975 /*
1976 =============
1977 ShowRespawnCountdown()
1978
1979 Update a respawn countdown display.
1980 =============
1981 */
1982 void ShowRespawnCountdown(entity this)
1983 {
1984         float number;
1985         if(!IS_DEAD(this)) // just respawned?
1986                 return;
1987         else
1988         {
1989                 number = ceil(this.respawn_time - time);
1990                 if(number <= 0)
1991                         return;
1992                 if(number <= this.respawn_countdown)
1993                 {
1994                         this.respawn_countdown = number - 1;
1995                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1996                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1997                 }
1998         }
1999 }
2000
2001 .bool team_selected;
2002 bool ShowTeamSelection(entity this)
2003 {
2004         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2005                 return false;
2006         stuffcmd(this, "menu_showteamselect\n");
2007         return true;
2008 }
2009 void Join(entity this)
2010 {
2011         TRANSMUTE(Player, this);
2012
2013         if(!this.team_selected)
2014         if(autocvar_g_campaign || autocvar_g_balance_teams)
2015                 JoinBestTeam(this, true);
2016
2017         if(autocvar_g_campaign)
2018                 campaign_bots_may_start = true;
2019
2020         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2021
2022         PutClientInServer(this);
2023
2024         if(IS_PLAYER(this))
2025         if(teamplay && this.team != -1)
2026                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2027         else
2028                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2029         this.team_selected = false;
2030 }
2031
2032 /**
2033  * Determines whether the player is allowed to join. This depends on cvar
2034  * g_maxplayers, if it isn't used this function always return true, otherwise
2035  * it checks whether the number of currently playing players exceeds g_maxplayers.
2036  * @return int number of free slots for players, 0 if none
2037  */
2038 int nJoinAllowed(entity this, entity ignore)
2039 {
2040         if(!ignore)
2041         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2042         // so report 0 free slots if restricted
2043         {
2044                 if(autocvar_g_forced_team_otherwise == "spectate")
2045                         return 0;
2046                 if(autocvar_g_forced_team_otherwise == "spectator")
2047                         return 0;
2048         }
2049
2050         if(this && this.team_forced < 0)
2051                 return 0; // forced spectators can never join
2052
2053         // TODO simplify this
2054         int totalClients = 0;
2055         int currentlyPlaying = 0;
2056         FOREACH_CLIENT(true, {
2057                 if(it != ignore)
2058                         ++totalClients;
2059                 if(IS_REAL_CLIENT(it))
2060                 if(IS_PLAYER(it) || it.caplayer)
2061                         ++currentlyPlaying;
2062         });
2063
2064         float free_slots = 0;
2065         if (!autocvar_g_maxplayers)
2066                 free_slots = maxclients - totalClients;
2067         else if(currentlyPlaying < autocvar_g_maxplayers)
2068                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2069
2070         static float join_prevent_msg_time = 0;
2071         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2072         {
2073                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2074                 join_prevent_msg_time = time + 3;
2075         }
2076
2077         return free_slots;
2078 }
2079
2080 /**
2081  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2082  * g_maxplayers_spectator_blocktime seconds
2083  */
2084 void checkSpectatorBlock(entity this)
2085 {
2086         if(IS_SPEC(this) || IS_OBSERVER(this))
2087         if(!this.caplayer)
2088         if(IS_REAL_CLIENT(this))
2089         {
2090                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2091                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2092                         dropclient(this);
2093                 }
2094         }
2095 }
2096
2097 void PrintWelcomeMessage(entity this)
2098 {
2099         if(CS(this).motd_actived_time == 0)
2100         {
2101                 if (autocvar_g_campaign) {
2102                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2103                                 CS(this).motd_actived_time = time;
2104                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2105                         }
2106                 } else {
2107                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2108                                 CS(this).motd_actived_time = time;
2109                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2110                         }
2111                 }
2112         }
2113         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2114         {
2115                 if (autocvar_g_campaign) {
2116                         if (PHYS_INPUT_BUTTON_INFO(this))
2117                                 CS(this).motd_actived_time = time;
2118                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2119                                 CS(this).motd_actived_time = 0;
2120                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2121                         }
2122                 } else {
2123                         if (PHYS_INPUT_BUTTON_INFO(this))
2124                                 CS(this).motd_actived_time = time;
2125                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2126                                 CS(this).motd_actived_time = 0;
2127                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2128                         }
2129                 }
2130         }
2131         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2132         {
2133                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2134                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2135                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2136                 {
2137                         // instanctly hide MOTD
2138                         CS(this).motd_actived_time = 0;
2139                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2140                 }
2141         }
2142 }
2143
2144 bool joinAllowed(entity this)
2145 {
2146         if (CS(this).version_mismatch) return false;
2147         if (!nJoinAllowed(this, this)) return false;
2148         if (teamplay && lockteams) return false;
2149         if (ShowTeamSelection(this)) return false;
2150         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2151         return true;
2152 }
2153
2154 .int items_added;
2155 .string shootfromfixedorigin;
2156 bool PlayerThink(entity this)
2157 {
2158         if (game_stopped || intermission_running) {
2159                 this.modelflags &= ~MF_ROCKET;
2160                 if(intermission_running)
2161                         IntermissionThink(this);
2162                 return false;
2163         }
2164
2165         if (timeout_status == TIMEOUT_ACTIVE) {
2166         // don't allow the player to turn around while game is paused
2167                 // FIXME turn this into CSQC stuff
2168                 this.v_angle = this.lastV_angle;
2169                 this.angles = this.lastV_angle;
2170                 this.fixangle = true;
2171         }
2172
2173         if (frametime) player_powerups(this);
2174
2175         if (IS_DEAD(this)) {
2176                 if (this.personal && g_race_qualifying) {
2177                         if (time > this.respawn_time) {
2178                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2179                                 respawn(this);
2180                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2181                         }
2182                 } else {
2183                         if (frametime) player_anim(this);
2184
2185                         if (this.respawn_flags & RESPAWN_DENY)
2186                         {
2187                                 STAT(RESPAWN_TIME, this) = 0;
2188                                 return false;
2189                         }
2190
2191                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2192
2193                         switch(this.deadflag)
2194                         {
2195                                 case DEAD_DYING:
2196                                 {
2197                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2198                                                 this.deadflag = DEAD_RESPAWNING;
2199                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2200                                                 this.deadflag = DEAD_DEAD;
2201                                         break;
2202                                 }
2203                                 case DEAD_DEAD:
2204                                 {
2205                                         if (button_pressed)
2206                                                 this.deadflag = DEAD_RESPAWNABLE;
2207                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2208                                                 this.deadflag = DEAD_RESPAWNING;
2209                                         break;
2210                                 }
2211                                 case DEAD_RESPAWNABLE:
2212                                 {
2213                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2214                                                 this.deadflag = DEAD_RESPAWNING;
2215                                         break;
2216                                 }
2217                                 case DEAD_RESPAWNING:
2218                                 {
2219                                         if (time > this.respawn_time)
2220                                         {
2221                                                 this.respawn_time = time + 1; // only retry once a second
2222                                                 this.respawn_time_max = this.respawn_time;
2223                                                 respawn(this);
2224                                         }
2225                                         break;
2226                                 }
2227                         }
2228
2229                         ShowRespawnCountdown(this);
2230
2231                         if (this.respawn_flags & RESPAWN_SILENT)
2232                                 STAT(RESPAWN_TIME, this) = 0;
2233                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2234                         {
2235                                 if (time < this.respawn_time)
2236                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2237                                 else if (this.deadflag != DEAD_RESPAWNING)
2238                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2239                         }
2240                         else
2241                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2242                 }
2243
2244                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2245                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2246                         STAT(RESPAWN_TIME, this) *= -1;
2247
2248                 return false;
2249         }
2250
2251         FixPlayermodel(this);
2252
2253         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2254                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2255                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2256         }
2257
2258         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2259         //if(frametime)
2260         {
2261                 this.items &= ~this.items_added;
2262
2263                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2264                 {
2265                         .entity weaponentity = weaponentities[slot];
2266                         W_WeaponFrame(this, weaponentity);
2267                 }
2268
2269                 this.items_added = 0;
2270                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2271             this.items_added |= IT_FUEL;
2272
2273                 this.items |= this.items_added;
2274         }
2275
2276         player_regen(this);
2277
2278         // WEAPONTODO: Add a weapon request for this
2279         // rot vortex charge to the charge limit
2280         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2281         {
2282                 .entity weaponentity = weaponentities[slot];
2283                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2284                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2285         }
2286
2287         if (frametime) player_anim(this);
2288
2289         // secret status
2290         secrets_setstatus(this);
2291
2292         // monsters status
2293         monsters_setstatus(this);
2294
2295         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2296
2297         return true;
2298 }
2299
2300 void ObserverThink(entity this)
2301 {
2302         if ( CS(this).impulse )
2303         {
2304                 MinigameImpulse(this, CS(this).impulse);
2305                 CS(this).impulse = 0;
2306         }
2307
2308         if (this.flags & FL_JUMPRELEASED) {
2309                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2310                         this.flags &= ~FL_JUMPRELEASED;
2311                         this.flags |= FL_SPAWNING;
2312                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2313                         this.flags &= ~FL_JUMPRELEASED;
2314                         if(SpectateNext(this)) {
2315                                 TRANSMUTE(Spectator, this);
2316                         }
2317                 } else {
2318                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2319                         set_movetype(this, preferred_movetype);
2320                 }
2321         } else {
2322                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2323                         this.flags |= FL_JUMPRELEASED;
2324                         if(this.flags & FL_SPAWNING)
2325                         {
2326                                 this.flags &= ~FL_SPAWNING;
2327                                 Join(this);
2328                                 return;
2329                         }
2330                 }
2331         }
2332 }
2333
2334 void SpectatorThink(entity this)
2335 {
2336         if ( CS(this).impulse )
2337         {
2338                 if(MinigameImpulse(this, CS(this).impulse))
2339                         CS(this).impulse = 0;
2340
2341                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2342                 {
2343                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2344                         CS(this).impulse = 0;
2345                         return;
2346                 }
2347         }
2348
2349         if (this.flags & FL_JUMPRELEASED) {
2350                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2351                         this.flags &= ~FL_JUMPRELEASED;
2352                         this.flags |= FL_SPAWNING;
2353                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2354                         this.flags &= ~FL_JUMPRELEASED;
2355                         if(SpectateNext(this)) {
2356                                 TRANSMUTE(Spectator, this);
2357                         } else {
2358                                 TRANSMUTE(Observer, this);
2359                                 PutClientInServer(this);
2360                         }
2361                         CS(this).impulse = 0;
2362                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2363                         this.flags &= ~FL_JUMPRELEASED;
2364                         if(SpectatePrev(this)) {
2365                                 TRANSMUTE(Spectator, this);
2366                         } else {
2367                                 TRANSMUTE(Observer, this);
2368                                 PutClientInServer(this);
2369                         }
2370                         CS(this).impulse = 0;
2371                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2372                         this.flags &= ~FL_JUMPRELEASED;
2373                         TRANSMUTE(Observer, this);
2374                         PutClientInServer(this);
2375                 } else {
2376                         if(!SpectateUpdate(this))
2377                                 PutObserverInServer(this);
2378                 }
2379         } else {
2380                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2381                         this.flags |= FL_JUMPRELEASED;
2382                         if(this.flags & FL_SPAWNING)
2383                         {
2384                                 this.flags &= ~FL_SPAWNING;
2385                                 Join(this);
2386                                 return;
2387                         }
2388                 }
2389                 if(!SpectateUpdate(this))
2390                         PutObserverInServer(this);
2391         }
2392
2393         this.flags |= FL_CLIENT | FL_NOTARGET;
2394 }
2395
2396 void vehicles_enter (entity pl, entity veh);
2397 void PlayerUseKey(entity this)
2398 {
2399         if (!IS_PLAYER(this))
2400                 return;
2401
2402         if(this.vehicle)
2403         {
2404                 if(!game_stopped)
2405                 {
2406                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2407                         return;
2408                 }
2409         }
2410         else if(autocvar_g_vehicles_enter)
2411         {
2412                 if(!STAT(FROZEN, this))
2413                 if(!IS_DEAD(this))
2414                 if(!game_stopped)
2415                 {
2416                         entity head, closest_target = NULL;
2417                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2418
2419                         while(head) // find the closest acceptable target to enter
2420                         {
2421                                 if(IS_VEHICLE(head))
2422                                 if(!IS_DEAD(head))
2423                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2424                                 if(head.takedamage != DAMAGE_NO)
2425                                 {
2426                                         if(closest_target)
2427                                         {
2428                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2429                                                 { closest_target = head; }
2430                                         }
2431                                         else { closest_target = head; }
2432                                 }
2433
2434                                 head = head.chain;
2435                         }
2436
2437                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2438                 }
2439         }
2440
2441         // a use key was pressed; call handlers
2442         MUTATOR_CALLHOOK(PlayerUseKey, this);
2443 }
2444
2445
2446 /*
2447 =============
2448 PlayerPreThink
2449
2450 Called every frame for each client before the physics are run
2451 =============
2452 */
2453 .float last_vehiclecheck;
2454 void PlayerPreThink (entity this)
2455 {
2456         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2457         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2458
2459         WarpZone_PlayerPhysics_FixVAngle(this);
2460
2461         if (frametime) {
2462                 // physics frames: update anticheat stuff
2463                 anticheat_prethink(this);
2464         }
2465
2466         if (blockSpectators && frametime) {
2467                 // WORKAROUND: only use dropclient in server frames (frametime set).
2468                 // Never use it in cl_movement frames (frametime zero).
2469                 checkSpectatorBlock(this);
2470         }
2471
2472         zoomstate_set = false;
2473
2474         // Check for nameless players
2475         if (this.netname == "" || this.netname != CS(this).netname_previous)
2476         {
2477                 bool assume_unchanged = (CS(this).netname_previous == "");
2478                 if (isInvisibleString(this.netname))
2479                 {
2480                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2481                         assume_unchanged = false;
2482                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2483                 }
2484                 if (!assume_unchanged && autocvar_sv_eventlog)
2485                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2486                 strcpy(CS(this).netname_previous, this.netname);
2487         }
2488
2489         // version nagging
2490         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2491         CS(this).version_nagtime = 0;
2492         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2493             // git client
2494         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2495             // git server
2496             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2497         } else {
2498             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2499             if (r < 0) { // old client
2500                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2501             } else if (r > 0) { // old server
2502                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2503             }
2504         }
2505     }
2506
2507         // GOD MODE info
2508         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2509         {
2510                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2511                 this.max_armorvalue = 0;
2512         }
2513
2514         if(IS_PLAYER(this))
2515         {
2516                 if (STAT(FROZEN, this) == 2)
2517                 {
2518                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2519                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2520                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2521
2522                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2523                                 Unfreeze(this);
2524                 }
2525                 else if (STAT(FROZEN, this) == 3)
2526                 {
2527                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2528                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2529
2530                         if (this.health < 1)
2531                         {
2532                                 if (this.vehicle)
2533                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2534                                 if(this.event_damage)
2535                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2536                         }
2537                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2538                                 Unfreeze(this);
2539                 }
2540         }
2541
2542         MUTATOR_CALLHOOK(PlayerPreThink, this);
2543
2544         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2545         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2546         {
2547                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2548                 {
2549                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2550                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2551                         {
2552                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2553                         }
2554                         else if(!it.owner)
2555                         {
2556                                 if(!it.team || SAME_TEAM(this, it))
2557                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2558                                 else if(autocvar_g_vehicles_steal)
2559                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2560                         }
2561                 });
2562
2563                 this.last_vehiclecheck = time + 1;
2564         }
2565
2566         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2567         {
2568                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2569                         PlayerUseKey(this);
2570                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2571         }
2572
2573         if (IS_REAL_CLIENT(this))
2574                 PrintWelcomeMessage(this);
2575
2576         if (IS_PLAYER(this)) {
2577                 if(!PlayerThink(this))
2578                         return;
2579         }
2580         else if (game_stopped || intermission_running) {
2581                 if(intermission_running)
2582                         IntermissionThink(this);
2583                 return;
2584         }
2585         else if (IS_OBSERVER(this)) {
2586                 ObserverThink(this);
2587         }
2588         else if (IS_SPEC(this)) {
2589                 SpectatorThink(this);
2590         }
2591
2592         // WEAPONTODO: Add weapon request for this
2593         if (!zoomstate_set) {
2594                 bool wep_zoomed = false;
2595                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2596                 {
2597                         .entity weaponentity = weaponentities[slot];
2598                         Weapon thiswep = this.(weaponentity).m_weapon;
2599                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2600                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2601                 }
2602                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2603     }
2604
2605         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2606         {
2607                 CS(this).teamkill_soundtime = 0;
2608
2609                 entity e = CS(this).teamkill_soundsource;
2610                 entity oldpusher = e.pusher;
2611                 e.pusher = this;
2612                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2613                 e.pusher = oldpusher;
2614         }
2615
2616         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2617                 CS(this).taunt_soundtime = 0;
2618                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2619         }
2620
2621         target_voicescript_next(this);
2622
2623         // WEAPONTODO: Move into weaponsystem somehow
2624         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2625         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2626         {
2627                 .entity weaponentity = weaponentities[slot];
2628                 if(this.(weaponentity).m_weapon == WEP_Null)
2629                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2630         }
2631 }
2632
2633 void DrownPlayer(entity this)
2634 {
2635         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2636                 return;
2637
2638         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2639         {
2640                 if(this.air_finished < time)
2641                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2642                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2643         }
2644         else if (this.air_finished < time)
2645         {       // drown!
2646                 if (this.pain_finished < time)
2647                 {
2648                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2649                         this.pain_finished = time + 0.5;
2650                 }
2651         }
2652 }
2653
2654 .bool move_qcphysics;
2655
2656 void Player_Physics(entity this)
2657 {
2658         set_movetype(this, this.move_movetype);
2659
2660         if(!this.move_qcphysics)
2661                 return;
2662
2663         if(!frametime && !CS(this).pm_frametime)
2664                 return;
2665
2666         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2667
2668         CS(this).pm_frametime = 0;
2669 }
2670
2671 /*
2672 =============
2673 PlayerPostThink
2674
2675 Called every frame for each client after the physics are run
2676 =============
2677 */
2678 void PlayerPostThink (entity this)
2679 {
2680         Player_Physics(this);
2681
2682         if (sv_maxidle > 0)
2683         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2684         if (IS_REAL_CLIENT(this))
2685         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2686         {
2687                 int totalClients = 0;
2688                 if(sv_maxidle_slots > 0)
2689                 {
2690                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2691                         {
2692                                 ++totalClients;
2693                         });
2694                 }
2695
2696                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2697                 { /* do nothing */ }
2698                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2699                 {
2700                         if (CS(this).idlekick_lasttimeleft)
2701                         {
2702                                 CS(this).idlekick_lasttimeleft = 0;
2703                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2704                         }
2705                 }
2706                 else
2707                 {
2708                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2709                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2710                                 if (!CS(this).idlekick_lasttimeleft)
2711                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2712                         }
2713                         if (timeleft <= 0) {
2714                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2715                                 dropclient(this);
2716                                 return;
2717                         }
2718                         else if (timeleft <= 10) {
2719                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2720                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2721                 }
2722                                 CS(this).idlekick_lasttimeleft = timeleft;
2723                         }
2724                 }
2725         }
2726
2727         CheatFrame(this);
2728
2729         if (game_stopped)
2730         {
2731                 this.solid = SOLID_NOT;
2732                 this.takedamage = DAMAGE_NO;
2733                 set_movetype(this, MOVETYPE_NONE);
2734         }
2735
2736         if (IS_PLAYER(this)) {
2737                 if(this.death_time == time && IS_DEAD(this))
2738                 {
2739                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2740                         // once all the damage events of this frame have been processed with normal size
2741                         this.maxs.z = 5;
2742                         setsize(this, this.mins, this.maxs);
2743                 }
2744                 DrownPlayer(this);
2745                 UpdateChatBubble(this);
2746                 if (CS(this).impulse) ImpulseCommands(this);
2747                 if (game_stopped)
2748                 {
2749                         CSQCMODEL_AUTOUPDATE(this);
2750                         return;
2751                 }
2752                 GetPressedKeys(this);
2753         }
2754
2755         if (this.waypointsprite_attachedforcarrier) {
2756             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2757                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2758     }
2759
2760         playerdemo_write(this);
2761
2762         CSQCMODEL_AUTOUPDATE(this);
2763 }
2764
2765 // hack to copy the button fields from the client entity to the Client State
2766 void PM_UpdateButtons(entity this, entity store)
2767 {
2768         if(this.impulse)
2769                 store.impulse = this.impulse;
2770         this.impulse = 0;
2771
2772         bool typing = this.buttonchat;
2773
2774         store.button0 = (typing) ? 0 : this.button0;
2775         //button1?!
2776         store.button2 = (typing) ? 0 : this.button2;
2777         store.button3 = (typing) ? 0 : this.button3;
2778         store.button4 = this.button4;
2779         store.button5 = (typing) ? 0 : this.button5;
2780         store.button6 = this.button6;
2781         store.button7 = this.button7;
2782         store.button8 = this.button8;
2783         store.button9 = this.button9;
2784         store.button10 = this.button10;
2785         store.button11 = this.button11;
2786         store.button12 = this.button12;
2787         store.button13 = this.button13;
2788         store.button14 = this.button14;
2789         store.button15 = this.button15;
2790         store.button16 = this.button16;
2791         store.buttonuse = this.buttonuse;
2792         store.buttonchat = this.buttonchat;
2793
2794         store.cursor_active = this.cursor_active;
2795         store.cursor_screen = this.cursor_screen;
2796         store.cursor_trace_start = this.cursor_trace_start;
2797         store.cursor_trace_endpos = this.cursor_trace_endpos;
2798         store.cursor_trace_ent = this.cursor_trace_ent;
2799
2800         store.ping = this.ping;
2801         store.ping_packetloss = this.ping_packetloss;
2802         store.ping_movementloss = this.ping_movementloss;
2803
2804         store.v_angle = this.v_angle;
2805         store.movement = (typing) ? '0 0 0' : this.movement;
2806 }
2807
2808 NET_HANDLE(fpsreport, bool)
2809 {
2810         int fps = ReadShort();
2811         PlayerScore_Set(sender, SP_FPS, fps);
2812         return true;
2813 }