qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include "compat/quake3.qh"
  36
  37 #include <common/effects/qc/globalsound.qh>
  38
  39 #include "../common/mapobjects/func/conveyor.qh"
  40 #include "../common/mapobjects/teleporters.qh"
  41 #include "../common/mapobjects/target/spawnpoint.qh"
  42 #include <common/mapobjects/trigger/counter.qh>
  43
  44 #include "../common/vehicles/all.qh"
  45
  46 #include "weapons/hitplot.qh"
  47 #include "weapons/weaponsystem.qh"
  48
  49 #include "../common/net_notice.qh"
  50 #include "../common/net_linked.qh"
  51 #include "../common/physics/player.qh"
  52
  53 #include <common/vehicles/sv_vehicles.qh>
  54
  55 #include "../common/items/_mod.qh"
  56
  57 #include "../common/mutators/mutator/waypoints/all.qh"
  58 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  59 #include <common/gamemodes/_mod.qh>
  60
  61 #include "../common/mapobjects/subs.qh"
  62 #include "../common/mapobjects/triggers.qh"
  63 #include "../common/mapobjects/trigger/secret.qh"
  64
  65 #include "../common/minigames/sv_minigames.qh"
  66
  67 #include "../common/items/inventory.qh"
  68
  69 #include "../common/monsters/sv_monsters.qh"
  70
  71 #include "../lib/warpzone/server.qh"
  72
  73 #include <common/mutators/mutator/overkill/oknex.qh>
  74
  75 STATIC_METHOD(Client, Add, void(Client this, int _team))
  76 {
  77     ClientConnect(this);
  78     TRANSMUTE(Player, this);
  79     this.frame = 12; // 7
  80     this.team = _team;
  81     PutClientInServer(this);
  82 }
  83
  84 STATIC_METHOD(Client, Remove, void(Client this))
  85 {
  86     TRANSMUTE(Observer, this);
  87     PutClientInServer(this);
  88     ClientDisconnect(this);
  89 }
  90
  91 void send_CSQC_teamnagger() {
  92         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  93 }
  94
  95 int CountSpectators(entity player, entity to)
  96 {
  97         if(!player) { return 0; } // not sure how, but best to be safe
  98
  99         int spec_count = 0;
 100
 101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 102         {
 103                 spec_count++;
 104         });
 105
 106         return spec_count;
 107 }
 108
 109 void WriteSpectators(entity player, entity to)
 110 {
 111         if(!player) { return; } // not sure how, but best to be safe
 112
 113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 114         {
 115                 WriteByte(MSG_ENTITY, num_for_edict(it));
 116         });
 117 }
 118
 119 bool ClientData_Send(entity this, entity to, int sf)
 120 {
 121         assert(to == this.owner, return false);
 122
 123         entity e = to;
 124         if (IS_SPEC(e)) e = e.enemy;
 125
 126         sf = 0;
 127         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 128         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 129         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 130         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 131
 132         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 133         WriteByte(MSG_ENTITY, sf);
 134
 135         if (sf & BIT(1))
 136                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 137
 138         if(sf & BIT(4))
 139         {
 140                 float specs = CountSpectators(e, to);
 141                 WriteByte(MSG_ENTITY, specs);
 142                 WriteSpectators(e, to);
 143         }
 144
 145         return true;
 146 }
 147
 148 void ClientData_Attach(entity this)
 149 {
 150         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 151         CS(this).clientdata.drawonlytoclient = this;
 152         CS(this).clientdata.owner = this;
 153 }
 154
 155 void ClientData_Detach(entity this)
 156 {
 157         delete(CS(this).clientdata);
 158         CS(this).clientdata = NULL;
 159 }
 160
 161 void ClientData_Touch(entity e)
 162 {
 163         entity cd = CS(e).clientdata;
 164         if (cd) { cd.SendFlags = 1; }
 165
 166         // make it spectatable
 167         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 168         {
 169                 entity cd = CS(it).clientdata;
 170                 if (cd) { cd.SendFlags = 1; }
 171         });
 172 }
 173
 174
 175 /*
 176 =============
 177 CheckPlayerModel
 178
 179 Checks if the argument string can be a valid playermodel.
 180 Returns a valid one in doubt.
 181 =============
 182 */
 183 string FallbackPlayerModel;
 184 string CheckPlayerModel(string plyermodel) {
 185         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 186         {
 187                 // note: we cannot summon Don Strunzone here, some player may
 188                 // still have the model string set. In case anyone manages how
 189                 // to change a cvar default, we'll have a small leak here.
 190                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 191         }
 192         // only in right path
 193         if( substring(plyermodel,0,14) != "models/player/")
 194                 return FallbackPlayerModel;
 195         // only good file extensions
 196         if(substring(plyermodel,-4,4) != ".zym")
 197         if(substring(plyermodel,-4,4) != ".dpm")
 198         if(substring(plyermodel,-4,4) != ".iqm")
 199         if(substring(plyermodel,-4,4) != ".md3")
 200         if(substring(plyermodel,-4,4) != ".psk")
 201                 return FallbackPlayerModel;
 202         // forbid the LOD models
 203         if(substring(plyermodel, -9,5) == "_lod1")
 204                 return FallbackPlayerModel;
 205         if(substring(plyermodel, -9,5) == "_lod2")
 206                 return FallbackPlayerModel;
 207         if(plyermodel != strtolower(plyermodel))
 208                 return FallbackPlayerModel;
 209         // also, restrict to server models
 210         if(autocvar_sv_servermodelsonly)
 211         {
 212                 if(!fexists(plyermodel))
 213                         return FallbackPlayerModel;
 214         }
 215         return plyermodel;
 216 }
 217
 218 void setplayermodel(entity e, string modelname)
 219 {
 220         precache_model(modelname);
 221         _setmodel(e, modelname);
 222         player_setupanimsformodel(e);
 223         if(!autocvar_g_debug_globalsounds)
 224                 UpdatePlayerSounds(e);
 225 }
 226
 227 /** putting a client as observer in the server */
 228 void PutObserverInServer(entity this)
 229 {
 230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 231         PlayerState_detach(this);
 232
 233         if (IS_PLAYER(this))
 234         {
 235                 if(GetResource(this, RES_HEALTH) >= 1)
 236                 {
 237                         // despawn effect
 238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 239                 }
 240
 241                 // was a player, recount votes and ready status
 242                 if(IS_REAL_CLIENT(this))
 243                 {
 244                         if (vote_called) { VoteCount(false); }
 245                         ReadyCount();
 246                 }
 247     }
 248
 249     {
 250         entity spot = SelectSpawnPoint(this, true);
 251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 252         this.angles = vec2(spot.angles);
 253         this.fixangle = true;
 254         // offset it so that the spectator spawns higher off the ground, looks better this way
 255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 256         if (IS_REAL_CLIENT(this))
 257         {
 258             msg_entity = this;
 259             WriteByte(MSG_ONE, SVC_SETVIEW);
 260             WriteEntity(MSG_ONE, this);
 261         }
 262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 264         if(!autocvar_g_debug_globalsounds)
 265         {
 266                 // needed for player sounds
 267                 this.model = "";
 268                 FixPlayermodel(this);
 269         }
 270         setmodel(this, MDL_Null);
 271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 272         this.view_ofs = '0 0 0';
 273     }
 274
 275     RemoveGrapplingHooks(this);
 276         Portal_ClearAll(this);
 277         Unfreeze(this, false);
 278         SetSpectatee(this, NULL);
 279
 280         if (this.alivetime)
 281         {
 282                 if (!warmup_stage)
 283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 284                 this.alivetime = 0;
 285         }
 286
 287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 288
 289         WaypointSprite_PlayerDead(this);
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 if(!game_stopped)
 294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 296         }
 297
 298         accuracy_resend(this);
 299
 300         CS(this).spectatortime = time;
 301         if(this.bot_attack)
 302                 IL_REMOVE(g_bot_targets, this);
 303         this.bot_attack = false;
 304         if(this.monster_attack)
 305                 IL_REMOVE(g_monster_targets, this);
 306         this.monster_attack = false;
 307     STAT(HUD, this) = HUD_NORMAL;
 308         TRANSMUTE(Observer, this);
 309         this.iscreature = false;
 310         this.teleportable = TELEPORT_SIMPLE;
 311         if(this.damagedbycontents)
 312                 IL_REMOVE(g_damagedbycontents, this);
 313         this.damagedbycontents = false;
 314         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 315         SetSpectatee_status(this, etof(this));
 316         this.takedamage = DAMAGE_NO;
 317         this.solid = SOLID_NOT;
 318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 319         this.flags = FL_CLIENT | FL_NOTARGET;
 320         this.effects = 0;
 321         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 322         this.pauserotarmor_finished = 0;
 323         this.pauserothealth_finished = 0;
 324         this.pauseregen_finished = 0;
 325         this.damageforcescale = 0;
 326         this.death_time = 0;
 327         this.respawn_flags = 0;
 328         this.respawn_time = 0;
 329         STAT(RESPAWN_TIME, this) = 0;
 330         this.alpha = 0;
 331         this.scale = 0;
 332         this.fade_time = 0;
 333         this.pain_frame = 0;
 334         this.pain_finished = 0;
 335         this.strength_finished = 0;
 336         this.invincible_finished = 0;
 337         this.superweapons_finished = 0;
 338         //this.dphitcontentsmask = 0;
 339         this.dphitcontentsmask = DPCONTENTS_SOLID;
 340         if (autocvar_g_playerclip_collisions)
 341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         STAT(REVIVE_PROGRESS, this) = 0;
 349         this.revival_time = 0;
 350         this.draggable = drag_undraggable;
 351
 352         this.items = 0;
 353         STAT(WEAPONS, this) = '0 0 0';
 354         this.drawonlytoclient = this;
 355
 356         this.viewloc = NULL;
 357
 358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 359
 360         this.weaponmodel = "";
 361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 362         {
 363                 this.weaponentities[slot] = NULL;
 364         }
 365         this.exteriorweaponentity = NULL;
 366         CS(this).killcount = FRAGS_SPECTATOR;
 367         this.velocity = '0 0 0';
 368         this.avelocity = '0 0 0';
 369         this.punchangle = '0 0 0';
 370         this.punchvector = '0 0 0';
 371         this.oldvelocity = this.velocity;
 372         this.fire_endtime = -1;
 373         this.event_damage = func_null;
 374         this.event_heal = func_null;
 375
 376         for(int slot = 0; slot < MAX_AXH; ++slot)
 377         {
 378                 entity axh = this.(AuxiliaryXhair[slot]);
 379                 this.(AuxiliaryXhair[slot]) = NULL;
 380
 381                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 382                         delete(axh);
 383         }
 384
 385         if (mutator_returnvalue)
 386         {
 387                 // mutator prevents resetting teams+score
 388         }
 389         else
 390         {
 391                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 392                 this.frags = FRAGS_SPECTATOR;
 393         }
 394         if (CS(this).just_joined)
 395                 CS(this).just_joined = false;
 396 }
 397
 398 int player_getspecies(entity this)
 399 {
 400         get_model_parameters(this.model, this.skin);
 401         int s = get_model_parameters_species;
 402         get_model_parameters(string_null, 0);
 403         if (s < 0) return SPECIES_HUMAN;
 404         return s;
 405 }
 406
 407 .float model_randomizer;
 408 void FixPlayermodel(entity player)
 409 {
 410         string defaultmodel = "";
 411         int defaultskin = 0;
 412         if(autocvar_sv_defaultcharacter)
 413         {
 414                 if(teamplay)
 415                 {
 416                         switch(player.team)
 417                         {
 418                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 419                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 420                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 421                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 422                         }
 423                 }
 424
 425                 if(defaultmodel == "")
 426                 {
 427                         defaultmodel = autocvar_sv_defaultplayermodel;
 428                         defaultskin = autocvar_sv_defaultplayerskin;
 429                 }
 430
 431                 int n = tokenize_console(defaultmodel);
 432                 if(n > 0)
 433                 {
 434                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 435                         // However, do NOT randomize if the player-selected model is in the list.
 436                         for (int i = 0; i < n; ++i)
 437                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 438                                         defaultmodel = argv(i);
 439                 }
 440
 441                 int i = strstrofs(defaultmodel, ":", 0);
 442                 if(i >= 0)
 443                 {
 444                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 445                         defaultmodel = substring(defaultmodel, 0, i);
 446                 }
 447         }
 448         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 449         {
 450                 if(teamplay)
 451                 {
 452                         switch(player.team)
 453                         {
 454                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 455                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 456                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 457                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 458                         }
 459                 }
 460
 461                 if(!defaultskin)
 462                         defaultskin = autocvar_sv_defaultplayerskin;
 463         }
 464
 465         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 466         defaultmodel = M_ARGV(0, string);
 467         defaultskin = M_ARGV(1, int);
 468
 469         bool chmdl = false;
 470         int oldskin;
 471         if(defaultmodel != "")
 472         {
 473                 if (defaultmodel != player.model)
 474                 {
 475                         vector m1 = player.mins;
 476                         vector m2 = player.maxs;
 477                         setplayermodel (player, defaultmodel);
 478                         setsize (player, m1, m2);
 479                         chmdl = true;
 480                 }
 481
 482                 oldskin = player.skin;
 483                 player.skin = defaultskin;
 484         } else {
 485                 if (player.playermodel != player.model || player.playermodel == "")
 486                 {
 487                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 488                         vector m1 = player.mins;
 489                         vector m2 = player.maxs;
 490                         setplayermodel (player, player.playermodel);
 491                         setsize (player, m1, m2);
 492                         chmdl = true;
 493                 }
 494
 495                 if(!autocvar_sv_defaultcharacterskin)
 496                 {
 497                         oldskin = player.skin;
 498                         player.skin = stof(player.playerskin);
 499                 }
 500                 else
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = defaultskin;
 504                 }
 505         }
 506
 507         if(chmdl || oldskin != player.skin) // model or skin has changed
 508         {
 509                 player.species = player_getspecies(player); // update species
 510                 if(!autocvar_g_debug_globalsounds)
 511                         UpdatePlayerSounds(player); // update skin sounds
 512         }
 513
 514         if(!teamplay)
 515                 if(strlen(autocvar_sv_defaultplayercolors))
 516                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 517                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 518 }
 519
 520 void PutPlayerInServer(entity this)
 521 {
 522         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 523
 524         PlayerState_attach(this);
 525         accuracy_resend(this);
 526
 527         if (this.team < 0)
 528                 TeamBalance_JoinBestTeam(this);
 529
 530         entity spot = SelectSpawnPoint(this, false);
 531         if (!spot) {
 532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 533                 return; // spawn failed
 534         }
 535
 536         TRANSMUTE(Player, this);
 537
 538         CS(this).wasplayer = true;
 539         this.iscreature = true;
 540         this.teleportable = TELEPORT_NORMAL;
 541         if(!this.damagedbycontents)
 542                 IL_PUSH(g_damagedbycontents, this);
 543         this.damagedbycontents = true;
 544         set_movetype(this, MOVETYPE_WALK);
 545         this.solid = SOLID_SLIDEBOX;
 546         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 547         if (autocvar_g_playerclip_collisions)
 548                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 549         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 550                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 551         this.frags = FRAGS_PLAYER;
 552         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 553         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 554         if (autocvar__notarget)
 555                 this.flags |= FL_NOTARGET;
 556         this.takedamage = DAMAGE_AIM;
 557         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 558
 559         if (warmup_stage) {
 560                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 561                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 562                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 563                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 564                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 565                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 566                 SetResource(this, RES_HEALTH, warmup_start_health);
 567                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 568                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 569         } else {
 570                 SetResource(this, RES_SHELLS, start_ammo_shells);
 571                 SetResource(this, RES_BULLETS, start_ammo_nails);
 572                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 573                 SetResource(this, RES_CELLS, start_ammo_cells);
 574                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 575                 SetResource(this, RES_FUEL, start_ammo_fuel);
 576                 SetResource(this, RES_HEALTH, start_health);
 577                 SetResource(this, RES_ARMOR, start_armorvalue);
 578                 STAT(WEAPONS, this) = start_weapons;
 579                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 580                 {
 581                         GiveRandomWeapons(this, random_start_weapons_count,
 582                                 autocvar_g_random_start_weapons, random_start_ammo);
 583                 }
 584         }
 585         SetSpectatee_status(this, 0);
 586
 587         PS(this).dual_weapons = '0 0 0';
 588
 589         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 590
 591         this.items = start_items;
 592
 593         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 594         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 595         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 596         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 597         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 598         if (!sv_ready_restart_after_countdown && time < game_starttime)
 599         {
 600                 float f = game_starttime - time;
 601                 this.spawnshieldtime += f;
 602                 this.pauserotarmor_finished += f;
 603                 this.pauserothealth_finished += f;
 604                 this.pauseregen_finished += f;
 605         }
 606
 607         this.damageforcescale = 2;
 608         this.death_time = 0;
 609         this.respawn_flags = 0;
 610         this.respawn_time = 0;
 611         STAT(RESPAWN_TIME, this) = 0;
 612         this.scale = autocvar_sv_player_scale;
 613         this.fade_time = 0;
 614         this.pain_frame = 0;
 615         this.pain_finished = 0;
 616         this.pushltime = 0;
 617         setthink(this, func_null); // players have no think function
 618         this.nextthink = 0;
 619         this.dmg_team = 0;
 620         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 621
 622         this.deadflag = DEAD_NO;
 623
 624         this.angles = spot.angles;
 625         this.angles_z = 0; // never spawn tilted even if the spot says to
 626         if (IS_BOT_CLIENT(this))
 627         {
 628                 this.v_angle = this.angles;
 629                 bot_aim_reset(this);
 630         }
 631         this.fixangle = true; // turn this way immediately
 632         this.oldvelocity = this.velocity = '0 0 0';
 633         this.avelocity = '0 0 0';
 634         this.punchangle = '0 0 0';
 635         this.punchvector = '0 0 0';
 636
 637         this.strength_finished = 0;
 638         this.invincible_finished = 0;
 639         this.fire_endtime = -1;
 640         STAT(REVIVE_PROGRESS, this) = 0;
 641         this.revival_time = 0;
 642
 643         this.air_finished = time + 12;
 644         this.waterlevel = WATERLEVEL_NONE;
 645         this.watertype = CONTENT_EMPTY;
 646
 647         entity spawnevent = new_pure(spawnevent);
 648         spawnevent.owner = this;
 649         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 650
 651         // Cut off any still running player sounds.
 652         stopsound(this, CH_PLAYER_SINGLE);
 653
 654         this.model = "";
 655         FixPlayermodel(this);
 656         this.drawonlytoclient = NULL;
 657
 658         this.viewloc = NULL;
 659
 660         for(int slot = 0; slot < MAX_AXH; ++slot)
 661         {
 662                 entity axh = this.(AuxiliaryXhair[slot]);
 663                 this.(AuxiliaryXhair[slot]) = NULL;
 664
 665                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 666                         delete(axh);
 667         }
 668
 669         this.spawnpoint_targ = NULL;
 670
 671         this.crouch = false;
 672         this.view_ofs = STAT(PL_VIEW_OFS, this);
 673         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 674         this.spawnorigin = spot.origin;
 675         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 676         // don't reset back to last position, even if new position is stuck in solid
 677         this.oldorigin = this.origin;
 678         if(this.conveyor)
 679                 IL_REMOVE(g_conveyed, this);
 680         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 681         STAT(HUD, this) = HUD_NORMAL;
 682
 683         this.event_damage = PlayerDamage;
 684         this.event_heal = PlayerHeal;
 685
 686         this.draggable = func_null;
 687
 688         if(!this.bot_attack)
 689                 IL_PUSH(g_bot_targets, this);
 690         this.bot_attack = true;
 691         if(!this.monster_attack)
 692                 IL_PUSH(g_monster_targets, this);
 693         this.monster_attack = true;
 694         navigation_dynamicgoal_init(this, false);
 695
 696         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 697
 698         // player was spectator
 699         if (CS(this).killcount == FRAGS_SPECTATOR) {
 700                 PlayerScore_Clear(this);
 701                 CS(this).killcount = 0;
 702                 CS(this).startplaytime = time;
 703         }
 704
 705         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 706         {
 707                 .entity weaponentity = weaponentities[slot];
 708                 entity oldwep = this.(weaponentity);
 709                 CL_SpawnWeaponentity(this, weaponentity);
 710                 if(oldwep && oldwep.owner == this)
 711                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 712         }
 713         this.alpha = default_player_alpha;
 714         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 715         this.exteriorweaponentity.alpha = default_weapon_alpha;
 716
 717         this.speedrunning = false;
 718
 719         this.counter_cnt = 0;
 720         this.fragsfilter_cnt = 0;
 721
 722         target_voicescript_clear(this);
 723
 724         // reset fields the weapons may use
 725         FOREACH(Weapons, true, {
 726                 it.wr_resetplayer(it, this);
 727                         // reload all reloadable weapons
 728                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 729                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 730                         {
 731                                 .entity weaponentity = weaponentities[slot];
 732                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 733                         }
 734                 }
 735         });
 736
 737         {
 738                 //string s = spot.target;
 739                 //spot.target = string_null;
 740                 SUB_UseTargets(spot, this, NULL);
 741                 //spot.target = s;
 742         }
 743
 744         Unfreeze(this, false);
 745
 746         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 747
 748         if (autocvar_spawn_debug)
 749         {
 750                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 751                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 752         }
 753
 754         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 755         {
 756                 .entity weaponentity = weaponentities[slot];
 757                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 758                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 759                 else
 760                         this.(weaponentity).m_switchweapon = WEP_Null;
 761                 this.(weaponentity).m_weapon = WEP_Null;
 762                 this.(weaponentity).weaponname = "";
 763                 this.(weaponentity).m_switchingweapon = WEP_Null;
 764                 this.(weaponentity).cnt = -1;
 765         }
 766
 767         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 768
 769         if (CS(this).impulse) ImpulseCommands(this);
 770
 771         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 772         {
 773                 .entity weaponentity = weaponentities[slot];
 774                 W_WeaponFrame(this, weaponentity);
 775         }
 776
 777         if (!warmup_stage && !this.alivetime)
 778                 this.alivetime = time;
 779
 780         antilag_clear(this, CS(this));
 781 }
 782
 783 /** Called when a client spawns in the server */
 784 void PutClientInServer(entity this)
 785 {
 786         if (IS_BOT_CLIENT(this)) {
 787                 TRANSMUTE(Player, this);
 788         } else if (IS_REAL_CLIENT(this)) {
 789                 msg_entity = this;
 790                 WriteByte(MSG_ONE, SVC_SETVIEW);
 791                 WriteEntity(MSG_ONE, this);
 792         }
 793         if (game_stopped)
 794                 TRANSMUTE(Observer, this);
 795
 796         SetSpectatee(this, NULL);
 797
 798         // reset player keys
 799         if(PS(this))
 800                 PS(this).itemkeys = 0;
 801
 802         MUTATOR_CALLHOOK(PutClientInServer, this);
 803
 804         if (IS_OBSERVER(this)) {
 805                 PutObserverInServer(this);
 806         } else if (IS_PLAYER(this)) {
 807                 PutPlayerInServer(this);
 808         }
 809 }
 810
 811 // TODO do we need all these fields, or should we stop autodetecting runtime
 812 // changes and just have a console command to update this?
 813 bool ClientInit_SendEntity(entity this, entity to, int sf)
 814 {
 815         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 816         return = true;
 817         msg_entity = to;
 818         // MSG_INIT replacement
 819         // TODO: make easier to use
 820         Registry_send_all();
 821         W_PROP_reload(MSG_ONE, to);
 822         ClientInit_misc(this);
 823         MUTATOR_CALLHOOK(Ent_Init);
 824 }
 825 void ClientInit_misc(entity this)
 826 {
 827         int channel = MSG_ONE;
 828         WriteHeader(channel, ENT_CLIENT_INIT);
 829         WriteByte(channel, g_nexball_meter_period * 32);
 830         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 831         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 832         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 833         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 834         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 835         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 836         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 837         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 838
 839         if(sv_foginterval && world.fog != "")
 840                 WriteString(channel, world.fog);
 841         else
 842                 WriteString(channel, "");
 843         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 844         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 845         WriteByte(channel, serverflags);
 846         WriteCoord(channel, autocvar_g_trueaim_minrange);
 847 }
 848
 849 void ClientInit_CheckUpdate(entity this)
 850 {
 851         this.nextthink = time;
 852         if(this.count != autocvar_g_balance_armor_blockpercent)
 853         {
 854                 this.count = autocvar_g_balance_armor_blockpercent;
 855                 this.SendFlags |= 1;
 856         }
 857         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 858         {
 859                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 860                 this.SendFlags |= 1;
 861         }
 862 }
 863
 864 void ClientInit_Spawn()
 865 {
 866         entity e = new_pure(clientinit);
 867         setthink(e, ClientInit_CheckUpdate);
 868         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 869
 870         ClientInit_CheckUpdate(e);
 871 }
 872
 873 /*
 874 =============
 875 SetNewParms
 876 =============
 877 */
 878 void SetNewParms ()
 879 {
 880         // initialize parms for a new player
 881         parm1 = -(86400 * 366);
 882
 883         MUTATOR_CALLHOOK(SetNewParms);
 884 }
 885
 886 /*
 887 =============
 888 SetChangeParms
 889 =============
 890 */
 891 void SetChangeParms (entity this)
 892 {
 893         // save parms for level change
 894         parm1 = CS(this).parm_idlesince - time;
 895
 896         MUTATOR_CALLHOOK(SetChangeParms);
 897 }
 898
 899 /*
 900 =============
 901 DecodeLevelParms
 902 =============
 903 */
 904 void DecodeLevelParms(entity this)
 905 {
 906         // load parms
 907         CS(this).parm_idlesince = parm1;
 908         if (CS(this).parm_idlesince == -(86400 * 366))
 909                 CS(this).parm_idlesince = time;
 910
 911         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 912         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 913
 914         MUTATOR_CALLHOOK(DecodeLevelParms);
 915 }
 916
 917 void FixClientCvars(entity e)
 918 {
 919         // send prediction settings to the client
 920         stuffcmd(e, "\nin_bindmap 0 0\n");
 921         if(autocvar_g_antilag == 3) // client side hitscan
 922                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 923         if(autocvar_sv_gentle)
 924                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 925
 926         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 927         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 928
 929         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 930
 931         MUTATOR_CALLHOOK(FixClientCvars, e);
 932 }
 933
 934 bool findinlist_abbrev(string tofind, string list)
 935 {
 936         if(list == "" || tofind == "")
 937                 return false; // empty list or search, just return
 938
 939         // this function allows abbreviated strings!
 940         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 941         {
 942                 return true;
 943         });
 944
 945         return false;
 946 }
 947
 948 bool PlayerInIPList(entity p, string iplist)
 949 {
 950         // some safety checks (never allow local?)
 951         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 952                 return false;
 953
 954         return findinlist_abbrev(p.netaddress, iplist);
 955 }
 956
 957 bool PlayerInIDList(entity p, string idlist)
 958 {
 959         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 960         if(!p.crypto_idfp)
 961                 return false;
 962
 963         return findinlist_abbrev(p.crypto_idfp, idlist);
 964 }
 965
 966 bool PlayerInList(entity player, string list)
 967 {
 968         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 969 }
 970
 971 #ifdef DP_EXT_PRECONNECT
 972 /*
 973 =============
 974 ClientPreConnect
 975
 976 Called once (not at each match start) when a client begins a connection to the server
 977 =============
 978 */
 979 void ClientPreConnect(entity this)
 980 {
 981         if(autocvar_sv_eventlog)
 982         {
 983                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 984                         this.playerid,
 985                         etof(this),
 986                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 987                 ));
 988         }
 989 }
 990 #endif
 991
 992 string GetClientVersionMessage(entity this)
 993 {
 994         if (CS(this).version_mismatch) {
 995                 if(CS(this).version < autocvar_gameversion) {
 996                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 997                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 998                 } else {
 999                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1000                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1001                 }
1002         } else {
1003                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1004         }
1005 }
1006
1007 string getwelcomemessage(entity this)
1008 {
1009         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1010         string modifications = M_ARGV(0, string);
1011
1012         if(g_weaponarena)
1013         {
1014                 if(g_weaponarena_random)
1015                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1016                 else
1017                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1018         }
1019         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1020                 modifications = strcat(modifications, ", No start weapons");
1021         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1022                 modifications = strcat(modifications, ", Low gravity");
1023         if(g_weapon_stay && !g_cts)
1024                 modifications = strcat(modifications, ", Weapons stay");
1025         if(g_jetpack)
1026                 modifications = strcat(modifications, ", Jet pack");
1027         if(autocvar_g_powerups == 0)
1028                 modifications = strcat(modifications, ", No powerups");
1029         if(autocvar_g_powerups > 0)
1030                 modifications = strcat(modifications, ", Powerups");
1031         modifications = substring(modifications, 2, strlen(modifications) - 2);
1032
1033         string versionmessage = GetClientVersionMessage(this);
1034         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1035
1036         if(modifications != "")
1037                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1038
1039         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1040         {
1041                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1042                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1043         }
1044
1045         if (cache_mutatormsg != "") {
1046                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1047         }
1048
1049         string mutator_msg = "";
1050         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1051         mutator_msg = M_ARGV(0, string);
1052
1053         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1054
1055         string motd = autocvar_sv_motd;
1056         if (motd != "") {
1057                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1058         }
1059         return s;
1060 }
1061
1062 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1063
1064 /**
1065 =============
1066 ClientConnect
1067
1068 Called when a client connects to the server
1069 =============
1070 */
1071 void ClientConnect(entity this)
1072 {
1073         if (Ban_MaybeEnforceBanOnce(this)) return;
1074         assert(!IS_CLIENT(this), return);
1075         this.flags |= FL_CLIENT;
1076         assert(player_count >= 0, player_count = 0);
1077
1078 #ifdef WATERMARK
1079         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1080 #endif
1081         TRANSMUTE(Client, this);
1082         CS(this).version_nagtime = time + 10 + random() * 10;
1083
1084         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1085
1086         bot_clientconnect(this);
1087
1088         Player_DetermineForcedTeam(this);
1089
1090         TRANSMUTE(Observer, this);
1091
1092         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1093
1094         // always track bots, don't ask for cl_allow_uidtracking
1095         if (IS_BOT_CLIENT(this))
1096                 PlayerStats_GameReport_AddPlayer(this);
1097         else
1098                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1099
1100         if (autocvar_sv_eventlog)
1101                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1102
1103         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1104
1105         stuffcmd(this, clientstuff, "\n");
1106         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1107
1108         FixClientCvars(this);
1109
1110         // get version info from player
1111         stuffcmd(this, "cmd clientversion $gameversion\n");
1112
1113         // notify about available teams
1114         if (teamplay)
1115         {
1116                 entity balance = TeamBalance_CheckAllowedTeams(this);
1117                 int t = TeamBalance_GetAllowedTeams(balance);
1118                 TeamBalance_Destroy(balance);
1119                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1120         }
1121         else
1122         {
1123                 stuffcmd(this, "set _teams_available 0\n");
1124         }
1125
1126         bot_relinkplayerlist();
1127
1128         CS(this).spectatortime = time;
1129         if (blockSpectators)
1130         {
1131                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1132         }
1133
1134         CS(this).jointime = time;
1135
1136         if (IS_REAL_CLIENT(this))
1137         {
1138                 if (g_weaponarena_weapons == WEPSET(TUBA))
1139                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1140         }
1141
1142         if (!sv_foginterval && world.fog != "")
1143                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1144
1145         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1146                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1147                         send_CSQC_teamnagger();
1148
1149         CSQCMODEL_AUTOINIT(this);
1150
1151         CS(this).model_randomizer = random();
1152
1153         if (IS_REAL_CLIENT(this))
1154                 sv_notice_join(this);
1155
1156         this.move_qcphysics = autocvar_sv_qcphysics;
1157
1158         // update physics stats (players can spawn before physics runs)
1159         Physics_UpdateStats(this);
1160
1161         IL_EACH(g_initforplayer, it.init_for_player, {
1162                 it.init_for_player(it, this);
1163         });
1164
1165         Handicap_Initialize(this);
1166
1167         MUTATOR_CALLHOOK(ClientConnect, this);
1168
1169         if (IS_REAL_CLIENT(this))
1170         {
1171                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1172                 {
1173                         CS(this).motd_actived_time = -1;
1174                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1175                 }
1176         }
1177 }
1178 /*
1179 =============
1180 ClientDisconnect
1181
1182 Called when a client disconnects from the server
1183 =============
1184 */
1185 .entity chatbubbleentity;
1186 void ClientDisconnect(entity this)
1187 {
1188         assert(IS_CLIENT(this), return);
1189
1190         PlayerStats_GameReport_FinalizePlayer(this);
1191         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1192         if (CS(this).active_minigame) part_minigame(this);
1193         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1194
1195         if (autocvar_sv_eventlog)
1196                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1197
1198         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1199
1200         if(IS_SPEC(this))
1201                 SetSpectatee(this, NULL);
1202
1203     MUTATOR_CALLHOOK(ClientDisconnect, this);
1204
1205         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1206         strfree(CS(this).weaponorder_byimpulse);
1207         ClientState_detach(this);
1208
1209         Portal_ClearAll(this);
1210
1211         Unfreeze(this, false);
1212
1213         RemoveGrapplingHooks(this);
1214
1215         // Here, everything has been done that requires this player to be a client.
1216
1217         this.flags &= ~FL_CLIENT;
1218
1219         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1220         if (this.killindicator) delete(this.killindicator);
1221
1222         WaypointSprite_PlayerGone(this);
1223
1224         bot_relinkplayerlist();
1225
1226         strfree(this.clientstatus);
1227         if (this.personal) delete(this.personal);
1228
1229         this.playerid = 0;
1230         ReadyCount();
1231         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1232
1233         ONREMOVE(this);
1234 }
1235
1236 void ChatBubbleThink(entity this)
1237 {
1238         this.nextthink = time;
1239         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1240         {
1241                 if(this.owner) // but why can that ever be NULL?
1242                         this.owner.chatbubbleentity = NULL;
1243                 delete(this);
1244                 return;
1245         }
1246
1247         this.mdl = "";
1248
1249         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1250         {
1251                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1252                         this.mdl = "models/sprites/minigame_busy.iqm";
1253                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1254                         this.mdl = "models/misc/chatbubble.spr";
1255         }
1256
1257         if ( this.model != this.mdl )
1258                 _setmodel(this, this.mdl);
1259
1260 }
1261
1262 void UpdateChatBubble(entity this)
1263 {
1264         if (this.alpha < 0)
1265                 return;
1266         // spawn a chatbubble entity if needed
1267         if (!this.chatbubbleentity)
1268         {
1269                 this.chatbubbleentity = new(chatbubbleentity);
1270                 this.chatbubbleentity.owner = this;
1271                 this.chatbubbleentity.exteriormodeltoclient = this;
1272                 setthink(this.chatbubbleentity, ChatBubbleThink);
1273                 this.chatbubbleentity.nextthink = time;
1274                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1275                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1276                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1277                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1278                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1279                 //this.chatbubbleentity.model = "";
1280                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1281         }
1282 }
1283
1284
1285 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1286 // added to the model skins
1287 /*void UpdateColorModHack()
1288 {
1289         float c;
1290         c = this.clientcolors & 15;
1291         // LordHavoc: only bothering to support white, green, red, yellow, blue
1292              if (!teamplay) this.colormod = '0 0 0';
1293         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1294         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1295         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1296         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1297         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1298         else this.colormod = '1 1 1';
1299 }*/
1300
1301 void respawn(entity this)
1302 {
1303         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1304         {
1305                 this.solid = SOLID_NOT;
1306                 this.takedamage = DAMAGE_NO;
1307                 set_movetype(this, MOVETYPE_FLY);
1308                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1309                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1310                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1311                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1312                 if(autocvar_g_respawn_ghosts_maxtime)
1313                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1314         }
1315
1316         CopyBody(this, 1);
1317
1318         this.effects |= EF_NODRAW; // prevent another CopyBody
1319         PutClientInServer(this);
1320 }
1321
1322 void PrintToChat(entity client, string text)
1323 {
1324         text = strcat("\{1}^7", text, "\n");
1325         sprint(client, text);
1326 }
1327
1328 void DebugPrintToChat(entity client, string text)
1329 {
1330         if (autocvar_developer)
1331         {
1332                 PrintToChat(client, text);
1333         }
1334 }
1335
1336 void PrintToChatAll(string text)
1337 {
1338         text = strcat("\{1}^7", text, "\n");
1339         bprint(text);
1340 }
1341
1342 void DebugPrintToChatAll(string text)
1343 {
1344         if (autocvar_developer)
1345         {
1346                 PrintToChatAll(text);
1347         }
1348 }
1349
1350 void PrintToChatTeam(int team_num, string text)
1351 {
1352         text = strcat("\{1}^7", text, "\n");
1353         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1354         {
1355                 if (it.team == team_num)
1356                 {
1357                         sprint(it, text);
1358                 }
1359         });
1360 }
1361
1362 void DebugPrintToChatTeam(int team_num, string text)
1363 {
1364         if (autocvar_developer)
1365         {
1366                 PrintToChatTeam(team_num, text);
1367         }
1368 }
1369
1370 void play_countdown(entity this, float finished, Sound samp)
1371 {
1372         TC(Sound, samp);
1373         if(IS_REAL_CLIENT(this))
1374                 if(floor(finished - time - frametime) != floor(finished - time))
1375                         if(finished - time < 6)
1376                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1377 }
1378
1379 void player_powerups(entity this)
1380 {
1381         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1382         int items_prev = this.items;
1383
1384         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1385                 this.modelflags |= MF_ROCKET;
1386         else
1387                 this.modelflags &= ~MF_ROCKET;
1388
1389         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1390
1391         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1392                 return;
1393
1394         Fire_ApplyDamage(this);
1395         Fire_ApplyEffect(this);
1396
1397         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1398         {
1399                 if (this.items & ITEM_Strength.m_itemid)
1400                 {
1401                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1402                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1403                         if (time > this.strength_finished)
1404                         {
1405                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1406                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1407                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1408                         }
1409                 }
1410                 else
1411                 {
1412                         if (time < this.strength_finished)
1413                         {
1414                                 this.items = this.items | ITEM_Strength.m_itemid;
1415                                 if(!g_cts)
1416                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1417                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1418                         }
1419                 }
1420                 if (this.items & ITEM_Shield.m_itemid)
1421                 {
1422                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1423                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1424                         if (time > this.invincible_finished)
1425                         {
1426                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1427                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1428                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1429                         }
1430                 }
1431                 else
1432                 {
1433                         if (time < this.invincible_finished)
1434                         {
1435                                 this.items = this.items | ITEM_Shield.m_itemid;
1436                                 if(!g_cts)
1437                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1438                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1439                         }
1440                 }
1441                 if (this.items & IT_SUPERWEAPON)
1442                 {
1443                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1444                         {
1445                                 this.superweapons_finished = 0;
1446                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1447                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1448                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1449                         }
1450                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1451                         {
1452                                 // don't let them run out
1453                         }
1454                         else
1455                         {
1456                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1457                                 if (time > this.superweapons_finished)
1458                                 {
1459                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1460                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1461                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1462                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1463                                 }
1464                         }
1465                 }
1466                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1467                 {
1468                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1469                         {
1470                                 this.items = this.items | IT_SUPERWEAPON;
1471                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1472                                 {
1473                                         if(!g_cts)
1474                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1475                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1476                                 }
1477                         }
1478                         else
1479                         {
1480                                 this.superweapons_finished = 0;
1481                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1482                         }
1483                 }
1484                 else
1485                 {
1486                         this.superweapons_finished = 0;
1487                 }
1488         }
1489
1490         if(autocvar_g_nodepthtestplayers)
1491                 this.effects = this.effects | EF_NODEPTHTEST;
1492
1493         if(autocvar_g_fullbrightplayers)
1494                 this.effects = this.effects | EF_FULLBRIGHT;
1495
1496         if (time >= game_starttime)
1497         if (time < this.spawnshieldtime)
1498                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1499
1500         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1501 }
1502
1503 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1504 {
1505         if(current > stable)
1506                 return current;
1507         else if(current > stable - 0.25) // when close enough, "snap"
1508                 return stable;
1509         else
1510                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1511 }
1512
1513 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1514 {
1515         if(current < stable)
1516                 return current;
1517         else if(current < stable + 0.25) // when close enough, "snap"
1518                 return stable;
1519         else
1520                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1521 }
1522
1523 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1524 {
1525         if(current > rotstable)
1526         {
1527                 if(rotframetime > 0)
1528                 {
1529                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1530                         current = max(rotstable, current - rotlinear * rotframetime);
1531                 }
1532         }
1533         else if(current < regenstable)
1534         {
1535                 if(regenframetime > 0)
1536                 {
1537                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1538                         current = min(regenstable, current + regenlinear * regenframetime);
1539                 }
1540         }
1541
1542         if(current > limit)
1543                 current = limit;
1544
1545         return current;
1546 }
1547
1548 void player_regen(entity this)
1549 {
1550         float max_mod, regen_mod, rot_mod, limit_mod;
1551         max_mod = regen_mod = rot_mod = limit_mod = 1;
1552
1553         float regen_health = autocvar_g_balance_health_regen;
1554         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1555         float regen_health_rot = autocvar_g_balance_health_rot;
1556         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1557         float regen_health_stable = autocvar_g_balance_health_regenstable;
1558         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1559         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1560                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1561         max_mod = M_ARGV(1, float);
1562         regen_mod = M_ARGV(2, float);
1563         rot_mod = M_ARGV(3, float);
1564         limit_mod = M_ARGV(4, float);
1565         regen_health = M_ARGV(5, float);
1566         regen_health_linear = M_ARGV(6, float);
1567         regen_health_rot = M_ARGV(7, float);
1568         regen_health_rotlinear = M_ARGV(8, float);
1569         regen_health_stable = M_ARGV(9, float);
1570         regen_health_rotstable = M_ARGV(10, float);
1571
1572         if(!mutator_returnvalue)
1573         if(!STAT(FROZEN, this))
1574         {
1575                 float mina, maxa, limith, limita;
1576                 maxa = autocvar_g_balance_armor_rotstable;
1577                 mina = autocvar_g_balance_armor_regenstable;
1578                 limith = GetResourceLimit(this, RES_HEALTH);
1579                 limita = GetResourceLimit(this, RES_ARMOR);
1580
1581                 regen_health_rotstable = regen_health_rotstable * max_mod;
1582                 regen_health_stable = regen_health_stable * max_mod;
1583                 limith = limith * limit_mod;
1584                 limita = limita * limit_mod;
1585
1586                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1587                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1588                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1589                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1590                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1591                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1592         }
1593
1594         // if player rotted to death...  die!
1595         // check this outside above checks, as player may still be able to rot to death
1596         if(GetResource(this, RES_HEALTH) < 1)
1597         {
1598                 if(this.vehicle)
1599                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1600                 if(this.event_damage)
1601                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1602         }
1603
1604         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1605         {
1606                 float minf, maxf, limitf;
1607
1608                 maxf = autocvar_g_balance_fuel_rotstable;
1609                 minf = autocvar_g_balance_fuel_regenstable;
1610                 limitf = GetResourceLimit(this, RES_FUEL);
1611
1612                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1613                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1614                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1615         }
1616 }
1617
1618 bool zoomstate_set;
1619 void SetZoomState(entity this, float newzoom)
1620 {
1621         if(newzoom != CS(this).zoomstate)
1622         {
1623                 CS(this).zoomstate = newzoom;
1624                 ClientData_Touch(this);
1625         }
1626         zoomstate_set = true;
1627 }
1628
1629 void GetPressedKeys(entity this)
1630 {
1631         MUTATOR_CALLHOOK(GetPressedKeys, this);
1632         int keys = STAT(PRESSED_KEYS, this);
1633         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1634         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1635         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1636         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1637
1638         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1639         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1640         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1641         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1642         CS(this).pressedkeys = keys; // store for other users
1643
1644         STAT(PRESSED_KEYS, this) = keys;
1645 }
1646
1647 /*
1648 ======================
1649 spectate mode routines
1650 ======================
1651 */
1652
1653 void SpectateCopy(entity this, entity spectatee)
1654 {
1655         TC(Client, this); TC(Client, spectatee);
1656
1657         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1658         PS(this) = PS(spectatee);
1659         this.armortype = spectatee.armortype;
1660         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1661         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1662         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1663         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1664         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1665         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1666         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1667         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1668         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1669         CS(this).impulse = 0;
1670         this.items = spectatee.items;
1671         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1672         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1673         this.strength_finished = spectatee.strength_finished;
1674         this.invincible_finished = spectatee.invincible_finished;
1675         this.superweapons_finished = spectatee.superweapons_finished;
1676         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1677         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1678         this.punchangle = spectatee.punchangle;
1679         this.view_ofs = spectatee.view_ofs;
1680         this.velocity = spectatee.velocity;
1681         this.dmg_take = spectatee.dmg_take;
1682         this.dmg_save = spectatee.dmg_save;
1683         this.dmg_inflictor = spectatee.dmg_inflictor;
1684         this.v_angle = spectatee.v_angle;
1685         this.angles = spectatee.v_angle;
1686         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1687         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1688         this.viewloc = spectatee.viewloc;
1689         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1690                 this.fixangle = true;
1691         setorigin(this, spectatee.origin);
1692         setsize(this, spectatee.mins, spectatee.maxs);
1693         SetZoomState(this, CS(spectatee).zoomstate);
1694
1695     anticheat_spectatecopy(this, spectatee);
1696         STAT(HUD, this) = STAT(HUD, spectatee);
1697         if(spectatee.vehicle)
1698     {
1699         this.angles = spectatee.v_angle;
1700
1701         //this.fixangle = false;
1702         //this.velocity = spectatee.vehicle.velocity;
1703         this.vehicle_health = spectatee.vehicle_health;
1704         this.vehicle_shield = spectatee.vehicle_shield;
1705         this.vehicle_energy = spectatee.vehicle_energy;
1706         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1707         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1708         this.vehicle_reload1 = spectatee.vehicle_reload1;
1709         this.vehicle_reload2 = spectatee.vehicle_reload2;
1710
1711         //msg_entity = this;
1712
1713        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1714             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1715            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1716            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1717
1718         //WriteByte (MSG_ONE, SVC_SETVIEW);
1719         //    WriteEntity(MSG_ONE, this);
1720         //makevectors(spectatee.v_angle);
1721         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1722     }
1723 }
1724
1725 bool SpectateUpdate(entity this)
1726 {
1727         if(!this.enemy)
1728                 return false;
1729
1730         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1731         {
1732                 SetSpectatee(this, NULL);
1733                 return false;
1734         }
1735
1736         SpectateCopy(this, this.enemy);
1737
1738         return true;
1739 }
1740
1741 bool SpectateSet(entity this)
1742 {
1743         if(!IS_PLAYER(this.enemy))
1744                 return false;
1745
1746         ClientData_Touch(this.enemy);
1747
1748         msg_entity = this;
1749         WriteByte(MSG_ONE, SVC_SETVIEW);
1750         WriteEntity(MSG_ONE, this.enemy);
1751         set_movetype(this, MOVETYPE_NONE);
1752         accuracy_resend(this);
1753
1754         if(!SpectateUpdate(this))
1755                 PutObserverInServer(this);
1756
1757         return true;
1758 }
1759
1760 void SetSpectatee_status(entity this, int spectatee_num)
1761 {
1762         int oldspectatee_status = CS(this).spectatee_status;
1763         CS(this).spectatee_status = spectatee_num;
1764
1765         if (CS(this).spectatee_status != oldspectatee_status)
1766         {
1767                 ClientData_Touch(this);
1768                 if (g_race || g_cts) race_InitSpectator();
1769         }
1770 }
1771
1772 void SetSpectatee(entity this, entity spectatee)
1773 {
1774         if(IS_BOT_CLIENT(this))
1775                 return; // bots abuse .enemy, this code is useless to them
1776
1777         entity old_spectatee = this.enemy;
1778
1779         this.enemy = spectatee;
1780
1781         // WEAPONTODO
1782         // these are required to fix the spectator bug with arc
1783         if(old_spectatee)
1784         {
1785                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1786                 {
1787                         .entity weaponentity = weaponentities[slot];
1788                         if(old_spectatee.(weaponentity).arc_beam)
1789                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1790                 }
1791         }
1792         if(this.enemy)
1793         {
1794                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1795                 {
1796                         .entity weaponentity = weaponentities[slot];
1797                         if(this.enemy.(weaponentity).arc_beam)
1798                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1799                 }
1800         }
1801
1802         if (this.enemy)
1803                 SetSpectatee_status(this, etof(this.enemy));
1804
1805         // needed to update spectator list
1806         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1807 }
1808
1809 bool Spectate(entity this, entity pl)
1810 {
1811         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1812                 return false;
1813         pl = M_ARGV(1, entity);
1814
1815         SetSpectatee(this, pl);
1816         return SpectateSet(this);
1817 }
1818
1819 bool SpectateNext(entity this)
1820 {
1821         entity ent = find(this.enemy, classname, STR_PLAYER);
1822
1823         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1824                 ent = M_ARGV(1, entity);
1825         else if (!ent)
1826                 ent = find(ent, classname, STR_PLAYER);
1827
1828         if(ent) { SetSpectatee(this, ent); }
1829
1830         return SpectateSet(this);
1831 }
1832
1833 bool SpectatePrev(entity this)
1834 {
1835         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1836         entity ent = findchain(classname, STR_PLAYER);
1837         if (!ent) // no player
1838                 return false;
1839
1840         entity first = ent;
1841         // skip players until current spectated player
1842         if(this.enemy)
1843         while(ent && ent != this.enemy)
1844                 ent = ent.chain;
1845
1846         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1847         {
1848                 case MUT_SPECPREV_FOUND:
1849                     ent = M_ARGV(1, entity);
1850                     break;
1851                 case MUT_SPECPREV_RETURN:
1852                     return true;
1853                 case MUT_SPECPREV_CONTINUE:
1854                 default:
1855                 {
1856                         if(ent.chain)
1857                                 ent = ent.chain;
1858                         else
1859                                 ent = first;
1860                         break;
1861                 }
1862         }
1863
1864         SetSpectatee(this, ent);
1865         return SpectateSet(this);
1866 }
1867
1868 /*
1869 =============
1870 ShowRespawnCountdown()
1871
1872 Update a respawn countdown display.
1873 =============
1874 */
1875 void ShowRespawnCountdown(entity this)
1876 {
1877         float number;
1878         if(!IS_DEAD(this)) // just respawned?
1879                 return;
1880         else
1881         {
1882                 number = ceil(this.respawn_time - time);
1883                 if(number <= 0)
1884                         return;
1885                 if(number <= this.respawn_countdown)
1886                 {
1887                         this.respawn_countdown = number - 1;
1888                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1889                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1890                 }
1891         }
1892 }
1893
1894 .bool team_selected;
1895 bool ShowTeamSelection(entity this)
1896 {
1897         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1898                 return false;
1899         stuffcmd(this, "menu_showteamselect\n");
1900         return true;
1901 }
1902 void Join(entity this)
1903 {
1904         TRANSMUTE(Player, this);
1905
1906         if(!this.team_selected)
1907         if(autocvar_g_campaign || autocvar_g_balance_teams)
1908                 TeamBalance_JoinBestTeam(this);
1909
1910         if(autocvar_g_campaign)
1911                 campaign_bots_may_start = true;
1912
1913         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1914
1915         PutClientInServer(this);
1916
1917         if(IS_PLAYER(this))
1918         if(teamplay && this.team != -1)
1919         {
1920         }
1921         else
1922                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1923         this.team_selected = false;
1924 }
1925
1926 int GetPlayerLimit()
1927 {
1928         int player_limit = autocvar_g_maxplayers;
1929         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1930         player_limit = M_ARGV(0, int);
1931         return player_limit;
1932 }
1933
1934 /**
1935  * Determines whether the player is allowed to join. This depends on cvar
1936  * g_maxplayers, if it isn't used this function always return true, otherwise
1937  * it checks whether the number of currently playing players exceeds g_maxplayers.
1938  * @return int number of free slots for players, 0 if none
1939  */
1940 int nJoinAllowed(entity this, entity ignore)
1941 {
1942         if(!ignore)
1943         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1944         // so report 0 free slots if restricted
1945         {
1946                 if(autocvar_g_forced_team_otherwise == "spectate")
1947                         return 0;
1948                 if(autocvar_g_forced_team_otherwise == "spectator")
1949                         return 0;
1950         }
1951
1952         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1953                 return 0; // forced spectators can never join
1954
1955         // TODO simplify this
1956         int totalClients = 0;
1957         int currentlyPlaying = 0;
1958         FOREACH_CLIENT(true, {
1959                 if(it != ignore)
1960                         ++totalClients;
1961                 if(IS_REAL_CLIENT(it))
1962                 if(IS_PLAYER(it) || it.caplayer)
1963                         ++currentlyPlaying;
1964         });
1965
1966         int player_limit = GetPlayerLimit();
1967
1968         float free_slots = 0;
1969         if (!player_limit)
1970                 free_slots = maxclients - totalClients;
1971         else if(currentlyPlaying < player_limit)
1972                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1973
1974         static float join_prevent_msg_time = 0;
1975         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1976         {
1977                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1978                 join_prevent_msg_time = time + 3;
1979         }
1980
1981         return free_slots;
1982 }
1983
1984 /**
1985  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1986  * g_maxplayers_spectator_blocktime seconds
1987  */
1988 void checkSpectatorBlock(entity this)
1989 {
1990         if(IS_SPEC(this) || IS_OBSERVER(this))
1991         if(!this.caplayer)
1992         if(IS_REAL_CLIENT(this))
1993         {
1994                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1995                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1996                         dropclient(this);
1997                 }
1998         }
1999 }
2000
2001 void PrintWelcomeMessage(entity this)
2002 {
2003         if(CS(this).motd_actived_time == 0)
2004         {
2005                 if (autocvar_g_campaign) {
2006                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2007                                 CS(this).motd_actived_time = time;
2008                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2009                         }
2010                 } else {
2011                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2012                                 CS(this).motd_actived_time = time;
2013                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2014                         }
2015                 }
2016         }
2017         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2018         {
2019                 if (autocvar_g_campaign) {
2020                         if (PHYS_INPUT_BUTTON_INFO(this))
2021                                 CS(this).motd_actived_time = time;
2022                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2023                                 CS(this).motd_actived_time = 0;
2024                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2025                         }
2026                 } else {
2027                         if (PHYS_INPUT_BUTTON_INFO(this))
2028                                 CS(this).motd_actived_time = time;
2029                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2030                                 CS(this).motd_actived_time = 0;
2031                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2032                         }
2033                 }
2034         }
2035         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2036         {
2037                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2038                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2039                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2040                 {
2041                         // instanctly hide MOTD
2042                         CS(this).motd_actived_time = 0;
2043                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2044                 }
2045         }
2046 }
2047
2048 const int MIN_SPEC_TIME = 1;
2049 bool joinAllowed(entity this)
2050 {
2051         if (CS(this).version_mismatch) return false;
2052         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2053         if (!nJoinAllowed(this, this)) return false;
2054         if (teamplay && lockteams) return false;
2055         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2056         if (ShowTeamSelection(this)) return false;
2057         return true;
2058 }
2059
2060 .int items_added;
2061 .string shootfromfixedorigin;
2062 bool PlayerThink(entity this)
2063 {
2064         if (game_stopped || intermission_running) {
2065                 this.modelflags &= ~MF_ROCKET;
2066                 if(intermission_running)
2067                         IntermissionThink(this);
2068                 return false;
2069         }
2070
2071         if (timeout_status == TIMEOUT_ACTIVE) {
2072         // don't allow the player to turn around while game is paused
2073                 // FIXME turn this into CSQC stuff
2074                 this.v_angle = this.lastV_angle;
2075                 this.angles = this.lastV_angle;
2076                 this.fixangle = true;
2077         }
2078
2079         if (frametime) player_powerups(this);
2080
2081         if (IS_DEAD(this)) {
2082                 if (this.personal && g_race_qualifying) {
2083                         if (time > this.respawn_time) {
2084                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2085                                 respawn(this);
2086                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2087                         }
2088                 } else {
2089                         if (frametime) player_anim(this);
2090
2091                         if (this.respawn_flags & RESPAWN_DENY)
2092                         {
2093                                 STAT(RESPAWN_TIME, this) = 0;
2094                                 return false;
2095                         }
2096
2097                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2098
2099                         switch(this.deadflag)
2100                         {
2101                                 case DEAD_DYING:
2102                                 {
2103                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2104                                                 this.deadflag = DEAD_RESPAWNING;
2105                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2106                                                 this.deadflag = DEAD_DEAD;
2107                                         break;
2108                                 }
2109                                 case DEAD_DEAD:
2110                                 {
2111                                         if (button_pressed)
2112                                                 this.deadflag = DEAD_RESPAWNABLE;
2113                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2114                                                 this.deadflag = DEAD_RESPAWNING;
2115                                         break;
2116                                 }
2117                                 case DEAD_RESPAWNABLE:
2118                                 {
2119                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2120                                                 this.deadflag = DEAD_RESPAWNING;
2121                                         break;
2122                                 }
2123                                 case DEAD_RESPAWNING:
2124                                 {
2125                                         if (time > this.respawn_time)
2126                                         {
2127                                                 this.respawn_time = time + 1; // only retry once a second
2128                                                 this.respawn_time_max = this.respawn_time;
2129                                                 respawn(this);
2130                                         }
2131                                         break;
2132                                 }
2133                         }
2134
2135                         ShowRespawnCountdown(this);
2136
2137                         if (this.respawn_flags & RESPAWN_SILENT)
2138                                 STAT(RESPAWN_TIME, this) = 0;
2139                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2140                         {
2141                                 if (time < this.respawn_time)
2142                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2143                                 else if (this.deadflag != DEAD_RESPAWNING)
2144                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2145                         }
2146                         else
2147                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2148                 }
2149
2150                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2151                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2152                         STAT(RESPAWN_TIME, this) *= -1;
2153
2154                 return false;
2155         }
2156
2157         FixPlayermodel(this);
2158
2159         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2160                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2161                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2162         }
2163
2164         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2165         //if(frametime)
2166         {
2167                 this.items &= ~this.items_added;
2168
2169                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2170                 {
2171                         .entity weaponentity = weaponentities[slot];
2172                         W_WeaponFrame(this, weaponentity);
2173                 }
2174
2175                 this.items_added = 0;
2176                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2177             this.items_added |= IT_FUEL;
2178
2179                 this.items |= this.items_added;
2180         }
2181
2182         player_regen(this);
2183
2184         // WEAPONTODO: Add a weapon request for this
2185         // rot vortex charge to the charge limit
2186         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2187         {
2188                 .entity weaponentity = weaponentities[slot];
2189                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2190                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2191         }
2192
2193         if (frametime) player_anim(this);
2194
2195         // secret status
2196         secrets_setstatus(this);
2197
2198         // monsters status
2199         monsters_setstatus(this);
2200
2201         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2202
2203         return true;
2204 }
2205
2206 .bool would_spectate;
2207 void ObserverThink(entity this)
2208 {
2209         if ( CS(this).impulse )
2210         {
2211                 MinigameImpulse(this, CS(this).impulse);
2212                 CS(this).impulse = 0;
2213         }
2214
2215         if (this.flags & FL_JUMPRELEASED) {
2216                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2217                         this.flags &= ~FL_JUMPRELEASED;
2218                         this.flags |= FL_SPAWNING;
2219                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2220                         this.flags &= ~FL_JUMPRELEASED;
2221                         if(SpectateNext(this)) {
2222                                 TRANSMUTE(Spectator, this);
2223                         }
2224                 } else {
2225                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2226                         set_movetype(this, preferred_movetype);
2227                 }
2228         } else {
2229                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2230                         this.flags |= FL_JUMPRELEASED;
2231                         if(this.flags & FL_SPAWNING)
2232                         {
2233                                 this.flags &= ~FL_SPAWNING;
2234                                 Join(this);
2235                                 return;
2236                         }
2237                 }
2238         }
2239 }
2240
2241 void SpectatorThink(entity this)
2242 {
2243         if ( CS(this).impulse )
2244         {
2245                 if(MinigameImpulse(this, CS(this).impulse))
2246                         CS(this).impulse = 0;
2247
2248                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2249                 {
2250                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2251                         CS(this).impulse = 0;
2252                         return;
2253                 }
2254         }
2255
2256         if (this.flags & FL_JUMPRELEASED) {
2257                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2258                         this.flags &= ~FL_JUMPRELEASED;
2259                         this.flags |= FL_SPAWNING;
2260                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2261                         this.flags &= ~FL_JUMPRELEASED;
2262                         if(SpectateNext(this)) {
2263                                 TRANSMUTE(Spectator, this);
2264                         } else {
2265                                 TRANSMUTE(Observer, this);
2266                                 PutClientInServer(this);
2267                         }
2268                         CS(this).impulse = 0;
2269                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2270                         this.flags &= ~FL_JUMPRELEASED;
2271                         if(SpectatePrev(this)) {
2272                                 TRANSMUTE(Spectator, this);
2273                         } else {
2274                                 TRANSMUTE(Observer, this);
2275                                 PutClientInServer(this);
2276                         }
2277                         CS(this).impulse = 0;
2278                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2279                         this.would_spectate = false;
2280                         this.flags &= ~FL_JUMPRELEASED;
2281                         TRANSMUTE(Observer, this);
2282                         PutClientInServer(this);
2283                 } else {
2284                         if(!SpectateUpdate(this))
2285                         {
2286                                 if(!SpectateNext(this))
2287                                 {
2288                                         PutObserverInServer(this);
2289                                         this.would_spectate = true;
2290                                 }
2291                         }
2292                 }
2293         } else {
2294                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2295                         this.flags |= FL_JUMPRELEASED;
2296                         if(this.flags & FL_SPAWNING)
2297                         {
2298                                 this.flags &= ~FL_SPAWNING;
2299                                 Join(this);
2300                                 return;
2301                         }
2302                 }
2303                 if(!SpectateUpdate(this))
2304                         PutObserverInServer(this);
2305         }
2306
2307         this.flags |= FL_CLIENT | FL_NOTARGET;
2308 }
2309
2310 void PlayerUseKey(entity this)
2311 {
2312         if (!IS_PLAYER(this))
2313                 return;
2314
2315         if(this.vehicle)
2316         {
2317                 if(!game_stopped)
2318                 {
2319                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2320                         return;
2321                 }
2322         }
2323         else if(autocvar_g_vehicles_enter)
2324         {
2325                 if(!STAT(FROZEN, this))
2326                 if(!IS_DEAD(this))
2327                 if(!game_stopped)
2328                 {
2329                         entity head, closest_target = NULL;
2330                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2331
2332                         while(head) // find the closest acceptable target to enter
2333                         {
2334                                 if(IS_VEHICLE(head))
2335                                 if(!IS_DEAD(head))
2336                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2337                                 if(head.takedamage != DAMAGE_NO)
2338                                 {
2339                                         if(closest_target)
2340                                         {
2341                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2342                                                 { closest_target = head; }
2343                                         }
2344                                         else { closest_target = head; }
2345                                 }
2346
2347                                 head = head.chain;
2348                         }
2349
2350                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2351                 }
2352         }
2353
2354         // a use key was pressed; call handlers
2355         MUTATOR_CALLHOOK(PlayerUseKey, this);
2356 }
2357
2358
2359 /*
2360 =============
2361 PlayerPreThink
2362
2363 Called every frame for each client before the physics are run
2364 =============
2365 */
2366 .float last_vehiclecheck;
2367 void PlayerPreThink (entity this)
2368 {
2369         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2370         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2371
2372         WarpZone_PlayerPhysics_FixVAngle(this);
2373
2374         if (frametime) {
2375                 // physics frames: update anticheat stuff
2376                 anticheat_prethink(this);
2377         }
2378
2379         if (blockSpectators && frametime) {
2380                 // WORKAROUND: only use dropclient in server frames (frametime set).
2381                 // Never use it in cl_movement frames (frametime zero).
2382                 checkSpectatorBlock(this);
2383         }
2384
2385         zoomstate_set = false;
2386
2387         // Check for nameless players
2388         if (this.netname == "" || this.netname != CS(this).netname_previous)
2389         {
2390                 bool assume_unchanged = (CS(this).netname_previous == "");
2391                 if (isInvisibleString(this.netname))
2392                 {
2393                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2394                         assume_unchanged = false;
2395                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2396                 }
2397                 if (!assume_unchanged && autocvar_sv_eventlog)
2398                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2399                 strcpy(CS(this).netname_previous, this.netname);
2400         }
2401
2402         // version nagging
2403         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2404         CS(this).version_nagtime = 0;
2405         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2406             // git client
2407         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2408             // git server
2409             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2410         } else {
2411             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2412             if (r < 0) { // old client
2413                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2414             } else if (r > 0) { // old server
2415                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2416             }
2417         }
2418     }
2419
2420         // GOD MODE info
2421         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2422         {
2423                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2424                 this.max_armorvalue = 0;
2425         }
2426
2427         if(IS_PLAYER(this))
2428         {
2429                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2430                 {
2431                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2432                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2433                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2434
2435                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2436                                 Unfreeze(this, false);
2437                 }
2438                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2439                 {
2440                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2441                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2442
2443                         if (GetResource(this, RES_HEALTH) < 1)
2444                         {
2445                                 if (this.vehicle)
2446                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2447                                 if(this.event_damage)
2448                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2449                         }
2450                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2451                                 Unfreeze(this, false);
2452                 }
2453         }
2454
2455         MUTATOR_CALLHOOK(PlayerPreThink, this);
2456
2457         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2458         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2459         {
2460                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2461                 {
2462                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2463                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2464                         {
2465                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2466                         }
2467                         else if(!it.owner)
2468                         {
2469                                 if(!it.team || SAME_TEAM(this, it))
2470                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2471                                 else if(autocvar_g_vehicles_steal)
2472                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2473                         }
2474                 });
2475
2476                 this.last_vehiclecheck = time + 1;
2477         }
2478
2479         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2480         {
2481                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2482                         PlayerUseKey(this);
2483                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2484         }
2485
2486         if (IS_REAL_CLIENT(this))
2487                 PrintWelcomeMessage(this);
2488
2489         if (IS_PLAYER(this)) {
2490                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2491                         error("Client can't be spawned as player on connection!");
2492                 if(!PlayerThink(this))
2493                         return;
2494         }
2495         else if (game_stopped || intermission_running) {
2496                 if(intermission_running)
2497                         IntermissionThink(this);
2498                 return;
2499         }
2500         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2501         {
2502                 CS(this).autojoin_checked = true;
2503                 // don't do this in ClientConnect
2504                 // many things can go wrong if a client is spawned as player on connection
2505                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2506                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2507                                 && (!teamplay || autocvar_g_balance_teams)))
2508                 {
2509                         campaign_bots_may_start = true;
2510                         Join(this);
2511                         return;
2512                 }
2513         }
2514         else if (IS_OBSERVER(this)) {
2515                 ObserverThink(this);
2516         }
2517         else if (IS_SPEC(this)) {
2518                 SpectatorThink(this);
2519         }
2520
2521         // WEAPONTODO: Add weapon request for this
2522         if (!zoomstate_set) {
2523                 bool wep_zoomed = false;
2524                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2525                 {
2526                         .entity weaponentity = weaponentities[slot];
2527                         Weapon thiswep = this.(weaponentity).m_weapon;
2528                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2529                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2530                 }
2531                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2532     }
2533
2534         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2535         {
2536                 CS(this).teamkill_soundtime = 0;
2537
2538                 entity e = CS(this).teamkill_soundsource;
2539                 entity oldpusher = e.pusher;
2540                 e.pusher = this;
2541                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2542                 e.pusher = oldpusher;
2543         }
2544
2545         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2546                 CS(this).taunt_soundtime = 0;
2547                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2548         }
2549
2550         target_voicescript_next(this);
2551
2552         // WEAPONTODO: Move into weaponsystem somehow
2553         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2554         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2555         {
2556                 .entity weaponentity = weaponentities[slot];
2557                 if(this.(weaponentity).m_weapon == WEP_Null)
2558                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2559         }
2560 }
2561
2562 void DrownPlayer(entity this)
2563 {
2564         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2565                 return;
2566
2567         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2568         {
2569                 if(this.air_finished < time)
2570                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2571                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2572         }
2573         else if (this.air_finished < time)
2574         {       // drown!
2575                 if (this.pain_finished < time)
2576                 {
2577                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2578                         this.pain_finished = time + 0.5;
2579                 }
2580         }
2581 }
2582
2583 .bool move_qcphysics;
2584
2585 void Player_Physics(entity this)
2586 {
2587         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2588
2589         if(!this.move_qcphysics)
2590                 return;
2591
2592         if(!frametime && !CS(this).pm_frametime)
2593                 return;
2594
2595         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2596
2597         CS(this).pm_frametime = 0;
2598 }
2599
2600 /*
2601 =============
2602 PlayerPostThink
2603
2604 Called every frame for each client after the physics are run
2605 =============
2606 */
2607 void PlayerPostThink (entity this)
2608 {
2609         Player_Physics(this);
2610
2611         if (sv_maxidle > 0)
2612         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2613         if (IS_REAL_CLIENT(this))
2614         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2615         {
2616                 int totalClients = 0;
2617                 if(sv_maxidle_slots > 0)
2618                 {
2619                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2620                         {
2621                                 ++totalClients;
2622                         });
2623                 }
2624
2625                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2626                 { /* do nothing */ }
2627                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2628                 {
2629                         if (CS(this).idlekick_lasttimeleft)
2630                         {
2631                                 CS(this).idlekick_lasttimeleft = 0;
2632                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2633                         }
2634                 }
2635                 else
2636                 {
2637                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2638                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2639                                 if (!CS(this).idlekick_lasttimeleft)
2640                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2641                         }
2642                         if (timeleft <= 0) {
2643                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2644                                 dropclient(this);
2645                                 return;
2646                         }
2647                         else if (timeleft <= 10) {
2648                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2649                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2650                 }
2651                                 CS(this).idlekick_lasttimeleft = timeleft;
2652                         }
2653                 }
2654         }
2655
2656         CheatFrame(this);
2657
2658         if (game_stopped)
2659         {
2660                 this.solid = SOLID_NOT;
2661                 this.takedamage = DAMAGE_NO;
2662                 set_movetype(this, MOVETYPE_NONE);
2663         }
2664
2665         if (IS_PLAYER(this)) {
2666                 if(this.death_time == time && IS_DEAD(this))
2667                 {
2668                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2669                         // once all the damage events of this frame have been processed with normal size
2670                         this.maxs.z = 5;
2671                         setsize(this, this.mins, this.maxs);
2672                 }
2673                 DrownPlayer(this);
2674                 UpdateChatBubble(this);
2675                 if (CS(this).impulse) ImpulseCommands(this);
2676                 if (game_stopped)
2677                 {
2678                         CSQCMODEL_AUTOUPDATE(this);
2679                         return;
2680                 }
2681                 GetPressedKeys(this);
2682         }
2683
2684         if (this.waypointsprite_attachedforcarrier) {
2685                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2686                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2687         }
2688
2689         CSQCMODEL_AUTOUPDATE(this);
2690 }
2691
2692 /**
2693  * message "": do not say, just test flood control
2694  * return value:
2695  *   1 = accept
2696  *   0 = reject
2697  *  -1 = fake accept
2698  */
2699 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2700 {
2701         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2702                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2703
2704         if (source)
2705                 msgin = formatmessage(source, msgin);
2706
2707         string colorstr;
2708         if (!(IS_PLAYER(source) || source.caplayer))
2709                 colorstr = "^0"; // black for spectators
2710         else if(teamplay)
2711                 colorstr = Team_ColorCode(source.team);
2712         else
2713         {
2714                 colorstr = "";
2715                 teamsay = false;
2716         }
2717
2718         if (!source) {
2719                 colorstr = "";
2720                 teamsay = false;
2721         }
2722
2723         if(msgin != "")
2724                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2725
2726         /*
2727          * using bprint solves this... me stupid
2728         // how can we prevent the message from appearing in a listen server?
2729         // for now, just give "say" back and only handle say_team
2730         if(!teamsay)
2731         {
2732                 clientcommand(source, strcat("say ", msgin));
2733                 return;
2734         }
2735         */
2736
2737         string namestr = "";
2738         if (source)
2739                 namestr = playername(source, autocvar_g_chat_teamcolors);
2740
2741         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2742
2743         string msgstr = "", cmsgstr = "";
2744         string privatemsgprefix = string_null;
2745         int privatemsgprefixlen = 0;
2746         if (msgin != "")
2747         {
2748                 bool found_me = false;
2749                 if(strstrofs(msgin, "/me", 0) >= 0)
2750                 {
2751                         string newmsgin = "";
2752                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2753                         FOREACH_WORD(msgin, true,
2754                         {
2755                                 if(strdecolorize(it) == "/me")
2756                                 {
2757                                         found_me = true;
2758                                         newmsgin = cons(newmsgin, newnamestr);
2759                                 }
2760                                 else
2761                                         newmsgin = cons(newmsgin, it);
2762                         });
2763                         msgin = newmsgin;
2764                 }
2765
2766                 if(privatesay)
2767                 {
2768                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2769                         privatemsgprefixlen = strlen(msgstr);
2770                         msgstr = strcat(msgstr, msgin);
2771                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2772                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2773                 }
2774                 else if(teamsay)
2775                 {
2776                         if(found_me)
2777                         {
2778                                 //msgin = strreplace("/me", "", msgin);
2779                                 //msgin = substring(msgin, 3, strlen(msgin));
2780                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2781                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2782                         }
2783                         else
2784                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2785                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2786                 }
2787                 else
2788                 {
2789                         if(found_me)
2790                         {
2791                                 //msgin = strreplace("/me", "", msgin);
2792                                 //msgin = substring(msgin, 3, strlen(msgin));
2793                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2794                                 msgstr = strcat("\{1}^4* ^7", msgin);
2795                         }
2796                         else {
2797                                 msgstr = "\{1}";
2798                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2799                                 msgstr = strcat(msgstr, msgin);
2800                         }
2801                         cmsgstr = "";
2802                 }
2803                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2804         }
2805
2806         string fullmsgstr = msgstr;
2807         string fullcmsgstr = cmsgstr;
2808
2809         // FLOOD CONTROL
2810         int flood = 0;
2811         var .float flood_field = floodcontrol_chat;
2812         if(floodcontrol && source)
2813         {
2814                 float flood_spl;
2815                 float flood_burst;
2816                 float flood_lmax;
2817                 float lines;
2818                 if(privatesay)
2819                 {
2820                         flood_spl = autocvar_g_chat_flood_spl_tell;
2821                         flood_burst = autocvar_g_chat_flood_burst_tell;
2822                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2823                         flood_field = floodcontrol_chattell;
2824                 }
2825                 else if(teamsay)
2826                 {
2827                         flood_spl = autocvar_g_chat_flood_spl_team;
2828                         flood_burst = autocvar_g_chat_flood_burst_team;
2829                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2830                         flood_field = floodcontrol_chatteam;
2831                 }
2832                 else
2833                 {
2834                         flood_spl = autocvar_g_chat_flood_spl;
2835                         flood_burst = autocvar_g_chat_flood_burst;
2836                         flood_lmax = autocvar_g_chat_flood_lmax;
2837                         flood_field = floodcontrol_chat;
2838                 }
2839                 flood_burst = max(0, flood_burst - 1);
2840                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2841
2842                 // do flood control for the default line size
2843                 if(msgstr != "")
2844                 {
2845                         getWrappedLine_remaining = msgstr;
2846                         msgstr = "";
2847                         lines = 0;
2848                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2849                         {
2850                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2851                                 ++lines;
2852                         }
2853                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2854
2855                         if(getWrappedLine_remaining != "")
2856                         {
2857                                 msgstr = strcat(msgstr, "\n");
2858                                 flood = 2;
2859                         }
2860
2861                         if (time >= source.(flood_field))
2862                         {
2863                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2864                         }
2865                         else
2866                         {
2867                                 flood = 1;
2868                                 msgstr = fullmsgstr;
2869                         }
2870                 }
2871                 else
2872                 {
2873                         if (time >= source.(flood_field))
2874                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2875                         else
2876                                 flood = 1;
2877                 }
2878
2879                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2880                         source.(flood_field) = flood = 0;
2881         }
2882
2883         string sourcemsgstr, sourcecmsgstr;
2884         if(flood == 2) // cannot happen for empty msgstr
2885         {
2886                 if(autocvar_g_chat_flood_notify_flooder)
2887                 {
2888                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2889                         sourcecmsgstr = "";
2890                 }
2891                 else
2892                 {
2893                         sourcemsgstr = fullmsgstr;
2894                         sourcecmsgstr = fullcmsgstr;
2895                 }
2896                 cmsgstr = "";
2897         }
2898         else
2899         {
2900                 sourcemsgstr = msgstr;
2901                 sourcecmsgstr = cmsgstr;
2902         }
2903
2904         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2905         {
2906                 if (!game_stopped)
2907                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2908                         teamsay = -1; // spectators
2909         }
2910
2911         if(flood)
2912                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2913
2914         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2915         if(privatesay)
2916                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2917
2918         int ret;
2919         if(source && CS(source).muted)
2920         {
2921                 // always fake the message
2922                 ret = -1;
2923         }
2924         else if(flood == 1)
2925         {
2926                 if (autocvar_g_chat_flood_notify_flooder)
2927                 {
2928                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2929                         ret = 0;
2930                 }
2931                 else
2932                         ret = -1;
2933         }
2934         else
2935         {
2936                 ret = 1;
2937         }
2938
2939         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2940         {
2941                 if (!game_stopped)
2942                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2943                         ret = -1; // just hide the message completely
2944         }
2945
2946         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2947         ret = M_ARGV(1, int);
2948
2949         string event_log_msg = "";
2950
2951         if(sourcemsgstr != "" && ret != 0)
2952         {
2953                 if(ret < 0) // faked message, because the player is muted
2954                 {
2955                         sprint(source, sourcemsgstr);
2956                         if(sourcecmsgstr != "" && !privatesay)
2957                                 centerprint(source, sourcecmsgstr);
2958                 }
2959                 else if(privatesay) // private message, between 2 people only
2960                 {
2961                         sprint(source, sourcemsgstr);
2962                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2963                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2964                         {
2965                                 sprint(privatesay, msgstr);
2966                                 if(cmsgstr != "")
2967                                         centerprint(privatesay, cmsgstr);
2968                         }
2969                 }
2970                 else if ( teamsay && CS(source).active_minigame )
2971                 {
2972                         sprint(source, sourcemsgstr);
2973                         dedicated_print(msgstr); // send to server console too
2974                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2975                                 sprint(it, msgstr);
2976                         });
2977                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
2978
2979                 }
2980                 else if(teamsay > 0) // team message, only sent to team mates
2981                 {
2982                         sprint(source, sourcemsgstr);
2983                         dedicated_print(msgstr); // send to server console too
2984                         if(sourcecmsgstr != "")
2985                                 centerprint(source, sourcecmsgstr);
2986                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2987                                 sprint(it, msgstr);
2988                                 if(cmsgstr != "")
2989                                         centerprint(it, cmsgstr);
2990                         });
2991                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
2992                 }
2993                 else if(teamsay < 0) // spectator message, only sent to spectators
2994                 {
2995                         sprint(source, sourcemsgstr);
2996                         dedicated_print(msgstr); // send to server console too
2997                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2998                                 sprint(it, msgstr);
2999                         });
3000                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3001                 }
3002                 else
3003                 {
3004                         if (source) {
3005                                 sprint(source, sourcemsgstr);
3006                                 dedicated_print(msgstr); // send to server console too
3007                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3008                         }
3009                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3010                                 sprint(it, msgstr);
3011                         });
3012                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3013                 }
3014         }
3015
3016         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3017                 GameLogEcho(event_log_msg);
3018         }
3019
3020         return ret;
3021 }
3022
3023 // hack to copy the button fields from the client entity to the Client State
3024 void PM_UpdateButtons(entity this, entity store)
3025 {
3026         if(this.impulse)
3027                 store.impulse = this.impulse;
3028         this.impulse = 0;
3029
3030         bool typing = this.buttonchat || this.button14;
3031
3032         store.button0 = (typing) ? 0 : this.button0;
3033         //button1?!
3034         store.button2 = (typing) ? 0 : this.button2;
3035         store.button3 = (typing) ? 0 : this.button3;
3036         store.button4 = this.button4;
3037         store.button5 = (typing) ? 0 : this.button5;
3038         store.button6 = this.button6;
3039         store.button7 = this.button7;
3040         store.button8 = this.button8;
3041         store.button9 = this.button9;
3042         store.button10 = this.button10;
3043         store.button11 = this.button11;
3044         store.button12 = this.button12;
3045         store.button13 = this.button13;
3046         store.button14 = this.button14;
3047         store.button15 = this.button15;
3048         store.button16 = this.button16;
3049         store.buttonuse = this.buttonuse;
3050         store.buttonchat = this.buttonchat;
3051
3052         store.cursor_active = this.cursor_active;
3053         store.cursor_screen = this.cursor_screen;
3054         store.cursor_trace_start = this.cursor_trace_start;
3055         store.cursor_trace_endpos = this.cursor_trace_endpos;
3056         store.cursor_trace_ent = this.cursor_trace_ent;
3057
3058         store.ping = this.ping;
3059         store.ping_packetloss = this.ping_packetloss;
3060         store.ping_movementloss = this.ping_movementloss;
3061
3062         store.v_angle = this.v_angle;
3063         store.movement = (typing) ? '0 0 0' : this.movement;
3064 }
3065
3066 NET_HANDLE(fpsreport, bool)
3067 {
3068         int fps = ReadShort();
3069         PlayerScore_Set(sender, SP_FPS, fps);
3070         return true;
3071 }