qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(1))
 156                                         {
 157                                                 if(g_ca) { self.caplayer = 1; }
 158                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 159
 160                                                 self.classname = "player";
 161                                                 PlayerScore_Clear(self);
 162                                                 bprint ("^4", self.netname, "^4 is playing now\n");
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 centerprint(self, PREVENT_JOIN_TEXT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(self.flags & FL_CLIENT)
 192                         {
 193                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 194                                 {
 195                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 196                                         {
 197                                                 if (self.ready) // toggle
 198                                                 {
 199                                                         self.ready = FALSE;
 200                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 201                                                 }
 202                                                 else
 203                                                 {
 204                                                         self.ready = TRUE;
 205                                                         bprint(self.netname, "^2 is ready\n");
 206                                                 }
 207
 208                                                 // cannot reset the game while a timeout is active!
 209                                                 if not(timeout_status)
 210                                                         ReadyCount();
 211                                         } else {
 212                                                 sprint(self, "^1Game has already been restarted\n");
 213                                         }
 214                                 }
 215                         }
 216                         return; // never fall through to usage
 217                 }
 218
 219                 default:
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         sprint(self, "\nUsage:^3 cmd ready\n");
 223                         sprint(self, "  No arguments required.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void ClientCommand_reportcvar(float request, float argc, string command)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         if(argv(1) != "")
 236                         {
 237                                 float tokens;
 238                                 string s;
 239
 240                                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
 241                                 {
 242                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 243                                         tokens = tokenize_console(s);
 244                                 }
 245
 246                                 GetCvars(1);
 247
 248                                 return;
 249                         }
 250                 }
 251
 252                 default:
 253                         sprint(self, "Incorrect parameters for ^2reportcvar^7\n");
 254                 case CMD_REQUEST_USAGE:
 255                 {
 256                         sprint(self, "\nUsage:^3 cmd reportcvar <cvar>\n");
 257                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 258                         return;
 259                 }
 260         }
 261 }
 262
 263 void ClientCommand_say(float request, float argc, string command)
 264 {
 265         switch(request)
 266         {
 267                 case CMD_REQUEST_COMMAND:
 268                 {
 269                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 270                         return; // never fall through to usage
 271                 }
 272
 273                 default:
 274                 case CMD_REQUEST_USAGE:
 275                 {
 276                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 277                         sprint(self, "  Where 'message' is the string of text to say.\n");
 278                         return;
 279                 }
 280         }
 281 }
 282
 283 void ClientCommand_say_team(float request, float argc, string command)
 284 {
 285         switch(request)
 286         {
 287                 case CMD_REQUEST_COMMAND:
 288                 {
 289                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 290                         return; // never fall through to usage
 291                 }
 292
 293                 default:
 294                 case CMD_REQUEST_USAGE:
 295                 {
 296                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 297                         sprint(self, "  Where 'message' is the string of text to say.\n");
 298                         return;
 299                 }
 300         }
 301 }
 302
 303 void ClientCommand_selectteam(float request, float argc)
 304 {
 305         switch(request)
 306         {
 307                 case CMD_REQUEST_COMMAND:
 308                 {
 309                         if(argv(1) != "")
 310                         {
 311                                 if(self.flags & FL_CLIENT)
 312                                 {
 313                                         if(teamplay)
 314                                                 if not(self.team_forced > 0)
 315                                                         if not(lockteams)
 316                                                         {
 317                                                                 float selection;
 318
 319                                                                 switch(argv(1))
 320                                                                 {
 321                                                                         case "red": selection = COLOR_TEAM1; break;
 322                                                                         case "blue": selection = COLOR_TEAM2; break;
 323                                                                         case "yellow": selection = COLOR_TEAM3; break;
 324                                                                         case "pink": selection = COLOR_TEAM4; break;
 325                                                                         case "auto": selection = (-1); break;
 326
 327                                                                         default: break;
 328                                                                 }
 329
 330                                                                 if(selection)
 331                                                                 {
 332                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 333                                                                                 sprint(self, "^7You already are on that team.\n");
 334                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 335                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 336                                                                         else
 337                                                                                 ClientKill_TeamChange(selection);
 338                                                                 }
 339                                                         }
 340                                                         else
 341                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 342                                                 else
 343                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 344                                         else
 345                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 346                                 }
 347                                 return;
 348                         }
 349                 }
 350
 351                 default:
 352                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 353                 case CMD_REQUEST_USAGE:
 354                 {
 355                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 356                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 357                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 358                         return;
 359                 }
 360         }
 361 }
 362
 363 void ClientCommand_selfstuff(float request, string command)
 364 {
 365         switch(request)
 366         {
 367                 case CMD_REQUEST_COMMAND:
 368                 {
 369                         if(argv(1) != "")
 370                         {
 371                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 372                                 return;
 373                         }
 374                 }
 375
 376                 default:
 377                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 378                 case CMD_REQUEST_USAGE:
 379                 {
 380                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 381                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 382                         return;
 383                 }
 384         }
 385 }
 386
 387 void ClientCommand_sentcvar(float request, float argc, string command)
 388 {
 389         switch(request)
 390         {
 391                 case CMD_REQUEST_COMMAND:
 392                 {
 393                         if(argv(1) != "")
 394                         {
 395                                 float tokens;
 396                                 string s;
 397
 398                                 if(argc == 2) // undefined cvar: use the default value on the server then
 399                                 {
 400                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 401                                         tokens = tokenize_console(s);
 402                                 }
 403
 404                                 GetCvars(1);
 405
 406                                 return;
 407                         }
 408                 }
 409
 410                 default:
 411                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 412                 case CMD_REQUEST_USAGE:
 413                 {
 414                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 415                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 416                         return;
 417                 }
 418         }
 419 }
 420
 421 void ClientCommand_spectate(float request)
 422 {
 423         switch(request)
 424         {
 425                 case CMD_REQUEST_COMMAND:
 426                 {
 427                         if(self.flags & FL_CLIENT)
 428                         {
 429                                 if(g_arena) { return; }
 430                                 if(g_lms)
 431                                 {
 432                                         if(self.lms_spectate_warning)
 433                                         {
 434                                                 // mark player as spectator
 435                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 436                                         }
 437                                         else
 438                                         {
 439                                                 self.lms_spectate_warning = 1;
 440                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 441                                                 return;
 442                                         }
 443                                 }
 444
 445                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 446                                         ClientKill_TeamChange(-2); // observe
 447
 448                                 // in CA, allow a dead player to move to spectatators (without that, caplayer!=0 will be moved back to the player list)
 449                                 // note: if arena game mode is ever done properly, this needs to be removed.
 450                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 451                                 {
 452                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 453                                         self.caplayer = 0;
 454                                 }
 455                         }
 456                         return; // never fall through to usage
 457                 }
 458
 459                 default:
 460                 case CMD_REQUEST_USAGE:
 461                 {
 462                         sprint(self, "\nUsage:^3 cmd spectate\n");
 463                         sprint(self, "  No arguments required.\n");
 464                         return;
 465                 }
 466         }
 467 }
 468
 469 void ClientCommand_suggestmap(float request, float argc)
 470 {
 471         switch(request)
 472         {
 473                 case CMD_REQUEST_COMMAND:
 474                 {
 475                         if(argv(1) != "")
 476                         {
 477                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 478                                 return;
 479                         }
 480                 }
 481
 482                 default:
 483                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 484                 case CMD_REQUEST_USAGE:
 485                 {
 486                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 487                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 488                         return;
 489                 }
 490         }
 491 }
 492
 493 void ClientCommand_tell(float request, float argc, string command)
 494 {
 495         switch(request)
 496         {
 497                 case CMD_REQUEST_COMMAND:
 498                 {
 499                         if(argc >= 3)
 500                         {
 501                                 entity tell_to = GetIndexedEntity(argc, 1);
 502                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 503
 504                                 if(tell_accepted > 0) // the target is a real client
 505                                 {
 506                                         if(tell_to != self) // and we're allowed to send to them :D
 507                                         {
 508                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 509                                                 return;
 510                                         }
 511                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 512                                 }
 513                                 else if(argv(1) == "#0")
 514                                 {
 515                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 516                                         return;
 517                                 }
 518                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 519                         }
 520                 }
 521
 522                 default:
 523                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 524                 case CMD_REQUEST_USAGE:
 525                 {
 526                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 527                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 528                         return;
 529                 }
 530         }
 531 }
 532
 533 void ClientCommand_voice(float request, float argc, string command)
 534 {
 535         switch(request)
 536         {
 537                 case CMD_REQUEST_COMMAND:
 538                 {
 539                         if(argv(1) != "")
 540                         {
 541                                 if(argc >= 3)
 542                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 543                                 else
 544                                         VoiceMessage(argv(1), "");
 545
 546                                 return;
 547                         }
 548                 }
 549
 550                 default:
 551                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 552                 case CMD_REQUEST_USAGE:
 553                 {
 554                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 555                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 556                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 557                         return;
 558                 }
 559         }
 560 }
 561
 562 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 563 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 564 void ClientCommand_(float request)
 565 {
 566         switch(request)
 567         {
 568                 case CMD_REQUEST_COMMAND:
 569                 {
 570
 571                         return; // never fall through to usage
 572                 }
 573
 574                 default:
 575                 case CMD_REQUEST_USAGE:
 576                 {
 577                         sprint(self, "\nUsage:^3 cmd \n");
 578                         sprint(self, "  No arguments required.\n");
 579                         return;
 580                 }
 581         }
 582 }
 583 */
 584
 585
 586 // =====================================
 587 //  Macro system for networked commands
 588 // =====================================
 589
 590 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 591 #define CLIENT_COMMANDS(request,arguments,command) \
 592         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 593         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 594         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 595         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 596         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 597         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 598         CLIENT_COMMAND("reportcvar", ClientCommand_reportcvar(request, arguments, command), "Old system for sending a client cvar to the server") \
 599         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 600         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 601         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 602         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 603         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 604         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 605         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 606         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 607         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 608         /* nothing */
 609
 610 void ClientCommand_macro_help()
 611 {
 612         #define CLIENT_COMMAND(name,function,description) \
 613                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 614
 615         CLIENT_COMMANDS(0, 0, "")
 616         #undef CLIENT_COMMAND
 617
 618         return;
 619 }
 620
 621 float ClientCommand_macro_command(float argc, string command)
 622 {
 623         #define CLIENT_COMMAND(name,function,description) \
 624                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 625
 626         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 627         #undef CLIENT_COMMAND
 628
 629         return FALSE;
 630 }
 631
 632 float ClientCommand_macro_usage(float argc)
 633 {
 634         #define CLIENT_COMMAND(name,function,description) \
 635                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 636
 637         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 638         #undef CLIENT_COMMAND
 639
 640         return FALSE;
 641 }
 642
 643 void ClientCommand_macro_write_aliases(float fh)
 644 {
 645         #define CLIENT_COMMAND(name,function,description) \
 646                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 647
 648         CLIENT_COMMANDS(0, 0, "")
 649         #undef CLIENT_COMMAND
 650
 651         return;
 652 }
 653
 654 // ======================================
 655 //  Main Function Called By Engine (cmd)
 656 // ======================================
 657 // If this function exists, server game code parses clientcommand before the engine code gets it.
 658
 659 void SV_ParseClientCommand(string command)
 660 {
 661         float argc = tokenize_console(command);
 662
 663         // for the mutator hook system
 664         cmd_name = strtolower(argv(0));
 665         cmd_argc = argc;
 666         cmd_string = command;
 667
 668         // Guide for working with argc arguments by example:
 669         // argc:   1    - 2      - 3     - 4
 670         // argv:   0    - 1      - 2     - 3
 671         // cmd     vote - master - login - password
 672
 673         // for floodcheck
 674         switch(strtolower(argv(0)))
 675         {
 676                 // exempt commands which are not subject to floodcheck
 677                 case "begin": break; // handled by engine in host_cmd.c
 678                 case "download": break; // handled by engine in cl_parse.c
 679                 case "mv_getpicture": break; // handled by server in this file
 680                 case "pause": break; // handled by engine in host_cmd.c
 681                 case "prespawn": break; // handled by engine in host_cmd.c
 682                 case "reportcvar": break; // handled by server in this file
 683                 case "sentcvar": break; // handled by server in this file
 684                 case "spawn": break; // handled by engine in host_cmd.c
 685
 686                 default:
 687                         if(SV_ParseClientCommand_floodcheck())
 688                                 break; // "TRUE": continue, as we're not flooding yet
 689                         else
 690                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 691         }
 692
 693         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 694         if(argv(0) == "help")
 695         {
 696                 if(argc == 1)
 697                 {
 698                         sprint(self, "\nClient networked commands:\n");
 699                         ClientCommand_macro_help();
 700
 701                         sprint(self, "\nCommon networked commands:\n");
 702                         CommonCommand_macro_help(self);
 703
 704                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 705                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 706                         return;
 707                 }
 708                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 709                 {
 710                         return;
 711                 }
 712                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 713                 {
 714                         return;
 715                 }
 716         }
 717         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 718         {
 719                 return; // handled by a mutator
 720         }
 721         else if(CheatCommand(argc))
 722         {
 723                 return; // handled by server/cheats.qc
 724         }
 725         else if(CommonCommand_macro_command(argc, self, command))
 726         {
 727                 return; // handled by server/command/common.qc
 728         }
 729         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 730         {
 731                 return; // handled by one of the above ClientCommand_* functions
 732         }
 733         else
 734                 clientcommand(self, command);
 735 }