]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/server/command/cmd.qc
Remove useless weaponarena check
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / cmd.qc
1 // =========================================================
2 //  Server side networked commands code, reworked by Samual
3 //  Last updated: December 28th, 2011
4 // =========================================================
5
6 float SV_ParseClientCommand_floodcheck()
7 {
8         if not(timeout_status) // not while paused
9         {
10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
11                 {
12                         self.cmd_floodcount += 1;
13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
14                 }
15                 else
16                 {
17                         self.cmd_floodtime = time;
18                         self.cmd_floodcount = 1;
19                 }
20         }
21         return TRUE; // continue, as we're not flooding yet
22 }
23
24
25 // =======================
26 //  Command Sub-Functions
27 // =======================
28
29 void ClientCommand_autoswitch(float request, float argc)
30 {
31         switch(request)
32         {
33                 case CMD_REQUEST_COMMAND:
34                 {
35                         if(argv(1) != "")
36                         {
37                                 self.autoswitch = InterpretBoolean(argv(1));
38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
39                                 return;
40                         }
41                 }
42                         
43                 default:
44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
45                 case CMD_REQUEST_USAGE:
46                 {
47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n"); 
49                         return;
50                 }
51         }
52 }
53
54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
55 {
56         switch(request)
57         {
58                 case CMD_REQUEST_COMMAND:
59                 {
60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
61                         self.checkfail = 1;
62                         return; // never fall through to usage
63                 }
64                         
65                 default:
66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
67                 case CMD_REQUEST_USAGE:
68                 {
69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
71                         return;
72                 }
73         }
74 }
75
76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
77 {
78         switch(request)
79         {
80                 case CMD_REQUEST_COMMAND:
81                 {
82                         if(argv(1) != "")
83                         {
84                                 if(self.flags & FL_CLIENT)
85                                 {
86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
87                                         
88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
89                                         {
90                                                 self.version_mismatch = 1;
91                                                 ClientKill_TeamChange(-2); // observe
92                                         } 
93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams) 
94                                         {
95                                                 //JoinBestTeam(self, FALSE, TRUE);
96                                         } 
97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0)) 
98                                         {
99                                                 self.classname = "observer"; // really?
100                                                 stuffcmd(self, "menu_showteamselect\n");
101                                         }
102                                 }
103                                 
104                                 return;
105                         }
106                 }
107                         
108                 default:
109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
110                 case CMD_REQUEST_USAGE:
111                 {
112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
114                         return;
115                 }
116         }
117 }
118
119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
120 {
121         switch(request)
122         {
123                 case CMD_REQUEST_COMMAND:
124                 {
125                         if(argv(1) != "")
126                         {
127                                 if(intermission_running)                                
128                                         MapVote_SendPicture(stof(argv(1)));
129
130                                 return;
131                         }
132                 }
133                         
134                 default:
135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
136                 case CMD_REQUEST_USAGE:
137                 {
138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
140                         return;
141                 }
142         }
143 }
144
145 void ClientCommand_join(float request) 
146 {
147         switch(request)
148         {
149                 case CMD_REQUEST_COMMAND:
150                 {
151                         if(self.flags & FL_CLIENT)
152                         {
153                                 if(self.classname != "player" && !lockteams && !g_arena)
154                                 {
155                                         if(nJoinAllowed(self)) 
156                                         {
157                                                 if(g_ca) { self.caplayer = 1; }
158                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
159                                                 
160                                                 self.classname = "player";
161                                                 PlayerScore_Clear(self);
162                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
163                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
164                                                 PutClientInServer();
165                                         }
166                                         else 
167                                         {
168                                                 //player may not join because of g_maxplayers is set
169                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
170                                         }
171                                 }
172                         }
173                         return; // never fall through to usage
174                 }
175                         
176                 default:
177                 case CMD_REQUEST_USAGE:
178                 {
179                         sprint(self, "\nUsage:^3 cmd join\n");
180                         sprint(self, "  No arguments required.\n");
181                         return;
182                 }
183         }
184 }
185
186 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
187 {
188         switch(request)
189         {
190                 case CMD_REQUEST_COMMAND:
191                 {
192                         if(self.flags & FL_CLIENT)
193                         {
194                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
195                                 {
196                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
197                                         {
198                                                 if (self.ready) // toggle
199                                                 {
200                                                         self.ready = FALSE;
201                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
202                                                 }
203                                                 else
204                                                 {
205                                                         self.ready = TRUE;
206                                                         bprint(self.netname, "^2 is ready\n");
207                                                 }
208
209                                                 // cannot reset the game while a timeout is active!
210                                                 if not(timeout_status)
211                                                         ReadyCount();
212                                         } else {
213                                                 sprint(self, "^1Game has already been restarted\n");
214                                         }
215                                 }
216                         }
217                         return; // never fall through to usage
218                 }
219                         
220                 default:
221                 case CMD_REQUEST_USAGE:
222                 {
223                         sprint(self, "\nUsage:^3 cmd ready\n");
224                         sprint(self, "  No arguments required.\n");
225                         return;
226                 }
227         }
228 }
229
230 void ClientCommand_say(float request, float argc, string command)
231 {
232         switch(request)
233         {
234                 case CMD_REQUEST_COMMAND:
235                 {
236                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
237                         return; // never fall through to usage
238                 }
239                         
240                 default:
241                 case CMD_REQUEST_USAGE:
242                 {
243                         sprint(self, "\nUsage:^3 cmd say <message>\n");
244                         sprint(self, "  Where 'message' is the string of text to say.\n");
245                         return;
246                 }
247         }
248 }
249
250 void ClientCommand_say_team(float request, float argc, string command)
251 {
252         switch(request)
253         {
254                 case CMD_REQUEST_COMMAND:
255                 {
256                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
257                         return; // never fall through to usage
258                 }
259                         
260                 default:
261                 case CMD_REQUEST_USAGE:
262                 {
263                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
264                         sprint(self, "  Where 'message' is the string of text to say.\n");
265                         return;
266                 }
267         }
268 }
269
270 void ClientCommand_selectteam(float request, float argc)
271 {
272         switch(request)
273         {
274                 case CMD_REQUEST_COMMAND:
275                 {
276                         if(argv(1) != "")
277                         {
278                                 if(self.flags & FL_CLIENT)
279                                 {
280                                         if(teamplay)
281                                                 if not(self.team_forced > 0) 
282                                                         if not(lockteams) 
283                                                         {
284                                                                 float selection;
285                                                                 
286                                                                 switch(argv(1))
287                                                                 {
288                                                                         case "red": selection = NUM_TEAM_1; break;
289                                                                         case "blue": selection = NUM_TEAM_2; break;
290                                                                         case "yellow": selection = NUM_TEAM_3; break;
291                                                                         case "pink": selection = NUM_TEAM_4; break;
292                                                                         case "auto": selection = (-1); break;
293                                                                         
294                                                                         default: selection = 0; break;
295                                                                 }
296                                                                 
297                                                                 if(selection)
298                                                                 {
299                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
300                                                                                 sprint(self, "^7You already are on that team.\n");
301                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
302                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
303                                                                         else
304                                                                                 ClientKill_TeamChange(selection);
305                                                                 }
306                                                         }
307                                                         else
308                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
309                                                 else
310                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
311                                         else
312                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
313                                 }
314                                 return; 
315                         }
316                 }
317
318                 default:
319                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
320                 case CMD_REQUEST_USAGE:
321                 {
322                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
323                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
324                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
325                         return;
326                 }
327         }
328 }
329
330 void ClientCommand_selfstuff(float request, string command)
331 {
332         switch(request)
333         {
334                 case CMD_REQUEST_COMMAND:
335                 {
336                         if(argv(1) != "")
337                         {
338                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
339                                 return;
340                         }
341                 }
342                         
343                 default:
344                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
345                 case CMD_REQUEST_USAGE:
346                 {
347                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
348                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
349                         return;
350                 }
351         }
352 }
353
354 void ClientCommand_sentcvar(float request, float argc, string command)
355 {
356         switch(request)
357         {
358                 case CMD_REQUEST_COMMAND:
359                 {
360                         if(argv(1) != "")
361                         {
362                                 //float tokens;
363                                 string s;
364                                 
365                                 if(argc == 2) // undefined cvar: use the default value on the server then
366                                 {
367                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
368                                         tokenize_console(s);
369                                 }
370                                 
371                                 GetCvars(1);
372                                 
373                                 return;
374                         }
375                 }
376                         
377                 default:
378                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
379                 case CMD_REQUEST_USAGE:
380                 {
381                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
382                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
383                         return;
384                 }
385         }
386 }
387
388 void ClientCommand_spectate(float request) 
389 {
390         switch(request)
391         {
392                 case CMD_REQUEST_COMMAND:
393                 {
394                         if(self.flags & FL_CLIENT)
395                         {
396                                 if(g_arena) { return; } 
397                                 if(g_lms)
398                                 {
399                                         if(self.lms_spectate_warning)
400                                         {
401                                                 // for the forfeit message...
402                                                 self.lms_spectate_warning = 2;
403                                                 // mark player as spectator
404                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
405                                         }
406                                         else
407                                         {
408                                                 self.lms_spectate_warning = 1;
409                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
410                                                 return;
411                                         }
412                                 }
413                                 
414                                 if(self.classname == "player" && autocvar_sv_spectate == 1) 
415                                         ClientKill_TeamChange(-2); // observe
416                                 
417                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
418                                 // note: if arena game mode is ever done properly, this needs to be removed.
419                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
420                                 {
421                                         sprint(self, "WARNING: you will spectate in the next round.\n");
422                                         self.caplayer = 0;
423                                 }
424                         }
425                         return; // never fall through to usage
426                 }
427                         
428                 default:
429                 case CMD_REQUEST_USAGE:
430                 {
431                         sprint(self, "\nUsage:^3 cmd spectate\n");
432                         sprint(self, "  No arguments required.\n");
433                         return;
434                 }
435         }
436 }
437
438 void ClientCommand_suggestmap(float request, float argc)
439 {
440         switch(request)
441         {
442                 case CMD_REQUEST_COMMAND:
443                 {
444                         if(argv(1) != "")
445                         {
446                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
447                                 return;
448                         }
449                 }
450                         
451                 default:
452                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
453                 case CMD_REQUEST_USAGE:
454                 {
455                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
456                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
457                         return;
458                 }
459         }
460 }
461
462 void ClientCommand_tell(float request, float argc, string command)
463 {
464         switch(request)
465         {
466                 case CMD_REQUEST_COMMAND:
467                 {
468                         if(argc >= 3)
469                         {
470                                 entity tell_to = GetIndexedEntity(argc, 1);
471                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
472                                 
473                                 if(tell_accepted > 0) // the target is a real client
474                                 {
475                                         if(tell_to != self) // and we're allowed to send to them :D
476                                         {
477                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
478                                                 return;
479                                         }
480                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
481                                 }
482                                 else if(argv(1) == "#0") 
483                                 { 
484                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
485                                         return;
486                                 }
487                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
488                         }
489                 }
490                         
491                 default:
492                         sprint(self, "Incorrect parameters for ^2tell^7\n");
493                 case CMD_REQUEST_USAGE:
494                 {
495                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
496                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
497                         return;
498                 }
499         }
500 }
501
502 void ClientCommand_voice(float request, float argc, string command) 
503 {
504         switch(request)
505         {
506                 case CMD_REQUEST_COMMAND:
507                 {
508                         if(argv(1) != "")
509                         {
510                                 if(argc >= 3)
511                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
512                                 else
513                                         VoiceMessage(argv(1), "");
514                                         
515                                 return;
516                         }
517                 }
518                         
519                 default:
520                         sprint(self, "Incorrect parameters for ^2voice^7\n");
521                 case CMD_REQUEST_USAGE:
522                 {
523                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
524                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
525                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
526                         return;
527                 }
528         }
529 }
530
531 /* use this when creating a new command, making sure to place it in alphabetical order... also,
532 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
533 void ClientCommand_(float request)
534 {
535         switch(request)
536         {
537                 case CMD_REQUEST_COMMAND:
538                 {
539                         
540                         return; // never fall through to usage
541                 }
542                         
543                 default:
544                 case CMD_REQUEST_USAGE:
545                 {
546                         sprint(self, "\nUsage:^3 cmd \n");
547                         sprint(self, "  No arguments required.\n");
548                         return;
549                 }
550         }
551 }
552 */
553
554
555 // =====================================
556 //  Macro system for networked commands
557 // =====================================
558
559 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
560 #define CLIENT_COMMANDS(request,arguments,command) \
561         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
562         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
563         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
564         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
565         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
566         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
567         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
568         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
569         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
570         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
571         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
572         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
573         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
574         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
575         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
576         /* nothing */
577         
578 void ClientCommand_macro_help()
579 {
580         #define CLIENT_COMMAND(name,function,description) \
581                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
582                 
583         CLIENT_COMMANDS(0, 0, "")
584         #undef CLIENT_COMMAND
585         
586         return;
587 }
588
589 float ClientCommand_macro_command(float argc, string command)
590 {
591         #define CLIENT_COMMAND(name,function,description) \
592                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
593                 
594         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
595         #undef CLIENT_COMMAND
596         
597         return FALSE;
598 }
599
600 float ClientCommand_macro_usage(float argc)
601 {
602         #define CLIENT_COMMAND(name,function,description) \
603                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
604                 
605         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
606         #undef CLIENT_COMMAND
607         
608         return FALSE;
609 }
610
611 void ClientCommand_macro_write_aliases(float fh)
612 {
613         #define CLIENT_COMMAND(name,function,description) \
614                 { CMD_Write_Alias("qc_cmd_cmd", name, description); } 
615                 
616         CLIENT_COMMANDS(0, 0, "")
617         #undef CLIENT_COMMAND
618         
619         return;
620 }
621
622 // ======================================
623 //  Main Function Called By Engine (cmd)
624 // ======================================
625 // If this function exists, server game code parses clientcommand before the engine code gets it.
626
627 void SV_ParseClientCommand(string command)
628 {
629         // if we're banned, don't even parse the command
630         if(Ban_MaybeEnforceBanOnce(self))
631                 return;
632
633         float argc = tokenize_console(command);
634         
635         // for the mutator hook system
636         cmd_name = strtolower(argv(0));
637         cmd_argc = argc;
638         cmd_string = command;
639         
640         // Guide for working with argc arguments by example:
641         // argc:   1    - 2      - 3     - 4
642         // argv:   0    - 1      - 2     - 3 
643         // cmd     vote - master - login - password
644         
645         // for floodcheck
646         switch(strtolower(argv(0)))
647         {
648                 // exempt commands which are not subject to floodcheck
649                 case "begin": break; // handled by engine in host_cmd.c
650                 case "download": break; // handled by engine in cl_parse.c
651                 case "mv_getpicture": break; // handled by server in this file
652                 case "pause": break; // handled by engine in host_cmd.c
653                 case "prespawn": break; // handled by engine in host_cmd.c
654                 case "sentcvar": break; // handled by server in this file
655                 case "spawn": break; // handled by engine in host_cmd.c
656                 
657                 default: 
658                         if(SV_ParseClientCommand_floodcheck())
659                                 break; // "TRUE": continue, as we're not flooding yet
660                         else
661                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
662         }
663         
664         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
665         if(argv(0) == "help") 
666         {
667                 if(argc == 1) 
668                 {
669                         sprint(self, "\nClient networked commands:\n");
670                         ClientCommand_macro_help();
671                         
672                         sprint(self, "\nCommon networked commands:\n");
673                         CommonCommand_macro_help(self);
674                         
675                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
676                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
677                         return;
678                 } 
679                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
680                 {
681                         return;
682                 }
683                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
684                 {
685                         return;
686                 }
687         } 
688         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
689         {
690                 return; // handled by a mutator
691         }
692         else if(CheatCommand(argc)) 
693         {
694                 return; // handled by server/cheats.qc
695         }
696         else if(CommonCommand_macro_command(argc, self, command))
697         {
698                 return; // handled by server/command/common.qc
699         }
700         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
701         {
702                 return; // handled by one of the above ClientCommand_* functions
703         }
704         else
705                 clientcommand(self, command);
706 }