qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/state.qh>
  34 #include <common/stats.qh>
  35 #include <common/vehicles/all.qh>
  36 #include <common/vehicles/sv_vehicles.qh>
  37 #include <common/viewloc.qh>
  38 #include <common/weapons/_all.qh>
  39 #include <common/weapons/weapon/vortex.qh>
  40 #include <common/wepent.qh>
  41 #include <lib/csqcmodel/sv_model.qh>
  42 #include <lib/warpzone/common.qh>
  43 #include <lib/warpzone/server.qh>
  44 #include <server/anticheat.qh>
  45 #include <server/antilag.qh>
  46 #include <server/bot/api.qh>
  47 #include <server/bot/default/cvars.qh>
  48 #include <server/campaign.qh>
  49 #include <server/chat.qh>
  50 #include <server/cheats.qh>
  51 #include <server/clientkill.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/vote.qh>
  55 #include <server/compat/quake3.qh>
  56 #include <server/damage.qh>
  57 #include <server/gamelog.qh>
  58 #include <server/handicap.qh>
  59 #include <server/hook.qh>
  60 #include <server/impulse.qh>
  61 #include <server/intermission.qh>
  62 #include <server/ipban.qh>
  63 #include <server/main.qh>
  64 #include <server/mutators/_mod.qh>
  65 #include <server/player.qh>
  66 #include <server/portals.qh>
  67 #include <server/race.qh>
  68 #include <server/resources.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         PlayerState_detach(this);
 242
 243         if (IS_PLAYER(this))
 244         {
 245                 if(GetResource(this, RES_HEALTH) >= 1)
 246                 {
 247                         // despawn effect
 248                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 249                 }
 250
 251                 // was a player, recount votes and ready status
 252                 if(IS_REAL_CLIENT(this))
 253                 {
 254                         if (vote_called) { VoteCount(false); }
 255                         ReadyCount();
 256                 }
 257                 entcs_update_players(this);
 258         }
 259
 260         entity spot = SelectSpawnPoint(this, true);
 261         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 262         this.angles = vec2(spot.angles);
 263         this.fixangle = true;
 264         // offset it so that the spectator spawns higher off the ground, looks better this way
 265         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 266         if (IS_REAL_CLIENT(this))
 267         {
 268                 msg_entity = this;
 269                 WriteByte(MSG_ONE, SVC_SETVIEW);
 270                 WriteEntity(MSG_ONE, this);
 271         }
 272         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 273         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 274         if(!autocvar_g_debug_globalsounds)
 275         {
 276                 // needed for player sounds
 277                 this.model = "";
 278                 FixPlayermodel(this);
 279         }
 280         setmodel(this, MDL_Null);
 281         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 282         this.view_ofs = '0 0 0';
 283
 284         RemoveGrapplingHooks(this);
 285         Portal_ClearAll(this);
 286         Unfreeze(this, false);
 287         SetSpectatee(this, NULL);
 288
 289         if (this.alivetime)
 290         {
 291                 if (!warmup_stage)
 292                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 293                 this.alivetime = 0;
 294         }
 295
 296         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 297
 298         WaypointSprite_PlayerDead(this);
 299
 300         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 301                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 302
 303         accuracy_resend(this);
 304
 305         CS(this).spectatortime = time;
 306         if(this.bot_attack)
 307                 IL_REMOVE(g_bot_targets, this);
 308         this.bot_attack = false;
 309         if(this.monster_attack)
 310                 IL_REMOVE(g_monster_targets, this);
 311         this.monster_attack = false;
 312         STAT(HUD, this) = HUD_NORMAL;
 313         TRANSMUTE(Observer, this);
 314         this.iscreature = false;
 315         this.teleportable = TELEPORT_SIMPLE;
 316         if(this.damagedbycontents)
 317                 IL_REMOVE(g_damagedbycontents, this);
 318         this.damagedbycontents = false;
 319         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 320         SetSpectatee_status(this, etof(this));
 321         this.takedamage = DAMAGE_NO;
 322         this.solid = SOLID_NOT;
 323         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 324         this.flags = FL_CLIENT | FL_NOTARGET;
 325         this.effects = 0;
 326         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 327         this.pauserotarmor_finished = 0;
 328         this.pauserothealth_finished = 0;
 329         this.pauseregen_finished = 0;
 330         this.damageforcescale = 0;
 331         this.death_time = 0;
 332         this.respawn_flags = 0;
 333         this.respawn_time = 0;
 334         STAT(RESPAWN_TIME, this) = 0;
 335         this.alpha = 0;
 336         this.scale = 0;
 337         this.fade_time = 0;
 338         this.pain_finished = 0;
 339         STAT(AIR_FINISHED, this) = 0;
 340         //this.dphitcontentsmask = 0;
 341         this.dphitcontentsmask = DPCONTENTS_SOLID;
 342         if (autocvar_g_playerclip_collisions)
 343                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 344         this.pushltime = 0;
 345         this.istypefrag = 0;
 346         setthink(this, func_null);
 347         this.nextthink = 0;
 348         this.deadflag = DEAD_NO;
 349         UNSET_DUCKED(this);
 350         STAT(REVIVE_PROGRESS, this) = 0;
 351         this.revival_time = 0;
 352         this.draggable = drag_undraggable;
 353
 354         this.items = 0;
 355         STAT(WEAPONS, this) = '0 0 0';
 356         this.drawonlytoclient = this;
 357
 358         this.viewloc = NULL;
 359
 360         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 361
 362         this.weaponmodel = "";
 363         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 364         {
 365                 this.weaponentities[slot] = NULL;
 366         }
 367         this.exteriorweaponentity = NULL;
 368         CS(this).killcount = FRAGS_SPECTATOR;
 369         this.velocity = '0 0 0';
 370         this.avelocity = '0 0 0';
 371         this.punchangle = '0 0 0';
 372         this.punchvector = '0 0 0';
 373         this.oldvelocity = this.velocity;
 374         this.event_damage = func_null;
 375         this.event_heal = func_null;
 376
 377         for(int slot = 0; slot < MAX_AXH; ++slot)
 378         {
 379                 entity axh = this.(AuxiliaryXhair[slot]);
 380                 this.(AuxiliaryXhair[slot]) = NULL;
 381
 382                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 383                         delete(axh);
 384         }
 385
 386         if (mutator_returnvalue)
 387         {
 388                 // mutator prevents resetting teams+score
 389         }
 390         else
 391         {
 392                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 393                 this.frags = FRAGS_SPECTATOR;
 394         }
 395
 396         bot_relinkplayerlist();
 397
 398         if (CS(this).just_joined)
 399                 CS(this).just_joined = false;
 400 }
 401
 402 int player_getspecies(entity this)
 403 {
 404         get_model_parameters(this.model, this.skin);
 405         int s = get_model_parameters_species;
 406         get_model_parameters(string_null, 0);
 407         if (s < 0) return SPECIES_HUMAN;
 408         return s;
 409 }
 410
 411 .float model_randomizer;
 412 void FixPlayermodel(entity player)
 413 {
 414         string defaultmodel = "";
 415         int defaultskin = 0;
 416         if(autocvar_sv_defaultcharacter)
 417         {
 418                 if(teamplay)
 419                 {
 420                         switch(player.team)
 421                         {
 422                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 423                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 424                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 425                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 426                         }
 427                 }
 428
 429                 if(defaultmodel == "")
 430                 {
 431                         defaultmodel = autocvar_sv_defaultplayermodel;
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433                 }
 434
 435                 int n = tokenize_console(defaultmodel);
 436                 if(n > 0)
 437                 {
 438                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 439                         // However, do NOT randomize if the player-selected model is in the list.
 440                         for (int i = 0; i < n; ++i)
 441                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 442                                         defaultmodel = argv(i);
 443                 }
 444
 445                 int i = strstrofs(defaultmodel, ":", 0);
 446                 if(i >= 0)
 447                 {
 448                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 449                         defaultmodel = substring(defaultmodel, 0, i);
 450                 }
 451         }
 452         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 453         {
 454                 if(teamplay)
 455                 {
 456                         switch(player.team)
 457                         {
 458                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 459                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 460                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 461                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 462                         }
 463                 }
 464
 465                 if(!defaultskin)
 466                         defaultskin = autocvar_sv_defaultplayerskin;
 467         }
 468
 469         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 470         defaultmodel = M_ARGV(0, string);
 471         defaultskin = M_ARGV(1, int);
 472
 473         bool chmdl = false;
 474         int oldskin;
 475         if(defaultmodel != "")
 476         {
 477                 if (defaultmodel != player.model)
 478                 {
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, defaultmodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 oldskin = player.skin;
 487                 player.skin = defaultskin;
 488         } else {
 489                 if (player.playermodel != player.model || player.playermodel == "")
 490                 {
 491                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, player.playermodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 if(!autocvar_sv_defaultcharacterskin)
 500                 {
 501                         oldskin = player.skin;
 502                         player.skin = stof(player.playerskin);
 503                 }
 504                 else
 505                 {
 506                         oldskin = player.skin;
 507                         player.skin = defaultskin;
 508                 }
 509         }
 510
 511         if(chmdl || oldskin != player.skin) // model or skin has changed
 512         {
 513                 player.species = player_getspecies(player); // update species
 514                 if(!autocvar_g_debug_globalsounds)
 515                         UpdatePlayerSounds(player); // update skin sounds
 516         }
 517
 518         if(!teamplay)
 519                 if(strlen(autocvar_sv_defaultplayercolors))
 520                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 521                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 522 }
 523
 524 void PutPlayerInServer(entity this)
 525 {
 526         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 527
 528         PlayerState_attach(this);
 529         accuracy_resend(this);
 530
 531         if (this.team < 0)
 532                 TeamBalance_JoinBestTeam(this);
 533
 534         entity spot = SelectSpawnPoint(this, false);
 535         if (!spot) {
 536                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 537                 return; // spawn failed
 538         }
 539
 540         TRANSMUTE(Player, this);
 541
 542         CS(this).wasplayer = true;
 543         this.iscreature = true;
 544         this.teleportable = TELEPORT_NORMAL;
 545         if(!this.damagedbycontents)
 546                 IL_PUSH(g_damagedbycontents, this);
 547         this.damagedbycontents = true;
 548         set_movetype(this, MOVETYPE_WALK);
 549         this.solid = SOLID_SLIDEBOX;
 550         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 551         if (autocvar_g_playerclip_collisions)
 552                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 553         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 554                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 555         this.frags = FRAGS_PLAYER;
 556         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 557         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 558         if (autocvar__notarget)
 559                 this.flags |= FL_NOTARGET;
 560         this.takedamage = DAMAGE_AIM;
 561         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 562
 563         if (warmup_stage) {
 564                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 565                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 566                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 567                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 568                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 569                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 570                 SetResource(this, RES_HEALTH, warmup_start_health);
 571                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 572                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 573         } else {
 574                 SetResource(this, RES_SHELLS, start_ammo_shells);
 575                 SetResource(this, RES_BULLETS, start_ammo_nails);
 576                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 577                 SetResource(this, RES_CELLS, start_ammo_cells);
 578                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 579                 SetResource(this, RES_FUEL, start_ammo_fuel);
 580                 SetResource(this, RES_HEALTH, start_health);
 581                 SetResource(this, RES_ARMOR, start_armorvalue);
 582                 STAT(WEAPONS, this) = start_weapons;
 583                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 584                 {
 585                         GiveRandomWeapons(this, random_start_weapons_count,
 586                                 autocvar_g_random_start_weapons, random_start_ammo);
 587                 }
 588         }
 589         SetSpectatee_status(this, 0);
 590
 591         PS(this).dual_weapons = '0 0 0';
 592
 593         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 594                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 595
 596         this.items = start_items;
 597
 598         float shieldtime = time + autocvar_g_spawnshieldtime;
 599
 600         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 601         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 602         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 603         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 604         if (!sv_ready_restart_after_countdown && time < game_starttime)
 605         {
 606                 float f = game_starttime - time;
 607                 shieldtime += f;
 608                 this.pauserotarmor_finished += f;
 609                 this.pauserothealth_finished += f;
 610                 this.pauseregen_finished += f;
 611         }
 612
 613         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 614
 615         this.damageforcescale = autocvar_g_player_damageforcescale;
 616         this.death_time = 0;
 617         this.respawn_flags = 0;
 618         this.respawn_time = 0;
 619         STAT(RESPAWN_TIME, this) = 0;
 620         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 621         this.fade_time = 0;
 622         this.pain_finished = 0;
 623         this.pushltime = 0;
 624         setthink(this, func_null); // players have no think function
 625         this.nextthink = 0;
 626         this.dmg_team = 0;
 627         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 628
 629         this.deadflag = DEAD_NO;
 630
 631         this.angles = spot.angles;
 632         this.angles_z = 0; // never spawn tilted even if the spot says to
 633         if (IS_BOT_CLIENT(this))
 634         {
 635                 this.v_angle = this.angles;
 636                 bot_aim_reset(this);
 637         }
 638         this.fixangle = true; // turn this way immediately
 639         this.oldvelocity = this.velocity = '0 0 0';
 640         this.avelocity = '0 0 0';
 641         this.punchangle = '0 0 0';
 642         this.punchvector = '0 0 0';
 643
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         STAT(AIR_FINISHED, this) = 0;
 648         this.waterlevel = WATERLEVEL_NONE;
 649         this.watertype = CONTENT_EMPTY;
 650
 651         entity spawnevent = new_pure(spawnevent);
 652         spawnevent.owner = this;
 653         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 654
 655         // Cut off any still running player sounds.
 656         stopsound(this, CH_PLAYER_SINGLE);
 657
 658         this.model = "";
 659         FixPlayermodel(this);
 660         this.drawonlytoclient = NULL;
 661
 662         this.viewloc = NULL;
 663
 664         for(int slot = 0; slot < MAX_AXH; ++slot)
 665         {
 666                 entity axh = this.(AuxiliaryXhair[slot]);
 667                 this.(AuxiliaryXhair[slot]) = NULL;
 668
 669                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 670                         delete(axh);
 671         }
 672
 673         this.spawnpoint_targ = NULL;
 674
 675         UNSET_DUCKED(this);
 676         this.view_ofs = STAT(PL_VIEW_OFS, this);
 677         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 678         this.spawnorigin = spot.origin;
 679         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 680         // don't reset back to last position, even if new position is stuck in solid
 681         this.oldorigin = this.origin;
 682         if(this.conveyor)
 683                 IL_REMOVE(g_conveyed, this);
 684         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 685         if(this.swampslug)
 686                 IL_REMOVE(g_swamped, this);
 687         this.swampslug = NULL;
 688         this.swamp_interval = 0;
 689         if(this.ladder_entity)
 690                 IL_REMOVE(g_ladderents, this);
 691         this.ladder_entity = NULL;
 692         IL_EACH(g_counters, it.realowner == this,
 693         {
 694                 delete(it);
 695         });
 696         STAT(HUD, this) = HUD_NORMAL;
 697
 698         this.event_damage = PlayerDamage;
 699         this.event_heal = PlayerHeal;
 700
 701         this.draggable = func_null;
 702
 703         if(!this.bot_attack)
 704                 IL_PUSH(g_bot_targets, this);
 705         this.bot_attack = true;
 706         if(!this.monster_attack)
 707                 IL_PUSH(g_monster_targets, this);
 708         this.monster_attack = true;
 709         navigation_dynamicgoal_init(this, false);
 710
 711         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 712
 713         // player was spectator
 714         if (CS(this).killcount == FRAGS_SPECTATOR) {
 715                 PlayerScore_Clear(this);
 716                 CS(this).killcount = 0;
 717                 CS(this).startplaytime = time;
 718         }
 719
 720         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 721         {
 722                 .entity weaponentity = weaponentities[slot];
 723                 CL_SpawnWeaponentity(this, weaponentity);
 724         }
 725         this.alpha = default_player_alpha;
 726         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 727         this.exteriorweaponentity.alpha = default_weapon_alpha;
 728
 729         this.speedrunning = false;
 730
 731         this.counter_cnt = 0;
 732         this.fragsfilter_cnt = 0;
 733
 734         target_voicescript_clear(this);
 735
 736         // reset fields the weapons may use
 737         FOREACH(Weapons, true, {
 738                 it.wr_resetplayer(it, this);
 739                         // reload all reloadable weapons
 740                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 741                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 742                         {
 743                                 .entity weaponentity = weaponentities[slot];
 744                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 745                         }
 746                 }
 747         });
 748
 749         Unfreeze(this, false);
 750
 751         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 752
 753         {
 754                 string s = spot.target;
 755                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 756                         spot.target = string_null;
 757                 SUB_UseTargets(spot, this, NULL);
 758                 if(g_assault || g_race)
 759                         spot.target = s;
 760         }
 761
 762         if (autocvar_spawn_debug)
 763         {
 764                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 765                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 766         }
 767
 768         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 769         {
 770                 .entity weaponentity = weaponentities[slot];
 771                 entity w_ent = this.(weaponentity);
 772                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 773                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 774                 else
 775                         w_ent.m_switchweapon = WEP_Null;
 776                 w_ent.m_weapon = WEP_Null;
 777                 w_ent.weaponname = "";
 778                 w_ent.m_switchingweapon = WEP_Null;
 779                 w_ent.cnt = -1;
 780         }
 781
 782         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 783
 784         if (CS(this).impulse) ImpulseCommands(this);
 785
 786         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 787         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 788         {
 789                 .entity weaponentity = weaponentities[slot];
 790                 W_WeaponFrame(this, weaponentity);
 791         }
 792
 793         if (!warmup_stage && !this.alivetime)
 794                 this.alivetime = time;
 795
 796         antilag_clear(this, CS(this));
 797 }
 798
 799 /** Called when a client spawns in the server */
 800 void PutClientInServer(entity this)
 801 {
 802         if (IS_BOT_CLIENT(this)) {
 803                 TRANSMUTE(Player, this);
 804         } else if (IS_REAL_CLIENT(this)) {
 805                 msg_entity = this;
 806                 WriteByte(MSG_ONE, SVC_SETVIEW);
 807                 WriteEntity(MSG_ONE, this);
 808         }
 809         if (game_stopped)
 810                 TRANSMUTE(Observer, this);
 811
 812         SetSpectatee(this, NULL);
 813
 814         // reset player keys
 815         if(PS(this))
 816                 PS(this).itemkeys = 0;
 817
 818         MUTATOR_CALLHOOK(PutClientInServer, this);
 819
 820         if (IS_OBSERVER(this)) {
 821                 PutObserverInServer(this, false);
 822         } else if (IS_PLAYER(this)) {
 823                 PutPlayerInServer(this);
 824         }
 825
 826         bot_relinkplayerlist();
 827 }
 828
 829 // TODO do we need all these fields, or should we stop autodetecting runtime
 830 // changes and just have a console command to update this?
 831 bool ClientInit_SendEntity(entity this, entity to, int sf)
 832 {
 833         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 834         return = true;
 835         msg_entity = to;
 836         // MSG_INIT replacement
 837         // TODO: make easier to use
 838         Registry_send_all();
 839         W_PROP_reload(MSG_ONE, to);
 840         ClientInit_misc(this);
 841         MUTATOR_CALLHOOK(Ent_Init);
 842 }
 843 void ClientInit_misc(entity this)
 844 {
 845         int channel = MSG_ONE;
 846         WriteHeader(channel, ENT_CLIENT_INIT);
 847         WriteByte(channel, g_nexball_meter_period * 32);
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 856
 857         if(autocvar_sv_foginterval && world.fog != "")
 858                 WriteString(channel, world.fog);
 859         else
 860                 WriteString(channel, "");
 861         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 862         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 863         WriteByte(channel, serverflags);
 864         WriteCoord(channel, autocvar_g_trueaim_minrange);
 865 }
 866
 867 void ClientInit_CheckUpdate(entity this)
 868 {
 869         this.nextthink = time;
 870         if(this.count != autocvar_g_balance_armor_blockpercent)
 871         {
 872                 this.count = autocvar_g_balance_armor_blockpercent;
 873                 this.SendFlags |= 1;
 874         }
 875         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 876         {
 877                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 878                 this.SendFlags |= 1;
 879         }
 880 }
 881
 882 void ClientInit_Spawn()
 883 {
 884         entity e = new_pure(clientinit);
 885         setthink(e, ClientInit_CheckUpdate);
 886         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 887
 888         ClientInit_CheckUpdate(e);
 889 }
 890
 891 /*
 892 =============
 893 SetNewParms
 894 =============
 895 */
 896 void SetNewParms ()
 897 {
 898         // initialize parms for a new player
 899         parm1 = -(86400 * 366);
 900
 901         MUTATOR_CALLHOOK(SetNewParms);
 902 }
 903
 904 /*
 905 =============
 906 SetChangeParms
 907 =============
 908 */
 909 void SetChangeParms (entity this)
 910 {
 911         // save parms for level change
 912         parm1 = CS(this).parm_idlesince - time;
 913
 914         MUTATOR_CALLHOOK(SetChangeParms);
 915 }
 916
 917 /*
 918 =============
 919 DecodeLevelParms
 920 =============
 921 */
 922 void DecodeLevelParms(entity this)
 923 {
 924         // load parms
 925         CS(this).parm_idlesince = parm1;
 926         if (CS(this).parm_idlesince == -(86400 * 366))
 927                 CS(this).parm_idlesince = time;
 928
 929         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 930         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 931
 932         MUTATOR_CALLHOOK(DecodeLevelParms);
 933 }
 934
 935 void FixClientCvars(entity e)
 936 {
 937         // send prediction settings to the client
 938         stuffcmd(e, "\nin_bindmap 0 0\n");
 939         if(autocvar_g_antilag == 3) // client side hitscan
 940                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 941         if(autocvar_sv_gentle)
 942                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 943
 944         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 945         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 946
 947         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 948
 949         MUTATOR_CALLHOOK(FixClientCvars, e);
 950 }
 951
 952 bool findinlist_abbrev(string tofind, string list)
 953 {
 954         if(list == "" || tofind == "")
 955                 return false; // empty list or search, just return
 956
 957         // this function allows abbreviated strings!
 958         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 959         {
 960                 return true;
 961         });
 962
 963         return false;
 964 }
 965
 966 bool PlayerInIPList(entity p, string iplist)
 967 {
 968         // some safety checks (never allow local?)
 969         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 970                 return false;
 971
 972         return findinlist_abbrev(p.netaddress, iplist);
 973 }
 974
 975 bool PlayerInIDList(entity p, string idlist)
 976 {
 977         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 978         if(!p.crypto_idfp)
 979                 return false;
 980
 981         return findinlist_abbrev(p.crypto_idfp, idlist);
 982 }
 983
 984 bool PlayerInList(entity player, string list)
 985 {
 986         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 987 }
 988
 989 #ifdef DP_EXT_PRECONNECT
 990 /*
 991 =============
 992 ClientPreConnect
 993
 994 Called once (not at each match start) when a client begins a connection to the server
 995 =============
 996 */
 997 void ClientPreConnect(entity this)
 998 {
 999         if(autocvar_sv_eventlog)
1000         {
1001                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1002                         this.playerid,
1003                         etof(this),
1004                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1005                 ));
1006         }
1007 }
1008 #endif
1009
1010 string GetClientVersionMessage(entity this)
1011 {
1012         if (CS(this).version_mismatch) {
1013                 if(CS(this).version < autocvar_gameversion) {
1014                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1015                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1016                 } else {
1017                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1018                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1019                 }
1020         } else {
1021                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1022         }
1023 }
1024
1025 string getwelcomemessage(entity this)
1026 {
1027         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1028         string modifications = M_ARGV(0, string);
1029
1030         if(g_weaponarena)
1031         {
1032                 if(g_weaponarena_random)
1033                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1034                 else
1035                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1036         }
1037         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1038                 modifications = strcat(modifications, ", No start weapons");
1039         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1040                 modifications = strcat(modifications, ", Low gravity");
1041         if(g_weapon_stay && !g_cts)
1042                 modifications = strcat(modifications, ", Weapons stay");
1043         if(autocvar_g_jetpack)
1044                 modifications = strcat(modifications, ", Jet pack");
1045         modifications = substring(modifications, 2, strlen(modifications) - 2);
1046
1047         string versionmessage = GetClientVersionMessage(this);
1048         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1049
1050         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1051
1052         if(modifications != "")
1053                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1054
1055         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1056         {
1057                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1058                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1059         }
1060
1061         if (cache_mutatormsg != "") {
1062                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1063         }
1064
1065         string mutator_msg = "";
1066         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1067         mutator_msg = M_ARGV(0, string);
1068
1069         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1070
1071         string motd = autocvar_sv_motd;
1072         if (motd != "") {
1073                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1074         }
1075         return s;
1076 }
1077
1078 /**
1079 =============
1080 ClientConnect
1081
1082 Called when a client connects to the server
1083 =============
1084 */
1085 void ClientConnect(entity this)
1086 {
1087         if (Ban_MaybeEnforceBanOnce(this)) return;
1088         assert(!IS_CLIENT(this), return);
1089         this.flags |= FL_CLIENT;
1090         assert(player_count >= 0, player_count = 0);
1091
1092         TRANSMUTE(Client, this);
1093         CS(this).version_nagtime = time + 10 + random() * 10;
1094
1095         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1096
1097         bot_clientconnect(this);
1098
1099         Player_DetermineForcedTeam(this);
1100
1101         TRANSMUTE(Observer, this);
1102
1103         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1104
1105         // always track bots, don't ask for cl_allow_uidtracking
1106         if (IS_BOT_CLIENT(this))
1107                 PlayerStats_GameReport_AddPlayer(this);
1108         else
1109                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1110
1111         if (autocvar_sv_eventlog)
1112                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1113
1114         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1115
1116         stuffcmd(this, clientstuff, "\n");
1117         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1118
1119         FixClientCvars(this);
1120
1121         // get version info from player
1122         stuffcmd(this, "cmd clientversion $gameversion\n");
1123
1124         // notify about available teams
1125         if (teamplay)
1126         {
1127                 entity balance = TeamBalance_CheckAllowedTeams(this);
1128                 int t = TeamBalance_GetAllowedTeams(balance);
1129                 TeamBalance_Destroy(balance);
1130                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1131         }
1132         else
1133         {
1134                 stuffcmd(this, "set _teams_available 0\n");
1135         }
1136
1137         bot_relinkplayerlist();
1138
1139         CS(this).spectatortime = time;
1140         if (blockSpectators)
1141         {
1142                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1143         }
1144
1145         CS(this).jointime = time;
1146
1147         if (IS_REAL_CLIENT(this))
1148         {
1149                 if (g_weaponarena_weapons == WEPSET(TUBA))
1150                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1151         }
1152
1153         if (!autocvar_sv_foginterval && world.fog != "")
1154                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1155
1156         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1157                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1158                         send_CSQC_teamnagger();
1159
1160         CSQCMODEL_AUTOINIT(this);
1161
1162         CS(this).model_randomizer = random();
1163
1164         if (IS_REAL_CLIENT(this))
1165                 sv_notice_join(this);
1166
1167         this.move_qcphysics = autocvar_sv_qcphysics;
1168
1169         // update physics stats (players can spawn before physics runs)
1170         Physics_UpdateStats(this);
1171
1172         IL_EACH(g_initforplayer, it.init_for_player, {
1173                 it.init_for_player(it, this);
1174         });
1175
1176         Handicap_Initialize(this);
1177
1178         MUTATOR_CALLHOOK(ClientConnect, this);
1179
1180         if (IS_REAL_CLIENT(this))
1181         {
1182                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1183                 {
1184                         CS(this).motd_actived_time = -1;
1185                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1186                 }
1187         }
1188 }
1189 /*
1190 =============
1191 ClientDisconnect
1192
1193 Called when a client disconnects from the server
1194 =============
1195 */
1196 .entity chatbubbleentity;
1197 void player_powerups_remove_all(entity this);
1198
1199 void ClientDisconnect(entity this)
1200 {
1201         assert(IS_CLIENT(this), return);
1202
1203         PlayerStats_GameReport_FinalizePlayer(this);
1204         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1205         if (CS(this).active_minigame) part_minigame(this);
1206         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1207
1208         if (autocvar_sv_eventlog)
1209                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1210
1211         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1212
1213         if(IS_SPEC(this))
1214                 SetSpectatee(this, NULL);
1215
1216         MUTATOR_CALLHOOK(ClientDisconnect, this);
1217
1218         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1219         strfree(CS_CVAR(this).weaponorder_byimpulse);
1220         ClientState_detach(this);
1221
1222         Portal_ClearAll(this);
1223
1224         Unfreeze(this, false);
1225
1226         RemoveGrapplingHooks(this);
1227
1228         // Here, everything has been done that requires this player to be a client.
1229
1230         this.flags &= ~FL_CLIENT;
1231
1232         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1233         if (this.killindicator) delete(this.killindicator);
1234
1235         IL_EACH(g_counters, it.realowner == this,
1236         {
1237                 delete(it);
1238         });
1239
1240         WaypointSprite_PlayerGone(this);
1241
1242         bot_relinkplayerlist();
1243
1244         strfree(this.clientstatus);
1245         if (this.personal) delete(this.personal);
1246
1247         this.playerid = 0;
1248         ReadyCount();
1249         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1250
1251         player_powerups_remove_all(this); // stop powerup sound
1252
1253         ONREMOVE(this);
1254 }
1255
1256 void ChatBubbleThink(entity this)
1257 {
1258         this.nextthink = time;
1259         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1260         {
1261                 if(this.owner) // but why can that ever be NULL?
1262                         this.owner.chatbubbleentity = NULL;
1263                 delete(this);
1264                 return;
1265         }
1266
1267         this.mdl = "";
1268
1269         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1270         {
1271                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1272                         this.mdl = "models/sprites/minigame_busy.iqm";
1273                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1274                         this.mdl = "models/misc/chatbubble.spr";
1275         }
1276
1277         if ( this.model != this.mdl )
1278                 _setmodel(this, this.mdl);
1279
1280 }
1281
1282 void UpdateChatBubble(entity this)
1283 {
1284         if (this.alpha < 0)
1285                 return;
1286         // spawn a chatbubble entity if needed
1287         if (!this.chatbubbleentity)
1288         {
1289                 this.chatbubbleentity = new(chatbubbleentity);
1290                 this.chatbubbleentity.owner = this;
1291                 this.chatbubbleentity.exteriormodeltoclient = this;
1292                 setthink(this.chatbubbleentity, ChatBubbleThink);
1293                 this.chatbubbleentity.nextthink = time;
1294                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1295                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1296                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1297                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1298                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1299                 //this.chatbubbleentity.model = "";
1300                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1301         }
1302 }
1303
1304 void calculate_player_respawn_time(entity this)
1305 {
1306         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1307                 return;
1308
1309         float gametype_setting_tmp;
1310         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1311         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1312         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1313         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1314         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1315         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1316
1317         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1318         if (teamplay)
1319         {
1320                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1321                         if(it.team == this.team)
1322                                 ++pcount;
1323                 });
1324                 if (sdelay_small_count == 0)
1325                         sdelay_small_count = 1;
1326                 if (sdelay_large_count == 0)
1327                         sdelay_large_count = 1;
1328         }
1329         else
1330         {
1331                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1332                         ++pcount;
1333                 });
1334                 if (sdelay_small_count == 0)
1335                 {
1336                         if (IS_INDEPENDENT_PLAYER(this))
1337                         {
1338                                 // Players play independently. No point in requiring enemies.
1339                                 sdelay_small_count = 1;
1340                         }
1341                         else
1342                         {
1343                                 // Players play AGAINST each other. Enemies required.
1344                                 sdelay_small_count = 2;
1345                         }
1346                 }
1347                 if (sdelay_large_count == 0)
1348                 {
1349                         if (IS_INDEPENDENT_PLAYER(this))
1350                         {
1351                                 // Players play independently. No point in requiring enemies.
1352                                 sdelay_large_count = 1;
1353                         }
1354                         else
1355                         {
1356                                 // Players play AGAINST each other. Enemies required.
1357                                 sdelay_large_count = 2;
1358                         }
1359                 }
1360         }
1361
1362         float sdelay;
1363
1364         if (pcount <= sdelay_small_count)
1365                 sdelay = sdelay_small;
1366         else if (pcount >= sdelay_large_count)
1367                 sdelay = sdelay_large;
1368         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1369                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1370
1371         if(waves)
1372                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1373         else
1374                 this.respawn_time = time + sdelay;
1375
1376         if(sdelay < sdelay_max)
1377                 this.respawn_time_max = time + sdelay_max;
1378         else
1379                 this.respawn_time_max = this.respawn_time;
1380
1381         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1382                 this.respawn_countdown = 10; // first number to count down from is 10
1383         else
1384                 this.respawn_countdown = -1; // do not count down
1385
1386         if(autocvar_g_forced_respawn)
1387                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1388 }
1389
1390 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1391 // added to the model skins
1392 /*void UpdateColorModHack()
1393 {
1394         float c;
1395         c = this.clientcolors & 15;
1396         // LordHavoc: only bothering to support white, green, red, yellow, blue
1397              if (!teamplay) this.colormod = '0 0 0';
1398         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1399         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1400         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1401         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1402         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1403         else this.colormod = '1 1 1';
1404 }*/
1405
1406 void respawn(entity this)
1407 {
1408         bool damagedbycontents_prev = this.damagedbycontents;
1409         if(this.alpha >= 0)
1410         {
1411                 if(autocvar_g_respawn_ghosts)
1412                 {
1413                         this.solid = SOLID_NOT;
1414                         this.takedamage = DAMAGE_NO;
1415                         this.damagedbycontents = false;
1416                         set_movetype(this, MOVETYPE_FLY);
1417                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1418                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1419                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1420                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1421                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1422                         if(autocvar_g_respawn_ghosts_time > 0)
1423                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1424                 }
1425                 else
1426                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1427         }
1428
1429         CopyBody(this, 1);
1430         this.damagedbycontents = damagedbycontents_prev;
1431
1432         this.effects |= EF_NODRAW; // prevent another CopyBody
1433         PutClientInServer(this);
1434 }
1435
1436 void play_countdown(entity this, float finished, Sound samp)
1437 {
1438         TC(Sound, samp);
1439         if(IS_REAL_CLIENT(this))
1440                 if(floor(finished - time - frametime) != floor(finished - time))
1441                         if(finished - time < 6)
1442                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1443 }
1444
1445 void player_powerups_remove_all(entity this)
1446 {
1447         if (this.items & IT_SUPERWEAPON)
1448         {
1449                 // don't play the poweroff sound when the game restarts or the player disconnects
1450                 if (time > game_starttime + 1 && IS_CLIENT(this))
1451                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1452                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1453                 this.items -= (this.items & IT_SUPERWEAPON);
1454         }
1455 }
1456
1457 void player_powerups(entity this)
1458 {
1459         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1460                 this.modelflags |= MF_ROCKET;
1461         else
1462                 this.modelflags &= ~MF_ROCKET;
1463
1464         this.effects &= ~EF_NODEPTHTEST;
1465
1466         if (IS_DEAD(this))
1467                 player_powerups_remove_all(this);
1468
1469         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1470                 return;
1471
1472         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1473         int items_prev = this.items;
1474
1475         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1476         {
1477                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1478                 if (this.items & IT_SUPERWEAPON)
1479                 {
1480                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1481                         {
1482                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1483                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1484                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1486                         }
1487                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1488                         {
1489                                 // don't let them run out
1490                         }
1491                         else
1492                         {
1493                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1494                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1495                                 {
1496                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1497                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1498                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1499                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1500                                 }
1501                         }
1502                 }
1503                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1504                 {
1505                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1506                         {
1507                                 this.items = this.items | IT_SUPERWEAPON;
1508                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1509                                 {
1510                                         if(!g_cts)
1511                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1512                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1513                                 }
1514                         }
1515                         else
1516                         {
1517                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1518                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1519                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1520                         }
1521                 }
1522                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1523                 {
1524                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1525                 }
1526         }
1527
1528         if(autocvar_g_nodepthtestplayers)
1529                 this.effects = this.effects | EF_NODEPTHTEST;
1530
1531         if(autocvar_g_fullbrightplayers)
1532                 this.effects = this.effects | EF_FULLBRIGHT;
1533
1534         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1535 }
1536
1537 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1538 {
1539         if(current > stable)
1540                 return current;
1541         else if(current > stable - 0.25) // when close enough, "snap"
1542                 return stable;
1543         else
1544                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1545 }
1546
1547 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1548 {
1549         if(current < stable)
1550                 return current;
1551         else if(current < stable + 0.25) // when close enough, "snap"
1552                 return stable;
1553         else
1554                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1555 }
1556
1557 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1558 {
1559         float old = GetResource(this, res);
1560         float current = old;
1561         if(current > rotstable)
1562         {
1563                 if(rotframetime > 0)
1564                 {
1565                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1566                         current = max(rotstable, current - rotlinear * rotframetime);
1567                 }
1568         }
1569         else if(current < regenstable)
1570         {
1571                 if(regenframetime > 0)
1572                 {
1573                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1574                         current = min(regenstable, current + regenlinear * regenframetime);
1575                 }
1576         }
1577
1578         float limit = GetResourceLimit(this, res) * limit_mod;
1579         if(current > limit)
1580                 current = limit;
1581
1582         if (current != old)
1583                 SetResource(this, res, current);
1584 }
1585
1586 void player_regen(entity this)
1587 {
1588         float max_mod, regen_mod, rot_mod, limit_mod;
1589         max_mod = regen_mod = rot_mod = limit_mod = 1;
1590
1591         float regen_health = autocvar_g_balance_health_regen;
1592         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1593         float regen_health_rot = autocvar_g_balance_health_rot;
1594         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1595         float regen_health_stable = autocvar_g_balance_health_regenstable;
1596         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1597         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1598                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1599         max_mod = M_ARGV(1, float);
1600         regen_mod = M_ARGV(2, float);
1601         rot_mod = M_ARGV(3, float);
1602         limit_mod = M_ARGV(4, float);
1603         regen_health = M_ARGV(5, float);
1604         regen_health_linear = M_ARGV(6, float);
1605         regen_health_rot = M_ARGV(7, float);
1606         regen_health_rotlinear = M_ARGV(8, float);
1607         regen_health_stable = M_ARGV(9, float);
1608         regen_health_rotstable = M_ARGV(10, float);
1609
1610         if(!mutator_returnvalue)
1611         if(!STAT(FROZEN, this))
1612         {
1613                 float maxa = autocvar_g_balance_armor_rotstable;
1614                 float mina = autocvar_g_balance_armor_regenstable;
1615
1616                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1617                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1618                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1619
1620                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1621                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1622                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1623         }
1624
1625         // if player rotted to death...  die!
1626         // check this outside above checks, as player may still be able to rot to death
1627         if(GetResource(this, RES_HEALTH) < 1)
1628         {
1629                 if(this.vehicle)
1630                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1631                 if(this.event_damage)
1632                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1633         }
1634
1635         if (!(this.items & IT_UNLIMITED_AMMO))
1636         {
1637                 float maxf = autocvar_g_balance_fuel_rotstable;
1638                 float minf = autocvar_g_balance_fuel_regenstable;
1639
1640                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1641                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1642                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1643         }
1644 }
1645
1646 bool zoomstate_set;
1647 void SetZoomState(entity this, float newzoom)
1648 {
1649         if(newzoom != CS(this).zoomstate)
1650         {
1651                 CS(this).zoomstate = newzoom;
1652                 ClientData_Touch(this);
1653         }
1654         zoomstate_set = true;
1655 }
1656
1657 void GetPressedKeys(entity this)
1658 {
1659         MUTATOR_CALLHOOK(GetPressedKeys, this);
1660         if (game_stopped)
1661         {
1662                 CS(this).pressedkeys = 0;
1663                 STAT(PRESSED_KEYS, this) = 0;
1664                 return;
1665         }
1666
1667         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1668         int keys = STAT(PRESSED_KEYS, this);
1669         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1670         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1671         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1672         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1673
1674         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1675         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1676         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1677         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1678         CS(this).pressedkeys = keys; // store for other users
1679
1680         STAT(PRESSED_KEYS, this) = keys;
1681 }
1682
1683 /*
1684 ======================
1685 spectate mode routines
1686 ======================
1687 */
1688
1689 void SpectateCopy(entity this, entity spectatee)
1690 {
1691         TC(Client, this); TC(Client, spectatee);
1692
1693         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1694         PS(this) = PS(spectatee);
1695         this.armortype = spectatee.armortype;
1696         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1697         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1698         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1699         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1700         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1701         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1702         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1703         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1704         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1705         CS(this).impulse = 0;
1706         this.disableclientprediction = 1; // no need to run prediction on a spectator
1707         this.items = spectatee.items;
1708         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1709         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1710         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1711         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1712         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1713         this.punchangle = spectatee.punchangle;
1714         this.view_ofs = spectatee.view_ofs;
1715         this.velocity = spectatee.velocity;
1716         this.dmg_take = spectatee.dmg_take;
1717         this.dmg_save = spectatee.dmg_save;
1718         this.dmg_inflictor = spectatee.dmg_inflictor;
1719         this.v_angle = spectatee.v_angle;
1720         this.angles = spectatee.v_angle;
1721         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1722         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1723         this.viewloc = spectatee.viewloc;
1724         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1725                 this.fixangle = true;
1726         setorigin(this, spectatee.origin);
1727         setsize(this, spectatee.mins, spectatee.maxs);
1728         SetZoomState(this, CS(spectatee).zoomstate);
1729
1730     anticheat_spectatecopy(this, spectatee);
1731         STAT(HUD, this) = STAT(HUD, spectatee);
1732         if(spectatee.vehicle)
1733     {
1734         this.angles = spectatee.v_angle;
1735
1736         //this.fixangle = false;
1737         //this.velocity = spectatee.vehicle.velocity;
1738         this.vehicle_health = spectatee.vehicle_health;
1739         this.vehicle_shield = spectatee.vehicle_shield;
1740         this.vehicle_energy = spectatee.vehicle_energy;
1741         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1742         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1743         this.vehicle_reload1 = spectatee.vehicle_reload1;
1744         this.vehicle_reload2 = spectatee.vehicle_reload2;
1745
1746         //msg_entity = this;
1747
1748        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1749             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1750            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1751            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1752
1753         //WriteByte (MSG_ONE, SVC_SETVIEW);
1754         //    WriteEntity(MSG_ONE, this);
1755         //makevectors(spectatee.v_angle);
1756         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1757     }
1758 }
1759
1760 bool SpectateUpdate(entity this)
1761 {
1762         if(!this.enemy)
1763                 return false;
1764
1765         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1766         {
1767                 SetSpectatee(this, NULL);
1768                 return false;
1769         }
1770
1771         SpectateCopy(this, this.enemy);
1772
1773         return true;
1774 }
1775
1776 bool SpectateSet(entity this)
1777 {
1778         if(!IS_PLAYER(this.enemy))
1779                 return false;
1780
1781         ClientData_Touch(this.enemy);
1782
1783         msg_entity = this;
1784         WriteByte(MSG_ONE, SVC_SETVIEW);
1785         WriteEntity(MSG_ONE, this.enemy);
1786         set_movetype(this, MOVETYPE_NONE);
1787         accuracy_resend(this);
1788
1789         if(!SpectateUpdate(this))
1790                 PutObserverInServer(this, false);
1791
1792         return true;
1793 }
1794
1795 void SetSpectatee_status(entity this, int spectatee_num)
1796 {
1797         int oldspectatee_status = CS(this).spectatee_status;
1798         CS(this).spectatee_status = spectatee_num;
1799
1800         if (CS(this).spectatee_status != oldspectatee_status)
1801         {
1802                 if (STAT(PRESSED_KEYS, this))
1803                 {
1804                         CS(this).pressedkeys = 0;
1805                         STAT(PRESSED_KEYS, this) = 0;
1806                 }
1807                 ClientData_Touch(this);
1808                 if (g_race || g_cts) race_InitSpectator();
1809         }
1810 }
1811
1812 void SetSpectatee(entity this, entity spectatee)
1813 {
1814         if(IS_BOT_CLIENT(this))
1815                 return; // bots abuse .enemy, this code is useless to them
1816
1817         entity old_spectatee = this.enemy;
1818
1819         this.enemy = spectatee;
1820
1821         // WEAPONTODO
1822         // these are required to fix the spectator bug with arc
1823         if(old_spectatee)
1824         {
1825                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1826                 {
1827                         .entity weaponentity = weaponentities[slot];
1828                         if(old_spectatee.(weaponentity).arc_beam)
1829                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1830                 }
1831         }
1832         if(this.enemy)
1833         {
1834                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1835                 {
1836                         .entity weaponentity = weaponentities[slot];
1837                         if(this.enemy.(weaponentity).arc_beam)
1838                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1839                 }
1840         }
1841
1842         if (this.enemy)
1843                 SetSpectatee_status(this, etof(this.enemy));
1844
1845         // needed to update spectator list
1846         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1847 }
1848
1849 bool Spectate(entity this, entity pl)
1850 {
1851         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1852                 return false;
1853         pl = M_ARGV(1, entity);
1854
1855         SetSpectatee(this, pl);
1856         return SpectateSet(this);
1857 }
1858
1859 bool SpectateNext(entity this)
1860 {
1861         entity ent = find(this.enemy, classname, STR_PLAYER);
1862
1863         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1864                 ent = M_ARGV(1, entity);
1865         else if (!ent)
1866                 ent = find(ent, classname, STR_PLAYER);
1867
1868         if(ent) { SetSpectatee(this, ent); }
1869
1870         return SpectateSet(this);
1871 }
1872
1873 bool SpectatePrev(entity this)
1874 {
1875         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1876         entity ent = findchain(classname, STR_PLAYER);
1877         if (!ent) // no player
1878                 return false;
1879
1880         entity first = ent;
1881         // skip players until current spectated player
1882         if(this.enemy)
1883         while(ent && ent != this.enemy)
1884                 ent = ent.chain;
1885
1886         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1887         {
1888                 case MUT_SPECPREV_FOUND:
1889                         ent = M_ARGV(1, entity);
1890                         break;
1891                 case MUT_SPECPREV_RETURN:
1892                         return true;
1893                 case MUT_SPECPREV_CONTINUE:
1894                 default:
1895                 {
1896                         if(ent.chain)
1897                                 ent = ent.chain;
1898                         else
1899                                 ent = first;
1900                         break;
1901                 }
1902         }
1903
1904         SetSpectatee(this, ent);
1905         return SpectateSet(this);
1906 }
1907
1908 /*
1909 =============
1910 ShowRespawnCountdown()
1911
1912 Update a respawn countdown display.
1913 =============
1914 */
1915 void ShowRespawnCountdown(entity this)
1916 {
1917         float number;
1918         if(!IS_DEAD(this)) // just respawned?
1919                 return;
1920         else
1921         {
1922                 number = ceil(this.respawn_time - time);
1923                 if(number <= 0)
1924                         return;
1925                 if(number <= this.respawn_countdown)
1926                 {
1927                         this.respawn_countdown = number - 1;
1928                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1929                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1930                 }
1931         }
1932 }
1933
1934 .bool team_selected;
1935 bool ShowTeamSelection(entity this)
1936 {
1937         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1938                 return false;
1939         stuffcmd(this, "menu_showteamselect\n");
1940         return true;
1941 }
1942 void Join(entity this)
1943 {
1944         TRANSMUTE(Player, this);
1945
1946         if(!this.team_selected)
1947         if(autocvar_g_campaign || autocvar_g_balance_teams)
1948                 TeamBalance_JoinBestTeam(this);
1949
1950         if(autocvar_g_campaign)
1951                 campaign_bots_may_start = true;
1952
1953         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1954
1955         PutClientInServer(this);
1956
1957         if(IS_PLAYER(this))
1958         if(teamplay && this.team != -1)
1959         {
1960         }
1961         else
1962                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1963         this.team_selected = false;
1964 }
1965
1966 int GetPlayerLimit()
1967 {
1968         if(g_duel)
1969                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1970         int player_limit = autocvar_g_maxplayers;
1971         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1972         player_limit = M_ARGV(0, int);
1973         return player_limit;
1974 }
1975
1976 /**
1977  * Determines whether the player is allowed to join. This depends on cvar
1978  * g_maxplayers, if it isn't used this function always return true, otherwise
1979  * it checks whether the number of currently playing players exceeds g_maxplayers.
1980  * @return int number of free slots for players, 0 if none
1981  */
1982 int nJoinAllowed(entity this, entity ignore)
1983 {
1984         if(!ignore)
1985         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1986         // so report 0 free slots if restricted
1987         {
1988                 if(autocvar_g_forced_team_otherwise == "spectate")
1989                         return 0;
1990                 if(autocvar_g_forced_team_otherwise == "spectator")
1991                         return 0;
1992         }
1993
1994         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1995                 return 0; // forced spectators can never join
1996
1997         // TODO simplify this
1998         int totalClients = 0;
1999         int currentlyPlaying = 0;
2000         FOREACH_CLIENT(true, {
2001                 if(it != ignore)
2002                         ++totalClients;
2003                 if(IS_REAL_CLIENT(it))
2004                 if(IS_PLAYER(it) || it.caplayer)
2005                         ++currentlyPlaying;
2006         });
2007
2008         int player_limit = GetPlayerLimit();
2009
2010         int free_slots = 0;
2011         if (!player_limit)
2012                 free_slots = maxclients - totalClients;
2013         else if(player_limit > 0 && currentlyPlaying < player_limit)
2014                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2015
2016         static float msg_time = 0;
2017         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2018         {
2019                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2020                 msg_time = time + 0.5;
2021         }
2022
2023         return free_slots;
2024 }
2025
2026 void PrintWelcomeMessage(entity this)
2027 {
2028         if(CS(this).motd_actived_time == 0)
2029         {
2030                 if (autocvar_g_campaign) {
2031                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2032                                 CS(this).motd_actived_time = time;
2033                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2034                         }
2035                 } else {
2036                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2037                                 CS(this).motd_actived_time = time;
2038                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2039                         }
2040                 }
2041         }
2042         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2043         {
2044                 if (autocvar_g_campaign) {
2045                         if (PHYS_INPUT_BUTTON_INFO(this))
2046                                 CS(this).motd_actived_time = time;
2047                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2048                                 CS(this).motd_actived_time = 0;
2049                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2050                         }
2051                 } else {
2052                         if (PHYS_INPUT_BUTTON_INFO(this))
2053                                 CS(this).motd_actived_time = time;
2054                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2055                                 CS(this).motd_actived_time = 0;
2056                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2057                         }
2058                 }
2059         }
2060         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2061         {
2062                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2063                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2064                 else if (CS(this).motd_actived_time == -2)
2065                 {
2066                         // instantly hide MOTD
2067                         CS(this).motd_actived_time = 0;
2068                         if (autocvar_g_campaign)
2069                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2070                         else
2071                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2072                 }
2073                 else if (IS_PLAYER(this) || IS_SPEC(this))
2074                 {
2075                         // FIXME occasionally for some reason MOTD never goes away
2076                         // delay MOTD removal a little bit in the hope it fixes this bug
2077                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2078                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2079                         else //if (CS(this).motd_actived_time < -2)
2080                                 CS(this).motd_actived_time++;
2081                 }
2082         }
2083 }
2084
2085 bool joinAllowed(entity this)
2086 {
2087         if (CS(this).version_mismatch) return false;
2088         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2089         if (!nJoinAllowed(this, this)) return false;
2090         if (teamplay && lockteams) return false;
2091         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2092         if (ShowTeamSelection(this)) return false;
2093         return true;
2094 }
2095
2096 .string shootfromfixedorigin;
2097 .bool dualwielding_prev;
2098 bool PlayerThink(entity this)
2099 {
2100         if (game_stopped || intermission_running) {
2101                 this.modelflags &= ~MF_ROCKET;
2102                 if(intermission_running)
2103                         IntermissionThink(this);
2104                 return false;
2105         }
2106
2107         if (timeout_status == TIMEOUT_ACTIVE) {
2108                 // don't allow the player to turn around while game is paused
2109                 // FIXME turn this into CSQC stuff
2110                 this.v_angle = this.lastV_angle;
2111                 this.angles = this.lastV_angle;
2112                 this.fixangle = true;
2113         }
2114
2115         if (frametime) player_powerups(this);
2116
2117         if (IS_DEAD(this)) {
2118                 if (this.personal && g_race_qualifying) {
2119                         if (time > this.respawn_time) {
2120                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2121                                 respawn(this);
2122                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2123                         }
2124                 } else {
2125                         if (frametime) player_anim(this);
2126
2127                         if (this.respawn_flags & RESPAWN_DENY)
2128                         {
2129                                 STAT(RESPAWN_TIME, this) = 0;
2130                                 return false;
2131                         }
2132
2133                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2134
2135                         switch(this.deadflag)
2136                         {
2137                                 case DEAD_DYING:
2138                                 {
2139                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2140                                                 this.deadflag = DEAD_RESPAWNING;
2141                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2142                                                 this.deadflag = DEAD_DEAD;
2143                                         break;
2144                                 }
2145                                 case DEAD_DEAD:
2146                                 {
2147                                         if (button_pressed)
2148                                                 this.deadflag = DEAD_RESPAWNABLE;
2149                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2150                                                 this.deadflag = DEAD_RESPAWNING;
2151                                         break;
2152                                 }
2153                                 case DEAD_RESPAWNABLE:
2154                                 {
2155                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2156                                                 this.deadflag = DEAD_RESPAWNING;
2157                                         break;
2158                                 }
2159                                 case DEAD_RESPAWNING:
2160                                 {
2161                                         if (time > this.respawn_time)
2162                                         {
2163                                                 this.respawn_time = time + 1; // only retry once a second
2164                                                 this.respawn_time_max = this.respawn_time;
2165                                                 respawn(this);
2166                                         }
2167                                         break;
2168                                 }
2169                         }
2170
2171                         ShowRespawnCountdown(this);
2172
2173                         if (this.respawn_flags & RESPAWN_SILENT)
2174                                 STAT(RESPAWN_TIME, this) = 0;
2175                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2176                         {
2177                                 if (time < this.respawn_time)
2178                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2179                                 else if (this.deadflag != DEAD_RESPAWNING)
2180                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2181                         }
2182                         else
2183                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2184                 }
2185
2186                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2187                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2188                         STAT(RESPAWN_TIME, this) *= -1;
2189
2190                 return false;
2191         }
2192
2193         FixPlayermodel(this);
2194
2195         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2196                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2197                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2198         }
2199
2200         // reset gun alignment when dual wielding status changes
2201         // to ensure guns are always aligned right and left
2202         bool dualwielding = W_DualWielding(this);
2203         if(this.dualwielding_prev != dualwielding)
2204         {
2205                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2206                 this.dualwielding_prev = dualwielding;
2207         }
2208
2209         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2210         //if(frametime)
2211         {
2212                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2213                 {
2214                         .entity weaponentity = weaponentities[slot];
2215                         if(WEP_CVAR(vortex, charge_always))
2216                                 W_Vortex_Charge(this, weaponentity, frametime);
2217                         W_WeaponFrame(this, weaponentity);
2218                 }
2219         }
2220
2221         if (frametime)
2222         {
2223                 // WEAPONTODO: Add a weapon request for this
2224                 // rot vortex charge to the charge limit
2225                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2226                 {
2227                         .entity weaponentity = weaponentities[slot];
2228                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2229                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2230                 }
2231
2232                 player_regen(this);
2233                 player_anim(this);
2234                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2235         }
2236
2237         monsters_setstatus(this);
2238
2239         return true;
2240 }
2241
2242 .bool would_spectate;
2243 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2244 void ObserverOrSpectatorThink(entity this)
2245 {
2246         bool is_spec = IS_SPEC(this);
2247         if ( CS(this).impulse )
2248         {
2249                 int r = MinigameImpulse(this, CS(this).impulse);
2250                 if (!is_spec || r)
2251                         CS(this).impulse = 0;
2252
2253                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2254                 {
2255                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2256                         CS(this).impulse = 0;
2257                         return;
2258                 }
2259         }
2260
2261         if (this.flags & FL_JUMPRELEASED) {
2262                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2263                         this.flags &= ~FL_JUMPRELEASED;
2264                         this.flags |= FL_SPAWNING;
2265                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2266                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2267                         this.flags &= ~FL_JUMPRELEASED;
2268                         if(SpectateNext(this)) {
2269                                 TRANSMUTE(Spectator, this);
2270                         } else if (is_spec) {
2271                                 TRANSMUTE(Observer, this);
2272                                 PutClientInServer(this);
2273                         }
2274                         else
2275                                 this.would_spectate = false; // unable to spectate anyone
2276                         if (is_spec)
2277                                 CS(this).impulse = 0;
2278                 } else if (is_spec) {
2279                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2280                                 this.flags &= ~FL_JUMPRELEASED;
2281                                 if(SpectatePrev(this)) {
2282                                         TRANSMUTE(Spectator, this);
2283                                 } else {
2284                                         TRANSMUTE(Observer, this);
2285                                         PutClientInServer(this);
2286                                 }
2287                                 CS(this).impulse = 0;
2288                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2289                                 this.would_spectate = false;
2290                                 this.flags &= ~FL_JUMPRELEASED;
2291                                 TRANSMUTE(Observer, this);
2292                                 PutClientInServer(this);
2293                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2294                                 PutObserverInServer(this, false);
2295                                 this.would_spectate = true;
2296                         }
2297                 }
2298                 else {
2299                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2300                         if (PHYS_INPUT_BUTTON_USE(this))
2301                                 wouldclip = !wouldclip;
2302                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2303                         set_movetype(this, preferred_movetype);
2304                 }
2305         } else { // jump pressed
2306                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2307                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2308                         this.flags |= FL_JUMPRELEASED;
2309                         if(this.flags & FL_SPAWNING)
2310                         {
2311                                 this.flags &= ~FL_SPAWNING;
2312                                 if(joinAllowed(this))
2313                                         Join(this);
2314                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2315                                         CS(this).autojoin_checked = -1;
2316                                 return;
2317                         }
2318                 }
2319                 if(is_spec && !SpectateUpdate(this))
2320                         PutObserverInServer(this, false);
2321         }
2322         if (is_spec)
2323                 this.flags |= FL_CLIENT | FL_NOTARGET;
2324 }
2325
2326 void PlayerUseKey(entity this)
2327 {
2328         if (!IS_PLAYER(this))
2329                 return;
2330
2331         if(this.vehicle)
2332         {
2333                 if(!game_stopped)
2334                 {
2335                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2336                         return;
2337                 }
2338         }
2339         else if(autocvar_g_vehicles_enter)
2340         {
2341                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2342                 {
2343                         entity head, closest_target = NULL;
2344                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2345
2346                         while(head) // find the closest acceptable target to enter
2347                         {
2348                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2349                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2350                                 {
2351                                         if(closest_target)
2352                                         {
2353                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2354                                                 { closest_target = head; }
2355                                         }
2356                                         else { closest_target = head; }
2357                                 }
2358
2359                                 head = head.chain;
2360                         }
2361
2362                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2363                 }
2364         }
2365
2366         // a use key was pressed; call handlers
2367         MUTATOR_CALLHOOK(PlayerUseKey, this);
2368 }
2369
2370
2371 /*
2372 =============
2373 PlayerPreThink
2374
2375 Called every frame for each client before the physics are run
2376 =============
2377 */
2378 .float last_vehiclecheck;
2379 void PlayerPreThink (entity this)
2380 {
2381         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2382         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2383
2384         WarpZone_PlayerPhysics_FixVAngle(this);
2385
2386         if (frametime) {
2387                 // physics frames: update anticheat stuff
2388                 anticheat_prethink(this);
2389
2390                 // WORKAROUND: only use dropclient in server frames (frametime set).
2391                 // Never use it in cl_movement frames (frametime zero).
2392                 if (blockSpectators && IS_REAL_CLIENT(this)
2393                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2394                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2395                 {
2396                         if (dropclient_schedule(this))
2397                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2398                 }
2399         }
2400
2401         zoomstate_set = false;
2402
2403         // Check for nameless players
2404         if (this.netname == "" || this.netname != CS(this).netname_previous)
2405         {
2406                 bool assume_unchanged = (CS(this).netname_previous == "");
2407                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2408                 {
2409                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2410                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2411                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2412                         assume_unchanged = false;
2413                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2414                 }
2415                 if (isInvisibleString(this.netname))
2416                 {
2417                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2418                         sprint(this, "Warning: invisible names are not allowed.\n");
2419                         assume_unchanged = false;
2420                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2421                 }
2422                 if (!assume_unchanged && autocvar_sv_eventlog)
2423                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2424                 strcpy(CS(this).netname_previous, this.netname);
2425         }
2426
2427         // version nagging
2428         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2429         CS(this).version_nagtime = 0;
2430         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2431             // git client
2432         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2433             // git server
2434             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2435         } else {
2436             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2437             if (r < 0) { // old client
2438                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2439             } else if (r > 0) { // old server
2440                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2441             }
2442         }
2443     }
2444
2445         // GOD MODE info
2446         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2447         {
2448                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2449                 this.max_armorvalue = 0;
2450         }
2451
2452         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2453         {
2454                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2455                 {
2456                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2457                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2458                         if (this.iceblock)
2459                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2460
2461                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2462                                 Unfreeze(this, false);
2463                 }
2464                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2465                 {
2466                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2467                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2468
2469                         if (GetResource(this, RES_HEALTH) < 1)
2470                         {
2471                                 if (this.vehicle)
2472                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2473                                 if(this.event_damage)
2474                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2475                         }
2476                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2477                                 Unfreeze(this, false);
2478                 }
2479         }
2480
2481         MUTATOR_CALLHOOK(PlayerPreThink, this);
2482
2483         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2484         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2485         {
2486                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2487                 {
2488                         if(!it.owner)
2489                         {
2490                                 if(!it.team || SAME_TEAM(this, it))
2491                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2492                                 else if(autocvar_g_vehicles_steal)
2493                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2494                         }
2495                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2496                         {
2497                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2498                         }
2499                 });
2500
2501                 this.last_vehiclecheck = time + 1;
2502         }
2503
2504         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2505         {
2506                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2507                         PlayerUseKey(this);
2508                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2509         }
2510
2511         if (IS_REAL_CLIENT(this))
2512                 PrintWelcomeMessage(this);
2513
2514         if (IS_PLAYER(this)) {
2515                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2516                         error("Client can't be spawned as player on connection!");
2517                 if(!PlayerThink(this))
2518                         return;
2519         }
2520         else if (game_stopped || intermission_running) {
2521                 if(intermission_running)
2522                         IntermissionThink(this);
2523                 return;
2524         }
2525         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2526         {
2527                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2528                 CS(this).autojoin_checked = 1;
2529                 // don't do this in ClientConnect
2530                 // many things can go wrong if a client is spawned as player on connection
2531                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2532                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2533                                 && (!teamplay || autocvar_g_balance_teams)))
2534                 {
2535                         campaign_bots_may_start = true;
2536                         if(joinAllowed(this))
2537                                 Join(this);
2538                         return;
2539                 }
2540         }
2541         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2542                 ObserverOrSpectatorThink(this);
2543         }
2544
2545         // WEAPONTODO: Add weapon request for this
2546         if (!zoomstate_set) {
2547                 bool wep_zoomed = false;
2548                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2549                 {
2550                         .entity weaponentity = weaponentities[slot];
2551                         Weapon thiswep = this.(weaponentity).m_weapon;
2552                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2553                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2554                 }
2555                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2556         }
2557
2558         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2559         {
2560                 CS(this).teamkill_soundtime = 0;
2561
2562                 entity e = CS(this).teamkill_soundsource;
2563                 entity oldpusher = e.pusher;
2564                 e.pusher = this;
2565                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2566                 e.pusher = oldpusher;
2567         }
2568
2569         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2570                 CS(this).taunt_soundtime = 0;
2571                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2572         }
2573
2574         target_voicescript_next(this);
2575 }
2576
2577 void DrownPlayer(entity this)
2578 {
2579         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2580                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2581         {
2582                 STAT(AIR_FINISHED, this) = 0;
2583                 return;
2584         }
2585
2586         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2587         {
2588                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2589                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2590                 STAT(AIR_FINISHED, this) = 0;
2591         }
2592         else
2593         {
2594                 if (!STAT(AIR_FINISHED, this))
2595                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2596                 if (STAT(AIR_FINISHED, this) < time)
2597                 {       // drown!
2598                         if (this.pain_finished < time)
2599                         {
2600                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2601                                 this.pain_finished = time + 0.5;
2602                         }
2603                 }
2604         }
2605 }
2606
2607 .bool move_qcphysics;
2608
2609 void Player_Physics(entity this)
2610 {
2611         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2612
2613         if(!this.move_qcphysics)
2614                 return;
2615
2616         if(!frametime && !CS(this).pm_frametime)
2617                 return;
2618
2619         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2620
2621         CS(this).pm_frametime = 0;
2622 }
2623
2624 /*
2625 =============
2626 PlayerPostThink
2627
2628 Called every frame for each client after the physics are run
2629 =============
2630 */
2631 void PlayerPostThink (entity this)
2632 {
2633         Player_Physics(this);
2634
2635         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2636         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2637         if (IS_REAL_CLIENT(this))
2638         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2639         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2640         {
2641                 int totalClients = 0;
2642                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2643                 {
2644                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2645                         if (server_is_dedicated)
2646                         {
2647                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2648                                 {
2649                                         ++totalClients;
2650                                 });
2651                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2652                                         totalClients = 0;
2653                         }
2654                 }
2655                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2656                 {
2657                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2658                         {
2659                                 ++totalClients;
2660                         });
2661                 }
2662
2663                 if (totalClients < autocvar_sv_maxidle_minplayers)
2664                 {
2665                         // idle kick disabled
2666                         CS(this).parm_idlesince = time;
2667                 }
2668                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2669                 {
2670                         if (CS(this).idlekick_lasttimeleft)
2671                         {
2672                                 CS(this).idlekick_lasttimeleft = 0;
2673                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2674                         }
2675                 }
2676                 else
2677                 {
2678                         float maxidle_time = autocvar_sv_maxidle;
2679                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2680                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2681                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2682                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2683                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2684                         {
2685                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2686                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2687                                 else
2688                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2689                         }
2690                         if (timeleft <= 0) {
2691                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2692                                 {
2693                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2694                                         PutObserverInServer(this, true);
2695                                 }
2696                                 else
2697                                 {
2698                                         if (dropclient_schedule(this))
2699                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2700                                 }
2701                                 return;
2702                         }
2703                         else if (timeleft <= countdown_time) {
2704                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2705                                         play2(this, SND(TALK2));
2706                                 CS(this).idlekick_lasttimeleft = timeleft;
2707                         }
2708                 }
2709         }
2710
2711         CheatFrame(this);
2712
2713         if (game_stopped)
2714         {
2715                 this.solid = SOLID_NOT;
2716                 this.takedamage = DAMAGE_NO;
2717                 set_movetype(this, MOVETYPE_NONE);
2718                 CS(this).teamkill_complain = 0;
2719                 CS(this).teamkill_soundtime = 0;
2720                 CS(this).teamkill_soundsource = NULL;
2721         }
2722
2723         if (IS_PLAYER(this)) {
2724                 if(this.death_time == time && IS_DEAD(this))
2725                 {
2726                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2727                         // once all the damage events of this frame have been processed with normal size
2728                         this.maxs.z = 5;
2729                         setsize(this, this.mins, this.maxs);
2730                 }
2731                 DrownPlayer(this);
2732                 UpdateChatBubble(this);
2733                 if (CS(this).impulse) ImpulseCommands(this);
2734                 GetPressedKeys(this);
2735                 if (game_stopped)
2736                 {
2737                         CSQCMODEL_AUTOUPDATE(this);
2738                         return;
2739                 }
2740         }
2741         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2742         {
2743                 CS(this).pressedkeys = 0;
2744                 STAT(PRESSED_KEYS, this) = 0;
2745         }
2746
2747         if (this.waypointsprite_attachedforcarrier) {
2748                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2749                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2750         }
2751
2752         CSQCMODEL_AUTOUPDATE(this);
2753 }
2754
2755 // hack to copy the button fields from the client entity to the Client State
2756 void PM_UpdateButtons(entity this, entity store)
2757 {
2758         if(this.impulse)
2759                 store.impulse = this.impulse;
2760         this.impulse = 0;
2761
2762         bool typing = this.buttonchat || this.button12;
2763
2764         store.button0 = (typing) ? 0 : this.button0;
2765         //button1?!
2766         store.button2 = (typing) ? 0 : this.button2;
2767         store.button3 = (typing) ? 0 : this.button3;
2768         store.button4 = this.button4;
2769         store.button5 = (typing) ? 0 : this.button5;
2770         store.button6 = this.button6;
2771         store.button7 = this.button7;
2772         store.button8 = this.button8;
2773         store.button9 = this.button9;
2774         store.button10 = this.button10;
2775         store.button11 = this.button11;
2776         store.button12 = this.button12;
2777         store.button13 = this.button13;
2778         store.button14 = this.button14;
2779         store.button15 = this.button15;
2780         store.button16 = this.button16;
2781         store.buttonuse = this.buttonuse;
2782         store.buttonchat = this.buttonchat;
2783
2784         store.cursor_active = this.cursor_active;
2785         store.cursor_screen = this.cursor_screen;
2786         store.cursor_trace_start = this.cursor_trace_start;
2787         store.cursor_trace_endpos = this.cursor_trace_endpos;
2788         store.cursor_trace_ent = this.cursor_trace_ent;
2789
2790         store.ping = this.ping;
2791         store.ping_packetloss = this.ping_packetloss;
2792         store.ping_movementloss = this.ping_movementloss;
2793
2794         store.v_angle = this.v_angle;
2795         store.movement = this.movement;
2796 }
2797
2798 NET_HANDLE(fpsreport, bool)
2799 {
2800         int fps = ReadShort();
2801         PlayerScore_Set(sender, SP_FPS, fps);
2802         return true;
2803 }