qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include <common/effects/qc/globalsound.qh>
  36
  37 #include "../common/mapobjects/func/conveyor.qh"
  38 #include "../common/mapobjects/teleporters.qh"
  39 #include "../common/mapobjects/target/spawnpoint.qh"
  40
  41 #include "../common/vehicles/all.qh"
  42
  43 #include "weapons/hitplot.qh"
  44 #include "weapons/weaponsystem.qh"
  45
  46 #include "../common/net_notice.qh"
  47 #include "../common/net_linked.qh"
  48 #include "../common/physics/player.qh"
  49
  50 #include <common/vehicles/sv_vehicles.qh>
  51
  52 #include "../common/items/_mod.qh"
  53
  54 #include "../common/mutators/mutator/waypoints/all.qh"
  55 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  56 #include <common/gamemodes/_mod.qh>
  57
  58 #include "../common/mapobjects/subs.qh"
  59 #include "../common/mapobjects/triggers.qh"
  60 #include "../common/mapobjects/trigger/secret.qh"
  61
  62 #include "../common/minigames/sv_minigames.qh"
  63
  64 #include "../common/items/inventory.qh"
  65
  66 #include "../common/monsters/sv_monsters.qh"
  67
  68 #include "../lib/warpzone/server.qh"
  69
  70 #include <common/mutators/mutator/overkill/oknex.qh>
  71
  72 STATIC_METHOD(Client, Add, void(Client this, int _team))
  73 {
  74     ClientConnect(this);
  75     TRANSMUTE(Player, this);
  76     this.frame = 12; // 7
  77     this.team = _team;
  78     PutClientInServer(this);
  79 }
  80
  81 STATIC_METHOD(Client, Remove, void(Client this))
  82 {
  83     TRANSMUTE(Observer, this);
  84     PutClientInServer(this);
  85     ClientDisconnect(this);
  86 }
  87
  88 void send_CSQC_teamnagger() {
  89         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  90 }
  91
  92 int CountSpectators(entity player, entity to)
  93 {
  94         if(!player) { return 0; } // not sure how, but best to be safe
  95
  96         int spec_count = 0;
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 spec_count++;
 101         });
 102
 103         return spec_count;
 104 }
 105
 106 void WriteSpectators(entity player, entity to)
 107 {
 108         if(!player) { return; } // not sure how, but best to be safe
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 WriteByte(MSG_ENTITY, num_for_edict(it));
 113         });
 114 }
 115
 116 bool ClientData_Send(entity this, entity to, int sf)
 117 {
 118         assert(to == this.owner, return false);
 119
 120         entity e = to;
 121         if (IS_SPEC(e)) e = e.enemy;
 122
 123         sf = 0;
 124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 128
 129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 130         WriteByte(MSG_ENTITY, sf);
 131
 132         if (sf & BIT(1))
 133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 134
 135         if(sf & BIT(4))
 136         {
 137                 float specs = CountSpectators(e, to);
 138                 WriteByte(MSG_ENTITY, specs);
 139                 WriteSpectators(e, to);
 140         }
 141
 142         return true;
 143 }
 144
 145 void ClientData_Attach(entity this)
 146 {
 147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 148         CS(this).clientdata.drawonlytoclient = this;
 149         CS(this).clientdata.owner = this;
 150 }
 151
 152 void ClientData_Detach(entity this)
 153 {
 154         delete(CS(this).clientdata);
 155         CS(this).clientdata = NULL;
 156 }
 157
 158 void ClientData_Touch(entity e)
 159 {
 160         entity cd = CS(e).clientdata;
 161         if (cd) { cd.SendFlags = 1; }
 162
 163         // make it spectatable
 164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 165         {
 166                 entity cd = CS(it).clientdata;
 167                 if (cd) { cd.SendFlags = 1; }
 168         });
 169 }
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 /** putting a client as observer in the server */
 225 void PutObserverInServer(entity this)
 226 {
 227     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 228         PlayerState_detach(this);
 229
 230         if (IS_PLAYER(this))
 231         {
 232                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 233                 {
 234                         // despawn effect
 235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 236                 }
 237
 238                 // was a player, recount votes and ready status
 239                 if(IS_REAL_CLIENT(this))
 240                 {
 241                         if (vote_called) { VoteCount(false); }
 242                         ReadyCount();
 243                 }
 244     }
 245
 246     {
 247         entity spot = SelectSpawnPoint(this, true);
 248         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 249         this.angles = vec2(spot.angles);
 250         this.fixangle = true;
 251         // offset it so that the spectator spawns higher off the ground, looks better this way
 252         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 253         if (IS_REAL_CLIENT(this))
 254         {
 255             msg_entity = this;
 256             WriteByte(MSG_ONE, SVC_SETVIEW);
 257             WriteEntity(MSG_ONE, this);
 258         }
 259         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 260         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 261         if(!autocvar_g_debug_globalsounds)
 262         {
 263                 // needed for player sounds
 264                 this.model = "";
 265                 FixPlayermodel(this);
 266         }
 267         setmodel(this, MDL_Null);
 268         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 269         this.view_ofs = '0 0 0';
 270     }
 271
 272     RemoveGrapplingHooks(this);
 273         Portal_ClearAll(this);
 274         Unfreeze(this);
 275         SetSpectatee(this, NULL);
 276
 277         if (this.alivetime)
 278         {
 279                 if (!warmup_stage)
 280                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 281                 this.alivetime = 0;
 282         }
 283
 284         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 285
 286         WaypointSprite_PlayerDead(this);
 287
 288         if (mutator_returnvalue) {
 289             // mutator prevents resetting teams+score
 290         } else {
 291                 int oldteam = this.team;
 292                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 293                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 294         this.frags = FRAGS_SPECTATOR;
 295         PlayerScore_Clear(this);  // clear scores when needed
 296     }
 297
 298         if (CS(this).killcount != FRAGS_SPECTATOR)
 299         {
 300                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 301                 if(!game_stopped)
 302                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 303                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 304
 305                 if(!CS(this).just_joined)
 306                         LogTeamchange(this.playerid, -1, 4);
 307                 else
 308                         CS(this).just_joined = false;
 309         }
 310
 311         accuracy_resend(this);
 312
 313         CS(this).spectatortime = time;
 314         if(this.bot_attack)
 315                 IL_REMOVE(g_bot_targets, this);
 316         this.bot_attack = false;
 317         if(this.monster_attack)
 318                 IL_REMOVE(g_monster_targets, this);
 319         this.monster_attack = false;
 320     STAT(HUD, this) = HUD_NORMAL;
 321         TRANSMUTE(Observer, this);
 322         this.iscreature = false;
 323         this.teleportable = TELEPORT_SIMPLE;
 324         if(this.damagedbycontents)
 325                 IL_REMOVE(g_damagedbycontents, this);
 326         this.damagedbycontents = false;
 327         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 328         SetSpectatee_status(this, etof(this));
 329         this.takedamage = DAMAGE_NO;
 330         this.solid = SOLID_NOT;
 331         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 332         this.flags = FL_CLIENT | FL_NOTARGET;
 333         this.effects = 0;
 334         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 335         this.pauserotarmor_finished = 0;
 336         this.pauserothealth_finished = 0;
 337         this.pauseregen_finished = 0;
 338         this.damageforcescale = 0;
 339         this.death_time = 0;
 340         this.respawn_flags = 0;
 341         this.respawn_time = 0;
 342         STAT(RESPAWN_TIME, this) = 0;
 343         this.alpha = 0;
 344         this.scale = 0;
 345         this.fade_time = 0;
 346         this.pain_frame = 0;
 347         this.pain_finished = 0;
 348         this.strength_finished = 0;
 349         this.invincible_finished = 0;
 350         this.superweapons_finished = 0;
 351         this.dphitcontentsmask = 0;
 352         this.pushltime = 0;
 353         this.istypefrag = 0;
 354         setthink(this, func_null);
 355         this.nextthink = 0;
 356         this.deadflag = DEAD_NO;
 357         this.crouch = false;
 358         STAT(REVIVE_PROGRESS, this) = 0;
 359         this.revival_time = 0;
 360
 361         this.items = 0;
 362         STAT(WEAPONS, this) = '0 0 0';
 363         this.drawonlytoclient = this;
 364
 365         this.viewloc = NULL;
 366
 367         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 368
 369         this.weaponmodel = "";
 370         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 371         {
 372                 this.weaponentities[slot] = NULL;
 373         }
 374         this.exteriorweaponentity = NULL;
 375         CS(this).killcount = FRAGS_SPECTATOR;
 376         this.velocity = '0 0 0';
 377         this.avelocity = '0 0 0';
 378         this.punchangle = '0 0 0';
 379         this.punchvector = '0 0 0';
 380         this.oldvelocity = this.velocity;
 381         this.fire_endtime = -1;
 382         this.event_damage = func_null;
 383         this.event_heal = func_null;
 384
 385         for(int slot = 0; slot < MAX_AXH; ++slot)
 386         {
 387                 entity axh = this.(AuxiliaryXhair[slot]);
 388                 this.(AuxiliaryXhair[slot]) = NULL;
 389
 390                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 391                         delete(axh);
 392         }
 393 }
 394
 395 int player_getspecies(entity this)
 396 {
 397         get_model_parameters(this.model, this.skin);
 398         int s = get_model_parameters_species;
 399         get_model_parameters(string_null, 0);
 400         if (s < 0) return SPECIES_HUMAN;
 401         return s;
 402 }
 403
 404 .float model_randomizer;
 405 void FixPlayermodel(entity player)
 406 {
 407         string defaultmodel = "";
 408         int defaultskin = 0;
 409         if(autocvar_sv_defaultcharacter)
 410         {
 411                 if(teamplay)
 412                 {
 413                         switch(player.team)
 414                         {
 415                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 416                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 417                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 418                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 419                         }
 420                 }
 421
 422                 if(defaultmodel == "")
 423                 {
 424                         defaultmodel = autocvar_sv_defaultplayermodel;
 425                         defaultskin = autocvar_sv_defaultplayerskin;
 426                 }
 427
 428                 int n = tokenize_console(defaultmodel);
 429                 if(n > 0)
 430                 {
 431                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 432                         // However, do NOT randomize if the player-selected model is in the list.
 433                         for (int i = 0; i < n; ++i)
 434                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 435                                         defaultmodel = argv(i);
 436                 }
 437
 438                 int i = strstrofs(defaultmodel, ":", 0);
 439                 if(i >= 0)
 440                 {
 441                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 442                         defaultmodel = substring(defaultmodel, 0, i);
 443                 }
 444         }
 445         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 446         {
 447                 if(teamplay)
 448                 {
 449                         switch(player.team)
 450                         {
 451                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 452                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 453                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 454                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 455                         }
 456                 }
 457
 458                 if(!defaultskin)
 459                         defaultskin = autocvar_sv_defaultplayerskin;
 460         }
 461
 462         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 463         defaultmodel = M_ARGV(0, string);
 464         defaultskin = M_ARGV(1, int);
 465
 466         bool chmdl = false;
 467         int oldskin;
 468         if(defaultmodel != "")
 469         {
 470                 if (defaultmodel != player.model)
 471                 {
 472                         vector m1 = player.mins;
 473                         vector m2 = player.maxs;
 474                         setplayermodel (player, defaultmodel);
 475                         setsize (player, m1, m2);
 476                         chmdl = true;
 477                 }
 478
 479                 oldskin = player.skin;
 480                 player.skin = defaultskin;
 481         } else {
 482                 if (player.playermodel != player.model || player.playermodel == "")
 483                 {
 484                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 485                         vector m1 = player.mins;
 486                         vector m2 = player.maxs;
 487                         setplayermodel (player, player.playermodel);
 488                         setsize (player, m1, m2);
 489                         chmdl = true;
 490                 }
 491
 492                 if(!autocvar_sv_defaultcharacterskin)
 493                 {
 494                         oldskin = player.skin;
 495                         player.skin = stof(player.playerskin);
 496                 }
 497                 else
 498                 {
 499                         oldskin = player.skin;
 500                         player.skin = defaultskin;
 501                 }
 502         }
 503
 504         if(chmdl || oldskin != player.skin) // model or skin has changed
 505         {
 506                 player.species = player_getspecies(player); // update species
 507                 if(!autocvar_g_debug_globalsounds)
 508                         UpdatePlayerSounds(player); // update skin sounds
 509         }
 510
 511         if(!teamplay)
 512                 if(strlen(autocvar_sv_defaultplayercolors))
 513                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 514                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 515 }
 516
 517 void PutPlayerInServer(entity this)
 518 {
 519         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 520
 521         PlayerState_attach(this);
 522         accuracy_resend(this);
 523
 524         if (this.team < 0)
 525                 JoinBestTeam(this, true);
 526
 527         entity spot = SelectSpawnPoint(this, false);
 528         if (!spot) {
 529                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 530                 return; // spawn failed
 531         }
 532
 533         TRANSMUTE(Player, this);
 534
 535         CS(this).wasplayer = true;
 536         this.iscreature = true;
 537         this.teleportable = TELEPORT_NORMAL;
 538         if(!this.damagedbycontents)
 539                 IL_PUSH(g_damagedbycontents, this);
 540         this.damagedbycontents = true;
 541         set_movetype(this, MOVETYPE_WALK);
 542         this.solid = SOLID_SLIDEBOX;
 543         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 544         if (autocvar_g_playerclip_collisions)
 545                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 546         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 547                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 548         this.frags = FRAGS_PLAYER;
 549         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 550         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 551         if (autocvar__notarget)
 552                 this.flags |= FL_NOTARGET;
 553         this.takedamage = DAMAGE_AIM;
 554         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 555
 556         if (warmup_stage) {
 557                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 558                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 559                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 560                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 561                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 562                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 563                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 564                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 565                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 566         } else {
 567                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 568                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 569                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 570                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 571                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 572                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 573                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 574                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 575                 STAT(WEAPONS, this) = start_weapons;
 576                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 577                 {
 578                         GiveRandomWeapons(this, random_start_weapons_count,
 579                                 autocvar_g_random_start_weapons, random_start_ammo);
 580                 }
 581         }
 582         SetSpectatee_status(this, 0);
 583
 584         PS(this).dual_weapons = '0 0 0';
 585
 586         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 587
 588         this.items = start_items;
 589
 590         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 591         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 592         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 593         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 594         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 595         if (!sv_ready_restart_after_countdown && time < game_starttime)
 596         {
 597                 float f = game_starttime - time;
 598                 this.spawnshieldtime += f;
 599                 this.pauserotarmor_finished += f;
 600                 this.pauserothealth_finished += f;
 601                 this.pauseregen_finished += f;
 602         }
 603
 604         this.damageforcescale = 2;
 605         this.death_time = 0;
 606         this.respawn_flags = 0;
 607         this.respawn_time = 0;
 608         STAT(RESPAWN_TIME, this) = 0;
 609         this.scale = autocvar_sv_player_scale;
 610         this.fade_time = 0;
 611         this.pain_frame = 0;
 612         this.pain_finished = 0;
 613         this.pushltime = 0;
 614         setthink(this, func_null); // players have no think function
 615         this.nextthink = 0;
 616         this.dmg_team = 0;
 617         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 618
 619         this.deadflag = DEAD_NO;
 620
 621         this.angles = spot.angles;
 622         this.angles_z = 0; // never spawn tilted even if the spot says to
 623         if (IS_BOT_CLIENT(this))
 624                 this.v_angle = this.angles;
 625         this.fixangle = true; // turn this way immediately
 626         this.oldvelocity = this.velocity = '0 0 0';
 627         this.avelocity = '0 0 0';
 628         this.punchangle = '0 0 0';
 629         this.punchvector = '0 0 0';
 630
 631         this.strength_finished = 0;
 632         this.invincible_finished = 0;
 633         this.fire_endtime = -1;
 634         STAT(REVIVE_PROGRESS, this) = 0;
 635         this.revival_time = 0;
 636
 637         this.air_finished = time + 12;
 638         this.waterlevel = WATERLEVEL_NONE;
 639         this.watertype = CONTENT_EMPTY;
 640
 641         entity spawnevent = new_pure(spawnevent);
 642         spawnevent.owner = this;
 643         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 644
 645         // Cut off any still running player sounds.
 646         stopsound(this, CH_PLAYER_SINGLE);
 647
 648         this.model = "";
 649         FixPlayermodel(this);
 650         this.drawonlytoclient = NULL;
 651
 652         this.viewloc = NULL;
 653
 654         for(int slot = 0; slot < MAX_AXH; ++slot)
 655         {
 656                 entity axh = this.(AuxiliaryXhair[slot]);
 657                 this.(AuxiliaryXhair[slot]) = NULL;
 658
 659                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 660                         delete(axh);
 661         }
 662
 663         this.spawnpoint_targ = NULL;
 664
 665         this.crouch = false;
 666         this.view_ofs = STAT(PL_VIEW_OFS, this);
 667         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 668         this.spawnorigin = spot.origin;
 669         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 670         // don't reset back to last position, even if new position is stuck in solid
 671         this.oldorigin = this.origin;
 672         if(this.conveyor)
 673                 IL_REMOVE(g_conveyed, this);
 674         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 675         STAT(HUD, this) = HUD_NORMAL;
 676
 677         this.event_damage = PlayerDamage;
 678         this.event_heal = PlayerHeal;
 679
 680         if(!this.bot_attack)
 681                 IL_PUSH(g_bot_targets, this);
 682         this.bot_attack = true;
 683         if(!this.monster_attack)
 684                 IL_PUSH(g_monster_targets, this);
 685         this.monster_attack = true;
 686         navigation_dynamicgoal_init(this, false);
 687
 688         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 689
 690         // player was spectator
 691         if (CS(this).killcount == FRAGS_SPECTATOR) {
 692                 PlayerScore_Clear(this);
 693                 CS(this).killcount = 0;
 694                 CS(this).startplaytime = time;
 695         }
 696
 697         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 698         {
 699                 .entity weaponentity = weaponentities[slot];
 700                 entity oldwep = this.(weaponentity);
 701                 CL_SpawnWeaponentity(this, weaponentity);
 702                 if(oldwep && oldwep.owner == this)
 703                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 704         }
 705         this.alpha = default_player_alpha;
 706         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 707         this.exteriorweaponentity.alpha = default_weapon_alpha;
 708
 709         this.speedrunning = false;
 710
 711         target_voicescript_clear(this);
 712
 713         // reset fields the weapons may use
 714         FOREACH(Weapons, true, {
 715                 it.wr_resetplayer(it, this);
 716                         // reload all reloadable weapons
 717                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 718                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 719                         {
 720                                 .entity weaponentity = weaponentities[slot];
 721                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 722                         }
 723                 }
 724         });
 725
 726         {
 727                 string s = spot.target;
 728                 spot.target = string_null;
 729                 SUB_UseTargets(spot, this, NULL);
 730                 spot.target = s;
 731         }
 732
 733         Unfreeze(this);
 734
 735         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 736
 737         if (autocvar_spawn_debug)
 738         {
 739                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 740                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 741         }
 742
 743         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744         {
 745                 .entity weaponentity = weaponentities[slot];
 746                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 747                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 748                 else
 749                         this.(weaponentity).m_switchweapon = WEP_Null;
 750                 this.(weaponentity).m_weapon = WEP_Null;
 751                 this.(weaponentity).weaponname = "";
 752                 this.(weaponentity).m_switchingweapon = WEP_Null;
 753                 this.(weaponentity).cnt = -1;
 754         }
 755
 756         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 757
 758         if (!warmup_stage && !this.alivetime)
 759                 this.alivetime = time;
 760
 761         antilag_clear(this, CS(this));
 762 }
 763
 764 /** Called when a client spawns in the server */
 765 void PutClientInServer(entity this)
 766 {
 767         if (IS_BOT_CLIENT(this)) {
 768                 TRANSMUTE(Player, this);
 769         } else if (IS_REAL_CLIENT(this)) {
 770                 msg_entity = this;
 771                 WriteByte(MSG_ONE, SVC_SETVIEW);
 772                 WriteEntity(MSG_ONE, this);
 773         }
 774         if (game_stopped)
 775                 TRANSMUTE(Observer, this);
 776
 777         SetSpectatee(this, NULL);
 778
 779         // reset player keys
 780         if(PS(this))
 781                 PS(this).itemkeys = 0;
 782
 783         MUTATOR_CALLHOOK(PutClientInServer, this);
 784
 785         if (IS_OBSERVER(this)) {
 786                 PutObserverInServer(this);
 787         } else if (IS_PLAYER(this)) {
 788                 PutPlayerInServer(this);
 789         }
 790 }
 791
 792 // TODO do we need all these fields, or should we stop autodetecting runtime
 793 // changes and just have a console command to update this?
 794 bool ClientInit_SendEntity(entity this, entity to, int sf)
 795 {
 796         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 797         return = true;
 798         msg_entity = to;
 799         // MSG_INIT replacement
 800         // TODO: make easier to use
 801         Registry_send_all();
 802         W_PROP_reload(MSG_ONE, to);
 803         ClientInit_misc(this);
 804         MUTATOR_CALLHOOK(Ent_Init);
 805 }
 806 void ClientInit_misc(entity this)
 807 {
 808         int channel = MSG_ONE;
 809         WriteHeader(channel, ENT_CLIENT_INIT);
 810         WriteByte(channel, g_nexball_meter_period * 32);
 811         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 812         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 813         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 814         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 815         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 816         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 817         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 818         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 819
 820         if(sv_foginterval && world.fog != "")
 821                 WriteString(channel, world.fog);
 822         else
 823                 WriteString(channel, "");
 824         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 825         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 826         WriteByte(channel, serverflags);
 827         WriteCoord(channel, autocvar_g_trueaim_minrange);
 828 }
 829
 830 void ClientInit_CheckUpdate(entity this)
 831 {
 832         this.nextthink = time;
 833         if(this.count != autocvar_g_balance_armor_blockpercent)
 834         {
 835                 this.count = autocvar_g_balance_armor_blockpercent;
 836                 this.SendFlags |= 1;
 837         }
 838         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 839         {
 840                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 841                 this.SendFlags |= 1;
 842         }
 843 }
 844
 845 void ClientInit_Spawn()
 846 {
 847         entity e = new_pure(clientinit);
 848         setthink(e, ClientInit_CheckUpdate);
 849         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 850
 851         ClientInit_CheckUpdate(e);
 852 }
 853
 854 /*
 855 =============
 856 SetNewParms
 857 =============
 858 */
 859 void SetNewParms ()
 860 {
 861         // initialize parms for a new player
 862         parm1 = -(86400 * 366);
 863
 864         MUTATOR_CALLHOOK(SetNewParms);
 865 }
 866
 867 /*
 868 =============
 869 SetChangeParms
 870 =============
 871 */
 872 void SetChangeParms (entity this)
 873 {
 874         // save parms for level change
 875         parm1 = CS(this).parm_idlesince - time;
 876
 877         MUTATOR_CALLHOOK(SetChangeParms);
 878 }
 879
 880 /*
 881 =============
 882 DecodeLevelParms
 883 =============
 884 */
 885 void DecodeLevelParms(entity this)
 886 {
 887         // load parms
 888         CS(this).parm_idlesince = parm1;
 889         if (CS(this).parm_idlesince == -(86400 * 366))
 890                 CS(this).parm_idlesince = time;
 891
 892         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 893         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 894
 895         MUTATOR_CALLHOOK(DecodeLevelParms);
 896 }
 897
 898 /*
 899 =============
 900 ClientKill
 901
 902 Called when a client types 'kill' in the console
 903 =============
 904 */
 905
 906 .float clientkill_nexttime;
 907 void ClientKill_Now_TeamChange(entity this)
 908 {
 909         if(this.killindicator_teamchange == -1)
 910         {
 911                 JoinBestTeam( this, true );
 912         }
 913         else if(this.killindicator_teamchange == -2)
 914         {
 915                 if(blockSpectators)
 916                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 917                 PutObserverInServer(this);
 918         }
 919         else
 920                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 921         this.killindicator_teamchange = 0;
 922 }
 923
 924 void ClientKill_Now(entity this)
 925 {
 926         if(this.vehicle)
 927         {
 928             vehicles_exit(this.vehicle, VHEF_RELEASE);
 929             if(!this.killindicator_teamchange)
 930             {
 931             this.vehicle_health = -1;
 932             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 933             }
 934         }
 935
 936         if(this.killindicator && !wasfreed(this.killindicator))
 937                 delete(this.killindicator);
 938
 939         this.killindicator = NULL;
 940
 941         if(this.killindicator_teamchange)
 942                 ClientKill_Now_TeamChange(this);
 943
 944         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 945         {
 946                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 947         }
 948
 949         // now I am sure the player IS dead
 950 }
 951 void KillIndicator_Think(entity this)
 952 {
 953         if (game_stopped)
 954         {
 955                 this.owner.killindicator = NULL;
 956                 delete(this);
 957                 return;
 958         }
 959
 960         if (this.owner.alpha < 0 && !this.owner.vehicle)
 961         {
 962                 this.owner.killindicator = NULL;
 963                 delete(this);
 964                 return;
 965         }
 966
 967         if(this.cnt <= 0)
 968         {
 969                 ClientKill_Now(this.owner);
 970                 return;
 971         }
 972     else if(this.count == 1) // count == 1 means that it's silent
 973     {
 974         this.nextthink = time + 1;
 975         this.cnt -= 1;
 976     }
 977         else
 978         {
 979                 if(this.cnt <= 10)
 980                         setmodel(this, MDL_NUM(this.cnt));
 981                 if(IS_REAL_CLIENT(this.owner))
 982                 {
 983                         if(this.cnt <= 10)
 984                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 985                 }
 986                 this.nextthink = time + 1;
 987                 this.cnt -= 1;
 988         }
 989 }
 990
 991 float clientkilltime;
 992 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 993 {
 994         float killtime;
 995         float starttime;
 996
 997         if (game_stopped)
 998                 return;
 999
1000         killtime = autocvar_g_balance_kill_delay;
1001
1002     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1003         return;
1004     killtime = M_ARGV(1, float);
1005
1006         this.killindicator_teamchange = targetteam;
1007
1008     if(!this.killindicator)
1009         {
1010                 if(!IS_DEAD(this))
1011                 {
1012                         killtime = max(killtime, this.clientkill_nexttime - time);
1013                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1014                 }
1015
1016                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1017                 {
1018                         ClientKill_Now(this);
1019                 }
1020                 else
1021                 {
1022                         starttime = max(time, clientkilltime);
1023
1024                         this.killindicator = spawn();
1025                         this.killindicator.owner = this;
1026                         this.killindicator.scale = 0.5;
1027                         setattachment(this.killindicator, this, "");
1028                         setorigin(this.killindicator, '0 0 52');
1029                         setthink(this.killindicator, KillIndicator_Think);
1030                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1031                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1032                         this.killindicator.cnt = ceil(killtime);
1033                         this.killindicator.count = bound(0, ceil(killtime), 10);
1034                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1035
1036                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1037                         {
1038                                 it.killindicator = spawn();
1039                                 it.killindicator.owner = it;
1040                                 it.killindicator.scale = 0.5;
1041                                 setattachment(it.killindicator, it, "");
1042                                 setorigin(it.killindicator, '0 0 52');
1043                                 setthink(it.killindicator, KillIndicator_Think);
1044                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1045                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1046                                 it.killindicator.cnt = ceil(killtime);
1047                         });
1048                         this.lip = 0;
1049                 }
1050         }
1051         if(this.killindicator)
1052         {
1053                 if(targetteam == 0) // just die
1054                 {
1055                         this.killindicator.colormod = '0 0 0';
1056                         if(IS_REAL_CLIENT(this))
1057                         if(this.killindicator.cnt > 0)
1058                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1059                 }
1060                 else if(targetteam == -1) // auto
1061                 {
1062                         this.killindicator.colormod = '0 1 0';
1063                         if(IS_REAL_CLIENT(this))
1064                         if(this.killindicator.cnt > 0)
1065                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1066                 }
1067                 else if(targetteam == -2) // spectate
1068                 {
1069                         this.killindicator.colormod = '0.5 0.5 0.5';
1070                         if(IS_REAL_CLIENT(this))
1071                         if(this.killindicator.cnt > 0)
1072                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1073                 }
1074                 else
1075                 {
1076                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1077                         if(IS_REAL_CLIENT(this))
1078                         if(this.killindicator.cnt > 0)
1079                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1080                 }
1081         }
1082
1083 }
1084
1085 void ClientKill (entity this)
1086 {
1087         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1088
1089         if(game_stopped) return;
1090         if(this.player_blocked) return;
1091         if(STAT(FROZEN, this)) return;
1092
1093         ClientKill_TeamChange(this, 0);
1094 }
1095
1096 void FixClientCvars(entity e)
1097 {
1098         // send prediction settings to the client
1099         stuffcmd(e, "\nin_bindmap 0 0\n");
1100         if(autocvar_g_antilag == 3) // client side hitscan
1101                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1102         if(autocvar_sv_gentle)
1103                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1104
1105         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1106         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1107
1108         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1109
1110         MUTATOR_CALLHOOK(FixClientCvars, e);
1111 }
1112
1113 bool findinlist_abbrev(string tofind, string list)
1114 {
1115         if(list == "" || tofind == "")
1116                 return false; // empty list or search, just return
1117
1118         // this function allows abbreviated strings!
1119         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1120         {
1121                 return true;
1122         });
1123
1124         return false;
1125 }
1126
1127 bool PlayerInIPList(entity p, string iplist)
1128 {
1129         // some safety checks (never allow local?)
1130         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1131                 return false;
1132
1133         return findinlist_abbrev(p.netaddress, iplist);
1134 }
1135
1136 bool PlayerInIDList(entity p, string idlist)
1137 {
1138         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1139         if(!p.crypto_idfp)
1140                 return false;
1141
1142         return findinlist_abbrev(p.crypto_idfp, idlist);
1143 }
1144
1145 bool PlayerInList(entity player, string list)
1146 {
1147         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1148 }
1149
1150 #ifdef DP_EXT_PRECONNECT
1151 /*
1152 =============
1153 ClientPreConnect
1154
1155 Called once (not at each match start) when a client begins a connection to the server
1156 =============
1157 */
1158 void ClientPreConnect(entity this)
1159 {
1160         if(autocvar_sv_eventlog)
1161         {
1162                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1163                         this.playerid,
1164                         etof(this),
1165                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1166                 ));
1167         }
1168 }
1169 #endif
1170
1171 /**
1172 =============
1173 ClientConnect
1174
1175 Called when a client connects to the server
1176 =============
1177 */
1178 void ClientConnect(entity this)
1179 {
1180         if (Ban_MaybeEnforceBanOnce(this)) return;
1181         assert(!IS_CLIENT(this), return);
1182         this.flags |= FL_CLIENT;
1183         assert(player_count >= 0, player_count = 0);
1184
1185 #ifdef WATERMARK
1186         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1187 #endif
1188         TRANSMUTE(Client, this);
1189         CS(this).version_nagtime = time + 10 + random() * 10;
1190
1191         // identify the right forced team
1192         if (autocvar_g_campaign)
1193         {
1194                 if (IS_REAL_CLIENT(this)) // only players, not bots
1195                 {
1196                         switch (autocvar_g_campaign_forceteam)
1197                         {
1198                                 case 1: this.team_forced = NUM_TEAM_1; break;
1199                                 case 2: this.team_forced = NUM_TEAM_2; break;
1200                                 case 3: this.team_forced = NUM_TEAM_3; break;
1201                                 case 4: this.team_forced = NUM_TEAM_4; break;
1202                                 default: this.team_forced = 0;
1203                         }
1204                 }
1205         }
1206         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1207         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1208         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1209         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1210         else switch (autocvar_g_forced_team_otherwise)
1211         {
1212                 default: this.team_forced = 0; break;
1213                 case "red": this.team_forced = NUM_TEAM_1; break;
1214                 case "blue": this.team_forced = NUM_TEAM_2; break;
1215                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1216                 case "pink": this.team_forced = NUM_TEAM_4; break;
1217                 case "spectate":
1218                 case "spectator":
1219                         this.team_forced = -1;
1220                         break;
1221         }
1222         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1223
1224         int playerid_save = this.playerid;
1225         this.playerid = 0; // silent
1226         JoinBestTeam(this, false); // if the team number is valid, keep it
1227         this.playerid = playerid_save;
1228
1229         TRANSMUTE(Observer, this);
1230
1231         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1232
1233         // always track bots, don't ask for cl_allow_uidtracking
1234         if (IS_BOT_CLIENT(this))
1235                 PlayerStats_GameReport_AddPlayer(this);
1236         else
1237                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1238
1239         if (autocvar_sv_eventlog)
1240                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1241
1242         LogTeamchange(this.playerid, this.team, 1);
1243
1244         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1245
1246         if(teamplay && IS_PLAYER(this))
1247                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1248         else
1249                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1250
1251         stuffcmd(this, clientstuff, "\n");
1252         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1253
1254         FixClientCvars(this);
1255
1256         // get version info from player
1257         stuffcmd(this, "cmd clientversion $gameversion\n");
1258
1259         // notify about available teams
1260         if (teamplay)
1261         {
1262                 CheckAllowedTeams(this);
1263                 int t = 0;
1264                 if (c1 >= 0) t |= BIT(0);
1265                 if (c2 >= 0) t |= BIT(1);
1266                 if (c3 >= 0) t |= BIT(2);
1267                 if (c4 >= 0) t |= BIT(3);
1268                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1269         }
1270         else
1271         {
1272                 stuffcmd(this, "set _teams_available 0\n");
1273         }
1274
1275         bot_relinkplayerlist();
1276
1277         CS(this).spectatortime = time;
1278         if (blockSpectators)
1279         {
1280                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1281         }
1282
1283         CS(this).jointime = time;
1284
1285         if (IS_REAL_CLIENT(this))
1286         {
1287                 if (g_weaponarena_weapons == WEPSET(TUBA))
1288                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1289         }
1290
1291         if (!sv_foginterval && world.fog != "")
1292                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1293
1294         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1295                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1296                         send_CSQC_teamnagger();
1297
1298         CSQCMODEL_AUTOINIT(this);
1299
1300         CS(this).model_randomizer = random();
1301
1302         if (IS_REAL_CLIENT(this))
1303                 sv_notice_join(this);
1304
1305         // update physics stats (players can spawn before physics runs)
1306         Physics_UpdateStats(this);
1307
1308         IL_EACH(g_initforplayer, it.init_for_player, {
1309                 it.init_for_player(it, this);
1310         });
1311
1312         Handicap_Initialize(this);
1313
1314         MUTATOR_CALLHOOK(ClientConnect, this);
1315
1316         if (IS_REAL_CLIENT(this))
1317         {
1318                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1319                 {
1320                         CS(this).motd_actived_time = -1;
1321                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1322                 }
1323         }
1324 }
1325 /*
1326 =============
1327 ClientDisconnect
1328
1329 Called when a client disconnects from the server
1330 =============
1331 */
1332 .entity chatbubbleentity;
1333 void ClientDisconnect(entity this)
1334 {
1335         assert(IS_CLIENT(this), return);
1336
1337         PlayerStats_GameReport_FinalizePlayer(this);
1338         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1339         if (CS(this).active_minigame) part_minigame(this);
1340         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1341
1342         if (autocvar_sv_eventlog)
1343                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1344
1345         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1346
1347         if(IS_SPEC(this))
1348                 SetSpectatee(this, NULL);
1349
1350     MUTATOR_CALLHOOK(ClientDisconnect, this);
1351
1352         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1353         strfree(CS(this).weaponorder_byimpulse);
1354         ClientState_detach(this);
1355
1356         Portal_ClearAll(this);
1357
1358         Unfreeze(this);
1359
1360         RemoveGrapplingHooks(this);
1361
1362         // Here, everything has been done that requires this player to be a client.
1363
1364         this.flags &= ~FL_CLIENT;
1365
1366         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1367         if (this.killindicator) delete(this.killindicator);
1368
1369         WaypointSprite_PlayerGone(this);
1370
1371         bot_relinkplayerlist();
1372
1373         strfree(this.clientstatus);
1374         if (this.personal) delete(this.personal);
1375
1376         this.playerid = 0;
1377         ReadyCount();
1378         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1379
1380         ONREMOVE(this);
1381 }
1382
1383 void ChatBubbleThink(entity this)
1384 {
1385         this.nextthink = time;
1386         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1387         {
1388                 if(this.owner) // but why can that ever be NULL?
1389                         this.owner.chatbubbleentity = NULL;
1390                 delete(this);
1391                 return;
1392         }
1393
1394         this.mdl = "";
1395
1396         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1397         {
1398                 if ( CS(this.owner).active_minigame )
1399                         this.mdl = "models/sprites/minigame_busy.iqm";
1400                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1401                         this.mdl = "models/misc/chatbubble.spr";
1402         }
1403
1404         if ( this.model != this.mdl )
1405                 _setmodel(this, this.mdl);
1406
1407 }
1408
1409 void UpdateChatBubble(entity this)
1410 {
1411         if (this.alpha < 0)
1412                 return;
1413         // spawn a chatbubble entity if needed
1414         if (!this.chatbubbleentity)
1415         {
1416                 this.chatbubbleentity = new(chatbubbleentity);
1417                 this.chatbubbleentity.owner = this;
1418                 this.chatbubbleentity.exteriormodeltoclient = this;
1419                 setthink(this.chatbubbleentity, ChatBubbleThink);
1420                 this.chatbubbleentity.nextthink = time;
1421                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1422                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1423                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1424                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1425                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1426                 //this.chatbubbleentity.model = "";
1427                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1428         }
1429 }
1430
1431
1432 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1433 // added to the model skins
1434 /*void UpdateColorModHack()
1435 {
1436         float c;
1437         c = this.clientcolors & 15;
1438         // LordHavoc: only bothering to support white, green, red, yellow, blue
1439              if (!teamplay) this.colormod = '0 0 0';
1440         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1441         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1442         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1443         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1444         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1445         else this.colormod = '1 1 1';
1446 }*/
1447
1448 void respawn(entity this)
1449 {
1450         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1451         {
1452                 this.solid = SOLID_NOT;
1453                 this.takedamage = DAMAGE_NO;
1454                 set_movetype(this, MOVETYPE_FLY);
1455                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1456                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1457                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1458                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1459                 if(autocvar_g_respawn_ghosts_maxtime)
1460                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1461         }
1462
1463         CopyBody(this, 1);
1464
1465         this.effects |= EF_NODRAW; // prevent another CopyBody
1466         PutClientInServer(this);
1467 }
1468
1469 void PrintToChat(entity client, string text)
1470 {
1471         text = strcat("\{1}^7", text, "\n");
1472         sprint(client, text);
1473 }
1474
1475 void DebugPrintToChat(entity client, string text)
1476 {
1477         if (autocvar_developer)
1478         {
1479                 PrintToChat(client, text);
1480         }
1481 }
1482
1483 void PrintToChatAll(string text)
1484 {
1485         text = strcat("\{1}^7", text, "\n");
1486         bprint(text);
1487 }
1488
1489 void DebugPrintToChatAll(string text)
1490 {
1491         if (autocvar_developer)
1492         {
1493                 PrintToChatAll(text);
1494         }
1495 }
1496
1497 void PrintToChatTeam(int team_num, string text)
1498 {
1499         text = strcat("\{1}^7", text, "\n");
1500         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1501         {
1502                 if (it.team == team_num)
1503                 {
1504                         sprint(it, text);
1505                 }
1506         });
1507 }
1508
1509 void DebugPrintToChatTeam(int team_num, string text)
1510 {
1511         if (autocvar_developer)
1512         {
1513                 PrintToChatTeam(team_num, text);
1514         }
1515 }
1516
1517 void play_countdown(entity this, float finished, Sound samp)
1518 {
1519     TC(Sound, samp);
1520         if(IS_REAL_CLIENT(this))
1521                 if(floor(finished - time - frametime) != floor(finished - time))
1522                         if(finished - time < 6)
1523                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1524 }
1525
1526 void player_powerups(entity this)
1527 {
1528         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1529         int items_prev = this.items;
1530
1531         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1532                 this.modelflags |= MF_ROCKET;
1533         else
1534                 this.modelflags &= ~MF_ROCKET;
1535
1536         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1537
1538         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1539                 return;
1540
1541         Fire_ApplyDamage(this);
1542         Fire_ApplyEffect(this);
1543
1544         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1545         {
1546                 if (this.items & ITEM_Strength.m_itemid)
1547                 {
1548                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1549                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1550                         if (time > this.strength_finished)
1551                         {
1552                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1553                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1554                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1555                         }
1556                 }
1557                 else
1558                 {
1559                         if (time < this.strength_finished)
1560                         {
1561                                 this.items = this.items | ITEM_Strength.m_itemid;
1562                                 if(!g_cts)
1563                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1564                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1565                         }
1566                 }
1567                 if (this.items & ITEM_Shield.m_itemid)
1568                 {
1569                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1570                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1571                         if (time > this.invincible_finished)
1572                         {
1573                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1574                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1575                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1576                         }
1577                 }
1578                 else
1579                 {
1580                         if (time < this.invincible_finished)
1581                         {
1582                                 this.items = this.items | ITEM_Shield.m_itemid;
1583                                 if(!g_cts)
1584                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1585                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1586                         }
1587                 }
1588                 if (this.items & IT_SUPERWEAPON)
1589                 {
1590                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1591                         {
1592                                 this.superweapons_finished = 0;
1593                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1594                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1595                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1596                         }
1597                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1598                         {
1599                                 // don't let them run out
1600                         }
1601                         else
1602                         {
1603                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1604                                 if (time > this.superweapons_finished)
1605                                 {
1606                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1607                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1608                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1609                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1610                                 }
1611                         }
1612                 }
1613                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1614                 {
1615                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1616                         {
1617                                 this.items = this.items | IT_SUPERWEAPON;
1618                                 if(!g_cts)
1619                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1620                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1621                         }
1622                         else
1623                         {
1624                                 this.superweapons_finished = 0;
1625                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1626                         }
1627                 }
1628                 else
1629                 {
1630                         this.superweapons_finished = 0;
1631                 }
1632         }
1633
1634         if(autocvar_g_nodepthtestplayers)
1635                 this.effects = this.effects | EF_NODEPTHTEST;
1636
1637         if(autocvar_g_fullbrightplayers)
1638                 this.effects = this.effects | EF_FULLBRIGHT;
1639
1640         if (time >= game_starttime)
1641         if (time < this.spawnshieldtime)
1642                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1643
1644         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1645 }
1646
1647 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1648 {
1649         if(current > stable)
1650                 return current;
1651         else if(current > stable - 0.25) // when close enough, "snap"
1652                 return stable;
1653         else
1654                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1655 }
1656
1657 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1658 {
1659         if(current < stable)
1660                 return current;
1661         else if(current < stable + 0.25) // when close enough, "snap"
1662                 return stable;
1663         else
1664                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1665 }
1666
1667 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1668 {
1669         if(current > rotstable)
1670         {
1671                 if(rotframetime > 0)
1672                 {
1673                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1674                         current = max(rotstable, current - rotlinear * rotframetime);
1675                 }
1676         }
1677         else if(current < regenstable)
1678         {
1679                 if(regenframetime > 0)
1680                 {
1681                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1682                         current = min(regenstable, current + regenlinear * regenframetime);
1683                 }
1684         }
1685
1686         if(current > limit)
1687                 current = limit;
1688
1689         return current;
1690 }
1691
1692 void player_regen(entity this)
1693 {
1694         float max_mod, regen_mod, rot_mod, limit_mod;
1695         max_mod = regen_mod = rot_mod = limit_mod = 1;
1696
1697         float regen_health = autocvar_g_balance_health_regen;
1698         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1699         float regen_health_rot = autocvar_g_balance_health_rot;
1700         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1701         float regen_health_stable = autocvar_g_balance_health_regenstable;
1702         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1703         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1704                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1705         max_mod = M_ARGV(1, float);
1706         regen_mod = M_ARGV(2, float);
1707         rot_mod = M_ARGV(3, float);
1708         limit_mod = M_ARGV(4, float);
1709         regen_health = M_ARGV(5, float);
1710         regen_health_linear = M_ARGV(6, float);
1711         regen_health_rot = M_ARGV(7, float);
1712         regen_health_rotlinear = M_ARGV(8, float);
1713         regen_health_stable = M_ARGV(9, float);
1714         regen_health_rotstable = M_ARGV(10, float);
1715
1716         if(!mutator_returnvalue)
1717         if(!STAT(FROZEN, this))
1718         {
1719                 float mina, maxa, limith, limita;
1720                 maxa = autocvar_g_balance_armor_rotstable;
1721                 mina = autocvar_g_balance_armor_regenstable;
1722                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1723                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1724
1725                 regen_health_rotstable = regen_health_rotstable * max_mod;
1726                 regen_health_stable = regen_health_stable * max_mod;
1727                 limith = limith * limit_mod;
1728                 limita = limita * limit_mod;
1729
1730                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1731                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1732                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1733                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1734                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1735                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1736         }
1737
1738         // if player rotted to death...  die!
1739         // check this outside above checks, as player may still be able to rot to death
1740         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1741         {
1742                 if(this.vehicle)
1743                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1744                 if(this.event_damage)
1745                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1746         }
1747
1748         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1749         {
1750                 float minf, maxf, limitf;
1751
1752                 maxf = autocvar_g_balance_fuel_rotstable;
1753                 minf = autocvar_g_balance_fuel_regenstable;
1754                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1755
1756                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1757                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1758                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1759         }
1760 }
1761
1762 bool zoomstate_set;
1763 void SetZoomState(entity this, float newzoom)
1764 {
1765         if(newzoom != CS(this).zoomstate)
1766         {
1767                 CS(this).zoomstate = newzoom;
1768                 ClientData_Touch(this);
1769         }
1770         zoomstate_set = true;
1771 }
1772
1773 void GetPressedKeys(entity this)
1774 {
1775         MUTATOR_CALLHOOK(GetPressedKeys, this);
1776         int keys = STAT(PRESSED_KEYS, this);
1777         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1778         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1779         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1780         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1781
1782         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1783         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1784         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1785         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1786         CS(this).pressedkeys = keys; // store for other users
1787
1788         STAT(PRESSED_KEYS, this) = keys;
1789 }
1790
1791 /*
1792 ======================
1793 spectate mode routines
1794 ======================
1795 */
1796
1797 void SpectateCopy(entity this, entity spectatee)
1798 {
1799     TC(Client, this); TC(Client, spectatee);
1800
1801         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1802         PS(this) = PS(spectatee);
1803         this.armortype = spectatee.armortype;
1804         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1805         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1806         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1807         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1808         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1809         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1810         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1811         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1812         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1813         CS(this).impulse = 0;
1814         this.items = spectatee.items;
1815         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1816         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1817         this.strength_finished = spectatee.strength_finished;
1818         this.invincible_finished = spectatee.invincible_finished;
1819         this.superweapons_finished = spectatee.superweapons_finished;
1820         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1821         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1822         this.punchangle = spectatee.punchangle;
1823         this.view_ofs = spectatee.view_ofs;
1824         this.velocity = spectatee.velocity;
1825         this.dmg_take = spectatee.dmg_take;
1826         this.dmg_save = spectatee.dmg_save;
1827         this.dmg_inflictor = spectatee.dmg_inflictor;
1828         this.v_angle = spectatee.v_angle;
1829         this.angles = spectatee.v_angle;
1830         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1831         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1832         this.viewloc = spectatee.viewloc;
1833         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1834                 this.fixangle = true;
1835         setorigin(this, spectatee.origin);
1836         setsize(this, spectatee.mins, spectatee.maxs);
1837         SetZoomState(this, CS(spectatee).zoomstate);
1838
1839     anticheat_spectatecopy(this, spectatee);
1840         STAT(HUD, this) = STAT(HUD, spectatee);
1841         if(spectatee.vehicle)
1842     {
1843         this.angles = spectatee.v_angle;
1844
1845         //this.fixangle = false;
1846         //this.velocity = spectatee.vehicle.velocity;
1847         this.vehicle_health = spectatee.vehicle_health;
1848         this.vehicle_shield = spectatee.vehicle_shield;
1849         this.vehicle_energy = spectatee.vehicle_energy;
1850         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1851         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1852         this.vehicle_reload1 = spectatee.vehicle_reload1;
1853         this.vehicle_reload2 = spectatee.vehicle_reload2;
1854
1855         //msg_entity = this;
1856
1857        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1858             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1859            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1860            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1861
1862         //WriteByte (MSG_ONE, SVC_SETVIEW);
1863         //    WriteEntity(MSG_ONE, this);
1864         //makevectors(spectatee.v_angle);
1865         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1866     }
1867 }
1868
1869 bool SpectateUpdate(entity this)
1870 {
1871         if(!this.enemy)
1872                 return false;
1873
1874         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1875         {
1876                 SetSpectatee(this, NULL);
1877                 return false;
1878         }
1879
1880         SpectateCopy(this, this.enemy);
1881
1882         return true;
1883 }
1884
1885 bool SpectateSet(entity this)
1886 {
1887         if(!IS_PLAYER(this.enemy))
1888                 return false;
1889
1890         ClientData_Touch(this.enemy);
1891
1892         msg_entity = this;
1893         WriteByte(MSG_ONE, SVC_SETVIEW);
1894         WriteEntity(MSG_ONE, this.enemy);
1895         set_movetype(this, MOVETYPE_NONE);
1896         accuracy_resend(this);
1897
1898         if(!SpectateUpdate(this))
1899                 PutObserverInServer(this);
1900
1901         return true;
1902 }
1903
1904 void SetSpectatee_status(entity this, int spectatee_num)
1905 {
1906         int oldspectatee_status = CS(this).spectatee_status;
1907         CS(this).spectatee_status = spectatee_num;
1908
1909         if (CS(this).spectatee_status != oldspectatee_status)
1910         {
1911                 ClientData_Touch(this);
1912                 if (g_race || g_cts) race_InitSpectator();
1913         }
1914 }
1915
1916 void SetSpectatee(entity this, entity spectatee)
1917 {
1918         if(IS_BOT_CLIENT(this))
1919                 return; // bots abuse .enemy, this code is useless to them
1920
1921         entity old_spectatee = this.enemy;
1922
1923         this.enemy = spectatee;
1924
1925         // WEAPONTODO
1926         // these are required to fix the spectator bug with arc
1927         if(old_spectatee)
1928         {
1929                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1930                 {
1931                         .entity weaponentity = weaponentities[slot];
1932                         if(old_spectatee.(weaponentity).arc_beam)
1933                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1934                 }
1935         }
1936         if(this.enemy)
1937         {
1938                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1939                 {
1940                         .entity weaponentity = weaponentities[slot];
1941                         if(this.enemy.(weaponentity).arc_beam)
1942                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1943                 }
1944         }
1945
1946         if (this.enemy)
1947                 SetSpectatee_status(this, etof(this.enemy));
1948
1949         // needed to update spectator list
1950         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1951 }
1952
1953 bool Spectate(entity this, entity pl)
1954 {
1955         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1956                 return false;
1957         pl = M_ARGV(1, entity);
1958
1959         SetSpectatee(this, pl);
1960         return SpectateSet(this);
1961 }
1962
1963 bool SpectateNext(entity this)
1964 {
1965         entity ent = find(this.enemy, classname, STR_PLAYER);
1966
1967         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1968                 ent = M_ARGV(1, entity);
1969         else if (!ent)
1970                 ent = find(ent, classname, STR_PLAYER);
1971
1972         if(ent) { SetSpectatee(this, ent); }
1973
1974         return SpectateSet(this);
1975 }
1976
1977 bool SpectatePrev(entity this)
1978 {
1979         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1980         entity ent = findchain(classname, STR_PLAYER);
1981         if (!ent) // no player
1982                 return false;
1983
1984         entity first = ent;
1985         // skip players until current spectated player
1986         if(this.enemy)
1987         while(ent && ent != this.enemy)
1988                 ent = ent.chain;
1989
1990         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1991         {
1992                 case MUT_SPECPREV_FOUND:
1993                     ent = M_ARGV(1, entity);
1994                     break;
1995                 case MUT_SPECPREV_RETURN:
1996                     return true;
1997                 case MUT_SPECPREV_CONTINUE:
1998                 default:
1999                 {
2000                         if(ent.chain)
2001                                 ent = ent.chain;
2002                         else
2003                                 ent = first;
2004                         break;
2005                 }
2006         }
2007
2008         SetSpectatee(this, ent);
2009         return SpectateSet(this);
2010 }
2011
2012 /*
2013 =============
2014 ShowRespawnCountdown()
2015
2016 Update a respawn countdown display.
2017 =============
2018 */
2019 void ShowRespawnCountdown(entity this)
2020 {
2021         float number;
2022         if(!IS_DEAD(this)) // just respawned?
2023                 return;
2024         else
2025         {
2026                 number = ceil(this.respawn_time - time);
2027                 if(number <= 0)
2028                         return;
2029                 if(number <= this.respawn_countdown)
2030                 {
2031                         this.respawn_countdown = number - 1;
2032                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2033                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2034                 }
2035         }
2036 }
2037
2038 .bool team_selected;
2039 bool ShowTeamSelection(entity this)
2040 {
2041         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2042                 return false;
2043         stuffcmd(this, "menu_showteamselect\n");
2044         return true;
2045 }
2046 void Join(entity this)
2047 {
2048         TRANSMUTE(Player, this);
2049
2050         if(!this.team_selected)
2051         if(autocvar_g_campaign || autocvar_g_balance_teams)
2052                 JoinBestTeam(this, true);
2053
2054         if(autocvar_g_campaign)
2055                 campaign_bots_may_start = true;
2056
2057         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2058
2059         PutClientInServer(this);
2060
2061         if(IS_PLAYER(this))
2062         if(teamplay && this.team != -1)
2063                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2064         else
2065                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2066         this.team_selected = false;
2067 }
2068
2069 /**
2070  * Determines whether the player is allowed to join. This depends on cvar
2071  * g_maxplayers, if it isn't used this function always return true, otherwise
2072  * it checks whether the number of currently playing players exceeds g_maxplayers.
2073  * @return int number of free slots for players, 0 if none
2074  */
2075 int nJoinAllowed(entity this, entity ignore)
2076 {
2077         if(!ignore)
2078         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2079         // so report 0 free slots if restricted
2080         {
2081                 if(autocvar_g_forced_team_otherwise == "spectate")
2082                         return 0;
2083                 if(autocvar_g_forced_team_otherwise == "spectator")
2084                         return 0;
2085         }
2086
2087         if(this && this.team_forced < 0)
2088                 return 0; // forced spectators can never join
2089
2090         // TODO simplify this
2091         int totalClients = 0;
2092         int currentlyPlaying = 0;
2093         FOREACH_CLIENT(true, {
2094                 if(it != ignore)
2095                         ++totalClients;
2096                 if(IS_REAL_CLIENT(it))
2097                 if(IS_PLAYER(it) || it.caplayer)
2098                         ++currentlyPlaying;
2099         });
2100
2101         float free_slots = 0;
2102         if (!autocvar_g_maxplayers)
2103                 free_slots = maxclients - totalClients;
2104         else if(currentlyPlaying < autocvar_g_maxplayers)
2105                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2106
2107         static float join_prevent_msg_time = 0;
2108         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2109         {
2110                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2111                 join_prevent_msg_time = time + 3;
2112         }
2113
2114         return free_slots;
2115 }
2116
2117 /**
2118  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2119  * g_maxplayers_spectator_blocktime seconds
2120  */
2121 void checkSpectatorBlock(entity this)
2122 {
2123         if(IS_SPEC(this) || IS_OBSERVER(this))
2124         if(!this.caplayer)
2125         if(IS_REAL_CLIENT(this))
2126         {
2127                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2128                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2129                         dropclient(this);
2130                 }
2131         }
2132 }
2133
2134 void PrintWelcomeMessage(entity this)
2135 {
2136         if(CS(this).motd_actived_time == 0)
2137         {
2138                 if (autocvar_g_campaign) {
2139                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2140                                 CS(this).motd_actived_time = time;
2141                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2142                         }
2143                 } else {
2144                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2145                                 CS(this).motd_actived_time = time;
2146                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2147                         }
2148                 }
2149         }
2150         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2151         {
2152                 if (autocvar_g_campaign) {
2153                         if (PHYS_INPUT_BUTTON_INFO(this))
2154                                 CS(this).motd_actived_time = time;
2155                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2156                                 CS(this).motd_actived_time = 0;
2157                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2158                         }
2159                 } else {
2160                         if (PHYS_INPUT_BUTTON_INFO(this))
2161                                 CS(this).motd_actived_time = time;
2162                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2163                                 CS(this).motd_actived_time = 0;
2164                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2165                         }
2166                 }
2167         }
2168         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2169         {
2170                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2171                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2172                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2173                 {
2174                         // instanctly hide MOTD
2175                         CS(this).motd_actived_time = 0;
2176                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2177                 }
2178         }
2179 }
2180
2181 const int MIN_SPEC_TIME = 1;
2182 bool joinAllowed(entity this)
2183 {
2184         if (CS(this).version_mismatch) return false;
2185         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2186         if (!nJoinAllowed(this, this)) return false;
2187         if (teamplay && lockteams) return false;
2188         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2189         if (ShowTeamSelection(this)) return false;
2190         return true;
2191 }
2192
2193 .int items_added;
2194 .string shootfromfixedorigin;
2195 bool PlayerThink(entity this)
2196 {
2197         if (game_stopped || intermission_running) {
2198                 this.modelflags &= ~MF_ROCKET;
2199                 if(intermission_running)
2200                         IntermissionThink(this);
2201                 return false;
2202         }
2203
2204         if (timeout_status == TIMEOUT_ACTIVE) {
2205         // don't allow the player to turn around while game is paused
2206                 // FIXME turn this into CSQC stuff
2207                 this.v_angle = this.lastV_angle;
2208                 this.angles = this.lastV_angle;
2209                 this.fixangle = true;
2210         }
2211
2212         if (frametime) player_powerups(this);
2213
2214         if (IS_DEAD(this)) {
2215                 if (this.personal && g_race_qualifying) {
2216                         if (time > this.respawn_time) {
2217                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2218                                 respawn(this);
2219                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2220                         }
2221                 } else {
2222                         if (frametime) player_anim(this);
2223
2224                         if (this.respawn_flags & RESPAWN_DENY)
2225                         {
2226                                 STAT(RESPAWN_TIME, this) = 0;
2227                                 return false;
2228                         }
2229
2230                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2231
2232                         switch(this.deadflag)
2233                         {
2234                                 case DEAD_DYING:
2235                                 {
2236                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2237                                                 this.deadflag = DEAD_RESPAWNING;
2238                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2239                                                 this.deadflag = DEAD_DEAD;
2240                                         break;
2241                                 }
2242                                 case DEAD_DEAD:
2243                                 {
2244                                         if (button_pressed)
2245                                                 this.deadflag = DEAD_RESPAWNABLE;
2246                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2247                                                 this.deadflag = DEAD_RESPAWNING;
2248                                         break;
2249                                 }
2250                                 case DEAD_RESPAWNABLE:
2251                                 {
2252                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2253                                                 this.deadflag = DEAD_RESPAWNING;
2254                                         break;
2255                                 }
2256                                 case DEAD_RESPAWNING:
2257                                 {
2258                                         if (time > this.respawn_time)
2259                                         {
2260                                                 this.respawn_time = time + 1; // only retry once a second
2261                                                 this.respawn_time_max = this.respawn_time;
2262                                                 respawn(this);
2263                                         }
2264                                         break;
2265                                 }
2266                         }
2267
2268                         ShowRespawnCountdown(this);
2269
2270                         if (this.respawn_flags & RESPAWN_SILENT)
2271                                 STAT(RESPAWN_TIME, this) = 0;
2272                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2273                         {
2274                                 if (time < this.respawn_time)
2275                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2276                                 else if (this.deadflag != DEAD_RESPAWNING)
2277                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2278                         }
2279                         else
2280                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2281                 }
2282
2283                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2284                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2285                         STAT(RESPAWN_TIME, this) *= -1;
2286
2287                 return false;
2288         }
2289
2290         FixPlayermodel(this);
2291
2292         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2293                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2294                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2295         }
2296
2297         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2298         //if(frametime)
2299         {
2300                 this.items &= ~this.items_added;
2301
2302                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2303                 {
2304                         .entity weaponentity = weaponentities[slot];
2305                         W_WeaponFrame(this, weaponentity);
2306                 }
2307
2308                 this.items_added = 0;
2309                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2310             this.items_added |= IT_FUEL;
2311
2312                 this.items |= this.items_added;
2313         }
2314
2315         player_regen(this);
2316
2317         // WEAPONTODO: Add a weapon request for this
2318         // rot vortex charge to the charge limit
2319         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2320         {
2321                 .entity weaponentity = weaponentities[slot];
2322                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2323                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2324         }
2325
2326         if (frametime) player_anim(this);
2327
2328         // secret status
2329         secrets_setstatus(this);
2330
2331         // monsters status
2332         monsters_setstatus(this);
2333
2334         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2335
2336         return true;
2337 }
2338
2339 .bool would_spectate;
2340 void ObserverThink(entity this)
2341 {
2342         if ( CS(this).impulse )
2343         {
2344                 MinigameImpulse(this, CS(this).impulse);
2345                 CS(this).impulse = 0;
2346         }
2347
2348         if (this.flags & FL_JUMPRELEASED) {
2349                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2350                         this.flags &= ~FL_JUMPRELEASED;
2351                         this.flags |= FL_SPAWNING;
2352                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2353                         this.flags &= ~FL_JUMPRELEASED;
2354                         if(SpectateNext(this)) {
2355                                 TRANSMUTE(Spectator, this);
2356                         }
2357                 } else {
2358                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2359                         set_movetype(this, preferred_movetype);
2360                 }
2361         } else {
2362                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2363                         this.flags |= FL_JUMPRELEASED;
2364                         if(this.flags & FL_SPAWNING)
2365                         {
2366                                 this.flags &= ~FL_SPAWNING;
2367                                 Join(this);
2368                                 return;
2369                         }
2370                 }
2371         }
2372 }
2373
2374 void SpectatorThink(entity this)
2375 {
2376         if ( CS(this).impulse )
2377         {
2378                 if(MinigameImpulse(this, CS(this).impulse))
2379                         CS(this).impulse = 0;
2380
2381                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2382                 {
2383                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2384                         CS(this).impulse = 0;
2385                         return;
2386                 }
2387         }
2388
2389         if (this.flags & FL_JUMPRELEASED) {
2390                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2391                         this.flags &= ~FL_JUMPRELEASED;
2392                         this.flags |= FL_SPAWNING;
2393                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2394                         this.flags &= ~FL_JUMPRELEASED;
2395                         if(SpectateNext(this)) {
2396                                 TRANSMUTE(Spectator, this);
2397                         } else {
2398                                 TRANSMUTE(Observer, this);
2399                                 PutClientInServer(this);
2400                         }
2401                         CS(this).impulse = 0;
2402                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2403                         this.flags &= ~FL_JUMPRELEASED;
2404                         if(SpectatePrev(this)) {
2405                                 TRANSMUTE(Spectator, this);
2406                         } else {
2407                                 TRANSMUTE(Observer, this);
2408                                 PutClientInServer(this);
2409                         }
2410                         CS(this).impulse = 0;
2411                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2412                         this.would_spectate = false;
2413                         this.flags &= ~FL_JUMPRELEASED;
2414                         TRANSMUTE(Observer, this);
2415                         PutClientInServer(this);
2416                 } else {
2417                         if(!SpectateUpdate(this))
2418                         {
2419                                 if(!SpectateNext(this))
2420                                 {
2421                                         PutObserverInServer(this);
2422                                         this.would_spectate = true;
2423                                 }
2424                         }
2425                 }
2426         } else {
2427                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2428                         this.flags |= FL_JUMPRELEASED;
2429                         if(this.flags & FL_SPAWNING)
2430                         {
2431                                 this.flags &= ~FL_SPAWNING;
2432                                 Join(this);
2433                                 return;
2434                         }
2435                 }
2436                 if(!SpectateUpdate(this))
2437                         PutObserverInServer(this);
2438         }
2439
2440         this.flags |= FL_CLIENT | FL_NOTARGET;
2441 }
2442
2443 void PlayerUseKey(entity this)
2444 {
2445         if (!IS_PLAYER(this))
2446                 return;
2447
2448         if(this.vehicle)
2449         {
2450                 if(!game_stopped)
2451                 {
2452                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2453                         return;
2454                 }
2455         }
2456         else if(autocvar_g_vehicles_enter)
2457         {
2458                 if(!STAT(FROZEN, this))
2459                 if(!IS_DEAD(this))
2460                 if(!game_stopped)
2461                 {
2462                         entity head, closest_target = NULL;
2463                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2464
2465                         while(head) // find the closest acceptable target to enter
2466                         {
2467                                 if(IS_VEHICLE(head))
2468                                 if(!IS_DEAD(head))
2469                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2470                                 if(head.takedamage != DAMAGE_NO)
2471                                 {
2472                                         if(closest_target)
2473                                         {
2474                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2475                                                 { closest_target = head; }
2476                                         }
2477                                         else { closest_target = head; }
2478                                 }
2479
2480                                 head = head.chain;
2481                         }
2482
2483                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2484                 }
2485         }
2486
2487         // a use key was pressed; call handlers
2488         MUTATOR_CALLHOOK(PlayerUseKey, this);
2489 }
2490
2491
2492 /*
2493 =============
2494 PlayerPreThink
2495
2496 Called every frame for each client before the physics are run
2497 =============
2498 */
2499 .float last_vehiclecheck;
2500 void PlayerPreThink (entity this)
2501 {
2502         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2503         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2504
2505         WarpZone_PlayerPhysics_FixVAngle(this);
2506
2507         if (frametime) {
2508                 // physics frames: update anticheat stuff
2509                 anticheat_prethink(this);
2510         }
2511
2512         if (blockSpectators && frametime) {
2513                 // WORKAROUND: only use dropclient in server frames (frametime set).
2514                 // Never use it in cl_movement frames (frametime zero).
2515                 checkSpectatorBlock(this);
2516         }
2517
2518         zoomstate_set = false;
2519
2520         // Check for nameless players
2521         if (this.netname == "" || this.netname != CS(this).netname_previous)
2522         {
2523                 bool assume_unchanged = (CS(this).netname_previous == "");
2524                 if (isInvisibleString(this.netname))
2525                 {
2526                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2527                         assume_unchanged = false;
2528                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2529                 }
2530                 if (!assume_unchanged && autocvar_sv_eventlog)
2531                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2532                 strcpy(CS(this).netname_previous, this.netname);
2533         }
2534
2535         // version nagging
2536         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2537         CS(this).version_nagtime = 0;
2538         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2539             // git client
2540         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2541             // git server
2542             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2543         } else {
2544             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2545             if (r < 0) { // old client
2546                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2547             } else if (r > 0) { // old server
2548                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2549             }
2550         }
2551     }
2552
2553         // GOD MODE info
2554         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2555         {
2556                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2557                 this.max_armorvalue = 0;
2558         }
2559
2560         if(IS_PLAYER(this))
2561         {
2562                 if (STAT(FROZEN, this) == 2)
2563                 {
2564                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2565                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2566                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2567
2568                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2569                                 Unfreeze(this);
2570                 }
2571                 else if (STAT(FROZEN, this) == 3)
2572                 {
2573                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2574                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2575
2576                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2577                         {
2578                                 if (this.vehicle)
2579                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2580                                 if(this.event_damage)
2581                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2582                         }
2583                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2584                                 Unfreeze(this);
2585                 }
2586         }
2587
2588         MUTATOR_CALLHOOK(PlayerPreThink, this);
2589
2590         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2591         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2592         {
2593                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2594                 {
2595                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2596                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2597                         {
2598                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2599                         }
2600                         else if(!it.owner)
2601                         {
2602                                 if(!it.team || SAME_TEAM(this, it))
2603                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2604                                 else if(autocvar_g_vehicles_steal)
2605                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2606                         }
2607                 });
2608
2609                 this.last_vehiclecheck = time + 1;
2610         }
2611
2612         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2613         {
2614                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2615                         PlayerUseKey(this);
2616                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2617         }
2618
2619         if (IS_REAL_CLIENT(this))
2620                 PrintWelcomeMessage(this);
2621
2622         if (IS_PLAYER(this)) {
2623                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2624                         error("Client can't be spawned as player on connection!");
2625                 if(!PlayerThink(this))
2626                         return;
2627         }
2628         else if (game_stopped || intermission_running) {
2629                 if(intermission_running)
2630                         IntermissionThink(this);
2631                 return;
2632         }
2633         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2634         {
2635                 CS(this).autojoin_checked = true;
2636                 // don't do this in ClientConnect
2637                 // many things can go wrong if a client is spawned as player on connection
2638                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2639                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2640                                 && (!teamplay || autocvar_g_balance_teams)))
2641                 {
2642                         campaign_bots_may_start = true;
2643                         Join(this);
2644                         return;
2645                 }
2646         }
2647         else if (IS_OBSERVER(this)) {
2648                 ObserverThink(this);
2649         }
2650         else if (IS_SPEC(this)) {
2651                 SpectatorThink(this);
2652         }
2653
2654         // WEAPONTODO: Add weapon request for this
2655         if (!zoomstate_set) {
2656                 bool wep_zoomed = false;
2657                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2658                 {
2659                         .entity weaponentity = weaponentities[slot];
2660                         Weapon thiswep = this.(weaponentity).m_weapon;
2661                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2662                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2663                 }
2664                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2665     }
2666
2667         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2668         {
2669                 CS(this).teamkill_soundtime = 0;
2670
2671                 entity e = CS(this).teamkill_soundsource;
2672                 entity oldpusher = e.pusher;
2673                 e.pusher = this;
2674                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2675                 e.pusher = oldpusher;
2676         }
2677
2678         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2679                 CS(this).taunt_soundtime = 0;
2680                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2681         }
2682
2683         target_voicescript_next(this);
2684
2685         // WEAPONTODO: Move into weaponsystem somehow
2686         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2687         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2688         {
2689                 .entity weaponentity = weaponentities[slot];
2690                 if(this.(weaponentity).m_weapon == WEP_Null)
2691                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2692         }
2693 }
2694
2695 void DrownPlayer(entity this)
2696 {
2697         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2698                 return;
2699
2700         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2701         {
2702                 if(this.air_finished < time)
2703                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2704                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2705         }
2706         else if (this.air_finished < time)
2707         {       // drown!
2708                 if (this.pain_finished < time)
2709                 {
2710                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2711                         this.pain_finished = time + 0.5;
2712                 }
2713         }
2714 }
2715
2716 .bool move_qcphysics;
2717
2718 void Player_Physics(entity this)
2719 {
2720         set_movetype(this, this.move_movetype);
2721
2722         if(!this.move_qcphysics)
2723                 return;
2724
2725         if(!frametime && !CS(this).pm_frametime)
2726                 return;
2727
2728         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2729
2730         CS(this).pm_frametime = 0;
2731 }
2732
2733 /*
2734 =============
2735 PlayerPostThink
2736
2737 Called every frame for each client after the physics are run
2738 =============
2739 */
2740 void PlayerPostThink (entity this)
2741 {
2742         Player_Physics(this);
2743
2744         if (sv_maxidle > 0)
2745         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2746         if (IS_REAL_CLIENT(this))
2747         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2748         {
2749                 int totalClients = 0;
2750                 if(sv_maxidle_slots > 0)
2751                 {
2752                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2753                         {
2754                                 ++totalClients;
2755                         });
2756                 }
2757
2758                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2759                 { /* do nothing */ }
2760                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2761                 {
2762                         if (CS(this).idlekick_lasttimeleft)
2763                         {
2764                                 CS(this).idlekick_lasttimeleft = 0;
2765                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2766                         }
2767                 }
2768                 else
2769                 {
2770                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2771                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2772                                 if (!CS(this).idlekick_lasttimeleft)
2773                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2774                         }
2775                         if (timeleft <= 0) {
2776                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2777                                 dropclient(this);
2778                                 return;
2779                         }
2780                         else if (timeleft <= 10) {
2781                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2782                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2783                 }
2784                                 CS(this).idlekick_lasttimeleft = timeleft;
2785                         }
2786                 }
2787         }
2788
2789         CheatFrame(this);
2790
2791         if (game_stopped)
2792         {
2793                 this.solid = SOLID_NOT;
2794                 this.takedamage = DAMAGE_NO;
2795                 set_movetype(this, MOVETYPE_NONE);
2796         }
2797
2798         if (IS_PLAYER(this)) {
2799                 if(this.death_time == time && IS_DEAD(this))
2800                 {
2801                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2802                         // once all the damage events of this frame have been processed with normal size
2803                         this.maxs.z = 5;
2804                         setsize(this, this.mins, this.maxs);
2805                 }
2806                 DrownPlayer(this);
2807                 UpdateChatBubble(this);
2808                 if (CS(this).impulse) ImpulseCommands(this);
2809                 if (game_stopped)
2810                 {
2811                         CSQCMODEL_AUTOUPDATE(this);
2812                         return;
2813                 }
2814                 GetPressedKeys(this);
2815         }
2816
2817         if (this.waypointsprite_attachedforcarrier) {
2818             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2819                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2820     }
2821
2822         playerdemo_write(this);
2823
2824         CSQCMODEL_AUTOUPDATE(this);
2825 }
2826
2827 // hack to copy the button fields from the client entity to the Client State
2828 void PM_UpdateButtons(entity this, entity store)
2829 {
2830         if(this.impulse)
2831                 store.impulse = this.impulse;
2832         this.impulse = 0;
2833
2834         bool typing = this.buttonchat;
2835
2836         store.button0 = (typing) ? 0 : this.button0;
2837         //button1?!
2838         store.button2 = (typing) ? 0 : this.button2;
2839         store.button3 = (typing) ? 0 : this.button3;
2840         store.button4 = this.button4;
2841         store.button5 = (typing) ? 0 : this.button5;
2842         store.button6 = this.button6;
2843         store.button7 = this.button7;
2844         store.button8 = this.button8;
2845         store.button9 = this.button9;
2846         store.button10 = this.button10;
2847         store.button11 = this.button11;
2848         store.button12 = this.button12;
2849         store.button13 = this.button13;
2850         store.button14 = this.button14;
2851         store.button15 = this.button15;
2852         store.button16 = this.button16;
2853         store.buttonuse = this.buttonuse;
2854         store.buttonchat = this.buttonchat;
2855
2856         store.cursor_active = this.cursor_active;
2857         store.cursor_screen = this.cursor_screen;
2858         store.cursor_trace_start = this.cursor_trace_start;
2859         store.cursor_trace_endpos = this.cursor_trace_endpos;
2860         store.cursor_trace_ent = this.cursor_trace_ent;
2861
2862         store.ping = this.ping;
2863         store.ping_packetloss = this.ping_packetloss;
2864         store.ping_movementloss = this.ping_movementloss;
2865
2866         store.v_angle = this.v_angle;
2867         store.movement = (typing) ? '0 0 0' : this.movement;
2868 }
2869
2870 NET_HANDLE(fpsreport, bool)
2871 {
2872         int fps = ReadShort();
2873         PlayerScore_Set(sender, SP_FPS, fps);
2874         return true;
2875 }