qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/gamemodes/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/triggers.qh>
  10 #include <common/minigames/sv_minigames.qh>
  11 #include <common/monsters/_mod.qh>
  12 #include <common/monsters/sv_monsters.qh>
  13 #include <common/monsters/sv_spawn.qh>
  14 #include <common/notifications/all.qh>
  15 #include <common/physics/player.qh>
  16 #include <common/teams.qh>
  17 #include <common/util.qh>
  18 #include <common/vehicles/all.qh>
  19 #include <lib/warpzone/common.qh>
  20 #include <server/bot/api.qh>
  21 #include <server/campaign.qh>
  22 #include <server/chat.qh>
  23 #include <server/cheats.qh>
  24 #include <server/client.qh>
  25 #include <server/clientkill.qh>
  26 #include <server/command/common.qh>
  27 #include <server/command/getreplies.qh>
  28 #include <server/command/vote.qh>
  29 #include <server/ipban.qh>
  30 #include <server/mapvoting.qh>
  31 #include <server/mutators/_mod.qh>
  32 #include <server/player.qh>
  33 #include <server/scores.qh>
  34 #include <server/teamplay.qh>
  35 #include <server/world.qh>
  36
  37 // =========================================================
  38 //  Server side networked commands code, reworked by Samual
  39 //  Last updated: December 28th, 2011
  40 // =========================================================
  41
  42 bool SV_ParseClientCommand_floodcheck(entity this)
  43 {
  44         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  45
  46         if (!timeout_status)  // not while paused
  47         {
  48                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  49                 {
  50                         store.cmd_floodcount += 1;
  51                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  52                 }
  53                 else
  54                 {
  55                         store.cmd_floodtime = time;
  56                         store.cmd_floodcount = 1;
  57                 }
  58         }
  59         return true;  // continue, as we're not flooding yet
  60 }
  61
  62
  63 // =======================
  64 //  Command Sub-Functions
  65 // =======================
  66
  67 void ClientCommand_autoswitch(entity caller, int request, int argc)
  68 {
  69         switch (request)
  70         {
  71                 case CMD_REQUEST_COMMAND:
  72                 {
  73                         if (argv(1) != "")
  74                         {
  75                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  76                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  77                                 return;
  78                         }
  79                 }
  80
  81                 default:
  82                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
  83                 case CMD_REQUEST_USAGE:
  84                 {
  85                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  86                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  87                         return;
  88                 }
  89         }
  90 }
  91
  92 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
  93 {
  94         switch (request)
  95         {
  96                 case CMD_REQUEST_COMMAND:
  97                 {
  98                         if (argv(1) != "")
  99                         {
 100                                 if (IS_CLIENT(caller))
 101                                 {
 102                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 103
 104                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 105                                         {
 106                                                 CS(caller).version_mismatch = true;
 107                                                 ClientKill_TeamChange(caller, -2);  // observe
 108                                         }
 109                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 110                                         {
 111                                                 // JoinBestTeam(caller, false, true);
 112                                         }
 113                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 114                                         {
 115                                                 TRANSMUTE(Observer, caller);  // really?
 116                                                 stuffcmd(caller, "menu_showteamselect\n");
 117                                         }
 118                                 }
 119
 120                                 return;
 121                         }
 122                 }
 123
 124                 default:
 125                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 126                 case CMD_REQUEST_USAGE:
 127                 {
 128                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 129                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 130                         return;
 131                 }
 132         }
 133 }
 134
 135 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 136 {
 137         switch (request)
 138         {
 139                 case CMD_REQUEST_COMMAND:
 140                 {
 141                         if (argv(1) != "")
 142                         {
 143                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 144
 145                                 return;
 146                         }
 147                 }
 148
 149                 default:
 150                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 151                 case CMD_REQUEST_USAGE:
 152                 {
 153                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 154                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 155                         return;
 156                 }
 157         }
 158 }
 159
 160 void ClientCommand_wpeditor(entity caller, int request, int argc)
 161 {
 162         switch (request)
 163         {
 164                 case CMD_REQUEST_COMMAND:
 165                 {
 166                         if (!autocvar_g_waypointeditor)
 167                         {
 168                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 169                                 return;
 170                         }
 171
 172                         if (argv(1) != "")
 173                         {
 174                                 if (argv(1) == "spawn")
 175                                 {
 176                                         string s = argv(2);
 177                                         if (!IS_PLAYER(caller))
 178                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 179                                         else
 180                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 181                                         return;
 182                                 }
 183                                 else if (argv(1) == "remove")
 184                                 {
 185                                         if (!IS_PLAYER(caller))
 186                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 187                                         else
 188                                                 waypoint_remove_fromeditor(caller);
 189                                         return;
 190                                 }
 191                                 else if (argv(1) == "hardwire")
 192                                 {
 193                                         string s = argv(2);
 194                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 195                                         return;
 196                                 }
 197                                 else if (argv(1) == "lock")
 198                                 {
 199                                         waypoint_lock(caller);
 200                                         return;
 201                                 }
 202                                 else if (argv(1) == "unreachable")
 203                                 {
 204                                         if (!IS_PLAYER(caller))
 205                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 206                                         else
 207                                                 waypoint_unreachable(caller);
 208                                         return;
 209                                 }
 210                                 else if (argv(1) == "saveall")
 211                                 {
 212                                         waypoint_saveall();
 213                                         return;
 214                                 }
 215                                 else if (argv(1) == "relinkall")
 216                                 {
 217                                         waypoint_schedulerelinkall();
 218                                         return;
 219                                 }
 220                                 else if (argv(1) == "symaxis")
 221                                 {
 222                                         if (argv(2) == "set" || argv(2) == "get")
 223                                         {
 224                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 225                                                 return;
 226                                         }
 227                                 }
 228                                 else if (argv(1) == "symorigin")
 229                                 {
 230                                         if (argv(2) == "set" || argv(2) == "get")
 231                                         {
 232                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 233                                                 return;
 234                                         }
 235                                 }
 236                         }
 237                 }
 238
 239                 default:
 240                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 241                 case CMD_REQUEST_USAGE:
 242                 {
 243                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 244                         sprint(caller, "  Where 'action' can be:\n");
 245                         sprint(caller, "   ^5spawn^7: spawns a waypoint at player's position\n");
 246                         sprint(caller, "   ^5remove^7: removes player's nearest waypoint\n");
 247                         sprint(caller, "   ^5unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 248                         sprint(caller, "   ^5saveall^7: saves all waypoints and links to file\n");
 249                         sprint(caller, "   ^5relinkall^7: relinks all waypoints as if they were respawned\n");
 250                         sprint(caller, "   ^5spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 251                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 252                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 253                         sprint(caller, "   ^5spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 254                         sprint(caller, "   ^5spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 255                         sprint(caller, "   ^5spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 256                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 257                         sprint(caller, "   ^5hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 258                         sprint(caller, "   ^5hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 259                         sprint(caller, "   ^5lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 260                         sprint(caller, "   ^5symorigin get|set\n");
 261                         sprint(caller, "   ^5symorigin get|set p1 p2 ... pX\n");
 262                         sprint(caller, "   ^5symaxis get|set p1 p2\n");
 263                         sprint(caller, "   ^7 where p1 p2 ... pX are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 264                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 265                         sprint(caller, "  See 'wpeditor_menu' for a selectable list of various commands and useful settings to edit waypoints.\n");
 266                         return;
 267                 }
 268         }
 269 }
 270
 271 void ClientCommand_join(entity caller, int request)
 272 {
 273         switch (request)
 274         {
 275                 case CMD_REQUEST_COMMAND:
 276                 {
 277                         if (!game_stopped && IS_CLIENT(caller) && !IS_PLAYER(caller))
 278                         {
 279                                 if (joinAllowed(caller))
 280                                         Join(caller);
 281                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
 282                                         CS(caller).autojoin_checked = -1;
 283                         }
 284
 285                         return;  // never fall through to usage
 286                 }
 287
 288                 default:
 289                 case CMD_REQUEST_USAGE:
 290                 {
 291                         sprint(caller, "\nUsage:^3 cmd join\n");
 292                         sprint(caller, "  No arguments required.\n");
 293                         return;
 294                 }
 295         }
 296 }
 297
 298 void ClientCommand_kill(entity caller, int request)
 299 {
 300         switch (request)
 301         {
 302                 case CMD_REQUEST_COMMAND:
 303                 {
 304                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 305                                 return; // no point warning about this, command does nothing
 306
 307                         if(GetResource(caller, RES_HEALTH) <= 0)
 308                         {
 309                                 sprint(caller, "Can't die - you are already dead!\n");
 310                                 return;
 311                         }
 312
 313                         ClientKill(caller);
 314
 315                         return;  // never fall through to usage
 316                 }
 317
 318                 default:
 319                 case CMD_REQUEST_USAGE:
 320                 {
 321                         sprint(caller, "\nUsage:^3 cmd kill\n");
 322                         sprint(caller, "  No arguments required.\n");
 323                         return;
 324                 }
 325         }
 326 }
 327
 328 void ClientCommand_physics(entity caller, int request, int argc)
 329 {
 330         switch (request)
 331         {
 332                 case CMD_REQUEST_COMMAND:
 333                 {
 334                         string command = strtolower(argv(1));
 335
 336                         if (!autocvar_g_physics_clientselect)
 337                         {
 338                                 sprint(caller, "Client physics selection is currently disabled.\n");
 339                                 return;
 340                         }
 341
 342                         if (command == "list" || command == "help")
 343                         {
 344                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 345                                 return;
 346                         }
 347
 348                         if (Physics_Valid(command) || command == "default")
 349                         {
 350                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 351                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 352                                 return;
 353                         }
 354                 }
 355
 356                 default:
 357                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 358                 case CMD_REQUEST_USAGE:
 359                 {
 360                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 361                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 362                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 363                         return;
 364                 }
 365         }
 366 }
 367
 368 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 369 {
 370         switch (request)
 371         {
 372                 case CMD_REQUEST_COMMAND:
 373                 {
 374                         if (IS_CLIENT(caller))
 375                         {
 376                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 377                                 {
 378                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 379                                         {
 380                                                 if (time < game_starttime) // game is already restarting
 381                                                         return;
 382                                                 if (caller.ready)            // toggle
 383                                                 {
 384                                                         caller.ready = false;
 385                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 386                                                                 bprint(playername(caller.netname, caller.team, false), "^2 is ^1NOT^2 ready\n");
 387                                                 }
 388                                                 else
 389                                                 {
 390                                                         caller.ready = true;
 391                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 392                                                                 bprint(playername(caller.netname, caller.team, false), "^2 is ready\n");
 393                                                 }
 394
 395                                                 // cannot reset the game while a timeout is active!
 396                                                 if (!timeout_status) ReadyCount();
 397                                         }
 398                                         else
 399                                         {
 400                                                 sprint(caller, "^1Game has already been restarted\n");
 401                                         }
 402                                 }
 403                         }
 404                         return;  // never fall through to usage
 405                 }
 406
 407                 default:
 408                 case CMD_REQUEST_USAGE:
 409                 {
 410                         sprint(caller, "\nUsage:^3 cmd ready\n");
 411                         sprint(caller, "  No arguments required.\n");
 412                         return;
 413                 }
 414         }
 415 }
 416
 417 void ClientCommand_say(entity caller, int request, int argc, string command)
 418 {
 419         switch (request)
 420         {
 421                 case CMD_REQUEST_COMMAND:
 422                 {
 423                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 424                         return;  // never fall through to usage
 425                 }
 426
 427                 default:
 428                 case CMD_REQUEST_USAGE:
 429                 {
 430                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 431                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 432                         return;
 433                 }
 434         }
 435 }
 436
 437 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 438 {
 439         switch (request)
 440         {
 441                 case CMD_REQUEST_COMMAND:
 442                 {
 443                         if (argc >= 2)
 444                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 445                         return;  // never fall through to usage
 446                 }
 447
 448                 default:
 449                 case CMD_REQUEST_USAGE:
 450                 {
 451                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 452                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 453                         return;
 454                 }
 455         }
 456 }
 457
 458 .bool team_selected;
 459 void ClientCommand_selectteam(entity caller, int request, int argc)
 460 {
 461         switch (request)
 462         {
 463                 case CMD_REQUEST_COMMAND:
 464                 {
 465                         if (argv(1) == "")
 466                         {
 467                                 return;
 468                         }
 469                         if (!IS_CLIENT(caller))
 470                         {
 471                                 return;
 472                         }
 473                         if (!teamplay)
 474                         {
 475                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 476                                 return;
 477                         }
 478                         if (Player_GetForcedTeamIndex(caller) > 0)
 479                         {
 480                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 481                                 return;
 482                         }
 483                         if (lockteams)
 484                         {
 485                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 486                                 return;
 487                         }
 488                         float selection;
 489                         switch (argv(1))
 490                         {
 491                                 case "red":
 492                                 {
 493                                         selection = NUM_TEAM_1;
 494                                         break;
 495                                 }
 496                                 case "blue":
 497                                 {
 498                                         selection = NUM_TEAM_2;
 499                                         break;
 500                                 }
 501                                 case "yellow":
 502                                 {
 503                                         selection = NUM_TEAM_3;
 504                                         break;
 505                                 }
 506                                 case "pink":
 507                                 {
 508                                         selection = NUM_TEAM_4;
 509                                         break;
 510                                 }
 511                                 case "auto":
 512                                 {
 513                                         selection = (-1);
 514                                         break;
 515                                 }
 516                                 default:
 517                                 {
 518                                         return;
 519                                 }
 520                         }
 521                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 522                         {
 523                                 sprint(caller, "^7You already are on that team.\n");
 524                                 return;
 525                         }
 526                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 527                         {
 528                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 529                                 return;
 530                         }
 531                         if ((selection != -1) && autocvar_g_balance_teams &&
 532                                 autocvar_g_balance_teams_prevent_imbalance)
 533                         {
 534                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 535                                 TeamBalance_GetTeamCounts(balance, caller);
 536                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 537                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 538                                 {
 539                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 540                                         TeamBalance_Destroy(balance);
 541                                         return;
 542                                 }
 543                                 TeamBalance_Destroy(balance);
 544                         }
 545                         ClientKill_TeamChange(caller, selection);
 546                         if (!IS_PLAYER(caller))
 547                         {
 548                                 caller.team_selected = true; // avoids asking again for team selection on join
 549                         }
 550                         return;
 551                 }
 552                 default:
 553                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 554                 case CMD_REQUEST_USAGE:
 555                 {
 556                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 557                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 558                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 559                         return;
 560                 }
 561         }
 562 }
 563
 564 void ClientCommand_selfstuff(entity caller, int request, string command)
 565 {
 566         switch (request)
 567         {
 568                 case CMD_REQUEST_COMMAND:
 569                 {
 570                         if (argv(1) != "")
 571                         {
 572                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 573                                 return;
 574                         }
 575                 }
 576
 577                 default:
 578                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 579                 case CMD_REQUEST_USAGE:
 580                 {
 581                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 582                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 583                         return;
 584                 }
 585         }
 586 }
 587
 588 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 589 {
 590         switch (request)
 591         {
 592                 case CMD_REQUEST_COMMAND:
 593                 {
 594                         if (argv(1) != "")
 595                         {
 596                                 // float tokens;
 597                                 string s;
 598
 599                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 600                                 {
 601                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 602                                         tokenize_console(s);
 603                                 }
 604
 605                                 GetCvars(caller, CS(caller), 1);
 606
 607                                 return;
 608                         }
 609                 }
 610
 611                 default:
 612                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 613                 case CMD_REQUEST_USAGE:
 614                 {
 615                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 616                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 617                         return;
 618                 }
 619         }
 620 }
 621
 622 void ClientCommand_spectate(entity caller, int request)
 623 {
 624         switch (request)
 625         {
 626                 case CMD_REQUEST_COMMAND:
 627                 {
 628                         if (!intermission_running && IS_CLIENT(caller))
 629                         {
 630                                 if(argv(1) != "")
 631                                 {
 632                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 633                                         {
 634                                                 entity client = GetFilteredEntity(argv(1));
 635                                                 int spec_accepted = VerifyClientEntity(client, false, false);
 636                                                 if(spec_accepted > 0 && IS_PLAYER(client))
 637                                                 {
 638                                                         bool caller_is_observer = (IS_OBSERVER(caller));
 639                                                         Spectate(caller, client);
 640                                                         if (caller_is_observer)
 641                                                                 TRANSMUTE(Spectator, caller);
 642                                                 }
 643                                                 else
 644                                                         sprint(caller, "Can't spectate ", argv(1), "^7\n");
 645                                         }
 646                                         else
 647                                                 sprint(caller, "cmd spectate client only works when you are spectator/observer\n");
 648                                         return;
 649                                 }
 650
 651                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 652
 653                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 654
 655                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 656                                 if (autocvar_sv_spectate == 1)
 657                                         ClientKill_TeamChange(caller, -2); // observe
 658                         }
 659                         return; // never fall through to usage
 660                 }
 661
 662                 default:
 663                 case CMD_REQUEST_USAGE:
 664                 {
 665                         sprint(caller, "\nUsage:^3 cmd spectate [client]\n");
 666                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 667                         return;
 668                 }
 669         }
 670 }
 671
 672 void ClientCommand_suggestmap(entity caller, int request, int argc)
 673 {
 674         switch (request)
 675         {
 676                 case CMD_REQUEST_COMMAND:
 677                 {
 678                         if (argv(1) != "")
 679                         {
 680                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 681                                 return;
 682                         }
 683                 }
 684
 685                 default:
 686                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 687                 case CMD_REQUEST_USAGE:
 688                 {
 689                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 690                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 691                         return;
 692                 }
 693         }
 694 }
 695
 696 void ClientCommand_tell(entity caller, int request, int argc, string command)
 697 {
 698         switch (request)
 699         {
 700                 case CMD_REQUEST_COMMAND:
 701                 {
 702                         if (argc >= 3)
 703                         {
 704                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 705                                 {
 706                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 707                                         return;
 708                                 }
 709
 710                                 entity tell_to = GetIndexedEntity(argc, 1);
 711                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 712
 713                                 if (tell_accepted > 0)   // the target is a real client
 714                                 {
 715                                         if (tell_to != caller) // and we're allowed to send to them :D
 716                                         {
 717                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 718                                                 // In this case when the player name contains utf8 chars
 719                                                 // the message gets partially trimmed in the beginning.
 720                                                 // Potentially this bug affects any substring call that uses
 721                                                 // argv_start_index and argv_end_index.
 722
 723                                                 string utf8_enable_save = cvar_string("utf8_enable");
 724                                                 cvar_set("utf8_enable", "0");
 725                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 726                                                 cvar_set("utf8_enable", utf8_enable_save);
 727
 728                                                 Say(caller, false, tell_to, msg, true);
 729                                                 return;
 730                                         }
 731                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 732                                 }
 733                                 else if (argv(1) == "#0")
 734                                 {
 735                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 736                                         return;
 737                                 }
 738                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 739                         }
 740                 }
 741
 742                 default:
 743                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 744                 case CMD_REQUEST_USAGE:
 745                 {
 746                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 747                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 748                         return;
 749                 }
 750         }
 751 }
 752
 753 void ClientCommand_voice(entity caller, int request, int argc, string command)
 754 {
 755         switch (request)
 756         {
 757                 case CMD_REQUEST_COMMAND:
 758                 {
 759                         if (argv(1) != "")
 760                         {
 761                                 entity e = GetVoiceMessage(argv(1));
 762                                 if (!e)
 763                                 {
 764                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 765                                         return;
 766                                 }
 767                                 if (IS_DEAD(caller))
 768                                 {
 769                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 770                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 771                                         return;
 772                                 }
 773                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
 774                                 {
 775                                         // observers/spectators have no player model of their own to play taunts from
 776                                         // again, allow them to see warnings
 777                                         return;
 778                                 }
 779                                 string msg = "";
 780                                 if (argc >= 3)
 781                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 782                                 VoiceMessage(caller, e, msg);
 783
 784                                 return;
 785                         }
 786                 }
 787
 788                 default:
 789                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 790                 case CMD_REQUEST_USAGE:
 791                 {
 792                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 793                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 794                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 795                         return;
 796                 }
 797         }
 798 }
 799
 800 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 801 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 802 void ClientCommand_(entity caller, int request)
 803 {
 804     switch(request)
 805     {
 806         case CMD_REQUEST_COMMAND:
 807         {
 808
 809             return; // never fall through to usage
 810         }
 811
 812         default:
 813         case CMD_REQUEST_USAGE:
 814         {
 815             sprint(caller, "\nUsage:^3 cmd \n");
 816             sprint(caller, "  No arguments required.\n");
 817             return;
 818         }
 819     }
 820 }
 821 */
 822
 823
 824 // =====================================
 825 //  Macro system for networked commands
 826 // =====================================
 827
 828 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 829 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 830         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 831         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 832         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 833         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 834         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 835         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 836         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 837         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 838         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 839         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 840         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 841         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 842         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 843         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 844         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 845         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 846         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 847         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 848         /* nothing */
 849
 850 void ClientCommand_macro_help(entity caller)
 851 {
 852         #define CLIENT_COMMAND(name, function, description) \
 853                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 854
 855         CLIENT_COMMANDS(NULL, 0, 0, "");
 856 #undef CLIENT_COMMAND
 857 }
 858
 859 float ClientCommand_macro_command(int argc, entity caller, string command)
 860 {
 861         #define CLIENT_COMMAND(name, function, description) \
 862                 { if (name == strtolower(argv(0))) { function; return true; } }
 863
 864         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 865 #undef CLIENT_COMMAND
 866
 867         return false;
 868 }
 869
 870 float ClientCommand_macro_usage(int argc, entity caller)
 871 {
 872         #define CLIENT_COMMAND(name, function, description) \
 873                 { if (name == strtolower(argv(1))) { function; return true; } }
 874
 875         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 876 #undef CLIENT_COMMAND
 877
 878         return false;
 879 }
 880
 881 void ClientCommand_macro_write_aliases(float fh)
 882 {
 883         #define CLIENT_COMMAND(name, function, description) \
 884                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 885
 886         CLIENT_COMMANDS(NULL, 0, 0, "");
 887 #undef CLIENT_COMMAND
 888 }
 889
 890 // ======================================
 891 //  Main Function Called By Engine (cmd)
 892 // ======================================
 893 // If this function exists, server game code parses clientcommand before the engine code gets it.
 894
 895 void SV_ParseClientCommand(entity this, string command)
 896 {
 897         // If invalid UTF-8, don't even parse it
 898         string command2 = "";
 899         float len = strlen(command);
 900         float i;
 901         for (i = 0; i < len; ++i)
 902                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 903         if (command != command2) return;
 904
 905         // if we're banned, don't even parse the command
 906         if (Ban_MaybeEnforceBanOnce(this)) return;
 907
 908         int argc = tokenize_console(command);
 909
 910         // Guide for working with argc arguments by example:
 911         // argc:   1    - 2      - 3     - 4
 912         // argv:   0    - 1      - 2     - 3
 913         // cmd     vote - master - login - password
 914
 915         // for floodcheck
 916         switch (strtolower(argv(0)))
 917         {
 918                 // exempt commands which are not subject to floodcheck
 919                 case "begin": break;                               // handled by engine in host_cmd.c
 920                 case "download": break;                            // handled by engine in cl_parse.c
 921                 case "mv_getpicture": break;                       // handled by server in this file
 922                 case "wpeditor": break;                            // handled by server in this file
 923                 case "pause": break;                               // handled by engine in host_cmd.c
 924                 case "prespawn": break;                            // handled by engine in host_cmd.c
 925                 case "sentcvar": break;                            // handled by server in this file
 926                 case "spawn": break;                               // handled by engine in host_cmd.c
 927                 case "color": case "topcolor": case "bottomcolor": if(teamplay) return; else break; // handled by engine in host_cmd.c
 928                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 929
 930                 default:
 931                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 932                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 933         }
 934
 935         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 936         if (argv(0) == "help")
 937         {
 938                 if (argc == 1)
 939                 {
 940                         sprint(this, "\nClient networked commands:\n");
 941                         ClientCommand_macro_help(this);
 942
 943                         sprint(this, "\nCommon networked commands:\n");
 944                         CommonCommand_macro_help(this);
 945
 946                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 947                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 948                         return;
 949                 }
 950                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 951                 {
 952                         return;
 953                 }
 954                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 955                 {
 956                         return;
 957                 }
 958         }
 959         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 960         {
 961                 return;  // handled by a mutator
 962         }
 963         else if (CheatCommand(this, argc))
 964         {
 965                 return;  // handled by server/cheats.qc
 966         }
 967         else if (CommonCommand_macro_command(argc, this, command))
 968         {
 969                 return;                                          // handled by server/command/common.qc
 970         }
 971         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 972         {
 973                 return;                                          // handled by one of the above ClientCommand_* functions
 974         }
 975         else
 976         {
 977                 clientcommand(this, command);
 978         }
 979 }