qcsrc/server/command/cmd.qc

   1 #include "../../common/command/command.qh"
   2 #include "cmd.qh"
   3
   4 #include "common.qh"
   5 #include "vote.qh"
   6
   7 #include "../campaign.qh"
   8 #include "../cheats.qh"
   9 #include "../cl_player.qh"
  10 #include "../ipban.qh"
  11 #include "../mapvoting.qh"
  12 #include "../scores.qh"
  13 #include "../teamplay.qh"
  14
  15 #include "../mutators/mutators_include.qh"
  16
  17 #ifdef SVQC
  18         #include "../../common/vehicles/all.qh"
  19 #endif
  20
  21 #include "../../common/constants.qh"
  22 #include "../../common/deathtypes/all.qh"
  23 #include "../../common/mapinfo.qh"
  24 #include "../../common/notifications.qh"
  25 #include "../../common/physics.qh"
  26 #include "../../common/teams.qh"
  27 #include "../../common/util.qh"
  28 #include "../../common/triggers/triggers.qh"
  29
  30 #include "../../common/minigames/sv_minigames.qh"
  31
  32 #include "../../common/monsters/all.qc"
  33 #include "../../common/monsters/spawn.qh"
  34 #include "../../common/monsters/sv_monsters.qh"
  35
  36 #include "../../lib/warpzone/common.qh"
  37
  38 void ClientKill_TeamChange (float targetteam); // 0 = don't change, -1 = auto, -2 = spec
  39
  40 // =========================================================
  41 //  Server side networked commands code, reworked by Samual
  42 //  Last updated: December 28th, 2011
  43 // =========================================================
  44
  45 float SV_ParseClientCommand_floodcheck()
  46 {SELFPARAM();
  47         if (!timeout_status) // not while paused
  48         {
  49                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  50                 {
  51                         self.cmd_floodcount += 1;
  52                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return false; } // too much spam, halt
  53                 }
  54                 else
  55                 {
  56                         self.cmd_floodtime = time;
  57                         self.cmd_floodcount = 1;
  58                 }
  59         }
  60         return true; // continue, as we're not flooding yet
  61 }
  62
  63
  64 // =======================
  65 //  Command Sub-Functions
  66 // =======================
  67
  68 void ClientCommand_autoswitch(float request, float argc)
  69 {SELFPARAM();
  70         switch(request)
  71         {
  72                 case CMD_REQUEST_COMMAND:
  73                 {
  74                         if(argv(1) != "")
  75                         {
  76                                 self.autoswitch = InterpretBoolean(argv(1));
  77                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  78                                 return;
  79                         }
  80                 }
  81
  82                 default:
  83                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  84                 case CMD_REQUEST_USAGE:
  85                 {
  86                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  87                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  88                         return;
  89                 }
  90         }
  91 }
  92
  93 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  94 {SELFPARAM();
  95         switch(request)
  96         {
  97                 case CMD_REQUEST_COMMAND:
  98                 {
  99                         if(argv(1) != "")
 100                         {
 101                                 if(IS_CLIENT(self))
 102                                 {
 103                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 104
 105                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
 106                                         {
 107                                                 self.version_mismatch = 1;
 108                                                 ClientKill_TeamChange(-2); // observe
 109                                         }
 110                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
 111                                         {
 112                                                 //JoinBestTeam(self, false, true);
 113                                         }
 114                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
 115                                         {
 116                                                 self.classname = "observer"; // really?
 117                                                 stuffcmd(self, "menu_showteamselect\n");
 118                                         }
 119                                 }
 120
 121                                 return;
 122                         }
 123                 }
 124
 125                 default:
 126                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 127                 case CMD_REQUEST_USAGE:
 128                 {
 129                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 130                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 131                         return;
 132                 }
 133         }
 134 }
 135
 136 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 137 {SELFPARAM();
 138         switch(request)
 139         {
 140                 case CMD_REQUEST_COMMAND:
 141                 {
 142                         if(argv(1) != "")
 143                         {
 144                                 if(intermission_running)
 145                                         MapVote_SendPicture(stof(argv(1)));
 146
 147                                 return;
 148                         }
 149                 }
 150
 151                 default:
 152                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 153                 case CMD_REQUEST_USAGE:
 154                 {
 155                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 156                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 157                         return;
 158                 }
 159         }
 160 }
 161
 162 void ClientCommand_join(float request)
 163 {SELFPARAM();
 164         switch(request)
 165         {
 166                 case CMD_REQUEST_COMMAND:
 167                 {
 168                         if(IS_CLIENT(self))
 169                         {
 170                                 if(!IS_PLAYER(self) && !lockteams && !gameover)
 171                                 {
 172                                         if(self.caplayer)
 173                                                 return;
 174                                         if(nJoinAllowed(self))
 175                                         {
 176                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 177
 178                                                 self.classname = "player";
 179                                                 PlayerScore_Clear(self);
 180                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 181                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 182                                                 PutClientInServer();
 183                                         }
 184                                         else
 185                                         {
 186                                                 //player may not join because of g_maxplayers is set
 187                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 188                                         }
 189                                 }
 190                         }
 191                         return; // never fall through to usage
 192                 }
 193
 194                 default:
 195                 case CMD_REQUEST_USAGE:
 196                 {
 197                         sprint(self, "\nUsage:^3 cmd join\n");
 198                         sprint(self, "  No arguments required.\n");
 199                         return;
 200                 }
 201         }
 202 }
 203
 204 void ClientCommand_physics(float request, float argc)
 205 {SELFPARAM();
 206         switch(request)
 207         {
 208                 case CMD_REQUEST_COMMAND:
 209                 {
 210                         string command = strtolower(argv(1));
 211
 212                         if(!autocvar_g_physics_clientselect)
 213                         {
 214                                 sprint(self, "Client physics selection is currently disabled.\n");
 215                                 return;
 216                         }
 217
 218                         if(command == "list" || command == "help")
 219                         {
 220                                 sprint(self, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 221                                 return;
 222                         }
 223
 224                         if(Physics_Valid(command) || command == "default")
 225                         {
 226                                 stuffcmd(self, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 227                                 sprint(self, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 228                                 return;
 229                         }
 230                 }
 231
 232                 default:
 233                         sprint(self, strcat("Current physics set: ^3", self.cvar_cl_physics, "\n"));
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         sprint(self, "\nUsage:^3 cmd physics <physics>\n");
 237                         sprint(self, "  See 'cmd physics list' for available physics sets.\n");
 238                         sprint(self, "  Argument 'default' resets to standard physics.\n");
 239                         return;
 240                 }
 241         }
 242 }
 243
 244 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 245 {SELFPARAM();
 246         switch(request)
 247         {
 248                 case CMD_REQUEST_COMMAND:
 249                 {
 250                         if(IS_CLIENT(self))
 251                         {
 252                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 253                                 {
 254                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 255                                         {
 256                                                 if(time < game_starttime) // game is already restarting
 257                                                         return;
 258                                                 if (self.ready) // toggle
 259                                                 {
 260                                                         self.ready = false;
 261                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 262                                                 }
 263                                                 else
 264                                                 {
 265                                                         self.ready = true;
 266                                                         bprint(self.netname, "^2 is ready\n");
 267                                                 }
 268
 269                                                 // cannot reset the game while a timeout is active!
 270                                                 if (!timeout_status)
 271                                                         ReadyCount();
 272                                         } else {
 273                                                 sprint(self, "^1Game has already been restarted\n");
 274                                         }
 275                                 }
 276                         }
 277                         return; // never fall through to usage
 278                 }
 279
 280                 default:
 281                 case CMD_REQUEST_USAGE:
 282                 {
 283                         sprint(self, "\nUsage:^3 cmd ready\n");
 284                         sprint(self, "  No arguments required.\n");
 285                         return;
 286                 }
 287         }
 288 }
 289
 290 void ClientCommand_say(float request, float argc, string command)
 291 {SELFPARAM();
 292         switch(request)
 293         {
 294                 case CMD_REQUEST_COMMAND:
 295                 {
 296                         if(argc >= 2) { Say(self, false, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 297                         return; // never fall through to usage
 298                 }
 299
 300                 default:
 301                 case CMD_REQUEST_USAGE:
 302                 {
 303                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 304                         sprint(self, "  Where 'message' is the string of text to say.\n");
 305                         return;
 306                 }
 307         }
 308 }
 309
 310 void ClientCommand_say_team(float request, float argc, string command)
 311 {SELFPARAM();
 312         switch(request)
 313         {
 314                 case CMD_REQUEST_COMMAND:
 315                 {
 316                         if(argc >= 2) { Say(self, true, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 317                         return; // never fall through to usage
 318                 }
 319
 320                 default:
 321                 case CMD_REQUEST_USAGE:
 322                 {
 323                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 324                         sprint(self, "  Where 'message' is the string of text to say.\n");
 325                         return;
 326                 }
 327         }
 328 }
 329
 330 void ClientCommand_selectteam(float request, float argc)
 331 {SELFPARAM();
 332         switch(request)
 333         {
 334                 case CMD_REQUEST_COMMAND:
 335                 {
 336                         if(argv(1) != "")
 337                         {
 338                                 if(IS_CLIENT(self))
 339                                 {
 340                                         if(teamplay)
 341                                                 if(self.team_forced <= 0)
 342                                                         if (!lockteams)
 343                                                         {
 344                                                                 float selection;
 345
 346                                                                 switch(argv(1))
 347                                                                 {
 348                                                                         case "red": selection = NUM_TEAM_1; break;
 349                                                                         case "blue": selection = NUM_TEAM_2; break;
 350                                                                         case "yellow": selection = NUM_TEAM_3; break;
 351                                                                         case "pink": selection = NUM_TEAM_4; break;
 352                                                                         case "auto": selection = (-1); break;
 353
 354                                                                         default: selection = 0; break;
 355                                                                 }
 356
 357                                                                 if(selection)
 358                                                                 {
 359                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 360                                                                                 sprint(self, "^7You already are on that team.\n");
 361                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 362                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 363                                                                         else
 364                                                                         {
 365                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 366                                                                                 {
 367                                                                                         CheckAllowedTeams(self);
 368                                                                                         GetTeamCounts(self);
 369                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 370                                                                                         {
 371                                                                                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 372                                                                                                 return;
 373                                                                                         }
 374                                                                                 }
 375                                                                                 ClientKill_TeamChange(selection);
 376                                                                         }
 377                                                                 }
 378                                                         }
 379                                                         else
 380                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 381                                                 else
 382                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 383                                         else
 384                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 385                                 }
 386                                 return;
 387                         }
 388                 }
 389
 390                 default:
 391                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 392                 case CMD_REQUEST_USAGE:
 393                 {
 394                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 395                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 396                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 397                         return;
 398                 }
 399         }
 400 }
 401
 402 void ClientCommand_selfstuff(float request, string command)
 403 {SELFPARAM();
 404         switch(request)
 405         {
 406                 case CMD_REQUEST_COMMAND:
 407                 {
 408                         if(argv(1) != "")
 409                         {
 410                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 411                                 return;
 412                         }
 413                 }
 414
 415                 default:
 416                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 417                 case CMD_REQUEST_USAGE:
 418                 {
 419                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 420                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 421                         return;
 422                 }
 423         }
 424 }
 425
 426 void ClientCommand_sentcvar(float request, float argc, string command)
 427 {SELFPARAM();
 428         switch(request)
 429         {
 430                 case CMD_REQUEST_COMMAND:
 431                 {
 432                         if(argv(1) != "")
 433                         {
 434                                 //float tokens;
 435                                 string s;
 436
 437                                 if(argc == 2) // undefined cvar: use the default value on the server then
 438                                 {
 439                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 440                                         tokenize_console(s);
 441                                 }
 442
 443                                 GetCvars(1);
 444
 445                                 return;
 446                         }
 447                 }
 448
 449                 default:
 450                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 451                 case CMD_REQUEST_USAGE:
 452                 {
 453                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 454                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 455                         return;
 456                 }
 457         }
 458 }
 459
 460 void ClientCommand_spectate(float request)
 461 {SELFPARAM();
 462         switch(request)
 463         {
 464                 case CMD_REQUEST_COMMAND:
 465                 {
 466                         if(IS_CLIENT(self))
 467                         {
 468                                 if(g_lms)
 469                                 {
 470                                         if(self.lms_spectate_warning)
 471                                         {
 472                                                 // for the forfeit message...
 473                                                 self.lms_spectate_warning = 2;
 474                                                 // mark player as spectator
 475                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 476                                         }
 477                                         else
 478                                         {
 479                                                 self.lms_spectate_warning = 1;
 480                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 481                                                 return;
 482                                         }
 483                                 }
 484
 485                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
 486                                 {
 487                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 488                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_LEAVE);
 489                                         ClientKill_TeamChange(-2); // observe
 490                                 }
 491                         }
 492                         return; // never fall through to usage
 493                 }
 494
 495                 default:
 496                 case CMD_REQUEST_USAGE:
 497                 {
 498                         sprint(self, "\nUsage:^3 cmd spectate\n");
 499                         sprint(self, "  No arguments required.\n");
 500                         return;
 501                 }
 502         }
 503 }
 504
 505 void ClientCommand_suggestmap(float request, float argc)
 506 {SELFPARAM();
 507         switch(request)
 508         {
 509                 case CMD_REQUEST_COMMAND:
 510                 {
 511                         if(argv(1) != "")
 512                         {
 513                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 514                                 return;
 515                         }
 516                 }
 517
 518                 default:
 519                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 520                 case CMD_REQUEST_USAGE:
 521                 {
 522                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 523                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 524                         return;
 525                 }
 526         }
 527 }
 528
 529 void ClientCommand_tell(float request, float argc, string command)
 530 {SELFPARAM();
 531         switch(request)
 532         {
 533                 case CMD_REQUEST_COMMAND:
 534                 {
 535                         if(argc >= 3)
 536                         {
 537                                 entity tell_to = GetIndexedEntity(argc, 1);
 538                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 539
 540                                 if(tell_accepted > 0) // the target is a real client
 541                                 {
 542                                         if(tell_to != self) // and we're allowed to send to them :D
 543                                         {
 544                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 545                                                 // In this case when the player name contains utf8 chars
 546                                                 // the message gets partially trimmed in the beginning.
 547                                                 // Potentially this bug affects any substring call that uses
 548                                                 // argv_start_index and argv_end_index.
 549
 550                                                 string utf8_enable_save = cvar_string("utf8_enable");
 551                                                 cvar_set("utf8_enable", "0");
 552                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 553                                                 cvar_set("utf8_enable", utf8_enable_save);
 554
 555                                                 Say(self, false, tell_to, msg, true);
 556                                                 return;
 557                                         }
 558                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 559                                 }
 560                                 else if(argv(1) == "#0")
 561                                 {
 562                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 563                                         return;
 564                                 }
 565                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 566                         }
 567                 }
 568
 569                 default:
 570                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 571                 case CMD_REQUEST_USAGE:
 572                 {
 573                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 574                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 575                         return;
 576                 }
 577         }
 578 }
 579
 580 void ClientCommand_voice(float request, float argc, string command)
 581 {SELFPARAM();
 582         switch(request)
 583         {
 584                 case CMD_REQUEST_COMMAND:
 585                 {
 586                         if(argv(1) != "")
 587                         {
 588                                 if(argc >= 3)
 589                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 590                                 else
 591                                         VoiceMessage(argv(1), "");
 592
 593                                 return;
 594                         }
 595                 }
 596
 597                 default:
 598                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 599                 case CMD_REQUEST_USAGE:
 600                 {
 601                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 602                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 603                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 604                         return;
 605                 }
 606         }
 607 }
 608
 609 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 610 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 611 void ClientCommand_(float request)
 612 {
 613         switch(request)
 614         {
 615                 case CMD_REQUEST_COMMAND:
 616                 {
 617
 618                         return; // never fall through to usage
 619                 }
 620
 621                 default:
 622                 case CMD_REQUEST_USAGE:
 623                 {
 624                         sprint(self, "\nUsage:^3 cmd \n");
 625                         sprint(self, "  No arguments required.\n");
 626                         return;
 627                 }
 628         }
 629 }
 630 */
 631
 632
 633 // =====================================
 634 //  Macro system for networked commands
 635 // =====================================
 636
 637 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 638 #define CLIENT_COMMANDS(request,arguments,command) \
 639         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 640         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 641         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 642         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 643         CLIENT_COMMAND("physics", ClientCommand_physics(request, arguments), "Change physics set") \
 644         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 645         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 646         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 647         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 648         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 649         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 650         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 651         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 652         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 653         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 654         CLIENT_COMMAND("minigame", ClientCommand_minigame(request, arguments, command), "Start a minigame") \
 655         /* nothing */
 656
 657 void ClientCommand_macro_help()
 658 {SELFPARAM();
 659         #define CLIENT_COMMAND(name,function,description) \
 660                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 661
 662         CLIENT_COMMANDS(0, 0, "");
 663         #undef CLIENT_COMMAND
 664
 665         return;
 666 }
 667
 668 float ClientCommand_macro_command(float argc, string command)
 669 {
 670         #define CLIENT_COMMAND(name,function,description) \
 671                 { if(name == strtolower(argv(0))) { function; return true; } }
 672
 673         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
 674         #undef CLIENT_COMMAND
 675
 676         return false;
 677 }
 678
 679 float ClientCommand_macro_usage(float argc)
 680 {
 681         #define CLIENT_COMMAND(name,function,description) \
 682                 { if(name == strtolower(argv(1))) { function; return true; } }
 683
 684         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "");
 685         #undef CLIENT_COMMAND
 686
 687         return false;
 688 }
 689
 690 void ClientCommand_macro_write_aliases(float fh)
 691 {
 692         #define CLIENT_COMMAND(name,function,description) \
 693                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 694
 695         CLIENT_COMMANDS(0, 0, "");
 696         #undef CLIENT_COMMAND
 697
 698         return;
 699 }
 700
 701 // ======================================
 702 //  Main Function Called By Engine (cmd)
 703 // ======================================
 704 // If this function exists, server game code parses clientcommand before the engine code gets it.
 705
 706 void SV_ParseClientCommand(string command)
 707 {SELFPARAM();
 708         // If invalid UTF-8, don't even parse it
 709         string command2 = "";
 710         float len = strlen(command);
 711         float i;
 712         for (i = 0; i < len; ++i)
 713                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 714         if (command != command2)
 715                 return;
 716
 717         // if we're banned, don't even parse the command
 718         if(Ban_MaybeEnforceBanOnce(self))
 719                 return;
 720
 721         float argc = tokenize_console(command);
 722
 723         // Guide for working with argc arguments by example:
 724         // argc:   1    - 2      - 3     - 4
 725         // argv:   0    - 1      - 2     - 3
 726         // cmd     vote - master - login - password
 727
 728         // for floodcheck
 729         switch(strtolower(argv(0)))
 730         {
 731                 // exempt commands which are not subject to floodcheck
 732                 case "begin": break; // handled by engine in host_cmd.c
 733                 case "download": break; // handled by engine in cl_parse.c
 734                 case "mv_getpicture": break; // handled by server in this file
 735                 case "pause": break; // handled by engine in host_cmd.c
 736                 case "prespawn": break; // handled by engine in host_cmd.c
 737                 case "sentcvar": break; // handled by server in this file
 738                 case "spawn": break; // handled by engine in host_cmd.c
 739
 740                 default:
 741                         if(SV_ParseClientCommand_floodcheck())
 742                                 break; // "true": continue, as we're not flooding yet
 743                         else
 744                                 return; // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 745         }
 746
 747         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 748         if(argv(0) == "help")
 749         {
 750                 if(argc == 1)
 751                 {
 752                         sprint(self, "\nClient networked commands:\n");
 753                         ClientCommand_macro_help();
 754
 755                         sprint(self, "\nCommon networked commands:\n");
 756                         CommonCommand_macro_help(self);
 757
 758                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 759                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 760                         return;
 761                 }
 762                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 763                 {
 764                         return;
 765                 }
 766                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 767                 {
 768                         return;
 769                 }
 770         }
 771         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand, strtolower(argv(0)), argc, command))
 772         {
 773                 return; // handled by a mutator
 774         }
 775         else if(CheatCommand(argc))
 776         {
 777                 return; // handled by server/cheats.qc
 778         }
 779         else if(CommonCommand_macro_command(argc, self, command))
 780         {
 781                 return; // handled by server/command/common.qc
 782         }
 783         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 784         {
 785                 return; // handled by one of the above ClientCommand_* functions
 786         }
 787         else
 788                 clientcommand(self, command);
 789 }