sv_maxidle_playertospectator: fix joining players getting moved to spec immediately
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / cmd.qc
1 #include "cmd.qh"
2
3 #include <common/command/_mod.qh>
4 #include <common/constants.qh>
5 #include <common/deathtypes/all.qh>
6 #include <common/effects/all.qh>
7 #include <common/gamemodes/_mod.qh>
8 #include <common/mapinfo.qh>
9 #include <common/mapobjects/triggers.qh>
10 #include <common/minigames/sv_minigames.qh>
11 #include <common/monsters/_mod.qh>
12 #include <common/monsters/sv_monsters.qh>
13 #include <common/monsters/sv_spawn.qh>
14 #include <common/notifications/all.qh>
15 #include <common/physics/player.qh>
16 #include <common/teams.qh>
17 #include <common/util.qh>
18 #include <common/vehicles/all.qh>
19 #include <lib/warpzone/common.qh>
20 #include <server/bot/api.qh>
21 #include <server/bot/default/waypoints.qh>
22 #include <server/campaign.qh>
23 #include <server/chat.qh>
24 #include <server/cheats.qh>
25 #include <server/client.qh>
26 #include <server/clientkill.qh>
27 #include <server/command/common.qh>
28 #include <server/command/getreplies.qh>
29 #include <server/command/vote.qh>
30 #include <server/ipban.qh>
31 #include <server/mapvoting.qh>
32 #include <server/mutators/_mod.qh>
33 #include <server/player.qh>
34 #include <server/scores.qh>
35 #include <server/teamplay.qh>
36 #include <server/world.qh>
37
38 // =========================================================
39 //  Server side networked commands code, reworked by Samual
40 //  Last updated: December 28th, 2011
41 // =========================================================
42
43 bool SV_ParseClientCommand_floodcheck(entity this)
44 {
45         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
46
47         if (!timeout_status)  // not while paused
48         {
49                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
50                 {
51                         store.cmd_floodcount += 1;
52                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
53                 }
54                 else
55                 {
56                         store.cmd_floodtime = time;
57                         store.cmd_floodcount = 1;
58                 }
59         }
60         return true;  // continue, as we're not flooding yet
61 }
62
63
64 // =======================
65 //  Command Sub-Functions
66 // =======================
67
68 void ClientCommand_autoswitch(entity caller, int request, int argc)
69 {
70         switch (request)
71         {
72                 case CMD_REQUEST_COMMAND:
73                 {
74                         if (argv(1) != "")
75                         {
76                                 CS_CVAR(caller).cvar_cl_autoswitch = InterpretBoolean(argv(1));
77                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS_CVAR(caller).cvar_cl_autoswitch ? "on" : "off"), ".\n"));
78                                 return;
79                         }
80                 }
81
82                 default:
83                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
84                 case CMD_REQUEST_USAGE:
85                 {
86                         sprint(caller, "\nUsage:^3 cmd autoswitch <selection>\n");
87                         sprint(caller, "  Where <selection> controls if autoswitch is on or off.\n");
88                         return;
89                 }
90         }
91 }
92
93 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
94 {
95         switch (request)
96         {
97                 case CMD_REQUEST_COMMAND:
98                 {
99                         if (argv(1) != "")
100                         {
101                                 if (IS_CLIENT(caller))
102                                 {
103                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
104
105                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
106                                         {
107                                                 CS(caller).version_mismatch = true;
108                                                 ClientKill_TeamChange(caller, -2);  // observe
109                                         }
110                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
111                                         {
112                                                 // JoinBestTeam(caller, false, true);
113                                         }
114                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
115                                         {
116                                                 TRANSMUTE(Observer, caller);  // really?
117                                                 stuffcmd(caller, "menu_showteamselect\n");
118                                         }
119                                 }
120
121                                 return;
122                         }
123                 }
124
125                 default:
126                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
127                 case CMD_REQUEST_USAGE:
128                 {
129                         sprint(caller, "\nUsage:^3 cmd clientversion <version>\n");
130                         sprint(caller, "  Where <version> is the game version reported by caller.\n");
131                         return;
132                 }
133         }
134 }
135
136 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
137 {
138         switch (request)
139         {
140                 case CMD_REQUEST_COMMAND:
141                 {
142                         if (argv(1) != "")
143                         {
144                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
145
146                                 return;
147                         }
148                 }
149
150                 default:
151                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
152                 case CMD_REQUEST_USAGE:
153                 {
154                         sprint(caller, "\nUsage:^3 cmd mv_getpicture <mapid>\n");
155                         sprint(caller, "  Where <mapid> is the id number of the map to request an image of on the map vote selection menu.\n");
156                         return;
157                 }
158         }
159 }
160
161 void ClientCommand_wpeditor(entity caller, int request, int argc)
162 {
163         switch (request)
164         {
165                 case CMD_REQUEST_COMMAND:
166                 {
167                         if (!waypointeditor_enabled)
168                         {
169                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
170                                 return;
171                         }
172
173                         if (argv(1) != "")
174                         {
175                                 if (argv(1) == "spawn")
176                                 {
177                                         string s = argv(2);
178                                         if (!IS_PLAYER(caller))
179                                                 sprint(caller, "ERROR: this command works only if you are player\n");
180                                         else
181                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
182                                         return;
183                                 }
184                                 else if (argv(1) == "remove")
185                                 {
186                                         if (!IS_PLAYER(caller))
187                                                 sprint(caller, "ERROR: this command works only if you are player\n");
188                                         else
189                                                 waypoint_remove_fromeditor(caller);
190                                         return;
191                                 }
192                                 else if (argv(1) == "hardwire")
193                                 {
194                                         string s = argv(2);
195                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
196                                         return;
197                                 }
198                                 else if (argv(1) == "lock")
199                                 {
200                                         waypoint_lock(caller);
201                                         return;
202                                 }
203                                 else if (argv(1) == "unreachable")
204                                 {
205                                         if (!IS_PLAYER(caller))
206                                                 sprint(caller, "ERROR: this command works only if you are player\n");
207                                         else
208                                                 waypoint_unreachable(caller);
209                                         return;
210                                 }
211                                 else if (argv(1) == "saveall")
212                                 {
213                                         waypoint_saveall();
214                                         return;
215                                 }
216                                 else if (argv(1) == "relinkall")
217                                 {
218                                         waypoint_schedulerelinkall();
219                                         return;
220                                 }
221                                 else if (argv(1) == "symaxis")
222                                 {
223                                         if (argv(2) == "set" || argv(2) == "get")
224                                         {
225                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
226                                                 return;
227                                         }
228                                 }
229                                 else if (argv(1) == "symorigin")
230                                 {
231                                         if (argv(2) == "set" || argv(2) == "get")
232                                         {
233                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
234                                                 return;
235                                         }
236                                 }
237                         }
238                 }
239
240                 default:
241                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
242                 case CMD_REQUEST_USAGE:
243                 {
244                         sprint(caller, "\nUsage:^3 cmd wpeditor <action>\n");
245                         sprint(caller, "  Where <action> can be:\n");
246                         sprint(caller, "   ^2spawn^7: spawns a waypoint at player's position\n");
247                         sprint(caller, "   ^2remove^7: removes player's nearest waypoint\n");
248                         sprint(caller, "   ^2unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
249                         sprint(caller, "   ^2saveall^7: saves all waypoints and links to file\n");
250                         sprint(caller, "   ^2relinkall^7: relinks all waypoints as if they were respawned\n");
251                         sprint(caller, "   ^2spawn crosshair^7: spawns a waypoint at crosshair's position\n");
252                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
253                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
254                         sprint(caller, "   ^2spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
255                         sprint(caller, "   ^2spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
256                         sprint(caller, "   ^2spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
257                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
258                         sprint(caller, "   ^2hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
259                         sprint(caller, "   ^2hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
260                         sprint(caller, "   ^2lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
261                         sprint(caller, "   ^2symorigin get|set\n");
262                         sprint(caller, "   ^2symorigin get|set <p1> <p2> ... <pX>\n");
263                         sprint(caller, "   ^2symaxis get|set <p1> <p2>\n");
264                         sprint(caller, "   ^7 where <p1> <p2> ... <pX> are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
265                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
266                         sprint(caller, "  See ^5wpeditor_menu^7 for a selectable list of various commands and useful settings to edit waypoints.\n");
267                         return;
268                 }
269         }
270 }
271
272 void ClientCommand_join(entity caller, int request)
273 {
274         switch (request)
275         {
276                 case CMD_REQUEST_COMMAND:
277                 {
278                         if (!game_stopped && IS_CLIENT(caller) && !IS_PLAYER(caller))
279                         {
280                                 if (joinAllowed(caller))
281                                         Join(caller);
282                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
283                                         CS(caller).autojoin_checked = -1;
284                         }
285                         CS(caller).parm_idlesince = time;
286
287                         return;  // never fall through to usage
288                 }
289
290                 default:
291                 case CMD_REQUEST_USAGE:
292                 {
293                         sprint(caller, "\nUsage:^3 cmd join\n");
294                         sprint(caller, "  No arguments required.\n");
295                         return;
296                 }
297         }
298 }
299
300 void ClientCommand_kill(entity caller, int request)
301 {
302         switch (request)
303         {
304                 case CMD_REQUEST_COMMAND:
305                 {
306                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
307                                 return; // no point warning about this, command does nothing
308
309                         if(GetResource(caller, RES_HEALTH) <= 0)
310                         {
311                                 sprint(caller, "Can't die - you are already dead!\n");
312                                 return;
313                         }
314
315                         ClientKill(caller);
316
317                         return;  // never fall through to usage
318                 }
319
320                 default:
321                 case CMD_REQUEST_USAGE:
322                 {
323                         sprint(caller, "\nUsage:^3 cmd kill\n");
324                         sprint(caller, "  No arguments required.\n");
325                         return;
326                 }
327         }
328 }
329
330 void ClientCommand_physics(entity caller, int request, int argc)
331 {
332         switch (request)
333         {
334                 case CMD_REQUEST_COMMAND:
335                 {
336                         string command = strtolower(argv(1));
337
338                         if (!autocvar_g_physics_clientselect)
339                         {
340                                 sprint(caller, "Client physics selection is currently disabled.\n");
341                                 return;
342                         }
343
344                         if (command == "list" || command == "help")
345                         {
346                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
347                                 return;
348                         }
349
350                         if (Physics_Valid(command) || command == "default")
351                         {
352                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
353                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
354                                 return;
355                         }
356                 }
357
358                 default:
359                         sprint(caller, strcat("Current physics set: ^3", CS_CVAR(caller).cvar_cl_physics, "\n"));
360                 case CMD_REQUEST_USAGE:
361                 {
362                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
363                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
364                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
365                         return;
366                 }
367         }
368 }
369
370 void ClientCommand_ready(entity caller, int request)
371 {
372         switch (request)
373         {
374                 case CMD_REQUEST_COMMAND:
375                 {
376                         if (IS_CLIENT(caller) && caller.last_ready < time - 3)
377                         {
378                                 if (warmup_stage || g_race_qualifying == 2)
379                                 {
380                                         if (time < game_starttime) // game is already restarting
381                                                 return;
382                                         if (caller.ready)            // toggle
383                                         {
384                                                 caller.ready = false;
385                                                 if (IS_PLAYER(caller) || INGAME_JOINED(caller))
386                                                         bprint(playername(caller.netname, caller.team, false), "^2 is ^1NOT^2 ready\n");
387                                         }
388                                         else
389                                         {
390                                                 caller.ready = true;
391                                                 if (IS_PLAYER(caller) || INGAME_JOINED(caller))
392                                                         bprint(playername(caller.netname, caller.team, false), "^2 is ready\n");
393                                         }
394
395                                         caller.last_ready = time;
396
397                                         // cannot reset the game while a timeout is active!
398                                         if (!timeout_status) ReadyCount();
399                                 }
400                         }
401                         return;  // never fall through to usage
402                 }
403
404                 default:
405                 case CMD_REQUEST_USAGE:
406                 {
407                         sprint(caller, "\nUsage:^3 cmd ready\n");
408                         sprint(caller, "  No arguments required.\n");
409                         return;
410                 }
411         }
412 }
413
414 void ClientCommand_say(entity caller, int request, int argc, string command)
415 {
416         switch (request)
417         {
418                 case CMD_REQUEST_COMMAND:
419                 {
420                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
421                         return;  // never fall through to usage
422                 }
423
424                 default:
425                 case CMD_REQUEST_USAGE:
426                 {
427                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
428                         sprint(caller, "  Where <message> is the string of text to say.\n");
429                         return;
430                 }
431         }
432 }
433
434 void ClientCommand_say_team(entity caller, int request, int argc, string command)
435 {
436         switch (request)
437         {
438                 case CMD_REQUEST_COMMAND:
439                 {
440                         if (argc >= 2)
441                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
442                         return;  // never fall through to usage
443                 }
444
445                 default:
446                 case CMD_REQUEST_USAGE:
447                 {
448                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
449                         sprint(caller, "  Where <message> is the string of text to say.\n");
450                         return;
451                 }
452         }
453 }
454
455 .bool team_selected;
456 void ClientCommand_selectteam(entity caller, int request, int argc)
457 {
458         switch (request)
459         {
460                 case CMD_REQUEST_COMMAND:
461                 {
462                         if (argv(1) == "")
463                         {
464                                 return;
465                         }
466                         if (!IS_CLIENT(caller))
467                         {
468                                 return;
469                         }
470                         if (!teamplay)
471                         {
472                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
473                                 return;
474                         }
475                         if (Player_GetForcedTeamIndex(caller) > 0)
476                         {
477                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
478                                 return;
479                         }
480                         if (lockteams)
481                         {
482                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
483                                 return;
484                         }
485
486                         float team_num = Team_ColorToTeam(argv(1));
487                         if (team_num == -1) // invalid
488                                 return;
489                         if (caller.team == team_num && team_num && !IS_DEAD(caller))
490                         {
491                                 sprint(caller, "^7You already are on that team.\n");
492                                 return;
493                         }
494                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
495                         {
496                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
497                                 return;
498                         }
499                         if (team_num && autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
500                         {
501                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
502                                 TeamBalance_GetTeamCounts(balance, caller);
503                                 if ((Team_IndexToBit(Team_TeamToIndex(team_num)) &
504                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
505                                 {
506                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
507                                         TeamBalance_Destroy(balance);
508                                         return;
509                                 }
510                                 TeamBalance_Destroy(balance);
511                         }
512                         if (team_num)
513                                 ClientKill_TeamChange(caller, team_num);
514                         else // auto
515                                 ClientKill_TeamChange(caller, -1);
516
517                         if (!IS_PLAYER(caller))
518                         {
519                                 caller.team_selected = true; // avoids asking again for team selection on join
520                         }
521                         return;
522                 }
523                 default:
524                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
525                 case CMD_REQUEST_USAGE:
526                 {
527                         sprint(caller, "\nUsage:^3 cmd selectteam <team>\n");
528                         sprint(caller, "  Where <team> is the prefered team to try and join.\n");
529                         sprint(caller, "  Full list of options here: red, blue, yellow, pink, auto.\n");
530                         return;
531                 }
532         }
533 }
534
535 void ClientCommand_selfstuff(entity caller, int request, string command)
536 {
537         switch (request)
538         {
539                 case CMD_REQUEST_COMMAND:
540                 {
541                         if (argv(1) != "")
542                         {
543                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
544                                 return;
545                         }
546                 }
547
548                 default:
549                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
550                 case CMD_REQUEST_USAGE:
551                 {
552                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
553                         sprint(caller, "  Where <command> is the string to be stuffed to your client.\n");
554                         return;
555                 }
556         }
557 }
558
559 void ClientCommand_sentcvar(entity caller, int request, int argc)
560 {
561         switch (request)
562         {
563                 case CMD_REQUEST_COMMAND:
564                 {
565                         if (argc >= 3)
566                         {
567                         // NOTE: client-side settings do not exist on the server, this functionality has been deprecated
568                         #if 0
569                                 if (argc == 2)  // undefined cvar: use the default value on the server then
570                                 {
571                                         string s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
572                                         tokenize_console(s);
573                                 }
574                         #endif
575
576                                 GetCvars(caller, CS_CVAR(caller), 1);
577
578                                 return;
579                         }
580                 }
581
582                 default:
583                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
584                 case CMD_REQUEST_USAGE:
585                 {
586                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar> <arguments>\n");
587                         sprint(caller, "  Where <cvar> is the cvar plus arguments to send to the server.\n");
588                         return;
589                 }
590         }
591 }
592
593 void ClientCommand_spectate(entity caller, int request)
594 {
595         switch (request)
596         {
597                 case CMD_REQUEST_COMMAND:
598                 {
599                         if (!intermission_running && IS_CLIENT(caller))
600                         {
601                                 if(argv(1) != "")
602                                 {
603                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
604                                         {
605                                                 entity client = GetFilteredEntity(argv(1));
606                                                 int spec_accepted = VerifyClientEntity(client, false, false);
607                                                 if(spec_accepted > 0 && IS_PLAYER(client))
608                                                 {
609                                                         bool caller_is_observer = (IS_OBSERVER(caller));
610                                                         Spectate(caller, client);
611                                                         if (caller_is_observer)
612                                                                 TRANSMUTE(Spectator, caller);
613                                                 }
614                                                 else
615                                                         sprint(caller, "Can't spectate ", argv(1), "^7\n");
616                                         }
617                                         else
618                                                 sprint(caller, "cmd spectate <client> only works when you are spectator/observer\n");
619                                         return;
620                                 }
621
622                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
623
624                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
625
626                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
627                                 if (autocvar_sv_spectate == 1)
628                                         ClientKill_TeamChange(caller, -2); // observe
629                         }
630                         return; // never fall through to usage
631                 }
632
633                 default:
634                 case CMD_REQUEST_USAGE:
635                 {
636                         sprint(caller, "\nUsage:^3 cmd spectate [<client>]\n");
637                         sprint(caller, "  Where <client> can be the player to spectate.\n");
638                         return;
639                 }
640         }
641 }
642
643 void ClientCommand_suggestmap(entity caller, int request, int argc)
644 {
645         switch (request)
646         {
647                 case CMD_REQUEST_COMMAND:
648                 {
649                         if (argv(1) != "")
650                         {
651                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
652                                 return;
653                         }
654                 }
655
656                 default:
657                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
658                 case CMD_REQUEST_USAGE:
659                 {
660                         sprint(caller, "\nUsage:^3 cmd suggestmap <map>\n");
661                         sprint(caller, "  Where <map> is the name of the map to suggest.\n");
662                         return;
663                 }
664         }
665 }
666
667 void ClientCommand_tell(entity caller, int request, int argc, string command)
668 {
669         switch (request)
670         {
671                 case CMD_REQUEST_COMMAND:
672                 {
673                         if (argc >= 3)
674                         {
675                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
676                                 {
677                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
678                                         return;
679                                 }
680
681                                 entity tell_to = GetIndexedEntity(argc, 1);
682                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
683
684                                 if (tell_accepted > 0)   // the target is a real client
685                                 {
686                                         if (tell_to != caller) // and we're allowed to send to them :D
687                                         {
688                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
689                                                 // In this case when the player name contains utf8 chars
690                                                 // the message gets partially trimmed in the beginning.
691                                                 // Potentially this bug affects any substring call that uses
692                                                 // argv_start_index and argv_end_index.
693
694                                                 string utf8_enable_save = cvar_string("utf8_enable");
695                                                 cvar_set("utf8_enable", "0");
696                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
697                                                 cvar_set("utf8_enable", utf8_enable_save);
698
699                                                 Say(caller, false, tell_to, msg, true);
700                                                 return;
701                                         }
702                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
703                                 }
704                                 else if (argv(1) == "#0")
705                                 {
706                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
707                                         return;
708                                 }
709                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
710                         }
711                 }
712
713                 default:
714                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
715                 case CMD_REQUEST_USAGE:
716                 {
717                         sprint(caller, "\nUsage:^3 cmd tell <client> <message>\n");
718                         sprint(caller, "  Where <client> is the entity number or name of the player to send <message> to.\n");
719                         return;
720                 }
721         }
722 }
723
724 void ClientCommand_voice(entity caller, int request, int argc, string command)
725 {
726         switch (request)
727         {
728                 case CMD_REQUEST_COMMAND:
729                 {
730                         if (argv(1) != "")
731                         {
732                                 entity e = GetVoiceMessage(argv(1));
733                                 if (!e)
734                                 {
735                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
736                                         return;
737                                 }
738                                 if (IS_DEAD(caller))
739                                 {
740                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
741                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
742                                         return;
743                                 }
744                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
745                                 {
746                                         // observers/spectators have no player model of their own to play taunts from
747                                         // again, allow them to see warnings
748                                         return;
749                                 }
750                                 string msg = "";
751                                 if (argc >= 3)
752                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
753                                 VoiceMessage(caller, e, msg);
754
755                                 return;
756                         }
757                 }
758
759                 default:
760                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
761                 case CMD_REQUEST_USAGE:
762                 {
763                         sprint(caller, "\nUsage:^3 cmd voice <voicetype> [<message>]\n");
764                         sprint(caller, "  <voicetype> is the type of voice message, it can be one of these:\n");
765                         sprint(caller, sprintf("   %s\n", allvoicesamples));
766                         sprint(caller, "  and <message> is the text message to send.\n");
767                         return;
768                 }
769         }
770 }
771
772 /* use this when creating a new command, making sure to place it in alphabetical order... also,
773 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
774 void ClientCommand_(entity caller, int request)
775 {
776     switch(request)
777     {
778         case CMD_REQUEST_COMMAND:
779         {
780
781             return; // never fall through to usage
782         }
783
784         default:
785         case CMD_REQUEST_USAGE:
786         {
787             sprint(caller, "\nUsage:^3 cmd \n");
788             sprint(caller, "  No arguments required.\n");
789             return;
790         }
791     }
792 }
793 */
794
795
796 // =====================================
797 //  Macro system for networked commands
798 // =====================================
799
800 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
801 #define CLIENT_COMMANDS(ent, request, arguments, command) \
802         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
803         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
804         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
805         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
806         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
807         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
808         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
809         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
810         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
811         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
812         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
813         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
814         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments), "New system for sending a client cvar to the server") \
815         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
816         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
817         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
818         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
819         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
820         /* nothing */
821
822 void ClientCommand_macro_help(entity caller)
823 {
824         #define CLIENT_COMMAND(name, function, description) \
825                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
826
827         CLIENT_COMMANDS(NULL, 0, 0, "");
828 #undef CLIENT_COMMAND
829 }
830
831 float ClientCommand_macro_command(int argc, entity caller, string command)
832 {
833         #define CLIENT_COMMAND(name, function, description) \
834                 { if (name == strtolower(argv(0))) { function; return true; } }
835
836         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
837 #undef CLIENT_COMMAND
838
839         return false;
840 }
841
842 float ClientCommand_macro_usage(int argc, entity caller)
843 {
844         #define CLIENT_COMMAND(name, function, description) \
845                 { if (name == strtolower(argv(1))) { function; return true; } }
846
847         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
848 #undef CLIENT_COMMAND
849
850         return false;
851 }
852
853 void ClientCommand_macro_write_aliases(float fh)
854 {
855         #define CLIENT_COMMAND(name, function, description) \
856                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
857
858         CLIENT_COMMANDS(NULL, 0, 0, "");
859 #undef CLIENT_COMMAND
860 }
861
862 // ======================================
863 //  Main Function Called By Engine (cmd)
864 // ======================================
865 // If this function exists, server game code parses clientcommand before the engine code gets it.
866
867 void SV_ParseClientCommand(entity this, string command)
868 {
869         // If invalid UTF-8, don't even parse it
870         string command2 = "";
871         float len = strlen(command);
872         float i;
873         for (i = 0; i < len; ++i)
874                 command2 = strcat(command2, chr2str(str2chr(command, i)));
875         if (command != command2) return;
876
877         // if we're banned, don't even parse the command
878         if (Ban_MaybeEnforceBanOnce(this)) return;
879
880         int argc = tokenize_console(command);
881
882         // Guide for working with argc arguments by example:
883         // argc:   1    - 2      - 3     - 4
884         // argv:   0    - 1      - 2     - 3
885         // cmd     vote - master - login - password
886
887         // for floodcheck
888         switch (strtolower(argv(0)))
889         {
890                 // exempt commands which are not subject to floodcheck
891                 case "begin": break;                               // handled by engine in host_cmd.c
892                 case "download": break;                            // handled by engine in cl_parse.c
893                 case "mv_getpicture": break;                       // handled by server in this file
894                 case "wpeditor": break;                            // handled by server in this file
895                 case "pause": break;                               // handled by engine in host_cmd.c
896                 case "prespawn": break;                            // handled by engine in host_cmd.c
897                 case "sentcvar": break;                            // handled by server in this file
898                 case "spawn": break;                               // handled by engine in host_cmd.c
899                 case "color": case "topcolor": case "bottomcolor": // handled by engine in host_cmd.c
900                         if(!IS_CLIENT(this)) // on connection
901                         {
902                                 // since gamecode doesn't have any calls earlier than this, do the connecting message here
903                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
904                         }
905                         if(teamplay)
906                                 return;
907                         break;
908                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
909
910                 default:
911                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
912                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
913         }
914
915         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
916         if (argv(0) == "help")
917         {
918                 if (argc == 1)
919                 {
920                         sprint(this, "\nClient networked commands:\n");
921                         ClientCommand_macro_help(this);
922
923                         sprint(this, "\nCommon networked commands:\n");
924                         CommonCommand_macro_help(this);
925
926                         sprint(this, "\nUsage:^3 cmd <command>^7, where possible commands are listed above.\n");
927                         sprint(this, "For help about a specific command, type cmd help <command>\n");
928                         return;
929                 }
930                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
931                 {
932                         return;
933                 }
934                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
935                 {
936                         return;
937                 }
938         }
939         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
940         {
941                 return;  // handled by a mutator
942         }
943         else if (CheatCommand(this, argc))
944         {
945                 return;  // handled by server/cheats.qc
946         }
947         else if (CommonCommand_macro_command(argc, this, command))
948         {
949                 return;                                          // handled by server/command/common.qc
950         }
951         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
952         {
953                 return;                                          // handled by one of the above ClientCommand_* functions
954         }
955         else
956         {
957                 clientcommand(this, command);
958         }
959 }