qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         bool recount_ready = false;
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         this.ready = false;
 257                         recount_ready = true;
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         if (use_spawnpoint)
 263         {
 264                 entity spot = SelectSpawnPoint(this, true);
 265                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 266                 this.angles = vec2(spot.angles);
 267                 // offset it so that the spectator spawns higher off the ground, looks better this way
 268                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 269         }
 270         else // change origin to restore previous view origin
 271                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 272         this.fixangle = true;
 273
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         TRANSMUTE(Observer, this);
 307
 308         if(recount_ready) ReadyCount();
 309
 310         WaypointSprite_PlayerDead(this);
 311         accuracy_resend(this);
 312
 313         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 314                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         player_powerups_remove_all(this);
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 605                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 606
 607         this.items = start_items;
 608
 609         float shieldtime = time + autocvar_g_spawnshieldtime;
 610
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 shieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 632         this.fade_time = 0;
 633         this.pain_finished = 0;
 634         this.pushltime = 0;
 635         setthink(this, func_null); // players have no think function
 636         this.nextthink = 0;
 637         this.dmg_team = 0;
 638         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 639
 640         this.deadflag = DEAD_NO;
 641
 642         this.angles = spot.angles;
 643         this.angles_z = 0; // never spawn tilted even if the spot says to
 644         if (IS_BOT_CLIENT(this))
 645         {
 646                 this.v_angle = this.angles;
 647                 bot_aim_reset(this);
 648         }
 649         this.fixangle = true; // turn this way immediately
 650         this.oldvelocity = this.velocity = '0 0 0';
 651         this.avelocity = '0 0 0';
 652         this.punchangle = '0 0 0';
 653         this.punchvector = '0 0 0';
 654
 655         STAT(REVIVE_PROGRESS, this) = 0;
 656         this.revival_time = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         {
 765                 string s = spot.target;
 766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 767                         spot.target = string_null;
 768                 SUB_UseTargets(spot, this, NULL);
 769                 if(g_assault || g_race)
 770                         spot.target = s;
 771         }
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 entity w_ent = this.(weaponentity);
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         w_ent.m_switchweapon = WEP_Null;
 787                 w_ent.m_weapon = WEP_Null;
 788                 w_ent.weaponname = "";
 789                 w_ent.m_switchingweapon = WEP_Null;
 790                 w_ent.cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false, use_spawnpoint);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 string GetClientVersionMessage(entity this)
1022 {
1023         if (CS(this).version_mismatch) {
1024                 if(CS(this).version < autocvar_gameversion) {
1025                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1026                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1027                 } else {
1028                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1029                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1030                 }
1031         } else {
1032                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1033         }
1034 }
1035
1036 void SendWelcomemessage(entity this, bool force_centerprint)
1037 {
1038         msg_entity = this;
1039         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1040         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1041 }
1042
1043 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1044 {
1045         WriteByte(msg_type, boolean(autocvar_g_campaign));
1046         if (boolean(autocvar_g_campaign))
1047         {
1048                 WriteString(msg_type, Campaign_GetTitle());
1049                 WriteByte(msg_type, Campaign_GetLevelNum());
1050                 WriteString(msg_type, Campaign_GetMessage());
1051                 return;
1052         }
1053         WriteByte(msg_type, force_centerprint);
1054         WriteString(msg_type, autocvar_hostname);
1055         WriteString(msg_type, GetClientVersionMessage(this));
1056
1057         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1058         string modifications = M_ARGV(0, string);
1059
1060         if(g_weaponarena)
1061         {
1062                 if(g_weaponarena_random)
1063                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1064                 else
1065                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1066         }
1067         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1068                 modifications = strcat(modifications, ", No start weapons");
1069         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1070                 modifications = strcat(modifications, ", Low gravity");
1071         if(g_weapon_stay && !g_cts)
1072                 modifications = strcat(modifications, ", Weapons stay");
1073         if(autocvar_g_jetpack)
1074                 modifications = strcat(modifications, ", Jet pack");
1075         modifications = substring(modifications, 2, strlen(modifications) - 2);
1076
1077         WriteString(msg_type, modifications);
1078
1079         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1080         {
1081                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1082                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1083         }
1084
1085         WriteString(msg_type, cache_mutatormsg);
1086
1087         string mutator_msg = "";
1088         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1089         mutator_msg = M_ARGV(0, string);
1090
1091         WriteString(msg_type, mutator_msg); // trust that the mutator will do proper formatting
1092         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1093 }
1094
1095 /**
1096 =============
1097 ClientConnect
1098
1099 Called when a client connects to the server
1100 =============
1101 */
1102 void ClientConnect(entity this)
1103 {
1104         if (Ban_MaybeEnforceBanOnce(this)) return;
1105         assert(!IS_CLIENT(this), return);
1106         this.flags |= FL_CLIENT;
1107         assert(player_count >= 0, player_count = 0);
1108
1109         TRANSMUTE(Client, this);
1110         CS(this).version_nagtime = time + 10 + random() * 10;
1111
1112         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1113
1114         bot_clientconnect(this);
1115
1116         Player_DetermineForcedTeam(this);
1117
1118         TRANSMUTE(Observer, this);
1119
1120         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1121
1122         // always track bots, don't ask for cl_allow_uidtracking
1123         if (IS_BOT_CLIENT(this))
1124                 PlayerStats_GameReport_AddPlayer(this);
1125         else
1126                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1127
1128         if (autocvar_sv_eventlog)
1129                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1130
1131         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1132
1133         stuffcmd(this, clientstuff, "\n");
1134         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1135
1136         FixClientCvars(this);
1137
1138         // get version info from player
1139         stuffcmd(this, "cmd clientversion $gameversion\n");
1140
1141         // notify about available teams
1142         if (teamplay)
1143         {
1144                 entity balance = TeamBalance_CheckAllowedTeams(this);
1145                 int t = TeamBalance_GetAllowedTeams(balance);
1146                 TeamBalance_Destroy(balance);
1147                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1148         }
1149         else
1150         {
1151                 stuffcmd(this, "set _teams_available 0\n");
1152         }
1153
1154         bot_relinkplayerlist();
1155
1156         CS(this).spectatortime = time;
1157         if (blockSpectators)
1158         {
1159                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1160         }
1161
1162         CS(this).jointime = time;
1163
1164         if (IS_REAL_CLIENT(this))
1165         {
1166                 if (g_weaponarena_weapons == WEPSET(TUBA))
1167                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1168         }
1169
1170         if (!autocvar_sv_foginterval && world.fog != "")
1171                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1172
1173         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1174                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1175                         send_CSQC_teamnagger();
1176
1177         CSQCMODEL_AUTOINIT(this);
1178
1179         CS(this).model_randomizer = random();
1180
1181         if (IS_REAL_CLIENT(this))
1182                 sv_notice_join(this);
1183
1184         this.move_qcphysics = autocvar_sv_qcphysics;
1185
1186         // update physics stats (players can spawn before physics runs)
1187         Physics_UpdateStats(this);
1188
1189         IL_EACH(g_initforplayer, it.init_for_player, {
1190                 it.init_for_player(it, this);
1191         });
1192
1193         Handicap_Initialize(this);
1194
1195         MUTATOR_CALLHOOK(ClientConnect, this);
1196
1197         if (player_count == 1)
1198                 localcmd("\nsv_hook_firstjoin\n");
1199
1200         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1201                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1202 }
1203 /*
1204 =============
1205 ClientDisconnect
1206
1207 Called when a client disconnects from the server
1208 =============
1209 */
1210 .entity chatbubbleentity;
1211 void player_powerups_remove_all(entity this);
1212
1213 void ClientDisconnect(entity this)
1214 {
1215         assert(IS_CLIENT(this), return);
1216
1217         PlayerStats_GameReport_FinalizePlayer(this);
1218         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1219         if (CS(this).active_minigame) part_minigame(this);
1220         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1221
1222         if (autocvar_sv_eventlog)
1223                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1224
1225         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1226
1227         if(IS_SPEC(this))
1228                 SetSpectatee(this, NULL);
1229
1230         MUTATOR_CALLHOOK(ClientDisconnect, this);
1231
1232         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1233         strfree(CS_CVAR(this).weaponorder_byimpulse);
1234         ClientState_detach(this);
1235
1236         Portal_ClearAll(this);
1237
1238         Unfreeze(this, false);
1239
1240         RemoveGrapplingHooks(this);
1241
1242         // Here, everything has been done that requires this player to be a client.
1243
1244         this.flags &= ~FL_CLIENT;
1245
1246         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1247         if (this.killindicator) delete(this.killindicator);
1248
1249         IL_EACH(g_counters, it.realowner == this,
1250         {
1251                 delete(it);
1252         });
1253
1254         WaypointSprite_PlayerGone(this);
1255
1256         bot_relinkplayerlist();
1257
1258         strfree(this.clientstatus);
1259         if (this.personal) delete(this.personal);
1260
1261         this.playerid = 0;
1262         ReadyCount();
1263         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1264
1265         player_powerups_remove_all(this); // stop powerup sound
1266
1267         ONREMOVE(this);
1268
1269         if (player_count == 0)
1270                 localcmd("\nsv_hook_lastleave\n");
1271 }
1272
1273 void ChatBubbleThink(entity this)
1274 {
1275         this.nextthink = time;
1276         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1277         {
1278                 if(this.owner) // but why can that ever be NULL?
1279                         this.owner.chatbubbleentity = NULL;
1280                 delete(this);
1281                 return;
1282         }
1283
1284         this.mdl = "";
1285
1286         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1287         {
1288                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1289                         this.mdl = "models/sprites/minigame_busy.iqm";
1290                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1291                         this.mdl = "models/misc/chatbubble.spr";
1292         }
1293
1294         if ( this.model != this.mdl )
1295                 _setmodel(this, this.mdl);
1296
1297 }
1298
1299 void UpdateChatBubble(entity this)
1300 {
1301         if (this.alpha < 0)
1302                 return;
1303         // spawn a chatbubble entity if needed
1304         if (!this.chatbubbleentity)
1305         {
1306                 this.chatbubbleentity = new(chatbubbleentity);
1307                 this.chatbubbleentity.owner = this;
1308                 this.chatbubbleentity.exteriormodeltoclient = this;
1309                 setthink(this.chatbubbleentity, ChatBubbleThink);
1310                 this.chatbubbleentity.nextthink = time;
1311                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1312                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1313                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1314                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1315                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1316                 //this.chatbubbleentity.model = "";
1317                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1318         }
1319 }
1320
1321 void calculate_player_respawn_time(entity this)
1322 {
1323         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1324                 return;
1325
1326         float gametype_setting_tmp;
1327         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1328         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1329         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1330         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1331         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1332         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1333
1334         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1335         if (teamplay)
1336         {
1337                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1338                         if(it.team == this.team)
1339                                 ++pcount;
1340                 });
1341                 if (sdelay_small_count == 0)
1342                         sdelay_small_count = 1;
1343                 if (sdelay_large_count == 0)
1344                         sdelay_large_count = 1;
1345         }
1346         else
1347         {
1348                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1349                         ++pcount;
1350                 });
1351                 if (sdelay_small_count == 0)
1352                 {
1353                         if (IS_INDEPENDENT_PLAYER(this))
1354                         {
1355                                 // Players play independently. No point in requiring enemies.
1356                                 sdelay_small_count = 1;
1357                         }
1358                         else
1359                         {
1360                                 // Players play AGAINST each other. Enemies required.
1361                                 sdelay_small_count = 2;
1362                         }
1363                 }
1364                 if (sdelay_large_count == 0)
1365                 {
1366                         if (IS_INDEPENDENT_PLAYER(this))
1367                         {
1368                                 // Players play independently. No point in requiring enemies.
1369                                 sdelay_large_count = 1;
1370                         }
1371                         else
1372                         {
1373                                 // Players play AGAINST each other. Enemies required.
1374                                 sdelay_large_count = 2;
1375                         }
1376                 }
1377         }
1378
1379         float sdelay;
1380
1381         if (pcount <= sdelay_small_count)
1382                 sdelay = sdelay_small;
1383         else if (pcount >= sdelay_large_count)
1384                 sdelay = sdelay_large;
1385         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1386                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1387
1388         if(waves)
1389                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1390         else
1391                 this.respawn_time = time + sdelay;
1392
1393         if(sdelay < sdelay_max)
1394                 this.respawn_time_max = time + sdelay_max;
1395         else
1396                 this.respawn_time_max = this.respawn_time;
1397
1398         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1399                 this.respawn_countdown = 10; // first number to count down from is 10
1400         else
1401                 this.respawn_countdown = -1; // do not count down
1402
1403         if(autocvar_g_forced_respawn)
1404                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1405 }
1406
1407 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1408 // added to the model skins
1409 /*void UpdateColorModHack()
1410 {
1411         float c;
1412         c = this.clientcolors & 15;
1413         // LordHavoc: only bothering to support white, green, red, yellow, blue
1414              if (!teamplay) this.colormod = '0 0 0';
1415         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1416         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1417         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1418         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1419         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1420         else this.colormod = '1 1 1';
1421 }*/
1422
1423 void respawn(entity this)
1424 {
1425         bool damagedbycontents_prev = this.damagedbycontents;
1426         if(this.alpha >= 0)
1427         {
1428                 if(autocvar_g_respawn_ghosts)
1429                 {
1430                         this.solid = SOLID_NOT;
1431                         this.takedamage = DAMAGE_NO;
1432                         this.damagedbycontents = false;
1433                         set_movetype(this, MOVETYPE_FLY);
1434                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1435                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1436                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1437                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1438                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1439                         if(autocvar_g_respawn_ghosts_time > 0)
1440                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1441                 }
1442                 else
1443                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1444         }
1445
1446         CopyBody(this, 1);
1447         this.damagedbycontents = damagedbycontents_prev;
1448
1449         this.effects |= EF_NODRAW; // prevent another CopyBody
1450         PutClientInServer(this);
1451 }
1452
1453 void play_countdown(entity this, float finished, Sound samp)
1454 {
1455         TC(Sound, samp);
1456         float time_left = finished - time;
1457         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1458                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1459 }
1460
1461 // it removes special powerups not handled by StatusEffects
1462 void player_powerups_remove_all(entity this)
1463 {
1464         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1465         {
1466                 // don't play the poweroff sound when the game restarts or the player disconnects
1467                 if (time > game_starttime + 1 && IS_CLIENT(this)
1468                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1469                 {
1470                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1471                 }
1472                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1473                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1474                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1475         }
1476 }
1477
1478 void player_powerups(entity this)
1479 {
1480         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1481                 this.modelflags |= MF_ROCKET;
1482         else
1483                 this.modelflags &= ~MF_ROCKET;
1484
1485         this.effects &= ~EF_NODEPTHTEST;
1486
1487         if (IS_DEAD(this))
1488                 player_powerups_remove_all(this);
1489
1490         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1491                 return;
1492
1493         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1494         int items_prev = this.items;
1495
1496         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1497         {
1498                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1499                 if (this.items & IT_SUPERWEAPON)
1500                 {
1501                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1502                         {
1503                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1504                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1505                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1506                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1507                         }
1508                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1509                         {
1510                                 // don't let them run out
1511                         }
1512                         else
1513                         {
1514                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1515                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1516                                 {
1517                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1518                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1519                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1520                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1521                                 }
1522                         }
1523                 }
1524                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1525                 {
1526                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1527                         {
1528                                 this.items = this.items | IT_SUPERWEAPON;
1529                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1530                                 {
1531                                         if(!g_cts)
1532                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1533                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1534                                 }
1535                         }
1536                         else
1537                         {
1538                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1539                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1540                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1541                         }
1542                 }
1543                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1544                 {
1545                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1546                 }
1547         }
1548
1549         if(autocvar_g_nodepthtestplayers)
1550                 this.effects = this.effects | EF_NODEPTHTEST;
1551
1552         if(autocvar_g_fullbrightplayers)
1553                 this.effects = this.effects | EF_FULLBRIGHT;
1554
1555         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1556 }
1557
1558 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1559 {
1560         if(current > stable)
1561                 return current;
1562         else if(current > stable - 0.25) // when close enough, "snap"
1563                 return stable;
1564         else
1565                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1566 }
1567
1568 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1569 {
1570         if(current < stable)
1571                 return current;
1572         else if(current < stable + 0.25) // when close enough, "snap"
1573                 return stable;
1574         else
1575                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1576 }
1577
1578 void RotRegen(entity this, Resource res, float limit_mod,
1579         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1580         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1581 {
1582         float old = GetResource(this, res);
1583         float current = old;
1584         if(current > rotstable)
1585         {
1586                 if(rotframetime > 0)
1587                 {
1588                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1589                         current = max(rotstable, current - rotlinear * rotframetime);
1590                 }
1591         }
1592         else if(current < regenstable)
1593         {
1594                 if(regenframetime > 0)
1595                 {
1596                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1597                         current = min(regenstable, current + regenlinear * regenframetime);
1598                 }
1599         }
1600
1601         float limit = GetResourceLimit(this, res) * limit_mod;
1602         if(current > limit)
1603                 current = limit;
1604
1605         if (current != old)
1606                 SetResource(this, res, current);
1607 }
1608
1609 void player_regen(entity this)
1610 {
1611         float max_mod, regen_mod, rot_mod, limit_mod;
1612         max_mod = regen_mod = rot_mod = limit_mod = 1;
1613
1614         float regen_health = autocvar_g_balance_health_regen;
1615         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1616         float regen_health_rot = autocvar_g_balance_health_rot;
1617         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1618         float regen_health_stable = autocvar_g_balance_health_regenstable;
1619         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1620         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1621                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1622         max_mod = M_ARGV(1, float);
1623         regen_mod = M_ARGV(2, float);
1624         rot_mod = M_ARGV(3, float);
1625         limit_mod = M_ARGV(4, float);
1626         regen_health = M_ARGV(5, float);
1627         regen_health_linear = M_ARGV(6, float);
1628         regen_health_rot = M_ARGV(7, float);
1629         regen_health_rotlinear = M_ARGV(8, float);
1630         regen_health_stable = M_ARGV(9, float);
1631         regen_health_rotstable = M_ARGV(10, float);
1632
1633         float rotstable, regenstable, rotframetime, regenframetime;
1634
1635         if(!mutator_returnvalue)
1636         if(!STAT(FROZEN, this))
1637         {
1638                 regenstable = autocvar_g_balance_armor_regenstable;
1639                 rotstable = autocvar_g_balance_armor_rotstable;
1640                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1641                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1642                 RotRegen(this, RES_ARMOR, limit_mod,
1643                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1644                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1645
1646                 // NOTE: max_mod is only applied to health
1647                 regenstable = regen_health_stable * max_mod;
1648                 rotstable = regen_health_rotstable * max_mod;
1649                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1650                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1651                 RotRegen(this, RES_HEALTH, limit_mod,
1652                         regenstable, regen_health, regen_health_linear, regenframetime,
1653                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1654         }
1655
1656         // if player rotted to death...  die!
1657         // check this outside above checks, as player may still be able to rot to death
1658         if(GetResource(this, RES_HEALTH) < 1)
1659         {
1660                 if(this.vehicle)
1661                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1662                 if(this.event_damage)
1663                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1664         }
1665
1666         if (!(this.items & IT_UNLIMITED_AMMO))
1667         {
1668                 regenstable = autocvar_g_balance_fuel_regenstable;
1669                 rotstable = autocvar_g_balance_fuel_rotstable;
1670                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1671                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1672                 RotRegen(this, RES_FUEL, 1,
1673                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1674                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1675         }
1676 }
1677
1678 bool zoomstate_set;
1679 void SetZoomState(entity this, float newzoom)
1680 {
1681         if(newzoom != CS(this).zoomstate)
1682         {
1683                 CS(this).zoomstate = newzoom;
1684                 ClientData_Touch(this);
1685         }
1686         zoomstate_set = true;
1687 }
1688
1689 void GetPressedKeys(entity this)
1690 {
1691         MUTATOR_CALLHOOK(GetPressedKeys, this);
1692         if (game_stopped)
1693         {
1694                 CS(this).pressedkeys = 0;
1695                 STAT(PRESSED_KEYS, this) = 0;
1696                 return;
1697         }
1698
1699         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1700         int keys = STAT(PRESSED_KEYS, this);
1701         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1702         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1703         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1704         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1705
1706         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1707         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1708         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1709         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1710         CS(this).pressedkeys = keys; // store for other users
1711
1712         STAT(PRESSED_KEYS, this) = keys;
1713 }
1714
1715 /*
1716 ======================
1717 spectate mode routines
1718 ======================
1719 */
1720
1721 void SpectateCopy(entity this, entity spectatee)
1722 {
1723         TC(Client, this); TC(Client, spectatee);
1724
1725         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1726         PS(this) = PS(spectatee);
1727         this.armortype = spectatee.armortype;
1728         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1729         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1730         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1731         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1732         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1733         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1734         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1735         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1736         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1737         CS(this).impulse = 0;
1738         this.disableclientprediction = 1; // no need to run prediction on a spectator
1739         this.items = spectatee.items;
1740         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1741         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1742         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1743         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1744         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1745         this.punchangle = spectatee.punchangle;
1746         this.view_ofs = spectatee.view_ofs;
1747         this.velocity = spectatee.velocity;
1748         this.dmg_take = spectatee.dmg_take;
1749         this.dmg_save = spectatee.dmg_save;
1750         this.dmg_inflictor = spectatee.dmg_inflictor;
1751         this.v_angle = spectatee.v_angle;
1752         this.angles = spectatee.v_angle;
1753         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1754         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1755         this.viewloc = spectatee.viewloc;
1756         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1757                 this.fixangle = true;
1758         setorigin(this, spectatee.origin);
1759         setsize(this, spectatee.mins, spectatee.maxs);
1760         SetZoomState(this, CS(spectatee).zoomstate);
1761
1762     anticheat_spectatecopy(this, spectatee);
1763         STAT(HUD, this) = STAT(HUD, spectatee);
1764         if(spectatee.vehicle)
1765     {
1766         this.angles = spectatee.v_angle;
1767
1768         //this.fixangle = false;
1769         //this.velocity = spectatee.vehicle.velocity;
1770         this.vehicle_health = spectatee.vehicle_health;
1771         this.vehicle_shield = spectatee.vehicle_shield;
1772         this.vehicle_energy = spectatee.vehicle_energy;
1773         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1774         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1775         this.vehicle_reload1 = spectatee.vehicle_reload1;
1776         this.vehicle_reload2 = spectatee.vehicle_reload2;
1777
1778         //msg_entity = this;
1779
1780        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1781             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1782            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1783            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1784
1785         //WriteByte (MSG_ONE, SVC_SETVIEW);
1786         //    WriteEntity(MSG_ONE, this);
1787         //makevectors(spectatee.v_angle);
1788         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1789     }
1790 }
1791
1792 bool SpectateUpdate(entity this)
1793 {
1794         if(!this.enemy)
1795                 return false;
1796
1797         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1798         {
1799                 SetSpectatee(this, NULL);
1800                 return false;
1801         }
1802
1803         SpectateCopy(this, this.enemy);
1804
1805         return true;
1806 }
1807
1808 bool SpectateSet(entity this)
1809 {
1810         if(!IS_PLAYER(this.enemy))
1811                 return false;
1812
1813         ClientData_Touch(this.enemy);
1814
1815         msg_entity = this;
1816         WriteByte(MSG_ONE, SVC_SETVIEW);
1817         WriteEntity(MSG_ONE, this.enemy);
1818         set_movetype(this, MOVETYPE_NONE);
1819         accuracy_resend(this);
1820
1821         if(!SpectateUpdate(this))
1822                 PutObserverInServer(this, false, true);
1823
1824         return true;
1825 }
1826
1827 void SetSpectatee_status(entity this, int spectatee_num)
1828 {
1829         int oldspectatee_status = CS(this).spectatee_status;
1830         CS(this).spectatee_status = spectatee_num;
1831
1832         if (CS(this).spectatee_status != oldspectatee_status)
1833         {
1834                 if (STAT(PRESSED_KEYS, this))
1835                 {
1836                         CS(this).pressedkeys = 0;
1837                         STAT(PRESSED_KEYS, this) = 0;
1838                 }
1839                 ClientData_Touch(this);
1840                 if (g_race || g_cts) race_InitSpectator();
1841         }
1842 }
1843
1844 void SetSpectatee(entity this, entity spectatee)
1845 {
1846         if(IS_BOT_CLIENT(this))
1847                 return; // bots abuse .enemy, this code is useless to them
1848
1849         entity old_spectatee = this.enemy;
1850
1851         this.enemy = spectatee;
1852
1853         // WEAPONTODO
1854         // these are required to fix the spectator bug with arc
1855         if(old_spectatee)
1856         {
1857                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1858                 {
1859                         .entity weaponentity = weaponentities[slot];
1860                         if(old_spectatee.(weaponentity).arc_beam)
1861                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1862                 }
1863         }
1864         if(spectatee)
1865         {
1866                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1867                 {
1868                         .entity weaponentity = weaponentities[slot];
1869                         if(spectatee.(weaponentity).arc_beam)
1870                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1871                 }
1872         }
1873
1874         if (spectatee)
1875                 SetSpectatee_status(this, etof(spectatee));
1876
1877         // needed to update spectator list
1878         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1879 }
1880
1881 bool Spectate(entity this, entity pl)
1882 {
1883         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1884                 return false;
1885         pl = M_ARGV(1, entity);
1886
1887         SetSpectatee(this, pl);
1888         return SpectateSet(this);
1889 }
1890
1891 bool SpectateNext(entity this)
1892 {
1893         entity ent = find(this.enemy, classname, STR_PLAYER);
1894
1895         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1896                 ent = M_ARGV(1, entity);
1897         else if (!ent)
1898                 ent = find(ent, classname, STR_PLAYER);
1899
1900         if(ent) { SetSpectatee(this, ent); }
1901
1902         return SpectateSet(this);
1903 }
1904
1905 bool SpectatePrev(entity this)
1906 {
1907         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1908         entity ent = findchain(classname, STR_PLAYER);
1909         if (!ent) // no player
1910                 return false;
1911
1912         entity first = ent;
1913         // skip players until current spectated player
1914         if(this.enemy)
1915         while(ent && ent != this.enemy)
1916                 ent = ent.chain;
1917
1918         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1919         {
1920                 case MUT_SPECPREV_FOUND:
1921                         ent = M_ARGV(1, entity);
1922                         break;
1923                 case MUT_SPECPREV_RETURN:
1924                         return true;
1925                 case MUT_SPECPREV_CONTINUE:
1926                 default:
1927                 {
1928                         if(ent.chain)
1929                                 ent = ent.chain;
1930                         else
1931                                 ent = first;
1932                         break;
1933                 }
1934         }
1935
1936         SetSpectatee(this, ent);
1937         return SpectateSet(this);
1938 }
1939
1940 /*
1941 =============
1942 ShowRespawnCountdown()
1943
1944 Update a respawn countdown display.
1945 =============
1946 */
1947 void ShowRespawnCountdown(entity this)
1948 {
1949         float number;
1950         if(!IS_DEAD(this)) // just respawned?
1951                 return;
1952         else
1953         {
1954                 number = ceil(this.respawn_time - time);
1955                 if(number <= 0)
1956                         return;
1957                 if(number <= this.respawn_countdown)
1958                 {
1959                         this.respawn_countdown = number - 1;
1960                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1961                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1962                 }
1963         }
1964 }
1965
1966 .bool team_selected;
1967 bool ShowTeamSelection(entity this)
1968 {
1969         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1970                 return false;
1971         stuffcmd(this, "menu_showteamselect\n");
1972         return true;
1973 }
1974 void Join(entity this)
1975 {
1976         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1977                 ReadyRestart(true);
1978
1979         TRANSMUTE(Player, this);
1980
1981         if(!this.team_selected)
1982         if(autocvar_g_campaign || autocvar_g_balance_teams)
1983                 TeamBalance_JoinBestTeam(this);
1984
1985         if(autocvar_g_campaign)
1986                 campaign_bots_may_start = true;
1987
1988         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1989
1990         PutClientInServer(this);
1991
1992         if(IS_PLAYER(this))
1993         if(teamplay && this.team != -1)
1994         {
1995         }
1996         else
1997                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1998         this.team_selected = false;
1999 }
2000
2001 int GetPlayerLimit()
2002 {
2003         if(g_duel)
2004                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2005         int player_limit = autocvar_g_maxplayers;
2006         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2007         player_limit = M_ARGV(0, int);
2008         return player_limit;
2009 }
2010
2011 /**
2012  * Determines whether the player is allowed to join. This depends on cvar
2013  * g_maxplayers, if it isn't used this function always return true, otherwise
2014  * it checks whether the number of currently playing players exceeds g_maxplayers.
2015  * @return int number of free slots for players, 0 if none
2016  */
2017 int nJoinAllowed(entity this, entity ignore)
2018 {
2019         if(!ignore)
2020         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2021         // so report 0 free slots if restricted
2022         {
2023                 if(autocvar_g_forced_team_otherwise == "spectate")
2024                         return 0;
2025                 if(autocvar_g_forced_team_otherwise == "spectator")
2026                         return 0;
2027         }
2028
2029         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2030                 return 0; // forced spectators can never join
2031
2032         // TODO simplify this
2033         int totalClients = 0;
2034         int currentlyPlaying = 0;
2035         FOREACH_CLIENT(true, {
2036                 if(it != ignore)
2037                         ++totalClients;
2038                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2039                         ++currentlyPlaying;
2040         });
2041
2042         int player_limit = GetPlayerLimit();
2043
2044         int free_slots = 0;
2045         if (!player_limit)
2046                 free_slots = maxclients - totalClients;
2047         else if(player_limit > 0 && currentlyPlaying < player_limit)
2048                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2049
2050         static float msg_time = 0;
2051         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2052         {
2053                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2054                 msg_time = time + 0.5;
2055         }
2056
2057         return free_slots;
2058 }
2059
2060 void PrintWelcomeMessage(entity this)
2061 {
2062         if(CS(this).motd_actived_time == 0)
2063         {
2064                 if (autocvar_g_campaign) {
2065                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2066                                 CS(this).motd_actived_time = time;
2067                                 SendWelcomemessage(this, false);
2068                         }
2069                 } else {
2070                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2071                                 CS(this).motd_actived_time = time;
2072                                 SendWelcomemessage(this, true);
2073                         }
2074                 }
2075         }
2076         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2077         {
2078                 if (autocvar_g_campaign) {
2079                         if (PHYS_INPUT_BUTTON_INFO(this))
2080                                 CS(this).motd_actived_time = time;
2081                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2082                                 CS(this).motd_actived_time = 0;
2083                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2084                         }
2085                 } else {
2086                         if (PHYS_INPUT_BUTTON_INFO(this))
2087                                 CS(this).motd_actived_time = time;
2088                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2089                                 CS(this).motd_actived_time = 0;
2090                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2091                         }
2092                 }
2093         }
2094         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2095         {
2096                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2097                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2098                 else if (CS(this).motd_actived_time == -2)
2099                 {
2100                         // instantly hide MOTD
2101                         CS(this).motd_actived_time = 0;
2102                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2103                 }
2104                 else if (IS_PLAYER(this) || IS_SPEC(this))
2105                 {
2106                         // FIXME occasionally for some reason MOTD never goes away
2107                         // delay MOTD removal a little bit in the hope it fixes this bug
2108                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2109                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2110                         else //if (CS(this).motd_actived_time < -2)
2111                                 CS(this).motd_actived_time++;
2112                 }
2113         }
2114 }
2115
2116 bool joinAllowed(entity this)
2117 {
2118         if (CS(this).version_mismatch) return false;
2119         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2120         if (!nJoinAllowed(this, this)) return false;
2121         if (teamplay && lockteams) return false;
2122         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2123         if (ShowTeamSelection(this)) return false;
2124         return true;
2125 }
2126
2127 .string shootfromfixedorigin;
2128 .bool dualwielding_prev;
2129 bool PlayerThink(entity this)
2130 {
2131         if (game_stopped || intermission_running) {
2132                 this.modelflags &= ~MF_ROCKET;
2133                 if(intermission_running)
2134                         IntermissionThink(this);
2135                 return false;
2136         }
2137
2138         if (timeout_status == TIMEOUT_ACTIVE) {
2139                 // don't allow the player to turn around while game is paused
2140                 // FIXME turn this into CSQC stuff
2141                 this.v_angle = this.lastV_angle;
2142                 this.angles = this.lastV_angle;
2143                 this.fixangle = true;
2144         }
2145
2146         if (frametime) player_powerups(this);
2147
2148         if (IS_DEAD(this)) {
2149                 if (this.personal && g_race_qualifying) {
2150                         if (time > this.respawn_time) {
2151                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2152                                 respawn(this);
2153                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2154                         }
2155                 } else {
2156                         if (frametime) player_anim(this);
2157
2158                         if (this.respawn_flags & RESPAWN_DENY)
2159                         {
2160                                 STAT(RESPAWN_TIME, this) = 0;
2161                                 return false;
2162                         }
2163
2164                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2165
2166                         switch(this.deadflag)
2167                         {
2168                                 case DEAD_DYING:
2169                                 {
2170                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2171                                                 this.deadflag = DEAD_RESPAWNING;
2172                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2173                                                 this.deadflag = DEAD_DEAD;
2174                                         break;
2175                                 }
2176                                 case DEAD_DEAD:
2177                                 {
2178                                         if (button_pressed)
2179                                                 this.deadflag = DEAD_RESPAWNABLE;
2180                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2181                                                 this.deadflag = DEAD_RESPAWNING;
2182                                         break;
2183                                 }
2184                                 case DEAD_RESPAWNABLE:
2185                                 {
2186                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2187                                                 this.deadflag = DEAD_RESPAWNING;
2188                                         break;
2189                                 }
2190                                 case DEAD_RESPAWNING:
2191                                 {
2192                                         if (time > this.respawn_time)
2193                                         {
2194                                                 this.respawn_time = time + 1; // only retry once a second
2195                                                 this.respawn_time_max = this.respawn_time;
2196                                                 respawn(this);
2197                                         }
2198                                         break;
2199                                 }
2200                         }
2201
2202                         ShowRespawnCountdown(this);
2203
2204                         if (this.respawn_flags & RESPAWN_SILENT)
2205                                 STAT(RESPAWN_TIME, this) = 0;
2206                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2207                         {
2208                                 if (time < this.respawn_time)
2209                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2210                                 else if (this.deadflag != DEAD_RESPAWNING)
2211                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2212                         }
2213                         else
2214                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2215                 }
2216
2217                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2218                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2219                         STAT(RESPAWN_TIME, this) *= -1;
2220
2221                 return false;
2222         }
2223
2224         FixPlayermodel(this);
2225
2226         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2227                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2228                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2229         }
2230
2231         // reset gun alignment when dual wielding status changes
2232         // to ensure guns are always aligned right and left
2233         bool dualwielding = W_DualWielding(this);
2234         if(this.dualwielding_prev != dualwielding)
2235         {
2236                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2237                 this.dualwielding_prev = dualwielding;
2238         }
2239
2240         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2241         //if(frametime)
2242         {
2243                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2244                 {
2245                         .entity weaponentity = weaponentities[slot];
2246                         if(WEP_CVAR(vortex, charge_always))
2247                                 W_Vortex_Charge(this, weaponentity, frametime);
2248                         W_WeaponFrame(this, weaponentity);
2249                 }
2250         }
2251
2252         if (frametime)
2253         {
2254                 // WEAPONTODO: Add a weapon request for this
2255                 // rot vortex charge to the charge limit
2256                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2257                 {
2258                         .entity weaponentity = weaponentities[slot];
2259                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2260                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2261                 }
2262
2263                 player_regen(this);
2264                 player_anim(this);
2265                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2266         }
2267
2268         monsters_setstatus(this);
2269
2270         return true;
2271 }
2272
2273 .bool would_spectate;
2274 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2275 void ObserverOrSpectatorThink(entity this)
2276 {
2277         bool is_spec = IS_SPEC(this);
2278         if ( CS(this).impulse )
2279         {
2280                 int r = MinigameImpulse(this, CS(this).impulse);
2281                 if (!is_spec || r)
2282                         CS(this).impulse = 0;
2283
2284                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2285                 {
2286                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2287                         CS(this).impulse = 0;
2288                         return;
2289                 }
2290         }
2291
2292         if (this.flags & FL_JUMPRELEASED) {
2293                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2294                         this.flags &= ~FL_JUMPRELEASED;
2295                         this.flags |= FL_SPAWNING;
2296                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2297                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2298                         this.flags &= ~FL_JUMPRELEASED;
2299                         if(SpectateNext(this)) {
2300                                 TRANSMUTE(Spectator, this);
2301                         } else if (is_spec) {
2302                                 TRANSMUTE(Observer, this);
2303                                 PutClientInServer(this);
2304                         }
2305                         else
2306                                 this.would_spectate = false; // unable to spectate anyone
2307                         if (is_spec)
2308                                 CS(this).impulse = 0;
2309                 } else if (is_spec) {
2310                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2311                                 this.flags &= ~FL_JUMPRELEASED;
2312                                 if(SpectatePrev(this)) {
2313                                         TRANSMUTE(Spectator, this);
2314                                 } else {
2315                                         TRANSMUTE(Observer, this);
2316                                         PutClientInServer(this);
2317                                 }
2318                                 CS(this).impulse = 0;
2319                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2320                                 this.would_spectate = false;
2321                                 this.flags &= ~FL_JUMPRELEASED;
2322                                 TRANSMUTE(Observer, this);
2323                                 PutClientInServer(this);
2324                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2325                                 PutObserverInServer(this, false, true);
2326                                 this.would_spectate = true;
2327                         }
2328                 }
2329                 else {
2330                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2331                         if (PHYS_INPUT_BUTTON_USE(this))
2332                                 wouldclip = !wouldclip;
2333                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2334                         set_movetype(this, preferred_movetype);
2335                 }
2336         } else { // jump pressed
2337                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2338                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2339                         this.flags |= FL_JUMPRELEASED;
2340                         if(this.flags & FL_SPAWNING)
2341                         {
2342                                 this.flags &= ~FL_SPAWNING;
2343                                 if(joinAllowed(this))
2344                                         Join(this);
2345                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2346                                         CS(this).autojoin_checked = -1;
2347                                 return;
2348                         }
2349                 }
2350                 if(is_spec && !SpectateUpdate(this))
2351                         PutObserverInServer(this, false, true);
2352         }
2353         if (is_spec)
2354                 this.flags |= FL_CLIENT | FL_NOTARGET;
2355 }
2356
2357 void PlayerUseKey(entity this)
2358 {
2359         if (!IS_PLAYER(this))
2360                 return;
2361
2362         if(this.vehicle)
2363         {
2364                 if(!game_stopped)
2365                 {
2366                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2367                         return;
2368                 }
2369         }
2370         else if(autocvar_g_vehicles_enter)
2371         {
2372                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2373                 {
2374                         entity head, closest_target = NULL;
2375                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2376
2377                         while(head) // find the closest acceptable target to enter
2378                         {
2379                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2380                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2381                                 {
2382                                         if(closest_target)
2383                                         {
2384                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2385                                                 { closest_target = head; }
2386                                         }
2387                                         else { closest_target = head; }
2388                                 }
2389
2390                                 head = head.chain;
2391                         }
2392
2393                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2394                 }
2395         }
2396
2397         // a use key was pressed; call handlers
2398         MUTATOR_CALLHOOK(PlayerUseKey, this);
2399 }
2400
2401
2402 /*
2403 =============
2404 PlayerPreThink
2405
2406 Called every frame for each client before the physics are run
2407 =============
2408 */
2409 .float last_vehiclecheck;
2410 void PlayerPreThink (entity this)
2411 {
2412         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2413         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2414
2415         WarpZone_PlayerPhysics_FixVAngle(this);
2416
2417         if (frametime) {
2418                 // physics frames: update anticheat stuff
2419                 anticheat_prethink(this);
2420
2421                 // WORKAROUND: only use dropclient in server frames (frametime set).
2422                 // Never use it in cl_movement frames (frametime zero).
2423                 if (blockSpectators && IS_REAL_CLIENT(this)
2424                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2425                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2426                 {
2427                         if (dropclient_schedule(this))
2428                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2429                 }
2430         }
2431
2432         zoomstate_set = false;
2433
2434         // Check for nameless players
2435         if (this.netname == "" || this.netname != CS(this).netname_previous)
2436         {
2437                 bool assume_unchanged = (CS(this).netname_previous == "");
2438                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2439                 {
2440                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2441                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2442                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2443                         assume_unchanged = false;
2444                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2445                 }
2446                 if (isInvisibleString(this.netname))
2447                 {
2448                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2449                         sprint(this, "Warning: invisible names are not allowed.\n");
2450                         assume_unchanged = false;
2451                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2452                 }
2453                 if (!assume_unchanged && autocvar_sv_eventlog)
2454                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2455                 strcpy(CS(this).netname_previous, this.netname);
2456         }
2457
2458         // version nagging
2459         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2460         CS(this).version_nagtime = 0;
2461         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2462             // git client
2463         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2464             // git server
2465             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2466         } else {
2467             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2468             if (r < 0) { // old client
2469                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2470             } else if (r > 0) { // old server
2471                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2472             }
2473         }
2474     }
2475
2476         // GOD MODE info
2477         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2478         {
2479                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2480                 this.max_armorvalue = 0;
2481         }
2482
2483         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2484         {
2485                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2486                 {
2487                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2488                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2489                         if (this.iceblock)
2490                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2491
2492                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2493                                 Unfreeze(this, false);
2494                 }
2495                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2496                 {
2497                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2498                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2499
2500                         if (GetResource(this, RES_HEALTH) < 1)
2501                         {
2502                                 if (this.vehicle)
2503                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2504                                 if(this.event_damage)
2505                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2506                         }
2507                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2508                                 Unfreeze(this, false);
2509                 }
2510         }
2511
2512         MUTATOR_CALLHOOK(PlayerPreThink, this);
2513
2514         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2515         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2516         {
2517                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2518                 {
2519                         if(!it.owner)
2520                         {
2521                                 if(!it.team || SAME_TEAM(this, it))
2522                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2523                                 else if(autocvar_g_vehicles_steal)
2524                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2525                         }
2526                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2527                         {
2528                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2529                         }
2530                 });
2531
2532                 this.last_vehiclecheck = time + 1;
2533         }
2534
2535         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2536                 PlayerUseKey(this);
2537         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2538
2539         if (IS_REAL_CLIENT(this))
2540                 PrintWelcomeMessage(this);
2541
2542         if (IS_PLAYER(this)) {
2543                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2544                         error("Client can't be spawned as player on connection!");
2545                 if(!PlayerThink(this))
2546                         return;
2547         }
2548         else if (game_stopped || intermission_running) {
2549                 if(intermission_running)
2550                         IntermissionThink(this);
2551                 return;
2552         }
2553         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2554         {
2555                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2556                 CS(this).autojoin_checked = 1;
2557                 // don't do this in ClientConnect
2558                 // many things can go wrong if a client is spawned as player on connection
2559                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2560                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2561                                 && (!teamplay || autocvar_g_balance_teams)))
2562                 {
2563                         if(joinAllowed(this))
2564                                 Join(this);
2565                         return;
2566                 }
2567         }
2568         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2569                 ObserverOrSpectatorThink(this);
2570         }
2571
2572         // WEAPONTODO: Add weapon request for this
2573         if (!zoomstate_set) {
2574                 bool wep_zoomed = false;
2575                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2576                 {
2577                         .entity weaponentity = weaponentities[slot];
2578                         Weapon thiswep = this.(weaponentity).m_weapon;
2579                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2580                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2581                 }
2582                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2583         }
2584
2585         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2586         {
2587                 CS(this).teamkill_soundtime = 0;
2588
2589                 entity e = CS(this).teamkill_soundsource;
2590                 entity oldpusher = e.pusher;
2591                 e.pusher = this;
2592                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2593                 e.pusher = oldpusher;
2594         }
2595
2596         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2597                 CS(this).taunt_soundtime = 0;
2598                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2599         }
2600
2601         target_voicescript_next(this);
2602 }
2603
2604 void DrownPlayer(entity this)
2605 {
2606         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2607                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2608         {
2609                 STAT(AIR_FINISHED, this) = 0;
2610                 return;
2611         }
2612
2613         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2614         {
2615                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2616                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2617                 STAT(AIR_FINISHED, this) = 0;
2618         }
2619         else
2620         {
2621                 if (!STAT(AIR_FINISHED, this))
2622                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2623                 if (STAT(AIR_FINISHED, this) < time)
2624                 {       // drown!
2625                         if (this.pain_finished < time)
2626                         {
2627                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2628                                 this.pain_finished = time + 0.5;
2629                         }
2630                 }
2631         }
2632 }
2633
2634 .bool move_qcphysics;
2635
2636 void Player_Physics(entity this)
2637 {
2638         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2639
2640         if(!this.move_qcphysics)
2641                 return;
2642
2643         if(!frametime && !CS(this).pm_frametime)
2644                 return;
2645
2646         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2647
2648         CS(this).pm_frametime = 0;
2649 }
2650
2651 /*
2652 =============
2653 PlayerPostThink
2654
2655 Called every frame for each client after the physics are run
2656 =============
2657 */
2658 void PlayerPostThink (entity this)
2659 {
2660         Player_Physics(this);
2661
2662         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2663         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2664         if (IS_REAL_CLIENT(this))
2665         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2666         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2667         {
2668                 int totalClients = 0;
2669                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2670                 {
2671                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2672                         if (server_is_dedicated)
2673                         {
2674                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2675                                 {
2676                                         ++totalClients;
2677                                 });
2678                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2679                                         totalClients = 0;
2680                         }
2681                 }
2682                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2683                 {
2684                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2685                         {
2686                                 ++totalClients;
2687                         });
2688                 }
2689
2690                 if (totalClients < autocvar_sv_maxidle_minplayers)
2691                 {
2692                         // idle kick disabled
2693                         CS(this).parm_idlesince = time;
2694                 }
2695                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2696                 {
2697                         if (CS(this).idlekick_lasttimeleft)
2698                         {
2699                                 CS(this).idlekick_lasttimeleft = 0;
2700                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2701                         }
2702                 }
2703                 else
2704                 {
2705                         float maxidle_time = autocvar_sv_maxidle;
2706                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2707                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2708                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2709                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2710                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2711                         {
2712                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2713                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2714                                 else
2715                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2716                         }
2717                         if (timeleft <= 0) {
2718                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2719                                 {
2720                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2721                                         PutObserverInServer(this, true, true);
2722                                 }
2723                                 else
2724                                 {
2725                                         if (dropclient_schedule(this))
2726                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2727                                 }
2728                                 return;
2729                         }
2730                         else if (timeleft <= countdown_time) {
2731                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2732                                         play2(this, SND(TALK2));
2733                                 CS(this).idlekick_lasttimeleft = timeleft;
2734                         }
2735                 }
2736         }
2737
2738         CheatFrame(this);
2739
2740         if (game_stopped)
2741         {
2742                 this.solid = SOLID_NOT;
2743                 this.takedamage = DAMAGE_NO;
2744                 set_movetype(this, MOVETYPE_NONE);
2745                 CS(this).teamkill_complain = 0;
2746                 CS(this).teamkill_soundtime = 0;
2747                 CS(this).teamkill_soundsource = NULL;
2748         }
2749
2750         if (IS_PLAYER(this)) {
2751                 if(this.death_time == time && IS_DEAD(this))
2752                 {
2753                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2754                         // once all the damage events of this frame have been processed with normal size
2755                         this.maxs.z = 5;
2756                         setsize(this, this.mins, this.maxs);
2757                 }
2758                 DrownPlayer(this);
2759                 UpdateChatBubble(this);
2760                 if (CS(this).impulse) ImpulseCommands(this);
2761                 GetPressedKeys(this);
2762                 if (game_stopped)
2763                 {
2764                         CSQCMODEL_AUTOUPDATE(this);
2765                         return;
2766                 }
2767         }
2768         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2769         {
2770                 CS(this).pressedkeys = 0;
2771                 STAT(PRESSED_KEYS, this) = 0;
2772         }
2773
2774         if (this.waypointsprite_attachedforcarrier) {
2775                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2776                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2777         }
2778
2779         CSQCMODEL_AUTOUPDATE(this);
2780 }
2781
2782 // hack to copy the button fields from the client entity to the Client State
2783 void PM_UpdateButtons(entity this, entity store)
2784 {
2785         if(this.impulse)
2786                 store.impulse = this.impulse;
2787         this.impulse = 0;
2788
2789         bool typing = this.buttonchat || this.button12;
2790
2791         store.button0 = (typing) ? 0 : this.button0;
2792         //button1?!
2793         store.button2 = (typing) ? 0 : this.button2;
2794         store.button3 = (typing) ? 0 : this.button3;
2795         store.button4 = this.button4;
2796         store.button5 = (typing) ? 0 : this.button5;
2797         store.button6 = this.button6;
2798         store.button7 = this.button7;
2799         store.button8 = this.button8;
2800         store.button9 = this.button9;
2801         store.button10 = this.button10;
2802         store.button11 = this.button11;
2803         store.button12 = this.button12;
2804         store.button13 = this.button13;
2805         store.button14 = this.button14;
2806         store.button15 = this.button15;
2807         store.button16 = this.button16;
2808         store.buttonuse = this.buttonuse;
2809         store.buttonchat = this.buttonchat;
2810
2811         store.cursor_active = this.cursor_active;
2812         store.cursor_screen = this.cursor_screen;
2813         store.cursor_trace_start = this.cursor_trace_start;
2814         store.cursor_trace_endpos = this.cursor_trace_endpos;
2815         store.cursor_trace_ent = this.cursor_trace_ent;
2816
2817         store.ping = this.ping;
2818         store.ping_packetloss = this.ping_packetloss;
2819         store.ping_movementloss = this.ping_movementloss;
2820
2821         store.v_angle = this.v_angle;
2822         store.movement = this.movement;
2823 }
2824
2825 NET_HANDLE(fpsreport, bool)
2826 {
2827         int fps = ReadShort();
2828         PlayerScore_Set(sender, SP_FPS, fps);
2829         return true;
2830 }