1c8b59facee90ba1228724239a499e5c4961d243
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / clientcommands.qc
1 entity nagger;
2 float readycount;
3
4 float Nagger_SendEntity(entity to, float sendflags)
5 {
6         float nags, i, f, b;
7         entity e;
8         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
9
10         // bits:
11         //   1 = ready
12         //   2 = player needs to ready up
13         //   4 = vote
14         //   8 = player needs to vote
15         //  16 = warmup
16         // sendflags:
17         //  64 = vote counts
18         // 128 = vote string
19
20         nags = 0;
21         if(readycount)
22         {
23                 nags |= 1;
24                 if(to.ready == 0)
25                         nags |= 2;
26         }
27         if(votecalled)
28         {
29                 nags |= 4;
30                 if(to.vote_vote == 0)
31                         nags |= 8;
32         }
33         if(inWarmupStage)
34                 nags |= 16;
35
36         if(sendflags & 64)
37                 nags |= 64;
38
39         if(sendflags & 128)
40                 nags |= 128;
41
42         if(!(nags & 4)) // no vote called? send no string
43                 nags &~= (64 | 128);
44
45         WriteByte(MSG_ENTITY, nags);
46
47         if(nags & 64)
48         {
49                 WriteByte(MSG_ENTITY, vote_yescount);
50                 WriteByte(MSG_ENTITY, vote_nocount);
51                 WriteByte(MSG_ENTITY, vote_needed_absolute);
52                 WriteChar(MSG_ENTITY, to.vote_vote);
53         }
54
55         if(nags & 128)
56                 WriteString(MSG_ENTITY, votecalledvote_display);
57
58         if(nags & 1)
59         {
60                 for(i = 1; i <= maxclients; i += 8)
61                 {
62                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
63                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
64                                         f |= b;
65                         WriteByte(MSG_ENTITY, f);
66                 }
67         }
68
69         return TRUE;
70 }
71 void Nagger_Init()
72 {
73         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
74 }
75 void Nagger_VoteChanged()
76 {
77         if(nagger)
78                 nagger.SendFlags |= 128;
79 }
80 void Nagger_VoteCountChanged()
81 {
82         if(nagger)
83                 nagger.SendFlags |= 64;
84 }
85 void Nagger_ReadyCounted()
86 {
87         if(nagger)
88                 nagger.SendFlags |= 1;
89 }
90
91 void ReadyCount();
92 string MapVote_Suggest(string m);
93
94 entity GetPlayer(string name)
95 {
96         float num;
97         entity e;
98         string ns;
99
100         if(substring(name, 0, 1) == "#") {
101                 num = stof(substring(name, 1, 999));
102                 if(num >= 1 && num <= maxclients) {
103                         for((e = world); num > 0; --num, (e = nextent(e)))
104                                 ;
105                         //if(clienttype(e) == CLIENTTYPE_REAL)
106                         if(e.classname == "player")
107                                 return e;
108                 }
109         } else {
110                 ns = strdecolorize(name);
111                 FOR_EACH_REALPLAYER(e) {
112                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
113                                 return e;
114                         }
115                 }
116         }
117         return world;
118 }
119
120 //float ctf_clientcommand();
121 float readyrestart_happened;
122 .float lms_spectate_warning;
123 void spawnfunc_func_breakable();
124
125 .float cmd_floodtime;
126 .float cmd_floodcount;
127 float cmd_floodcheck()
128 {
129         if (timeoutStatus != 2)
130         {
131                 if(time == self.cmd_floodtime)
132                 {
133                         self.cmd_floodcount += 1;
134                         if(self.cmd_floodcount > 8)
135                                 return TRUE;
136                 }
137                 else
138                 {
139                         self.cmd_floodtime = time;
140                         self.cmd_floodcount = 1;
141                 }
142         }
143         return FALSE;
144 }
145
146 .float checkfail;
147 void SV_ParseClientCommand(string s) {
148         float i;
149         entity e;
150
151         cmd_argc = tokenize_console(s);
152         cmd_string = s;
153         cmd_name = strtolower(argv(0));
154         if(cmd_name != "reportcvar")
155         if(cmd_name != "sentcvar")
156         if(cmd_name != "pause")
157         if(cmd_name != "prespawn")
158         if(cmd_name != "spawn")
159         if(cmd_name != "begin")
160         {
161                 if(cmd_floodcheck())
162                         return;
163         }
164
165         if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
166                 return; // already handled
167         
168         if(GameCommand_Vote(s, self)) {
169                 return;
170         } else if(GameCommand_MapVote(argv(0))) {
171                 return;
172         } else if(cmd_name == "checkfail") {
173                 print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
174                 self.checkfail = 1;
175         } else if(cmd_name == "autoswitch") {
176                 // be backwards compatible with older clients (enabled)
177                 self.autoswitch = ("0" != argv(1));
178                 string autoswitchmsg;
179                 if (self.autoswitch) {
180                         autoswitchmsg = "on";
181                 } else {
182                         autoswitchmsg = "off";
183                 }
184                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
185         } else if(cmd_name == "clientversion") {
186                 if not(self.flags & FL_CLIENT)
187                         return;
188                 if (argv(1) == "$gameversion") {
189                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.xonotic.com)^8";
190                         // either that or someone wants to be funny
191                         self.version = 1;
192                 } else {
193                         self.version = stof(argv(1));
194                 }
195                 if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
196                 {
197                         self.version_mismatch = 1;
198                         ClientKill_TeamChange(-2); // observe
199                 } else if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force) {
200                         //JoinBestTeam(self, FALSE, TRUE);
201                 } else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0)) {
202                         self.classname = "observer";
203                         stuffcmd(self,"menu_showteamselect\n");
204                 }
205         } else if(cmd_name == "reportcvar") { // old system
206                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
207                 {
208                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
209                         cmd_argc = tokenize_console(s);
210                 }
211                 GetCvars(1);
212         } else if(cmd_name == "sentcvar") { // new system
213                 if(cmd_argc == 2) // undefined cvar: use the default value on the server then
214                 {
215                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
216                         cmd_argc = tokenize_console(s);
217                 }
218                 GetCvars(1);
219         } else if(cmd_name == "spectate") {
220                 if(cmd_floodcheck())
221                         return;
222                 if not(self.flags & FL_CLIENT)
223                         return;
224                 if(g_arena)
225                         return;
226                 if(g_lms)
227                 {
228                         if(self.lms_spectate_warning)
229                         {
230                                 // mark player as spectator
231                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
232                         }
233                         else
234                         {
235                                 self.lms_spectate_warning = 1;
236                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
237                                 return;
238                         }
239                 }
240                 if(self.classname == "player" && autocvar_sv_spectate == 1) {
241                         ClientKill_TeamChange(-2); // observe
242                 }
243                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer")) {
244                         // in CA, allow a dead player to move to spectatators (without that, caplayer!=0 will be moved back to the player list)
245                         sprint(self, "WARNING: you will spectate in the next round.\n");
246                         self.caplayer = 0;
247                 }
248         } else if(cmd_name == "join") {
249                 if not(self.flags & FL_CLIENT)
250                         return;
251                 if(!g_arena)
252                 if (self.classname != "player" && !lockteams)
253                 {
254                         if(nJoinAllowed(1)) {
255                                 self.classname = "player";
256                                 if(g_ca)
257                                         self.caplayer = 1;
258                                 PlayerScore_Clear(self);
259                                 bprint ("^4", self.netname, "^4 is playing now\n");
260                                 PutClientInServer();
261                                 if(autocvar_g_campaign)
262                                         campaign_bots_may_start = 1;
263                         }
264                         else {
265                                 //player may not join because of g_maxplayers is set
266                                 centerprint(self, PREVENT_JOIN_TEXT);
267                         }
268                 }
269         } else if( cmd_name == "selectteam" ) {
270                 if not(self.flags & FL_CLIENT)
271                         return;
272                 if( !teamplay ) {
273                         sprint( self, "selectteam can only be used in teamgames\n");
274                 } else if(autocvar_g_campaign) {
275                         //JoinBestTeam(self, 0);
276                 } else if(self.team_forced > 0) {
277                         sprint( self, "selectteam can not be used as your team is forced\n");
278                 } else if(lockteams) {
279                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
280                 } else if( argv(1) == "red" ) {
281                         if(self.team == COLOR_TEAM1 && self.deadflag == DEAD_NO)
282                                 sprint( self, "^7You already are on that team.\n");
283                         else if (self.wasplayer && autocvar_g_changeteam_banned)
284                                 sprint( self, "^1You cannot change team, forbidden by the server.\n");
285                         else
286                                 ClientKill_TeamChange(COLOR_TEAM1);
287                 } else if( argv(1) == "blue" ) {
288                         if(self.team == COLOR_TEAM2 && self.deadflag == DEAD_NO)
289                                 sprint( self, "^7You already are on that team.\n");
290                         else if (self.wasplayer && autocvar_g_changeteam_banned)
291                                 sprint( self, "^1You cannot change team, forbidden by the server.\n");
292                         else
293                                 ClientKill_TeamChange(COLOR_TEAM2);
294                 } else if( argv(1) == "yellow" ) {
295                         if(self.team == COLOR_TEAM3 && self.deadflag == DEAD_NO)
296                                 sprint( self, "^7You already are on that team.\n");
297                         else if (self.wasplayer && autocvar_g_changeteam_banned)
298                                 sprint( self, "^1You cannot change team, forbidden by the server.\n");
299                         else
300                                 ClientKill_TeamChange(COLOR_TEAM3);
301                 } else if( argv(1) == "pink" ) {
302                         if(self.team == COLOR_TEAM4 && self.deadflag == DEAD_NO)
303                                 sprint( self, "^7You already are on that team.\n");
304                         else if (self.wasplayer && autocvar_g_changeteam_banned)
305                                 sprint( self, "^1You cannot change team, forbidden by the server.\n");
306                         else
307                                 ClientKill_TeamChange(COLOR_TEAM4);
308                 } else if( argv(1) == "auto" ) {
309                         ClientKill_TeamChange(-1);
310                 } else {
311                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
312                 }
313         } else if(cmd_name == "ready") {
314                 if not(self.flags & FL_CLIENT)
315                         return;
316
317                 if((inWarmupStage)
318                    || autocvar_sv_ready_restart || g_race_qualifying == 2)
319                 {
320                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
321                         {
322                                 if (self.ready) // toggle
323                                 {
324                                         self.ready = FALSE;
325                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
326                                 }
327                                 else
328                                 {
329                                         self.ready = TRUE;
330                                         bprint(self.netname, "^2 is ready\n");
331                                 }
332
333                                 // cannot reset the game while a timeout is active!
334                                 if(!timeoutStatus)
335                                         ReadyCount();
336                         } else {
337                                 sprint(self, "^1Game has already been restarted\n");
338                         }
339                 }
340         } else if(cmd_name == "maplist") {
341                 sprint(self, maplist_reply);
342         } else if(cmd_name == "lsmaps") {
343                 sprint(self, lsmaps_reply);
344         } else if(cmd_name == "lsnewmaps") {
345                 sprint(self, lsnewmaps_reply);
346         } else if(cmd_name == "records") {
347                 for(i = 0; i < 10; ++i)
348                         sprint(self, records_reply[i]);
349         } else if(cmd_name == "ladder") {
350                 sprint(self, ladder_reply);
351         } else if(cmd_name == "rankings") {
352                 sprint(self, rankings_reply);
353         } else if(cmd_name == "voice") {
354                 if(cmd_argc >= 3)
355                         VoiceMessage(argv(1), substring(s, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
356                 else
357                         VoiceMessage(argv(1), "");
358         } else if(cmd_name == "say") {
359                 if(cmd_argc >= 2)
360                         Say(self, FALSE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
361                 //clientcommand(self, formatmessage(s));
362         } else if(cmd_name == "say_team") {
363                 if(cmd_argc >= 2)
364                         Say(self, TRUE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
365                 //clientcommand(self, formatmessage(s));
366         } else if(cmd_name == "tell") {
367                 e = GetCommandPlayerSlotTargetFromTokenizedCommand(cmd_argc, 1);
368                 if(e && cmd_argc > ParseCommandPlayerSlotTarget_firsttoken)
369                 {
370                         Say(self, FALSE, e, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)), TRUE);
371                 }
372                 else
373                 {
374                         if(cmd_argc > ParseCommandPlayerSlotTarget_firsttoken)
375                                 trigger_magicear_processmessage_forallears(self, -1, world, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)));
376                         sprint(self, "ERROR: usage: tell # playerid text...\n");
377                 }
378                 //clientcommand(self, formatmessage(s));
379         } else if(cmd_name == "info") {
380                 cmd_name = cvar_string_builtin(strcat("sv_info_", argv(1))); // This needed fixed for the cvar check
381                 if(cmd_name == "")
382                         sprint(self, "ERROR: unsupported info command\n");
383                 else
384                         wordwrap_sprint(cmd_name, 1111);
385         } else if(cmd_name == "suggestmap") {
386                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
387         } else if(cmd_name == "timeout") {
388                 if not(self.flags & FL_CLIENT)
389                         return;
390                 if(autocvar_sv_timeout) {
391                         if(self.classname == "player") {
392                                 if(votecalled)
393                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
394                                 else
395                                         evaluateTimeout();
396                         }
397                         else
398                                 sprint(self, "^7Error: only players can call a timeout!\n");
399                 }
400         } else if(cmd_name == "timein") {
401                 if not(self.flags & FL_CLIENT)
402                         return;
403                 if(autocvar_sv_timeout) {
404                         evaluateTimein();
405                 }
406         } else if(cmd_name == "teamstatus") {
407                 Score_NicePrint(self);
408         } else if(cmd_name == "cvar_changes") {
409                 sprint(self, cvar_changes);
410         } else if(cmd_name == "cvar_purechanges") {
411                 sprint(self, cvar_purechanges);
412         } else if(CheatCommand(cmd_argc)) {
413         } else {
414 #if 0
415                 //if(ctf_clientcommand())
416                 //      return;
417                 // grep for Cmd_AddCommand_WithClientCommand to find them all
418                 if(cmd_name != "status")
419                 //if(cmd_name != "say") // handled above
420                 //if(cmd_name != "say_team") // handled above
421                 if(cmd_name != "kill")
422                 if(cmd_name != "pause")
423                 if(cmd_name != "ping")
424                 if(cmd_name != "name")
425                 if(cmd_name != "color")
426                 if(cmd_name != "rate")
427                 if(cmd_name != "pmodel")
428                 if(cmd_name != "playermodel")
429                 if(cmd_name != "playerskin")
430                 if(cmd_name != "prespawn")
431                 if(cmd_name != "spawn")
432                 if(cmd_name != "begin")
433                 if(cmd_name != "pings")
434                 if(cmd_name != "sv_startdownload")
435                 if(cmd_name != "download")
436                 {
437                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
438                         return;
439                 }
440 #endif
441
442                 if(self.jointime > 0 && time > self.jointime + 10 && time > self.nickspamtime) // allow any changes in the first 10 seconds since joining
443                 if(cmd_name == "name" || cmd_name == "playermodel") // TODO also playerskin and color?
444                 {
445                         if(self.nickspamtime == 0 || time > self.nickspamtime + autocvar_g_nick_flood_timeout)
446                                 // good, no serious flood
447                                 self.nickspamcount = 1;
448                         else
449                                 self.nickspamcount += 1;
450                         self.nickspamtime = time + autocvar_g_nick_flood_penalty;
451
452                         if (timeoutStatus == 2) //when game is paused, no flood protection
453                                 self.nickspamcount = self.nickspamtime = 0;
454                 }
455
456                 clientcommand(self,s);
457         }
458 }
459
460 void ReadyRestartForce()
461 {
462         entity e;
463
464         bprint("^1Server is restarting...\n");
465
466         VoteReset();
467
468         // clear overtime
469         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) {
470                 //we have to decrease timelimit to its original value again!!
471                 float newTL;
472                 newTL = autocvar_timelimit;
473                 newTL -= checkrules_overtimesadded * autocvar_timelimit_overtime;
474                 cvar_set("timelimit", ftos(newTL));
475         }
476
477         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
478
479
480         readyrestart_happened = 1;
481         game_starttime = time;
482         if(!g_ca && !g_arena)
483                 game_starttime += RESTART_COUNTDOWN;
484         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
485
486         inWarmupStage = 0; //once the game is restarted the game is in match stage
487
488         //reset the .ready status of all players (also spectators)
489         FOR_EACH_CLIENTSLOT(e)
490                 e.ready = 0;
491         readycount = 0;
492         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
493
494         if(autocvar_teamplay_lockonrestart && teamplay) {
495                 lockteams = 1;
496                 bprint("^1The teams are now locked.\n");
497         }
498
499         //initiate the restart-countdown-announcer entity
500         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
501         {
502                 restartTimer = spawn();
503                 restartTimer.think = restartTimer_Think;
504                 restartTimer.nextthink = game_starttime;
505         }
506
507         //after a restart every players number of allowed timeouts gets reset, too
508         if(autocvar_sv_timeout)
509         {
510                 FOR_EACH_REALPLAYER(e)
511                         e.allowedTimeouts = autocvar_sv_timeout_number;
512         }
513
514         //reset map immediately if this cvar is not set
515         if (!autocvar_sv_ready_restart_after_countdown)
516                 reset_map(TRUE);
517
518         if(autocvar_sv_eventlog)
519                 GameLogEcho(":restart");
520 }
521
522 void ReadyRestart()
523 {
524         // no arena, assault support yet...
525         if(g_arena | g_assault | gameover | intermission_running | race_completing)
526                 localcmd("restart\n");
527         else
528                 localcmd("\nsv_hook_gamerestart\n");
529
530         ReadyRestartForce();
531
532         // reset ALL scores, but only do that at the beginning
533         //of the countdown if sv_ready_restart_after_countdown is off!
534         //Otherwise scores could be manipulated during the countdown!
535         if (!autocvar_sv_ready_restart_after_countdown)
536                 Score_ClearAll();
537 }
538
539 /**
540  * Counts how many players are ready. If not enough players are ready, the function
541  * does nothing. If all players are ready, the timelimit will be extended and the
542  * restart_countdown variable is set to allow other functions like PlayerPostThink
543  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
544  * is not set the map will be resetted.
545  *
546  * Function is called after the server receives a 'ready' sign from a player.
547  */
548 void ReadyCount()
549 {
550         entity e;
551         float r, p;
552
553         r = p = 0;
554
555         FOR_EACH_REALPLAYER(e)
556         {
557                 p += 1;
558                 if(e.ready)
559                         r += 1;
560         }
561
562         readycount = r;
563
564         Nagger_ReadyCounted();
565
566         if(r) // at least one is ready
567         if(r == p) // and, everyone is ready
568                 ReadyRestart();
569 }
570
571 /**
572  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
573  * is set)
574  */
575 void restartTimer_Think() {
576         restart_mapalreadyrestarted = 1;
577         reset_map(TRUE);
578         Score_ClearAll();
579         remove(self);
580         return;
581 }
582
583 /**
584  * Checks whether the player who calls the timeout is allowed to do so.
585  * If so, it initializes the timeout countdown. It also checks whether another
586  * timeout was already running at this time and reacts correspondingly.
587  *
588  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
589  *                          timeoutInitiator, timeoutStatus, timeoutHandler
590  *
591  * This function is called when a player issues the calltimeout command.
592  */
593 void evaluateTimeout() {
594         if (inWarmupStage && !g_warmup_allow_timeout)
595                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
596         if (time < game_starttime )
597                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
598         if (timeoutStatus != 2) {
599                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
600                 if (autocvar_timelimit) {
601                         //a timelimit was used
602                         float myTl;
603                         myTl = autocvar_timelimit;
604
605                         float lastPossibleTimeout;
606                         lastPossibleTimeout = (myTl*60) - autocvar_sv_timeout_leadtime - 1;
607
608                         if (lastPossibleTimeout < time - game_starttime)
609                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
610                 }
611         }
612         //player may not call a timeout if he has no calls left
613         if (self.allowedTimeouts < 1)
614                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
615         //now all required checks are passed
616         self.allowedTimeouts -= 1;
617         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
618         remainingTimeoutTime = autocvar_sv_timeout_length;
619         remainingLeadTime = autocvar_sv_timeout_leadtime;
620         timeoutInitiator = self;
621         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
622                 timeoutStatus = 1;
623                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
624                 timeoutHandler = spawn();
625                 timeoutHandler.think = timeoutHandler_Think;
626         }
627         timeoutHandler.nextthink = time; //always let the entity think asap
628
629         //inform all connected clients about the timeout call
630         Announce("timeoutcalled");
631 }
632
633 /**
634  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
635  * and the lead time for the timeout is still active, this countdown just will be aborted (the
636  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
637  * value of the cvar sv_timeout_resumetime.
638  *
639  * This function is called when a player issues the resumegame command.
640  */
641 void evaluateTimein() {
642         if (!timeoutStatus)
643                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
644         if (self != timeoutInitiator)
645                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
646         if (timeoutStatus == 1) {
647                 remainingTimeoutTime = timeoutStatus = 0;
648                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
649                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
650         }
651         else if (timeoutStatus == 2) {
652                 //only shorten the remainingTimeoutTime if it makes sense
653                 if( remainingTimeoutTime > (autocvar_sv_timeout_resumetime + 1) ) {
654                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
655                         remainingTimeoutTime = autocvar_sv_timeout_resumetime;
656                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
657                 }
658                 else
659                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
660
661         }
662 }