qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3 float Nagger_SendEntity(entity to, float sendflags)
   4 {
   5         float nags, i, f, b;
   6         entity e;
   7         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   8
   9         nags = 0;
  10         if(readycount)
  11         {
  12                 nags |= 1;
  13                 if(to.ready == 0)
  14                         nags |= 2;
  15         }
  16         if(votecalled)
  17         {
  18                 nags |= 4;
  19                 if(to.vote_vote == 0)
  20                         nags |= 8;
  21         }
  22         if(inWarmupStage)
  23                 nags |= 16;
  24
  25         if(sendflags & 128)
  26                 nags |= 128;
  27
  28         WriteByte(MSG_ENTITY, nags);
  29
  30         if(nags & 128)
  31         {
  32                 WriteString(MSG_ENTITY, votecalledvote_display);
  33         }
  34
  35         if(nags & 1)
  36         {
  37                 for(i = 1; i <= maxclients; i += 8)
  38                 {
  39                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  40                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  41                                         f |= b;
  42                         WriteByte(MSG_ENTITY, f);
  43                 }
  44         }
  45
  46         return TRUE;
  47 }
  48 void Nagger_Init()
  49 {
  50         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  51 }
  52 void Nagger_VoteChanged()
  53 {
  54         if(nagger)
  55                 nagger.SendFlags |= 128;
  56 }
  57 void Nagger_VoteCountChanged()
  58 {
  59         if(nagger)
  60                 nagger.SendFlags |= 1;
  61 }
  62 void Nagger_ReadyCounted()
  63 {
  64         if(nagger)
  65                 nagger.SendFlags |= 1;
  66 }
  67
  68 void ReadyCount();
  69 string MapVote_Suggest(string m);
  70
  71 entity GetPlayer(string name)
  72 {
  73         float num;
  74         entity e;
  75         string ns;
  76
  77         if(substring(name, 0, 1) == "#") {
  78                 num = stof(substring(name, 1, 999));
  79                 if(num >= 1 && num <= maxclients) {
  80                         for((e = world); num > 0; --num, (e = nextent(e)))
  81                                 ;
  82                         //if(clienttype(e) == CLIENTTYPE_REAL)
  83                         if(e.classname == "player")
  84                                 return e;
  85                 }
  86         } else {
  87                 ns = strdecolorize(name);
  88                 FOR_EACH_REALPLAYER(e) {
  89                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
  90                                 return e;
  91                         }
  92                 }
  93         }
  94         return world;
  95 }
  96
  97 //float ctf_clientcommand();
  98 float readyrestart_happened;
  99 .float lms_spectate_warning;
 100 void spawnfunc_func_breakable();
 101
 102 .float cmd_floodtime;
 103 .float cmd_floodcount;
 104 float cmd_floodcheck()
 105 {
 106         if (timeoutStatus != 2)
 107         {
 108                 if(time == self.cmd_floodtime)
 109                 {
 110                         self.cmd_floodcount += 1;
 111                         if(self.cmd_floodcount > 8)
 112                                 return TRUE;
 113                 }
 114                 else
 115                 {
 116                         self.cmd_floodtime = time;
 117                         self.cmd_floodcount = 1;
 118                 }
 119         }
 120         return FALSE;
 121 }
 122
 123 void SV_ParseClientCommand(string s) {
 124         string cmd;
 125         float tokens;
 126         float i;
 127         entity e;
 128
 129         tokens = tokenize_console(s);
 130
 131         cmd = argv(0);
 132         if(cmd != "reportcvar")
 133         if(cmd != "sentcvar")
 134         if(cmd != "pause")
 135         if(cmd != "prespawn")
 136         if(cmd != "spawn")
 137         if(cmd != "begin")
 138         {
 139                 if(cmd_floodcheck())
 140                         return;
 141         }
 142
 143         if(GameCommand_Vote(s, self)) {
 144                 return;
 145         } else if(GameCommand_MapVote(argv(0))) {
 146                 return;
 147         } else if(cmd == "autoswitch") {
 148                 // be backwards compatible with older clients (enabled)
 149                 self.autoswitch = ("0" != argv(1));
 150                 local string autoswitchmsg;
 151                 if (self.autoswitch) {
 152                         autoswitchmsg = "on";
 153                 } else {
 154                         autoswitchmsg = "off";
 155                 }
 156                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 157         } else if(cmd == "clientversion") {
 158                 if not(self.flags & FL_CLIENT)
 159                         return;
 160                 if (argv(1) == "$gameversion") {
 161                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.xonotic.com)^8";
 162                         // either that or someone wants to be funny
 163                         self.version = 1;
 164                 } else {
 165                         self.version = stof(argv(1));
 166                 }
 167                 if(self.version != cvar("gameversion"))
 168                 {
 169                         self.classname = "observer";
 170                         self.version_mismatch = 1;
 171                         PutClientInServer();
 172                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 173                         //JoinBestTeam(self, FALSE, TRUE);
 174                 } else if(teams_matter && !cvar("sv_spectate")) {
 175                         self.classname = "observer";
 176                         stuffcmd(self,"menu_showteamselect\n");
 177                 }
 178         } else if(cmd == "reportcvar") { // old system
 179                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
 180                 {
 181                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 182                         tokens = tokenize_console(s);
 183                 }
 184                 GetCvars(1);
 185 #ifdef UID
 186         } else if(cmd == "uid") {
 187                 if not(self.uid)
 188                 {
 189                         self.uid = strzone(argv(1));
 190                         self.uid_kicktime = 0;
 191                         print("Client ", etos(self), " has UID ", self.uid, "\n");
 192                         Ban_MaybeEnforceBan(self);
 193                 }
 194 #endif
 195         } else if(cmd == "sentcvar") { // new system
 196                 if(tokens == 2) // undefined cvar: use the default value on the server then
 197                 {
 198                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 199                         tokens = tokenize_console(s);
 200                 }
 201                 GetCvars(1);
 202         } else if(cmd == "spectate") {
 203                 if(cmd_floodcheck())
 204                         return;
 205                 if not(self.flags & FL_CLIENT)
 206                         return;
 207                 if(g_arena)
 208                         return;
 209                 if(g_lms)
 210                 {
 211                         if(self.lms_spectate_warning)
 212                         {
 213                                 // mark player as spectator
 214                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 215                         }
 216                         else
 217                         {
 218                                 self.lms_spectate_warning = 1;
 219                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 220                                 return;
 221                         }
 222                 }
 223                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 224                         if(self.flagcarried)
 225                                 DropFlag(self.flagcarried, world, world);
 226                         if(self.ballcarried)
 227                                 DropBall(self.ballcarried, self.origin, self.velocity);
 228                         WaypointSprite_PlayerDead();
 229                         self.classname = "observer";
 230                         if(g_ca)
 231                                 self.caplayer = 0;
 232                         if(blockSpectators)
 233                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 234                         PutClientInServer();
 235                 }
 236         } else if(cmd == "join") {
 237                 if not(self.flags & FL_CLIENT)
 238                         return;
 239                 if(!g_arena)
 240                 if (self.classname != "player" && !lockteams)
 241                 {
 242                         if(isJoinAllowed()) {
 243                                 self.classname = "player";
 244                                 if(g_ca)
 245                                         self.caplayer = 1;
 246                                 PlayerScore_Clear(self);
 247                                 bprint ("^4", self.netname, "^4 is playing now\n");
 248                                 self.stat_count = WEP_LAST;
 249                                 PutClientInServer();
 250                                 if(cvar("g_campaign"))
 251                                         campaign_bots_may_start = 1;
 252                         }
 253                         else {
 254                                 //player may not join because of g_maxplayers is set
 255                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 256                         }
 257                 }
 258         } else if( cmd == "selectteam" ) {
 259                 if not(self.flags & FL_CLIENT)
 260                         return;
 261                 if( !teams_matter ) {
 262                         sprint( self, "selecteam can only be used in teamgames\n");
 263                 } else if(cvar("g_campaign")) {
 264                         //JoinBestTeam(self, 0);
 265                 } else if(lockteams) {
 266                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 267                 } else if( argv(1) == "red" ) {
 268                         DoTeamChange(COLOR_TEAM1);
 269                 } else if( argv(1) == "blue" ) {
 270                         DoTeamChange(COLOR_TEAM2);
 271                 } else if( argv(1) == "yellow" ) {
 272                         DoTeamChange(COLOR_TEAM3);
 273                 } else if( argv(1) == "pink" ) {
 274                         DoTeamChange(COLOR_TEAM4);
 275                 } else if( argv(1) == "auto" ) {
 276                         DoTeamChange(-1);
 277                 } else {
 278                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 279                 }
 280         } else if(cmd == "ready") {
 281                 if not(self.flags & FL_CLIENT)
 282                         return;
 283
 284                 if((inWarmupStage && 0 >= g_warmup_limit) // with unlimited warmup players have to be able to restart
 285                    || cvar("sv_ready_restart") || g_race_qualifying == 2)
 286                 {
 287                         if(!readyrestart_happened || cvar("sv_ready_restart_repeatable"))
 288                         {
 289                                 if (self.ready) // toggle
 290                                 {
 291                                         self.ready = FALSE;
 292                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 293                                 }
 294                                 else
 295                                 {
 296                                         self.ready = TRUE;
 297                                         bprint(self.netname, "^2 is ready\n");
 298                                 }
 299
 300                                 // cannot reset the game while a timeout is active!
 301                                 if(!timeoutStatus)
 302                                         ReadyCount();
 303                         } else {
 304                                 sprint(self, "^1Game has already been restarted\n");
 305                         }
 306                 }
 307         } else if(cmd == "maplist") {
 308                 sprint(self, maplist_reply);
 309         } else if(cmd == "lsmaps") {
 310                 sprint(self, lsmaps_reply);
 311         } else if(cmd == "lsnewmaps") {
 312                 sprint(self, lsnewmaps_reply);
 313         } else if(cmd == "records") {
 314                 for(i = 0; i < 10; ++i)
 315                         sprint(self, records_reply[i]);
 316         } else if(cmd == "rankings") {
 317                 sprint(self, rankings_reply);
 318         } else if(cmd == "voice") {
 319                 if(tokens >= 3)
 320                         VoiceMessage(argv(1), substring(s, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 321                 else
 322                         VoiceMessage(argv(1), "");
 323         } else if(cmd == "say") {
 324                 if(tokens >= 2)
 325                         Say(self, FALSE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 326                 //clientcommand(self, formatmessage(s));
 327         } else if(cmd == "say_team") {
 328                 if(tokens >= 2)
 329                         Say(self, TRUE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 330                 //clientcommand(self, formatmessage(s));
 331         } else if(cmd == "tell") {
 332                 e = GetCommandPlayerSlotTargetFromTokenizedCommand(tokens, 1);
 333                 if(e && tokens > ParseCommandPlayerSlotTarget_firsttoken)
 334                 {
 335                         Say(self, FALSE, e, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)), TRUE);
 336                 }
 337                 else
 338                 {
 339                         if(tokens > ParseCommandPlayerSlotTarget_firsttoken)
 340                                 trigger_magicear_processmessage_forallears(self, -1, world, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)));
 341                         sprint(self, "ERROR: usage: tell # playerid text...\n");
 342                 }
 343                 //clientcommand(self, formatmessage(s));
 344         } else if(cmd == "info") {
 345                 cmd = cvar_string_builtin(strcat("sv_info_", argv(1))); // This needed fixed for the cvar check
 346                 if(cmd == "")
 347                         sprint(self, "ERROR: unsupported info command\n");
 348                 else
 349                         wordwrap_sprint(cmd, 1111);
 350         } else if(cmd == "suggestmap") {
 351                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 352         } else if(cmd == "timeout") {
 353                 if not(self.flags & FL_CLIENT)
 354                         return;
 355                 if(cvar("sv_timeout")) {
 356                         if(self.classname == "player") {
 357                                 if(votecalled)
 358                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 359                                 else
 360                                         evaluateTimeout();
 361                         }
 362                         else
 363                                 sprint(self, "^7Error: only players can call a timeout!\n");
 364                 }
 365         } else if(cmd == "timein") {
 366                 if not(self.flags & FL_CLIENT)
 367                         return;
 368                 if(cvar("sv_timeout")) {
 369                         evaluateTimein();
 370                 }
 371         } else if(cmd == "teamstatus") {
 372                 Score_NicePrint(self);
 373         } else if(cmd == "cvar_changes") {
 374                 sprint(self, cvar_changes);
 375         } else if(CheatCommand(tokens)) {
 376         } else {
 377                 //if(ctf_clientcommand())
 378                 //      return;
 379                 // grep for Cmd_AddCommand_WithClientCommand to find them all
 380                 if(cmd != "status")
 381                 //if(cmd != "say") // handled above
 382                 //if(cmd != "say_team") // handled above
 383                 if(cmd != "kill")
 384                 if(cmd != "pause")
 385                 if(cmd != "ping")
 386                 if(cmd != "name")
 387                 if(cmd != "color")
 388                 if(cmd != "rate")
 389                 if(cmd != "pmodel")
 390                 if(cmd != "playermodel")
 391                 if(cmd != "playerskin")
 392                 if(cmd != "prespawn")
 393                 if(cmd != "spawn")
 394                 if(cmd != "begin")
 395                 if(cmd != "pings")
 396                 if(cmd != "sv_startdownload")
 397                 if(cmd != "download")
 398                 {
 399                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 400                         return;
 401                 }
 402
 403                 if(self.jointime > 0 && time > self.jointime + 10 && time > self.nickspamtime) // allow any changes in the first 10 seconds since joining
 404                 if(cmd == "name" || cmd == "playermodel") // TODO also playerskin and color?
 405                 {
 406                         if(self.nickspamtime == 0 || time > self.nickspamtime + cvar("g_nick_flood_timeout"))
 407                                 // good, no serious flood
 408                                 self.nickspamcount = 1;
 409                         else
 410                                 self.nickspamcount += 1;
 411                         self.nickspamtime = time + cvar("g_nick_flood_penalty");
 412
 413                         if (timeoutStatus == 2) //when game is paused, no flood protection
 414                                 self.nickspamcount = self.nickspamtime = 0;
 415                 }
 416
 417                 clientcommand(self,s);
 418         }
 419 }
 420
 421 void ReadyRestartForce()
 422 {
 423         local entity e;
 424
 425         bprint("^1Server is restarting...\n");
 426
 427         VoteReset();
 428
 429         // clear overtime
 430         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) {
 431                 //we have to decrease timelimit to its original value again!!
 432                 float newTL;
 433                 newTL = cvar("timelimit");
 434                 newTL -= checkrules_overtimesadded * cvar("timelimit_overtime");
 435                 cvar_set("timelimit", ftos(newTL));
 436         }
 437
 438         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 439
 440
 441         readyrestart_happened = 1;
 442         game_starttime = time;
 443         if(!g_ca)
 444                 game_starttime += RESTART_COUNTDOWN;
 445         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 446
 447         inWarmupStage = 0; //once the game is restarted the game is in match stage
 448
 449         //reset the .ready status of all players (also spectators)
 450         FOR_EACH_CLIENTSLOT(e)
 451                 e.ready = 0;
 452         readycount = 0;
 453         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 454
 455         if(cvar("teamplay_lockonrestart") && teams_matter) {
 456                 lockteams = 1;
 457                 bprint("^1The teams are now locked.\n");
 458         }
 459
 460         //initiate the restart-countdown-announcer entity
 461         if(cvar("sv_ready_restart_after_countdown"))
 462         {
 463                 restartTimer = spawn();
 464                 restartTimer.think = restartTimer_Think;
 465                 restartTimer.nextthink = game_starttime;
 466         }
 467
 468         //after a restart every players number of allowed timeouts gets reset, too
 469         if(cvar("sv_timeout"))
 470         {
 471                 FOR_EACH_REALPLAYER(e)
 472                         e.allowedTimeouts = cvar("sv_timeout_number");
 473         }
 474
 475         //reset map immediately if this cvar is not set
 476         if (!cvar("sv_ready_restart_after_countdown"))
 477                 reset_map(TRUE);
 478
 479         if(cvar("sv_eventlog"))
 480                 GameLogEcho(":restart");
 481 }
 482
 483 void ReadyRestart()
 484 {
 485         // no arena, assault support yet...
 486         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 487                 localcmd("restart\n");
 488         else
 489                 localcmd("\nsv_hook_gamerestart\n");
 490
 491         ReadyRestartForce();
 492
 493         // reset ALL scores, but only do that at the beginning
 494         //of the countdown if sv_ready_restart_after_countdown is off!
 495         //Otherwise scores could be manipulated during the countdown!
 496         if (!cvar("sv_ready_restart_after_countdown"))
 497                 Score_ClearAll();
 498 }
 499
 500 /**
 501  * Counts how many players are ready. If not enough players are ready, the function
 502  * does nothing. If all players are ready, the timelimit will be extended and the
 503  * restart_countdown variable is set to allow other functions like PlayerPostThink
 504  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 505  * is not set the map will be resetted.
 506  *
 507  * Function is called after the server receives a 'ready' sign from a player.
 508  */
 509 void ReadyCount()
 510 {
 511         local entity e;
 512         local float r, p;
 513
 514         r = p = 0;
 515
 516         FOR_EACH_REALPLAYER(e)
 517         {
 518                 p += 1;
 519                 if(e.ready)
 520                         r += 1;
 521         }
 522
 523         readycount = r;
 524
 525         Nagger_ReadyCounted();
 526
 527         if(r) // at least one is ready
 528         if(r == p) // and, everyone is ready
 529                 ReadyRestart();
 530 }
 531
 532 /**
 533  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 534  * is set)
 535  */
 536 void restartTimer_Think() {
 537         restart_mapalreadyrestarted = 1;
 538         reset_map(TRUE);
 539         Score_ClearAll();
 540         remove(self);
 541         return;
 542 }
 543
 544 /**
 545  * Checks whether the player who calls the timeout is allowed to do so.
 546  * If so, it initializes the timeout countdown. It also checks whether another
 547  * timeout was already running at this time and reacts correspondingly.
 548  *
 549  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 550  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 551  *
 552  * This function is called when a player issues the calltimeout command.
 553  */
 554 void evaluateTimeout() {
 555         if (inWarmupStage && !g_warmup_allow_timeout)
 556                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 557         if (time < game_starttime )
 558                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 559         if (timeoutStatus != 2) {
 560                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 561                 if (cvar("timelimit")) {
 562                         //a timelimit was used
 563                         local float myTl;
 564                         myTl = cvar("timelimit");
 565
 566                         local float lastPossibleTimeout;
 567                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 568
 569                         if (lastPossibleTimeout < time - game_starttime)
 570                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 571                 }
 572         }
 573         //player may not call a timeout if he has no calls left
 574         if (self.allowedTimeouts < 1)
 575                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 576         //now all required checks are passed
 577         self.allowedTimeouts -= 1;
 578         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 579         remainingTimeoutTime = cvar("sv_timeout_length");
 580         remainingLeadTime = cvar("sv_timeout_leadtime");
 581         timeoutInitiator = self;
 582         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 583                 timeoutStatus = 1;
 584                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 585                 timeoutHandler = spawn();
 586                 timeoutHandler.think = timeoutHandler_Think;
 587         }
 588         timeoutHandler.nextthink = time; //always let the entity think asap
 589
 590         //inform all connected clients about the timeout call
 591         Announce("timeoutcalled");
 592 }
 593
 594 /**
 595  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 596  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 597  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 598  * value of the cvar sv_timeout_resumetime.
 599  *
 600  * This function is called when a player issues the resumegame command.
 601  */
 602 void evaluateTimein() {
 603         if (!timeoutStatus)
 604                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 605         if (self != timeoutInitiator)
 606                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 607         if (timeoutStatus == 1) {
 608                 remainingTimeoutTime = timeoutStatus = 0;
 609                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 610                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 611         }
 612         else if (timeoutStatus == 2) {
 613                 //only shorten the remainingTimeoutTime if it makes sense
 614                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 615                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 616                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 617                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 618                 }
 619                 else
 620                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 621
 622         }
 623 }