qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3 float Nagger_SendEntity(entity to, float sendflags)
   4 {
   5         float nags, i, f, b;
   6         entity e;
   7         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   8
   9         nags = 0;
  10         if(readycount)
  11         {
  12                 nags |= 1;
  13                 if(to.ready == 0)
  14                         nags |= 2;
  15         }
  16         if(votecalled)
  17         {
  18                 nags |= 4;
  19                 if(to.vote_vote == 0)
  20                         nags |= 8;
  21         }
  22         if(inWarmupStage)
  23                 nags |= 16;
  24
  25         if(sendflags & 128)
  26                 nags |= 128;
  27
  28         WriteByte(MSG_ENTITY, nags);
  29
  30         if(nags & 128)
  31         {
  32                 WriteString(MSG_ENTITY, votecalledvote_display);
  33         }
  34
  35         if(nags & 1)
  36         {
  37                 for(i = 1; i <= maxclients; i += 8)
  38                 {
  39                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  40                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  41                                         f |= b;
  42                         WriteByte(MSG_ENTITY, f);
  43                 }
  44         }
  45
  46         return TRUE;
  47 }
  48 void Nagger_Init()
  49 {
  50         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  51 }
  52 void Nagger_VoteChanged()
  53 {
  54         if(nagger)
  55                 nagger.SendFlags |= 128;
  56 }
  57 void Nagger_VoteCountChanged()
  58 {
  59         if(nagger)
  60                 nagger.SendFlags |= 1;
  61 }
  62 void Nagger_ReadyCounted()
  63 {
  64         if(nagger)
  65                 nagger.SendFlags |= 1;
  66 }
  67
  68 void ReadyCount();
  69 string MapVote_Suggest(string m);
  70
  71 entity GetPlayer(string name)
  72 {
  73         float num;
  74         entity e;
  75         string ns;
  76
  77         if(substring(name, 0, 1) == "#") {
  78                 num = stof(substring(name, 1, 999));
  79                 if(num >= 1 && num <= maxclients) {
  80                         for((e = world); num > 0; --num, (e = nextent(e)))
  81                                 ;
  82                         //if(clienttype(e) == CLIENTTYPE_REAL)
  83                         if(e.classname == "player")
  84                                 return e;
  85                 }
  86         } else {
  87                 ns = strdecolorize(name);
  88                 FOR_EACH_REALPLAYER(e) {
  89                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
  90                                 return e;
  91                         }
  92                 }
  93         }
  94         return world;
  95 }
  96
  97 //float ctf_clientcommand();
  98 float readyrestart_happened;
  99 .float lms_spectate_warning;
 100 void spawnfunc_func_breakable();
 101
 102 .float cmd_floodtime;
 103 .float cmd_floodcount;
 104 float cmd_floodcheck()
 105 {
 106         if (timeoutStatus != 2)
 107         {
 108                 if(time == self.cmd_floodtime)
 109                 {
 110                         self.cmd_floodcount += 1;
 111                         if(self.cmd_floodcount > 8)
 112                                 return TRUE;
 113                 }
 114                 else
 115                 {
 116                         self.cmd_floodtime = time;
 117                         self.cmd_floodcount = 1;
 118                 }
 119         }
 120         return FALSE;
 121 }
 122
 123 void SV_ParseClientCommand(string s) {
 124         string cmd;
 125         float tokens;
 126         float i;
 127         entity e;
 128
 129         tokens = tokenize_console(s);
 130
 131         cmd = argv(0);
 132         if(cmd != "reportcvar")
 133         if(cmd != "sentcvar")
 134         if(cmd != "pause")
 135         if(cmd != "prespawn")
 136         if(cmd != "spawn")
 137         if(cmd != "begin")
 138         {
 139                 if(cmd_floodcheck())
 140                         return;
 141         }
 142
 143         if(GameCommand_Vote(s, self)) {
 144                 return;
 145         } else if(GameCommand_MapVote(argv(0))) {
 146                 return;
 147         } else if(cmd == "autoswitch") {
 148                 // be backwards compatible with older clients (enabled)
 149                 self.autoswitch = ("0" != argv(1));
 150                 local string autoswitchmsg;
 151                 if (self.autoswitch) {
 152                         autoswitchmsg = "on";
 153                 } else {
 154                         autoswitchmsg = "off";
 155                 }
 156                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 157         } else if(cmd == "clientversion") {
 158                 if not(self.flags & FL_CLIENT)
 159                         return;
 160                 if (argv(1) == "$gameversion") {
 161                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.xonotic.com)^8";
 162                         // either that or someone wants to be funny
 163                         self.version = 1;
 164                 } else {
 165                         self.version = stof(argv(1));
 166                 }
 167                 if(self.version != cvar("gameversion"))
 168                 {
 169                         self.classname = "observer";
 170                         self.version_mismatch = 1;
 171                         PutClientInServer();
 172                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 173                         //JoinBestTeam(self, FALSE, TRUE);
 174                 } else if(teams_matter && !cvar("sv_spectate") && !(self.team_forced > 0)) {
 175                         self.classname = "observer";
 176                         stuffcmd(self,"menu_showteamselect\n");
 177                 }
 178         } else if(cmd == "reportcvar") { // old system
 179                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
 180                 {
 181                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 182                         tokens = tokenize_console(s);
 183                 }
 184                 GetCvars(1);
 185         } else if(cmd == "sentcvar") { // new system
 186                 if(tokens == 2) // undefined cvar: use the default value on the server then
 187                 {
 188                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 189                         tokens = tokenize_console(s);
 190                 }
 191                 GetCvars(1);
 192         } else if(cmd == "spectate") {
 193                 if(cmd_floodcheck())
 194                         return;
 195                 if not(self.flags & FL_CLIENT)
 196                         return;
 197                 if(g_arena)
 198                         return;
 199                 if(g_lms)
 200                 {
 201                         if(self.lms_spectate_warning)
 202                         {
 203                                 // mark player as spectator
 204                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 205                         }
 206                         else
 207                         {
 208                                 self.lms_spectate_warning = 1;
 209                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 210                                 return;
 211                         }
 212                 }
 213                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 214                         if(self.flagcarried)
 215                                 DropFlag(self.flagcarried, world, world);
 216                         if(self.ballcarried)
 217                                 DropBall(self.ballcarried, self.origin, self.velocity);
 218                         WaypointSprite_PlayerDead();
 219                         self.classname = "observer";
 220                         if(g_ca)
 221                                 self.caplayer = 0;
 222                         if(blockSpectators)
 223                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 224                         PutClientInServer();
 225                 }
 226         } else if(cmd == "join") {
 227                 if not(self.flags & FL_CLIENT)
 228                         return;
 229                 if(!g_arena)
 230                 if (self.classname != "player" && !lockteams)
 231                 {
 232                         if(isJoinAllowed()) {
 233                                 self.classname = "player";
 234                                 if(g_ca)
 235                                         self.caplayer = 1;
 236                                 PlayerScore_Clear(self);
 237                                 bprint ("^4", self.netname, "^4 is playing now\n");
 238                                 self.stat_count = WEP_LAST;
 239                                 PutClientInServer();
 240                                 if(cvar("g_campaign"))
 241                                         campaign_bots_may_start = 1;
 242                         }
 243                         else {
 244                                 //player may not join because of g_maxplayers is set
 245                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 246                         }
 247                 }
 248         } else if( cmd == "selectteam" ) {
 249                 if not(self.flags & FL_CLIENT)
 250                         return;
 251                 if( !teams_matter ) {
 252                         sprint( self, "selectteam can only be used in teamgames\n");
 253                 } else if(cvar("g_campaign")) {
 254                         //JoinBestTeam(self, 0);
 255                 } else if(self.team_forced > 0) {
 256                         sprint( self, "selectteam can not be used as your team is forced\n");
 257                 } else if(lockteams) {
 258                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 259                 } else if( argv(1) == "red" ) {
 260                         DoTeamChange(COLOR_TEAM1);
 261                 } else if( argv(1) == "blue" ) {
 262                         DoTeamChange(COLOR_TEAM2);
 263                 } else if( argv(1) == "yellow" ) {
 264                         DoTeamChange(COLOR_TEAM3);
 265                 } else if( argv(1) == "pink" ) {
 266                         DoTeamChange(COLOR_TEAM4);
 267                 } else if( argv(1) == "auto" ) {
 268                         DoTeamChange(-1);
 269                 } else {
 270                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 271                 }
 272         } else if(cmd == "ready") {
 273                 if not(self.flags & FL_CLIENT)
 274                         return;
 275
 276                 if((inWarmupStage && 0 >= g_warmup_limit) // with unlimited warmup players have to be able to restart
 277                    || cvar("sv_ready_restart") || g_race_qualifying == 2)
 278                 {
 279                         if(!readyrestart_happened || cvar("sv_ready_restart_repeatable"))
 280                         {
 281                                 if (self.ready) // toggle
 282                                 {
 283                                         self.ready = FALSE;
 284                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 285                                 }
 286                                 else
 287                                 {
 288                                         self.ready = TRUE;
 289                                         bprint(self.netname, "^2 is ready\n");
 290                                 }
 291
 292                                 // cannot reset the game while a timeout is active!
 293                                 if(!timeoutStatus)
 294                                         ReadyCount();
 295                         } else {
 296                                 sprint(self, "^1Game has already been restarted\n");
 297                         }
 298                 }
 299         } else if(cmd == "maplist") {
 300                 sprint(self, maplist_reply);
 301         } else if(cmd == "lsmaps") {
 302                 sprint(self, lsmaps_reply);
 303         } else if(cmd == "lsnewmaps") {
 304                 sprint(self, lsnewmaps_reply);
 305         } else if(cmd == "records") {
 306                 for(i = 0; i < 10; ++i)
 307                         sprint(self, records_reply[i]);
 308         } else if(cmd == "ladder") {
 309                 sprint(self, ladder_reply);
 310         } else if(cmd == "rankings") {
 311                 sprint(self, rankings_reply);
 312         } else if(cmd == "voice") {
 313                 if(tokens >= 3)
 314                         VoiceMessage(argv(1), substring(s, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 315                 else
 316                         VoiceMessage(argv(1), "");
 317         } else if(cmd == "say") {
 318                 if(tokens >= 2)
 319                         Say(self, FALSE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 320                 //clientcommand(self, formatmessage(s));
 321         } else if(cmd == "say_team") {
 322                 if(tokens >= 2)
 323                         Say(self, TRUE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 324                 //clientcommand(self, formatmessage(s));
 325         } else if(cmd == "tell") {
 326                 e = GetCommandPlayerSlotTargetFromTokenizedCommand(tokens, 1);
 327                 if(e && tokens > ParseCommandPlayerSlotTarget_firsttoken)
 328                 {
 329                         Say(self, FALSE, e, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)), TRUE);
 330                 }
 331                 else
 332                 {
 333                         if(tokens > ParseCommandPlayerSlotTarget_firsttoken)
 334                                 trigger_magicear_processmessage_forallears(self, -1, world, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)));
 335                         sprint(self, "ERROR: usage: tell # playerid text...\n");
 336                 }
 337                 //clientcommand(self, formatmessage(s));
 338         } else if(cmd == "info") {
 339                 cmd = cvar_string_builtin(strcat("sv_info_", argv(1))); // This needed fixed for the cvar check
 340                 if(cmd == "")
 341                         sprint(self, "ERROR: unsupported info command\n");
 342                 else
 343                         wordwrap_sprint(cmd, 1111);
 344         } else if(cmd == "suggestmap") {
 345                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 346         } else if(cmd == "timeout") {
 347                 if not(self.flags & FL_CLIENT)
 348                         return;
 349                 if(cvar("sv_timeout")) {
 350                         if(self.classname == "player") {
 351                                 if(votecalled)
 352                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 353                                 else
 354                                         evaluateTimeout();
 355                         }
 356                         else
 357                                 sprint(self, "^7Error: only players can call a timeout!\n");
 358                 }
 359         } else if(cmd == "timein") {
 360                 if not(self.flags & FL_CLIENT)
 361                         return;
 362                 if(cvar("sv_timeout")) {
 363                         evaluateTimein();
 364                 }
 365         } else if(cmd == "teamstatus") {
 366                 Score_NicePrint(self);
 367         } else if(cmd == "cvar_changes") {
 368                 sprint(self, cvar_changes);
 369         } else if(cmd == "cvar_purechanges") {
 370                 sprint(self, cvar_purechanges);
 371         } else if(CheatCommand(tokens)) {
 372         } else {
 373                 //if(ctf_clientcommand())
 374                 //      return;
 375                 // grep for Cmd_AddCommand_WithClientCommand to find them all
 376                 if(cmd != "status")
 377                 //if(cmd != "say") // handled above
 378                 //if(cmd != "say_team") // handled above
 379                 if(cmd != "kill")
 380                 if(cmd != "pause")
 381                 if(cmd != "ping")
 382                 if(cmd != "name")
 383                 if(cmd != "color")
 384                 if(cmd != "rate")
 385                 if(cmd != "pmodel")
 386                 if(cmd != "playermodel")
 387                 if(cmd != "playerskin")
 388                 if(cmd != "prespawn")
 389                 if(cmd != "spawn")
 390                 if(cmd != "begin")
 391                 if(cmd != "pings")
 392                 if(cmd != "sv_startdownload")
 393                 if(cmd != "download")
 394                 {
 395                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 396                         return;
 397                 }
 398
 399                 if(self.jointime > 0 && time > self.jointime + 10 && time > self.nickspamtime) // allow any changes in the first 10 seconds since joining
 400                 if(cmd == "name" || cmd == "playermodel") // TODO also playerskin and color?
 401                 {
 402                         if(self.nickspamtime == 0 || time > self.nickspamtime + cvar("g_nick_flood_timeout"))
 403                                 // good, no serious flood
 404                                 self.nickspamcount = 1;
 405                         else
 406                                 self.nickspamcount += 1;
 407                         self.nickspamtime = time + cvar("g_nick_flood_penalty");
 408
 409                         if (timeoutStatus == 2) //when game is paused, no flood protection
 410                                 self.nickspamcount = self.nickspamtime = 0;
 411                 }
 412
 413                 clientcommand(self,s);
 414         }
 415 }
 416
 417 void ReadyRestartForce()
 418 {
 419         local entity e;
 420
 421         bprint("^1Server is restarting...\n");
 422
 423         VoteReset();
 424
 425         // clear overtime
 426         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) {
 427                 //we have to decrease timelimit to its original value again!!
 428                 float newTL;
 429                 newTL = cvar("timelimit");
 430                 newTL -= checkrules_overtimesadded * cvar("timelimit_overtime");
 431                 cvar_set("timelimit", ftos(newTL));
 432         }
 433
 434         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 435
 436
 437         readyrestart_happened = 1;
 438         game_starttime = time;
 439         if(!g_ca && !g_arena)
 440                 game_starttime += RESTART_COUNTDOWN;
 441         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 442
 443         inWarmupStage = 0; //once the game is restarted the game is in match stage
 444
 445         //reset the .ready status of all players (also spectators)
 446         FOR_EACH_CLIENTSLOT(e)
 447                 e.ready = 0;
 448         readycount = 0;
 449         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 450
 451         if(cvar("teamplay_lockonrestart") && teams_matter) {
 452                 lockteams = 1;
 453                 bprint("^1The teams are now locked.\n");
 454         }
 455
 456         //initiate the restart-countdown-announcer entity
 457         if(cvar("sv_ready_restart_after_countdown") && !g_ca && !g_arena)
 458         {
 459                 restartTimer = spawn();
 460                 restartTimer.think = restartTimer_Think;
 461                 restartTimer.nextthink = game_starttime;
 462         }
 463
 464         //after a restart every players number of allowed timeouts gets reset, too
 465         if(cvar("sv_timeout"))
 466         {
 467                 FOR_EACH_REALPLAYER(e)
 468                         e.allowedTimeouts = cvar("sv_timeout_number");
 469         }
 470
 471         //reset map immediately if this cvar is not set
 472         if (!cvar("sv_ready_restart_after_countdown"))
 473                 reset_map(TRUE);
 474
 475         if(cvar("sv_eventlog"))
 476                 GameLogEcho(":restart");
 477 }
 478
 479 void ReadyRestart()
 480 {
 481         // no arena, assault support yet...
 482         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 483                 localcmd("restart\n");
 484         else
 485                 localcmd("\nsv_hook_gamerestart\n");
 486
 487         ReadyRestartForce();
 488
 489         // reset ALL scores, but only do that at the beginning
 490         //of the countdown if sv_ready_restart_after_countdown is off!
 491         //Otherwise scores could be manipulated during the countdown!
 492         if (!cvar("sv_ready_restart_after_countdown"))
 493                 Score_ClearAll();
 494 }
 495
 496 /**
 497  * Counts how many players are ready. If not enough players are ready, the function
 498  * does nothing. If all players are ready, the timelimit will be extended and the
 499  * restart_countdown variable is set to allow other functions like PlayerPostThink
 500  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 501  * is not set the map will be resetted.
 502  *
 503  * Function is called after the server receives a 'ready' sign from a player.
 504  */
 505 void ReadyCount()
 506 {
 507         local entity e;
 508         local float r, p;
 509
 510         r = p = 0;
 511
 512         FOR_EACH_REALPLAYER(e)
 513         {
 514                 p += 1;
 515                 if(e.ready)
 516                         r += 1;
 517         }
 518
 519         readycount = r;
 520
 521         Nagger_ReadyCounted();
 522
 523         if(r) // at least one is ready
 524         if(r == p) // and, everyone is ready
 525                 ReadyRestart();
 526 }
 527
 528 /**
 529  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 530  * is set)
 531  */
 532 void restartTimer_Think() {
 533         restart_mapalreadyrestarted = 1;
 534         reset_map(TRUE);
 535         Score_ClearAll();
 536         remove(self);
 537         return;
 538 }
 539
 540 /**
 541  * Checks whether the player who calls the timeout is allowed to do so.
 542  * If so, it initializes the timeout countdown. It also checks whether another
 543  * timeout was already running at this time and reacts correspondingly.
 544  *
 545  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 546  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 547  *
 548  * This function is called when a player issues the calltimeout command.
 549  */
 550 void evaluateTimeout() {
 551         if (inWarmupStage && !g_warmup_allow_timeout)
 552                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 553         if (time < game_starttime )
 554                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 555         if (timeoutStatus != 2) {
 556                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 557                 if (cvar("timelimit")) {
 558                         //a timelimit was used
 559                         local float myTl;
 560                         myTl = cvar("timelimit");
 561
 562                         local float lastPossibleTimeout;
 563                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 564
 565                         if (lastPossibleTimeout < time - game_starttime)
 566                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 567                 }
 568         }
 569         //player may not call a timeout if he has no calls left
 570         if (self.allowedTimeouts < 1)
 571                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 572         //now all required checks are passed
 573         self.allowedTimeouts -= 1;
 574         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 575         remainingTimeoutTime = cvar("sv_timeout_length");
 576         remainingLeadTime = cvar("sv_timeout_leadtime");
 577         timeoutInitiator = self;
 578         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 579                 timeoutStatus = 1;
 580                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 581                 timeoutHandler = spawn();
 582                 timeoutHandler.think = timeoutHandler_Think;
 583         }
 584         timeoutHandler.nextthink = time; //always let the entity think asap
 585
 586         //inform all connected clients about the timeout call
 587         Announce("timeoutcalled");
 588 }
 589
 590 /**
 591  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 592  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 593  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 594  * value of the cvar sv_timeout_resumetime.
 595  *
 596  * This function is called when a player issues the resumegame command.
 597  */
 598 void evaluateTimein() {
 599         if (!timeoutStatus)
 600                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 601         if (self != timeoutInitiator)
 602                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 603         if (timeoutStatus == 1) {
 604                 remainingTimeoutTime = timeoutStatus = 0;
 605                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 606                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 607         }
 608         else if (timeoutStatus == 2) {
 609                 //only shorten the remainingTimeoutTime if it makes sense
 610                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 611                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 612                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 613                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 614                 }
 615                 else
 616                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 617
 618         }
 619 }