qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2 #include <common/command/command.qh>
   3
   4 #include "common.qh"
   5 #include "vote.qh"
   6
   7 #include "../campaign.qh"
   8 #include "../cheats.qh"
   9 #include "../cl_player.qh"
  10 #include "../ipban.qh"
  11 #include "../mapvoting.qh"
  12 #include "../scores.qh"
  13 #include "../teamplay.qh"
  14
  15 #include "../mutators/all.qh"
  16
  17 #ifdef SVQC
  18         #include <common/vehicles/all.qh>
  19 #endif
  20
  21 #include <common/constants.qh>
  22 #include <common/deathtypes/all.qh>
  23 #include <common/effects/all.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/notifications/all.qh>
  26 #include <common/physics/player.qh>
  27 #include <common/teams.qh>
  28 #include <common/util.qh>
  29 #include <common/triggers/triggers.qh>
  30
  31 #include <common/minigames/sv_minigames.qh>
  32
  33 #include <common/monsters/all.qc>
  34 #include <common/monsters/spawn.qh>
  35 #include <common/monsters/sv_monsters.qh>
  36
  37 #include <lib/warpzone/common.qh>
  38
  39 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
  40
  41 // =========================================================
  42 //  Server side networked commands code, reworked by Samual
  43 //  Last updated: December 28th, 2011
  44 // =========================================================
  45
  46 bool SV_ParseClientCommand_floodcheck(entity this)
  47 {
  48         if (!timeout_status)  // not while paused
  49         {
  50                 if (time <= (this.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  51                 {
  52                         this.cmd_floodcount += 1;
  53                         if (this.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  54                 }
  55                 else
  56                 {
  57                         this.cmd_floodtime = time;
  58                         this.cmd_floodcount = 1;
  59                 }
  60         }
  61         return true;  // continue, as we're not flooding yet
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void ClientCommand_autoswitch(entity caller, float request, float argc)
  70 {
  71         switch (request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         if (argv(1) != "")
  76                         {
  77                                 caller.autoswitch = InterpretBoolean(argv(1));
  78                                 sprint(caller, strcat("^1autoswitch is currently turned ", (caller.autoswitch ? "on" : "off"), ".\n"));
  79                                 return;
  80                         }
  81                 }
  82
  83                 default:
  84                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  85                 case CMD_REQUEST_USAGE:
  86                 {
  87                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  88                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  89                         return;
  90                 }
  91         }
  92 }
  93
  94 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
  95 {
  96         switch (request)
  97         {
  98                 case CMD_REQUEST_COMMAND:
  99                 {
 100                         if (argv(1) != "")
 101                         {
 102                                 if (IS_CLIENT(caller))
 103                                 {
 104                                         caller.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 105
 106                                         if (caller.version < autocvar_gameversion_min || caller.version > autocvar_gameversion_max)
 107                                         {
 108                                                 caller.version_mismatch = 1;
 109                                                 ClientKill_TeamChange(caller, -2);  // observe
 110                                         }
 111                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 112                                         {
 113                                                 // JoinBestTeam(caller, false, true);
 114                                         }
 115                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 116                                         {
 117                                                 TRANSMUTE(Observer, caller);  // really?
 118                                                 stuffcmd(caller, "menu_showteamselect\n");
 119                                         }
 120                                 }
 121
 122                                 return;
 123                         }
 124                 }
 125
 126                 default:
 127                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 128                 case CMD_REQUEST_USAGE:
 129                 {
 130                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 131                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 132                         return;
 133                 }
 134         }
 135 }
 136
 137 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 138 {
 139         switch (request)
 140         {
 141                 case CMD_REQUEST_COMMAND:
 142                 {
 143                         if (argv(1) != "")
 144                         {
 145                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 146
 147                                 return;
 148                         }
 149                 }
 150
 151                 default:
 152                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 153                 case CMD_REQUEST_USAGE:
 154                 {
 155                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 156                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 157                         return;
 158                 }
 159         }
 160 }
 161
 162 void ClientCommand_join(entity caller, float request)
 163 {
 164         switch (request)
 165         {
 166                 case CMD_REQUEST_COMMAND:
 167                 {
 168                         if (IS_CLIENT(caller))
 169                         {
 170                                 if (!IS_PLAYER(caller) && !lockteams && !gameover)
 171                                 {
 172                                         if (caller.caplayer) return;
 173                                         if (nJoinAllowed(caller, caller))
 174                                         {
 175                                                 if (autocvar_g_campaign)   campaign_bots_may_start = true;
 176                                                 TRANSMUTE(Player, caller);
 177                                                 PlayerScore_Clear(caller);
 178                                                 Kill_Notification(NOTIF_ONE_ONLY, caller, MSG_CENTER, CPID_PREVENT_JOIN);
 179                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && caller.team != -1) ? APP_TEAM_ENT(caller, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), caller.netname);
 180                                                 PutClientInServer(caller);
 181                                         }
 182                                         else
 183                                         {
 184                                                 // player may not join because of g_maxplayers is set
 185                                                 Send_Notification(NOTIF_ONE_ONLY, caller, MSG_CENTER, CENTER_JOIN_PREVENT);
 186                                         }
 187                                 }
 188                         }
 189                         return;  // never fall through to usage
 190                 }
 191
 192                 default:
 193                 case CMD_REQUEST_USAGE:
 194                 {
 195                         sprint(caller, "\nUsage:^3 cmd join\n");
 196                         sprint(caller, "  No arguments required.\n");
 197                         return;
 198                 }
 199         }
 200 }
 201
 202 void ClientCommand_physics(entity caller, float request, float argc)
 203 {
 204         switch (request)
 205         {
 206                 case CMD_REQUEST_COMMAND:
 207                 {
 208                         string command = strtolower(argv(1));
 209
 210                         if (!autocvar_g_physics_clientselect)
 211                         {
 212                                 sprint(caller, "Client physics selection is currently disabled.\n");
 213                                 return;
 214                         }
 215
 216                         if (command == "list" || command == "help")
 217                         {
 218                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 219                                 return;
 220                         }
 221
 222                         if (Physics_Valid(command) || command == "default")
 223                         {
 224                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 225                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 226                                 return;
 227                         }
 228                 }
 229
 230                 default:
 231                         sprint(caller, strcat("Current physics set: ^3", caller.cvar_cl_physics, "\n"));
 232                 case CMD_REQUEST_USAGE:
 233                 {
 234                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 235                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 236                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 237                         return;
 238                 }
 239         }
 240 }
 241
 242 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 243 {
 244         switch (request)
 245         {
 246                 case CMD_REQUEST_COMMAND:
 247                 {
 248                         if (IS_CLIENT(caller))
 249                         {
 250                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 251                                 {
 252                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 253                                         {
 254                                                 if (time < game_starttime) // game is already restarting
 255                                                         return;
 256                                                 if (caller.ready)            // toggle
 257                                                 {
 258                                                         caller.ready = false;
 259                                                         bprint(caller.netname, "^2 is ^1NOT^2 ready\n");
 260                                                 }
 261                                                 else
 262                                                 {
 263                                                         caller.ready = true;
 264                                                         bprint(caller.netname, "^2 is ready\n");
 265                                                 }
 266
 267                                                 // cannot reset the game while a timeout is active!
 268                                                 if (!timeout_status) ReadyCount();
 269                                         }
 270                                         else
 271                                         {
 272                                                 sprint(caller, "^1Game has already been restarted\n");
 273                                         }
 274                                 }
 275                         }
 276                         return;  // never fall through to usage
 277                 }
 278
 279                 default:
 280                 case CMD_REQUEST_USAGE:
 281                 {
 282                         sprint(caller, "\nUsage:^3 cmd ready\n");
 283                         sprint(caller, "  No arguments required.\n");
 284                         return;
 285                 }
 286         }
 287 }
 288
 289 void ClientCommand_say(entity caller, float request, float argc, string command)
 290 {
 291         switch (request)
 292         {
 293                 case CMD_REQUEST_COMMAND:
 294                 {
 295                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 296                         return;  // never fall through to usage
 297                 }
 298
 299                 default:
 300                 case CMD_REQUEST_USAGE:
 301                 {
 302                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 303                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 304                         return;
 305                 }
 306         }
 307 }
 308
 309 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 310 {
 311         switch (request)
 312         {
 313                 case CMD_REQUEST_COMMAND:
 314                 {
 315                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 316                         return;  // never fall through to usage
 317                 }
 318
 319                 default:
 320                 case CMD_REQUEST_USAGE:
 321                 {
 322                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 323                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void ClientCommand_selectteam(entity caller, float request, float argc)
 330 {
 331         switch (request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         if (argv(1) != "")
 336                         {
 337                                 if (IS_CLIENT(caller))
 338                                 {
 339                                         if (teamplay)
 340                                         {
 341                                                 if (caller.team_forced <= 0)
 342                                                 {
 343                                                         if (!lockteams)
 344                                                         {
 345                                                                 float selection;
 346
 347                                                                 switch (argv(1))
 348                                                                 {
 349                                                                         case "red": selection = NUM_TEAM_1;
 350                                                                                 break;
 351                                                                         case "blue": selection = NUM_TEAM_2;
 352                                                                                 break;
 353                                                                         case "yellow": selection = NUM_TEAM_3;
 354                                                                                 break;
 355                                                                         case "pink": selection = NUM_TEAM_4;
 356                                                                                 break;
 357                                                                         case "auto": selection = (-1);
 358                                                                                 break;
 359
 360                                                                         default: selection = 0;
 361                                                                                 break;
 362                                                                 }
 363
 364                                                                 if (selection)
 365                                                                 {
 366                                                                         if (caller.team == selection && !IS_DEAD(caller))
 367                                                                         {
 368                                                                                 sprint(caller, "^7You already are on that team.\n");
 369                                                                         }
 370                                                                         else if (caller.wasplayer && autocvar_g_changeteam_banned)
 371                                                                         {
 372                                                                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 373                                                                         }
 374                                                                         else
 375                                                                         {
 376                                                                                 if (autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 377                                                                                 {
 378                                                                                         CheckAllowedTeams(caller);
 379                                                                                         GetTeamCounts(caller);
 380                                                                                         if (!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(caller.team), caller))
 381                                                                                         {
 382                                                                                                 Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 383                                                                                                 return;
 384                                                                                         }
 385                                                                                 }
 386                                                                                 ClientKill_TeamChange(caller, selection);
 387                                                                         }
 388                                                                 }
 389                                                         }
 390                                                         else
 391                                                         {
 392                                                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 393                                                         }
 394                                                 }
 395                                                 else
 396                                                 {
 397                                                         sprint(caller, "^7selectteam can not be used as your team is forced\n");
 398                                                 }
 399                                         }
 400                                         else
 401                                         {
 402                                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 403                                         }
 404                                 }
 405                                 return;
 406                         }
 407                 }
 408
 409                 default:
 410                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 411                 case CMD_REQUEST_USAGE:
 412                 {
 413                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 414                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 415                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 416                         return;
 417                 }
 418         }
 419 }
 420
 421 void ClientCommand_selfstuff(entity caller, float request, string command)
 422 {
 423         switch (request)
 424         {
 425                 case CMD_REQUEST_COMMAND:
 426                 {
 427                         if (argv(1) != "")
 428                         {
 429                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 430                                 return;
 431                         }
 432                 }
 433
 434                 default:
 435                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 439                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 446 {
 447         switch (request)
 448         {
 449                 case CMD_REQUEST_COMMAND:
 450                 {
 451                         if (argv(1) != "")
 452                         {
 453                                 // float tokens;
 454                                 string s;
 455
 456                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 457                                 {
 458                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 459                                         tokenize_console(s);
 460                                 }
 461
 462                                 GetCvars(caller, 1);
 463
 464                                 return;
 465                         }
 466                 }
 467
 468                 default:
 469                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 470                 case CMD_REQUEST_USAGE:
 471                 {
 472                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 473                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 474                         return;
 475                 }
 476         }
 477 }
 478
 479 void ClientCommand_spectate(entity caller, float request)
 480 {
 481         switch (request)
 482         {
 483                 case CMD_REQUEST_COMMAND:
 484                 {
 485                         if (IS_CLIENT(caller))
 486                         {
 487                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 488
 489                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 490
 491                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE) && autocvar_sv_spectate == 1) ClientKill_TeamChange(caller, -2); // observe
 492                         }
 493                         return;                                                                                                                        // never fall through to usage
 494                 }
 495
 496                 default:
 497                 case CMD_REQUEST_USAGE:
 498                 {
 499                         sprint(caller, "\nUsage:^3 cmd spectate\n");
 500                         sprint(caller, "  No arguments required.\n");
 501                         return;
 502                 }
 503         }
 504 }
 505
 506 void ClientCommand_suggestmap(entity caller, float request, float argc)
 507 {
 508         switch (request)
 509         {
 510                 case CMD_REQUEST_COMMAND:
 511                 {
 512                         if (argv(1) != "")
 513                         {
 514                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 515                                 return;
 516                         }
 517                 }
 518
 519                 default:
 520                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 521                 case CMD_REQUEST_USAGE:
 522                 {
 523                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 524                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 525                         return;
 526                 }
 527         }
 528 }
 529
 530 void ClientCommand_tell(entity caller, float request, float argc, string command)
 531 {
 532         switch (request)
 533         {
 534                 case CMD_REQUEST_COMMAND:
 535                 {
 536                         if (argc >= 3)
 537                         {
 538                                 entity tell_to = GetIndexedEntity(argc, 1);
 539                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 540
 541                                 if (tell_accepted > 0)   // the target is a real client
 542                                 {
 543                                         if (tell_to != caller) // and we're allowed to send to them :D
 544                                         {
 545                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 546                                                 // In this case when the player name contains utf8 chars
 547                                                 // the message gets partially trimmed in the beginning.
 548                                                 // Potentially this bug affects any substring call that uses
 549                                                 // argv_start_index and argv_end_index.
 550
 551                                                 string utf8_enable_save = cvar_string("utf8_enable");
 552                                                 cvar_set("utf8_enable", "0");
 553                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 554                                                 cvar_set("utf8_enable", utf8_enable_save);
 555
 556                                                 Say(caller, false, tell_to, msg, true);
 557                                                 return;
 558                                         }
 559                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 560                                 }
 561                                 else if (argv(1) == "#0")
 562                                 {
 563                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 564                                         return;
 565                                 }
 566                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 567                         }
 568                 }
 569
 570                 default:
 571                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 572                 case CMD_REQUEST_USAGE:
 573                 {
 574                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 575                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 576                         return;
 577                 }
 578         }
 579 }
 580
 581 void ClientCommand_voice(entity caller, float request, float argc, string command)
 582 {
 583         switch (request)
 584         {
 585                 case CMD_REQUEST_COMMAND:
 586                 {
 587                         if (argv(1) != "")
 588                         {
 589                                 entity e = GetVoiceMessage(argv(1));
 590                                 if (!e)
 591                                 {
 592                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 593                                         return;
 594                                 }
 595                                 if (argc >= 3) VoiceMessage(caller, e, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 596                                 else VoiceMessage(caller, e, "");
 597
 598                                 return;
 599                         }
 600                 }
 601
 602                 default:
 603                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 604                 case CMD_REQUEST_USAGE:
 605                 {
 606                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 607                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 608                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 609                         return;
 610                 }
 611         }
 612 }
 613
 614 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 615 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 616 void ClientCommand_(entity caller, float request)
 617 {
 618     switch(request)
 619     {
 620         case CMD_REQUEST_COMMAND:
 621         {
 622
 623             return; // never fall through to usage
 624         }
 625
 626         default:
 627         case CMD_REQUEST_USAGE:
 628         {
 629             sprint(caller, "\nUsage:^3 cmd \n");
 630             sprint(caller, "  No arguments required.\n");
 631             return;
 632         }
 633     }
 634 }
 635 */
 636
 637
 638 // =====================================
 639 //  Macro system for networked commands
 640 // =====================================
 641
 642 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 643 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 644         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 645         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 646         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 647         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 648         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 649         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 650         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 651         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 652         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 653         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 654         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 655         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 656         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 657         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 658         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 659         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 660         /* nothing */
 661
 662 void ClientCommand_macro_help(entity caller)
 663 {
 664         #define CLIENT_COMMAND(name, function, description) \
 665                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 666
 667         CLIENT_COMMANDS(NULL, 0, 0, "");
 668 #undef CLIENT_COMMAND
 669 }
 670
 671 float ClientCommand_macro_command(float argc, entity caller, string command)
 672 {
 673         #define CLIENT_COMMAND(name, function, description) \
 674                 { if (name == strtolower(argv(0))) { function; return true; } }
 675
 676         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 677 #undef CLIENT_COMMAND
 678
 679         return false;
 680 }
 681
 682 float ClientCommand_macro_usage(float argc, entity caller)
 683 {
 684         #define CLIENT_COMMAND(name, function, description) \
 685                 { if (name == strtolower(argv(1))) { function; return true; } }
 686
 687         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 688 #undef CLIENT_COMMAND
 689
 690         return false;
 691 }
 692
 693 void ClientCommand_macro_write_aliases(float fh)
 694 {
 695         #define CLIENT_COMMAND(name, function, description) \
 696                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 697
 698         CLIENT_COMMANDS(NULL, 0, 0, "");
 699 #undef CLIENT_COMMAND
 700 }
 701
 702 // ======================================
 703 //  Main Function Called By Engine (cmd)
 704 // ======================================
 705 // If this function exists, server game code parses clientcommand before the engine code gets it.
 706
 707 void SV_ParseClientCommand(entity this, string command)
 708 {
 709         // If invalid UTF-8, don't even parse it
 710         string command2 = "";
 711         float len = strlen(command);
 712         float i;
 713         for (i = 0; i < len; ++i)
 714                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 715         if (command != command2) return;
 716
 717         // if we're banned, don't even parse the command
 718         if (Ban_MaybeEnforceBanOnce(this)) return;
 719
 720         float argc = tokenize_console(command);
 721
 722         // Guide for working with argc arguments by example:
 723         // argc:   1    - 2      - 3     - 4
 724         // argv:   0    - 1      - 2     - 3
 725         // cmd     vote - master - login - password
 726
 727         // for floodcheck
 728         switch (strtolower(argv(0)))
 729         {
 730                 // exempt commands which are not subject to floodcheck
 731                 case "begin": break;                               // handled by engine in host_cmd.c
 732                 case "download": break;                            // handled by engine in cl_parse.c
 733                 case "mv_getpicture": break;                       // handled by server in this file
 734                 case "pause": break;                               // handled by engine in host_cmd.c
 735                 case "prespawn": break;                            // handled by engine in host_cmd.c
 736                 case "sentcvar": break;                            // handled by server in this file
 737                 case "spawn": break;                               // handled by engine in host_cmd.c
 738                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 739
 740                 default:
 741                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 742                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 743         }
 744
 745         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 746         if (argv(0) == "help")
 747         {
 748                 if (argc == 1)
 749                 {
 750                         sprint(this, "\nClient networked commands:\n");
 751                         ClientCommand_macro_help(this);
 752
 753                         sprint(this, "\nCommon networked commands:\n");
 754                         CommonCommand_macro_help(this);
 755
 756                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 757                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 758                         return;
 759                 }
 760                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 761                 {
 762                         return;
 763                 }
 764                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 765                 {
 766                         return;
 767                 }
 768         }
 769         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 770         {
 771                 return;  // handled by a mutator
 772         }
 773         else if (CheatCommand(this, argc))
 774         {
 775                 return;  // handled by server/cheats.qc
 776         }
 777         else if (CommonCommand_macro_command(argc, this, command))
 778         {
 779                 return;                                          // handled by server/command/common.qc
 780         }
 781         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 782         {
 783                 return;                                          // handled by one of the above ClientCommand_* functions
 784         }
 785         else
 786         {
 787                 clientcommand(this, command);
 788         }
 789 }