qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (CS(e).race_completed)       sf |= 1; // forced scoreboard
 114         if (CS(to).spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (CS(e).zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 void SetSpectatee(entity this, entity spectatee);
 158 void SetSpectatee_status(entity this, int spectatee_num);
 159
 160
 161 /*
 162 =============
 163 CheckPlayerModel
 164
 165 Checks if the argument string can be a valid playermodel.
 166 Returns a valid one in doubt.
 167 =============
 168 */
 169 string FallbackPlayerModel;
 170 string CheckPlayerModel(string plyermodel) {
 171         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 172         {
 173                 // note: we cannot summon Don Strunzone here, some player may
 174                 // still have the model string set. In case anyone manages how
 175                 // to change a cvar default, we'll have a small leak here.
 176                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 177         }
 178         // only in right path
 179         if( substring(plyermodel,0,14) != "models/player/")
 180                 return FallbackPlayerModel;
 181         // only good file extensions
 182         if(substring(plyermodel,-4,4) != ".zym")
 183         if(substring(plyermodel,-4,4) != ".dpm")
 184         if(substring(plyermodel,-4,4) != ".iqm")
 185         if(substring(plyermodel,-4,4) != ".md3")
 186         if(substring(plyermodel,-4,4) != ".psk")
 187                 return FallbackPlayerModel;
 188         // forbid the LOD models
 189         if(substring(plyermodel, -9,5) == "_lod1")
 190                 return FallbackPlayerModel;
 191         if(substring(plyermodel, -9,5) == "_lod2")
 192                 return FallbackPlayerModel;
 193         if(plyermodel != strtolower(plyermodel))
 194                 return FallbackPlayerModel;
 195         // also, restrict to server models
 196         if(autocvar_sv_servermodelsonly)
 197         {
 198                 if(!fexists(plyermodel))
 199                         return FallbackPlayerModel;
 200         }
 201         return plyermodel;
 202 }
 203
 204 void setplayermodel(entity e, string modelname)
 205 {
 206         precache_model(modelname);
 207         _setmodel(e, modelname);
 208         player_setupanimsformodel(e);
 209         if(!autocvar_g_debug_globalsounds)
 210                 UpdatePlayerSounds(e);
 211 }
 212
 213 void FixPlayermodel(entity player);
 214 /** putting a client as observer in the server */
 215 void PutObserverInServer(entity this)
 216 {
 217     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 218         PlayerState_detach(this);
 219
 220         if (IS_PLAYER(this) && this.health >= 1) {
 221         // despawn effect
 222                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 223     }
 224
 225     {
 226         entity spot = SelectSpawnPoint(this, true);
 227         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 228         this.angles = vec2(spot.angles);
 229         this.fixangle = true;
 230         // offset it so that the spectator spawns higher off the ground, looks better this way
 231         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 232         if (IS_REAL_CLIENT(this))
 233         {
 234             msg_entity = this;
 235             WriteByte(MSG_ONE, SVC_SETVIEW);
 236             WriteEntity(MSG_ONE, this);
 237         }
 238         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 239         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 240         if(!autocvar_g_debug_globalsounds)
 241         {
 242                 // needed for player sounds
 243                 this.model = "";
 244                 FixPlayermodel(this);
 245         }
 246         setmodel(this, MDL_Null);
 247         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 248         this.view_ofs = '0 0 0';
 249     }
 250
 251     RemoveGrapplingHooks(this);
 252         Portal_ClearAll(this);
 253         Unfreeze(this);
 254         SetSpectatee(this, NULL);
 255
 256         if (this.alivetime)
 257         {
 258                 if (!warmup_stage)
 259                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 260                 this.alivetime = 0;
 261         }
 262
 263         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 264
 265         WaypointSprite_PlayerDead(this);
 266
 267         if (mutator_returnvalue) {
 268             // mutator prevents resetting teams+score
 269         } else {
 270                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 271         this.frags = FRAGS_SPECTATOR;
 272         PlayerScore_Clear(this);  // clear scores when needed
 273     }
 274
 275         if (CS(this).killcount != FRAGS_SPECTATOR)
 276         {
 277                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 278                 if(!game_stopped)
 279                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 280                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 281
 282                 if(!CS(this).just_joined)
 283                         LogTeamchange(this.playerid, -1, 4);
 284                 else
 285                         CS(this).just_joined = false;
 286         }
 287
 288         accuracy_resend(this);
 289
 290         CS(this).spectatortime = time;
 291         if(this.bot_attack)
 292                 IL_REMOVE(g_bot_targets, this);
 293         this.bot_attack = false;
 294     this.hud = HUD_NORMAL;
 295         TRANSMUTE(Observer, this);
 296         this.iscreature = false;
 297         this.teleportable = TELEPORT_SIMPLE;
 298         if(this.damagedbycontents)
 299                 IL_REMOVE(g_damagedbycontents, this);
 300         this.damagedbycontents = false;
 301         this.health = FRAGS_SPECTATOR;
 302         SetSpectatee_status(this, etof(this));
 303         this.takedamage = DAMAGE_NO;
 304         this.solid = SOLID_NOT;
 305         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 306         this.flags = FL_CLIENT | FL_NOTARGET;
 307         this.armorvalue = 666;
 308         this.effects = 0;
 309         this.armorvalue = autocvar_g_balance_armor_start;
 310         this.pauserotarmor_finished = 0;
 311         this.pauserothealth_finished = 0;
 312         this.pauseregen_finished = 0;
 313         this.damageforcescale = 0;
 314         this.death_time = 0;
 315         this.respawn_flags = 0;
 316         this.respawn_time = 0;
 317         this.stat_respawn_time = 0;
 318         this.alpha = 0;
 319         this.scale = 0;
 320         this.fade_time = 0;
 321         this.pain_frame = 0;
 322         this.pain_finished = 0;
 323         this.strength_finished = 0;
 324         this.invincible_finished = 0;
 325         this.superweapons_finished = 0;
 326         this.pushltime = 0;
 327         this.istypefrag = 0;
 328         setthink(this, func_null);
 329         this.nextthink = 0;
 330         this.deadflag = DEAD_NO;
 331         this.crouch = false;
 332         this.revive_progress = 0;
 333         this.revival_time = 0;
 334
 335         this.items = 0;
 336         this.weapons = '0 0 0';
 337         PS(this).dual_weapons = '0 0 0';
 338         this.drawonlytoclient = this;
 339
 340         this.weaponmodel = "";
 341         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 342         {
 343                 this.weaponentities[slot] = NULL;
 344         }
 345         this.exteriorweaponentity = NULL;
 346         CS(this).killcount = FRAGS_SPECTATOR;
 347         this.velocity = '0 0 0';
 348         this.avelocity = '0 0 0';
 349         this.punchangle = '0 0 0';
 350         this.punchvector = '0 0 0';
 351         this.oldvelocity = this.velocity;
 352         this.fire_endtime = -1;
 353         this.event_damage = func_null;
 354
 355         for(int slot = 0; slot < MAX_AXH; ++slot)
 356         {
 357                 entity axh = this.(AuxiliaryXhair[slot]);
 358                 this.(AuxiliaryXhair[slot]) = NULL;
 359
 360                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 361                         delete(axh);
 362         }
 363 }
 364
 365 int player_getspecies(entity this)
 366 {
 367         get_model_parameters(this.model, this.skin);
 368         int s = get_model_parameters_species;
 369         get_model_parameters(string_null, 0);
 370         if (s < 0) return SPECIES_HUMAN;
 371         return s;
 372 }
 373
 374 .float model_randomizer;
 375 void FixPlayermodel(entity player)
 376 {
 377         string defaultmodel = "";
 378         int defaultskin = 0;
 379         if(autocvar_sv_defaultcharacter)
 380         {
 381                 if(teamplay)
 382                 {
 383                         switch(player.team)
 384                         {
 385                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 386                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 387                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 388                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 389                         }
 390                 }
 391
 392                 if(defaultmodel == "")
 393                 {
 394                         defaultmodel = autocvar_sv_defaultplayermodel;
 395                         defaultskin = autocvar_sv_defaultplayerskin;
 396                 }
 397
 398                 int n = tokenize_console(defaultmodel);
 399                 if(n > 0)
 400                 {
 401                         defaultmodel = argv(floor(n * player.model_randomizer));
 402                         // However, do NOT randomize if the player-selected model is in the list.
 403                         for (int i = 0; i < n; ++i)
 404                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 405                                         defaultmodel = argv(i);
 406                 }
 407
 408                 int i = strstrofs(defaultmodel, ":", 0);
 409                 if(i >= 0)
 410                 {
 411                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 412                         defaultmodel = substring(defaultmodel, 0, i);
 413                 }
 414         }
 415         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(!defaultskin)
 429                         defaultskin = autocvar_sv_defaultplayerskin;
 430         }
 431
 432         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 433         defaultmodel = M_ARGV(0, string);
 434         defaultskin = M_ARGV(1, int);
 435
 436         bool chmdl = false;
 437         int oldskin;
 438         if(defaultmodel != "")
 439         {
 440                 if (defaultmodel != player.model)
 441                 {
 442                         vector m1 = player.mins;
 443                         vector m2 = player.maxs;
 444                         setplayermodel (player, defaultmodel);
 445                         setsize (player, m1, m2);
 446                         chmdl = true;
 447                 }
 448
 449                 oldskin = player.skin;
 450                 player.skin = defaultskin;
 451         } else {
 452                 if (player.playermodel != player.model || player.playermodel == "")
 453                 {
 454                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 455                         vector m1 = player.mins;
 456                         vector m2 = player.maxs;
 457                         setplayermodel (player, player.playermodel);
 458                         setsize (player, m1, m2);
 459                         chmdl = true;
 460                 }
 461
 462                 if(!autocvar_sv_defaultcharacterskin)
 463                 {
 464                         oldskin = player.skin;
 465                         player.skin = stof(player.playerskin);
 466                 }
 467                 else
 468                 {
 469                         oldskin = player.skin;
 470                         player.skin = defaultskin;
 471                 }
 472         }
 473
 474         if(chmdl || oldskin != player.skin) // model or skin has changed
 475         {
 476                 player.species = player_getspecies(player); // update species
 477                 if(!autocvar_g_debug_globalsounds)
 478                         UpdatePlayerSounds(player); // update skin sounds
 479         }
 480
 481         if(!teamplay)
 482                 if(strlen(autocvar_sv_defaultplayercolors))
 483                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 484                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 485 }
 486
 487 void PutPlayerInServer(entity this)
 488 {
 489         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 490
 491         PlayerState_attach(this);
 492         accuracy_resend(this);
 493
 494         if (this.team < 0)
 495                 JoinBestTeam(this, false, true);
 496
 497         entity spot = SelectSpawnPoint(this, false);
 498         if (!spot) {
 499                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 500                 return; // spawn failed
 501         }
 502
 503         TRANSMUTE(Player, this);
 504
 505         this.wasplayer = true;
 506         this.iscreature = true;
 507         this.teleportable = TELEPORT_NORMAL;
 508         if(!this.damagedbycontents)
 509                 IL_PUSH(g_damagedbycontents, this);
 510         this.damagedbycontents = true;
 511         set_movetype(this, MOVETYPE_WALK);
 512         this.solid = SOLID_SLIDEBOX;
 513         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 514         if (autocvar_g_playerclip_collisions)
 515                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 516         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 517                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 518         this.frags = FRAGS_PLAYER;
 519         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 520         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 521         if (autocvar__notarget)
 522                 this.flags |= FL_NOTARGET;
 523         this.takedamage = DAMAGE_AIM;
 524         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 525         this.dmg = 2; // WTF
 526
 527         if (warmup_stage) {
 528                 this.ammo_shells = warmup_start_ammo_shells;
 529                 this.ammo_nails = warmup_start_ammo_nails;
 530                 this.ammo_rockets = warmup_start_ammo_rockets;
 531                 this.ammo_cells = warmup_start_ammo_cells;
 532                 this.ammo_plasma = warmup_start_ammo_plasma;
 533                 this.ammo_fuel = warmup_start_ammo_fuel;
 534                 this.health = warmup_start_health;
 535                 this.armorvalue = warmup_start_armorvalue;
 536                 this.weapons = WARMUP_START_WEAPONS;
 537         } else {
 538                 this.ammo_shells = start_ammo_shells;
 539                 this.ammo_nails = start_ammo_nails;
 540                 this.ammo_rockets = start_ammo_rockets;
 541                 this.ammo_cells = start_ammo_cells;
 542                 this.ammo_plasma = start_ammo_plasma;
 543                 this.ammo_fuel = start_ammo_fuel;
 544                 this.health = start_health;
 545                 this.armorvalue = start_armorvalue;
 546                 this.weapons = start_weapons;
 547         }
 548         SetSpectatee_status(this, 0);
 549
 550         PS(this).dual_weapons = '0 0 0';
 551
 552         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 553
 554         this.items = start_items;
 555
 556         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 557         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 558         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 559         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 560         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 561         // extend the pause of rotting if client was reset at the beginning of the countdown
 562         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 563                 float f = game_starttime - time;
 564                 this.spawnshieldtime += f;
 565                 this.pauserotarmor_finished += f;
 566                 this.pauserothealth_finished += f;
 567                 this.pauseregen_finished += f;
 568         }
 569         this.damageforcescale = 2;
 570         this.death_time = 0;
 571         this.respawn_flags = 0;
 572         this.respawn_time = 0;
 573         this.stat_respawn_time = 0;
 574         this.scale = autocvar_sv_player_scale;
 575         this.fade_time = 0;
 576         this.pain_frame = 0;
 577         this.pain_finished = 0;
 578         this.pushltime = 0;
 579         setthink(this, func_null); // players have no think function
 580         this.nextthink = 0;
 581         this.dmg_team = 0;
 582         this.ballistics_density = autocvar_g_ballistics_density_player;
 583
 584         this.deadflag = DEAD_NO;
 585
 586         this.angles = spot.angles;
 587         this.angles_z = 0; // never spawn tilted even if the spot says to
 588         if (IS_BOT_CLIENT(this))
 589                 this.v_angle = this.angles;
 590         this.fixangle = true; // turn this way immediately
 591         this.oldvelocity = this.velocity = '0 0 0';
 592         this.avelocity = '0 0 0';
 593         this.punchangle = '0 0 0';
 594         this.punchvector = '0 0 0';
 595
 596         this.strength_finished = 0;
 597         this.invincible_finished = 0;
 598         this.fire_endtime = -1;
 599         this.revive_progress = 0;
 600         this.revival_time = 0;
 601         this.air_finished = time + 12;
 602
 603         entity spawnevent = new_pure(spawnevent);
 604         spawnevent.owner = this;
 605         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 606
 607         // Cut off any still running player sounds.
 608         stopsound(this, CH_PLAYER_SINGLE);
 609
 610         this.model = "";
 611         FixPlayermodel(this);
 612         this.drawonlytoclient = NULL;
 613
 614         this.viewloc = NULL;
 615
 616         this.crouch = false;
 617         this.view_ofs = STAT(PL_VIEW_OFS, this);
 618         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 619         this.spawnorigin = spot.origin;
 620         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 621         // don't reset back to last position, even if new position is stuck in solid
 622         this.oldorigin = this.origin;
 623         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 624         if(this.conveyor)
 625                 IL_REMOVE(g_conveyed, this);
 626         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 627         this.hud = HUD_NORMAL;
 628
 629         this.event_damage = PlayerDamage;
 630
 631         if(!this.bot_attack)
 632                 IL_PUSH(g_bot_targets, this);
 633         this.bot_attack = true;
 634         if(!this.monster_attack)
 635                 IL_PUSH(g_monster_targets, this);
 636         this.monster_attack = true;
 637         navigation_dynamicgoal_init(this, false);
 638
 639         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 640
 641         if (CS(this).killcount == FRAGS_SPECTATOR) {
 642                 PlayerScore_Clear(this);
 643                 CS(this).killcount = 0;
 644         }
 645
 646         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 647         {
 648                 .entity weaponentity = weaponentities[slot];
 649                 entity oldwep = this.(weaponentity);
 650                 CL_SpawnWeaponentity(this, weaponentity);
 651                 if(oldwep && oldwep.owner == this)
 652                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 653         }
 654         this.alpha = default_player_alpha;
 655         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 656         this.exteriorweaponentity.alpha = default_weapon_alpha;
 657
 658         this.speedrunning = false;
 659
 660         target_voicescript_clear(this);
 661
 662         // reset fields the weapons may use
 663         FOREACH(Weapons, true, LAMBDA(
 664                 it.wr_resetplayer(it, this);
 665                         // reload all reloadable weapons
 666                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 667                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 668                         {
 669                                 .entity weaponentity = weaponentities[slot];
 670                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 671                         }
 672                 }
 673         ));
 674
 675         {
 676                 string s = spot.target;
 677                 spot.target = string_null;
 678                 SUB_UseTargets(spot, this, NULL);
 679                 spot.target = s;
 680         }
 681
 682         Unfreeze(this);
 683
 684         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 685
 686         if (autocvar_spawn_debug)
 687         {
 688                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 689                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 690         }
 691
 692         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 693         {
 694                 .entity weaponentity = weaponentities[slot];
 695                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 696                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 697                 else
 698                         this.(weaponentity).m_switchweapon = WEP_Null;
 699                 this.(weaponentity).m_weapon = WEP_Null;
 700                 this.(weaponentity).weaponname = "";
 701                 this.(weaponentity).m_switchingweapon = WEP_Null;
 702                 this.(weaponentity).cnt = -1;
 703         }
 704
 705         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 706
 707         if (!warmup_stage && !this.alivetime)
 708                 this.alivetime = time;
 709
 710         antilag_clear(this, CS(this));
 711 }
 712
 713 /** Called when a client spawns in the server */
 714 void PutClientInServer(entity this)
 715 {
 716         if (IS_BOT_CLIENT(this)) {
 717                 TRANSMUTE(Player, this);
 718         } else if (IS_REAL_CLIENT(this)) {
 719                 msg_entity = this;
 720                 WriteByte(MSG_ONE, SVC_SETVIEW);
 721                 WriteEntity(MSG_ONE, this);
 722         }
 723         if (game_stopped)
 724                 TRANSMUTE(Observer, this);
 725
 726         SetSpectatee(this, NULL);
 727
 728         // reset player keys
 729         this.itemkeys = 0;
 730
 731         MUTATOR_CALLHOOK(PutClientInServer, this);
 732
 733         if (IS_OBSERVER(this)) {
 734                 PutObserverInServer(this);
 735         } else if (IS_PLAYER(this)) {
 736                 PutPlayerInServer(this);
 737         }
 738 }
 739
 740 void ClientInit_misc(entity this);
 741
 742 // TODO do we need all these fields, or should we stop autodetecting runtime
 743 // changes and just have a console command to update this?
 744 bool ClientInit_SendEntity(entity this, entity to, int sf)
 745 {
 746         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 747         return = true;
 748         msg_entity = to;
 749         // MSG_INIT replacement
 750         // TODO: make easier to use
 751         Registry_send_all();
 752         W_PROP_reload(MSG_ONE, to);
 753         ClientInit_misc(this);
 754         MUTATOR_CALLHOOK(Ent_Init);
 755 }
 756 void ClientInit_misc(entity this)
 757 {
 758         int channel = MSG_ONE;
 759         WriteHeader(channel, ENT_CLIENT_INIT);
 760         WriteByte(channel, g_nexball_meter_period * 32);
 761         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 765         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 769
 770         if(sv_foginterval && world.fog != "")
 771                 WriteString(channel, world.fog);
 772         else
 773                 WriteString(channel, "");
 774         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 775         WriteByte(channel, serverflags);
 776         WriteCoord(channel, autocvar_g_trueaim_minrange);
 777 }
 778
 779 void ClientInit_CheckUpdate(entity this)
 780 {
 781         this.nextthink = time;
 782         if(this.count != autocvar_g_balance_armor_blockpercent)
 783         {
 784                 this.count = autocvar_g_balance_armor_blockpercent;
 785                 this.SendFlags |= 1;
 786         }
 787 }
 788
 789 void ClientInit_Spawn()
 790 {
 791         entity e = new_pure(clientinit);
 792         setthink(e, ClientInit_CheckUpdate);
 793         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 794
 795         ClientInit_CheckUpdate(e);
 796 }
 797
 798 /*
 799 =============
 800 SetNewParms
 801 =============
 802 */
 803 void SetNewParms ()
 804 {
 805         // initialize parms for a new player
 806         parm1 = -(86400 * 366);
 807
 808         MUTATOR_CALLHOOK(SetNewParms);
 809 }
 810
 811 /*
 812 =============
 813 SetChangeParms
 814 =============
 815 */
 816 void SetChangeParms (entity this)
 817 {
 818         // save parms for level change
 819         parm1 = CS(this).parm_idlesince - time;
 820
 821         MUTATOR_CALLHOOK(SetChangeParms);
 822 }
 823
 824 /*
 825 =============
 826 DecodeLevelParms
 827 =============
 828 */
 829 void DecodeLevelParms(entity this)
 830 {
 831         // load parms
 832         CS(this).parm_idlesince = parm1;
 833         if (CS(this).parm_idlesince == -(86400 * 366))
 834                 CS(this).parm_idlesince = time;
 835
 836         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 837         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 838
 839         MUTATOR_CALLHOOK(DecodeLevelParms);
 840 }
 841
 842 /*
 843 =============
 844 ClientKill
 845
 846 Called when a client types 'kill' in the console
 847 =============
 848 */
 849
 850 .float clientkill_nexttime;
 851 void ClientKill_Now_TeamChange(entity this)
 852 {
 853         if(CS(this).killindicator_teamchange == -1)
 854         {
 855                 JoinBestTeam( this, false, true );
 856         }
 857         else if(CS(this).killindicator_teamchange == -2)
 858         {
 859                 if(blockSpectators)
 860                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 861                 PutObserverInServer(this);
 862         }
 863         else
 864                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 865         CS(this).killindicator_teamchange = 0;
 866 }
 867
 868 void ClientKill_Now(entity this)
 869 {
 870         if(this.vehicle)
 871         {
 872             vehicles_exit(this.vehicle, VHEF_RELEASE);
 873             if(!CS(this).killindicator_teamchange)
 874             {
 875             this.vehicle_health = -1;
 876             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 877             }
 878         }
 879
 880         if(this.killindicator && !wasfreed(this.killindicator))
 881                 delete(this.killindicator);
 882
 883         this.killindicator = NULL;
 884
 885         if(CS(this).killindicator_teamchange)
 886                 ClientKill_Now_TeamChange(this);
 887
 888         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 889                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 890
 891         // now I am sure the player IS dead
 892 }
 893 void KillIndicator_Think(entity this)
 894 {
 895         if (game_stopped)
 896         {
 897                 this.owner.killindicator = NULL;
 898                 delete(this);
 899                 return;
 900         }
 901
 902         if (this.owner.alpha < 0 && !this.owner.vehicle)
 903         {
 904                 this.owner.killindicator = NULL;
 905                 delete(this);
 906                 return;
 907         }
 908
 909         if(this.cnt <= 0)
 910         {
 911                 ClientKill_Now(this.owner);
 912                 return;
 913         }
 914     else if(this.health == 1) // health == 1 means that it's silent
 915     {
 916         this.nextthink = time + 1;
 917         this.cnt -= 1;
 918     }
 919         else
 920         {
 921                 if(this.cnt <= 10)
 922                         setmodel(this, MDL_NUM(this.cnt));
 923                 if(IS_REAL_CLIENT(this.owner))
 924                 {
 925                         if(this.cnt <= 10)
 926                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 927                 }
 928                 this.nextthink = time + 1;
 929                 this.cnt -= 1;
 930         }
 931 }
 932
 933 float clientkilltime;
 934 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 935 {
 936         float killtime;
 937         float starttime;
 938
 939         if (game_stopped)
 940                 return;
 941
 942         killtime = autocvar_g_balance_kill_delay;
 943
 944     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 945         return;
 946     killtime = M_ARGV(1, float);
 947
 948         CS(this).killindicator_teamchange = targetteam;
 949
 950     if(!this.killindicator)
 951         {
 952                 if(!IS_DEAD(this))
 953                 {
 954                         killtime = max(killtime, this.clientkill_nexttime - time);
 955                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 956                 }
 957
 958                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 959                 {
 960                         ClientKill_Now(this);
 961                 }
 962                 else
 963                 {
 964                         starttime = max(time, clientkilltime);
 965
 966                         this.killindicator = spawn();
 967                         this.killindicator.owner = this;
 968                         this.killindicator.scale = 0.5;
 969                         setattachment(this.killindicator, this, "");
 970                         setorigin(this.killindicator, '0 0 52');
 971                         setthink(this.killindicator, KillIndicator_Think);
 972                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 973                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 974                         this.killindicator.cnt = ceil(killtime);
 975                         this.killindicator.count = bound(0, ceil(killtime), 10);
 976                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 977
 978                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 979                         {
 980                                 it.killindicator = spawn();
 981                                 it.killindicator.owner = it;
 982                                 it.killindicator.scale = 0.5;
 983                                 setattachment(it.killindicator, it, "");
 984                                 setorigin(it.killindicator, '0 0 52');
 985                                 setthink(it.killindicator, KillIndicator_Think);
 986                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 987                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 988                                 it.killindicator.cnt = ceil(killtime);
 989                         });
 990                         this.lip = 0;
 991                 }
 992         }
 993         if(this.killindicator)
 994         {
 995                 if(targetteam == 0) // just die
 996                 {
 997                         this.killindicator.colormod = '0 0 0';
 998                         if(IS_REAL_CLIENT(this))
 999                         if(this.killindicator.cnt > 0)
1000                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1001                 }
1002                 else if(targetteam == -1) // auto
1003                 {
1004                         this.killindicator.colormod = '0 1 0';
1005                         if(IS_REAL_CLIENT(this))
1006                         if(this.killindicator.cnt > 0)
1007                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1008                 }
1009                 else if(targetteam == -2) // spectate
1010                 {
1011                         this.killindicator.colormod = '0.5 0.5 0.5';
1012                         if(IS_REAL_CLIENT(this))
1013                         if(this.killindicator.cnt > 0)
1014                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1015                 }
1016                 else
1017                 {
1018                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1019                         if(IS_REAL_CLIENT(this))
1020                         if(this.killindicator.cnt > 0)
1021                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1022                 }
1023         }
1024
1025 }
1026
1027 void ClientKill (entity this)
1028 {
1029         if(game_stopped) return;
1030         if(this.player_blocked) return;
1031         if(STAT(FROZEN, this)) return;
1032
1033         ClientKill_TeamChange(this, 0);
1034 }
1035
1036 void FixClientCvars(entity e)
1037 {
1038         // send prediction settings to the client
1039         stuffcmd(e, "\nin_bindmap 0 0\n");
1040         if(autocvar_g_antilag == 3) // client side hitscan
1041                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1042         if(autocvar_sv_gentle)
1043                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1044
1045         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1046         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1047
1048         MUTATOR_CALLHOOK(FixClientCvars, e);
1049 }
1050
1051 bool findinlist_abbrev(string tofind, string list)
1052 {
1053         if(list == "" || tofind == "")
1054                 return false; // empty list or search, just return
1055
1056         // this function allows abbreviated strings!
1057         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1058         {
1059                 return true;
1060         });
1061
1062         return false;
1063 }
1064
1065 bool PlayerInIPList(entity p, string iplist)
1066 {
1067         // some safety checks (never allow local?)
1068         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1069                 return false;
1070
1071         return findinlist_abbrev(p.netaddress, iplist);
1072 }
1073
1074 bool PlayerInIDList(entity p, string idlist)
1075 {
1076         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1077         if(!p.crypto_idfp)
1078                 return false;
1079
1080         return findinlist_abbrev(p.crypto_idfp, idlist);
1081 }
1082
1083 bool PlayerInList(entity player, string list)
1084 {
1085         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1086 }
1087
1088 #ifdef DP_EXT_PRECONNECT
1089 /*
1090 =============
1091 ClientPreConnect
1092
1093 Called once (not at each match start) when a client begins a connection to the server
1094 =============
1095 */
1096 void ClientPreConnect(entity this)
1097 {
1098         if(autocvar_sv_eventlog)
1099         {
1100                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1101                         this.playerid,
1102                         etof(this),
1103                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1104                 ));
1105         }
1106 }
1107 #endif
1108
1109 /**
1110 =============
1111 ClientConnect
1112
1113 Called when a client connects to the server
1114 =============
1115 */
1116 void ClientConnect(entity this)
1117 {
1118         if (Ban_MaybeEnforceBanOnce(this)) return;
1119         assert(!IS_CLIENT(this), return);
1120         this.flags |= FL_CLIENT;
1121         assert(player_count >= 0, player_count = 0);
1122
1123 #ifdef WATERMARK
1124         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1125 #endif
1126         TRANSMUTE(Client, this);
1127         CS(this).version_nagtime = time + 10 + random() * 10;
1128
1129         // identify the right forced team
1130         if (autocvar_g_campaign)
1131         {
1132                 if (IS_REAL_CLIENT(this)) // only players, not bots
1133                 {
1134                         switch (autocvar_g_campaign_forceteam)
1135                         {
1136                                 case 1: this.team_forced = NUM_TEAM_1; break;
1137                                 case 2: this.team_forced = NUM_TEAM_2; break;
1138                                 case 3: this.team_forced = NUM_TEAM_3; break;
1139                                 case 4: this.team_forced = NUM_TEAM_4; break;
1140                                 default: this.team_forced = 0;
1141                         }
1142                 }
1143         }
1144         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1145         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1146         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1147         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1148         else switch (autocvar_g_forced_team_otherwise)
1149         {
1150                 default: this.team_forced = 0; break;
1151                 case "red": this.team_forced = NUM_TEAM_1; break;
1152                 case "blue": this.team_forced = NUM_TEAM_2; break;
1153                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1154                 case "pink": this.team_forced = NUM_TEAM_4; break;
1155                 case "spectate":
1156                 case "spectator":
1157                         this.team_forced = -1;
1158                         break;
1159         }
1160         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1161
1162     {
1163         int id = this.playerid;
1164         this.playerid = 0; // silent
1165             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1166             this.playerid = id;
1167     }
1168
1169         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1170                 TRANSMUTE(Observer, this);
1171         } else {
1172                 if (!teamplay || autocvar_g_balance_teams) {
1173                         TRANSMUTE(Player, this);
1174                         campaign_bots_may_start = true;
1175                 } else {
1176                         TRANSMUTE(Observer, this); // do it anyway
1177                 }
1178         }
1179
1180         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1181
1182         // always track bots, don't ask for cl_allow_uidtracking
1183     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1184
1185         if (autocvar_sv_eventlog)
1186                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1187
1188         LogTeamchange(this.playerid, this.team, 1);
1189
1190         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1191
1192         CS(this).netname_previous = strzone(this.netname);
1193
1194         if(teamplay && IS_PLAYER(this))
1195                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1196         else
1197                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1198
1199         stuffcmd(this, clientstuff, "\n");
1200         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1201
1202         FixClientCvars(this);
1203
1204         // get version info from player
1205         stuffcmd(this, "cmd clientversion $gameversion\n");
1206
1207         // notify about available teams
1208         if (teamplay)
1209         {
1210                 CheckAllowedTeams(this);
1211                 int t = 0;
1212                 if (c1 >= 0) t |= BIT(0);
1213                 if (c2 >= 0) t |= BIT(1);
1214                 if (c3 >= 0) t |= BIT(2);
1215                 if (c4 >= 0) t |= BIT(3);
1216                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1217         }
1218         else
1219         {
1220                 stuffcmd(this, "set _teams_available 0\n");
1221         }
1222
1223         bot_relinkplayerlist();
1224
1225         CS(this).spectatortime = time;
1226         if (blockSpectators)
1227         {
1228                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1229         }
1230
1231         CS(this).jointime = time;
1232         CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1233
1234         if (IS_REAL_CLIENT(this))
1235         {
1236                 if (g_weaponarena_weapons == WEPSET(TUBA))
1237                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1238         }
1239
1240         if (!sv_foginterval && world.fog != "")
1241                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1242
1243         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1244                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1245                         send_CSQC_teamnagger();
1246
1247         CSQCMODEL_AUTOINIT(this);
1248
1249         this.model_randomizer = random();
1250
1251         if (IS_REAL_CLIENT(this))
1252                 sv_notice_join(this);
1253
1254         // update physics stats (players can spawn before physics runs)
1255         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1256         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1257         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1258
1259         IL_EACH(g_initforplayer, it.init_for_player, {
1260                 it.init_for_player(it, this);
1261         });
1262
1263         MUTATOR_CALLHOOK(ClientConnect, this);
1264
1265         if (IS_REAL_CLIENT(this))
1266         {
1267                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1268                 {
1269                         CS(this).motd_actived_time = -1;
1270                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1271                 }
1272         }
1273 }
1274 /*
1275 =============
1276 ClientDisconnect
1277
1278 Called when a client disconnects from the server
1279 =============
1280 */
1281 .entity chatbubbleentity;
1282 void ReadyCount();
1283 void ClientDisconnect(entity this)
1284 {
1285         assert(IS_CLIENT(this), return);
1286
1287         PlayerStats_GameReport_FinalizePlayer(this);
1288         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1289         if (CS(this).active_minigame) part_minigame(this);
1290         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1291
1292         if (autocvar_sv_eventlog)
1293                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1294
1295         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1296
1297         if(IS_SPEC(this))
1298                 SetSpectatee(this, NULL);
1299
1300     MUTATOR_CALLHOOK(ClientDisconnect, this);
1301
1302         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1303         ClientState_detach(this);
1304
1305         Portal_ClearAll(this);
1306
1307         Unfreeze(this);
1308
1309         RemoveGrapplingHooks(this);
1310
1311         // Here, everything has been done that requires this player to be a client.
1312
1313         this.flags &= ~FL_CLIENT;
1314
1315         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1316         if (this.killindicator) delete(this.killindicator);
1317
1318         WaypointSprite_PlayerGone(this);
1319
1320         bot_relinkplayerlist();
1321
1322         if (this.clientstatus) strunzone(this.clientstatus);
1323         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1324         if (this.personal) delete(this.personal);
1325
1326         this.playerid = 0;
1327         ReadyCount();
1328         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1329
1330         ONREMOVE(this);
1331 }
1332
1333 void ChatBubbleThink(entity this)
1334 {
1335         this.nextthink = time;
1336         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1337         {
1338                 if(this.owner) // but why can that ever be NULL?
1339                         this.owner.chatbubbleentity = NULL;
1340                 delete(this);
1341                 return;
1342         }
1343
1344         this.mdl = "";
1345
1346         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1347         {
1348                 if ( CS(this.owner).active_minigame )
1349                         this.mdl = "models/sprites/minigame_busy.iqm";
1350                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1351                         this.mdl = "models/misc/chatbubble.spr";
1352         }
1353
1354         if ( this.model != this.mdl )
1355                 _setmodel(this, this.mdl);
1356
1357 }
1358
1359 void UpdateChatBubble(entity this)
1360 {
1361         if (this.alpha < 0)
1362                 return;
1363         // spawn a chatbubble entity if needed
1364         if (!this.chatbubbleentity)
1365         {
1366                 this.chatbubbleentity = new(chatbubbleentity);
1367                 this.chatbubbleentity.owner = this;
1368                 this.chatbubbleentity.exteriormodeltoclient = this;
1369                 setthink(this.chatbubbleentity, ChatBubbleThink);
1370                 this.chatbubbleentity.nextthink = time;
1371                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1372                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1373                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1374                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1375                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1376                 //this.chatbubbleentity.model = "";
1377                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1378         }
1379 }
1380
1381
1382 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1383 // added to the model skins
1384 /*void UpdateColorModHack()
1385 {
1386         float c;
1387         c = this.clientcolors & 15;
1388         // LordHavoc: only bothering to support white, green, red, yellow, blue
1389              if (!teamplay) this.colormod = '0 0 0';
1390         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1391         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1392         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1393         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1394         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1395         else this.colormod = '1 1 1';
1396 }*/
1397
1398 void respawn(entity this)
1399 {
1400         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1401         {
1402                 this.solid = SOLID_NOT;
1403                 this.takedamage = DAMAGE_NO;
1404                 set_movetype(this, MOVETYPE_FLY);
1405                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1406                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1407                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1408                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1409                 if(autocvar_g_respawn_ghosts_maxtime)
1410                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1411         }
1412
1413         CopyBody(this, 1);
1414
1415         this.effects |= EF_NODRAW; // prevent another CopyBody
1416         PutClientInServer(this);
1417 }
1418
1419 void play_countdown(entity this, float finished, Sound samp)
1420 {
1421     TC(Sound, samp);
1422         if(IS_REAL_CLIENT(this))
1423                 if(floor(finished - time - frametime) != floor(finished - time))
1424                         if(finished - time < 6)
1425                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1426 }
1427
1428 void player_powerups(entity this)
1429 {
1430         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1431         int items_prev = this.items;
1432
1433         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1434                 this.modelflags |= MF_ROCKET;
1435         else
1436                 this.modelflags &= ~MF_ROCKET;
1437
1438         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1439
1440         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1441                 return;
1442
1443         Fire_ApplyDamage(this);
1444         Fire_ApplyEffect(this);
1445
1446         if (!g_instagib)
1447         {
1448                 if (this.items & ITEM_Strength.m_itemid)
1449                 {
1450                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1451                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1452                         if (time > this.strength_finished)
1453                         {
1454                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1455                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1456                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1457                         }
1458                 }
1459                 else
1460                 {
1461                         if (time < this.strength_finished)
1462                         {
1463                                 this.items = this.items | ITEM_Strength.m_itemid;
1464                                 if(!g_cts)
1465                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1466                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1467                         }
1468                 }
1469                 if (this.items & ITEM_Shield.m_itemid)
1470                 {
1471                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1472                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1473                         if (time > this.invincible_finished)
1474                         {
1475                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1476                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1478                         }
1479                 }
1480                 else
1481                 {
1482                         if (time < this.invincible_finished)
1483                         {
1484                                 this.items = this.items | ITEM_Shield.m_itemid;
1485                                 if(!g_cts)
1486                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1487                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1488                         }
1489                 }
1490                 if (this.items & IT_SUPERWEAPON)
1491                 {
1492                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1493                         {
1494                                 this.superweapons_finished = 0;
1495                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1496                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1497                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1498                         }
1499                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1500                         {
1501                                 // don't let them run out
1502                         }
1503                         else
1504                         {
1505                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1506                                 if (time > this.superweapons_finished)
1507                                 {
1508                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1509                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1510                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1511                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1512                                 }
1513                         }
1514                 }
1515                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1516                 {
1517                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1518                         {
1519                                 this.items = this.items | IT_SUPERWEAPON;
1520                                 if(!g_cts)
1521                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1522                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1523                         }
1524                         else
1525                         {
1526                                 this.superweapons_finished = 0;
1527                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1528                         }
1529                 }
1530                 else
1531                 {
1532                         this.superweapons_finished = 0;
1533                 }
1534         }
1535
1536         if(autocvar_g_nodepthtestplayers)
1537                 this.effects = this.effects | EF_NODEPTHTEST;
1538
1539         if(autocvar_g_fullbrightplayers)
1540                 this.effects = this.effects | EF_FULLBRIGHT;
1541
1542         if (time >= game_starttime)
1543         if (time < this.spawnshieldtime)
1544                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1545
1546         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1547 }
1548
1549 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1550 {
1551         if(current > stable)
1552                 return current;
1553         else if(current > stable - 0.25) // when close enough, "snap"
1554                 return stable;
1555         else
1556                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1557 }
1558
1559 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1560 {
1561         if(current < stable)
1562                 return current;
1563         else if(current < stable + 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1567 }
1568
1569 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1570 {
1571         if(current > rotstable)
1572         {
1573                 if(rotframetime > 0)
1574                 {
1575                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1576                         current = max(rotstable, current - rotlinear * rotframetime);
1577                 }
1578         }
1579         else if(current < regenstable)
1580         {
1581                 if(regenframetime > 0)
1582                 {
1583                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1584                         current = min(regenstable, current + regenlinear * regenframetime);
1585                 }
1586         }
1587
1588         if(current > limit)
1589                 current = limit;
1590
1591         return current;
1592 }
1593
1594 void player_regen(entity this)
1595 {
1596         float max_mod, regen_mod, rot_mod, limit_mod;
1597         max_mod = regen_mod = rot_mod = limit_mod = 1;
1598
1599         float regen_health = autocvar_g_balance_health_regen;
1600         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1601         float regen_health_rot = autocvar_g_balance_health_rot;
1602         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1603         float regen_health_stable = autocvar_g_balance_health_regenstable;
1604         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1605         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1606                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1607         max_mod = M_ARGV(1, float);
1608         regen_mod = M_ARGV(2, float);
1609         rot_mod = M_ARGV(3, float);
1610         limit_mod = M_ARGV(4, float);
1611         regen_health = M_ARGV(5, float);
1612         regen_health_linear = M_ARGV(6, float);
1613         regen_health_rot = M_ARGV(7, float);
1614         regen_health_rotlinear = M_ARGV(8, float);
1615         regen_health_stable = M_ARGV(9, float);
1616         regen_health_rotstable = M_ARGV(10, float);
1617
1618
1619         if(!mutator_returnvalue)
1620         if(!STAT(FROZEN, this))
1621         {
1622                 float mina, maxa, limith, limita;
1623                 maxa = autocvar_g_balance_armor_rotstable;
1624                 mina = autocvar_g_balance_armor_regenstable;
1625                 limith = autocvar_g_balance_health_limit;
1626                 limita = autocvar_g_balance_armor_limit;
1627
1628                 regen_health_rotstable = regen_health_rotstable * max_mod;
1629                 regen_health_stable = regen_health_stable * max_mod;
1630                 limith = limith * limit_mod;
1631                 limita = limita * limit_mod;
1632
1633                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1634                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1635         }
1636
1637         // if player rotted to death...  die!
1638         // check this outside above checks, as player may still be able to rot to death
1639         if(this.health < 1)
1640         {
1641                 if(this.vehicle)
1642                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1643                 if(this.event_damage)
1644                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1645         }
1646
1647         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1648         {
1649                 float minf, maxf, limitf;
1650
1651                 maxf = autocvar_g_balance_fuel_rotstable;
1652                 minf = autocvar_g_balance_fuel_regenstable;
1653                 limitf = autocvar_g_balance_fuel_limit;
1654
1655                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1656         }
1657 }
1658
1659 bool zoomstate_set;
1660 void SetZoomState(entity this, float newzoom)
1661 {
1662         if(newzoom != CS(this).zoomstate)
1663         {
1664                 CS(this).zoomstate = newzoom;
1665                 ClientData_Touch(this);
1666         }
1667         zoomstate_set = true;
1668 }
1669
1670 void GetPressedKeys(entity this)
1671 {
1672         MUTATOR_CALLHOOK(GetPressedKeys, this);
1673         int keys = STAT(PRESSED_KEYS, this);
1674         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1675         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1676         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1677         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1678
1679         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1680         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1681         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1682         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1683         CS(this).pressedkeys = keys; // store for other users
1684
1685         STAT(PRESSED_KEYS, this) = keys;
1686 }
1687
1688 /*
1689 ======================
1690 spectate mode routines
1691 ======================
1692 */
1693
1694 void SpectateCopy(entity this, entity spectatee)
1695 {
1696     TC(Client, this); TC(Client, spectatee);
1697
1698         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1699         PS(this) = PS(spectatee);
1700         this.armortype = spectatee.armortype;
1701         this.armorvalue = spectatee.armorvalue;
1702         this.ammo_cells = spectatee.ammo_cells;
1703         this.ammo_plasma = spectatee.ammo_plasma;
1704         this.ammo_shells = spectatee.ammo_shells;
1705         this.ammo_nails = spectatee.ammo_nails;
1706         this.ammo_rockets = spectatee.ammo_rockets;
1707         this.ammo_fuel = spectatee.ammo_fuel;
1708         this.clip_load = spectatee.clip_load;
1709         this.clip_size = spectatee.clip_size;
1710         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1711         this.health = spectatee.health;
1712         CS(this).impulse = 0;
1713         this.items = spectatee.items;
1714         this.last_pickup = spectatee.last_pickup;
1715         this.hit_time = spectatee.hit_time;
1716         this.strength_finished = spectatee.strength_finished;
1717         this.invincible_finished = spectatee.invincible_finished;
1718         this.superweapons_finished = spectatee.superweapons_finished;
1719         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1720         this.weapons = spectatee.weapons;
1721         this.vortex_charge = spectatee.vortex_charge;
1722         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1723         this.hagar_load = spectatee.hagar_load;
1724         this.arc_heat_percent = spectatee.arc_heat_percent;
1725         this.minelayer_mines = spectatee.minelayer_mines;
1726         this.punchangle = spectatee.punchangle;
1727         this.view_ofs = spectatee.view_ofs;
1728         this.velocity = spectatee.velocity;
1729         this.dmg_take = spectatee.dmg_take;
1730         this.dmg_save = spectatee.dmg_save;
1731         this.dmg_inflictor = spectatee.dmg_inflictor;
1732         this.v_angle = spectatee.v_angle;
1733         this.angles = spectatee.v_angle;
1734         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1735         this.revive_progress = spectatee.revive_progress;
1736         this.viewloc = spectatee.viewloc;
1737         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1738                 this.fixangle = true;
1739         setorigin(this, spectatee.origin);
1740         setsize(this, spectatee.mins, spectatee.maxs);
1741         SetZoomState(this, CS(spectatee).zoomstate);
1742
1743         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1744         {
1745                 .entity weaponentity = weaponentities[slot];
1746                 this.(weaponentity) = spectatee.(weaponentity);
1747         }
1748
1749         for(int slot = 0; slot < MAX_AXH; ++slot)
1750         {
1751                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1752         }
1753
1754     anticheat_spectatecopy(this, spectatee);
1755         this.hud = spectatee.hud;
1756         if(spectatee.vehicle)
1757     {
1758         this.angles = spectatee.v_angle;
1759
1760         //this.fixangle = false;
1761         //this.velocity = spectatee.vehicle.velocity;
1762         this.vehicle_health = spectatee.vehicle_health;
1763         this.vehicle_shield = spectatee.vehicle_shield;
1764         this.vehicle_energy = spectatee.vehicle_energy;
1765         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1766         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1767         this.vehicle_reload1 = spectatee.vehicle_reload1;
1768         this.vehicle_reload2 = spectatee.vehicle_reload2;
1769
1770         //msg_entity = this;
1771
1772        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1773             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1774            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1775            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1776
1777         //WriteByte (MSG_ONE, SVC_SETVIEW);
1778         //    WriteEntity(MSG_ONE, this);
1779         //makevectors(spectatee.v_angle);
1780         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1781     }
1782 }
1783
1784 bool SpectateUpdate(entity this)
1785 {
1786         if(!this.enemy)
1787                 return false;
1788
1789         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1790         {
1791                 SetSpectatee(this, NULL);
1792                 return false;
1793         }
1794
1795         SpectateCopy(this, this.enemy);
1796
1797         return true;
1798 }
1799
1800 bool SpectateSet(entity this)
1801 {
1802         if(!IS_PLAYER(this.enemy))
1803                 return false;
1804
1805         ClientData_Touch(this.enemy);
1806
1807         msg_entity = this;
1808         WriteByte(MSG_ONE, SVC_SETVIEW);
1809         WriteEntity(MSG_ONE, this.enemy);
1810         set_movetype(this, MOVETYPE_NONE);
1811         accuracy_resend(this);
1812
1813         if(!SpectateUpdate(this))
1814                 PutObserverInServer(this);
1815
1816         return true;
1817 }
1818
1819 void SetSpectatee_status(entity this, int spectatee_num)
1820 {
1821         int oldspectatee_status = CS(this).spectatee_status;
1822         CS(this).spectatee_status = spectatee_num;
1823
1824         if (CS(this).spectatee_status != oldspectatee_status)
1825         {
1826                 ClientData_Touch(this);
1827                 if (g_race || g_cts) race_InitSpectator();
1828         }
1829 }
1830
1831 void SetSpectatee(entity this, entity spectatee)
1832 {
1833         if(IS_BOT_CLIENT(this))
1834                 return; // bots abuse .enemy, this code is useless to them
1835
1836         entity old_spectatee = this.enemy;
1837
1838         this.enemy = spectatee;
1839
1840         // WEAPONTODO
1841         // these are required to fix the spectator bug with arc
1842         if(old_spectatee)
1843         {
1844                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1845                 {
1846                         .entity weaponentity = weaponentities[slot];
1847                         if(old_spectatee.(weaponentity).arc_beam)
1848                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1849                 }
1850         }
1851         if(this.enemy)
1852         {
1853                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1854                 {
1855                         .entity weaponentity = weaponentities[slot];
1856                         if(this.enemy.(weaponentity).arc_beam)
1857                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1858                 }
1859         }
1860
1861         if (this.enemy)
1862                 SetSpectatee_status(this, etof(this.enemy));
1863
1864         // needed to update spectator list
1865         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1866 }
1867
1868 bool Spectate(entity this, entity pl)
1869 {
1870         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1871                 return false;
1872         pl = M_ARGV(1, entity);
1873
1874         SetSpectatee(this, pl);
1875         return SpectateSet(this);
1876 }
1877
1878 bool SpectateNext(entity this)
1879 {
1880         entity ent = find(this.enemy, classname, STR_PLAYER);
1881
1882         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1883                 ent = M_ARGV(1, entity);
1884         else if (!ent)
1885                 ent = find(ent, classname, STR_PLAYER);
1886
1887         if(ent) { SetSpectatee(this, ent); }
1888
1889         return SpectateSet(this);
1890 }
1891
1892 bool SpectatePrev(entity this)
1893 {
1894         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1895         entity ent = findchain(classname, STR_PLAYER);
1896         if (!ent) // no player
1897                 return false;
1898
1899         entity first = ent;
1900         // skip players until current spectated player
1901         if(this.enemy)
1902         while(ent && ent != this.enemy)
1903                 ent = ent.chain;
1904
1905         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1906         {
1907                 case MUT_SPECPREV_FOUND:
1908                     ent = M_ARGV(1, entity);
1909                     break;
1910                 case MUT_SPECPREV_RETURN:
1911                     return true;
1912                 case MUT_SPECPREV_CONTINUE:
1913                 default:
1914                 {
1915                         if(ent.chain)
1916                                 ent = ent.chain;
1917                         else
1918                                 ent = first;
1919                         break;
1920                 }
1921         }
1922
1923         SetSpectatee(this, ent);
1924         return SpectateSet(this);
1925 }
1926
1927 /*
1928 =============
1929 ShowRespawnCountdown()
1930
1931 Update a respawn countdown display.
1932 =============
1933 */
1934 void ShowRespawnCountdown(entity this)
1935 {
1936         float number;
1937         if(!IS_DEAD(this)) // just respawned?
1938                 return;
1939         else
1940         {
1941                 number = ceil(this.respawn_time - time);
1942                 if(number <= 0)
1943                         return;
1944                 if(number <= this.respawn_countdown)
1945                 {
1946                         this.respawn_countdown = number - 1;
1947                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1948                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1949                 }
1950         }
1951 }
1952
1953 .bool team_selected;
1954 bool ShowTeamSelection(entity this)
1955 {
1956         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1957                 return false;
1958         stuffcmd(this, "menu_showteamselect\n");
1959         return true;
1960 }
1961 void Join(entity this)
1962 {
1963         TRANSMUTE(Player, this);
1964
1965         if(!this.team_selected)
1966         if(autocvar_g_campaign || autocvar_g_balance_teams)
1967                 JoinBestTeam(this, false, true);
1968
1969         if(autocvar_g_campaign)
1970                 campaign_bots_may_start = true;
1971
1972         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1973
1974         PutClientInServer(this);
1975
1976         if(IS_PLAYER(this))
1977         if(teamplay && this.team != -1)
1978                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1979         else
1980                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1981         this.team_selected = false;
1982 }
1983
1984 /**
1985  * Determines whether the player is allowed to join. This depends on cvar
1986  * g_maxplayers, if it isn't used this function always return true, otherwise
1987  * it checks whether the number of currently playing players exceeds g_maxplayers.
1988  * @return int number of free slots for players, 0 if none
1989  */
1990 int nJoinAllowed(entity this, entity ignore)
1991 {
1992         if(!ignore)
1993         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1994         // so report 0 free slots if restricted
1995         {
1996                 if(autocvar_g_forced_team_otherwise == "spectate")
1997                         return 0;
1998                 if(autocvar_g_forced_team_otherwise == "spectator")
1999                         return 0;
2000         }
2001
2002         if(this && this.team_forced < 0)
2003                 return 0; // forced spectators can never join
2004
2005         // TODO simplify this
2006         int totalClients = 0;
2007         int currentlyPlaying = 0;
2008         FOREACH_CLIENT(true, LAMBDA(
2009                 if(it != ignore)
2010                         ++totalClients;
2011                 if(IS_REAL_CLIENT(it))
2012                 if(IS_PLAYER(it) || it.caplayer)
2013                         ++currentlyPlaying;
2014         ));
2015
2016         float free_slots = 0;
2017         if (!autocvar_g_maxplayers)
2018                 free_slots = maxclients - totalClients;
2019         else if(currentlyPlaying < autocvar_g_maxplayers)
2020                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2021
2022         static float join_prevent_msg_time = 0;
2023         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2024         {
2025                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2026                 join_prevent_msg_time = time + 3;
2027         }
2028
2029         return free_slots;
2030 }
2031
2032 /**
2033  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2034  * g_maxplayers_spectator_blocktime seconds
2035  */
2036 void checkSpectatorBlock(entity this)
2037 {
2038         if(IS_SPEC(this) || IS_OBSERVER(this))
2039         if(!this.caplayer)
2040         if(IS_REAL_CLIENT(this))
2041         {
2042                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2043                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2044                         dropclient(this);
2045                 }
2046         }
2047 }
2048
2049 void PrintWelcomeMessage(entity this)
2050 {
2051         if(CS(this).motd_actived_time == 0)
2052         {
2053                 if (autocvar_g_campaign) {
2054                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2055                                 CS(this).motd_actived_time = time;
2056                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2057                         }
2058                 } else {
2059                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2060                                 CS(this).motd_actived_time = time;
2061                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2062                         }
2063                 }
2064         }
2065         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2066         {
2067                 if (autocvar_g_campaign) {
2068                         if (PHYS_INPUT_BUTTON_INFO(this))
2069                                 CS(this).motd_actived_time = time;
2070                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2071                                 CS(this).motd_actived_time = 0;
2072                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2073                         }
2074                 } else {
2075                         if (PHYS_INPUT_BUTTON_INFO(this))
2076                                 CS(this).motd_actived_time = time;
2077                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2078                                 CS(this).motd_actived_time = 0;
2079                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2080                         }
2081                 }
2082         }
2083         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2084         {
2085                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2086                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2087                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2088                 {
2089                         // instanctly hide MOTD
2090                         CS(this).motd_actived_time = 0;
2091                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2092                 }
2093         }
2094 }
2095
2096 bool joinAllowed(entity this)
2097 {
2098         if (CS(this).version_mismatch) return false;
2099         if (!nJoinAllowed(this, this)) return false;
2100         if (teamplay && lockteams) return false;
2101         if (ShowTeamSelection(this)) return false;
2102         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2103         return true;
2104 }
2105
2106 .int items_added;
2107 bool PlayerThink(entity this)
2108 {
2109         if (game_stopped || intermission_running) {
2110                 this.modelflags &= ~MF_ROCKET;
2111                 if(intermission_running)
2112                         IntermissionThink(this);
2113                 return false;
2114         }
2115
2116         if (timeout_status == TIMEOUT_ACTIVE) {
2117         // don't allow the player to turn around while game is paused
2118                 // FIXME turn this into CSQC stuff
2119                 this.v_angle = this.lastV_angle;
2120                 this.angles = this.lastV_angle;
2121                 this.fixangle = true;
2122         }
2123
2124         if (frametime) player_powerups(this);
2125
2126         if (IS_DEAD(this)) {
2127                 if (this.personal && g_race_qualifying) {
2128                         if (time > this.respawn_time) {
2129                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2130                                 respawn(this);
2131                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2132                         }
2133                 } else {
2134                         if (frametime) player_anim(this);
2135
2136                         if (this.respawn_flags & RESPAWN_DENY)
2137                         {
2138                                 STAT(RESPAWN_TIME, this) = 0;
2139                                 return false;
2140                         }
2141
2142                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2143
2144                         switch(this.deadflag)
2145                         {
2146                                 case DEAD_DYING:
2147                                 {
2148                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2149                                                 this.deadflag = DEAD_RESPAWNING;
2150                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2151                                                 this.deadflag = DEAD_DEAD;
2152                                         break;
2153                                 }
2154                                 case DEAD_DEAD:
2155                                 {
2156                                         if (button_pressed)
2157                                                 this.deadflag = DEAD_RESPAWNABLE;
2158                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2159                                                 this.deadflag = DEAD_RESPAWNING;
2160                                         break;
2161                                 }
2162                                 case DEAD_RESPAWNABLE:
2163                                 {
2164                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2165                                                 this.deadflag = DEAD_RESPAWNING;
2166                                         break;
2167                                 }
2168                                 case DEAD_RESPAWNING:
2169                                 {
2170                                         if (time > this.respawn_time)
2171                                         {
2172                                                 this.respawn_time = time + 1; // only retry once a second
2173                                                 this.respawn_time_max = this.respawn_time;
2174                                                 respawn(this);
2175                                         }
2176                                         break;
2177                                 }
2178                         }
2179
2180                         ShowRespawnCountdown(this);
2181
2182                         if (this.respawn_flags & RESPAWN_SILENT)
2183                                 STAT(RESPAWN_TIME, this) = 0;
2184                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2185                         {
2186                                 if (time < this.respawn_time)
2187                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2188                                 else if (this.deadflag != DEAD_RESPAWNING)
2189                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2190                         }
2191                         else
2192                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2193                 }
2194
2195                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2196                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2197                         STAT(RESPAWN_TIME, this) *= -1;
2198
2199                 return false;
2200         }
2201
2202         bool have_hook = false;
2203         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2204         {
2205                 .entity weaponentity = weaponentities[slot];
2206                 if(this.(weaponentity).hook.state)
2207                 {
2208                         have_hook = true;
2209                         break;
2210                 }
2211         }
2212         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2213         if (have_hook) {
2214                 do_crouch = false;
2215         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2216                 do_crouch = false;
2217         } else if (this.vehicle) {
2218                 do_crouch = false;
2219         } else if (STAT(FROZEN, this)) {
2220                 do_crouch = false;
2221     }
2222
2223         if (do_crouch) {
2224                 if (!this.crouch) {
2225                         this.crouch = true;
2226                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2227                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2228                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2229                 }
2230         } else if (this.crouch) {
2231         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2232         if (!trace_startsolid) {
2233             this.crouch = false;
2234             this.view_ofs = STAT(PL_VIEW_OFS, this);
2235             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2236         }
2237         }
2238
2239         FixPlayermodel(this);
2240
2241         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2242         //if(frametime)
2243         {
2244                 this.items &= ~this.items_added;
2245
2246                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2247                 {
2248                         .entity weaponentity = weaponentities[slot];
2249                         W_WeaponFrame(this, weaponentity);
2250
2251                         if(slot == 0)
2252                         {
2253                                 this.clip_load = this.(weaponentity).clip_load;
2254                                 this.clip_size = this.(weaponentity).clip_size;
2255                         }
2256                 }
2257
2258                 this.items_added = 0;
2259                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2260             this.items_added |= IT_FUEL;
2261
2262                 this.items |= this.items_added;
2263         }
2264
2265         player_regen(this);
2266
2267         // WEAPONTODO: Add a weapon request for this
2268         // rot vortex charge to the charge limit
2269         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2270         {
2271                 .entity weaponentity = weaponentities[slot];
2272                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2273                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2274         }
2275
2276         if (frametime) player_anim(this);
2277
2278         // secret status
2279         secrets_setstatus(this);
2280
2281         // monsters status
2282         monsters_setstatus(this);
2283
2284         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2285
2286         return true;
2287 }
2288
2289 void ObserverThink(entity this)
2290 {
2291         if ( CS(this).impulse )
2292         {
2293                 MinigameImpulse(this, CS(this).impulse);
2294                 CS(this).impulse = 0;
2295         }
2296
2297         if (this.flags & FL_JUMPRELEASED) {
2298                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2299                         this.flags &= ~FL_JUMPRELEASED;
2300                         this.flags |= FL_SPAWNING;
2301                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2302                         this.flags &= ~FL_JUMPRELEASED;
2303                         if(SpectateNext(this)) {
2304                                 TRANSMUTE(Spectator, this);
2305                         }
2306                 } else {
2307                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2308                         set_movetype(this, preferred_movetype);
2309                 }
2310         } else {
2311                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2312                         this.flags |= FL_JUMPRELEASED;
2313                         if(this.flags & FL_SPAWNING)
2314                         {
2315                                 this.flags &= ~FL_SPAWNING;
2316                                 Join(this);
2317                                 return;
2318                         }
2319                 }
2320         }
2321 }
2322
2323 void SpectatorThink(entity this)
2324 {
2325         if ( CS(this).impulse )
2326         {
2327                 if(MinigameImpulse(this, CS(this).impulse))
2328                         CS(this).impulse = 0;
2329
2330                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2331                 {
2332                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2333                         CS(this).impulse = 0;
2334                         return;
2335                 }
2336         }
2337
2338         if (this.flags & FL_JUMPRELEASED) {
2339                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2340                         this.flags &= ~FL_JUMPRELEASED;
2341                         this.flags |= FL_SPAWNING;
2342                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2343                         this.flags &= ~FL_JUMPRELEASED;
2344                         if(SpectateNext(this)) {
2345                                 TRANSMUTE(Spectator, this);
2346                         } else {
2347                                 TRANSMUTE(Observer, this);
2348                                 PutClientInServer(this);
2349                         }
2350                         CS(this).impulse = 0;
2351                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2352                         this.flags &= ~FL_JUMPRELEASED;
2353                         if(SpectatePrev(this)) {
2354                                 TRANSMUTE(Spectator, this);
2355                         } else {
2356                                 TRANSMUTE(Observer, this);
2357                                 PutClientInServer(this);
2358                         }
2359                         CS(this).impulse = 0;
2360                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2361                         this.flags &= ~FL_JUMPRELEASED;
2362                         TRANSMUTE(Observer, this);
2363                         PutClientInServer(this);
2364                 } else {
2365                         if(!SpectateUpdate(this))
2366                                 PutObserverInServer(this);
2367                 }
2368         } else {
2369                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2370                         this.flags |= FL_JUMPRELEASED;
2371                         if(this.flags & FL_SPAWNING)
2372                         {
2373                                 this.flags &= ~FL_SPAWNING;
2374                                 Join(this);
2375                                 return;
2376                         }
2377                 }
2378                 if(!SpectateUpdate(this))
2379                         PutObserverInServer(this);
2380         }
2381
2382         this.flags |= FL_CLIENT | FL_NOTARGET;
2383 }
2384
2385 void vehicles_enter (entity pl, entity veh);
2386 void PlayerUseKey(entity this)
2387 {
2388         if (!IS_PLAYER(this))
2389                 return;
2390
2391         if(this.vehicle)
2392         {
2393                 if(!game_stopped)
2394                 {
2395                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2396                         return;
2397                 }
2398         }
2399         else if(autocvar_g_vehicles_enter)
2400         {
2401                 if(!STAT(FROZEN, this))
2402                 if(!IS_DEAD(this))
2403                 if(!game_stopped)
2404                 {
2405                         entity head, closest_target = NULL;
2406                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2407
2408                         while(head) // find the closest acceptable target to enter
2409                         {
2410                                 if(IS_VEHICLE(head))
2411                                 if(!IS_DEAD(head))
2412                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2413                                 if(head.takedamage != DAMAGE_NO)
2414                                 {
2415                                         if(closest_target)
2416                                         {
2417                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2418                                                 { closest_target = head; }
2419                                         }
2420                                         else { closest_target = head; }
2421                                 }
2422
2423                                 head = head.chain;
2424                         }
2425
2426                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2427                 }
2428         }
2429
2430         // a use key was pressed; call handlers
2431         MUTATOR_CALLHOOK(PlayerUseKey, this);
2432 }
2433
2434
2435 /*
2436 =============
2437 PlayerPreThink
2438
2439 Called every frame for each client before the physics are run
2440 =============
2441 */
2442 .float last_vehiclecheck;
2443 void PlayerPreThink (entity this)
2444 {
2445         WarpZone_PlayerPhysics_FixVAngle(this);
2446
2447     STAT(GAMESTARTTIME, this) = game_starttime;
2448         STAT(ROUNDSTARTTIME, this) = round_starttime;
2449         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2450         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2451
2452         STAT(WEAPONSINMAP, this) = weaponsInMap;
2453
2454         if (frametime) {
2455                 // physics frames: update anticheat stuff
2456                 anticheat_prethink(this);
2457         }
2458
2459         if (blockSpectators && frametime) {
2460                 // WORKAROUND: only use dropclient in server frames (frametime set).
2461                 // Never use it in cl_movement frames (frametime zero).
2462                 checkSpectatorBlock(this);
2463     }
2464
2465         zoomstate_set = false;
2466
2467         // Check for nameless players
2468         if (isInvisibleString(this.netname)) {
2469                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2470                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2471         }
2472         if (this.netname != CS(this).netname_previous) {
2473                 if (autocvar_sv_eventlog) {
2474                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2475         }
2476                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2477                 CS(this).netname_previous = strzone(this.netname);
2478         }
2479
2480         // version nagging
2481         if (CS(this).version_nagtime && this.cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2482         CS(this).version_nagtime = 0;
2483         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2484             // git client
2485         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2486             // git server
2487             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2488         } else {
2489             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2490             if (r < 0) { // old client
2491                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2492             } else if (r > 0) { // old server
2493                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2494             }
2495         }
2496     }
2497
2498         // GOD MODE info
2499         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2500         {
2501                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2502                 this.max_armorvalue = 0;
2503         }
2504
2505         if (STAT(FROZEN, this) == 2)
2506         {
2507                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2508                 this.health = max(1, this.revive_progress * start_health);
2509                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2510
2511                 if (this.revive_progress >= 1)
2512                         Unfreeze(this);
2513         }
2514         else if (STAT(FROZEN, this) == 3)
2515         {
2516                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2517                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2518
2519                 if (this.health < 1)
2520                 {
2521                         if (this.vehicle)
2522                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2523                         if(this.event_damage)
2524                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2525                 }
2526                 else if (this.revive_progress <= 0)
2527                         Unfreeze(this);
2528         }
2529
2530         MUTATOR_CALLHOOK(PlayerPreThink, this);
2531
2532         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2533         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2534         {
2535                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2536                 {
2537                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2538                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2539                         {
2540                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2541                         }
2542                         else if(!it.owner)
2543                         {
2544                                 if(!it.team || SAME_TEAM(this, it))
2545                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2546                                 else if(autocvar_g_vehicles_steal)
2547                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2548                         }
2549                 });
2550
2551                 this.last_vehiclecheck = time + 1;
2552         }
2553
2554         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2555         {
2556                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2557                         PlayerUseKey(this);
2558                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2559         }
2560
2561         if (IS_REAL_CLIENT(this))
2562                 PrintWelcomeMessage(this);
2563
2564         if (IS_PLAYER(this)) {
2565                 if(!PlayerThink(this))
2566                         return;
2567         }
2568         else if (game_stopped || intermission_running) {
2569                 if(intermission_running)
2570                         IntermissionThink(this);
2571                 return;
2572         }
2573         else if (IS_OBSERVER(this)) {
2574                 ObserverThink(this);
2575         }
2576         else if (IS_SPEC(this)) {
2577                 SpectatorThink(this);
2578         }
2579
2580         // WEAPONTODO: Add weapon request for this
2581         if (!zoomstate_set) {
2582                 bool wep_zoomed = false;
2583                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2584                 {
2585                         .entity weaponentity = weaponentities[slot];
2586                         Weapon thiswep = this.(weaponentity).m_weapon;
2587                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2588                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2589                 }
2590                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2591     }
2592
2593         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2594         {
2595                 CS(this).teamkill_soundtime = 0;
2596
2597                 entity e = CS(this).teamkill_soundsource;
2598                 entity oldpusher = e.pusher;
2599                 e.pusher = this;
2600                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2601                 e.pusher = oldpusher;
2602         }
2603
2604         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2605                 CS(this).taunt_soundtime = 0;
2606                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2607         }
2608
2609         target_voicescript_next(this);
2610
2611         // WEAPONTODO: Move into weaponsystem somehow
2612         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2613         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2614         {
2615                 .entity weaponentity = weaponentities[slot];
2616                 if(this.(weaponentity).m_weapon == WEP_Null)
2617                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2618         }
2619 }
2620
2621 void DrownPlayer(entity this)
2622 {
2623         if(IS_DEAD(this))
2624                 return;
2625
2626         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2627         {
2628                 if(this.air_finished < time)
2629                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2630                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2631                 this.dmg = 2;
2632         }
2633         else if (this.air_finished < time)
2634         {       // drown!
2635                 if (this.pain_finished < time)
2636                 {
2637                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2638                         this.pain_finished = time + 0.5;
2639                 }
2640         }
2641 }
2642
2643 .bool move_qcphysics;
2644
2645 void Player_Physics(entity this)
2646 {
2647         set_movetype(this, this.move_movetype);
2648
2649         if(!this.move_qcphysics)
2650                 return;
2651
2652         if(!frametime && !CS(this).pm_frametime)
2653                 return;
2654
2655         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2656
2657         CS(this).pm_frametime = 0;
2658 }
2659
2660 /*
2661 =============
2662 PlayerPostThink
2663
2664 Called every frame for each client after the physics are run
2665 =============
2666 */
2667 void PlayerPostThink (entity this)
2668 {
2669         Player_Physics(this);
2670
2671         if (sv_maxidle > 0)
2672         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2673         if (IS_REAL_CLIENT(this))
2674         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2675         {
2676                 int totalClients = 0;
2677                 if(sv_maxidle_slots > 0)
2678                 {
2679                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2680                         {
2681                                 ++totalClients;
2682                         });
2683                 }
2684
2685                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2686                 { /* do nothing */ }
2687                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2688                 {
2689                         if (CS(this).idlekick_lasttimeleft)
2690                         {
2691                                 CS(this).idlekick_lasttimeleft = 0;
2692                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2693                         }
2694                 }
2695                 else
2696                 {
2697                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2698                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2699                                 if (!CS(this).idlekick_lasttimeleft)
2700                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2701                         }
2702                         if (timeleft <= 0) {
2703                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2704                                 dropclient(this);
2705                                 return;
2706                         }
2707                         else if (timeleft <= 10) {
2708                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2709                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2710                 }
2711                                 CS(this).idlekick_lasttimeleft = timeleft;
2712                         }
2713                 }
2714         }
2715
2716         CheatFrame(this);
2717
2718         if (game_stopped)
2719         {
2720                 this.solid = SOLID_NOT;
2721                 this.takedamage = DAMAGE_NO;
2722                 set_movetype(this, MOVETYPE_NONE);
2723         }
2724
2725         if (IS_PLAYER(this)) {
2726                 DrownPlayer(this);
2727                 UpdateChatBubble(this);
2728                 if (CS(this).impulse) ImpulseCommands(this);
2729                 if (game_stopped)
2730                 {
2731                         CSQCMODEL_AUTOUPDATE(this);
2732                         return;
2733                 }
2734                 GetPressedKeys(this);
2735         }
2736
2737         if (this.waypointsprite_attachedforcarrier) {
2738             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2739                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2740     }
2741
2742         playerdemo_write(this);
2743
2744         CSQCMODEL_AUTOUPDATE(this);
2745 }
2746
2747 // hack to copy the button fields from the client entity to the Client State
2748 void PM_UpdateButtons(entity this, entity store)
2749 {
2750         if(this.impulse)
2751                 store.impulse = this.impulse;
2752         this.impulse = 0;
2753
2754         store.button0 = this.button0;
2755         store.button2 = this.button2;
2756         store.button3 = this.button3;
2757         store.button4 = this.button4;
2758         store.button5 = this.button5;
2759         store.button6 = this.button6;
2760         store.button7 = this.button7;
2761         store.button8 = this.button8;
2762         store.button9 = this.button9;
2763         store.button10 = this.button10;
2764         store.button11 = this.button11;
2765         store.button12 = this.button12;
2766         store.button13 = this.button13;
2767         store.button14 = this.button14;
2768         store.button15 = this.button15;
2769         store.button16 = this.button16;
2770         store.buttonuse = this.buttonuse;
2771         store.buttonchat = this.buttonchat;
2772
2773         store.cursor_active = this.cursor_active;
2774         store.cursor_screen = this.cursor_screen;
2775         store.cursor_trace_start = this.cursor_trace_start;
2776         store.cursor_trace_endpos = this.cursor_trace_endpos;
2777         store.cursor_trace_ent = this.cursor_trace_ent;
2778
2779         store.ping = this.ping;
2780         store.ping_packetloss = this.ping_packetloss;
2781         store.ping_movementloss = this.ping_movementloss;
2782
2783         store.v_angle = this.v_angle;
2784         store.movement = this.movement;
2785 }