qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38
  39 #include "../common/vehicles/all.qh"
  40
  41 #include "weapons/hitplot.qh"
  42 #include "weapons/weaponsystem.qh"
  43
  44 #include "../common/net_notice.qh"
  45 #include "../common/net_linked.qh"
  46 #include "../common/physics/player.qh"
  47
  48 #include "../common/items/_mod.qh"
  49
  50 #include "../common/mutators/mutator/waypoints/all.qh"
  51
  52 #include "../common/triggers/subs.qh"
  53 #include "../common/triggers/triggers.qh"
  54 #include "../common/triggers/trigger/secret.qh"
  55
  56 #include "../common/minigames/sv_minigames.qh"
  57
  58 #include "../common/items/inventory.qh"
  59
  60 #include "../common/monsters/sv_monsters.qh"
  61
  62 #include "../lib/warpzone/server.qh"
  63
  64 STATIC_METHOD(Client, Add, void(Client this, int _team))
  65 {
  66     ClientConnect(this);
  67     TRANSMUTE(Player, this);
  68     this.frame = 12; // 7
  69     this.team = _team;
  70     PutClientInServer(this);
  71 }
  72
  73 void PutObserverInServer(entity this);
  74
  75 STATIC_METHOD(Client, Remove, void(Client this))
  76 {
  77     TRANSMUTE(Observer, this);
  78     PutClientInServer(this);
  79     ClientDisconnect(this);
  80 }
  81
  82 void send_CSQC_teamnagger() {
  83         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  84 }
  85
  86 int CountSpectators(entity player, entity to)
  87 {
  88         if(!player) { return 0; } // not sure how, but best to be safe
  89
  90         int spec_count = 0;
  91
  92         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  93         {
  94                 spec_count++;
  95         });
  96
  97         return spec_count;
  98 }
  99
 100 void WriteSpectators(entity player, entity to)
 101 {
 102         if(!player) { return; } // not sure how, but best to be safe
 103
 104         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 105         {
 106                 WriteByte(MSG_ENTITY, num_for_edict(it));
 107         });
 108 }
 109
 110 bool ClientData_Send(entity this, entity to, int sf)
 111 {
 112         assert(to == this.owner, return false);
 113
 114         entity e = to;
 115         if (IS_SPEC(e)) e = e.enemy;
 116
 117         sf = 0;
 118         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 119         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 120         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 121         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 122
 123         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 124         WriteByte(MSG_ENTITY, sf);
 125
 126         if (sf & BIT(1))
 127                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 128
 129         if(sf & BIT(4))
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         CS(this).clientdata.drawonlytoclient = this;
 143         CS(this).clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(CS(this).clientdata);
 149         CS(this).clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         CS(e).clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 158 }
 159
 160 void SetSpectatee(entity this, entity spectatee);
 161 void SetSpectatee_status(entity this, int spectatee_num);
 162
 163
 164 /*
 165 =============
 166 CheckPlayerModel
 167
 168 Checks if the argument string can be a valid playermodel.
 169 Returns a valid one in doubt.
 170 =============
 171 */
 172 string FallbackPlayerModel;
 173 string CheckPlayerModel(string plyermodel) {
 174         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 175         {
 176                 // note: we cannot summon Don Strunzone here, some player may
 177                 // still have the model string set. In case anyone manages how
 178                 // to change a cvar default, we'll have a small leak here.
 179                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 180         }
 181         // only in right path
 182         if( substring(plyermodel,0,14) != "models/player/")
 183                 return FallbackPlayerModel;
 184         // only good file extensions
 185         if(substring(plyermodel,-4,4) != ".zym")
 186         if(substring(plyermodel,-4,4) != ".dpm")
 187         if(substring(plyermodel,-4,4) != ".iqm")
 188         if(substring(plyermodel,-4,4) != ".md3")
 189         if(substring(plyermodel,-4,4) != ".psk")
 190                 return FallbackPlayerModel;
 191         // forbid the LOD models
 192         if(substring(plyermodel, -9,5) == "_lod1")
 193                 return FallbackPlayerModel;
 194         if(substring(plyermodel, -9,5) == "_lod2")
 195                 return FallbackPlayerModel;
 196         if(plyermodel != strtolower(plyermodel))
 197                 return FallbackPlayerModel;
 198         // also, restrict to server models
 199         if(autocvar_sv_servermodelsonly)
 200         {
 201                 if(!fexists(plyermodel))
 202                         return FallbackPlayerModel;
 203         }
 204         return plyermodel;
 205 }
 206
 207 void setplayermodel(entity e, string modelname)
 208 {
 209         precache_model(modelname);
 210         _setmodel(e, modelname);
 211         player_setupanimsformodel(e);
 212         if(!autocvar_g_debug_globalsounds)
 213                 UpdatePlayerSounds(e);
 214 }
 215
 216 void FixPlayermodel(entity player);
 217 /** putting a client as observer in the server */
 218 void PutObserverInServer(entity this)
 219 {
 220     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 221         PlayerState_detach(this);
 222
 223         if (IS_PLAYER(this))
 224         {
 225                 if(this.health >= 1)
 226                 {
 227                         // despawn effect
 228                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229                 }
 230
 231                 // was a player, recount votes and ready status
 232                 if(IS_REAL_CLIENT(this))
 233                 {
 234                         if (vote_called) { VoteCount(false); }
 235                         ReadyCount();
 236                 }
 237     }
 238
 239     {
 240         entity spot = SelectSpawnPoint(this, true);
 241         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 242         this.angles = vec2(spot.angles);
 243         this.fixangle = true;
 244         // offset it so that the spectator spawns higher off the ground, looks better this way
 245         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 246         if (IS_REAL_CLIENT(this))
 247         {
 248             msg_entity = this;
 249             WriteByte(MSG_ONE, SVC_SETVIEW);
 250             WriteEntity(MSG_ONE, this);
 251         }
 252         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254         if(!autocvar_g_debug_globalsounds)
 255         {
 256                 // needed for player sounds
 257                 this.model = "";
 258                 FixPlayermodel(this);
 259         }
 260         setmodel(this, MDL_Null);
 261         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 262         this.view_ofs = '0 0 0';
 263     }
 264
 265     RemoveGrapplingHooks(this);
 266         Portal_ClearAll(this);
 267         Unfreeze(this);
 268         SetSpectatee(this, NULL);
 269
 270         if (this.alivetime)
 271         {
 272                 if (!warmup_stage)
 273                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 274                 this.alivetime = 0;
 275         }
 276
 277         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 278
 279         WaypointSprite_PlayerDead(this);
 280
 281         if (mutator_returnvalue) {
 282             // mutator prevents resetting teams+score
 283         } else {
 284                 int oldteam = this.team;
 285                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 286                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 287         this.frags = FRAGS_SPECTATOR;
 288         PlayerScore_Clear(this);  // clear scores when needed
 289     }
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 294                 if(!game_stopped)
 295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297
 298                 if(!CS(this).just_joined)
 299                         LogTeamchange(this.playerid, -1, 4);
 300                 else
 301                         CS(this).just_joined = false;
 302         }
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310     this.hud = HUD_NORMAL;
 311         TRANSMUTE(Observer, this);
 312         this.iscreature = false;
 313         this.teleportable = TELEPORT_SIMPLE;
 314         if(this.damagedbycontents)
 315                 IL_REMOVE(g_damagedbycontents, this);
 316         this.damagedbycontents = false;
 317         this.health = FRAGS_SPECTATOR;
 318         SetSpectatee_status(this, etof(this));
 319         this.takedamage = DAMAGE_NO;
 320         this.solid = SOLID_NOT;
 321         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 322         this.flags = FL_CLIENT | FL_NOTARGET;
 323         this.armorvalue = 666;
 324         this.effects = 0;
 325         this.armorvalue = autocvar_g_balance_armor_start;
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         this.stat_respawn_time = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_frame = 0;
 338         this.pain_finished = 0;
 339         this.strength_finished = 0;
 340         this.invincible_finished = 0;
 341         this.superweapons_finished = 0;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         this.revive_progress = 0;
 349         this.revival_time = 0;
 350
 351         this.items = 0;
 352         this.weapons = '0 0 0';
 353         this.drawonlytoclient = this;
 354
 355         this.weaponmodel = "";
 356         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 357         {
 358                 this.weaponentities[slot] = NULL;
 359         }
 360         this.exteriorweaponentity = NULL;
 361         CS(this).killcount = FRAGS_SPECTATOR;
 362         this.velocity = '0 0 0';
 363         this.avelocity = '0 0 0';
 364         this.punchangle = '0 0 0';
 365         this.punchvector = '0 0 0';
 366         this.oldvelocity = this.velocity;
 367         this.fire_endtime = -1;
 368         this.event_damage = func_null;
 369
 370         for(int slot = 0; slot < MAX_AXH; ++slot)
 371         {
 372                 entity axh = this.(AuxiliaryXhair[slot]);
 373                 this.(AuxiliaryXhair[slot]) = NULL;
 374
 375                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 376                         delete(axh);
 377         }
 378 }
 379
 380 int player_getspecies(entity this)
 381 {
 382         get_model_parameters(this.model, this.skin);
 383         int s = get_model_parameters_species;
 384         get_model_parameters(string_null, 0);
 385         if (s < 0) return SPECIES_HUMAN;
 386         return s;
 387 }
 388
 389 .float model_randomizer;
 390 void FixPlayermodel(entity player)
 391 {
 392         string defaultmodel = "";
 393         int defaultskin = 0;
 394         if(autocvar_sv_defaultcharacter)
 395         {
 396                 if(teamplay)
 397                 {
 398                         switch(player.team)
 399                         {
 400                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 401                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 402                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 403                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 404                         }
 405                 }
 406
 407                 if(defaultmodel == "")
 408                 {
 409                         defaultmodel = autocvar_sv_defaultplayermodel;
 410                         defaultskin = autocvar_sv_defaultplayerskin;
 411                 }
 412
 413                 int n = tokenize_console(defaultmodel);
 414                 if(n > 0)
 415                 {
 416                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 417                         // However, do NOT randomize if the player-selected model is in the list.
 418                         for (int i = 0; i < n; ++i)
 419                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 420                                         defaultmodel = argv(i);
 421                 }
 422
 423                 int i = strstrofs(defaultmodel, ":", 0);
 424                 if(i >= 0)
 425                 {
 426                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 427                         defaultmodel = substring(defaultmodel, 0, i);
 428                 }
 429         }
 430         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 431         {
 432                 if(teamplay)
 433                 {
 434                         switch(player.team)
 435                         {
 436                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 437                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 438                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 439                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 440                         }
 441                 }
 442
 443                 if(!defaultskin)
 444                         defaultskin = autocvar_sv_defaultplayerskin;
 445         }
 446
 447         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 448         defaultmodel = M_ARGV(0, string);
 449         defaultskin = M_ARGV(1, int);
 450
 451         bool chmdl = false;
 452         int oldskin;
 453         if(defaultmodel != "")
 454         {
 455                 if (defaultmodel != player.model)
 456                 {
 457                         vector m1 = player.mins;
 458                         vector m2 = player.maxs;
 459                         setplayermodel (player, defaultmodel);
 460                         setsize (player, m1, m2);
 461                         chmdl = true;
 462                 }
 463
 464                 oldskin = player.skin;
 465                 player.skin = defaultskin;
 466         } else {
 467                 if (player.playermodel != player.model || player.playermodel == "")
 468                 {
 469                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 470                         vector m1 = player.mins;
 471                         vector m2 = player.maxs;
 472                         setplayermodel (player, player.playermodel);
 473                         setsize (player, m1, m2);
 474                         chmdl = true;
 475                 }
 476
 477                 if(!autocvar_sv_defaultcharacterskin)
 478                 {
 479                         oldskin = player.skin;
 480                         player.skin = stof(player.playerskin);
 481                 }
 482                 else
 483                 {
 484                         oldskin = player.skin;
 485                         player.skin = defaultskin;
 486                 }
 487         }
 488
 489         if(chmdl || oldskin != player.skin) // model or skin has changed
 490         {
 491                 player.species = player_getspecies(player); // update species
 492                 if(!autocvar_g_debug_globalsounds)
 493                         UpdatePlayerSounds(player); // update skin sounds
 494         }
 495
 496         if(!teamplay)
 497                 if(strlen(autocvar_sv_defaultplayercolors))
 498                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 499                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 500 }
 501
 502 void PutPlayerInServer(entity this)
 503 {
 504         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 505
 506         PlayerState_attach(this);
 507         accuracy_resend(this);
 508
 509         if (this.team < 0)
 510                 JoinBestTeam(this, false, true);
 511
 512         entity spot = SelectSpawnPoint(this, false);
 513         if (!spot) {
 514                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 515                 return; // spawn failed
 516         }
 517
 518         TRANSMUTE(Player, this);
 519
 520         CS(this).wasplayer = true;
 521         this.iscreature = true;
 522         this.teleportable = TELEPORT_NORMAL;
 523         if(!this.damagedbycontents)
 524                 IL_PUSH(g_damagedbycontents, this);
 525         this.damagedbycontents = true;
 526         set_movetype(this, MOVETYPE_WALK);
 527         this.solid = SOLID_SLIDEBOX;
 528         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 529         if (autocvar_g_playerclip_collisions)
 530                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 531         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 532                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 533         this.frags = FRAGS_PLAYER;
 534         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 535         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 536         if (autocvar__notarget)
 537                 this.flags |= FL_NOTARGET;
 538         this.takedamage = DAMAGE_AIM;
 539         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 540
 541         if (warmup_stage) {
 542                 this.ammo_shells = warmup_start_ammo_shells;
 543                 this.ammo_nails = warmup_start_ammo_nails;
 544                 this.ammo_rockets = warmup_start_ammo_rockets;
 545                 this.ammo_cells = warmup_start_ammo_cells;
 546                 this.ammo_plasma = warmup_start_ammo_plasma;
 547                 this.ammo_fuel = warmup_start_ammo_fuel;
 548                 this.health = warmup_start_health;
 549                 this.armorvalue = warmup_start_armorvalue;
 550                 this.weapons = WARMUP_START_WEAPONS;
 551         } else {
 552                 this.ammo_shells = start_ammo_shells;
 553                 this.ammo_nails = start_ammo_nails;
 554                 this.ammo_rockets = start_ammo_rockets;
 555                 this.ammo_cells = start_ammo_cells;
 556                 this.ammo_plasma = start_ammo_plasma;
 557                 this.ammo_fuel = start_ammo_fuel;
 558                 this.health = start_health;
 559                 this.armorvalue = start_armorvalue;
 560                 this.weapons = start_weapons;
 561                 GiveRandomWeapons(this, random_start_weapons_count,
 562                         autocvar_g_random_start_weapons, random_start_ammo);
 563         }
 564         SetSpectatee_status(this, 0);
 565
 566         PS(this).dual_weapons = '0 0 0';
 567
 568         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 569
 570         this.items = start_items;
 571
 572         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 573         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 574         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 575         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 576         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 577         // extend the pause of rotting if client was reset at the beginning of the countdown
 578         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 579                 float f = game_starttime - time;
 580                 this.spawnshieldtime += f;
 581                 this.pauserotarmor_finished += f;
 582                 this.pauserothealth_finished += f;
 583                 this.pauseregen_finished += f;
 584         }
 585         this.damageforcescale = 2;
 586         this.death_time = 0;
 587         this.respawn_flags = 0;
 588         this.respawn_time = 0;
 589         this.stat_respawn_time = 0;
 590         this.scale = autocvar_sv_player_scale;
 591         this.fade_time = 0;
 592         this.pain_frame = 0;
 593         this.pain_finished = 0;
 594         this.pushltime = 0;
 595         setthink(this, func_null); // players have no think function
 596         this.nextthink = 0;
 597         this.dmg_team = 0;
 598         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 599
 600         this.deadflag = DEAD_NO;
 601
 602         this.angles = spot.angles;
 603         this.angles_z = 0; // never spawn tilted even if the spot says to
 604         if (IS_BOT_CLIENT(this))
 605                 this.v_angle = this.angles;
 606         this.fixangle = true; // turn this way immediately
 607         this.oldvelocity = this.velocity = '0 0 0';
 608         this.avelocity = '0 0 0';
 609         this.punchangle = '0 0 0';
 610         this.punchvector = '0 0 0';
 611
 612         this.strength_finished = 0;
 613         this.invincible_finished = 0;
 614         this.fire_endtime = -1;
 615         this.revive_progress = 0;
 616         this.revival_time = 0;
 617         this.air_finished = time + 12;
 618
 619         entity spawnevent = new_pure(spawnevent);
 620         spawnevent.owner = this;
 621         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 622
 623         // Cut off any still running player sounds.
 624         stopsound(this, CH_PLAYER_SINGLE);
 625
 626         this.model = "";
 627         FixPlayermodel(this);
 628         this.drawonlytoclient = NULL;
 629
 630         this.viewloc = NULL;
 631
 632         this.crouch = false;
 633         this.view_ofs = STAT(PL_VIEW_OFS, this);
 634         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 635         this.spawnorigin = spot.origin;
 636         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 637         // don't reset back to last position, even if new position is stuck in solid
 638         this.oldorigin = this.origin;
 639         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 640         if(this.conveyor)
 641                 IL_REMOVE(g_conveyed, this);
 642         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 643         this.hud = HUD_NORMAL;
 644
 645         this.event_damage = PlayerDamage;
 646
 647         if(!this.bot_attack)
 648                 IL_PUSH(g_bot_targets, this);
 649         this.bot_attack = true;
 650         if(!this.monster_attack)
 651                 IL_PUSH(g_monster_targets, this);
 652         this.monster_attack = true;
 653         navigation_dynamicgoal_init(this, false);
 654
 655         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 656
 657         if (CS(this).killcount == FRAGS_SPECTATOR) {
 658                 PlayerScore_Clear(this);
 659                 CS(this).killcount = 0;
 660         }
 661
 662         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 663         {
 664                 .entity weaponentity = weaponentities[slot];
 665                 entity oldwep = this.(weaponentity);
 666                 CL_SpawnWeaponentity(this, weaponentity);
 667                 if(oldwep && oldwep.owner == this)
 668                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 669         }
 670         this.alpha = default_player_alpha;
 671         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 672         this.exteriorweaponentity.alpha = default_weapon_alpha;
 673
 674         this.speedrunning = false;
 675
 676         target_voicescript_clear(this);
 677
 678         // reset fields the weapons may use
 679         FOREACH(Weapons, true, {
 680                 it.wr_resetplayer(it, this);
 681                         // reload all reloadable weapons
 682                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 683                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 684                         {
 685                                 .entity weaponentity = weaponentities[slot];
 686                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 687                         }
 688                 }
 689         });
 690
 691         {
 692                 string s = spot.target;
 693                 spot.target = string_null;
 694                 SUB_UseTargets(spot, this, NULL);
 695                 spot.target = s;
 696         }
 697
 698         Unfreeze(this);
 699
 700         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 701
 702         if (autocvar_spawn_debug)
 703         {
 704                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 705                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 706         }
 707
 708         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 709         {
 710                 .entity weaponentity = weaponentities[slot];
 711                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 712                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 713                 else
 714                         this.(weaponentity).m_switchweapon = WEP_Null;
 715                 this.(weaponentity).m_weapon = WEP_Null;
 716                 this.(weaponentity).weaponname = "";
 717                 this.(weaponentity).m_switchingweapon = WEP_Null;
 718                 this.(weaponentity).cnt = -1;
 719         }
 720
 721         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 722
 723         if (!warmup_stage && !this.alivetime)
 724                 this.alivetime = time;
 725
 726         antilag_clear(this, CS(this));
 727 }
 728
 729 /** Called when a client spawns in the server */
 730 void PutClientInServer(entity this)
 731 {
 732         if (IS_BOT_CLIENT(this)) {
 733                 TRANSMUTE(Player, this);
 734         } else if (IS_REAL_CLIENT(this)) {
 735                 msg_entity = this;
 736                 WriteByte(MSG_ONE, SVC_SETVIEW);
 737                 WriteEntity(MSG_ONE, this);
 738         }
 739         if (game_stopped)
 740                 TRANSMUTE(Observer, this);
 741
 742         SetSpectatee(this, NULL);
 743
 744         // reset player keys
 745         if(PS(this))
 746                 PS(this).itemkeys = 0;
 747
 748         MUTATOR_CALLHOOK(PutClientInServer, this);
 749
 750         if (IS_OBSERVER(this)) {
 751                 PutObserverInServer(this);
 752         } else if (IS_PLAYER(this)) {
 753                 PutPlayerInServer(this);
 754         }
 755 }
 756
 757 void ClientInit_misc(entity this);
 758
 759 // TODO do we need all these fields, or should we stop autodetecting runtime
 760 // changes and just have a console command to update this?
 761 bool ClientInit_SendEntity(entity this, entity to, int sf)
 762 {
 763         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 764         return = true;
 765         msg_entity = to;
 766         // MSG_INIT replacement
 767         // TODO: make easier to use
 768         Registry_send_all();
 769         W_PROP_reload(MSG_ONE, to);
 770         ClientInit_misc(this);
 771         MUTATOR_CALLHOOK(Ent_Init);
 772 }
 773 void ClientInit_misc(entity this)
 774 {
 775         int channel = MSG_ONE;
 776         WriteHeader(channel, ENT_CLIENT_INIT);
 777         WriteByte(channel, g_nexball_meter_period * 32);
 778         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 779         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 780         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 781         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 782         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 783         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 784         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 785         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 786
 787         if(sv_foginterval && world.fog != "")
 788                 WriteString(channel, world.fog);
 789         else
 790                 WriteString(channel, "");
 791         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 792         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 793         WriteByte(channel, serverflags);
 794         WriteCoord(channel, autocvar_g_trueaim_minrange);
 795 }
 796
 797 void ClientInit_CheckUpdate(entity this)
 798 {
 799         this.nextthink = time;
 800         if(this.count != autocvar_g_balance_armor_blockpercent)
 801         {
 802                 this.count = autocvar_g_balance_armor_blockpercent;
 803                 this.SendFlags |= 1;
 804         }
 805         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 806         {
 807                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 808                 this.SendFlags |= 1;
 809         }
 810 }
 811
 812 void ClientInit_Spawn()
 813 {
 814         entity e = new_pure(clientinit);
 815         setthink(e, ClientInit_CheckUpdate);
 816         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 817
 818         ClientInit_CheckUpdate(e);
 819 }
 820
 821 /*
 822 =============
 823 SetNewParms
 824 =============
 825 */
 826 void SetNewParms ()
 827 {
 828         // initialize parms for a new player
 829         parm1 = -(86400 * 366);
 830
 831         MUTATOR_CALLHOOK(SetNewParms);
 832 }
 833
 834 /*
 835 =============
 836 SetChangeParms
 837 =============
 838 */
 839 void SetChangeParms (entity this)
 840 {
 841         // save parms for level change
 842         parm1 = CS(this).parm_idlesince - time;
 843
 844         MUTATOR_CALLHOOK(SetChangeParms);
 845 }
 846
 847 /*
 848 =============
 849 DecodeLevelParms
 850 =============
 851 */
 852 void DecodeLevelParms(entity this)
 853 {
 854         // load parms
 855         CS(this).parm_idlesince = parm1;
 856         if (CS(this).parm_idlesince == -(86400 * 366))
 857                 CS(this).parm_idlesince = time;
 858
 859         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 860         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 861
 862         MUTATOR_CALLHOOK(DecodeLevelParms);
 863 }
 864
 865 /*
 866 =============
 867 ClientKill
 868
 869 Called when a client types 'kill' in the console
 870 =============
 871 */
 872
 873 .float clientkill_nexttime;
 874 void ClientKill_Now_TeamChange(entity this)
 875 {
 876         if(this.killindicator_teamchange == -1)
 877         {
 878                 JoinBestTeam( this, false, true );
 879         }
 880         else if(this.killindicator_teamchange == -2)
 881         {
 882                 if(blockSpectators)
 883                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 884                 PutObserverInServer(this);
 885         }
 886         else
 887                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 888         this.killindicator_teamchange = 0;
 889 }
 890
 891 void ClientKill_Now(entity this)
 892 {
 893         if(this.vehicle)
 894         {
 895             vehicles_exit(this.vehicle, VHEF_RELEASE);
 896             if(!this.killindicator_teamchange)
 897             {
 898             this.vehicle_health = -1;
 899             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 900             }
 901         }
 902
 903         if(this.killindicator && !wasfreed(this.killindicator))
 904                 delete(this.killindicator);
 905
 906         this.killindicator = NULL;
 907
 908         if(this.killindicator_teamchange)
 909                 ClientKill_Now_TeamChange(this);
 910
 911         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 912         {
 913                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 914         }
 915
 916         // now I am sure the player IS dead
 917 }
 918 void KillIndicator_Think(entity this)
 919 {
 920         if (game_stopped)
 921         {
 922                 this.owner.killindicator = NULL;
 923                 delete(this);
 924                 return;
 925         }
 926
 927         if (this.owner.alpha < 0 && !this.owner.vehicle)
 928         {
 929                 this.owner.killindicator = NULL;
 930                 delete(this);
 931                 return;
 932         }
 933
 934         if(this.cnt <= 0)
 935         {
 936                 ClientKill_Now(this.owner);
 937                 return;
 938         }
 939     else if(this.health == 1) // health == 1 means that it's silent
 940     {
 941         this.nextthink = time + 1;
 942         this.cnt -= 1;
 943     }
 944         else
 945         {
 946                 if(this.cnt <= 10)
 947                         setmodel(this, MDL_NUM(this.cnt));
 948                 if(IS_REAL_CLIENT(this.owner))
 949                 {
 950                         if(this.cnt <= 10)
 951                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 952                 }
 953                 this.nextthink = time + 1;
 954                 this.cnt -= 1;
 955         }
 956 }
 957
 958 float clientkilltime;
 959 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 960 {
 961         float killtime;
 962         float starttime;
 963
 964         if (game_stopped)
 965                 return;
 966
 967         killtime = autocvar_g_balance_kill_delay;
 968
 969     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 970         return;
 971     killtime = M_ARGV(1, float);
 972
 973         this.killindicator_teamchange = targetteam;
 974
 975     if(!this.killindicator)
 976         {
 977                 if(!IS_DEAD(this))
 978                 {
 979                         killtime = max(killtime, this.clientkill_nexttime - time);
 980                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 981                 }
 982
 983                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 984                 {
 985                         ClientKill_Now(this);
 986                 }
 987                 else
 988                 {
 989                         starttime = max(time, clientkilltime);
 990
 991                         this.killindicator = spawn();
 992                         this.killindicator.owner = this;
 993                         this.killindicator.scale = 0.5;
 994                         setattachment(this.killindicator, this, "");
 995                         setorigin(this.killindicator, '0 0 52');
 996                         setthink(this.killindicator, KillIndicator_Think);
 997                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 998                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 999                         this.killindicator.cnt = ceil(killtime);
1000                         this.killindicator.count = bound(0, ceil(killtime), 10);
1001                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1002
1003                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1004                         {
1005                                 it.killindicator = spawn();
1006                                 it.killindicator.owner = it;
1007                                 it.killindicator.scale = 0.5;
1008                                 setattachment(it.killindicator, it, "");
1009                                 setorigin(it.killindicator, '0 0 52');
1010                                 setthink(it.killindicator, KillIndicator_Think);
1011                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1012                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1013                                 it.killindicator.cnt = ceil(killtime);
1014                         });
1015                         this.lip = 0;
1016                 }
1017         }
1018         if(this.killindicator)
1019         {
1020                 if(targetteam == 0) // just die
1021                 {
1022                         this.killindicator.colormod = '0 0 0';
1023                         if(IS_REAL_CLIENT(this))
1024                         if(this.killindicator.cnt > 0)
1025                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1026                 }
1027                 else if(targetteam == -1) // auto
1028                 {
1029                         this.killindicator.colormod = '0 1 0';
1030                         if(IS_REAL_CLIENT(this))
1031                         if(this.killindicator.cnt > 0)
1032                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1033                 }
1034                 else if(targetteam == -2) // spectate
1035                 {
1036                         this.killindicator.colormod = '0.5 0.5 0.5';
1037                         if(IS_REAL_CLIENT(this))
1038                         if(this.killindicator.cnt > 0)
1039                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1040                 }
1041                 else
1042                 {
1043                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1044                         if(IS_REAL_CLIENT(this))
1045                         if(this.killindicator.cnt > 0)
1046                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1047                 }
1048         }
1049
1050 }
1051
1052 void ClientKill (entity this)
1053 {
1054         if(game_stopped) return;
1055         if(this.player_blocked) return;
1056         if(STAT(FROZEN, this)) return;
1057
1058         ClientKill_TeamChange(this, 0);
1059 }
1060
1061 void FixClientCvars(entity e)
1062 {
1063         // send prediction settings to the client
1064         stuffcmd(e, "\nin_bindmap 0 0\n");
1065         if(autocvar_g_antilag == 3) // client side hitscan
1066                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1067         if(autocvar_sv_gentle)
1068                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1069
1070         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1071         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1072
1073         MUTATOR_CALLHOOK(FixClientCvars, e);
1074 }
1075
1076 bool findinlist_abbrev(string tofind, string list)
1077 {
1078         if(list == "" || tofind == "")
1079                 return false; // empty list or search, just return
1080
1081         // this function allows abbreviated strings!
1082         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1083         {
1084                 return true;
1085         });
1086
1087         return false;
1088 }
1089
1090 bool PlayerInIPList(entity p, string iplist)
1091 {
1092         // some safety checks (never allow local?)
1093         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1094                 return false;
1095
1096         return findinlist_abbrev(p.netaddress, iplist);
1097 }
1098
1099 bool PlayerInIDList(entity p, string idlist)
1100 {
1101         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1102         if(!p.crypto_idfp)
1103                 return false;
1104
1105         return findinlist_abbrev(p.crypto_idfp, idlist);
1106 }
1107
1108 bool PlayerInList(entity player, string list)
1109 {
1110         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1111 }
1112
1113 #ifdef DP_EXT_PRECONNECT
1114 /*
1115 =============
1116 ClientPreConnect
1117
1118 Called once (not at each match start) when a client begins a connection to the server
1119 =============
1120 */
1121 void ClientPreConnect(entity this)
1122 {
1123         if(autocvar_sv_eventlog)
1124         {
1125                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1126                         this.playerid,
1127                         etof(this),
1128                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1129                 ));
1130         }
1131 }
1132 #endif
1133
1134 /**
1135 =============
1136 ClientConnect
1137
1138 Called when a client connects to the server
1139 =============
1140 */
1141 void ClientConnect(entity this)
1142 {
1143         if (Ban_MaybeEnforceBanOnce(this)) return;
1144         assert(!IS_CLIENT(this), return);
1145         this.flags |= FL_CLIENT;
1146         assert(player_count >= 0, player_count = 0);
1147
1148 #ifdef WATERMARK
1149         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1150 #endif
1151         TRANSMUTE(Client, this);
1152         CS(this).version_nagtime = time + 10 + random() * 10;
1153
1154         // identify the right forced team
1155         if (autocvar_g_campaign)
1156         {
1157                 if (IS_REAL_CLIENT(this)) // only players, not bots
1158                 {
1159                         switch (autocvar_g_campaign_forceteam)
1160                         {
1161                                 case 1: this.team_forced = NUM_TEAM_1; break;
1162                                 case 2: this.team_forced = NUM_TEAM_2; break;
1163                                 case 3: this.team_forced = NUM_TEAM_3; break;
1164                                 case 4: this.team_forced = NUM_TEAM_4; break;
1165                                 default: this.team_forced = 0;
1166                         }
1167                 }
1168         }
1169         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1170         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1171         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1172         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1173         else switch (autocvar_g_forced_team_otherwise)
1174         {
1175                 default: this.team_forced = 0; break;
1176                 case "red": this.team_forced = NUM_TEAM_1; break;
1177                 case "blue": this.team_forced = NUM_TEAM_2; break;
1178                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1179                 case "pink": this.team_forced = NUM_TEAM_4; break;
1180                 case "spectate":
1181                 case "spectator":
1182                         this.team_forced = -1;
1183                         break;
1184         }
1185         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1186
1187     {
1188         int id = this.playerid;
1189         this.playerid = 0; // silent
1190             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1191             this.playerid = id;
1192     }
1193
1194         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1195                 TRANSMUTE(Observer, this);
1196         } else {
1197                 if (!teamplay || autocvar_g_balance_teams) {
1198                         TRANSMUTE(Player, this);
1199                         campaign_bots_may_start = true;
1200                 } else {
1201                         TRANSMUTE(Observer, this); // do it anyway
1202                 }
1203         }
1204
1205         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1206
1207         // always track bots, don't ask for cl_allow_uidtracking
1208         if (IS_BOT_CLIENT(this))
1209                 PlayerStats_GameReport_AddPlayer(this);
1210         else
1211                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1212
1213         if (autocvar_sv_eventlog)
1214                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1215
1216         LogTeamchange(this.playerid, this.team, 1);
1217
1218         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1219
1220         if(teamplay && IS_PLAYER(this))
1221                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1222         else
1223                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1224
1225         stuffcmd(this, clientstuff, "\n");
1226         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1227
1228         FixClientCvars(this);
1229
1230         // get version info from player
1231         stuffcmd(this, "cmd clientversion $gameversion\n");
1232
1233         // notify about available teams
1234         if (teamplay)
1235         {
1236                 CheckAllowedTeams(this);
1237                 int t = 0;
1238                 if (c1 >= 0) t |= BIT(0);
1239                 if (c2 >= 0) t |= BIT(1);
1240                 if (c3 >= 0) t |= BIT(2);
1241                 if (c4 >= 0) t |= BIT(3);
1242                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1243         }
1244         else
1245         {
1246                 stuffcmd(this, "set _teams_available 0\n");
1247         }
1248
1249         bot_relinkplayerlist();
1250
1251         CS(this).spectatortime = time;
1252         if (blockSpectators)
1253         {
1254                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1255         }
1256
1257         CS(this).jointime = time;
1258
1259         if (IS_REAL_CLIENT(this))
1260         {
1261                 if (g_weaponarena_weapons == WEPSET(TUBA))
1262                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1263         }
1264
1265         if (!sv_foginterval && world.fog != "")
1266                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1267
1268         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1269                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1270                         send_CSQC_teamnagger();
1271
1272         CSQCMODEL_AUTOINIT(this);
1273
1274         CS(this).model_randomizer = random();
1275
1276         if (IS_REAL_CLIENT(this))
1277                 sv_notice_join(this);
1278
1279         // update physics stats (players can spawn before physics runs)
1280         Physics_UpdateStats(this);
1281
1282         IL_EACH(g_initforplayer, it.init_for_player, {
1283                 it.init_for_player(it, this);
1284         });
1285
1286         Handicap_Initialize(this);
1287
1288         MUTATOR_CALLHOOK(ClientConnect, this);
1289
1290         if (IS_REAL_CLIENT(this))
1291         {
1292                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1293                 {
1294                         CS(this).motd_actived_time = -1;
1295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1296                 }
1297         }
1298 }
1299 /*
1300 =============
1301 ClientDisconnect
1302
1303 Called when a client disconnects from the server
1304 =============
1305 */
1306 .entity chatbubbleentity;
1307 void ReadyCount();
1308 void ClientDisconnect(entity this)
1309 {
1310         assert(IS_CLIENT(this), return);
1311
1312         PlayerStats_GameReport_FinalizePlayer(this);
1313         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1314         if (CS(this).active_minigame) part_minigame(this);
1315         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1316
1317         if (autocvar_sv_eventlog)
1318                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1319
1320         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1321
1322         if(IS_SPEC(this))
1323                 SetSpectatee(this, NULL);
1324
1325     MUTATOR_CALLHOOK(ClientDisconnect, this);
1326
1327         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1328         ClientState_detach(this);
1329
1330         Portal_ClearAll(this);
1331
1332         Unfreeze(this);
1333
1334         RemoveGrapplingHooks(this);
1335
1336         // Here, everything has been done that requires this player to be a client.
1337
1338         this.flags &= ~FL_CLIENT;
1339
1340         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1341         if (this.killindicator) delete(this.killindicator);
1342
1343         WaypointSprite_PlayerGone(this);
1344
1345         bot_relinkplayerlist();
1346
1347         if (this.clientstatus) strunzone(this.clientstatus);
1348         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1349         if (this.personal) delete(this.personal);
1350
1351         this.playerid = 0;
1352         ReadyCount();
1353         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1354
1355         ONREMOVE(this);
1356 }
1357
1358 void ChatBubbleThink(entity this)
1359 {
1360         this.nextthink = time;
1361         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1362         {
1363                 if(this.owner) // but why can that ever be NULL?
1364                         this.owner.chatbubbleentity = NULL;
1365                 delete(this);
1366                 return;
1367         }
1368
1369         this.mdl = "";
1370
1371         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1372         {
1373                 if ( CS(this.owner).active_minigame )
1374                         this.mdl = "models/sprites/minigame_busy.iqm";
1375                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1376                         this.mdl = "models/misc/chatbubble.spr";
1377         }
1378
1379         if ( this.model != this.mdl )
1380                 _setmodel(this, this.mdl);
1381
1382 }
1383
1384 void UpdateChatBubble(entity this)
1385 {
1386         if (this.alpha < 0)
1387                 return;
1388         // spawn a chatbubble entity if needed
1389         if (!this.chatbubbleentity)
1390         {
1391                 this.chatbubbleentity = new(chatbubbleentity);
1392                 this.chatbubbleentity.owner = this;
1393                 this.chatbubbleentity.exteriormodeltoclient = this;
1394                 setthink(this.chatbubbleentity, ChatBubbleThink);
1395                 this.chatbubbleentity.nextthink = time;
1396                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1397                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1398                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1399                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1400                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1401                 //this.chatbubbleentity.model = "";
1402                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1403         }
1404 }
1405
1406
1407 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1408 // added to the model skins
1409 /*void UpdateColorModHack()
1410 {
1411         float c;
1412         c = this.clientcolors & 15;
1413         // LordHavoc: only bothering to support white, green, red, yellow, blue
1414              if (!teamplay) this.colormod = '0 0 0';
1415         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1416         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1417         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1418         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1419         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1420         else this.colormod = '1 1 1';
1421 }*/
1422
1423 void respawn(entity this)
1424 {
1425         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1426         {
1427                 this.solid = SOLID_NOT;
1428                 this.takedamage = DAMAGE_NO;
1429                 set_movetype(this, MOVETYPE_FLY);
1430                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1431                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1432                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1433                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1434                 if(autocvar_g_respawn_ghosts_maxtime)
1435                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1436         }
1437
1438         CopyBody(this, 1);
1439
1440         this.effects |= EF_NODRAW; // prevent another CopyBody
1441         PutClientInServer(this);
1442 }
1443
1444 void play_countdown(entity this, float finished, Sound samp)
1445 {
1446     TC(Sound, samp);
1447         if(IS_REAL_CLIENT(this))
1448                 if(floor(finished - time - frametime) != floor(finished - time))
1449                         if(finished - time < 6)
1450                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1451 }
1452
1453 void player_powerups(entity this)
1454 {
1455         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1456         int items_prev = this.items;
1457
1458         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1459                 this.modelflags |= MF_ROCKET;
1460         else
1461                 this.modelflags &= ~MF_ROCKET;
1462
1463         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1464
1465         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1466                 return;
1467
1468         Fire_ApplyDamage(this);
1469         Fire_ApplyEffect(this);
1470
1471         if (!g_instagib)
1472         {
1473                 if (this.items & ITEM_Strength.m_itemid)
1474                 {
1475                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1476                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1477                         if (time > this.strength_finished)
1478                         {
1479                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1480                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1481                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1482                         }
1483                 }
1484                 else
1485                 {
1486                         if (time < this.strength_finished)
1487                         {
1488                                 this.items = this.items | ITEM_Strength.m_itemid;
1489                                 if(!g_cts)
1490                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1491                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1492                         }
1493                 }
1494                 if (this.items & ITEM_Shield.m_itemid)
1495                 {
1496                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1497                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1498                         if (time > this.invincible_finished)
1499                         {
1500                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1501                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1502                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1503                         }
1504                 }
1505                 else
1506                 {
1507                         if (time < this.invincible_finished)
1508                         {
1509                                 this.items = this.items | ITEM_Shield.m_itemid;
1510                                 if(!g_cts)
1511                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1512                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1513                         }
1514                 }
1515                 if (this.items & IT_SUPERWEAPON)
1516                 {
1517                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1518                         {
1519                                 this.superweapons_finished = 0;
1520                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1521                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1522                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1523                         }
1524                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1525                         {
1526                                 // don't let them run out
1527                         }
1528                         else
1529                         {
1530                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1531                                 if (time > this.superweapons_finished)
1532                                 {
1533                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1534                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1535                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1536                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1537                                 }
1538                         }
1539                 }
1540                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1541                 {
1542                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1543                         {
1544                                 this.items = this.items | IT_SUPERWEAPON;
1545                                 if(!g_cts)
1546                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1547                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1548                         }
1549                         else
1550                         {
1551                                 this.superweapons_finished = 0;
1552                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1553                         }
1554                 }
1555                 else
1556                 {
1557                         this.superweapons_finished = 0;
1558                 }
1559         }
1560
1561         if(autocvar_g_nodepthtestplayers)
1562                 this.effects = this.effects | EF_NODEPTHTEST;
1563
1564         if(autocvar_g_fullbrightplayers)
1565                 this.effects = this.effects | EF_FULLBRIGHT;
1566
1567         if (time >= game_starttime)
1568         if (time < this.spawnshieldtime)
1569                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1570
1571         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1572 }
1573
1574 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1575 {
1576         if(current > stable)
1577                 return current;
1578         else if(current > stable - 0.25) // when close enough, "snap"
1579                 return stable;
1580         else
1581                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1582 }
1583
1584 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1585 {
1586         if(current < stable)
1587                 return current;
1588         else if(current < stable + 0.25) // when close enough, "snap"
1589                 return stable;
1590         else
1591                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1592 }
1593
1594 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1595 {
1596         if(current > rotstable)
1597         {
1598                 if(rotframetime > 0)
1599                 {
1600                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1601                         current = max(rotstable, current - rotlinear * rotframetime);
1602                 }
1603         }
1604         else if(current < regenstable)
1605         {
1606                 if(regenframetime > 0)
1607                 {
1608                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1609                         current = min(regenstable, current + regenlinear * regenframetime);
1610                 }
1611         }
1612
1613         if(current > limit)
1614                 current = limit;
1615
1616         return current;
1617 }
1618
1619 void player_regen(entity this)
1620 {
1621         float max_mod, regen_mod, rot_mod, limit_mod;
1622         max_mod = regen_mod = rot_mod = limit_mod = 1;
1623
1624         float regen_health = autocvar_g_balance_health_regen;
1625         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1626         float regen_health_rot = autocvar_g_balance_health_rot;
1627         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1628         float regen_health_stable = autocvar_g_balance_health_regenstable;
1629         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1630         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1631                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1632         max_mod = M_ARGV(1, float);
1633         regen_mod = M_ARGV(2, float);
1634         rot_mod = M_ARGV(3, float);
1635         limit_mod = M_ARGV(4, float);
1636         regen_health = M_ARGV(5, float);
1637         regen_health_linear = M_ARGV(6, float);
1638         regen_health_rot = M_ARGV(7, float);
1639         regen_health_rotlinear = M_ARGV(8, float);
1640         regen_health_stable = M_ARGV(9, float);
1641         regen_health_rotstable = M_ARGV(10, float);
1642
1643         if(!mutator_returnvalue)
1644         if(!STAT(FROZEN, this))
1645         {
1646                 float mina, maxa, limith, limita;
1647                 maxa = autocvar_g_balance_armor_rotstable;
1648                 mina = autocvar_g_balance_armor_regenstable;
1649                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1650                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1651
1652                 regen_health_rotstable = regen_health_rotstable * max_mod;
1653                 regen_health_stable = regen_health_stable * max_mod;
1654                 limith = limith * limit_mod;
1655                 limita = limita * limit_mod;
1656
1657                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1658                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1659         }
1660
1661         // if player rotted to death...  die!
1662         // check this outside above checks, as player may still be able to rot to death
1663         if(this.health < 1)
1664         {
1665                 if(this.vehicle)
1666                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1667                 if(this.event_damage)
1668                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1669         }
1670
1671         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1672         {
1673                 float minf, maxf, limitf;
1674
1675                 maxf = autocvar_g_balance_fuel_rotstable;
1676                 minf = autocvar_g_balance_fuel_regenstable;
1677                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1678
1679                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1680         }
1681         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1682         // TODO: Remove this hack when all code uses GivePlayerHealth and
1683         // GivePlayerArmor.
1684         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1685         {
1686                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1687         }
1688         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1689         {
1690                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1691         }
1692         // End hack.
1693 }
1694
1695 bool zoomstate_set;
1696 void SetZoomState(entity this, float newzoom)
1697 {
1698         if(newzoom != CS(this).zoomstate)
1699         {
1700                 CS(this).zoomstate = newzoom;
1701                 ClientData_Touch(this);
1702         }
1703         zoomstate_set = true;
1704 }
1705
1706 void GetPressedKeys(entity this)
1707 {
1708         MUTATOR_CALLHOOK(GetPressedKeys, this);
1709         int keys = STAT(PRESSED_KEYS, this);
1710         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1711         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1712         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1713         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1714
1715         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1716         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1717         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1718         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1719         CS(this).pressedkeys = keys; // store for other users
1720
1721         STAT(PRESSED_KEYS, this) = keys;
1722 }
1723
1724 /*
1725 ======================
1726 spectate mode routines
1727 ======================
1728 */
1729
1730 void SpectateCopy(entity this, entity spectatee)
1731 {
1732     TC(Client, this); TC(Client, spectatee);
1733
1734         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1735         PS(this) = PS(spectatee);
1736         this.armortype = spectatee.armortype;
1737         this.armorvalue = spectatee.armorvalue;
1738         this.ammo_cells = spectatee.ammo_cells;
1739         this.ammo_plasma = spectatee.ammo_plasma;
1740         this.ammo_shells = spectatee.ammo_shells;
1741         this.ammo_nails = spectatee.ammo_nails;
1742         this.ammo_rockets = spectatee.ammo_rockets;
1743         this.ammo_fuel = spectatee.ammo_fuel;
1744         this.clip_load = spectatee.clip_load;
1745         this.clip_size = spectatee.clip_size;
1746         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1747         this.health = spectatee.health;
1748         CS(this).impulse = 0;
1749         this.items = spectatee.items;
1750         this.last_pickup = spectatee.last_pickup;
1751         this.hit_time = spectatee.hit_time;
1752         this.strength_finished = spectatee.strength_finished;
1753         this.invincible_finished = spectatee.invincible_finished;
1754         this.superweapons_finished = spectatee.superweapons_finished;
1755         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1756         this.weapons = spectatee.weapons;
1757         this.vortex_charge = spectatee.vortex_charge;
1758         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1759         this.hagar_load = spectatee.hagar_load;
1760         this.arc_heat_percent = spectatee.arc_heat_percent;
1761         this.minelayer_mines = spectatee.minelayer_mines;
1762         this.punchangle = spectatee.punchangle;
1763         this.view_ofs = spectatee.view_ofs;
1764         this.velocity = spectatee.velocity;
1765         this.dmg_take = spectatee.dmg_take;
1766         this.dmg_save = spectatee.dmg_save;
1767         this.dmg_inflictor = spectatee.dmg_inflictor;
1768         this.v_angle = spectatee.v_angle;
1769         this.angles = spectatee.v_angle;
1770         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1771         this.revive_progress = spectatee.revive_progress;
1772         this.viewloc = spectatee.viewloc;
1773         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1774                 this.fixangle = true;
1775         setorigin(this, spectatee.origin);
1776         setsize(this, spectatee.mins, spectatee.maxs);
1777         SetZoomState(this, CS(spectatee).zoomstate);
1778
1779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1780         {
1781                 .entity weaponentity = weaponentities[slot];
1782                 this.(weaponentity) = spectatee.(weaponentity);
1783         }
1784
1785         for(int slot = 0; slot < MAX_AXH; ++slot)
1786         {
1787                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1788         }
1789
1790     anticheat_spectatecopy(this, spectatee);
1791         this.hud = spectatee.hud;
1792         if(spectatee.vehicle)
1793     {
1794         this.angles = spectatee.v_angle;
1795
1796         //this.fixangle = false;
1797         //this.velocity = spectatee.vehicle.velocity;
1798         this.vehicle_health = spectatee.vehicle_health;
1799         this.vehicle_shield = spectatee.vehicle_shield;
1800         this.vehicle_energy = spectatee.vehicle_energy;
1801         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1802         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1803         this.vehicle_reload1 = spectatee.vehicle_reload1;
1804         this.vehicle_reload2 = spectatee.vehicle_reload2;
1805
1806         //msg_entity = this;
1807
1808        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1809             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1810            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1811            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1812
1813         //WriteByte (MSG_ONE, SVC_SETVIEW);
1814         //    WriteEntity(MSG_ONE, this);
1815         //makevectors(spectatee.v_angle);
1816         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1817     }
1818 }
1819
1820 bool SpectateUpdate(entity this)
1821 {
1822         if(!this.enemy)
1823                 return false;
1824
1825         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1826         {
1827                 SetSpectatee(this, NULL);
1828                 return false;
1829         }
1830
1831         SpectateCopy(this, this.enemy);
1832
1833         return true;
1834 }
1835
1836 bool SpectateSet(entity this)
1837 {
1838         if(!IS_PLAYER(this.enemy))
1839                 return false;
1840
1841         ClientData_Touch(this.enemy);
1842
1843         msg_entity = this;
1844         WriteByte(MSG_ONE, SVC_SETVIEW);
1845         WriteEntity(MSG_ONE, this.enemy);
1846         set_movetype(this, MOVETYPE_NONE);
1847         accuracy_resend(this);
1848
1849         if(!SpectateUpdate(this))
1850                 PutObserverInServer(this);
1851
1852         return true;
1853 }
1854
1855 void SetSpectatee_status(entity this, int spectatee_num)
1856 {
1857         int oldspectatee_status = CS(this).spectatee_status;
1858         CS(this).spectatee_status = spectatee_num;
1859
1860         if (CS(this).spectatee_status != oldspectatee_status)
1861         {
1862                 ClientData_Touch(this);
1863                 if (g_race || g_cts) race_InitSpectator();
1864         }
1865 }
1866
1867 void SetSpectatee(entity this, entity spectatee)
1868 {
1869         if(IS_BOT_CLIENT(this))
1870                 return; // bots abuse .enemy, this code is useless to them
1871
1872         entity old_spectatee = this.enemy;
1873
1874         this.enemy = spectatee;
1875
1876         // WEAPONTODO
1877         // these are required to fix the spectator bug with arc
1878         if(old_spectatee)
1879         {
1880                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1881                 {
1882                         .entity weaponentity = weaponentities[slot];
1883                         if(old_spectatee.(weaponentity).arc_beam)
1884                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1885                 }
1886         }
1887         if(this.enemy)
1888         {
1889                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1890                 {
1891                         .entity weaponentity = weaponentities[slot];
1892                         if(this.enemy.(weaponentity).arc_beam)
1893                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1894                 }
1895         }
1896
1897         if (this.enemy)
1898                 SetSpectatee_status(this, etof(this.enemy));
1899
1900         // needed to update spectator list
1901         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1902 }
1903
1904 bool Spectate(entity this, entity pl)
1905 {
1906         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1907                 return false;
1908         pl = M_ARGV(1, entity);
1909
1910         SetSpectatee(this, pl);
1911         return SpectateSet(this);
1912 }
1913
1914 bool SpectateNext(entity this)
1915 {
1916         entity ent = find(this.enemy, classname, STR_PLAYER);
1917
1918         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1919                 ent = M_ARGV(1, entity);
1920         else if (!ent)
1921                 ent = find(ent, classname, STR_PLAYER);
1922
1923         if(ent) { SetSpectatee(this, ent); }
1924
1925         return SpectateSet(this);
1926 }
1927
1928 bool SpectatePrev(entity this)
1929 {
1930         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1931         entity ent = findchain(classname, STR_PLAYER);
1932         if (!ent) // no player
1933                 return false;
1934
1935         entity first = ent;
1936         // skip players until current spectated player
1937         if(this.enemy)
1938         while(ent && ent != this.enemy)
1939                 ent = ent.chain;
1940
1941         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1942         {
1943                 case MUT_SPECPREV_FOUND:
1944                     ent = M_ARGV(1, entity);
1945                     break;
1946                 case MUT_SPECPREV_RETURN:
1947                     return true;
1948                 case MUT_SPECPREV_CONTINUE:
1949                 default:
1950                 {
1951                         if(ent.chain)
1952                                 ent = ent.chain;
1953                         else
1954                                 ent = first;
1955                         break;
1956                 }
1957         }
1958
1959         SetSpectatee(this, ent);
1960         return SpectateSet(this);
1961 }
1962
1963 /*
1964 =============
1965 ShowRespawnCountdown()
1966
1967 Update a respawn countdown display.
1968 =============
1969 */
1970 void ShowRespawnCountdown(entity this)
1971 {
1972         float number;
1973         if(!IS_DEAD(this)) // just respawned?
1974                 return;
1975         else
1976         {
1977                 number = ceil(this.respawn_time - time);
1978                 if(number <= 0)
1979                         return;
1980                 if(number <= this.respawn_countdown)
1981                 {
1982                         this.respawn_countdown = number - 1;
1983                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1984                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1985                 }
1986         }
1987 }
1988
1989 .bool team_selected;
1990 bool ShowTeamSelection(entity this)
1991 {
1992         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1993                 return false;
1994         stuffcmd(this, "menu_showteamselect\n");
1995         return true;
1996 }
1997 void Join(entity this)
1998 {
1999         TRANSMUTE(Player, this);
2000
2001         if(!this.team_selected)
2002         if(autocvar_g_campaign || autocvar_g_balance_teams)
2003                 JoinBestTeam(this, false, true);
2004
2005         if(autocvar_g_campaign)
2006                 campaign_bots_may_start = true;
2007
2008         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2009
2010         PutClientInServer(this);
2011
2012         if(IS_PLAYER(this))
2013         if(teamplay && this.team != -1)
2014                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2015         else
2016                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2017         this.team_selected = false;
2018 }
2019
2020 /**
2021  * Determines whether the player is allowed to join. This depends on cvar
2022  * g_maxplayers, if it isn't used this function always return true, otherwise
2023  * it checks whether the number of currently playing players exceeds g_maxplayers.
2024  * @return int number of free slots for players, 0 if none
2025  */
2026 int nJoinAllowed(entity this, entity ignore)
2027 {
2028         if(!ignore)
2029         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2030         // so report 0 free slots if restricted
2031         {
2032                 if(autocvar_g_forced_team_otherwise == "spectate")
2033                         return 0;
2034                 if(autocvar_g_forced_team_otherwise == "spectator")
2035                         return 0;
2036         }
2037
2038         if(this && this.team_forced < 0)
2039                 return 0; // forced spectators can never join
2040
2041         // TODO simplify this
2042         int totalClients = 0;
2043         int currentlyPlaying = 0;
2044         FOREACH_CLIENT(true, {
2045                 if(it != ignore)
2046                         ++totalClients;
2047                 if(IS_REAL_CLIENT(it))
2048                 if(IS_PLAYER(it) || it.caplayer)
2049                         ++currentlyPlaying;
2050         });
2051
2052         float free_slots = 0;
2053         if (!autocvar_g_maxplayers)
2054                 free_slots = maxclients - totalClients;
2055         else if(currentlyPlaying < autocvar_g_maxplayers)
2056                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2057
2058         static float join_prevent_msg_time = 0;
2059         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2060         {
2061                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2062                 join_prevent_msg_time = time + 3;
2063         }
2064
2065         return free_slots;
2066 }
2067
2068 /**
2069  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2070  * g_maxplayers_spectator_blocktime seconds
2071  */
2072 void checkSpectatorBlock(entity this)
2073 {
2074         if(IS_SPEC(this) || IS_OBSERVER(this))
2075         if(!this.caplayer)
2076         if(IS_REAL_CLIENT(this))
2077         {
2078                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2079                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2080                         dropclient(this);
2081                 }
2082         }
2083 }
2084
2085 void PrintWelcomeMessage(entity this)
2086 {
2087         if(CS(this).motd_actived_time == 0)
2088         {
2089                 if (autocvar_g_campaign) {
2090                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2091                                 CS(this).motd_actived_time = time;
2092                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2093                         }
2094                 } else {
2095                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2096                                 CS(this).motd_actived_time = time;
2097                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2098                         }
2099                 }
2100         }
2101         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2102         {
2103                 if (autocvar_g_campaign) {
2104                         if (PHYS_INPUT_BUTTON_INFO(this))
2105                                 CS(this).motd_actived_time = time;
2106                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2107                                 CS(this).motd_actived_time = 0;
2108                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2109                         }
2110                 } else {
2111                         if (PHYS_INPUT_BUTTON_INFO(this))
2112                                 CS(this).motd_actived_time = time;
2113                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2114                                 CS(this).motd_actived_time = 0;
2115                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2116                         }
2117                 }
2118         }
2119         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2120         {
2121                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2122                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2123                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2124                 {
2125                         // instanctly hide MOTD
2126                         CS(this).motd_actived_time = 0;
2127                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2128                 }
2129         }
2130 }
2131
2132 bool joinAllowed(entity this)
2133 {
2134         if (CS(this).version_mismatch) return false;
2135         if (!nJoinAllowed(this, this)) return false;
2136         if (teamplay && lockteams) return false;
2137         if (ShowTeamSelection(this)) return false;
2138         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2139         return true;
2140 }
2141
2142 .int items_added;
2143 bool PlayerThink(entity this)
2144 {
2145         if (game_stopped || intermission_running) {
2146                 this.modelflags &= ~MF_ROCKET;
2147                 if(intermission_running)
2148                         IntermissionThink(this);
2149                 return false;
2150         }
2151
2152         if (timeout_status == TIMEOUT_ACTIVE) {
2153         // don't allow the player to turn around while game is paused
2154                 // FIXME turn this into CSQC stuff
2155                 this.v_angle = this.lastV_angle;
2156                 this.angles = this.lastV_angle;
2157                 this.fixangle = true;
2158         }
2159
2160         if (frametime) player_powerups(this);
2161
2162         if (IS_DEAD(this)) {
2163                 if (this.personal && g_race_qualifying) {
2164                         if (time > this.respawn_time) {
2165                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2166                                 respawn(this);
2167                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2168                         }
2169                 } else {
2170                         if (frametime) player_anim(this);
2171
2172                         if (this.respawn_flags & RESPAWN_DENY)
2173                         {
2174                                 STAT(RESPAWN_TIME, this) = 0;
2175                                 return false;
2176                         }
2177
2178                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2179
2180                         switch(this.deadflag)
2181                         {
2182                                 case DEAD_DYING:
2183                                 {
2184                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2185                                                 this.deadflag = DEAD_RESPAWNING;
2186                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2187                                                 this.deadflag = DEAD_DEAD;
2188                                         break;
2189                                 }
2190                                 case DEAD_DEAD:
2191                                 {
2192                                         if (button_pressed)
2193                                                 this.deadflag = DEAD_RESPAWNABLE;
2194                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2195                                                 this.deadflag = DEAD_RESPAWNING;
2196                                         break;
2197                                 }
2198                                 case DEAD_RESPAWNABLE:
2199                                 {
2200                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2201                                                 this.deadflag = DEAD_RESPAWNING;
2202                                         break;
2203                                 }
2204                                 case DEAD_RESPAWNING:
2205                                 {
2206                                         if (time > this.respawn_time)
2207                                         {
2208                                                 this.respawn_time = time + 1; // only retry once a second
2209                                                 this.respawn_time_max = this.respawn_time;
2210                                                 respawn(this);
2211                                         }
2212                                         break;
2213                                 }
2214                         }
2215
2216                         ShowRespawnCountdown(this);
2217
2218                         if (this.respawn_flags & RESPAWN_SILENT)
2219                                 STAT(RESPAWN_TIME, this) = 0;
2220                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2221                         {
2222                                 if (time < this.respawn_time)
2223                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2224                                 else if (this.deadflag != DEAD_RESPAWNING)
2225                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2226                         }
2227                         else
2228                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2229                 }
2230
2231                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2232                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2233                         STAT(RESPAWN_TIME, this) *= -1;
2234
2235                 return false;
2236         }
2237
2238         bool have_hook = false;
2239         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2240         {
2241                 .entity weaponentity = weaponentities[slot];
2242                 if(this.(weaponentity).hook.state)
2243                 {
2244                         have_hook = true;
2245                         break;
2246                 }
2247         }
2248         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2249         if (have_hook) {
2250                 do_crouch = false;
2251         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2252                 do_crouch = false;
2253         } else if (this.vehicle) {
2254                 do_crouch = false;
2255         } else if (STAT(FROZEN, this)) {
2256                 do_crouch = false;
2257     }
2258
2259         if (do_crouch) {
2260                 if (!this.crouch) {
2261                         this.crouch = true;
2262                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2263                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2264                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2265                 }
2266         } else if (this.crouch) {
2267         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2268         if (!trace_startsolid) {
2269             this.crouch = false;
2270             this.view_ofs = STAT(PL_VIEW_OFS, this);
2271             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2272         }
2273         }
2274
2275         FixPlayermodel(this);
2276
2277         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2278         //if(frametime)
2279         {
2280                 this.items &= ~this.items_added;
2281
2282                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2283                 {
2284                         .entity weaponentity = weaponentities[slot];
2285                         W_WeaponFrame(this, weaponentity);
2286
2287                         if(slot == 0)
2288                         {
2289                                 this.clip_load = this.(weaponentity).clip_load;
2290                                 this.clip_size = this.(weaponentity).clip_size;
2291                         }
2292                 }
2293
2294                 this.items_added = 0;
2295                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2296             this.items_added |= IT_FUEL;
2297
2298                 this.items |= this.items_added;
2299         }
2300
2301         player_regen(this);
2302
2303         // WEAPONTODO: Add a weapon request for this
2304         // rot vortex charge to the charge limit
2305         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2306         {
2307                 .entity weaponentity = weaponentities[slot];
2308                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2309                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2310         }
2311
2312         if (frametime) player_anim(this);
2313
2314         // secret status
2315         secrets_setstatus(this);
2316
2317         // monsters status
2318         monsters_setstatus(this);
2319
2320         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2321
2322         return true;
2323 }
2324
2325 void ObserverThink(entity this)
2326 {
2327         if ( CS(this).impulse )
2328         {
2329                 MinigameImpulse(this, CS(this).impulse);
2330                 CS(this).impulse = 0;
2331         }
2332
2333         if (this.flags & FL_JUMPRELEASED) {
2334                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2335                         this.flags &= ~FL_JUMPRELEASED;
2336                         this.flags |= FL_SPAWNING;
2337                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2338                         this.flags &= ~FL_JUMPRELEASED;
2339                         if(SpectateNext(this)) {
2340                                 TRANSMUTE(Spectator, this);
2341                         }
2342                 } else {
2343                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2344                         set_movetype(this, preferred_movetype);
2345                 }
2346         } else {
2347                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2348                         this.flags |= FL_JUMPRELEASED;
2349                         if(this.flags & FL_SPAWNING)
2350                         {
2351                                 this.flags &= ~FL_SPAWNING;
2352                                 Join(this);
2353                                 return;
2354                         }
2355                 }
2356         }
2357 }
2358
2359 void SpectatorThink(entity this)
2360 {
2361         if ( CS(this).impulse )
2362         {
2363                 if(MinigameImpulse(this, CS(this).impulse))
2364                         CS(this).impulse = 0;
2365
2366                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2367                 {
2368                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2369                         CS(this).impulse = 0;
2370                         return;
2371                 }
2372         }
2373
2374         if (this.flags & FL_JUMPRELEASED) {
2375                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2376                         this.flags &= ~FL_JUMPRELEASED;
2377                         this.flags |= FL_SPAWNING;
2378                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2379                         this.flags &= ~FL_JUMPRELEASED;
2380                         if(SpectateNext(this)) {
2381                                 TRANSMUTE(Spectator, this);
2382                         } else {
2383                                 TRANSMUTE(Observer, this);
2384                                 PutClientInServer(this);
2385                         }
2386                         CS(this).impulse = 0;
2387                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2388                         this.flags &= ~FL_JUMPRELEASED;
2389                         if(SpectatePrev(this)) {
2390                                 TRANSMUTE(Spectator, this);
2391                         } else {
2392                                 TRANSMUTE(Observer, this);
2393                                 PutClientInServer(this);
2394                         }
2395                         CS(this).impulse = 0;
2396                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2397                         this.flags &= ~FL_JUMPRELEASED;
2398                         TRANSMUTE(Observer, this);
2399                         PutClientInServer(this);
2400                 } else {
2401                         if(!SpectateUpdate(this))
2402                                 PutObserverInServer(this);
2403                 }
2404         } else {
2405                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2406                         this.flags |= FL_JUMPRELEASED;
2407                         if(this.flags & FL_SPAWNING)
2408                         {
2409                                 this.flags &= ~FL_SPAWNING;
2410                                 Join(this);
2411                                 return;
2412                         }
2413                 }
2414                 if(!SpectateUpdate(this))
2415                         PutObserverInServer(this);
2416         }
2417
2418         this.flags |= FL_CLIENT | FL_NOTARGET;
2419 }
2420
2421 void vehicles_enter (entity pl, entity veh);
2422 void PlayerUseKey(entity this)
2423 {
2424         if (!IS_PLAYER(this))
2425                 return;
2426
2427         if(this.vehicle)
2428         {
2429                 if(!game_stopped)
2430                 {
2431                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2432                         return;
2433                 }
2434         }
2435         else if(autocvar_g_vehicles_enter)
2436         {
2437                 if(!STAT(FROZEN, this))
2438                 if(!IS_DEAD(this))
2439                 if(!game_stopped)
2440                 {
2441                         entity head, closest_target = NULL;
2442                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2443
2444                         while(head) // find the closest acceptable target to enter
2445                         {
2446                                 if(IS_VEHICLE(head))
2447                                 if(!IS_DEAD(head))
2448                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2449                                 if(head.takedamage != DAMAGE_NO)
2450                                 {
2451                                         if(closest_target)
2452                                         {
2453                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2454                                                 { closest_target = head; }
2455                                         }
2456                                         else { closest_target = head; }
2457                                 }
2458
2459                                 head = head.chain;
2460                         }
2461
2462                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2463                 }
2464         }
2465
2466         // a use key was pressed; call handlers
2467         MUTATOR_CALLHOOK(PlayerUseKey, this);
2468 }
2469
2470
2471 /*
2472 =============
2473 PlayerPreThink
2474
2475 Called every frame for each client before the physics are run
2476 =============
2477 */
2478 .float last_vehiclecheck;
2479 void PlayerPreThink (entity this)
2480 {
2481         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2482         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2483
2484         WarpZone_PlayerPhysics_FixVAngle(this);
2485
2486         if (frametime) {
2487                 // physics frames: update anticheat stuff
2488                 anticheat_prethink(this);
2489         }
2490
2491         if (blockSpectators && frametime) {
2492                 // WORKAROUND: only use dropclient in server frames (frametime set).
2493                 // Never use it in cl_movement frames (frametime zero).
2494                 checkSpectatorBlock(this);
2495         }
2496
2497         zoomstate_set = false;
2498
2499         // Check for nameless players
2500         if (this.netname == "" || this.netname != CS(this).netname_previous)
2501         {
2502                 bool assume_unchanged = (CS(this).netname_previous == "");
2503                 if (isInvisibleString(this.netname))
2504                 {
2505                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2506                         assume_unchanged = false;
2507                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2508                 }
2509                 if (!assume_unchanged && autocvar_sv_eventlog)
2510                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2511                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2512                 CS(this).netname_previous = strzone(this.netname);
2513         }
2514
2515         // version nagging
2516         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2517         CS(this).version_nagtime = 0;
2518         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2519             // git client
2520         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2521             // git server
2522             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2523         } else {
2524             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2525             if (r < 0) { // old client
2526                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2527             } else if (r > 0) { // old server
2528                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2529             }
2530         }
2531     }
2532
2533         // GOD MODE info
2534         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2535         {
2536                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2537                 this.max_armorvalue = 0;
2538         }
2539
2540         if(IS_PLAYER(this))
2541         {
2542                 if (STAT(FROZEN, this) == 2)
2543                 {
2544                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2545                         this.health = max(1, this.revive_progress * start_health);
2546                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2547
2548                         if (this.revive_progress >= 1)
2549                                 Unfreeze(this);
2550                 }
2551                 else if (STAT(FROZEN, this) == 3)
2552                 {
2553                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2554                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2555
2556                         if (this.health < 1)
2557                         {
2558                                 if (this.vehicle)
2559                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2560                                 if(this.event_damage)
2561                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2562                         }
2563                         else if (this.revive_progress <= 0)
2564                                 Unfreeze(this);
2565                 }
2566         }
2567
2568         MUTATOR_CALLHOOK(PlayerPreThink, this);
2569
2570         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2571         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2572         {
2573                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2574                 {
2575                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2576                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2577                         {
2578                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2579                         }
2580                         else if(!it.owner)
2581                         {
2582                                 if(!it.team || SAME_TEAM(this, it))
2583                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2584                                 else if(autocvar_g_vehicles_steal)
2585                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2586                         }
2587                 });
2588
2589                 this.last_vehiclecheck = time + 1;
2590         }
2591
2592         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2593         {
2594                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2595                         PlayerUseKey(this);
2596                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2597         }
2598
2599         if (IS_REAL_CLIENT(this))
2600                 PrintWelcomeMessage(this);
2601
2602         if (IS_PLAYER(this)) {
2603                 if(!PlayerThink(this))
2604                         return;
2605         }
2606         else if (game_stopped || intermission_running) {
2607                 if(intermission_running)
2608                         IntermissionThink(this);
2609                 return;
2610         }
2611         else if (IS_OBSERVER(this)) {
2612                 ObserverThink(this);
2613         }
2614         else if (IS_SPEC(this)) {
2615                 SpectatorThink(this);
2616         }
2617
2618         // WEAPONTODO: Add weapon request for this
2619         if (!zoomstate_set) {
2620                 bool wep_zoomed = false;
2621                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2622                 {
2623                         .entity weaponentity = weaponentities[slot];
2624                         Weapon thiswep = this.(weaponentity).m_weapon;
2625                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2626                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2627                 }
2628                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2629     }
2630
2631         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2632         {
2633                 CS(this).teamkill_soundtime = 0;
2634
2635                 entity e = CS(this).teamkill_soundsource;
2636                 entity oldpusher = e.pusher;
2637                 e.pusher = this;
2638                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2639                 e.pusher = oldpusher;
2640         }
2641
2642         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2643                 CS(this).taunt_soundtime = 0;
2644                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2645         }
2646
2647         target_voicescript_next(this);
2648
2649         // WEAPONTODO: Move into weaponsystem somehow
2650         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2651         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2652         {
2653                 .entity weaponentity = weaponentities[slot];
2654                 if(this.(weaponentity).m_weapon == WEP_Null)
2655                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2656         }
2657 }
2658
2659 void DrownPlayer(entity this)
2660 {
2661         if(IS_DEAD(this))
2662                 return;
2663
2664         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2665         {
2666                 if(this.air_finished < time)
2667                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2668                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2669         }
2670         else if (this.air_finished < time)
2671         {       // drown!
2672                 if (this.pain_finished < time)
2673                 {
2674                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2675                         this.pain_finished = time + 0.5;
2676                 }
2677         }
2678 }
2679
2680 .bool move_qcphysics;
2681
2682 void Player_Physics(entity this)
2683 {
2684         set_movetype(this, this.move_movetype);
2685
2686         if(!this.move_qcphysics)
2687                 return;
2688
2689         if(!frametime && !CS(this).pm_frametime)
2690                 return;
2691
2692         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2693
2694         CS(this).pm_frametime = 0;
2695 }
2696
2697 /*
2698 =============
2699 PlayerPostThink
2700
2701 Called every frame for each client after the physics are run
2702 =============
2703 */
2704 void PlayerPostThink (entity this)
2705 {
2706         Player_Physics(this);
2707
2708         if (sv_maxidle > 0)
2709         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2710         if (IS_REAL_CLIENT(this))
2711         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2712         {
2713                 int totalClients = 0;
2714                 if(sv_maxidle_slots > 0)
2715                 {
2716                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2717                         {
2718                                 ++totalClients;
2719                         });
2720                 }
2721
2722                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2723                 { /* do nothing */ }
2724                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2725                 {
2726                         if (CS(this).idlekick_lasttimeleft)
2727                         {
2728                                 CS(this).idlekick_lasttimeleft = 0;
2729                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2730                         }
2731                 }
2732                 else
2733                 {
2734                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2735                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2736                                 if (!CS(this).idlekick_lasttimeleft)
2737                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2738                         }
2739                         if (timeleft <= 0) {
2740                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2741                                 dropclient(this);
2742                                 return;
2743                         }
2744                         else if (timeleft <= 10) {
2745                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2746                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2747                 }
2748                                 CS(this).idlekick_lasttimeleft = timeleft;
2749                         }
2750                 }
2751         }
2752
2753         CheatFrame(this);
2754
2755         if (game_stopped)
2756         {
2757                 this.solid = SOLID_NOT;
2758                 this.takedamage = DAMAGE_NO;
2759                 set_movetype(this, MOVETYPE_NONE);
2760         }
2761
2762         if (IS_PLAYER(this)) {
2763                 DrownPlayer(this);
2764                 UpdateChatBubble(this);
2765                 if (CS(this).impulse) ImpulseCommands(this);
2766                 if (game_stopped)
2767                 {
2768                         CSQCMODEL_AUTOUPDATE(this);
2769                         return;
2770                 }
2771                 GetPressedKeys(this);
2772         }
2773
2774         if (this.waypointsprite_attachedforcarrier) {
2775             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2776                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2777     }
2778
2779         playerdemo_write(this);
2780
2781         CSQCMODEL_AUTOUPDATE(this);
2782 }
2783
2784 // hack to copy the button fields from the client entity to the Client State
2785 void PM_UpdateButtons(entity this, entity store)
2786 {
2787         if(this.impulse)
2788                 store.impulse = this.impulse;
2789         this.impulse = 0;
2790
2791         store.button0 = this.button0;
2792         store.button2 = this.button2;
2793         store.button3 = this.button3;
2794         store.button4 = this.button4;
2795         store.button5 = this.button5;
2796         store.button6 = this.button6;
2797         store.button7 = this.button7;
2798         store.button8 = this.button8;
2799         store.button9 = this.button9;
2800         store.button10 = this.button10;
2801         store.button11 = this.button11;
2802         store.button12 = this.button12;
2803         store.button13 = this.button13;
2804         store.button14 = this.button14;
2805         store.button15 = this.button15;
2806         store.button16 = this.button16;
2807         store.buttonuse = this.buttonuse;
2808         store.buttonchat = this.buttonchat;
2809
2810         store.cursor_active = this.cursor_active;
2811         store.cursor_screen = this.cursor_screen;
2812         store.cursor_trace_start = this.cursor_trace_start;
2813         store.cursor_trace_endpos = this.cursor_trace_endpos;
2814         store.cursor_trace_ent = this.cursor_trace_ent;
2815
2816         store.ping = this.ping;
2817         store.ping_packetloss = this.ping_packetloss;
2818         store.ping_movementloss = this.ping_movementloss;
2819
2820         store.v_angle = this.v_angle;
2821         store.movement = this.movement;
2822 }