qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3
   4 float Nagger_SendEntity(entity to, float sendflags)
   5 {
   6         float nags, i, f, b;
   7         entity e;
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   9
  10         // bits:
  11         //   1 = ready
  12         //   2 = player needs to ready up
  13         //   4 = vote
  14         //   8 = player needs to vote
  15         //  16 = warmup
  16         // sendflags:
  17         //  64 = vote counts
  18         // 128 = vote string
  19
  20         nags = 0;
  21         if(readycount)
  22         {
  23                 nags |= 1;
  24                 if(to.ready == 0)
  25                         nags |= 2;
  26         }
  27         if(votecalled)
  28         {
  29                 nags |= 4;
  30                 if(to.vote_vote == 0)
  31                         nags |= 8;
  32         }
  33         if(inWarmupStage)
  34                 nags |= 16;
  35
  36         if(sendflags & 64)
  37                 nags |= 64;
  38
  39         if(sendflags & 128)
  40                 nags |= 128;
  41
  42         if(!(nags & 4)) // no vote called? send no string
  43                 nags &~= (64 | 128);
  44
  45         WriteByte(MSG_ENTITY, nags);
  46
  47         if(nags & 64)
  48         {
  49                 WriteByte(MSG_ENTITY, vote_yescount);
  50                 WriteByte(MSG_ENTITY, vote_nocount);
  51                 WriteByte(MSG_ENTITY, vote_needed_absolute);
  52                 WriteChar(MSG_ENTITY, to.vote_vote);
  53         }
  54
  55         if(nags & 128)
  56                 WriteString(MSG_ENTITY, votecalledvote_display);
  57
  58         if(nags & 1)
  59         {
  60                 for(i = 1; i <= maxclients; i += 8)
  61                 {
  62                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  63                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  64                                         f |= b;
  65                         WriteByte(MSG_ENTITY, f);
  66                 }
  67         }
  68
  69         return TRUE;
  70 }
  71 void Nagger_Init()
  72 {
  73         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  74 }
  75 void Nagger_VoteChanged()
  76 {
  77         if(nagger)
  78                 nagger.SendFlags |= 128;
  79 }
  80 void Nagger_VoteCountChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 64;
  84 }
  85 void Nagger_ReadyCounted()
  86 {
  87         if(nagger)
  88                 nagger.SendFlags |= 1;
  89 }
  90
  91 void ReadyCount();
  92 string MapVote_Suggest(string m);
  93
  94 entity GetPlayer(string name)
  95 {
  96         float num;
  97         entity e;
  98         string ns;
  99
 100         if(substring(name, 0, 1) == "#") {
 101                 num = stof(substring(name, 1, 999));
 102                 if(num >= 1 && num <= maxclients) {
 103                         for((e = world); num > 0; --num, (e = nextent(e)))
 104                                 ;
 105                         //if(clienttype(e) == CLIENTTYPE_REAL)
 106                         if(e.classname == "player")
 107                                 return e;
 108                 }
 109         } else {
 110                 ns = strdecolorize(name);
 111                 FOR_EACH_REALPLAYER(e) {
 112                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
 113                                 return e;
 114                         }
 115                 }
 116         }
 117         return world;
 118 }
 119
 120 //float ctf_clientcommand();
 121 float readyrestart_happened;
 122 .float lms_spectate_warning;
 123 void spawnfunc_func_breakable();
 124
 125 .float cmd_floodtime;
 126 .float cmd_floodcount;
 127 float cmd_floodcheck()
 128 {
 129         if (timeoutStatus != 2)
 130         {
 131                 if(time == self.cmd_floodtime)
 132                 {
 133                         self.cmd_floodcount += 1;
 134                         if(self.cmd_floodcount > 8)
 135                                 return TRUE;
 136                 }
 137                 else
 138                 {
 139                         self.cmd_floodtime = time;
 140                         self.cmd_floodcount = 1;
 141                 }
 142         }
 143         return FALSE;
 144 }
 145
 146 .float checkfail;
 147 void SV_ParseClientCommand(string s) {
 148         string cmd;
 149         float tokens;
 150         float i;
 151         entity e;
 152
 153         tokens = tokenize_console(s);
 154
 155         cmd = strtolower(argv(0));
 156         if(cmd != "reportcvar")
 157         if(cmd != "sentcvar")
 158         if(cmd != "pause")
 159         if(cmd != "prespawn")
 160         if(cmd != "spawn")
 161         if(cmd != "begin")
 162         {
 163                 if(cmd_floodcheck())
 164                         return;
 165         }
 166
 167         if(GameCommand_Vote(s, self)) {
 168                 return;
 169         } else if(GameCommand_MapVote(argv(0))) {
 170                 return;
 171         } else if(cmd == "checkfail") {
 172                 print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
 173                 self.checkfail = 1;
 174         } else if(cmd == "autoswitch") {
 175                 // be backwards compatible with older clients (enabled)
 176                 self.autoswitch = ("0" != argv(1));
 177                 local string autoswitchmsg;
 178                 if (self.autoswitch) {
 179                         autoswitchmsg = "on";
 180                 } else {
 181                         autoswitchmsg = "off";
 182                 }
 183                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 184         } else if(cmd == "clientversion") {
 185                 if not(self.flags & FL_CLIENT)
 186                         return;
 187                 if (argv(1) == "$gameversion") {
 188                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.xonotic.com)^8";
 189                         // either that or someone wants to be funny
 190                         self.version = 1;
 191                 } else {
 192                         self.version = stof(argv(1));
 193                 }
 194                 if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
 195                 {
 196                         self.version_mismatch = 1;
 197                         ClientKill_TeamChange(-2); // observe
 198                 } else if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force) {
 199                         //JoinBestTeam(self, FALSE, TRUE);
 200                 } else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0)) {
 201                         self.classname = "observer";
 202                         stuffcmd(self,"menu_showteamselect\n");
 203                 }
 204         } else if(cmd == "reportcvar") { // old system
 205                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
 206                 {
 207                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 208                         tokens = tokenize_console(s);
 209                 }
 210                 GetCvars(1);
 211         } else if(cmd == "sentcvar") { // new system
 212                 if(tokens == 2) // undefined cvar: use the default value on the server then
 213                 {
 214                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 215                         tokens = tokenize_console(s);
 216                 }
 217                 GetCvars(1);
 218         } else if(cmd == "spectate") {
 219                 if(cmd_floodcheck())
 220                         return;
 221                 if not(self.flags & FL_CLIENT)
 222                         return;
 223                 if(g_arena)
 224                         return;
 225                 if(g_lms)
 226                 {
 227                         if(self.lms_spectate_warning)
 228                         {
 229                                 // mark player as spectator
 230                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 231                         }
 232                         else
 233                         {
 234                                 self.lms_spectate_warning = 1;
 235                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 236                                 return;
 237                         }
 238                 }
 239                 if(self.classname == "player" && autocvar_sv_spectate == 1) {
 240                         ClientKill_TeamChange(-2); // observe
 241                 }
 242         } else if(cmd == "join") {
 243                 if not(self.flags & FL_CLIENT)
 244                         return;
 245                 if(!g_arena)
 246                 if (self.classname != "player" && !lockteams)
 247                 {
 248                         if(nJoinAllowed(1)) {
 249                                 self.classname = "player";
 250                                 if(g_ca)
 251                                         self.caplayer = 1;
 252                                 PlayerScore_Clear(self);
 253                                 bprint ("^4", self.netname, "^4 is playing now\n");
 254                                 PutClientInServer();
 255                                 if(autocvar_g_campaign)
 256                                         campaign_bots_may_start = 1;
 257                         }
 258                         else {
 259                                 //player may not join because of g_maxplayers is set
 260                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 261                         }
 262                 }
 263         } else if( cmd == "selectteam" ) {
 264                 if not(self.flags & FL_CLIENT)
 265                         return;
 266                 if( !teamplay ) {
 267                         sprint( self, "selectteam can only be used in teamgames\n");
 268                 } else if(autocvar_g_campaign) {
 269                         //JoinBestTeam(self, 0);
 270                 } else if(self.team_forced > 0) {
 271                         sprint( self, "selectteam can not be used as your team is forced\n");
 272                 } else if(lockteams) {
 273                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 274                 } else if( argv(1) == "red" ) {
 275                         ClientKill_TeamChange(COLOR_TEAM1);
 276                 } else if( argv(1) == "blue" ) {
 277                         ClientKill_TeamChange(COLOR_TEAM2);
 278                 } else if( argv(1) == "yellow" ) {
 279                         ClientKill_TeamChange(COLOR_TEAM3);
 280                 } else if( argv(1) == "pink" ) {
 281                         ClientKill_TeamChange(COLOR_TEAM4);
 282                 } else if( argv(1) == "auto" ) {
 283                         ClientKill_TeamChange(-1);
 284                 } else {
 285                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 286                 }
 287         } else if(cmd == "ready") {
 288                 if not(self.flags & FL_CLIENT)
 289                         return;
 290
 291                 if((inWarmupStage)
 292                    || autocvar_sv_ready_restart || g_race_qualifying == 2)
 293                 {
 294                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 295                         {
 296                                 if (self.ready) // toggle
 297                                 {
 298                                         self.ready = FALSE;
 299                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 300                                 }
 301                                 else
 302                                 {
 303                                         self.ready = TRUE;
 304                                         bprint(self.netname, "^2 is ready\n");
 305                                 }
 306
 307                                 // cannot reset the game while a timeout is active!
 308                                 if(!timeoutStatus)
 309                                         ReadyCount();
 310                         } else {
 311                                 sprint(self, "^1Game has already been restarted\n");
 312                         }
 313                 }
 314         } else if(cmd == "maplist") {
 315                 sprint(self, maplist_reply);
 316         } else if(cmd == "lsmaps") {
 317                 sprint(self, lsmaps_reply);
 318         } else if(cmd == "lsnewmaps") {
 319                 sprint(self, lsnewmaps_reply);
 320         } else if(cmd == "records") {
 321                 for(i = 0; i < 10; ++i)
 322                         sprint(self, records_reply[i]);
 323         } else if(cmd == "ladder") {
 324                 sprint(self, ladder_reply);
 325         } else if(cmd == "rankings") {
 326                 sprint(self, rankings_reply);
 327         } else if(cmd == "voice") {
 328                 if(tokens >= 3)
 329                         VoiceMessage(argv(1), substring(s, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 330                 else
 331                         VoiceMessage(argv(1), "");
 332         } else if(cmd == "say") {
 333                 if(tokens >= 2)
 334                         Say(self, FALSE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 335                 //clientcommand(self, formatmessage(s));
 336         } else if(cmd == "say_team") {
 337                 if(tokens >= 2)
 338                         Say(self, TRUE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 339                 //clientcommand(self, formatmessage(s));
 340         } else if(cmd == "tell") {
 341                 e = GetCommandPlayerSlotTargetFromTokenizedCommand(tokens, 1);
 342                 if(e && tokens > ParseCommandPlayerSlotTarget_firsttoken)
 343                 {
 344                         Say(self, FALSE, e, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)), TRUE);
 345                 }
 346                 else
 347                 {
 348                         if(tokens > ParseCommandPlayerSlotTarget_firsttoken)
 349                                 trigger_magicear_processmessage_forallears(self, -1, world, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)));
 350                         sprint(self, "ERROR: usage: tell # playerid text...\n");
 351                 }
 352                 //clientcommand(self, formatmessage(s));
 353         } else if(cmd == "info") {
 354                 cmd = cvar_string_builtin(strcat("sv_info_", argv(1))); // This needed fixed for the cvar check
 355                 if(cmd == "")
 356                         sprint(self, "ERROR: unsupported info command\n");
 357                 else
 358                         wordwrap_sprint(cmd, 1111);
 359         } else if(cmd == "suggestmap") {
 360                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 361         } else if(cmd == "timeout") {
 362                 if not(self.flags & FL_CLIENT)
 363                         return;
 364                 if(autocvar_sv_timeout) {
 365                         if(self.classname == "player") {
 366                                 if(votecalled)
 367                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 368                                 else
 369                                         evaluateTimeout();
 370                         }
 371                         else
 372                                 sprint(self, "^7Error: only players can call a timeout!\n");
 373                 }
 374         } else if(cmd == "timein") {
 375                 if not(self.flags & FL_CLIENT)
 376                         return;
 377                 if(autocvar_sv_timeout) {
 378                         evaluateTimein();
 379                 }
 380         } else if(cmd == "teamstatus") {
 381                 Score_NicePrint(self);
 382         } else if(cmd == "cvar_changes") {
 383                 sprint(self, cvar_changes);
 384         } else if(cmd == "cvar_purechanges") {
 385                 sprint(self, cvar_purechanges);
 386         } else if(CheatCommand(tokens)) {
 387         } else {
 388 #if 0
 389                 //if(ctf_clientcommand())
 390                 //      return;
 391                 // grep for Cmd_AddCommand_WithClientCommand to find them all
 392                 if(cmd != "status")
 393                 //if(cmd != "say") // handled above
 394                 //if(cmd != "say_team") // handled above
 395                 if(cmd != "kill")
 396                 if(cmd != "pause")
 397                 if(cmd != "ping")
 398                 if(cmd != "name")
 399                 if(cmd != "color")
 400                 if(cmd != "rate")
 401                 if(cmd != "pmodel")
 402                 if(cmd != "playermodel")
 403                 if(cmd != "playerskin")
 404                 if(cmd != "prespawn")
 405                 if(cmd != "spawn")
 406                 if(cmd != "begin")
 407                 if(cmd != "pings")
 408                 if(cmd != "sv_startdownload")
 409                 if(cmd != "download")
 410                 {
 411                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 412                         return;
 413                 }
 414 #endif
 415
 416                 if(self.jointime > 0 && time > self.jointime + 10 && time > self.nickspamtime) // allow any changes in the first 10 seconds since joining
 417                 if(cmd == "name" || cmd == "playermodel") // TODO also playerskin and color?
 418                 {
 419                         if(self.nickspamtime == 0 || time > self.nickspamtime + autocvar_g_nick_flood_timeout)
 420                                 // good, no serious flood
 421                                 self.nickspamcount = 1;
 422                         else
 423                                 self.nickspamcount += 1;
 424                         self.nickspamtime = time + autocvar_g_nick_flood_penalty;
 425
 426                         if (timeoutStatus == 2) //when game is paused, no flood protection
 427                                 self.nickspamcount = self.nickspamtime = 0;
 428                 }
 429
 430                 clientcommand(self,s);
 431         }
 432 }
 433
 434 void ReadyRestartForce()
 435 {
 436         local entity e;
 437
 438         bprint("^1Server is restarting...\n");
 439
 440         VoteReset();
 441
 442         // clear overtime
 443         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) {
 444                 //we have to decrease timelimit to its original value again!!
 445                 float newTL;
 446                 newTL = autocvar_timelimit;
 447                 newTL -= checkrules_overtimesadded * autocvar_timelimit_overtime;
 448                 cvar_set("timelimit", ftos(newTL));
 449         }
 450
 451         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 452
 453
 454         readyrestart_happened = 1;
 455         game_starttime = time;
 456         if(!g_ca && !g_arena)
 457                 game_starttime += RESTART_COUNTDOWN;
 458         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 459
 460         inWarmupStage = 0; //once the game is restarted the game is in match stage
 461
 462         //reset the .ready status of all players (also spectators)
 463         FOR_EACH_CLIENTSLOT(e)
 464                 e.ready = 0;
 465         readycount = 0;
 466         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 467
 468         if(autocvar_teamplay_lockonrestart && teamplay) {
 469                 lockteams = 1;
 470                 bprint("^1The teams are now locked.\n");
 471         }
 472
 473         //initiate the restart-countdown-announcer entity
 474         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 475         {
 476                 restartTimer = spawn();
 477                 restartTimer.think = restartTimer_Think;
 478                 restartTimer.nextthink = game_starttime;
 479         }
 480
 481         //after a restart every players number of allowed timeouts gets reset, too
 482         if(autocvar_sv_timeout)
 483         {
 484                 FOR_EACH_REALPLAYER(e)
 485                         e.allowedTimeouts = autocvar_sv_timeout_number;
 486         }
 487
 488         //reset map immediately if this cvar is not set
 489         if (!autocvar_sv_ready_restart_after_countdown)
 490                 reset_map(TRUE);
 491
 492         if(autocvar_sv_eventlog)
 493                 GameLogEcho(":restart");
 494 }
 495
 496 void ReadyRestart()
 497 {
 498         // no arena, assault support yet...
 499         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 500                 localcmd("restart\n");
 501         else
 502                 localcmd("\nsv_hook_gamerestart\n");
 503
 504         ReadyRestartForce();
 505
 506         // reset ALL scores, but only do that at the beginning
 507         //of the countdown if sv_ready_restart_after_countdown is off!
 508         //Otherwise scores could be manipulated during the countdown!
 509         if (!autocvar_sv_ready_restart_after_countdown)
 510                 Score_ClearAll();
 511 }
 512
 513 /**
 514  * Counts how many players are ready. If not enough players are ready, the function
 515  * does nothing. If all players are ready, the timelimit will be extended and the
 516  * restart_countdown variable is set to allow other functions like PlayerPostThink
 517  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 518  * is not set the map will be resetted.
 519  *
 520  * Function is called after the server receives a 'ready' sign from a player.
 521  */
 522 void ReadyCount()
 523 {
 524         local entity e;
 525         local float r, p;
 526
 527         r = p = 0;
 528
 529         FOR_EACH_REALPLAYER(e)
 530         {
 531                 p += 1;
 532                 if(e.ready)
 533                         r += 1;
 534         }
 535
 536         readycount = r;
 537
 538         Nagger_ReadyCounted();
 539
 540         if(r) // at least one is ready
 541         if(r == p) // and, everyone is ready
 542                 ReadyRestart();
 543 }
 544
 545 /**
 546  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 547  * is set)
 548  */
 549 void restartTimer_Think() {
 550         restart_mapalreadyrestarted = 1;
 551         reset_map(TRUE);
 552         Score_ClearAll();
 553         remove(self);
 554         return;
 555 }
 556
 557 /**
 558  * Checks whether the player who calls the timeout is allowed to do so.
 559  * If so, it initializes the timeout countdown. It also checks whether another
 560  * timeout was already running at this time and reacts correspondingly.
 561  *
 562  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 563  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 564  *
 565  * This function is called when a player issues the calltimeout command.
 566  */
 567 void evaluateTimeout() {
 568         if (inWarmupStage && !g_warmup_allow_timeout)
 569                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 570         if (time < game_starttime )
 571                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 572         if (timeoutStatus != 2) {
 573                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 574                 if (autocvar_timelimit) {
 575                         //a timelimit was used
 576                         local float myTl;
 577                         myTl = autocvar_timelimit;
 578
 579                         local float lastPossibleTimeout;
 580                         lastPossibleTimeout = (myTl*60) - autocvar_sv_timeout_leadtime - 1;
 581
 582                         if (lastPossibleTimeout < time - game_starttime)
 583                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 584                 }
 585         }
 586         //player may not call a timeout if he has no calls left
 587         if (self.allowedTimeouts < 1)
 588                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 589         //now all required checks are passed
 590         self.allowedTimeouts -= 1;
 591         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 592         remainingTimeoutTime = autocvar_sv_timeout_length;
 593         remainingLeadTime = autocvar_sv_timeout_leadtime;
 594         timeoutInitiator = self;
 595         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 596                 timeoutStatus = 1;
 597                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 598                 timeoutHandler = spawn();
 599                 timeoutHandler.think = timeoutHandler_Think;
 600         }
 601         timeoutHandler.nextthink = time; //always let the entity think asap
 602
 603         //inform all connected clients about the timeout call
 604         Announce("timeoutcalled");
 605 }
 606
 607 /**
 608  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 609  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 610  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 611  * value of the cvar sv_timeout_resumetime.
 612  *
 613  * This function is called when a player issues the resumegame command.
 614  */
 615 void evaluateTimein() {
 616         if (!timeoutStatus)
 617                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 618         if (self != timeoutInitiator)
 619                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 620         if (timeoutStatus == 1) {
 621                 remainingTimeoutTime = timeoutStatus = 0;
 622                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 623                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 624         }
 625         else if (timeoutStatus == 2) {
 626                 //only shorten the remainingTimeoutTime if it makes sense
 627                 if( remainingTimeoutTime > (autocvar_sv_timeout_resumetime + 1) ) {
 628                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 629                         remainingTimeoutTime = autocvar_sv_timeout_resumetime;
 630                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 631                 }
 632                 else
 633                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 634
 635         }
 636 }