Attempt to clean up commands a bit
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / cmd.qc
1 // =========================================================
2 //  Server side networked commands code, reworked by Samual
3 //  Last updated: December 28th, 2011
4 // =========================================================
5
6 float SV_ParseClientCommand_floodcheck()
7 {
8         if (!timeout_status) // not while paused
9         {
10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
11                 {
12                         self.cmd_floodcount += 1;
13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
14                 }
15                 else
16                 {
17                         self.cmd_floodtime = time;
18                         self.cmd_floodcount = 1;
19                 }
20         }
21         return TRUE; // continue, as we're not flooding yet
22 }
23
24
25 // =======================
26 //  Command Sub-Functions
27 // =======================
28
29 void ClientCommand_autoswitch(float request, float argc)
30 {
31         switch(request)
32         {
33                 case CMD_REQUEST_COMMAND:
34                 {
35                         if(argv(1) != "")
36                         {
37                                 self.autoswitch = InterpretBoolean(argv(1));
38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
39                                 return;
40                         }
41                 }
42
43                 default:
44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
45                 case CMD_REQUEST_USAGE:
46                 {
47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
49                         return;
50                 }
51         }
52 }
53
54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
55 {
56         switch(request)
57         {
58                 case CMD_REQUEST_COMMAND:
59                 {
60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
61                         self.checkfail = 1;
62                         return; // never fall through to usage
63                 }
64
65                 default:
66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
67                 case CMD_REQUEST_USAGE:
68                 {
69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
71                         return;
72                 }
73         }
74 }
75
76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
77 {
78         switch(request)
79         {
80                 case CMD_REQUEST_COMMAND:
81                 {
82                         if(argv(1) != "")
83                         {
84                                 if(IS_CLIENT(self))
85                                 {
86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
87
88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
89                                         {
90                                                 self.version_mismatch = 1;
91                                                 ClientKill_TeamChange(-2); // observe
92                                         }
93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
94                                         {
95                                                 //JoinBestTeam(self, FALSE, TRUE);
96                                         }
97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
98                                         {
99                                                 self.classname = "observer"; // really?
100                                                 stuffcmd(self, "menu_showteamselect\n");
101                                         }
102                                 }
103
104                                 return;
105                         }
106                 }
107
108                 default:
109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
110                 case CMD_REQUEST_USAGE:
111                 {
112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
114                         return;
115                 }
116         }
117 }
118
119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
120 {
121         switch(request)
122         {
123                 case CMD_REQUEST_COMMAND:
124                 {
125                         if(argv(1) != "")
126                         {
127                                 if(intermission_running)
128                                         MapVote_SendPicture(stof(argv(1)));
129
130                                 return;
131                         }
132                 }
133
134                 default:
135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
136                 case CMD_REQUEST_USAGE:
137                 {
138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
140                         return;
141                 }
142         }
143 }
144
145 void ClientCommand_join(float request)
146 {
147         switch(request)
148         {
149                 case CMD_REQUEST_COMMAND:
150                 {
151                         if(IS_CLIENT(self))
152                         {
153                                 if(!IS_PLAYER(self) && !lockteams)
154                                 {
155                                         if(nJoinAllowed(self))
156                                         {
157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
158
159                                                 self.classname = "player";
160                                                 PlayerScore_Clear(self);
161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
163                                                 PutClientInServer();
164                                         }
165                                         else
166                                         {
167                                                 //player may not join because of g_maxplayers is set
168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
169                                         }
170                                 }
171                         }
172                         return; // never fall through to usage
173                 }
174
175                 default:
176                 case CMD_REQUEST_USAGE:
177                 {
178                         sprint(self, "\nUsage:^3 cmd join\n");
179                         sprint(self, "  No arguments required.\n");
180                         return;
181                 }
182         }
183 }
184
185 void ClientCommand_mobedit(float request, float argc)
186 {
187         switch(request)
188         {
189                 case CMD_REQUEST_COMMAND:
190                 {
191                         if(argv(1) && argv(2))
192                         {
193                                 makevectors(self.v_angle);
194                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
195                                 
196                                 if(!(trace_ent.flags & FL_MONSTER)) { sprint(self, "You need to aim at your monster to edit its properties.\n"); }
197                                 else if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); }
198                                 else // all went well, continue
199                                 {
200                                         switch(argv(1))
201                                         {
202                                                 case "skin":
203                                                 {
204                                                         if(trace_ent.monsterid != MON_MAGE)
205                                                                 trace_ent.skin = stof(argv(2));
206                                                         break;
207                                                 }
208                                                 case "movetarget":
209                                                 {
210                                                         trace_ent.monster_moveflags = stof(argv(2));
211                                                         break;
212                                                 }
213                                         }
214                                 }
215                         }
216                 }
217                 default:
218                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
219                 case CMD_REQUEST_USAGE:
220                 {
221                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
222                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
223                         return;
224                 }
225         }
226 }
227
228 void ClientCommand_mobkill(float request)
229 {
230         switch(request)
231         {
232                 case CMD_REQUEST_COMMAND:
233                 {
234                         makevectors(self.v_angle);
235                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
236                         
237                         if(trace_ent.flags & FL_MONSTER)
238                         {
239                                 if(trace_ent.realowner != self)
240                                 {
241                                         sprint(self, "That monster does not belong to you.\n");
242                                         return;
243                                 }
244                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
245                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
246                                 return;
247                         }
248                         else
249                                 sprint(self, "You need to aim at your monster to kill it.\n");
250                         
251                         return;
252                 }
253         
254                 default:
255                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
256                 case CMD_REQUEST_USAGE:
257                 {
258                         sprint(self, "\nUsage:^3 cmd mobkill\n");
259                         sprint(self, "  Aim at your monster to kill it.\n");
260                         return;
261                 }
262         }
263 }
264
265 void ClientCommand_mobspawn(float request, float argc)
266 {
267         switch(request)
268         {
269                 case CMD_REQUEST_COMMAND:
270                 {
271                         entity e;
272                         string tospawn;
273                         float moveflag;
274                         
275                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
276                         tospawn = strtolower(argv(1));
277                         
278                         if(tospawn == "list")
279                         {
280                                 sprint(self, monsterlist_reply);
281                                 return;
282                         }
283                         
284                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
285                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
286                         else if(tospawn == "") { sprint(self, "No argument specified.\n"); }
287                         else if(g_invasion) { sprint(self, "You can't spawn monsters during an invasion!\n"); }
288                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
289                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
290                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
291                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); }
292                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
293                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
294                         else // all worked out, so continue
295                         {
296                                 self.monstercount += 1;
297                                 totalspawned += 1;
298                         
299                                 makevectors(self.v_angle);
300                                 WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
301                                 //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
302                         
303                                 e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
304                                 
305                                 sprint(self, strcat("Spawned ", e.monster_name, "\n"));
306                         }
307                         
308                         return;
309                 }
310         
311                 default:
312                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
313                 case CMD_REQUEST_USAGE:
314                 {
315                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
316                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
317                         sprint(self, "  Argument 'random' spawns a random monster.\n");
318                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
319                         return;
320                 }
321         }
322 }
323
324 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
325 {
326         switch(request)
327         {
328                 case CMD_REQUEST_COMMAND:
329                 {
330                         if(IS_CLIENT(self))
331                         {
332                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
333                                 {
334                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
335                                         {
336                                                 if(time < game_starttime) // game is already restarting
337                                                         return;
338                                                 if (self.ready) // toggle
339                                                 {
340                                                         self.ready = FALSE;
341                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
342                                                 }
343                                                 else
344                                                 {
345                                                         self.ready = TRUE;
346                                                         bprint(self.netname, "^2 is ready\n");
347                                                 }
348
349                                                 // cannot reset the game while a timeout is active!
350                                                 if (!timeout_status)
351                                                         ReadyCount();
352                                         } else {
353                                                 sprint(self, "^1Game has already been restarted\n");
354                                         }
355                                 }
356                         }
357                         return; // never fall through to usage
358                 }
359
360                 default:
361                 case CMD_REQUEST_USAGE:
362                 {
363                         sprint(self, "\nUsage:^3 cmd ready\n");
364                         sprint(self, "  No arguments required.\n");
365                         return;
366                 }
367         }
368 }
369
370 void ClientCommand_say(float request, float argc, string command)
371 {
372         switch(request)
373         {
374                 case CMD_REQUEST_COMMAND:
375                 {
376                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
377                         return; // never fall through to usage
378                 }
379
380                 default:
381                 case CMD_REQUEST_USAGE:
382                 {
383                         sprint(self, "\nUsage:^3 cmd say <message>\n");
384                         sprint(self, "  Where 'message' is the string of text to say.\n");
385                         return;
386                 }
387         }
388 }
389
390 void ClientCommand_say_team(float request, float argc, string command)
391 {
392         switch(request)
393         {
394                 case CMD_REQUEST_COMMAND:
395                 {
396                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
397                         return; // never fall through to usage
398                 }
399
400                 default:
401                 case CMD_REQUEST_USAGE:
402                 {
403                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
404                         sprint(self, "  Where 'message' is the string of text to say.\n");
405                         return;
406                 }
407         }
408 }
409
410 void ClientCommand_selectteam(float request, float argc)
411 {
412         switch(request)
413         {
414                 case CMD_REQUEST_COMMAND:
415                 {
416                         if(argv(1) != "")
417                         {
418                                 if(IS_CLIENT(self))
419                                 {
420                                         if(teamplay)
421                                                 if(self.team_forced <= 0)
422                                                         if (!lockteams)
423                                                         {
424                                                                 float selection;
425
426                                                                 switch(argv(1))
427                                                                 {
428                                                                         case "red": selection = NUM_TEAM_1; break;
429                                                                         case "blue": selection = NUM_TEAM_2; break;
430                                                                         case "yellow": selection = NUM_TEAM_3; break;
431                                                                         case "pink": selection = NUM_TEAM_4; break;
432                                                                         case "auto": selection = (-1); break;
433
434                                                                         default: selection = 0; break;
435                                                                 }
436
437                                                                 if(selection)
438                                                                 {
439                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
440                                                                                 sprint(self, "^7You already are on that team.\n");
441                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
442                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
443                                                                         else
444                                                                                 ClientKill_TeamChange(selection);
445                                                                 }
446                                                         }
447                                                         else
448                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
449                                                 else
450                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
451                                         else
452                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
453                                 }
454                                 return;
455                         }
456                 }
457
458                 default:
459                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
460                 case CMD_REQUEST_USAGE:
461                 {
462                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
463                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
464                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
465                         return;
466                 }
467         }
468 }
469
470 void ClientCommand_selfstuff(float request, string command)
471 {
472         switch(request)
473         {
474                 case CMD_REQUEST_COMMAND:
475                 {
476                         if(argv(1) != "")
477                         {
478                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
479                                 return;
480                         }
481                 }
482
483                 default:
484                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
485                 case CMD_REQUEST_USAGE:
486                 {
487                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
488                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
489                         return;
490                 }
491         }
492 }
493
494 void ClientCommand_sentcvar(float request, float argc, string command)
495 {
496         switch(request)
497         {
498                 case CMD_REQUEST_COMMAND:
499                 {
500                         if(argv(1) != "")
501                         {
502                                 //float tokens;
503                                 string s;
504
505                                 if(argc == 2) // undefined cvar: use the default value on the server then
506                                 {
507                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
508                                         tokenize_console(s);
509                                 }
510
511                                 GetCvars(1);
512
513                                 return;
514                         }
515                 }
516
517                 default:
518                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
519                 case CMD_REQUEST_USAGE:
520                 {
521                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
522                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
523                         return;
524                 }
525         }
526 }
527
528 void ClientCommand_spectate(float request)
529 {
530         switch(request)
531         {
532                 case CMD_REQUEST_COMMAND:
533                 {
534                         if(IS_CLIENT(self))
535                         {
536                                 if(g_lms)
537                                 {
538                                         if(self.lms_spectate_warning)
539                                         {
540                                                 // for the forfeit message...
541                                                 self.lms_spectate_warning = 2;
542                                                 // mark player as spectator
543                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
544                                         }
545                                         else
546                                         {
547                                                 self.lms_spectate_warning = 1;
548                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
549                                                 return;
550                                         }
551                                 }
552
553                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
554                                         ClientKill_TeamChange(-2); // observe
555
556                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
557                                 // note: if arena game mode is ever done properly, this needs to be removed.
558                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
559                                 {
560                                         sprint(self, "WARNING: you will spectate in the next round.\n");
561                                         self.caplayer = 0;
562                                 }
563                         }
564                         return; // never fall through to usage
565                 }
566
567                 default:
568                 case CMD_REQUEST_USAGE:
569                 {
570                         sprint(self, "\nUsage:^3 cmd spectate\n");
571                         sprint(self, "  No arguments required.\n");
572                         return;
573                 }
574         }
575 }
576
577 void ClientCommand_suggestmap(float request, float argc)
578 {
579         switch(request)
580         {
581                 case CMD_REQUEST_COMMAND:
582                 {
583                         if(argv(1) != "")
584                         {
585                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
586                                 return;
587                         }
588                 }
589
590                 default:
591                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
592                 case CMD_REQUEST_USAGE:
593                 {
594                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
595                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
596                         return;
597                 }
598         }
599 }
600
601 void ClientCommand_tell(float request, float argc, string command)
602 {
603         switch(request)
604         {
605                 case CMD_REQUEST_COMMAND:
606                 {
607                         if(argc >= 3)
608                         {
609                                 entity tell_to = GetIndexedEntity(argc, 1);
610                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
611
612                                 if(tell_accepted > 0) // the target is a real client
613                                 {
614                                         if(tell_to != self) // and we're allowed to send to them :D
615                                         {
616                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
617                                                 return;
618                                         }
619                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
620                                 }
621                                 else if(argv(1) == "#0")
622                                 {
623                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
624                                         return;
625                                 }
626                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
627                         }
628                 }
629
630                 default:
631                         sprint(self, "Incorrect parameters for ^2tell^7\n");
632                 case CMD_REQUEST_USAGE:
633                 {
634                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
635                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
636                         return;
637                 }
638         }
639 }
640
641 void ClientCommand_voice(float request, float argc, string command)
642 {
643         switch(request)
644         {
645                 case CMD_REQUEST_COMMAND:
646                 {
647                         if(argv(1) != "")
648                         {
649                                 if(argc >= 3)
650                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
651                                 else
652                                         VoiceMessage(argv(1), "");
653
654                                 return;
655                         }
656                 }
657
658                 default:
659                         sprint(self, "Incorrect parameters for ^2voice^7\n");
660                 case CMD_REQUEST_USAGE:
661                 {
662                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
663                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
664                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
665                         return;
666                 }
667         }
668 }
669
670 /* use this when creating a new command, making sure to place it in alphabetical order... also,
671 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
672 void ClientCommand_(float request)
673 {
674         switch(request)
675         {
676                 case CMD_REQUEST_COMMAND:
677                 {
678
679                         return; // never fall through to usage
680                 }
681
682                 default:
683                 case CMD_REQUEST_USAGE:
684                 {
685                         sprint(self, "\nUsage:^3 cmd \n");
686                         sprint(self, "  No arguments required.\n");
687                         return;
688                 }
689         }
690 }
691 */
692
693
694 // =====================================
695 //  Macro system for networked commands
696 // =====================================
697
698 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
699 #define CLIENT_COMMANDS(request,arguments,command) \
700         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
701         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
702         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
703         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
704         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
705         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
706         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
707         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
708         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
709         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
710         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
711         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
712         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
713         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
714         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
715         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
716         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
717         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
718         /* nothing */
719
720 void ClientCommand_macro_help()
721 {
722         #define CLIENT_COMMAND(name,function,description) \
723                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
724
725         CLIENT_COMMANDS(0, 0, "")
726         #undef CLIENT_COMMAND
727
728         return;
729 }
730
731 float ClientCommand_macro_command(float argc, string command)
732 {
733         #define CLIENT_COMMAND(name,function,description) \
734                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
735
736         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
737         #undef CLIENT_COMMAND
738
739         return FALSE;
740 }
741
742 float ClientCommand_macro_usage(float argc)
743 {
744         #define CLIENT_COMMAND(name,function,description) \
745                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
746
747         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
748         #undef CLIENT_COMMAND
749
750         return FALSE;
751 }
752
753 void ClientCommand_macro_write_aliases(float fh)
754 {
755         #define CLIENT_COMMAND(name,function,description) \
756                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
757
758         CLIENT_COMMANDS(0, 0, "")
759         #undef CLIENT_COMMAND
760
761         return;
762 }
763
764 // ======================================
765 //  Main Function Called By Engine (cmd)
766 // ======================================
767 // If this function exists, server game code parses clientcommand before the engine code gets it.
768
769 void SV_ParseClientCommand(string command)
770 {
771         // if we're banned, don't even parse the command
772         if(Ban_MaybeEnforceBanOnce(self))
773                 return;
774
775         float argc = tokenize_console(command);
776
777         // for the mutator hook system
778         cmd_name = strtolower(argv(0));
779         cmd_argc = argc;
780         cmd_string = command;
781
782         // Guide for working with argc arguments by example:
783         // argc:   1    - 2      - 3     - 4
784         // argv:   0    - 1      - 2     - 3
785         // cmd     vote - master - login - password
786
787         // for floodcheck
788         switch(strtolower(argv(0)))
789         {
790                 // exempt commands which are not subject to floodcheck
791                 case "begin": break; // handled by engine in host_cmd.c
792                 case "download": break; // handled by engine in cl_parse.c
793                 case "mv_getpicture": break; // handled by server in this file
794                 case "pause": break; // handled by engine in host_cmd.c
795                 case "prespawn": break; // handled by engine in host_cmd.c
796                 case "sentcvar": break; // handled by server in this file
797                 case "spawn": break; // handled by engine in host_cmd.c
798
799                 default:
800                         if(SV_ParseClientCommand_floodcheck())
801                                 break; // "TRUE": continue, as we're not flooding yet
802                         else
803                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
804         }
805
806         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
807         if(argv(0) == "help")
808         {
809                 if(argc == 1)
810                 {
811                         sprint(self, "\nClient networked commands:\n");
812                         ClientCommand_macro_help();
813
814                         sprint(self, "\nCommon networked commands:\n");
815                         CommonCommand_macro_help(self);
816
817                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
818                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
819                         return;
820                 }
821                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
822                 {
823                         return;
824                 }
825                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
826                 {
827                         return;
828                 }
829         }
830         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
831         {
832                 return; // handled by a mutator
833         }
834         else if(CheatCommand(argc))
835         {
836                 return; // handled by server/cheats.qc
837         }
838         else if(CommonCommand_macro_command(argc, self, command))
839         {
840                 return; // handled by server/command/common.qc
841         }
842         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
843         {
844                 return; // handled by one of the above ClientCommand_* functions
845         }
846         else
847                 clientcommand(self, command);
848 }