qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../bot/api.qh"
  12
  13 #include "../campaign.qh"
  14 #include "../cheats.qh"
  15 #include "../client.qh"
  16 #include "../clientkill.qh"
  17 #include "../player.qh"
  18 #include "../ipban.qh"
  19 #include "../mapvoting.qh"
  20 #include "../scores.qh"
  21 #include "../teamplay.qh"
  22
  23 #include <server/mutators/_mod.qh>
  24 #include <common/gamemodes/_mod.qh>
  25
  26 #ifdef SVQC
  27         #include <common/vehicles/all.qh>
  28 #endif
  29
  30 #include <common/constants.qh>
  31 #include <common/deathtypes/all.qh>
  32 #include <common/effects/all.qh>
  33 #include <common/mapinfo.qh>
  34 #include <common/notifications/all.qh>
  35 #include <common/physics/player.qh>
  36 #include <common/teams.qh>
  37 #include <common/util.qh>
  38 #include <common/mapobjects/triggers.qh>
  39
  40 #include <common/minigames/sv_minigames.qh>
  41
  42 #include <common/monsters/_mod.qh>
  43 #include <common/monsters/sv_spawn.qh>
  44 #include <common/monsters/sv_monsters.qh>
  45
  46 #include <lib/warpzone/common.qh>
  47
  48 // =========================================================
  49 //  Server side networked commands code, reworked by Samual
  50 //  Last updated: December 28th, 2011
  51 // =========================================================
  52
  53 bool SV_ParseClientCommand_floodcheck(entity this)
  54 {
  55         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  56
  57         if (!timeout_status)  // not while paused
  58         {
  59                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  60                 {
  61                         store.cmd_floodcount += 1;
  62                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  63                 }
  64                 else
  65                 {
  66                         store.cmd_floodtime = time;
  67                         store.cmd_floodcount = 1;
  68                 }
  69         }
  70         return true;  // continue, as we're not flooding yet
  71 }
  72
  73
  74 // =======================
  75 //  Command Sub-Functions
  76 // =======================
  77
  78 void ClientCommand_autoswitch(entity caller, int request, int argc)
  79 {
  80         switch (request)
  81         {
  82                 case CMD_REQUEST_COMMAND:
  83                 {
  84                         if (argv(1) != "")
  85                         {
  86                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  87                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  88                                 return;
  89                         }
  90                 }
  91
  92                 default:
  93                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  94                 case CMD_REQUEST_USAGE:
  95                 {
  96                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  97                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  98                         return;
  99                 }
 100         }
 101 }
 102
 103 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 104 {
 105         switch (request)
 106         {
 107                 case CMD_REQUEST_COMMAND:
 108                 {
 109                         if (argv(1) != "")
 110                         {
 111                                 if (IS_CLIENT(caller))
 112                                 {
 113                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 114
 115                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 116                                         {
 117                                                 CS(caller).version_mismatch = true;
 118                                                 ClientKill_TeamChange(caller, -2);  // observe
 119                                         }
 120                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 121                                         {
 122                                                 // JoinBestTeam(caller, false, true);
 123                                         }
 124                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 125                                         {
 126                                                 TRANSMUTE(Observer, caller);  // really?
 127                                                 stuffcmd(caller, "menu_showteamselect\n");
 128                                         }
 129                                 }
 130
 131                                 return;
 132                         }
 133                 }
 134
 135                 default:
 136                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 137                 case CMD_REQUEST_USAGE:
 138                 {
 139                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 140                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 141                         return;
 142                 }
 143         }
 144 }
 145
 146 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 147 {
 148         switch (request)
 149         {
 150                 case CMD_REQUEST_COMMAND:
 151                 {
 152                         if (argv(1) != "")
 153                         {
 154                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 155
 156                                 return;
 157                         }
 158                 }
 159
 160                 default:
 161                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 162                 case CMD_REQUEST_USAGE:
 163                 {
 164                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 165                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 166                         return;
 167                 }
 168         }
 169 }
 170
 171 void ClientCommand_wpeditor(entity caller, int request, int argc)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         if (!autocvar_g_waypointeditor)
 178                         {
 179                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 180                                 return;
 181                         }
 182
 183                         if (argv(1) != "")
 184                         {
 185                                 if (argv(1) == "spawn")
 186                                 {
 187                                         if (!IS_PLAYER(caller))
 188                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 189                                         else
 190                                                 waypoint_spawn_fromeditor(caller);
 191                                 }
 192                                 else if (argv(1) == "remove")
 193                                 {
 194                                         if (!IS_PLAYER(caller))
 195                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 196                                         else
 197                                                 waypoint_remove_fromeditor(caller);
 198                                 }
 199                                 else if (argv(1) == "unreachable")
 200                                 {
 201                                         if (!IS_PLAYER(caller))
 202                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 203                                         else
 204                                                 waypoint_unreachable(caller);
 205                                 }
 206                                 else if (argv(1) == "saveall")
 207                                         waypoint_saveall();
 208                                 else if (argv(1) == "relinkall")
 209                                         waypoint_schedulerelinkall();
 210
 211                                 return;
 212                         }
 213                 }
 214
 215                 default:
 216                         sprint(caller, "Incorrect parameters for ^2wpeditor^7\n");
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 220                         sprint(caller, "  Where 'action' can be: spawn, remove, unreachable, saveall, relinkall\n");
 221                         return;
 222                 }
 223         }
 224 }
 225
 226 void ClientCommand_join(entity caller, int request)
 227 {
 228         switch (request)
 229         {
 230                 case CMD_REQUEST_COMMAND:
 231                 {
 232                         if (!game_stopped)
 233                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 234                         if (joinAllowed(caller))
 235                                 Join(caller);
 236
 237                         return;  // never fall through to usage
 238                 }
 239
 240                 default:
 241                 case CMD_REQUEST_USAGE:
 242                 {
 243                         sprint(caller, "\nUsage:^3 cmd join\n");
 244                         sprint(caller, "  No arguments required.\n");
 245                         return;
 246                 }
 247         }
 248 }
 249
 250 void ClientCommand_physics(entity caller, int request, int argc)
 251 {
 252         switch (request)
 253         {
 254                 case CMD_REQUEST_COMMAND:
 255                 {
 256                         string command = strtolower(argv(1));
 257
 258                         if (!autocvar_g_physics_clientselect)
 259                         {
 260                                 sprint(caller, "Client physics selection is currently disabled.\n");
 261                                 return;
 262                         }
 263
 264                         if (command == "list" || command == "help")
 265                         {
 266                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 267                                 return;
 268                         }
 269
 270                         if (Physics_Valid(command) || command == "default")
 271                         {
 272                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 273                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 274                                 return;
 275                         }
 276                 }
 277
 278                 default:
 279                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 280                 case CMD_REQUEST_USAGE:
 281                 {
 282                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 283                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 284                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 285                         return;
 286                 }
 287         }
 288 }
 289
 290 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 291 {
 292         switch (request)
 293         {
 294                 case CMD_REQUEST_COMMAND:
 295                 {
 296                         if (IS_CLIENT(caller))
 297                         {
 298                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 299                                 {
 300                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 301                                         {
 302                                                 if (time < game_starttime) // game is already restarting
 303                                                         return;
 304                                                 if (caller.ready)            // toggle
 305                                                 {
 306                                                         caller.ready = false;
 307                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 308                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 309                                                 }
 310                                                 else
 311                                                 {
 312                                                         caller.ready = true;
 313                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 314                                                                 bprint(playername(caller, false), "^2 is ready\n");
 315                                                 }
 316
 317                                                 // cannot reset the game while a timeout is active!
 318                                                 if (!timeout_status) ReadyCount();
 319                                         }
 320                                         else
 321                                         {
 322                                                 sprint(caller, "^1Game has already been restarted\n");
 323                                         }
 324                                 }
 325                         }
 326                         return;  // never fall through to usage
 327                 }
 328
 329                 default:
 330                 case CMD_REQUEST_USAGE:
 331                 {
 332                         sprint(caller, "\nUsage:^3 cmd ready\n");
 333                         sprint(caller, "  No arguments required.\n");
 334                         return;
 335                 }
 336         }
 337 }
 338
 339 void ClientCommand_say(entity caller, int request, int argc, string command)
 340 {
 341         switch (request)
 342         {
 343                 case CMD_REQUEST_COMMAND:
 344                 {
 345                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 346                         return;  // never fall through to usage
 347                 }
 348
 349                 default:
 350                 case CMD_REQUEST_USAGE:
 351                 {
 352                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 353                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 354                         return;
 355                 }
 356         }
 357 }
 358
 359 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 360 {
 361         switch (request)
 362         {
 363                 case CMD_REQUEST_COMMAND:
 364                 {
 365                         if (argc >= 2)
 366                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 367                         return;  // never fall through to usage
 368                 }
 369
 370                 default:
 371                 case CMD_REQUEST_USAGE:
 372                 {
 373                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 374                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 375                         return;
 376                 }
 377         }
 378 }
 379
 380 .bool team_selected;
 381 void ClientCommand_selectteam(entity caller, int request, int argc)
 382 {
 383         switch (request)
 384         {
 385                 case CMD_REQUEST_COMMAND:
 386                 {
 387                         if (argv(1) == "")
 388                         {
 389                                 return;
 390                         }
 391                         if (!IS_CLIENT(caller))
 392                         {
 393                                 return;
 394                         }
 395                         if (!teamplay)
 396                         {
 397                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 398                                 return;
 399                         }
 400                         if (Player_GetForcedTeamIndex(caller) > 0)
 401                         {
 402                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 403                                 return;
 404                         }
 405                         if (lockteams)
 406                         {
 407                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 408                                 return;
 409                         }
 410                         float selection;
 411                         switch (argv(1))
 412                         {
 413                                 case "red":
 414                                 {
 415                                         selection = NUM_TEAM_1;
 416                                         break;
 417                                 }
 418                                 case "blue":
 419                                 {
 420                                         selection = NUM_TEAM_2;
 421                                         break;
 422                                 }
 423                                 case "yellow":
 424                                 {
 425                                         selection = NUM_TEAM_3;
 426                                         break;
 427                                 }
 428                                 case "pink":
 429                                 {
 430                                         selection = NUM_TEAM_4;
 431                                         break;
 432                                 }
 433                                 case "auto":
 434                                 {
 435                                         selection = (-1);
 436                                         break;
 437                                 }
 438                                 default:
 439                                 {
 440                                         return;
 441                                 }
 442                         }
 443                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 444                         {
 445                                 sprint(caller, "^7You already are on that team.\n");
 446                                 return;
 447                         }
 448                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 449                         {
 450                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 451                                 return;
 452                         }
 453                         if ((selection != -1) && autocvar_g_balance_teams &&
 454                                 autocvar_g_balance_teams_prevent_imbalance)
 455                         {
 456                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 457                                 TeamBalance_GetTeamCounts(balance, caller);
 458                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 459                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 460                                 {
 461                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 462                                         TeamBalance_Destroy(balance);
 463                                         return;
 464                                 }
 465                                 TeamBalance_Destroy(balance);
 466                         }
 467                         ClientKill_TeamChange(caller, selection);
 468                         if (!IS_PLAYER(caller))
 469                         {
 470                                 caller.team_selected = true; // avoids asking again for team selection on join
 471                         }
 472                         return;
 473                 }
 474                 default:
 475                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 476                 case CMD_REQUEST_USAGE:
 477                 {
 478                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 479                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 480                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 481                         return;
 482                 }
 483         }
 484 }
 485
 486 void ClientCommand_selfstuff(entity caller, int request, string command)
 487 {
 488         switch (request)
 489         {
 490                 case CMD_REQUEST_COMMAND:
 491                 {
 492                         if (argv(1) != "")
 493                         {
 494                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 495                                 return;
 496                         }
 497                 }
 498
 499                 default:
 500                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 501                 case CMD_REQUEST_USAGE:
 502                 {
 503                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 504                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 505                         return;
 506                 }
 507         }
 508 }
 509
 510 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 511 {
 512         switch (request)
 513         {
 514                 case CMD_REQUEST_COMMAND:
 515                 {
 516                         if (argv(1) != "")
 517                         {
 518                                 // float tokens;
 519                                 string s;
 520
 521                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 522                                 {
 523                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 524                                         tokenize_console(s);
 525                                 }
 526
 527                                 GetCvars(caller, CS(caller), 1);
 528
 529                                 return;
 530                         }
 531                 }
 532
 533                 default:
 534                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 535                 case CMD_REQUEST_USAGE:
 536                 {
 537                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 538                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 539                         return;
 540                 }
 541         }
 542 }
 543
 544 void ClientCommand_spectate(entity caller, int request)
 545 {
 546         switch (request)
 547         {
 548                 case CMD_REQUEST_COMMAND:
 549                 {
 550                         if (!intermission_running && IS_CLIENT(caller))
 551                         {
 552                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 553                                 {
 554                                         entity client = GetFilteredEntity(argv(1));
 555                                         int spec_accepted = VerifyClientEntity(client, false, false);
 556                                         if(spec_accepted > 0 && IS_PLAYER(client))
 557                                         {
 558                                                 if(Spectate(caller, client))
 559                                                         return; // fall back to regular handling
 560                                         }
 561                                 }
 562
 563                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 564
 565                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 566
 567                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 568                                 if (autocvar_sv_spectate == 1)
 569                                         ClientKill_TeamChange(caller, -2); // observe
 570                         }
 571                         return; // never fall through to usage
 572                 }
 573
 574                 default:
 575                 case CMD_REQUEST_USAGE:
 576                 {
 577                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 578                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 579                         return;
 580                 }
 581         }
 582 }
 583
 584 void ClientCommand_suggestmap(entity caller, int request, int argc)
 585 {
 586         switch (request)
 587         {
 588                 case CMD_REQUEST_COMMAND:
 589                 {
 590                         if (argv(1) != "")
 591                         {
 592                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 593                                 return;
 594                         }
 595                 }
 596
 597                 default:
 598                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 599                 case CMD_REQUEST_USAGE:
 600                 {
 601                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 602                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 603                         return;
 604                 }
 605         }
 606 }
 607
 608 void ClientCommand_tell(entity caller, int request, int argc, string command)
 609 {
 610         switch (request)
 611         {
 612                 case CMD_REQUEST_COMMAND:
 613                 {
 614                         if (argc >= 3)
 615                         {
 616                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 617                                 {
 618                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 619                                         return;
 620                                 }
 621
 622                                 entity tell_to = GetIndexedEntity(argc, 1);
 623                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 624
 625                                 if (tell_accepted > 0)   // the target is a real client
 626                                 {
 627                                         if (tell_to != caller) // and we're allowed to send to them :D
 628                                         {
 629                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 630                                                 // In this case when the player name contains utf8 chars
 631                                                 // the message gets partially trimmed in the beginning.
 632                                                 // Potentially this bug affects any substring call that uses
 633                                                 // argv_start_index and argv_end_index.
 634
 635                                                 string utf8_enable_save = cvar_string("utf8_enable");
 636                                                 cvar_set("utf8_enable", "0");
 637                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 638                                                 cvar_set("utf8_enable", utf8_enable_save);
 639
 640                                                 Say(caller, false, tell_to, msg, true);
 641                                                 return;
 642                                         }
 643                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 644                                 }
 645                                 else if (argv(1) == "#0")
 646                                 {
 647                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 648                                         return;
 649                                 }
 650                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 651                         }
 652                 }
 653
 654                 default:
 655                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 656                 case CMD_REQUEST_USAGE:
 657                 {
 658                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 659                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 660                         return;
 661                 }
 662         }
 663 }
 664
 665 void ClientCommand_voice(entity caller, int request, int argc, string command)
 666 {
 667         switch (request)
 668         {
 669                 case CMD_REQUEST_COMMAND:
 670                 {
 671                         if (argv(1) != "")
 672                         {
 673                                 entity e = GetVoiceMessage(argv(1));
 674                                 if (!e)
 675                                 {
 676                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 677                                         return;
 678                                 }
 679                                 string msg = "";
 680                                 if (argc >= 3)
 681                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 682                                 VoiceMessage(caller, e, msg);
 683
 684                                 return;
 685                         }
 686                 }
 687
 688                 default:
 689                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 690                 case CMD_REQUEST_USAGE:
 691                 {
 692                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 693                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 694                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 695                         return;
 696                 }
 697         }
 698 }
 699
 700 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 701 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 702 void ClientCommand_(entity caller, int request)
 703 {
 704     switch(request)
 705     {
 706         case CMD_REQUEST_COMMAND:
 707         {
 708
 709             return; // never fall through to usage
 710         }
 711
 712         default:
 713         case CMD_REQUEST_USAGE:
 714         {
 715             sprint(caller, "\nUsage:^3 cmd \n");
 716             sprint(caller, "  No arguments required.\n");
 717             return;
 718         }
 719     }
 720 }
 721 */
 722
 723
 724 // =====================================
 725 //  Macro system for networked commands
 726 // =====================================
 727
 728 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 729 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 730         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 731         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 732         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 733         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 734         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 735         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 736         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 737         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 738         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 739         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 740         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 741         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 742         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 743         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 744         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 745         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 746         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 747         /* nothing */
 748
 749 void ClientCommand_macro_help(entity caller)
 750 {
 751         #define CLIENT_COMMAND(name, function, description) \
 752                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 753
 754         CLIENT_COMMANDS(NULL, 0, 0, "");
 755 #undef CLIENT_COMMAND
 756 }
 757
 758 float ClientCommand_macro_command(int argc, entity caller, string command)
 759 {
 760         #define CLIENT_COMMAND(name, function, description) \
 761                 { if (name == strtolower(argv(0))) { function; return true; } }
 762
 763         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 764 #undef CLIENT_COMMAND
 765
 766         return false;
 767 }
 768
 769 float ClientCommand_macro_usage(int argc, entity caller)
 770 {
 771         #define CLIENT_COMMAND(name, function, description) \
 772                 { if (name == strtolower(argv(1))) { function; return true; } }
 773
 774         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 775 #undef CLIENT_COMMAND
 776
 777         return false;
 778 }
 779
 780 void ClientCommand_macro_write_aliases(float fh)
 781 {
 782         #define CLIENT_COMMAND(name, function, description) \
 783                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 784
 785         CLIENT_COMMANDS(NULL, 0, 0, "");
 786 #undef CLIENT_COMMAND
 787 }
 788
 789 // ======================================
 790 //  Main Function Called By Engine (cmd)
 791 // ======================================
 792 // If this function exists, server game code parses clientcommand before the engine code gets it.
 793
 794 void SV_ParseClientCommand(entity this, string command)
 795 {
 796         // If invalid UTF-8, don't even parse it
 797         string command2 = "";
 798         float len = strlen(command);
 799         float i;
 800         for (i = 0; i < len; ++i)
 801                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 802         if (command != command2) return;
 803
 804         // if we're banned, don't even parse the command
 805         if (Ban_MaybeEnforceBanOnce(this)) return;
 806
 807         int argc = tokenize_console(command);
 808
 809         // Guide for working with argc arguments by example:
 810         // argc:   1    - 2      - 3     - 4
 811         // argv:   0    - 1      - 2     - 3
 812         // cmd     vote - master - login - password
 813
 814         // for floodcheck
 815         switch (strtolower(argv(0)))
 816         {
 817                 // exempt commands which are not subject to floodcheck
 818                 case "begin": break;                               // handled by engine in host_cmd.c
 819                 case "download": break;                            // handled by engine in cl_parse.c
 820                 case "mv_getpicture": break;                       // handled by server in this file
 821                 case "wpeditor": break;                            // handled by server in this file
 822                 case "pause": break;                               // handled by engine in host_cmd.c
 823                 case "prespawn": break;                            // handled by engine in host_cmd.c
 824                 case "sentcvar": break;                            // handled by server in this file
 825                 case "spawn": break;                               // handled by engine in host_cmd.c
 826                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 827
 828                 default:
 829                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 830                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 831         }
 832
 833         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 834         if (argv(0) == "help")
 835         {
 836                 if (argc == 1)
 837                 {
 838                         sprint(this, "\nClient networked commands:\n");
 839                         ClientCommand_macro_help(this);
 840
 841                         sprint(this, "\nCommon networked commands:\n");
 842                         CommonCommand_macro_help(this);
 843
 844                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 845                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 846                         return;
 847                 }
 848                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 849                 {
 850                         return;
 851                 }
 852                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 853                 {
 854                         return;
 855                 }
 856         }
 857         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 858         {
 859                 return;  // handled by a mutator
 860         }
 861         else if (CheatCommand(this, argc))
 862         {
 863                 return;  // handled by server/cheats.qc
 864         }
 865         else if (CommonCommand_macro_command(argc, this, command))
 866         {
 867                 return;                                          // handled by server/command/common.qc
 868         }
 869         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 870         {
 871                 return;                                          // handled by one of the above ClientCommand_* functions
 872         }
 873         else
 874         {
 875                 clientcommand(this, command);
 876         }
 877 }