qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357 }
 358
 359 int player_getspecies(entity this)
 360 {
 361         get_model_parameters(this.model, this.skin);
 362         int s = get_model_parameters_species;
 363         get_model_parameters(string_null, 0);
 364         if (s < 0) return SPECIES_HUMAN;
 365         return s;
 366 }
 367
 368 .float model_randomizer;
 369 void FixPlayermodel(entity player)
 370 {
 371         string defaultmodel = "";
 372         int defaultskin = 0;
 373         if(autocvar_sv_defaultcharacter)
 374         {
 375                 if(teamplay)
 376                 {
 377                         string s = Static_Team_ColorName_Lower(player.team);
 378                         if (s != "neutral")
 379                         {
 380                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 381                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 382                         }
 383                 }
 384
 385                 if(defaultmodel == "")
 386                 {
 387                         defaultmodel = autocvar_sv_defaultplayermodel;
 388                         defaultskin = autocvar_sv_defaultplayerskin;
 389                 }
 390
 391                 int n = tokenize_console(defaultmodel);
 392                 if(n > 0)
 393                 {
 394                         defaultmodel = argv(floor(n * player.model_randomizer));
 395                         // However, do NOT randomize if the player-selected model is in the list.
 396                         for (int i = 0; i < n; ++i)
 397                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 398                                         defaultmodel = argv(i);
 399                 }
 400
 401                 int i = strstrofs(defaultmodel, ":", 0);
 402                 if(i >= 0)
 403                 {
 404                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 405                         defaultmodel = substring(defaultmodel, 0, i);
 406                 }
 407         }
 408         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 409         {
 410                 if(teamplay)
 411                 {
 412                         string s = Static_Team_ColorName_Lower(player.team);
 413                         if (s != "neutral")
 414                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 415                 }
 416
 417                 if(!defaultskin)
 418                         defaultskin = autocvar_sv_defaultplayerskin;
 419         }
 420
 421         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 422         defaultmodel = M_ARGV(0, string);
 423         defaultskin = M_ARGV(1, int);
 424
 425         bool chmdl = false;
 426         int oldskin;
 427         if(defaultmodel != "")
 428         {
 429                 if (defaultmodel != player.model)
 430                 {
 431                         vector m1 = player.mins;
 432                         vector m2 = player.maxs;
 433                         setplayermodel (player, defaultmodel);
 434                         setsize (player, m1, m2);
 435                         chmdl = true;
 436                 }
 437
 438                 oldskin = player.skin;
 439                 player.skin = defaultskin;
 440         } else {
 441                 if (player.playermodel != player.model || player.playermodel == "")
 442                 {
 443                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 444                         vector m1 = player.mins;
 445                         vector m2 = player.maxs;
 446                         setplayermodel (player, player.playermodel);
 447                         setsize (player, m1, m2);
 448                         chmdl = true;
 449                 }
 450
 451                 if(!autocvar_sv_defaultcharacterskin)
 452                 {
 453                         oldskin = player.skin;
 454                         player.skin = stof(player.playerskin);
 455                 }
 456                 else
 457                 {
 458                         oldskin = player.skin;
 459                         player.skin = defaultskin;
 460                 }
 461         }
 462
 463         if(chmdl || oldskin != player.skin) // model or skin has changed
 464         {
 465                 player.species = player_getspecies(player); // update species
 466                 if(!autocvar_g_debug_globalsounds)
 467                         UpdatePlayerSounds(player); // update skin sounds
 468         }
 469
 470         if(!teamplay)
 471                 if(strlen(autocvar_sv_defaultplayercolors))
 472                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 473                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 474 }
 475
 476
 477 /** Called when a client spawns in the server */
 478 void PutClientInServer(entity this)
 479 {
 480         if (IS_BOT_CLIENT(this)) {
 481                 TRANSMUTE(Player, this);
 482         } else if (IS_REAL_CLIENT(this)) {
 483                 msg_entity = this;
 484                 WriteByte(MSG_ONE, SVC_SETVIEW);
 485                 WriteEntity(MSG_ONE, this);
 486         }
 487         if (game_stopped)
 488                 TRANSMUTE(Observer, this);
 489
 490         SetSpectatee(this, NULL);
 491
 492         // reset player keys
 493         this.itemkeys = 0;
 494
 495         MUTATOR_CALLHOOK(PutClientInServer, this);
 496
 497         if (IS_OBSERVER(this)) {
 498                 PutObserverInServer(this);
 499         } else if (IS_PLAYER(this)) {
 500                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 501
 502                 PlayerState_attach(this);
 503                 accuracy_resend(this);
 504
 505                 if (this.team < 0)
 506                         JoinBestTeam(this, false, true);
 507
 508                 entity spot = SelectSpawnPoint(this, false);
 509                 if (!spot) {
 510                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 511                         return; // spawn failed
 512                 }
 513
 514                 TRANSMUTE(Player, this);
 515
 516                 this.wasplayer = true;
 517                 this.iscreature = true;
 518                 this.teleportable = TELEPORT_NORMAL;
 519                 if(!this.damagedbycontents)
 520                         IL_PUSH(g_damagedbycontents, this);
 521                 this.damagedbycontents = true;
 522                 set_movetype(this, MOVETYPE_WALK);
 523                 this.solid = SOLID_SLIDEBOX;
 524                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 525                 if (autocvar_g_playerclip_collisions)
 526                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 527                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 528                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 529                 this.frags = FRAGS_PLAYER;
 530                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 531                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 532                 if (autocvar__notarget)
 533                         this.flags |= FL_NOTARGET;
 534                 this.takedamage = DAMAGE_AIM;
 535                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 536                 this.dmg = 2; // WTF
 537
 538                 if (warmup_stage) {
 539                         this.ammo_shells = warmup_start_ammo_shells;
 540                         this.ammo_nails = warmup_start_ammo_nails;
 541                         this.ammo_rockets = warmup_start_ammo_rockets;
 542                         this.ammo_cells = warmup_start_ammo_cells;
 543                         this.ammo_plasma = warmup_start_ammo_plasma;
 544                         this.ammo_fuel = warmup_start_ammo_fuel;
 545                         this.health = warmup_start_health;
 546                         this.armorvalue = warmup_start_armorvalue;
 547                         this.weapons = WARMUP_START_WEAPONS;
 548                 } else {
 549                         this.ammo_shells = start_ammo_shells;
 550                         this.ammo_nails = start_ammo_nails;
 551                         this.ammo_rockets = start_ammo_rockets;
 552                         this.ammo_cells = start_ammo_cells;
 553                         this.ammo_plasma = start_ammo_plasma;
 554                         this.ammo_fuel = start_ammo_fuel;
 555                         this.health = start_health;
 556                         this.armorvalue = start_armorvalue;
 557                         this.weapons = start_weapons;
 558                 }
 559                 SetSpectatee_status(this, 0);
 560
 561                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 562
 563                 this.items = start_items;
 564
 565                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 566                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 567                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 568                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 569                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 570                 // extend the pause of rotting if client was reset at the beginning of the countdown
 571                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 572                         float f = game_starttime - time;
 573                         this.spawnshieldtime += f;
 574                         this.pauserotarmor_finished += f;
 575                         this.pauserothealth_finished += f;
 576                         this.pauseregen_finished += f;
 577                 }
 578                 this.damageforcescale = 2;
 579                 this.death_time = 0;
 580                 this.respawn_flags = 0;
 581                 this.respawn_time = 0;
 582                 this.stat_respawn_time = 0;
 583                 this.scale = autocvar_sv_player_scale;
 584                 this.fade_time = 0;
 585                 this.pain_frame = 0;
 586                 this.pain_finished = 0;
 587                 this.pushltime = 0;
 588                 setthink(this, func_null); // players have no think function
 589                 this.nextthink = 0;
 590                 this.dmg_team = 0;
 591                 this.ballistics_density = autocvar_g_ballistics_density_player;
 592
 593                 this.deadflag = DEAD_NO;
 594
 595                 this.angles = spot.angles;
 596                 this.angles_z = 0; // never spawn tilted even if the spot says to
 597                 if (IS_BOT_CLIENT(this))
 598                         this.v_angle = this.angles;
 599                 this.fixangle = true; // turn this way immediately
 600                 this.oldvelocity = this.velocity = '0 0 0';
 601                 this.avelocity = '0 0 0';
 602                 this.punchangle = '0 0 0';
 603                 this.punchvector = '0 0 0';
 604
 605                 this.strength_finished = 0;
 606                 this.invincible_finished = 0;
 607                 this.fire_endtime = -1;
 608                 this.revive_progress = 0;
 609                 this.revival_time = 0;
 610                 this.air_finished = time + 12;
 611
 612                 entity spawnevent = new_pure(spawnevent);
 613                 spawnevent.owner = this;
 614                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 615
 616                 // Cut off any still running player sounds.
 617                 stopsound(this, CH_PLAYER_SINGLE);
 618
 619                 this.model = "";
 620                 FixPlayermodel(this);
 621                 this.drawonlytoclient = NULL;
 622
 623                 this.viewloc = NULL;
 624
 625                 this.crouch = false;
 626                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 627                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 628                 this.spawnorigin = spot.origin;
 629                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 630                 // don't reset back to last position, even if new position is stuck in solid
 631                 this.oldorigin = this.origin;
 632                 this.prevorigin = this.origin;
 633                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 634                 if(this.conveyor)
 635                         IL_REMOVE(g_conveyed, this);
 636                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 637                 this.hud = HUD_NORMAL;
 638
 639                 this.event_damage = PlayerDamage;
 640
 641                 if(!this.bot_attack)
 642                         IL_PUSH(g_bot_targets, this);
 643                 this.bot_attack = true;
 644                 this.monster_attack = true;
 645
 646                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 647
 648                 if (this.killcount == FRAGS_SPECTATOR) {
 649                         PlayerScore_Clear(this);
 650                         this.killcount = 0;
 651                 }
 652
 653                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 654                 {
 655                         .entity weaponentity = weaponentities[slot];
 656                         CL_SpawnWeaponentity(this, weaponentity);
 657                 }
 658                 this.alpha = default_player_alpha;
 659                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 660                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 661
 662                 this.speedrunning = false;
 663
 664                 target_voicescript_clear(this);
 665
 666                 // reset fields the weapons may use
 667                 FOREACH(Weapons, true, LAMBDA(
 668                         it.wr_resetplayer(it, this);
 669                         // reload all reloadable weapons
 670                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 671                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 672                                 {
 673                                         .entity weaponentity = weaponentities[slot];
 674                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 675                                 }
 676                         }
 677                 ));
 678
 679                 {
 680                         string s = spot.target;
 681                         spot.target = string_null;
 682                         SUB_UseTargets(spot, this, NULL);
 683                         spot.target = s;
 684                 }
 685
 686                 Unfreeze(this);
 687
 688                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 689
 690                 if (autocvar_spawn_debug)
 691                 {
 692                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 693                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 694                 }
 695
 696                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 697                 {
 698                         .entity weaponentity = weaponentities[slot];
 699                         if(slot == 0)
 700                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 701                         else
 702                                 this.(weaponentity).m_switchweapon = WEP_Null;
 703                         this.(weaponentity).m_weapon = WEP_Null;
 704                         this.(weaponentity).weaponname = "";
 705                         this.(weaponentity).m_switchingweapon = WEP_Null;
 706                         this.(weaponentity).cnt = -1;
 707                 }
 708
 709                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 710
 711                 if (!warmup_stage && !this.alivetime)
 712                         this.alivetime = time;
 713
 714                 antilag_clear(this, CS(this));
 715         }
 716 }
 717
 718 void ClientInit_misc(entity this);
 719
 720 // TODO do we need all these fields, or should we stop autodetecting runtime
 721 // changes and just have a console command to update this?
 722 bool ClientInit_SendEntity(entity this, entity to, int sf)
 723 {
 724         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 725         return = true;
 726         msg_entity = to;
 727         // MSG_INIT replacement
 728         // TODO: make easier to use
 729         Registry_send_all();
 730         W_PROP_reload(MSG_ONE, to);
 731         ClientInit_misc(this);
 732         MUTATOR_CALLHOOK(Ent_Init);
 733 }
 734 void ClientInit_misc(entity this)
 735 {
 736         int channel = MSG_ONE;
 737         WriteHeader(channel, ENT_CLIENT_INIT);
 738         WriteByte(channel, g_nexball_meter_period * 32);
 739         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 741         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 742         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 743         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 745         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 746         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 747
 748         if(sv_foginterval && world.fog != "")
 749                 WriteString(channel, world.fog);
 750         else
 751                 WriteString(channel, "");
 752         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 753         WriteByte(channel, serverflags);
 754         WriteCoord(channel, autocvar_g_trueaim_minrange);
 755 }
 756
 757 void ClientInit_CheckUpdate(entity this)
 758 {
 759         this.nextthink = time;
 760         if(this.count != autocvar_g_balance_armor_blockpercent)
 761         {
 762                 this.count = autocvar_g_balance_armor_blockpercent;
 763                 this.SendFlags |= 1;
 764         }
 765 }
 766
 767 void ClientInit_Spawn()
 768 {
 769         entity e = new_pure(clientinit);
 770         setthink(e, ClientInit_CheckUpdate);
 771         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 772
 773         ClientInit_CheckUpdate(e);
 774 }
 775
 776 /*
 777 =============
 778 SetNewParms
 779 =============
 780 */
 781 void SetNewParms ()
 782 {
 783         // initialize parms for a new player
 784         parm1 = -(86400 * 366);
 785
 786         MUTATOR_CALLHOOK(SetNewParms);
 787 }
 788
 789 /*
 790 =============
 791 SetChangeParms
 792 =============
 793 */
 794 void SetChangeParms (entity this)
 795 {
 796         // save parms for level change
 797         parm1 = this.parm_idlesince - time;
 798
 799         MUTATOR_CALLHOOK(SetChangeParms);
 800 }
 801
 802 /*
 803 =============
 804 DecodeLevelParms
 805 =============
 806 */
 807 void DecodeLevelParms(entity this)
 808 {
 809         // load parms
 810         this.parm_idlesince = parm1;
 811         if (this.parm_idlesince == -(86400 * 366))
 812                 this.parm_idlesince = time;
 813
 814         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 815         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 816
 817         MUTATOR_CALLHOOK(DecodeLevelParms);
 818 }
 819
 820 /*
 821 =============
 822 ClientKill
 823
 824 Called when a client types 'kill' in the console
 825 =============
 826 */
 827
 828 .float clientkill_nexttime;
 829 void ClientKill_Now_TeamChange(entity this)
 830 {
 831         if(this.killindicator_teamchange == -1)
 832         {
 833                 JoinBestTeam( this, false, true );
 834         }
 835         else if(this.killindicator_teamchange == -2)
 836         {
 837                 if(blockSpectators)
 838                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 839                 PutObserverInServer(this);
 840         }
 841         else
 842                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 843         this.killindicator_teamchange = 0;
 844 }
 845
 846 void ClientKill_Now(entity this)
 847 {
 848         if(this.vehicle)
 849         {
 850             vehicles_exit(this.vehicle, VHEF_RELEASE);
 851             if(!this.killindicator_teamchange)
 852             {
 853             this.vehicle_health = -1;
 854             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 855             }
 856         }
 857
 858         if(this.killindicator && !wasfreed(this.killindicator))
 859                 delete(this.killindicator);
 860
 861         this.killindicator = NULL;
 862
 863         if(this.killindicator_teamchange)
 864                 ClientKill_Now_TeamChange(this);
 865
 866         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 867                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 868
 869         // now I am sure the player IS dead
 870 }
 871 void KillIndicator_Think(entity this)
 872 {
 873         if (game_stopped)
 874         {
 875                 this.owner.killindicator = NULL;
 876                 delete(this);
 877                 return;
 878         }
 879
 880         if (this.owner.alpha < 0 && !this.owner.vehicle)
 881         {
 882                 this.owner.killindicator = NULL;
 883                 delete(this);
 884                 return;
 885         }
 886
 887         if(this.cnt <= 0)
 888         {
 889                 ClientKill_Now(this.owner);
 890                 return;
 891         }
 892     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 893     {
 894         this.nextthink = time + 1;
 895         this.cnt -= 1;
 896     }
 897         else
 898         {
 899                 if(this.cnt <= 10)
 900                         setmodel(this, MDL_NUM(this.cnt));
 901                 if(IS_REAL_CLIENT(this.owner))
 902                 {
 903                         if(this.cnt <= 10)
 904                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 905                 }
 906                 this.nextthink = time + 1;
 907                 this.cnt -= 1;
 908         }
 909 }
 910
 911 float clientkilltime;
 912 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 913 {
 914         float killtime;
 915         float starttime;
 916
 917         if (game_stopped)
 918                 return;
 919
 920         killtime = autocvar_g_balance_kill_delay;
 921
 922         if(g_race_qualifying || g_cts)
 923                 killtime = 0;
 924
 925     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 926         return;
 927
 928         this.killindicator_teamchange = targetteam;
 929
 930     if(!this.killindicator)
 931         {
 932                 if(!IS_DEAD(this))
 933                 {
 934                         killtime = max(killtime, this.clientkill_nexttime - time);
 935                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 936                 }
 937
 938                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 939                 {
 940                         ClientKill_Now(this);
 941                 }
 942                 else
 943                 {
 944                         starttime = max(time, clientkilltime);
 945
 946                         this.killindicator = spawn();
 947                         this.killindicator.owner = this;
 948                         this.killindicator.scale = 0.5;
 949                         setattachment(this.killindicator, this, "");
 950                         setorigin(this.killindicator, '0 0 52');
 951                         setthink(this.killindicator, KillIndicator_Think);
 952                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 953                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 954                         this.killindicator.cnt = ceil(killtime);
 955                         this.killindicator.count = bound(0, ceil(killtime), 10);
 956                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 957
 958                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 959                         {
 960                                 it.killindicator = spawn();
 961                                 it.killindicator.owner = it;
 962                                 it.killindicator.scale = 0.5;
 963                                 setattachment(it.killindicator, it, "");
 964                                 setorigin(it.killindicator, '0 0 52');
 965                                 setthink(it.killindicator, KillIndicator_Think);
 966                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 967                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 968                                 it.killindicator.cnt = ceil(killtime);
 969                         });
 970                         this.lip = 0;
 971                 }
 972         }
 973         if(this.killindicator)
 974         {
 975                 if(targetteam == 0) // just die
 976                 {
 977                         this.killindicator.colormod = '0 0 0';
 978                         if(IS_REAL_CLIENT(this))
 979                         if(this.killindicator.cnt > 0)
 980                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 981                 }
 982                 else if(targetteam == -1) // auto
 983                 {
 984                         this.killindicator.colormod = '0 1 0';
 985                         if(IS_REAL_CLIENT(this))
 986                         if(this.killindicator.cnt > 0)
 987                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 988                 }
 989                 else if(targetteam == -2) // spectate
 990                 {
 991                         this.killindicator.colormod = '0.5 0.5 0.5';
 992                         if(IS_REAL_CLIENT(this))
 993                         if(this.killindicator.cnt > 0)
 994                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 995                 }
 996                 else
 997                 {
 998                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 999                         if(IS_REAL_CLIENT(this))
1000                         if(this.killindicator.cnt > 0)
1001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1002                 }
1003         }
1004
1005 }
1006
1007 void ClientKill (entity this)
1008 {
1009         if(game_stopped) return;
1010         if(this.player_blocked) return;
1011         if(STAT(FROZEN, this)) return;
1012
1013         ClientKill_TeamChange(this, 0);
1014 }
1015
1016 void FixClientCvars(entity e)
1017 {
1018         // send prediction settings to the client
1019         stuffcmd(e, "\nin_bindmap 0 0\n");
1020         if(autocvar_g_antilag == 3) // client side hitscan
1021                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1022         if(autocvar_sv_gentle)
1023                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1024
1025         MUTATOR_CALLHOOK(FixClientCvars, e);
1026 }
1027
1028 float PlayerInIDList(entity p, string idlist)
1029 {
1030         float n, i;
1031         string s;
1032
1033         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1034         if (!p.crypto_idfp)
1035                 return 0;
1036
1037         // this function allows abbreviated player IDs too!
1038         n = tokenize_console(idlist);
1039         for(i = 0; i < n; ++i)
1040         {
1041                 s = argv(i);
1042                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1043                         return 1;
1044         }
1045
1046         return 0;
1047 }
1048
1049 #ifdef DP_EXT_PRECONNECT
1050 /*
1051 =============
1052 ClientPreConnect
1053
1054 Called once (not at each match start) when a client begins a connection to the server
1055 =============
1056 */
1057 void ClientPreConnect(entity this)
1058 {
1059         if(autocvar_sv_eventlog)
1060         {
1061                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1062                         this.playerid,
1063                         etof(this),
1064                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1065                 ));
1066         }
1067 }
1068 #endif
1069
1070 /**
1071 =============
1072 ClientConnect
1073
1074 Called when a client connects to the server
1075 =============
1076 */
1077 void ClientConnect(entity this)
1078 {
1079         if (Ban_MaybeEnforceBanOnce(this)) return;
1080         assert(!IS_CLIENT(this), return);
1081         this.flags |= FL_CLIENT;
1082         assert(player_count >= 0, player_count = 0);
1083
1084 #ifdef WATERMARK
1085         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1086 #endif
1087         this.version_nagtime = time + 10 + random() * 10;
1088         TRANSMUTE(Client, this);
1089
1090         // identify the right forced team
1091         if (autocvar_g_campaign)
1092         {
1093                 if (IS_REAL_CLIENT(this)) // only players, not bots
1094                 {
1095                         switch (autocvar_g_campaign_forceteam)
1096                         {
1097                                 case 1: this.team_forced = NUM_TEAM_1; break;
1098                                 case 2: this.team_forced = NUM_TEAM_2; break;
1099                                 case 3: this.team_forced = NUM_TEAM_3; break;
1100                                 case 4: this.team_forced = NUM_TEAM_4; break;
1101                                 default: this.team_forced = 0;
1102                         }
1103                 }
1104         }
1105         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1107         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1108         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1109         else switch (autocvar_g_forced_team_otherwise)
1110         {
1111                 default: this.team_forced = 0; break;
1112                 case "red": this.team_forced = NUM_TEAM_1; break;
1113                 case "blue": this.team_forced = NUM_TEAM_2; break;
1114                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1115                 case "pink": this.team_forced = NUM_TEAM_4; break;
1116                 case "spectate":
1117                 case "spectator":
1118                         this.team_forced = -1;
1119                         break;
1120         }
1121         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1122
1123     {
1124         int id = this.playerid;
1125         this.playerid = 0; // silent
1126             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1127             this.playerid = id;
1128     }
1129
1130         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1131                 TRANSMUTE(Observer, this);
1132         } else {
1133                 if (!teamplay || autocvar_g_balance_teams) {
1134                         TRANSMUTE(Player, this);
1135                         campaign_bots_may_start = true;
1136                 } else {
1137                         TRANSMUTE(Observer, this); // do it anyway
1138                 }
1139         }
1140
1141         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1142
1143         // always track bots, don't ask for cl_allow_uidtracking
1144     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1145
1146         if (autocvar_sv_eventlog)
1147                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1148
1149         LogTeamchange(this.playerid, this.team, 1);
1150
1151         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1152
1153         this.netname_previous = strzone(this.netname);
1154
1155         if(teamplay && IS_PLAYER(this))
1156                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1157         else
1158                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1159
1160         stuffcmd(this, clientstuff, "\n");
1161         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1162
1163         FixClientCvars(this);
1164
1165         // get version info from player
1166         stuffcmd(this, "cmd clientversion $gameversion\n");
1167
1168         // notify about available teams
1169         if (teamplay)
1170         {
1171                 CheckAllowedTeams(this);
1172                 int t = 0;
1173                 if (c1 >= 0) t |= BIT(0);
1174                 if (c2 >= 0) t |= BIT(1);
1175                 if (c3 >= 0) t |= BIT(2);
1176                 if (c4 >= 0) t |= BIT(3);
1177                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1178         }
1179         else
1180         {
1181                 stuffcmd(this, "set _teams_available 0\n");
1182         }
1183
1184         bot_relinkplayerlist();
1185
1186         this.spectatortime = time;
1187         if (blockSpectators)
1188         {
1189                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1190         }
1191
1192         this.jointime = time;
1193         this.allowed_timeouts = autocvar_sv_timeout_number;
1194
1195         if (IS_REAL_CLIENT(this))
1196         {
1197                 if (g_weaponarena_weapons == WEPSET(TUBA))
1198                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1199         }
1200
1201         if (!sv_foginterval && world.fog != "")
1202                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1203
1204         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1205                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1206                         send_CSQC_teamnagger();
1207
1208         CSQCMODEL_AUTOINIT(this);
1209
1210         this.model_randomizer = random();
1211
1212         if (IS_REAL_CLIENT(this))
1213                 sv_notice_join(this);
1214
1215         // update physics stats (players can spawn before physics runs)
1216         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1217
1218         IL_EACH(g_initforplayer, it.init_for_player, {
1219                 it.init_for_player(it, this);
1220         });
1221
1222         MUTATOR_CALLHOOK(ClientConnect, this);
1223
1224         if (IS_REAL_CLIENT(this))
1225         {
1226                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1227                 {
1228                         this.motd_actived_time = -1;
1229                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1230                 }
1231         }
1232 }
1233 /*
1234 =============
1235 ClientDisconnect
1236
1237 Called when a client disconnects from the server
1238 =============
1239 */
1240 .entity chatbubbleentity;
1241 void ReadyCount();
1242 void ClientDisconnect(entity this)
1243 {
1244         assert(IS_CLIENT(this), return);
1245
1246         PlayerStats_GameReport_FinalizePlayer(this);
1247         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1248         if (this.active_minigame) part_minigame(this);
1249         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1250
1251         if (autocvar_sv_eventlog)
1252                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1253
1254         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1255
1256         SetSpectatee(this, NULL);
1257
1258     MUTATOR_CALLHOOK(ClientDisconnect, this);
1259
1260         ClientState_detach(this);
1261
1262         Portal_ClearAll(this);
1263
1264         Unfreeze(this);
1265
1266         RemoveGrapplingHooks(this);
1267
1268         // Here, everything has been done that requires this player to be a client.
1269
1270         this.flags &= ~FL_CLIENT;
1271
1272         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1273         if (this.killindicator) delete(this.killindicator);
1274
1275         WaypointSprite_PlayerGone(this);
1276
1277         bot_relinkplayerlist();
1278
1279         if (this.netname_previous) strunzone(this.netname_previous);
1280         if (this.clientstatus) strunzone(this.clientstatus);
1281         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1282         if (this.personal) delete(this.personal);
1283
1284         this.playerid = 0;
1285         ReadyCount();
1286         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1287
1288         ONREMOVE(this);
1289 }
1290
1291 void ChatBubbleThink(entity this)
1292 {
1293         this.nextthink = time;
1294         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1295         {
1296                 if(this.owner) // but why can that ever be NULL?
1297                         this.owner.chatbubbleentity = NULL;
1298                 delete(this);
1299                 return;
1300         }
1301
1302         this.mdl = "";
1303
1304         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1305         {
1306                 if ( this.owner.active_minigame )
1307                         this.mdl = "models/sprites/minigame_busy.iqm";
1308                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1309                         this.mdl = "models/misc/chatbubble.spr";
1310         }
1311
1312         if ( this.model != this.mdl )
1313                 _setmodel(this, this.mdl);
1314
1315 }
1316
1317 void UpdateChatBubble(entity this)
1318 {
1319         if (this.alpha < 0)
1320                 return;
1321         // spawn a chatbubble entity if needed
1322         if (!this.chatbubbleentity)
1323         {
1324                 this.chatbubbleentity = new(chatbubbleentity);
1325                 this.chatbubbleentity.owner = this;
1326                 this.chatbubbleentity.exteriormodeltoclient = this;
1327                 setthink(this.chatbubbleentity, ChatBubbleThink);
1328                 this.chatbubbleentity.nextthink = time;
1329                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1330                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1331                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1332                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1333                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1334                 //this.chatbubbleentity.model = "";
1335                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1336         }
1337 }
1338
1339
1340 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1341 // added to the model skins
1342 /*void UpdateColorModHack()
1343 {
1344         float c;
1345         c = this.clientcolors & 15;
1346         // LordHavoc: only bothering to support white, green, red, yellow, blue
1347              if (!teamplay) this.colormod = '0 0 0';
1348         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1349         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1350         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1351         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1352         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1353         else this.colormod = '1 1 1';
1354 }*/
1355
1356 void respawn(entity this)
1357 {
1358         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1359         {
1360                 this.solid = SOLID_NOT;
1361                 this.takedamage = DAMAGE_NO;
1362                 set_movetype(this, MOVETYPE_FLY);
1363                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1364                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1365                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1366                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1367                 if(autocvar_g_respawn_ghosts_maxtime)
1368                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1369         }
1370
1371         CopyBody(this, 1);
1372
1373         this.effects |= EF_NODRAW; // prevent another CopyBody
1374         PutClientInServer(this);
1375 }
1376
1377 void play_countdown(entity this, float finished, Sound samp)
1378 {
1379     TC(Sound, samp);
1380         if(IS_REAL_CLIENT(this))
1381                 if(floor(finished - time - frametime) != floor(finished - time))
1382                         if(finished - time < 6)
1383                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1384 }
1385
1386 void player_powerups(entity this)
1387 {
1388         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1389         int items_prev = this.items;
1390
1391         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1392                 this.modelflags |= MF_ROCKET;
1393         else
1394                 this.modelflags &= ~MF_ROCKET;
1395
1396         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1397
1398         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1399                 return;
1400
1401         Fire_ApplyDamage(this);
1402         Fire_ApplyEffect(this);
1403
1404         if (!g_instagib)
1405         {
1406                 if (this.items & ITEM_Strength.m_itemid)
1407                 {
1408                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1409                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1410                         if (time > this.strength_finished)
1411                         {
1412                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1413                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1414                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1415                         }
1416                 }
1417                 else
1418                 {
1419                         if (time < this.strength_finished)
1420                         {
1421                                 this.items = this.items | ITEM_Strength.m_itemid;
1422                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1423                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1424                         }
1425                 }
1426                 if (this.items & ITEM_Shield.m_itemid)
1427                 {
1428                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1429                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1430                         if (time > this.invincible_finished)
1431                         {
1432                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1433                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1434                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1435                         }
1436                 }
1437                 else
1438                 {
1439                         if (time < this.invincible_finished)
1440                         {
1441                                 this.items = this.items | ITEM_Shield.m_itemid;
1442                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1444                         }
1445                 }
1446                 if (this.items & IT_SUPERWEAPON)
1447                 {
1448                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1449                         {
1450                                 this.superweapons_finished = 0;
1451                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1452                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1453                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1454                         }
1455                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1456                         {
1457                                 // don't let them run out
1458                         }
1459                         else
1460                         {
1461                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1462                                 if (time > this.superweapons_finished)
1463                                 {
1464                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1465                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1466                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1467                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1468                                 }
1469                         }
1470                 }
1471                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1472                 {
1473                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1474                         {
1475                                 this.items = this.items | IT_SUPERWEAPON;
1476                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1478                         }
1479                         else
1480                         {
1481                                 this.superweapons_finished = 0;
1482                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1483                         }
1484                 }
1485                 else
1486                 {
1487                         this.superweapons_finished = 0;
1488                 }
1489         }
1490
1491         if(autocvar_g_nodepthtestplayers)
1492                 this.effects = this.effects | EF_NODEPTHTEST;
1493
1494         if(autocvar_g_fullbrightplayers)
1495                 this.effects = this.effects | EF_FULLBRIGHT;
1496
1497         if (time >= game_starttime)
1498         if (time < this.spawnshieldtime)
1499                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1500
1501         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1502 }
1503
1504 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1505 {
1506         if(current > stable)
1507                 return current;
1508         else if(current > stable - 0.25) // when close enough, "snap"
1509                 return stable;
1510         else
1511                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1512 }
1513
1514 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1515 {
1516         if(current < stable)
1517                 return current;
1518         else if(current < stable + 0.25) // when close enough, "snap"
1519                 return stable;
1520         else
1521                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1522 }
1523
1524 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1525 {
1526         if(current > rotstable)
1527         {
1528                 if(rotframetime > 0)
1529                 {
1530                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1531                         current = max(rotstable, current - rotlinear * rotframetime);
1532                 }
1533         }
1534         else if(current < regenstable)
1535         {
1536                 if(regenframetime > 0)
1537                 {
1538                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1539                         current = min(regenstable, current + regenlinear * regenframetime);
1540                 }
1541         }
1542
1543         if(current > limit)
1544                 current = limit;
1545
1546         return current;
1547 }
1548
1549 void player_regen(entity this)
1550 {
1551         float max_mod, regen_mod, rot_mod, limit_mod;
1552         max_mod = regen_mod = rot_mod = limit_mod = 1;
1553
1554         float regen_health = autocvar_g_balance_health_regen;
1555         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1556         float regen_health_rot = autocvar_g_balance_health_rot;
1557         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1558         float regen_health_stable = autocvar_g_balance_health_regenstable;
1559         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1560         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1561                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1562         max_mod = M_ARGV(1, float);
1563         regen_mod = M_ARGV(2, float);
1564         rot_mod = M_ARGV(3, float);
1565         limit_mod = M_ARGV(4, float);
1566         regen_health = M_ARGV(5, float);
1567         regen_health_linear = M_ARGV(6, float);
1568         regen_health_rot = M_ARGV(7, float);
1569         regen_health_rotlinear = M_ARGV(8, float);
1570         regen_health_stable = M_ARGV(9, float);
1571         regen_health_rotstable = M_ARGV(10, float);
1572
1573
1574         if(!mutator_returnvalue)
1575         if(!STAT(FROZEN, this))
1576         {
1577                 float mina, maxa, limith, limita;
1578                 maxa = autocvar_g_balance_armor_rotstable;
1579                 mina = autocvar_g_balance_armor_regenstable;
1580                 limith = autocvar_g_balance_health_limit;
1581                 limita = autocvar_g_balance_armor_limit;
1582
1583                 regen_health_rotstable = regen_health_rotstable * max_mod;
1584                 regen_health_stable = regen_health_stable * max_mod;
1585                 limith = limith * limit_mod;
1586                 limita = limita * limit_mod;
1587
1588                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1589                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1590         }
1591
1592         // if player rotted to death...  die!
1593         // check this outside above checks, as player may still be able to rot to death
1594         if(this.health < 1)
1595         {
1596                 if(this.vehicle)
1597                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1598                 if(this.event_damage)
1599                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1600         }
1601
1602         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1603         {
1604                 float minf, maxf, limitf;
1605
1606                 maxf = autocvar_g_balance_fuel_rotstable;
1607                 minf = autocvar_g_balance_fuel_regenstable;
1608                 limitf = autocvar_g_balance_fuel_limit;
1609
1610                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1611         }
1612 }
1613
1614 bool zoomstate_set;
1615 void SetZoomState(entity this, float newzoom)
1616 {
1617         if(newzoom != this.zoomstate)
1618         {
1619                 this.zoomstate = newzoom;
1620                 ClientData_Touch(this);
1621         }
1622         zoomstate_set = true;
1623 }
1624
1625 void GetPressedKeys(entity this)
1626 {
1627         MUTATOR_CALLHOOK(GetPressedKeys, this);
1628         int keys = STAT(PRESSED_KEYS, this);
1629         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1630         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1631         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1632         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1633
1634         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1635         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1636         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1637         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1638         this.pressedkeys = keys; // store for other users
1639
1640         STAT(PRESSED_KEYS, this) = keys;
1641 }
1642
1643 /*
1644 ======================
1645 spectate mode routines
1646 ======================
1647 */
1648
1649 void SpectateCopy(entity this, entity spectatee)
1650 {
1651     TC(Client, this); TC(Client, spectatee);
1652
1653         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1654         PS(this) = PS(spectatee);
1655         this.armortype = spectatee.armortype;
1656         this.armorvalue = spectatee.armorvalue;
1657         this.ammo_cells = spectatee.ammo_cells;
1658         this.ammo_plasma = spectatee.ammo_plasma;
1659         this.ammo_shells = spectatee.ammo_shells;
1660         this.ammo_nails = spectatee.ammo_nails;
1661         this.ammo_rockets = spectatee.ammo_rockets;
1662         this.ammo_fuel = spectatee.ammo_fuel;
1663         this.clip_load = spectatee.clip_load;
1664         this.clip_size = spectatee.clip_size;
1665         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1666         this.health = spectatee.health;
1667         this.impulse = 0;
1668         this.items = spectatee.items;
1669         this.last_pickup = spectatee.last_pickup;
1670         this.hit_time = spectatee.hit_time;
1671         this.strength_finished = spectatee.strength_finished;
1672         this.invincible_finished = spectatee.invincible_finished;
1673         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1674         this.weapons = spectatee.weapons;
1675         this.vortex_charge = spectatee.vortex_charge;
1676         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1677         this.hagar_load = spectatee.hagar_load;
1678         this.arc_heat_percent = spectatee.arc_heat_percent;
1679         this.minelayer_mines = spectatee.minelayer_mines;
1680         this.punchangle = spectatee.punchangle;
1681         this.view_ofs = spectatee.view_ofs;
1682         this.velocity = spectatee.velocity;
1683         this.dmg_take = spectatee.dmg_take;
1684         this.dmg_save = spectatee.dmg_save;
1685         this.dmg_inflictor = spectatee.dmg_inflictor;
1686         this.v_angle = spectatee.v_angle;
1687         this.angles = spectatee.v_angle;
1688         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1689         this.revive_progress = spectatee.revive_progress;
1690         this.viewloc = spectatee.viewloc;
1691         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1692                 this.fixangle = true;
1693         setorigin(this, spectatee.origin);
1694         setsize(this, spectatee.mins, spectatee.maxs);
1695         SetZoomState(this, spectatee.zoomstate);
1696
1697         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1698         {
1699                 .entity weaponentity = weaponentities[slot];
1700                 this.(weaponentity) = spectatee.(weaponentity);
1701         }
1702
1703     anticheat_spectatecopy(this, spectatee);
1704         this.hud = spectatee.hud;
1705         if(spectatee.vehicle)
1706     {
1707         this.angles = spectatee.v_angle;
1708
1709         //this.fixangle = false;
1710         //this.velocity = spectatee.vehicle.velocity;
1711         this.vehicle_health = spectatee.vehicle_health;
1712         this.vehicle_shield = spectatee.vehicle_shield;
1713         this.vehicle_energy = spectatee.vehicle_energy;
1714         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1715         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1716         this.vehicle_reload1 = spectatee.vehicle_reload1;
1717         this.vehicle_reload2 = spectatee.vehicle_reload2;
1718
1719         //msg_entity = this;
1720
1721        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1722             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1723            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1724            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1725
1726         //WriteByte (MSG_ONE, SVC_SETVIEW);
1727         //    WriteEntity(MSG_ONE, this);
1728         //makevectors(spectatee.v_angle);
1729         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1730     }
1731 }
1732
1733 bool SpectateUpdate(entity this)
1734 {
1735         if(!this.enemy)
1736                 return false;
1737
1738         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1739         {
1740                 SetSpectatee(this, NULL);
1741                 return false;
1742         }
1743
1744         SpectateCopy(this, this.enemy);
1745
1746         return true;
1747 }
1748
1749 bool SpectateSet(entity this)
1750 {
1751         if(!IS_PLAYER(this.enemy))
1752                 return false;
1753
1754         ClientData_Touch(this.enemy);
1755
1756         msg_entity = this;
1757         WriteByte(MSG_ONE, SVC_SETVIEW);
1758         WriteEntity(MSG_ONE, this.enemy);
1759         set_movetype(this, MOVETYPE_NONE);
1760         accuracy_resend(this);
1761
1762         if(!SpectateUpdate(this))
1763                 PutObserverInServer(this);
1764
1765         return true;
1766 }
1767
1768 void SetSpectatee_status(entity this, int spectatee_num)
1769 {
1770         int oldspectatee_status = this.spectatee_status;
1771         this.spectatee_status = spectatee_num;
1772
1773         if (this.spectatee_status != oldspectatee_status)
1774         {
1775                 ClientData_Touch(this);
1776                 if (g_race || g_cts) race_InitSpectator();
1777         }
1778 }
1779
1780 void SetSpectatee(entity this, entity spectatee)
1781 {
1782         entity old_spectatee = this.enemy;
1783
1784         this.enemy = spectatee;
1785
1786         // WEAPONTODO
1787         // these are required to fix the spectator bug with arc
1788         if(old_spectatee)
1789         {
1790                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1791                 {
1792                         .entity weaponentity = weaponentities[slot];
1793                         if(old_spectatee.(weaponentity).arc_beam)
1794                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1795                 }
1796         }
1797         if(this.enemy)
1798         {
1799                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1800                 {
1801                         .entity weaponentity = weaponentities[slot];
1802                         if(this.enemy.(weaponentity).arc_beam)
1803                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1804                 }
1805         }
1806
1807         if (this.enemy)
1808                 SetSpectatee_status(this, etof(this.enemy));
1809
1810         // needed to update spectator list
1811         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1812 }
1813
1814 bool Spectate(entity this, entity pl)
1815 {
1816         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1817                 return false;
1818         pl = M_ARGV(1, entity);
1819
1820         SetSpectatee(this, pl);
1821         return SpectateSet(this);
1822 }
1823
1824 bool SpectateNext(entity this)
1825 {
1826         entity ent = find(this.enemy, classname, STR_PLAYER);
1827
1828         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1829                 ent = M_ARGV(1, entity);
1830         else if (!ent)
1831                 ent = find(ent, classname, STR_PLAYER);
1832
1833         if(ent) { SetSpectatee(this, ent); }
1834
1835         return SpectateSet(this);
1836 }
1837
1838 bool SpectatePrev(entity this)
1839 {
1840         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1841         entity ent = findchain(classname, STR_PLAYER);
1842         if (!ent) // no player
1843                 return false;
1844
1845         entity first = ent;
1846         // skip players until current spectated player
1847         if(this.enemy)
1848         while(ent && ent != this.enemy)
1849                 ent = ent.chain;
1850
1851         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1852         {
1853                 case MUT_SPECPREV_FOUND:
1854                     ent = M_ARGV(1, entity);
1855                     break;
1856                 case MUT_SPECPREV_RETURN:
1857                     return true;
1858                 case MUT_SPECPREV_CONTINUE:
1859                 default:
1860                 {
1861                         if(ent.chain)
1862                                 ent = ent.chain;
1863                         else
1864                                 ent = first;
1865                         break;
1866                 }
1867         }
1868
1869         SetSpectatee(this, ent);
1870         return SpectateSet(this);
1871 }
1872
1873 /*
1874 =============
1875 ShowRespawnCountdown()
1876
1877 Update a respawn countdown display.
1878 =============
1879 */
1880 void ShowRespawnCountdown(entity this)
1881 {
1882         float number;
1883         if(!IS_DEAD(this)) // just respawned?
1884                 return;
1885         else
1886         {
1887                 number = ceil(this.respawn_time - time);
1888                 if(number <= 0)
1889                         return;
1890                 if(number <= this.respawn_countdown)
1891                 {
1892                         this.respawn_countdown = number - 1;
1893                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1894                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1895                 }
1896         }
1897 }
1898
1899 .bool team_selected;
1900 bool ShowTeamSelection(entity this)
1901 {
1902         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1903                 return false;
1904         stuffcmd(this, "menu_showteamselect\n");
1905         return true;
1906 }
1907 void Join(entity this)
1908 {
1909         TRANSMUTE(Player, this);
1910
1911         if(!this.team_selected)
1912         if(autocvar_g_campaign || autocvar_g_balance_teams)
1913                 JoinBestTeam(this, false, true);
1914
1915         if(autocvar_g_campaign)
1916                 campaign_bots_may_start = true;
1917
1918         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1919
1920         PutClientInServer(this);
1921
1922         if(teamplay && this.team != -1)
1923                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1924         else
1925                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1926         this.team_selected = false;
1927 }
1928
1929 /**
1930  * Determines whether the player is allowed to join. This depends on cvar
1931  * g_maxplayers, if it isn't used this function always return true, otherwise
1932  * it checks whether the number of currently playing players exceeds g_maxplayers.
1933  * @return int number of free slots for players, 0 if none
1934  */
1935 int nJoinAllowed(entity this, entity ignore)
1936 {
1937         if(!ignore)
1938         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1939         // so report 0 free slots if restricted
1940         {
1941                 if(autocvar_g_forced_team_otherwise == "spectate")
1942                         return 0;
1943                 if(autocvar_g_forced_team_otherwise == "spectator")
1944                         return 0;
1945         }
1946
1947         if(this && this.team_forced < 0)
1948                 return 0; // forced spectators can never join
1949
1950         // TODO simplify this
1951         int totalClients = 0;
1952         int currentlyPlaying = 0;
1953         FOREACH_CLIENT(true, LAMBDA(
1954                 if(it != ignore)
1955                         ++totalClients;
1956                 if(IS_REAL_CLIENT(it))
1957                 if(IS_PLAYER(it) || it.caplayer)
1958                         ++currentlyPlaying;
1959         ));
1960
1961         float free_slots = 0;
1962         if (!autocvar_g_maxplayers)
1963                 free_slots = maxclients - totalClients;
1964         else if(currentlyPlaying < autocvar_g_maxplayers)
1965                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1966
1967         static float join_prevent_msg_time = 0;
1968         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1969         {
1970                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1971                 join_prevent_msg_time = time + 3;
1972         }
1973
1974         return free_slots;
1975 }
1976
1977 /**
1978  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1979  * g_maxplayers_spectator_blocktime seconds
1980  */
1981 void checkSpectatorBlock(entity this)
1982 {
1983         if(IS_SPEC(this) || IS_OBSERVER(this))
1984         if(!this.caplayer)
1985         if(IS_REAL_CLIENT(this))
1986         {
1987                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1988                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1989                         dropclient(this);
1990                 }
1991         }
1992 }
1993
1994 void PrintWelcomeMessage(entity this)
1995 {
1996         if(this.motd_actived_time == 0)
1997         {
1998                 if (autocvar_g_campaign) {
1999                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2000                                 this.motd_actived_time = time;
2001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2002                         }
2003                 } else {
2004                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2005                                 this.motd_actived_time = time;
2006                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2007                         }
2008                 }
2009         }
2010         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2011         {
2012                 if (autocvar_g_campaign) {
2013                         if (PHYS_INPUT_BUTTON_INFO(this))
2014                                 this.motd_actived_time = time;
2015                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2016                                 this.motd_actived_time = 0;
2017                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2018                         }
2019                 } else {
2020                         if (PHYS_INPUT_BUTTON_INFO(this))
2021                                 this.motd_actived_time = time;
2022                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2023                                 this.motd_actived_time = 0;
2024                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2025                         }
2026                 }
2027         }
2028         else //if(this.motd_actived_time < 0) // just connected, motd is active
2029         {
2030                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2031                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2032                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2033                 {
2034                         // instanctly hide MOTD
2035                         this.motd_actived_time = 0;
2036                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2037                 }
2038         }
2039 }
2040
2041 bool joinAllowed(entity this)
2042 {
2043         if (this.version_mismatch) return false;
2044         if (!nJoinAllowed(this, this)) return false;
2045         if (teamplay && lockteams) return false;
2046         if (ShowTeamSelection(this)) return false;
2047         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2048         return true;
2049 }
2050
2051 void ObserverThink(entity this)
2052 {
2053         if ( this.impulse )
2054         {
2055                 MinigameImpulse(this, this.impulse);
2056                 this.impulse = 0;
2057         }
2058
2059         if (this.flags & FL_JUMPRELEASED) {
2060                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2061                         this.flags &= ~FL_JUMPRELEASED;
2062                         this.flags |= FL_SPAWNING;
2063                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2064                         this.flags &= ~FL_JUMPRELEASED;
2065                         if(SpectateNext(this)) {
2066                                 TRANSMUTE(Spectator, this);
2067                         }
2068                 } else {
2069                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2070                         set_movetype(this, preferred_movetype);
2071                 }
2072         } else {
2073                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2074                         this.flags |= FL_JUMPRELEASED;
2075                         if(this.flags & FL_SPAWNING)
2076                         {
2077                                 this.flags &= ~FL_SPAWNING;
2078                                 Join(this);
2079                                 return;
2080                         }
2081                 }
2082         }
2083 }
2084
2085 void SpectatorThink(entity this)
2086 {
2087         if ( this.impulse )
2088         {
2089                 if(MinigameImpulse(this, this.impulse))
2090                         this.impulse = 0;
2091
2092                 if (this.impulse == IMP_weapon_drop.impulse)
2093                 {
2094                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2095                         this.impulse = 0;
2096                         return;
2097                 }
2098         }
2099
2100         if (this.flags & FL_JUMPRELEASED) {
2101                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2102                         this.flags &= ~FL_JUMPRELEASED;
2103                         this.flags |= FL_SPAWNING;
2104                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2105                         this.flags &= ~FL_JUMPRELEASED;
2106                         if(SpectateNext(this)) {
2107                                 TRANSMUTE(Spectator, this);
2108                         } else {
2109                                 TRANSMUTE(Observer, this);
2110                                 PutClientInServer(this);
2111                         }
2112                         this.impulse = 0;
2113                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2114                         this.flags &= ~FL_JUMPRELEASED;
2115                         if(SpectatePrev(this)) {
2116                                 TRANSMUTE(Spectator, this);
2117                         } else {
2118                                 TRANSMUTE(Observer, this);
2119                                 PutClientInServer(this);
2120                         }
2121                         this.impulse = 0;
2122                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2123                         this.flags &= ~FL_JUMPRELEASED;
2124                         TRANSMUTE(Observer, this);
2125                         PutClientInServer(this);
2126                 } else {
2127                         if(!SpectateUpdate(this))
2128                                 PutObserverInServer(this);
2129                 }
2130         } else {
2131                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2132                         this.flags |= FL_JUMPRELEASED;
2133                         if(this.flags & FL_SPAWNING)
2134                         {
2135                                 this.flags &= ~FL_SPAWNING;
2136                                 Join(this);
2137                                 return;
2138                         }
2139                 }
2140                 if(!SpectateUpdate(this))
2141                         PutObserverInServer(this);
2142         }
2143
2144         this.flags |= FL_CLIENT | FL_NOTARGET;
2145 }
2146
2147 void vehicles_enter (entity pl, entity veh);
2148 void PlayerUseKey(entity this)
2149 {
2150         if (!IS_PLAYER(this))
2151                 return;
2152
2153         if(this.vehicle)
2154         {
2155                 if(!game_stopped)
2156                 {
2157                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2158                         return;
2159                 }
2160         }
2161         else if(autocvar_g_vehicles_enter)
2162         {
2163                 if(!STAT(FROZEN, this))
2164                 if(!IS_DEAD(this))
2165                 if(!game_stopped)
2166                 {
2167                         entity head, closest_target = NULL;
2168                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2169
2170                         while(head) // find the closest acceptable target to enter
2171                         {
2172                                 if(IS_VEHICLE(head))
2173                                 if(!IS_DEAD(head))
2174                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2175                                 if(head.takedamage != DAMAGE_NO)
2176                                 {
2177                                         if(closest_target)
2178                                         {
2179                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2180                                                 { closest_target = head; }
2181                                         }
2182                                         else { closest_target = head; }
2183                                 }
2184
2185                                 head = head.chain;
2186                         }
2187
2188                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2189                 }
2190         }
2191
2192         // a use key was pressed; call handlers
2193         MUTATOR_CALLHOOK(PlayerUseKey, this);
2194 }
2195
2196
2197 /*
2198 =============
2199 PlayerPreThink
2200
2201 Called every frame for each client before the physics are run
2202 =============
2203 */
2204 .float usekeypressed;
2205 .float last_vehiclecheck;
2206 .int items_added;
2207 void PlayerPreThink (entity this)
2208 {
2209         WarpZone_PlayerPhysics_FixVAngle(this);
2210
2211     STAT(GAMESTARTTIME, this) = game_starttime;
2212         STAT(ROUNDSTARTTIME, this) = round_starttime;
2213         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2214         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2215
2216         STAT(WEAPONSINMAP, this) = weaponsInMap;
2217
2218         if (frametime) {
2219                 // physics frames: update anticheat stuff
2220                 anticheat_prethink(this);
2221         }
2222
2223         if (blockSpectators && frametime) {
2224                 // WORKAROUND: only use dropclient in server frames (frametime set).
2225                 // Never use it in cl_movement frames (frametime zero).
2226                 checkSpectatorBlock(this);
2227     }
2228
2229         zoomstate_set = false;
2230
2231         // Check for nameless players
2232         if (isInvisibleString(this.netname)) {
2233                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2234                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2235         }
2236         if (this.netname != this.netname_previous) {
2237                 if (autocvar_sv_eventlog) {
2238                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2239         }
2240                 if (this.netname_previous) strunzone(this.netname_previous);
2241                 this.netname_previous = strzone(this.netname);
2242         }
2243
2244         // version nagging
2245         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2246         this.version_nagtime = 0;
2247         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2248             // git client
2249         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2250             // git server
2251             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2252         } else {
2253             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2254             if (r < 0) { // old client
2255                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2256             } else if (r > 0) { // old server
2257                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2258             }
2259         }
2260     }
2261
2262         // GOD MODE info
2263         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2264         {
2265                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2266                 this.max_armorvalue = 0;
2267         }
2268
2269         if (STAT(FROZEN, this) == 2)
2270         {
2271                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2272                 this.health = max(1, this.revive_progress * start_health);
2273                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2274
2275                 if (this.revive_progress >= 1)
2276                         Unfreeze(this);
2277         }
2278         else if (STAT(FROZEN, this) == 3)
2279         {
2280                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2281                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2282
2283                 if (this.health < 1)
2284                 {
2285                         if (this.vehicle)
2286                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2287                         if(this.event_damage)
2288                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2289                 }
2290                 else if (this.revive_progress <= 0)
2291                         Unfreeze(this);
2292         }
2293
2294         MUTATOR_CALLHOOK(PlayerPreThink, this);
2295
2296         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2297         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2298         {
2299                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2300                 {
2301                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2302                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2303                         {
2304                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2305                         }
2306                         else if(!it.owner)
2307                         {
2308                                 if(!it.team || SAME_TEAM(this, it))
2309                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2310                                 else if(autocvar_g_vehicles_steal)
2311                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2312                         }
2313                 });
2314
2315                 this.last_vehiclecheck = time + 1;
2316         }
2317
2318         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2319         {
2320                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2321                         PlayerUseKey(this);
2322                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2323         }
2324
2325         if (IS_REAL_CLIENT(this))
2326                 PrintWelcomeMessage(this);
2327
2328         if (IS_PLAYER(this)) {
2329                 CheckRules_Player(this);
2330
2331                 if (game_stopped || intermission_running) {
2332                         if(intermission_running)
2333                                 IntermissionThink(this);
2334                         return;
2335                 }
2336
2337                 if (timeout_status == TIMEOUT_ACTIVE) {
2338             // don't allow the player to turn around while game is paused
2339                         // FIXME turn this into CSQC stuff
2340                         this.v_angle = this.lastV_angle;
2341                         this.angles = this.lastV_angle;
2342                         this.fixangle = true;
2343                 }
2344
2345                 if (frametime) player_powerups(this);
2346
2347                 if (IS_DEAD(this)) {
2348                         if (this.personal && g_race_qualifying) {
2349                                 if (time > this.respawn_time) {
2350                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2351                                         respawn(this);
2352                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2353                                 }
2354                         } else {
2355                                 if (frametime) player_anim(this);
2356                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2357
2358                                 switch(this.deadflag)
2359                                 {
2360                                         case DEAD_DYING:
2361                                         {
2362                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2363                                                         this.deadflag = DEAD_RESPAWNING;
2364                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2365                                                         this.deadflag = DEAD_DEAD;
2366                                                 break;
2367                                         }
2368                                         case DEAD_DEAD:
2369                                         {
2370                                                 if (button_pressed)
2371                                                         this.deadflag = DEAD_RESPAWNABLE;
2372                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2373                                                         this.deadflag = DEAD_RESPAWNING;
2374                                                 break;
2375                                         }
2376                                         case DEAD_RESPAWNABLE:
2377                                         {
2378                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2379                                                         this.deadflag = DEAD_RESPAWNING;
2380                                                 break;
2381                                         }
2382                                         case DEAD_RESPAWNING:
2383                                         {
2384                                                 if (time > this.respawn_time)
2385                                                 {
2386                                                         this.respawn_time = time + 1; // only retry once a second
2387                                                         this.respawn_time_max = this.respawn_time;
2388                                                         respawn(this);
2389                                                 }
2390                                                 break;
2391                                         }
2392                                 }
2393
2394                                 ShowRespawnCountdown(this);
2395
2396                                 if (this.respawn_flags & RESPAWN_SILENT)
2397                                         STAT(RESPAWN_TIME, this) = 0;
2398                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2399                                 {
2400                                         if (time < this.respawn_time)
2401                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2402                                         else if (this.deadflag != DEAD_RESPAWNING)
2403                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2404                                 }
2405                                 else
2406                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2407                         }
2408
2409                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2410                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2411                                 STAT(RESPAWN_TIME, this) *= -1;
2412
2413                         return;
2414                 }
2415
2416                 this.prevorigin = this.origin;
2417
2418                 bool have_hook = false;
2419                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2420                 {
2421                         .entity weaponentity = weaponentities[slot];
2422                         if(this.(weaponentity).hook.state)
2423                         {
2424                                 have_hook = true;
2425                                 break;
2426                         }
2427                 }
2428                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2429                 if (have_hook) {
2430                         do_crouch = false;
2431                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2432                         do_crouch = false;
2433                 } else if (this.vehicle) {
2434                         do_crouch = false;
2435                 } else if (STAT(FROZEN, this)) {
2436                         do_crouch = false;
2437         }
2438
2439                 if (do_crouch) {
2440                         if (!this.crouch) {
2441                                 this.crouch = true;
2442                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2443                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2444                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2445                         }
2446                 } else if (this.crouch) {
2447             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2448             if (!trace_startsolid) {
2449                 this.crouch = false;
2450                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2451                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2452             }
2453                 }
2454
2455                 FixPlayermodel(this);
2456
2457                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2458                 //if(frametime)
2459                 {
2460                         this.items &= ~this.items_added;
2461
2462                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2463                         {
2464                                 .entity weaponentity = weaponentities[slot];
2465                                 W_WeaponFrame(this, weaponentity);
2466
2467                                 if(slot == 0)
2468                                 {
2469                                         this.clip_load = this.(weaponentity).clip_load;
2470                                         this.clip_size = this.(weaponentity).clip_size;
2471                                 }
2472                         }
2473
2474                         this.items_added = 0;
2475                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2476                 this.items_added |= IT_FUEL;
2477
2478                         this.items |= this.items_added;
2479                 }
2480
2481                 player_regen(this);
2482
2483                 // WEAPONTODO: Add a weapon request for this
2484                 // rot vortex charge to the charge limit
2485                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2486                 {
2487                         .entity weaponentity = weaponentities[slot];
2488                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2489                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2490                 }
2491
2492                 if (frametime) player_anim(this);
2493
2494                 // secret status
2495                 secrets_setstatus(this);
2496
2497                 // monsters status
2498                 monsters_setstatus(this);
2499
2500                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2501         }
2502         else if (game_stopped || intermission_running) {
2503                 if(intermission_running)
2504                         IntermissionThink(this);
2505                 return;
2506         }
2507         else if (IS_OBSERVER(this)) {
2508                 ObserverThink(this);
2509         }
2510         else if (IS_SPEC(this)) {
2511                 SpectatorThink(this);
2512         }
2513
2514         // WEAPONTODO: Add weapon request for this
2515         if (!zoomstate_set) {
2516                 bool wep_zoomed = false;
2517                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2518                 {
2519                         .entity weaponentity = weaponentities[slot];
2520                         Weapon thiswep = this.(weaponentity).m_weapon;
2521                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2522                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2523                 }
2524                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2525     }
2526
2527         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2528         {
2529                 this.teamkill_soundtime = 0;
2530
2531                 entity e = this.teamkill_soundsource;
2532                 entity oldpusher = e.pusher;
2533                 e.pusher = this;
2534                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2535                 e.pusher = oldpusher;
2536         }
2537
2538         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2539                 this.taunt_soundtime = 0;
2540                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2541         }
2542
2543         target_voicescript_next(this);
2544
2545         // WEAPONTODO: Move into weaponsystem somehow
2546         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2547         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2548         {
2549                 .entity weaponentity = weaponentities[slot];
2550                 if(this.(weaponentity).m_weapon == WEP_Null)
2551                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2552         }
2553 }
2554
2555 void DrownPlayer(entity this)
2556 {
2557         if(IS_DEAD(this))
2558                 return;
2559
2560         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2561         {
2562                 if(this.air_finished < time)
2563                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2564                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2565                 this.dmg = 2;
2566         }
2567         else if (this.air_finished < time)
2568         {       // drown!
2569                 if (this.pain_finished < time)
2570                 {
2571                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2572                         this.pain_finished = time + 0.5;
2573                 }
2574         }
2575 }
2576
2577 .bool move_qcphysics;
2578
2579 void Player_Physics(entity this)
2580 {
2581         set_movetype(this, this.move_movetype);
2582
2583         if(!this.move_qcphysics)
2584                 return;
2585
2586         if(!frametime && !this.pm_frametime)
2587                 return;
2588
2589         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2590
2591         this.pm_frametime = 0;
2592 }
2593
2594 /*
2595 =============
2596 PlayerPostThink
2597
2598 Called every frame for each client after the physics are run
2599 =============
2600 */
2601 .float idlekick_lasttimeleft;
2602 void PlayerPostThink (entity this)
2603 {
2604         Player_Physics(this);
2605
2606         if (sv_maxidle > 0)
2607         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2608         if (IS_REAL_CLIENT(this))
2609         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2610         {
2611                 int totalClients = 0;
2612                 if(sv_maxidle_slots > 0)
2613                 {
2614                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2615                         {
2616                                 ++totalClients;
2617                         });
2618                 }
2619
2620                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2621                 { /* do nothing */ }
2622                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2623                 {
2624                         if (this.idlekick_lasttimeleft)
2625                         {
2626                                 this.idlekick_lasttimeleft = 0;
2627                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2628                         }
2629                 }
2630                 else
2631                 {
2632                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2633                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2634                                 if (!this.idlekick_lasttimeleft)
2635                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2636                         }
2637                         if (timeleft <= 0) {
2638                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2639                                 dropclient(this);
2640                                 return;
2641                         }
2642                         else if (timeleft <= 10) {
2643                                 if (timeleft != this.idlekick_lasttimeleft) {
2644                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2645                 }
2646                                 this.idlekick_lasttimeleft = timeleft;
2647                         }
2648                 }
2649         }
2650
2651         CheatFrame(this);
2652
2653         //CheckPlayerJump();
2654         if (game_stopped)
2655         {
2656                 this.solid = SOLID_NOT;
2657                 this.takedamage = DAMAGE_NO;
2658                 set_movetype(this, MOVETYPE_NONE);
2659         }
2660
2661         if (IS_PLAYER(this)) {
2662                 DrownPlayer(this);
2663                 CheckRules_Player(this);
2664                 UpdateChatBubble(this);
2665                 if (this.impulse) ImpulseCommands(this);
2666                 if (game_stopped)
2667                 {
2668                         CSQCMODEL_AUTOUPDATE(this);
2669                         return;
2670                 }
2671                 GetPressedKeys(this);
2672         }
2673
2674         if (this.waypointsprite_attachedforcarrier) {
2675             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2676                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2677     }
2678
2679         playerdemo_write(this);
2680
2681         CSQCMODEL_AUTOUPDATE(this);
2682 }