qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/lms/sv_lms.qh>
  10 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  11 #include <common/items/_mod.qh>
  12 #include <common/items/inventory.qh>
  13 #include <common/mapobjects/func/conveyor.qh>
  14 #include <common/mapobjects/func/ladder.qh>
  15 #include <common/mapobjects/subs.qh>
  16 #include <common/mapobjects/target/spawnpoint.qh>
  17 #include <common/mapobjects/teleporters.qh>
  18 #include <common/mapobjects/trigger/counter.qh>
  19 #include <common/mapobjects/trigger/secret.qh>
  20 #include <common/mapobjects/trigger/swamp.qh>
  21 #include <common/mapobjects/triggers.qh>
  22 #include <common/minigames/sv_minigames.qh>
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  25 #include <common/mutators/mutator/nades/nades.qh>
  26 #include <common/mutators/mutator/overkill/oknex.qh>
  27 #include <common/mutators/mutator/status_effects/_mod.qh>
  28 #include <common/mutators/mutator/waypoints/all.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/notifications/all.qh>
  32 #include <common/physics/player.qh>
  33 #include <common/playerstats.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/resources.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 142
 143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if (sf & BIT(1))
 147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 148
 149         if(sf & BIT(4))
 150         {
 151                 float specs = CountSpectators(e, to);
 152                 WriteByte(MSG_ENTITY, specs);
 153                 WriteSpectators(e, to);
 154         }
 155
 156         return true;
 157 }
 158
 159 void ClientData_Attach(entity this)
 160 {
 161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 162         CS(this).clientdata.drawonlytoclient = this;
 163         CS(this).clientdata.owner = this;
 164 }
 165
 166 void ClientData_Detach(entity this)
 167 {
 168         delete(CS(this).clientdata);
 169         CS(this).clientdata = NULL;
 170 }
 171
 172 void ClientData_Touch(entity e)
 173 {
 174         entity cd = CS(e).clientdata;
 175         if (cd) { cd.SendFlags = 1; }
 176
 177         // make it spectatable
 178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 179         {
 180                 entity cd = CS(it).clientdata;
 181                 if (cd) { cd.SendFlags = 1; }
 182         });
 183 }
 184
 185
 186 /*
 187 =============
 188 CheckPlayerModel
 189
 190 Checks if the argument string can be a valid playermodel.
 191 Returns a valid one in doubt.
 192 =============
 193 */
 194 string FallbackPlayerModel;
 195 string CheckPlayerModel(string plyermodel) {
 196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 197         {
 198                 // note: we cannot summon Don Strunzone here, some player may
 199                 // still have the model string set. In case anyone manages how
 200                 // to change a cvar default, we'll have a small leak here.
 201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 202         }
 203         // only in right path
 204         if(substring(plyermodel, 0, 14) != "models/player/")
 205                 return FallbackPlayerModel;
 206         // only good file extensions
 207         if(substring(plyermodel, -4, 4) != ".iqm"
 208                 && substring(plyermodel, -4, 4) != ".zym"
 209                 && substring(plyermodel, -4, 4) != ".dpm"
 210                 && substring(plyermodel, -4, 4) != ".md3"
 211                 && substring(plyermodel, -4, 4) != ".psk")
 212         {
 213                 return FallbackPlayerModel;
 214         }
 215         // forbid the LOD models
 216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 217                 return FallbackPlayerModel;
 218         if(plyermodel != strtolower(plyermodel))
 219                 return FallbackPlayerModel;
 220         // also, restrict to server models
 221         if(autocvar_sv_servermodelsonly)
 222         {
 223                 if(!fexists(plyermodel))
 224                         return FallbackPlayerModel;
 225         }
 226         return plyermodel;
 227 }
 228
 229 void setplayermodel(entity e, string modelname)
 230 {
 231         precache_model(modelname);
 232         _setmodel(e, modelname);
 233         player_setupanimsformodel(e);
 234         if(!autocvar_g_debug_globalsounds)
 235                 UpdatePlayerSounds(e);
 236 }
 237
 238 /** putting a client as observer in the server */
 239 void PutObserverInServer(entity this)
 240 {
 241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         ReadyCount();
 257                 }
 258                 entcs_update_players(this);
 259         }
 260
 261         entity spot = SelectSpawnPoint(this, true);
 262         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 263         this.angles = vec2(spot.angles);
 264         this.fixangle = true;
 265         // offset it so that the spectator spawns higher off the ground, looks better this way
 266         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 267         if (IS_REAL_CLIENT(this))
 268         {
 269                 msg_entity = this;
 270                 WriteByte(MSG_ONE, SVC_SETVIEW);
 271                 WriteEntity(MSG_ONE, this);
 272         }
 273         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 274         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 275         if(!autocvar_g_debug_globalsounds)
 276         {
 277                 // needed for player sounds
 278                 this.model = "";
 279                 FixPlayermodel(this);
 280         }
 281         setmodel(this, MDL_Null);
 282         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 283         this.view_ofs = '0 0 0';
 284
 285         RemoveGrapplingHooks(this);
 286         Portal_ClearAll(this);
 287         Unfreeze(this, false);
 288         SetSpectatee(this, NULL);
 289
 290         if (this.alivetime)
 291         {
 292                 if (!warmup_stage)
 293                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 294                 this.alivetime = 0;
 295         }
 296
 297         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 298
 299         WaypointSprite_PlayerDead(this);
 300
 301         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 302                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310         if(this.monster_attack)
 311                 IL_REMOVE(g_monster_targets, this);
 312         this.monster_attack = false;
 313         STAT(HUD, this) = HUD_NORMAL;
 314         TRANSMUTE(Observer, this);
 315         this.iscreature = false;
 316         this.teleportable = TELEPORT_SIMPLE;
 317         if(this.damagedbycontents)
 318                 IL_REMOVE(g_damagedbycontents, this);
 319         this.damagedbycontents = false;
 320         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 321         SetSpectatee_status(this, etof(this));
 322         this.takedamage = DAMAGE_NO;
 323         this.solid = SOLID_NOT;
 324         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 325         this.flags = FL_CLIENT | FL_NOTARGET;
 326         this.effects = 0;
 327         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 328         this.pauserotarmor_finished = 0;
 329         this.pauserothealth_finished = 0;
 330         this.pauseregen_finished = 0;
 331         this.damageforcescale = 0;
 332         this.death_time = 0;
 333         this.respawn_flags = 0;
 334         this.respawn_time = 0;
 335         STAT(RESPAWN_TIME, this) = 0;
 336         this.alpha = 0;
 337         this.scale = 0;
 338         this.fade_time = 0;
 339         this.pain_finished = 0;
 340         STAT(AIR_FINISHED, this) = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         UNSET_DUCKED(this);
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.event_damage = func_null;
 376         this.event_heal = func_null;
 377
 378         for(int slot = 0; slot < MAX_AXH; ++slot)
 379         {
 380                 entity axh = this.(AuxiliaryXhair[slot]);
 381                 this.(AuxiliaryXhair[slot]) = NULL;
 382
 383                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 384                         delete(axh);
 385         }
 386
 387         if (mutator_returnvalue)
 388         {
 389                 // mutator prevents resetting teams+score
 390         }
 391         else
 392         {
 393                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 394                 this.frags = FRAGS_SPECTATOR;
 395         }
 396
 397         bot_relinkplayerlist();
 398
 399         if (CS(this).just_joined)
 400                 CS(this).just_joined = false;
 401 }
 402
 403 int player_getspecies(entity this)
 404 {
 405         get_model_parameters(this.model, this.skin);
 406         int s = get_model_parameters_species;
 407         get_model_parameters(string_null, 0);
 408         if (s < 0) return SPECIES_HUMAN;
 409         return s;
 410 }
 411
 412 .float model_randomizer;
 413 void FixPlayermodel(entity player)
 414 {
 415         string defaultmodel = "";
 416         int defaultskin = 0;
 417         if(autocvar_sv_defaultcharacter)
 418         {
 419                 if(teamplay)
 420                 {
 421                         switch(player.team)
 422                         {
 423                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 424                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 425                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 426                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 427                         }
 428                 }
 429
 430                 if(defaultmodel == "")
 431                 {
 432                         defaultmodel = autocvar_sv_defaultplayermodel;
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434                 }
 435
 436                 int n = tokenize_console(defaultmodel);
 437                 if(n > 0)
 438                 {
 439                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 440                         // However, do NOT randomize if the player-selected model is in the list.
 441                         for (int i = 0; i < n; ++i)
 442                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 443                                         defaultmodel = argv(i);
 444                 }
 445
 446                 int i = strstrofs(defaultmodel, ":", 0);
 447                 if(i >= 0)
 448                 {
 449                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 450                         defaultmodel = substring(defaultmodel, 0, i);
 451                 }
 452         }
 453         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 454         {
 455                 if(teamplay)
 456                 {
 457                         switch(player.team)
 458                         {
 459                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 460                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 461                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 462                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 463                         }
 464                 }
 465
 466                 if(!defaultskin)
 467                         defaultskin = autocvar_sv_defaultplayerskin;
 468         }
 469
 470         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 471         defaultmodel = M_ARGV(0, string);
 472         defaultskin = M_ARGV(1, int);
 473
 474         bool chmdl = false;
 475         int oldskin;
 476         if(defaultmodel != "")
 477         {
 478                 if (defaultmodel != player.model)
 479                 {
 480                         vector m1 = player.mins;
 481                         vector m2 = player.maxs;
 482                         setplayermodel (player, defaultmodel);
 483                         setsize (player, m1, m2);
 484                         chmdl = true;
 485                 }
 486
 487                 oldskin = player.skin;
 488                 player.skin = defaultskin;
 489         } else {
 490                 if (player.playermodel != player.model || player.playermodel == "")
 491                 {
 492                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 493                         vector m1 = player.mins;
 494                         vector m2 = player.maxs;
 495                         setplayermodel (player, player.playermodel);
 496                         setsize (player, m1, m2);
 497                         chmdl = true;
 498                 }
 499
 500                 if(!autocvar_sv_defaultcharacterskin)
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = stof(player.playerskin);
 504                 }
 505                 else
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = defaultskin;
 509                 }
 510         }
 511
 512         if(chmdl || oldskin != player.skin) // model or skin has changed
 513         {
 514                 player.species = player_getspecies(player); // update species
 515                 if(!autocvar_g_debug_globalsounds)
 516                         UpdatePlayerSounds(player); // update skin sounds
 517         }
 518
 519         if(!teamplay)
 520                 if(strlen(autocvar_sv_defaultplayercolors))
 521                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 522                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 523 }
 524
 525 void PutPlayerInServer(entity this)
 526 {
 527         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 528
 529         PlayerState_attach(this);
 530         accuracy_resend(this);
 531
 532         if (this.team < 0)
 533                 TeamBalance_JoinBestTeam(this);
 534
 535         entity spot = SelectSpawnPoint(this, false);
 536         if (!spot) {
 537                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 538                 return; // spawn failed
 539         }
 540
 541         TRANSMUTE(Player, this);
 542
 543         CS(this).wasplayer = true;
 544         this.iscreature = true;
 545         this.teleportable = TELEPORT_NORMAL;
 546         if(!this.damagedbycontents)
 547                 IL_PUSH(g_damagedbycontents, this);
 548         this.damagedbycontents = true;
 549         set_movetype(this, MOVETYPE_WALK);
 550         this.solid = SOLID_SLIDEBOX;
 551         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 552         if (autocvar_g_playerclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 554         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 555                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 556         this.frags = FRAGS_PLAYER;
 557         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 558         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 559         if (autocvar__notarget)
 560                 this.flags |= FL_NOTARGET;
 561         this.takedamage = DAMAGE_AIM;
 562         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 563
 564         if (warmup_stage) {
 565                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 566                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 567                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 568                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 569                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 570                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 571                 SetResource(this, RES_HEALTH, warmup_start_health);
 572                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 573                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 574         } else {
 575                 SetResource(this, RES_SHELLS, start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, start_health);
 582                 SetResource(this, RES_ARMOR, start_armorvalue);
 583                 STAT(WEAPONS, this) = start_weapons;
 584                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 585                 {
 586                         GiveRandomWeapons(this, random_start_weapons_count,
 587                                 autocvar_g_random_start_weapons, random_start_ammo);
 588                 }
 589         }
 590         SetSpectatee_status(this, 0);
 591
 592         PS(this).dual_weapons = '0 0 0';
 593
 594         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 595                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 596
 597         this.items = start_items;
 598
 599         float shieldtime = time + autocvar_g_spawnshieldtime;
 600
 601         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 602         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 603         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 604         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 605         if (!sv_ready_restart_after_countdown && time < game_starttime)
 606         {
 607                 float f = game_starttime - time;
 608                 shieldtime += f;
 609                 this.pauserotarmor_finished += f;
 610                 this.pauserothealth_finished += f;
 611                 this.pauseregen_finished += f;
 612         }
 613
 614         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 615
 616         this.damageforcescale = autocvar_g_player_damageforcescale;
 617         this.death_time = 0;
 618         this.respawn_flags = 0;
 619         this.respawn_time = 0;
 620         STAT(RESPAWN_TIME, this) = 0;
 621         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 622         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 623         this.fade_time = 0;
 624         this.pain_finished = 0;
 625         this.pushltime = 0;
 626         setthink(this, func_null); // players have no think function
 627         this.nextthink = 0;
 628         this.dmg_team = 0;
 629         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 630
 631         this.deadflag = DEAD_NO;
 632
 633         this.angles = spot.angles;
 634         this.angles_z = 0; // never spawn tilted even if the spot says to
 635         if (IS_BOT_CLIENT(this))
 636         {
 637                 this.v_angle = this.angles;
 638                 bot_aim_reset(this);
 639         }
 640         this.fixangle = true; // turn this way immediately
 641         this.oldvelocity = this.velocity = '0 0 0';
 642         this.avelocity = '0 0 0';
 643         this.punchangle = '0 0 0';
 644         this.punchvector = '0 0 0';
 645
 646         STAT(REVIVE_PROGRESS, this) = 0;
 647         this.revival_time = 0;
 648
 649         STAT(AIR_FINISHED, this) = 0;
 650         this.waterlevel = WATERLEVEL_NONE;
 651         this.watertype = CONTENT_EMPTY;
 652
 653         entity spawnevent = new_pure(spawnevent);
 654         spawnevent.owner = this;
 655         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 656
 657         // Cut off any still running player sounds.
 658         stopsound(this, CH_PLAYER_SINGLE);
 659
 660         this.model = "";
 661         FixPlayermodel(this);
 662         this.drawonlytoclient = NULL;
 663
 664         this.viewloc = NULL;
 665
 666         for(int slot = 0; slot < MAX_AXH; ++slot)
 667         {
 668                 entity axh = this.(AuxiliaryXhair[slot]);
 669                 this.(AuxiliaryXhair[slot]) = NULL;
 670
 671                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 672                         delete(axh);
 673         }
 674
 675         this.spawnpoint_targ = NULL;
 676
 677         UNSET_DUCKED(this);
 678         this.view_ofs = STAT(PL_VIEW_OFS, this);
 679         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 680         this.spawnorigin = spot.origin;
 681         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 682         // don't reset back to last position, even if new position is stuck in solid
 683         this.oldorigin = this.origin;
 684         if(this.conveyor)
 685                 IL_REMOVE(g_conveyed, this);
 686         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 687         if(this.swampslug)
 688                 IL_REMOVE(g_swamped, this);
 689         this.swampslug = NULL;
 690         this.swamp_interval = 0;
 691         if(this.ladder_entity)
 692                 IL_REMOVE(g_ladderents, this);
 693         this.ladder_entity = NULL;
 694         IL_EACH(g_counters, it.realowner == this,
 695         {
 696                 delete(it);
 697         });
 698         STAT(HUD, this) = HUD_NORMAL;
 699
 700         this.event_damage = PlayerDamage;
 701         this.event_heal = PlayerHeal;
 702
 703         this.draggable = func_null;
 704
 705         if(!this.bot_attack)
 706                 IL_PUSH(g_bot_targets, this);
 707         this.bot_attack = true;
 708         if(!this.monster_attack)
 709                 IL_PUSH(g_monster_targets, this);
 710         this.monster_attack = true;
 711         navigation_dynamicgoal_init(this, false);
 712
 713         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 714
 715         // player was spectator
 716         if (CS(this).killcount == FRAGS_SPECTATOR) {
 717                 PlayerScore_Clear(this);
 718                 CS(this).killcount = 0;
 719                 CS(this).startplaytime = time;
 720         }
 721
 722         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 723         {
 724                 .entity weaponentity = weaponentities[slot];
 725                 CL_SpawnWeaponentity(this, weaponentity);
 726         }
 727         this.alpha = default_player_alpha;
 728         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 729         this.exteriorweaponentity.alpha = default_weapon_alpha;
 730
 731         this.speedrunning = false;
 732
 733         this.counter_cnt = 0;
 734         this.fragsfilter_cnt = 0;
 735
 736         target_voicescript_clear(this);
 737
 738         // reset fields the weapons may use
 739         FOREACH(Weapons, true, {
 740                 it.wr_resetplayer(it, this);
 741                         // reload all reloadable weapons
 742                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 743                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744                         {
 745                                 .entity weaponentity = weaponentities[slot];
 746                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 747                         }
 748                 }
 749         });
 750
 751         Unfreeze(this, false);
 752
 753         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 754
 755         {
 756                 string s = spot.target;
 757                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 758                         spot.target = string_null;
 759                 SUB_UseTargets(spot, this, NULL);
 760                 if(g_assault || g_race)
 761                         spot.target = s;
 762         }
 763
 764         if (autocvar_spawn_debug)
 765         {
 766                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 767                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 768         }
 769
 770         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 771         {
 772                 .entity weaponentity = weaponentities[slot];
 773                 entity w_ent = this.(weaponentity);
 774                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 775                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 776                 else
 777                         w_ent.m_switchweapon = WEP_Null;
 778                 w_ent.m_weapon = WEP_Null;
 779                 w_ent.weaponname = "";
 780                 w_ent.m_switchingweapon = WEP_Null;
 781                 w_ent.cnt = -1;
 782         }
 783
 784         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 785
 786         if (CS(this).impulse) ImpulseCommands(this);
 787
 788         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 789         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 790         {
 791                 .entity weaponentity = weaponentities[slot];
 792                 W_WeaponFrame(this, weaponentity);
 793         }
 794
 795         if (!warmup_stage && !this.alivetime)
 796                 this.alivetime = time;
 797
 798         antilag_clear(this, CS(this));
 799 }
 800
 801 /** Called when a client spawns in the server */
 802 void PutClientInServer(entity this)
 803 {
 804         if (IS_BOT_CLIENT(this)) {
 805                 TRANSMUTE(Player, this);
 806         } else if (IS_REAL_CLIENT(this)) {
 807                 msg_entity = this;
 808                 WriteByte(MSG_ONE, SVC_SETVIEW);
 809                 WriteEntity(MSG_ONE, this);
 810         }
 811         if (game_stopped)
 812                 TRANSMUTE(Observer, this);
 813
 814         SetSpectatee(this, NULL);
 815
 816         // reset player keys
 817         if(PS(this))
 818                 PS(this).itemkeys = 0;
 819
 820         MUTATOR_CALLHOOK(PutClientInServer, this);
 821
 822         if (IS_OBSERVER(this)) {
 823                 PutObserverInServer(this);
 824         } else if (IS_PLAYER(this)) {
 825                 PutPlayerInServer(this);
 826         }
 827
 828         bot_relinkplayerlist();
 829 }
 830
 831 // TODO do we need all these fields, or should we stop autodetecting runtime
 832 // changes and just have a console command to update this?
 833 bool ClientInit_SendEntity(entity this, entity to, int sf)
 834 {
 835         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 836         return = true;
 837         msg_entity = to;
 838         // MSG_INIT replacement
 839         // TODO: make easier to use
 840         Registry_send_all();
 841         W_PROP_reload(MSG_ONE, to);
 842         ClientInit_misc(this);
 843         MUTATOR_CALLHOOK(Ent_Init);
 844 }
 845 void ClientInit_misc(entity this)
 846 {
 847         int channel = MSG_ONE;
 848         WriteHeader(channel, ENT_CLIENT_INIT);
 849         WriteByte(channel, g_nexball_meter_period * 32);
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 852         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 853         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 856         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 857         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 858
 859         if(autocvar_sv_foginterval && world.fog != "")
 860                 WriteString(channel, world.fog);
 861         else
 862                 WriteString(channel, "");
 863         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 864         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 865         WriteByte(channel, serverflags);
 866         WriteCoord(channel, autocvar_g_trueaim_minrange);
 867 }
 868
 869 void ClientInit_CheckUpdate(entity this)
 870 {
 871         this.nextthink = time;
 872         if(this.count != autocvar_g_balance_armor_blockpercent)
 873         {
 874                 this.count = autocvar_g_balance_armor_blockpercent;
 875                 this.SendFlags |= 1;
 876         }
 877         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 878         {
 879                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 880                 this.SendFlags |= 1;
 881         }
 882 }
 883
 884 void ClientInit_Spawn()
 885 {
 886         entity e = new_pure(clientinit);
 887         setthink(e, ClientInit_CheckUpdate);
 888         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 889
 890         ClientInit_CheckUpdate(e);
 891 }
 892
 893 /*
 894 =============
 895 SetNewParms
 896 =============
 897 */
 898 void SetNewParms ()
 899 {
 900         // initialize parms for a new player
 901         parm1 = -(86400 * 366);
 902
 903         MUTATOR_CALLHOOK(SetNewParms);
 904 }
 905
 906 /*
 907 =============
 908 SetChangeParms
 909 =============
 910 */
 911 void SetChangeParms (entity this)
 912 {
 913         // save parms for level change
 914         parm1 = CS(this).parm_idlesince - time;
 915
 916         MUTATOR_CALLHOOK(SetChangeParms);
 917 }
 918
 919 /*
 920 =============
 921 DecodeLevelParms
 922 =============
 923 */
 924 void DecodeLevelParms(entity this)
 925 {
 926         // load parms
 927         CS(this).parm_idlesince = parm1;
 928         if (CS(this).parm_idlesince == -(86400 * 366))
 929                 CS(this).parm_idlesince = time;
 930
 931         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 932         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 933
 934         MUTATOR_CALLHOOK(DecodeLevelParms);
 935 }
 936
 937 void FixClientCvars(entity e)
 938 {
 939         // send prediction settings to the client
 940         stuffcmd(e, "\nin_bindmap 0 0\n");
 941         if(autocvar_g_antilag == 3) // client side hitscan
 942                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 943         if(autocvar_sv_gentle)
 944                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 945
 946         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 947         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 948
 949         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 950
 951         MUTATOR_CALLHOOK(FixClientCvars, e);
 952 }
 953
 954 bool findinlist_abbrev(string tofind, string list)
 955 {
 956         if(list == "" || tofind == "")
 957                 return false; // empty list or search, just return
 958
 959         // this function allows abbreviated strings!
 960         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 961         {
 962                 return true;
 963         });
 964
 965         return false;
 966 }
 967
 968 bool PlayerInIPList(entity p, string iplist)
 969 {
 970         // some safety checks (never allow local?)
 971         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 972                 return false;
 973
 974         return findinlist_abbrev(p.netaddress, iplist);
 975 }
 976
 977 bool PlayerInIDList(entity p, string idlist)
 978 {
 979         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 980         if(!p.crypto_idfp)
 981                 return false;
 982
 983         return findinlist_abbrev(p.crypto_idfp, idlist);
 984 }
 985
 986 bool PlayerInList(entity player, string list)
 987 {
 988         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 989 }
 990
 991 #ifdef DP_EXT_PRECONNECT
 992 /*
 993 =============
 994 ClientPreConnect
 995
 996 Called once (not at each match start) when a client begins a connection to the server
 997 =============
 998 */
 999 void ClientPreConnect(entity this)
1000 {
1001         if(autocvar_sv_eventlog)
1002         {
1003                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1004                         this.playerid,
1005                         etof(this),
1006                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1007                 ));
1008         }
1009 }
1010 #endif
1011
1012 string GetClientVersionMessage(entity this)
1013 {
1014         if (CS(this).version_mismatch) {
1015                 if(CS(this).version < autocvar_gameversion) {
1016                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1017                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1018                 } else {
1019                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1020                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1021                 }
1022         } else {
1023                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1024         }
1025 }
1026
1027 string getwelcomemessage(entity this)
1028 {
1029         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1030         string modifications = M_ARGV(0, string);
1031
1032         if(g_weaponarena)
1033         {
1034                 if(g_weaponarena_random)
1035                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1036                 else
1037                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1038         }
1039         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1040                 modifications = strcat(modifications, ", No start weapons");
1041         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1042                 modifications = strcat(modifications, ", Low gravity");
1043         if(g_weapon_stay && !g_cts)
1044                 modifications = strcat(modifications, ", Weapons stay");
1045         if(autocvar_g_jetpack)
1046                 modifications = strcat(modifications, ", Jet pack");
1047         modifications = substring(modifications, 2, strlen(modifications) - 2);
1048
1049         string versionmessage = GetClientVersionMessage(this);
1050         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1051
1052         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1053
1054         if(modifications != "")
1055                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1056
1057         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1058         {
1059                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1060                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1061         }
1062
1063         if (cache_mutatormsg != "") {
1064                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1065         }
1066
1067         string mutator_msg = "";
1068         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1069         mutator_msg = M_ARGV(0, string);
1070
1071         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1072
1073         string motd = autocvar_sv_motd;
1074         if (motd != "") {
1075                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1076         }
1077         return s;
1078 }
1079
1080 /**
1081 =============
1082 ClientConnect
1083
1084 Called when a client connects to the server
1085 =============
1086 */
1087 void ClientConnect(entity this)
1088 {
1089         if (Ban_MaybeEnforceBanOnce(this)) return;
1090         assert(!IS_CLIENT(this), return);
1091         this.flags |= FL_CLIENT;
1092         assert(player_count >= 0, player_count = 0);
1093
1094         TRANSMUTE(Client, this);
1095         CS(this).version_nagtime = time + 10 + random() * 10;
1096
1097         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1098
1099         bot_clientconnect(this);
1100
1101         Player_DetermineForcedTeam(this);
1102
1103         TRANSMUTE(Observer, this);
1104
1105         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1106
1107         // always track bots, don't ask for cl_allow_uidtracking
1108         if (IS_BOT_CLIENT(this))
1109                 PlayerStats_GameReport_AddPlayer(this);
1110         else
1111                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1112
1113         if (autocvar_sv_eventlog)
1114                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1115
1116         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1117
1118         stuffcmd(this, clientstuff, "\n");
1119         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1120
1121         FixClientCvars(this);
1122
1123         // get version info from player
1124         stuffcmd(this, "cmd clientversion $gameversion\n");
1125
1126         // notify about available teams
1127         if (teamplay)
1128         {
1129                 entity balance = TeamBalance_CheckAllowedTeams(this);
1130                 int t = TeamBalance_GetAllowedTeams(balance);
1131                 TeamBalance_Destroy(balance);
1132                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1133         }
1134         else
1135         {
1136                 stuffcmd(this, "set _teams_available 0\n");
1137         }
1138
1139         bot_relinkplayerlist();
1140
1141         CS(this).spectatortime = time;
1142         if (blockSpectators)
1143         {
1144                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1145         }
1146
1147         CS(this).jointime = time;
1148
1149         if (IS_REAL_CLIENT(this))
1150         {
1151                 if (g_weaponarena_weapons == WEPSET(TUBA))
1152                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1153         }
1154
1155         if (!autocvar_sv_foginterval && world.fog != "")
1156                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1157
1158         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1159                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1160                         send_CSQC_teamnagger();
1161
1162         CSQCMODEL_AUTOINIT(this);
1163
1164         CS(this).model_randomizer = random();
1165
1166         if (IS_REAL_CLIENT(this))
1167                 sv_notice_join(this);
1168
1169         this.move_qcphysics = autocvar_sv_qcphysics;
1170
1171         // update physics stats (players can spawn before physics runs)
1172         Physics_UpdateStats(this);
1173
1174         IL_EACH(g_initforplayer, it.init_for_player, {
1175                 it.init_for_player(it, this);
1176         });
1177
1178         Handicap_Initialize(this);
1179
1180         MUTATOR_CALLHOOK(ClientConnect, this);
1181
1182         if (IS_REAL_CLIENT(this))
1183         {
1184                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1185                 {
1186                         CS(this).motd_actived_time = -1;
1187                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1188                 }
1189         }
1190 }
1191 /*
1192 =============
1193 ClientDisconnect
1194
1195 Called when a client disconnects from the server
1196 =============
1197 */
1198 .entity chatbubbleentity;
1199 void player_powerups_remove_all(entity this);
1200
1201 void ClientDisconnect(entity this)
1202 {
1203         assert(IS_CLIENT(this), return);
1204
1205         PlayerStats_GameReport_FinalizePlayer(this);
1206         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1207         if (CS(this).active_minigame) part_minigame(this);
1208         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1209
1210         if (autocvar_sv_eventlog)
1211                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1212
1213         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1214
1215         if(IS_SPEC(this))
1216                 SetSpectatee(this, NULL);
1217
1218         MUTATOR_CALLHOOK(ClientDisconnect, this);
1219
1220         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1221         strfree(CS_CVAR(this).weaponorder_byimpulse);
1222         ClientState_detach(this);
1223
1224         Portal_ClearAll(this);
1225
1226         Unfreeze(this, false);
1227
1228         RemoveGrapplingHooks(this);
1229
1230         // Here, everything has been done that requires this player to be a client.
1231
1232         this.flags &= ~FL_CLIENT;
1233
1234         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1235         if (this.killindicator) delete(this.killindicator);
1236
1237         IL_EACH(g_counters, it.realowner == this,
1238         {
1239                 delete(it);
1240         });
1241
1242         WaypointSprite_PlayerGone(this);
1243
1244         bot_relinkplayerlist();
1245
1246         strfree(this.clientstatus);
1247         if (this.personal) delete(this.personal);
1248
1249         this.playerid = 0;
1250         ReadyCount();
1251         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1252
1253         player_powerups_remove_all(this); // stop powerup sound
1254
1255         ONREMOVE(this);
1256 }
1257
1258 void ChatBubbleThink(entity this)
1259 {
1260         this.nextthink = time;
1261         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1262         {
1263                 if(this.owner) // but why can that ever be NULL?
1264                         this.owner.chatbubbleentity = NULL;
1265                 delete(this);
1266                 return;
1267         }
1268
1269         this.mdl = "";
1270
1271         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1272         {
1273                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1274                         this.mdl = "models/sprites/minigame_busy.iqm";
1275                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1276                         this.mdl = "models/misc/chatbubble.spr";
1277         }
1278
1279         if ( this.model != this.mdl )
1280                 _setmodel(this, this.mdl);
1281
1282 }
1283
1284 void UpdateChatBubble(entity this)
1285 {
1286         if (this.alpha < 0)
1287                 return;
1288         // spawn a chatbubble entity if needed
1289         if (!this.chatbubbleentity)
1290         {
1291                 this.chatbubbleentity = new(chatbubbleentity);
1292                 this.chatbubbleentity.owner = this;
1293                 this.chatbubbleentity.exteriormodeltoclient = this;
1294                 setthink(this.chatbubbleentity, ChatBubbleThink);
1295                 this.chatbubbleentity.nextthink = time;
1296                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1297                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1298                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1299                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1300                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1301                 //this.chatbubbleentity.model = "";
1302                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1303         }
1304 }
1305
1306 void calculate_player_respawn_time(entity this)
1307 {
1308         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1309                 return;
1310
1311         float gametype_setting_tmp;
1312         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1313         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1314         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1315         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1316         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1317         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1318
1319         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1320         if (teamplay)
1321         {
1322                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1323                         if(it.team == this.team)
1324                                 ++pcount;
1325                 });
1326                 if (sdelay_small_count == 0)
1327                         sdelay_small_count = 1;
1328                 if (sdelay_large_count == 0)
1329                         sdelay_large_count = 1;
1330         }
1331         else
1332         {
1333                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1334                         ++pcount;
1335                 });
1336                 if (sdelay_small_count == 0)
1337                 {
1338                         if (IS_INDEPENDENT_PLAYER(this))
1339                         {
1340                                 // Players play independently. No point in requiring enemies.
1341                                 sdelay_small_count = 1;
1342                         }
1343                         else
1344                         {
1345                                 // Players play AGAINST each other. Enemies required.
1346                                 sdelay_small_count = 2;
1347                         }
1348                 }
1349                 if (sdelay_large_count == 0)
1350                 {
1351                         if (IS_INDEPENDENT_PLAYER(this))
1352                         {
1353                                 // Players play independently. No point in requiring enemies.
1354                                 sdelay_large_count = 1;
1355                         }
1356                         else
1357                         {
1358                                 // Players play AGAINST each other. Enemies required.
1359                                 sdelay_large_count = 2;
1360                         }
1361                 }
1362         }
1363
1364         float sdelay;
1365
1366         if (pcount <= sdelay_small_count)
1367                 sdelay = sdelay_small;
1368         else if (pcount >= sdelay_large_count)
1369                 sdelay = sdelay_large;
1370         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1371                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1372
1373         if(waves)
1374                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1375         else
1376                 this.respawn_time = time + sdelay;
1377
1378         if(sdelay < sdelay_max)
1379                 this.respawn_time_max = time + sdelay_max;
1380         else
1381                 this.respawn_time_max = this.respawn_time;
1382
1383         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1384                 this.respawn_countdown = 10; // first number to count down from is 10
1385         else
1386                 this.respawn_countdown = -1; // do not count down
1387
1388         if(autocvar_g_forced_respawn)
1389                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1390 }
1391
1392 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1393 // added to the model skins
1394 /*void UpdateColorModHack()
1395 {
1396         float c;
1397         c = this.clientcolors & 15;
1398         // LordHavoc: only bothering to support white, green, red, yellow, blue
1399              if (!teamplay) this.colormod = '0 0 0';
1400         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1401         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1402         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1403         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1404         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1405         else this.colormod = '1 1 1';
1406 }*/
1407
1408 void respawn(entity this)
1409 {
1410         bool damagedbycontents_prev = this.damagedbycontents;
1411         if(this.alpha >= 0)
1412         {
1413                 if(autocvar_g_respawn_ghosts)
1414                 {
1415                         this.solid = SOLID_NOT;
1416                         this.takedamage = DAMAGE_NO;
1417                         this.damagedbycontents = false;
1418                         set_movetype(this, MOVETYPE_FLY);
1419                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1420                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1421                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1422                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1423                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1424                         if(autocvar_g_respawn_ghosts_time > 0)
1425                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1426                 }
1427                 else
1428                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1429         }
1430
1431         CopyBody(this, 1);
1432         this.damagedbycontents = damagedbycontents_prev;
1433
1434         this.effects |= EF_NODRAW; // prevent another CopyBody
1435         PutClientInServer(this);
1436 }
1437
1438 void play_countdown(entity this, float finished, Sound samp)
1439 {
1440         TC(Sound, samp);
1441         if(IS_REAL_CLIENT(this))
1442                 if(floor(finished - time - frametime) != floor(finished - time))
1443                         if(finished - time < 6)
1444                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1445 }
1446
1447 void player_powerups_remove_all(entity this)
1448 {
1449         if (this.items & IT_SUPERWEAPON)
1450         {
1451                 // don't play the poweroff sound when the game restarts or the player disconnects
1452                 if (time > game_starttime + 1 && IS_CLIENT(this))
1453                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1454                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1455                 this.items -= (this.items & IT_SUPERWEAPON);
1456         }
1457 }
1458
1459 void player_powerups(entity this)
1460 {
1461         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1462                 this.modelflags |= MF_ROCKET;
1463         else
1464                 this.modelflags &= ~MF_ROCKET;
1465
1466         this.effects &= ~EF_NODEPTHTEST;
1467
1468         if (IS_DEAD(this))
1469                 player_powerups_remove_all(this);
1470
1471         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1472                 return;
1473
1474         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1475         int items_prev = this.items;
1476
1477         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1478         {
1479                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1480                 if (this.items & IT_SUPERWEAPON)
1481                 {
1482                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1483                         {
1484                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1485                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1486                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1487                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1488                         }
1489                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1490                         {
1491                                 // don't let them run out
1492                         }
1493                         else
1494                         {
1495                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1496                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1497                                 {
1498                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1499                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1500                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1501                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1502                                 }
1503                         }
1504                 }
1505                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1506                 {
1507                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1508                         {
1509                                 this.items = this.items | IT_SUPERWEAPON;
1510                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1511                                 {
1512                                         if(!g_cts)
1513                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1514                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1515                                 }
1516                         }
1517                         else
1518                         {
1519                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1520                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1521                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1522                         }
1523                 }
1524                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1525                 {
1526                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1527                 }
1528         }
1529
1530         if(autocvar_g_nodepthtestplayers)
1531                 this.effects = this.effects | EF_NODEPTHTEST;
1532
1533         if(autocvar_g_fullbrightplayers)
1534                 this.effects = this.effects | EF_FULLBRIGHT;
1535
1536         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1537 }
1538
1539 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1540 {
1541         if(current > stable)
1542                 return current;
1543         else if(current > stable - 0.25) // when close enough, "snap"
1544                 return stable;
1545         else
1546                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1547 }
1548
1549 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1550 {
1551         if(current < stable)
1552                 return current;
1553         else if(current < stable + 0.25) // when close enough, "snap"
1554                 return stable;
1555         else
1556                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1557 }
1558
1559 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1560 {
1561         float old = GetResource(this, res);
1562         float current = old;
1563         if(current > rotstable)
1564         {
1565                 if(rotframetime > 0)
1566                 {
1567                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1568                         current = max(rotstable, current - rotlinear * rotframetime);
1569                 }
1570         }
1571         else if(current < regenstable)
1572         {
1573                 if(regenframetime > 0)
1574                 {
1575                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1576                         current = min(regenstable, current + regenlinear * regenframetime);
1577                 }
1578         }
1579
1580         float limit = GetResourceLimit(this, res) * limit_mod;
1581         if(current > limit)
1582                 current = limit;
1583
1584         if (current != old)
1585                 SetResource(this, res, current);
1586 }
1587
1588 void player_regen(entity this)
1589 {
1590         float max_mod, regen_mod, rot_mod, limit_mod;
1591         max_mod = regen_mod = rot_mod = limit_mod = 1;
1592
1593         float regen_health = autocvar_g_balance_health_regen;
1594         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1595         float regen_health_rot = autocvar_g_balance_health_rot;
1596         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1597         float regen_health_stable = autocvar_g_balance_health_regenstable;
1598         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1599         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1600                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1601         max_mod = M_ARGV(1, float);
1602         regen_mod = M_ARGV(2, float);
1603         rot_mod = M_ARGV(3, float);
1604         limit_mod = M_ARGV(4, float);
1605         regen_health = M_ARGV(5, float);
1606         regen_health_linear = M_ARGV(6, float);
1607         regen_health_rot = M_ARGV(7, float);
1608         regen_health_rotlinear = M_ARGV(8, float);
1609         regen_health_stable = M_ARGV(9, float);
1610         regen_health_rotstable = M_ARGV(10, float);
1611
1612         if(!mutator_returnvalue)
1613         if(!STAT(FROZEN, this))
1614         {
1615                 float maxa = autocvar_g_balance_armor_rotstable;
1616                 float mina = autocvar_g_balance_armor_regenstable;
1617
1618                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1619                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1620                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1621
1622                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1623                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1624                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1625         }
1626
1627         // if player rotted to death...  die!
1628         // check this outside above checks, as player may still be able to rot to death
1629         if(GetResource(this, RES_HEALTH) < 1)
1630         {
1631                 if(this.vehicle)
1632                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1633                 if(this.event_damage)
1634                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1635         }
1636
1637         if (!(this.items & IT_UNLIMITED_AMMO))
1638         {
1639                 float maxf = autocvar_g_balance_fuel_rotstable;
1640                 float minf = autocvar_g_balance_fuel_regenstable;
1641
1642                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1643                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1644                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1645         }
1646 }
1647
1648 bool zoomstate_set;
1649 void SetZoomState(entity this, float newzoom)
1650 {
1651         if(newzoom != CS(this).zoomstate)
1652         {
1653                 CS(this).zoomstate = newzoom;
1654                 ClientData_Touch(this);
1655         }
1656         zoomstate_set = true;
1657 }
1658
1659 void GetPressedKeys(entity this)
1660 {
1661         MUTATOR_CALLHOOK(GetPressedKeys, this);
1662         if (game_stopped)
1663         {
1664                 CS(this).pressedkeys = 0;
1665                 STAT(PRESSED_KEYS, this) = 0;
1666                 return;
1667         }
1668
1669         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1670         int keys = STAT(PRESSED_KEYS, this);
1671         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1672         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1673         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1674         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1675
1676         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1677         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1678         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1679         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1680         CS(this).pressedkeys = keys; // store for other users
1681
1682         STAT(PRESSED_KEYS, this) = keys;
1683 }
1684
1685 /*
1686 ======================
1687 spectate mode routines
1688 ======================
1689 */
1690
1691 void SpectateCopy(entity this, entity spectatee)
1692 {
1693         TC(Client, this); TC(Client, spectatee);
1694
1695         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1696         PS(this) = PS(spectatee);
1697         this.armortype = spectatee.armortype;
1698         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1699         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1700         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1701         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1702         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1703         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1704         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1705         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1706         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1707         CS(this).impulse = 0;
1708         this.disableclientprediction = 1; // no need to run prediction on a spectator
1709         this.items = spectatee.items;
1710         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1711         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1712         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1713         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1714         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1715         this.punchangle = spectatee.punchangle;
1716         this.view_ofs = spectatee.view_ofs;
1717         this.velocity = spectatee.velocity;
1718         this.dmg_take = spectatee.dmg_take;
1719         this.dmg_save = spectatee.dmg_save;
1720         this.dmg_inflictor = spectatee.dmg_inflictor;
1721         this.v_angle = spectatee.v_angle;
1722         this.angles = spectatee.v_angle;
1723         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1724         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1725         this.viewloc = spectatee.viewloc;
1726         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1727                 this.fixangle = true;
1728         setorigin(this, spectatee.origin);
1729         setsize(this, spectatee.mins, spectatee.maxs);
1730         SetZoomState(this, CS(spectatee).zoomstate);
1731
1732     anticheat_spectatecopy(this, spectatee);
1733         STAT(HUD, this) = STAT(HUD, spectatee);
1734         if(spectatee.vehicle)
1735     {
1736         this.angles = spectatee.v_angle;
1737
1738         //this.fixangle = false;
1739         //this.velocity = spectatee.vehicle.velocity;
1740         this.vehicle_health = spectatee.vehicle_health;
1741         this.vehicle_shield = spectatee.vehicle_shield;
1742         this.vehicle_energy = spectatee.vehicle_energy;
1743         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1744         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1745         this.vehicle_reload1 = spectatee.vehicle_reload1;
1746         this.vehicle_reload2 = spectatee.vehicle_reload2;
1747
1748         //msg_entity = this;
1749
1750        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1751             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1752            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1753            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1754
1755         //WriteByte (MSG_ONE, SVC_SETVIEW);
1756         //    WriteEntity(MSG_ONE, this);
1757         //makevectors(spectatee.v_angle);
1758         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1759     }
1760 }
1761
1762 bool SpectateUpdate(entity this)
1763 {
1764         if(!this.enemy)
1765                 return false;
1766
1767         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1768         {
1769                 SetSpectatee(this, NULL);
1770                 return false;
1771         }
1772
1773         SpectateCopy(this, this.enemy);
1774
1775         return true;
1776 }
1777
1778 bool SpectateSet(entity this)
1779 {
1780         if(!IS_PLAYER(this.enemy))
1781                 return false;
1782
1783         ClientData_Touch(this.enemy);
1784
1785         msg_entity = this;
1786         WriteByte(MSG_ONE, SVC_SETVIEW);
1787         WriteEntity(MSG_ONE, this.enemy);
1788         set_movetype(this, MOVETYPE_NONE);
1789         accuracy_resend(this);
1790
1791         if(!SpectateUpdate(this))
1792                 PutObserverInServer(this);
1793
1794         return true;
1795 }
1796
1797 void SetSpectatee_status(entity this, int spectatee_num)
1798 {
1799         int oldspectatee_status = CS(this).spectatee_status;
1800         CS(this).spectatee_status = spectatee_num;
1801
1802         if (CS(this).spectatee_status != oldspectatee_status)
1803         {
1804                 if (STAT(PRESSED_KEYS, this))
1805                 {
1806                         CS(this).pressedkeys = 0;
1807                         STAT(PRESSED_KEYS, this) = 0;
1808                 }
1809                 ClientData_Touch(this);
1810                 if (g_race || g_cts) race_InitSpectator();
1811         }
1812 }
1813
1814 void SetSpectatee(entity this, entity spectatee)
1815 {
1816         if(IS_BOT_CLIENT(this))
1817                 return; // bots abuse .enemy, this code is useless to them
1818
1819         entity old_spectatee = this.enemy;
1820
1821         this.enemy = spectatee;
1822
1823         // WEAPONTODO
1824         // these are required to fix the spectator bug with arc
1825         if(old_spectatee)
1826         {
1827                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1828                 {
1829                         .entity weaponentity = weaponentities[slot];
1830                         if(old_spectatee.(weaponentity).arc_beam)
1831                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1832                 }
1833         }
1834         if(this.enemy)
1835         {
1836                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1837                 {
1838                         .entity weaponentity = weaponentities[slot];
1839                         if(this.enemy.(weaponentity).arc_beam)
1840                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1841                 }
1842         }
1843
1844         if (this.enemy)
1845                 SetSpectatee_status(this, etof(this.enemy));
1846
1847         // needed to update spectator list
1848         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1849 }
1850
1851 bool Spectate(entity this, entity pl)
1852 {
1853         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1854                 return false;
1855         pl = M_ARGV(1, entity);
1856
1857         SetSpectatee(this, pl);
1858         return SpectateSet(this);
1859 }
1860
1861 bool SpectateNext(entity this)
1862 {
1863         entity ent = find(this.enemy, classname, STR_PLAYER);
1864
1865         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1866                 ent = M_ARGV(1, entity);
1867         else if (!ent)
1868                 ent = find(ent, classname, STR_PLAYER);
1869
1870         if(ent) { SetSpectatee(this, ent); }
1871
1872         return SpectateSet(this);
1873 }
1874
1875 bool SpectatePrev(entity this)
1876 {
1877         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1878         entity ent = findchain(classname, STR_PLAYER);
1879         if (!ent) // no player
1880                 return false;
1881
1882         entity first = ent;
1883         // skip players until current spectated player
1884         if(this.enemy)
1885         while(ent && ent != this.enemy)
1886                 ent = ent.chain;
1887
1888         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1889         {
1890                 case MUT_SPECPREV_FOUND:
1891                         ent = M_ARGV(1, entity);
1892                         break;
1893                 case MUT_SPECPREV_RETURN:
1894                         return true;
1895                 case MUT_SPECPREV_CONTINUE:
1896                 default:
1897                 {
1898                         if(ent.chain)
1899                                 ent = ent.chain;
1900                         else
1901                                 ent = first;
1902                         break;
1903                 }
1904         }
1905
1906         SetSpectatee(this, ent);
1907         return SpectateSet(this);
1908 }
1909
1910 /*
1911 =============
1912 ShowRespawnCountdown()
1913
1914 Update a respawn countdown display.
1915 =============
1916 */
1917 void ShowRespawnCountdown(entity this)
1918 {
1919         float number;
1920         if(!IS_DEAD(this)) // just respawned?
1921                 return;
1922         else
1923         {
1924                 number = ceil(this.respawn_time - time);
1925                 if(number <= 0)
1926                         return;
1927                 if(number <= this.respawn_countdown)
1928                 {
1929                         this.respawn_countdown = number - 1;
1930                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1931                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1932                 }
1933         }
1934 }
1935
1936 .bool team_selected;
1937 bool ShowTeamSelection(entity this)
1938 {
1939         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1940                 return false;
1941         stuffcmd(this, "menu_showteamselect\n");
1942         return true;
1943 }
1944 void Join(entity this)
1945 {
1946         TRANSMUTE(Player, this);
1947
1948         if(!this.team_selected)
1949         if(autocvar_g_campaign || autocvar_g_balance_teams)
1950                 TeamBalance_JoinBestTeam(this);
1951
1952         if(autocvar_g_campaign)
1953                 campaign_bots_may_start = true;
1954
1955         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1956
1957         PutClientInServer(this);
1958
1959         if(IS_PLAYER(this))
1960         if(teamplay && this.team != -1)
1961         {
1962         }
1963         else
1964                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1965         this.team_selected = false;
1966 }
1967
1968 int GetPlayerLimit()
1969 {
1970         if(g_duel)
1971                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1972         int player_limit = autocvar_g_maxplayers;
1973         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1974         player_limit = M_ARGV(0, int);
1975         return player_limit;
1976 }
1977
1978 /**
1979  * Determines whether the player is allowed to join. This depends on cvar
1980  * g_maxplayers, if it isn't used this function always return true, otherwise
1981  * it checks whether the number of currently playing players exceeds g_maxplayers.
1982  * @return int number of free slots for players, 0 if none
1983  */
1984 int nJoinAllowed(entity this, entity ignore)
1985 {
1986         if(!ignore)
1987         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1988         // so report 0 free slots if restricted
1989         {
1990                 if(autocvar_g_forced_team_otherwise == "spectate")
1991                         return 0;
1992                 if(autocvar_g_forced_team_otherwise == "spectator")
1993                         return 0;
1994         }
1995
1996         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1997                 return 0; // forced spectators can never join
1998
1999         // TODO simplify this
2000         int totalClients = 0;
2001         int currentlyPlaying = 0;
2002         FOREACH_CLIENT(true, {
2003                 if(it != ignore)
2004                         ++totalClients;
2005                 if(IS_REAL_CLIENT(it))
2006                 if(IS_PLAYER(it) || it.caplayer)
2007                         ++currentlyPlaying;
2008         });
2009
2010         int player_limit = GetPlayerLimit();
2011
2012         int free_slots = 0;
2013         if (!player_limit)
2014                 free_slots = maxclients - totalClients;
2015         else if(player_limit > 0 && currentlyPlaying < player_limit)
2016                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2017
2018         static float msg_time = 0;
2019         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2020         {
2021                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2022                 msg_time = time + 0.5;
2023         }
2024
2025         return free_slots;
2026 }
2027
2028 void PrintWelcomeMessage(entity this)
2029 {
2030         if(CS(this).motd_actived_time == 0)
2031         {
2032                 if (autocvar_g_campaign) {
2033                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2034                                 CS(this).motd_actived_time = time;
2035                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2036                         }
2037                 } else {
2038                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2039                                 CS(this).motd_actived_time = time;
2040                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2041                         }
2042                 }
2043         }
2044         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2045         {
2046                 if (autocvar_g_campaign) {
2047                         if (PHYS_INPUT_BUTTON_INFO(this))
2048                                 CS(this).motd_actived_time = time;
2049                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2050                                 CS(this).motd_actived_time = 0;
2051                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2052                         }
2053                 } else {
2054                         if (PHYS_INPUT_BUTTON_INFO(this))
2055                                 CS(this).motd_actived_time = time;
2056                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2057                                 CS(this).motd_actived_time = 0;
2058                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2059                         }
2060                 }
2061         }
2062         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2063         {
2064                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2065                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2066                 else if (CS(this).motd_actived_time == -2)
2067                 {
2068                         // instantly hide MOTD
2069                         CS(this).motd_actived_time = 0;
2070                         if (autocvar_g_campaign)
2071                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2072                         else
2073                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2074                 }
2075                 else if (IS_PLAYER(this) || IS_SPEC(this))
2076                 {
2077                         // FIXME occasionally for some reason MOTD never goes away
2078                         // delay MOTD removal a little bit in the hope it fixes this bug
2079                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2080                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2081                         else //if (CS(this).motd_actived_time < -2)
2082                                 CS(this).motd_actived_time++;
2083                 }
2084         }
2085 }
2086
2087 bool joinAllowed(entity this)
2088 {
2089         if (CS(this).version_mismatch) return false;
2090         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2091         if (!nJoinAllowed(this, this)) return false;
2092         if (teamplay && lockteams) return false;
2093         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2094         if (ShowTeamSelection(this)) return false;
2095         return true;
2096 }
2097
2098 .string shootfromfixedorigin;
2099 .bool dualwielding_prev;
2100 bool PlayerThink(entity this)
2101 {
2102         if (game_stopped || intermission_running) {
2103                 this.modelflags &= ~MF_ROCKET;
2104                 if(intermission_running)
2105                         IntermissionThink(this);
2106                 return false;
2107         }
2108
2109         if (timeout_status == TIMEOUT_ACTIVE) {
2110                 // don't allow the player to turn around while game is paused
2111                 // FIXME turn this into CSQC stuff
2112                 this.v_angle = this.lastV_angle;
2113                 this.angles = this.lastV_angle;
2114                 this.fixangle = true;
2115         }
2116
2117         if (frametime) player_powerups(this);
2118
2119         if (IS_DEAD(this)) {
2120                 if (this.personal && g_race_qualifying) {
2121                         if (time > this.respawn_time) {
2122                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2123                                 respawn(this);
2124                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2125                         }
2126                 } else {
2127                         if (frametime) player_anim(this);
2128
2129                         if (this.respawn_flags & RESPAWN_DENY)
2130                         {
2131                                 STAT(RESPAWN_TIME, this) = 0;
2132                                 return false;
2133                         }
2134
2135                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2136
2137                         switch(this.deadflag)
2138                         {
2139                                 case DEAD_DYING:
2140                                 {
2141                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2142                                                 this.deadflag = DEAD_RESPAWNING;
2143                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2144                                                 this.deadflag = DEAD_DEAD;
2145                                         break;
2146                                 }
2147                                 case DEAD_DEAD:
2148                                 {
2149                                         if (button_pressed)
2150                                                 this.deadflag = DEAD_RESPAWNABLE;
2151                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2152                                                 this.deadflag = DEAD_RESPAWNING;
2153                                         break;
2154                                 }
2155                                 case DEAD_RESPAWNABLE:
2156                                 {
2157                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2158                                                 this.deadflag = DEAD_RESPAWNING;
2159                                         break;
2160                                 }
2161                                 case DEAD_RESPAWNING:
2162                                 {
2163                                         if (time > this.respawn_time)
2164                                         {
2165                                                 this.respawn_time = time + 1; // only retry once a second
2166                                                 this.respawn_time_max = this.respawn_time;
2167                                                 respawn(this);
2168                                         }
2169                                         break;
2170                                 }
2171                         }
2172
2173                         ShowRespawnCountdown(this);
2174
2175                         if (this.respawn_flags & RESPAWN_SILENT)
2176                                 STAT(RESPAWN_TIME, this) = 0;
2177                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2178                         {
2179                                 if (time < this.respawn_time)
2180                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2181                                 else if (this.deadflag != DEAD_RESPAWNING)
2182                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2183                         }
2184                         else
2185                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2186                 }
2187
2188                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2189                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2190                         STAT(RESPAWN_TIME, this) *= -1;
2191
2192                 return false;
2193         }
2194
2195         FixPlayermodel(this);
2196
2197         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2198                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2199                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2200         }
2201
2202         // reset gun alignment when dual wielding status changes
2203         // to ensure guns are always aligned right and left
2204         bool dualwielding = W_DualWielding(this);
2205         if(this.dualwielding_prev != dualwielding)
2206         {
2207                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2208                 this.dualwielding_prev = dualwielding;
2209         }
2210
2211         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2212         //if(frametime)
2213         {
2214                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2215                 {
2216                         .entity weaponentity = weaponentities[slot];
2217                         if(WEP_CVAR(vortex, charge_always))
2218                                 W_Vortex_Charge(this, weaponentity, frametime);
2219                         W_WeaponFrame(this, weaponentity);
2220                 }
2221         }
2222
2223         if (frametime)
2224         {
2225                 // WEAPONTODO: Add a weapon request for this
2226                 // rot vortex charge to the charge limit
2227                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2228                 {
2229                         .entity weaponentity = weaponentities[slot];
2230                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2231                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2232                 }
2233
2234                 player_regen(this);
2235                 player_anim(this);
2236                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2237         }
2238
2239         monsters_setstatus(this);
2240
2241         return true;
2242 }
2243
2244 .bool would_spectate;
2245 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2246 void ObserverOrSpectatorThink(entity this)
2247 {
2248         bool is_spec = IS_SPEC(this);
2249         if ( CS(this).impulse )
2250         {
2251                 int r = MinigameImpulse(this, CS(this).impulse);
2252                 if (!is_spec || r)
2253                         CS(this).impulse = 0;
2254
2255                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2256                 {
2257                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2258                         CS(this).impulse = 0;
2259                         return;
2260                 }
2261         }
2262
2263         if (this.flags & FL_JUMPRELEASED) {
2264                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2265                         this.flags &= ~FL_JUMPRELEASED;
2266                         this.flags |= FL_SPAWNING;
2267                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2268                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2269                         this.flags &= ~FL_JUMPRELEASED;
2270                         if(SpectateNext(this)) {
2271                                 TRANSMUTE(Spectator, this);
2272                         } else if (is_spec) {
2273                                 TRANSMUTE(Observer, this);
2274                                 PutClientInServer(this);
2275                         }
2276                         else
2277                                 this.would_spectate = false; // unable to spectate anyone
2278                         if (is_spec)
2279                                 CS(this).impulse = 0;
2280                 } else if (is_spec) {
2281                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2282                                 this.flags &= ~FL_JUMPRELEASED;
2283                                 if(SpectatePrev(this)) {
2284                                         TRANSMUTE(Spectator, this);
2285                                 } else {
2286                                         TRANSMUTE(Observer, this);
2287                                         PutClientInServer(this);
2288                                 }
2289                                 CS(this).impulse = 0;
2290                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2291                                 this.would_spectate = false;
2292                                 this.flags &= ~FL_JUMPRELEASED;
2293                                 TRANSMUTE(Observer, this);
2294                                 PutClientInServer(this);
2295                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2296                                 PutObserverInServer(this);
2297                                 this.would_spectate = true;
2298                         }
2299                 }
2300                 else {
2301                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2302                         if (PHYS_INPUT_BUTTON_USE(this))
2303                                 wouldclip = !wouldclip;
2304                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2305                         set_movetype(this, preferred_movetype);
2306                 }
2307         } else { // jump pressed
2308                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2309                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2310                         this.flags |= FL_JUMPRELEASED;
2311                         if(this.flags & FL_SPAWNING)
2312                         {
2313                                 this.flags &= ~FL_SPAWNING;
2314                                 if(joinAllowed(this))
2315                                         Join(this);
2316                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2317                                         CS(this).autojoin_checked = -1;
2318                                 return;
2319                         }
2320                 }
2321                 if(is_spec && !SpectateUpdate(this))
2322                         PutObserverInServer(this);
2323         }
2324         if (is_spec)
2325                 this.flags |= FL_CLIENT | FL_NOTARGET;
2326 }
2327
2328 void PlayerUseKey(entity this)
2329 {
2330         if (!IS_PLAYER(this))
2331                 return;
2332
2333         if(this.vehicle)
2334         {
2335                 if(!game_stopped)
2336                 {
2337                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2338                         return;
2339                 }
2340         }
2341         else if(autocvar_g_vehicles_enter)
2342         {
2343                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2344                 {
2345                         entity head, closest_target = NULL;
2346                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2347
2348                         while(head) // find the closest acceptable target to enter
2349                         {
2350                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2351                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2352                                 {
2353                                         if(closest_target)
2354                                         {
2355                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2356                                                 { closest_target = head; }
2357                                         }
2358                                         else { closest_target = head; }
2359                                 }
2360
2361                                 head = head.chain;
2362                         }
2363
2364                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2365                 }
2366         }
2367
2368         // a use key was pressed; call handlers
2369         MUTATOR_CALLHOOK(PlayerUseKey, this);
2370 }
2371
2372
2373 /*
2374 =============
2375 PlayerPreThink
2376
2377 Called every frame for each client before the physics are run
2378 =============
2379 */
2380 .float last_vehiclecheck;
2381 void PlayerPreThink (entity this)
2382 {
2383         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2384         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2385
2386         WarpZone_PlayerPhysics_FixVAngle(this);
2387
2388         if (frametime) {
2389                 // physics frames: update anticheat stuff
2390                 anticheat_prethink(this);
2391
2392                 // WORKAROUND: only use dropclient in server frames (frametime set).
2393                 // Never use it in cl_movement frames (frametime zero).
2394                 if (blockSpectators && IS_REAL_CLIENT(this)
2395                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2396                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2397                 {
2398                         if (dropclient_schedule(this))
2399                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2400                 }
2401         }
2402
2403         zoomstate_set = false;
2404
2405         // Check for nameless players
2406         if (this.netname == "" || this.netname != CS(this).netname_previous)
2407         {
2408                 bool assume_unchanged = (CS(this).netname_previous == "");
2409                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2410                 {
2411                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2412                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2413                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2414                         assume_unchanged = false;
2415                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2416                 }
2417                 if (isInvisibleString(this.netname))
2418                 {
2419                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2420                         sprint(this, "Warning: invisible names are not allowed.\n");
2421                         assume_unchanged = false;
2422                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2423                 }
2424                 if (!assume_unchanged && autocvar_sv_eventlog)
2425                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2426                 strcpy(CS(this).netname_previous, this.netname);
2427         }
2428
2429         // version nagging
2430         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2431         CS(this).version_nagtime = 0;
2432         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2433             // git client
2434         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2435             // git server
2436             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2437         } else {
2438             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2439             if (r < 0) { // old client
2440                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2441             } else if (r > 0) { // old server
2442                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2443             }
2444         }
2445     }
2446
2447         // GOD MODE info
2448         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2449         {
2450                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2451                 this.max_armorvalue = 0;
2452         }
2453
2454         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2455         {
2456                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2457                 {
2458                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2459                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2460                         if (this.iceblock)
2461                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2462
2463                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2464                                 Unfreeze(this, false);
2465                 }
2466                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2467                 {
2468                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2469                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2470
2471                         if (GetResource(this, RES_HEALTH) < 1)
2472                         {
2473                                 if (this.vehicle)
2474                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2475                                 if(this.event_damage)
2476                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2477                         }
2478                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2479                                 Unfreeze(this, false);
2480                 }
2481         }
2482
2483         MUTATOR_CALLHOOK(PlayerPreThink, this);
2484
2485         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2486         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2487         {
2488                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2489                 {
2490                         if(!it.owner)
2491                         {
2492                                 if(!it.team || SAME_TEAM(this, it))
2493                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2494                                 else if(autocvar_g_vehicles_steal)
2495                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2496                         }
2497                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2498                         {
2499                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2500                         }
2501                 });
2502
2503                 this.last_vehiclecheck = time + 1;
2504         }
2505
2506         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2507         {
2508                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2509                         PlayerUseKey(this);
2510                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2511         }
2512
2513         if (IS_REAL_CLIENT(this))
2514                 PrintWelcomeMessage(this);
2515
2516         if (IS_PLAYER(this)) {
2517                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2518                         error("Client can't be spawned as player on connection!");
2519                 if(!PlayerThink(this))
2520                         return;
2521         }
2522         else if (game_stopped || intermission_running) {
2523                 if(intermission_running)
2524                         IntermissionThink(this);
2525                 return;
2526         }
2527         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2528         {
2529                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2530                 CS(this).autojoin_checked = 1;
2531                 // don't do this in ClientConnect
2532                 // many things can go wrong if a client is spawned as player on connection
2533                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2534                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2535                                 && (!teamplay || autocvar_g_balance_teams)))
2536                 {
2537                         campaign_bots_may_start = true;
2538                         if(joinAllowed(this))
2539                                 Join(this);
2540                         return;
2541                 }
2542         }
2543         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2544                 ObserverOrSpectatorThink(this);
2545         }
2546
2547         // WEAPONTODO: Add weapon request for this
2548         if (!zoomstate_set) {
2549                 bool wep_zoomed = false;
2550                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2551                 {
2552                         .entity weaponentity = weaponentities[slot];
2553                         Weapon thiswep = this.(weaponentity).m_weapon;
2554                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2555                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2556                 }
2557                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2558         }
2559
2560         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2561         {
2562                 CS(this).teamkill_soundtime = 0;
2563
2564                 entity e = CS(this).teamkill_soundsource;
2565                 entity oldpusher = e.pusher;
2566                 e.pusher = this;
2567                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2568                 e.pusher = oldpusher;
2569         }
2570
2571         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2572                 CS(this).taunt_soundtime = 0;
2573                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2574         }
2575
2576         target_voicescript_next(this);
2577 }
2578
2579 void DrownPlayer(entity this)
2580 {
2581         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2582                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2583         {
2584                 STAT(AIR_FINISHED, this) = 0;
2585                 return;
2586         }
2587
2588         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2589         {
2590                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2591                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2592                 STAT(AIR_FINISHED, this) = 0;
2593         }
2594         else
2595         {
2596                 if (!STAT(AIR_FINISHED, this))
2597                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2598                 if (STAT(AIR_FINISHED, this) < time)
2599                 {       // drown!
2600                         if (this.pain_finished < time)
2601                         {
2602                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2603                                 this.pain_finished = time + 0.5;
2604                         }
2605                 }
2606         }
2607 }
2608
2609 .bool move_qcphysics;
2610
2611 void Player_Physics(entity this)
2612 {
2613         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2614
2615         if(!this.move_qcphysics)
2616                 return;
2617
2618         if(!frametime && !CS(this).pm_frametime)
2619                 return;
2620
2621         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2622
2623         CS(this).pm_frametime = 0;
2624 }
2625
2626 /*
2627 =============
2628 PlayerPostThink
2629
2630 Called every frame for each client after the physics are run
2631 =============
2632 */
2633 void PlayerPostThink (entity this)
2634 {
2635         Player_Physics(this);
2636
2637         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2638         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2639         if (IS_REAL_CLIENT(this))
2640         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2641         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2642         {
2643                 int totalClients = 0;
2644                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2645                 {
2646                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2647                         if (server_is_dedicated)
2648                         {
2649                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2650                                 {
2651                                         ++totalClients;
2652                                 });
2653                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2654                                         totalClients = 0;
2655                         }
2656                 }
2657                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2658                 {
2659                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2660                         {
2661                                 ++totalClients;
2662                         });
2663                 }
2664
2665                 if (totalClients < autocvar_sv_maxidle_minplayers)
2666                 {
2667                         // idle kick disabled
2668                         CS(this).parm_idlesince = time;
2669                 }
2670                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2671                 {
2672                         if (CS(this).idlekick_lasttimeleft)
2673                         {
2674                                 CS(this).idlekick_lasttimeleft = 0;
2675                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2676                         }
2677                 }
2678                 else
2679                 {
2680                         float maxidle_time = autocvar_sv_maxidle;
2681                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2682                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2683                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2684                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2685                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2686                         {
2687                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2688                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2689                                 else
2690                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2691                         }
2692                         if (timeleft <= 0) {
2693                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2694                                 {
2695                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2696                                         if (this.caplayer)
2697                                                 this.caplayer = 0;
2698                                         this.lms_spectate_warning = 2; // TODO: mutator hook for players forcibly moved to spectator?
2699                                         PutObserverInServer(this);
2700                                 }
2701                                 else
2702                                 {
2703                                         if (dropclient_schedule(this))
2704                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2705                                 }
2706                                 return;
2707                         }
2708                         else if (timeleft <= countdown_time) {
2709                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2710                                         play2(this, SND(TALK2));
2711                                 CS(this).idlekick_lasttimeleft = timeleft;
2712                         }
2713                 }
2714         }
2715
2716         CheatFrame(this);
2717
2718         if (game_stopped)
2719         {
2720                 this.solid = SOLID_NOT;
2721                 this.takedamage = DAMAGE_NO;
2722                 set_movetype(this, MOVETYPE_NONE);
2723                 CS(this).teamkill_complain = 0;
2724                 CS(this).teamkill_soundtime = 0;
2725                 CS(this).teamkill_soundsource = NULL;
2726         }
2727
2728         if (IS_PLAYER(this)) {
2729                 if(this.death_time == time && IS_DEAD(this))
2730                 {
2731                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2732                         // once all the damage events of this frame have been processed with normal size
2733                         this.maxs.z = 5;
2734                         setsize(this, this.mins, this.maxs);
2735                 }
2736                 DrownPlayer(this);
2737                 UpdateChatBubble(this);
2738                 if (CS(this).impulse) ImpulseCommands(this);
2739                 GetPressedKeys(this);
2740                 if (game_stopped)
2741                 {
2742                         CSQCMODEL_AUTOUPDATE(this);
2743                         return;
2744                 }
2745         }
2746         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2747         {
2748                 CS(this).pressedkeys = 0;
2749                 STAT(PRESSED_KEYS, this) = 0;
2750         }
2751
2752         if (this.waypointsprite_attachedforcarrier) {
2753                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2754                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2755         }
2756
2757         CSQCMODEL_AUTOUPDATE(this);
2758 }
2759
2760 // hack to copy the button fields from the client entity to the Client State
2761 void PM_UpdateButtons(entity this, entity store)
2762 {
2763         if(this.impulse)
2764                 store.impulse = this.impulse;
2765         this.impulse = 0;
2766
2767         bool typing = this.buttonchat || this.button12;
2768
2769         store.button0 = (typing) ? 0 : this.button0;
2770         //button1?!
2771         store.button2 = (typing) ? 0 : this.button2;
2772         store.button3 = (typing) ? 0 : this.button3;
2773         store.button4 = this.button4;
2774         store.button5 = (typing) ? 0 : this.button5;
2775         store.button6 = this.button6;
2776         store.button7 = this.button7;
2777         store.button8 = this.button8;
2778         store.button9 = this.button9;
2779         store.button10 = this.button10;
2780         store.button11 = this.button11;
2781         store.button12 = this.button12;
2782         store.button13 = this.button13;
2783         store.button14 = this.button14;
2784         store.button15 = this.button15;
2785         store.button16 = this.button16;
2786         store.buttonuse = this.buttonuse;
2787         store.buttonchat = this.buttonchat;
2788
2789         store.cursor_active = this.cursor_active;
2790         store.cursor_screen = this.cursor_screen;
2791         store.cursor_trace_start = this.cursor_trace_start;
2792         store.cursor_trace_endpos = this.cursor_trace_endpos;
2793         store.cursor_trace_ent = this.cursor_trace_ent;
2794
2795         store.ping = this.ping;
2796         store.ping_packetloss = this.ping_packetloss;
2797         store.ping_movementloss = this.ping_movementloss;
2798
2799         store.v_angle = this.v_angle;
2800         store.movement = this.movement;
2801 }
2802
2803 NET_HANDLE(fpsreport, bool)
2804 {
2805         int fps = ReadShort();
2806         PlayerScore_Set(sender, SP_FPS, fps);
2807         return true;
2808 }