qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../bot/api.qh"
  12
  13 #include "../campaign.qh"
  14 #include "../cheats.qh"
  15 #include "../client.qh"
  16 #include "../clientkill.qh"
  17 #include "../player.qh"
  18 #include "../ipban.qh"
  19 #include "../mapvoting.qh"
  20 #include "../scores.qh"
  21 #include "../teamplay.qh"
  22
  23 #include <server/mutators/_mod.qh>
  24 #include <common/gamemodes/_mod.qh>
  25
  26 #ifdef SVQC
  27         #include <common/vehicles/all.qh>
  28 #endif
  29
  30 #include <common/constants.qh>
  31 #include <common/deathtypes/all.qh>
  32 #include <common/effects/all.qh>
  33 #include <common/mapinfo.qh>
  34 #include <common/notifications/all.qh>
  35 #include <common/physics/player.qh>
  36 #include <common/teams.qh>
  37 #include <common/util.qh>
  38 #include <common/mapobjects/triggers.qh>
  39
  40 #include <common/minigames/sv_minigames.qh>
  41
  42 #include <common/monsters/_mod.qh>
  43 #include <common/monsters/sv_spawn.qh>
  44 #include <common/monsters/sv_monsters.qh>
  45
  46 #include <lib/warpzone/common.qh>
  47
  48 // =========================================================
  49 //  Server side networked commands code, reworked by Samual
  50 //  Last updated: December 28th, 2011
  51 // =========================================================
  52
  53 bool SV_ParseClientCommand_floodcheck(entity this)
  54 {
  55         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  56
  57         if (!timeout_status)  // not while paused
  58         {
  59                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  60                 {
  61                         store.cmd_floodcount += 1;
  62                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  63                 }
  64                 else
  65                 {
  66                         store.cmd_floodtime = time;
  67                         store.cmd_floodcount = 1;
  68                 }
  69         }
  70         return true;  // continue, as we're not flooding yet
  71 }
  72
  73
  74 // =======================
  75 //  Command Sub-Functions
  76 // =======================
  77
  78 void ClientCommand_autoswitch(entity caller, int request, int argc)
  79 {
  80         switch (request)
  81         {
  82                 case CMD_REQUEST_COMMAND:
  83                 {
  84                         if (argv(1) != "")
  85                         {
  86                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  87                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  88                                 return;
  89                         }
  90                 }
  91
  92                 default:
  93                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  94                 case CMD_REQUEST_USAGE:
  95                 {
  96                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  97                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  98                         return;
  99                 }
 100         }
 101 }
 102
 103 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 104 {
 105         switch (request)
 106         {
 107                 case CMD_REQUEST_COMMAND:
 108                 {
 109                         if (argv(1) != "")
 110                         {
 111                                 if (IS_CLIENT(caller))
 112                                 {
 113                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 114
 115                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 116                                         {
 117                                                 CS(caller).version_mismatch = true;
 118                                                 ClientKill_TeamChange(caller, -2);  // observe
 119                                         }
 120                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 121                                         {
 122                                                 // JoinBestTeam(caller, false, true);
 123                                         }
 124                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 125                                         {
 126                                                 TRANSMUTE(Observer, caller);  // really?
 127                                                 stuffcmd(caller, "menu_showteamselect\n");
 128                                         }
 129                                 }
 130
 131                                 return;
 132                         }
 133                 }
 134
 135                 default:
 136                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 137                 case CMD_REQUEST_USAGE:
 138                 {
 139                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 140                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 141                         return;
 142                 }
 143         }
 144 }
 145
 146 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 147 {
 148         switch (request)
 149         {
 150                 case CMD_REQUEST_COMMAND:
 151                 {
 152                         if (argv(1) != "")
 153                         {
 154                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 155
 156                                 return;
 157                         }
 158                 }
 159
 160                 default:
 161                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 162                 case CMD_REQUEST_USAGE:
 163                 {
 164                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 165                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 166                         return;
 167                 }
 168         }
 169 }
 170
 171 void ClientCommand_wpeditor(entity caller, int request, int argc)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         if (!autocvar_g_waypointeditor)
 178                         {
 179                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 180                                 return;
 181                         }
 182
 183                         if (argv(1) != "")
 184                         {
 185                                 if (argv(1) == "spawn")
 186                                 {
 187                                         string s = argv(2);
 188                                         if (!IS_PLAYER(caller))
 189                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 190                                         else
 191                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 192                                         return;
 193                                 }
 194                                 else if (argv(1) == "remove")
 195                                 {
 196                                         if (!IS_PLAYER(caller))
 197                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 198                                         else
 199                                                 waypoint_remove_fromeditor(caller);
 200                                         return;
 201                                 }
 202                                 else if (argv(1) == "hardwire")
 203                                 {
 204                                         string s = argv(2);
 205                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 206                                         return;
 207                                 }
 208                                 else if (argv(1) == "lock")
 209                                 {
 210                                         waypoint_lock(caller);
 211                                         return;
 212                                 }
 213                                 else if (argv(1) == "unreachable")
 214                                 {
 215                                         if (!IS_PLAYER(caller))
 216                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 217                                         else
 218                                                 waypoint_unreachable(caller);
 219                                         return;
 220                                 }
 221                                 else if (argv(1) == "saveall")
 222                                 {
 223                                         waypoint_saveall();
 224                                         return;
 225                                 }
 226                                 else if (argv(1) == "relinkall")
 227                                 {
 228                                         waypoint_schedulerelinkall();
 229                                         return;
 230                                 }
 231                                 else if (argv(1) == "symaxis")
 232                                 {
 233                                         if (argv(2) == "set" || argv(2) == "get")
 234                                         {
 235                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 236                                                 return;
 237                                         }
 238                                 }
 239                                 else if (argv(1) == "symorigin")
 240                                 {
 241                                         if (argv(2) == "set" || argv(2) == "get")
 242                                         {
 243                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 244                                                 return;
 245                                         }
 246                                 }
 247                         }
 248                 }
 249
 250                 default:
 251                         sprint(caller, "Incorrect parameters for ^2wpeditor^7\n");
 252                 case CMD_REQUEST_USAGE:
 253                 {
 254                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 255                         sprint(caller, "  Where 'action' can be:\n");
 256                         sprint(caller, "   ^5spawn^7: spawns a waypoint at player's position\n");
 257                         sprint(caller, "   ^5remove^7: removes player's nearest waypoint\n");
 258                         sprint(caller, "   ^5unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 259                         sprint(caller, "   ^5saveall^7: saves all waypoints and links to file\n");
 260                         sprint(caller, "   ^5relinkall^7: relinks all waypoints as if they were respawned\n");
 261                         sprint(caller, "   ^5spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 262                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 263                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 264                         sprint(caller, "   ^5spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 265                         sprint(caller, "   ^5spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 266                         sprint(caller, "   ^5spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 267                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 268                         sprint(caller, "   ^5hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 269                         sprint(caller, "   ^5hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 270                         sprint(caller, "   ^5lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 271                         sprint(caller, "   ^5symorigin get|set\n");
 272                         sprint(caller, "   ^5symorigin get|set p1 p2 ... pX\n");
 273                         sprint(caller, "   ^5symaxis get|set p1 p2\n");
 274                         sprint(caller, "   ^7 where p1 p2 ... pX are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 275                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 276                         sprint(caller, "  See 'wpeditor_menu' for a selectable list of various commands and useful settings to edit waypoints.\n");
 277                         return;
 278                 }
 279         }
 280 }
 281
 282 void ClientCommand_join(entity caller, int request)
 283 {
 284         switch (request)
 285         {
 286                 case CMD_REQUEST_COMMAND:
 287                 {
 288                         if (!game_stopped)
 289                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 290                         if (joinAllowed(caller))
 291                                 Join(caller);
 292
 293                         return;  // never fall through to usage
 294                 }
 295
 296                 default:
 297                 case CMD_REQUEST_USAGE:
 298                 {
 299                         sprint(caller, "\nUsage:^3 cmd join\n");
 300                         sprint(caller, "  No arguments required.\n");
 301                         return;
 302                 }
 303         }
 304 }
 305
 306 void ClientCommand_kill(entity caller, int request)
 307 {
 308         switch (request)
 309         {
 310                 case CMD_REQUEST_COMMAND:
 311                 {
 312                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 313                                 return; // no point warning about this, command does nothing
 314
 315                         if(GetResource(caller, RES_HEALTH) <= 0)
 316                         {
 317                                 sprint(caller, "Can't die - you are already dead!\n");
 318                                 return;
 319                         }
 320
 321                         ClientKill(caller);
 322
 323                         return;  // never fall through to usage
 324                 }
 325
 326                 default:
 327                 case CMD_REQUEST_USAGE:
 328                 {
 329                         sprint(caller, "\nUsage:^3 cmd kill\n");
 330                         sprint(caller, "  No arguments required.\n");
 331                         return;
 332                 }
 333         }
 334 }
 335
 336 void ClientCommand_physics(entity caller, int request, int argc)
 337 {
 338         switch (request)
 339         {
 340                 case CMD_REQUEST_COMMAND:
 341                 {
 342                         string command = strtolower(argv(1));
 343
 344                         if (!autocvar_g_physics_clientselect)
 345                         {
 346                                 sprint(caller, "Client physics selection is currently disabled.\n");
 347                                 return;
 348                         }
 349
 350                         if (command == "list" || command == "help")
 351                         {
 352                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 353                                 return;
 354                         }
 355
 356                         if (Physics_Valid(command) || command == "default")
 357                         {
 358                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 359                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 360                                 return;
 361                         }
 362                 }
 363
 364                 default:
 365                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 366                 case CMD_REQUEST_USAGE:
 367                 {
 368                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 369                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 370                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 371                         return;
 372                 }
 373         }
 374 }
 375
 376 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 377 {
 378         switch (request)
 379         {
 380                 case CMD_REQUEST_COMMAND:
 381                 {
 382                         if (IS_CLIENT(caller))
 383                         {
 384                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 385                                 {
 386                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 387                                         {
 388                                                 if (time < game_starttime) // game is already restarting
 389                                                         return;
 390                                                 if (caller.ready)            // toggle
 391                                                 {
 392                                                         caller.ready = false;
 393                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 394                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 395                                                 }
 396                                                 else
 397                                                 {
 398                                                         caller.ready = true;
 399                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 400                                                                 bprint(playername(caller, false), "^2 is ready\n");
 401                                                 }
 402
 403                                                 // cannot reset the game while a timeout is active!
 404                                                 if (!timeout_status) ReadyCount();
 405                                         }
 406                                         else
 407                                         {
 408                                                 sprint(caller, "^1Game has already been restarted\n");
 409                                         }
 410                                 }
 411                         }
 412                         return;  // never fall through to usage
 413                 }
 414
 415                 default:
 416                 case CMD_REQUEST_USAGE:
 417                 {
 418                         sprint(caller, "\nUsage:^3 cmd ready\n");
 419                         sprint(caller, "  No arguments required.\n");
 420                         return;
 421                 }
 422         }
 423 }
 424
 425 void ClientCommand_say(entity caller, int request, int argc, string command)
 426 {
 427         switch (request)
 428         {
 429                 case CMD_REQUEST_COMMAND:
 430                 {
 431                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 432                         return;  // never fall through to usage
 433                 }
 434
 435                 default:
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 439                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 446 {
 447         switch (request)
 448         {
 449                 case CMD_REQUEST_COMMAND:
 450                 {
 451                         if (argc >= 2)
 452                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 453                         return;  // never fall through to usage
 454                 }
 455
 456                 default:
 457                 case CMD_REQUEST_USAGE:
 458                 {
 459                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 460                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 461                         return;
 462                 }
 463         }
 464 }
 465
 466 .bool team_selected;
 467 void ClientCommand_selectteam(entity caller, int request, int argc)
 468 {
 469         switch (request)
 470         {
 471                 case CMD_REQUEST_COMMAND:
 472                 {
 473                         if (argv(1) == "")
 474                         {
 475                                 return;
 476                         }
 477                         if (!IS_CLIENT(caller))
 478                         {
 479                                 return;
 480                         }
 481                         if (!teamplay)
 482                         {
 483                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 484                                 return;
 485                         }
 486                         if (Player_GetForcedTeamIndex(caller) > 0)
 487                         {
 488                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 489                                 return;
 490                         }
 491                         if (lockteams)
 492                         {
 493                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 494                                 return;
 495                         }
 496                         float selection;
 497                         switch (argv(1))
 498                         {
 499                                 case "red":
 500                                 {
 501                                         selection = NUM_TEAM_1;
 502                                         break;
 503                                 }
 504                                 case "blue":
 505                                 {
 506                                         selection = NUM_TEAM_2;
 507                                         break;
 508                                 }
 509                                 case "yellow":
 510                                 {
 511                                         selection = NUM_TEAM_3;
 512                                         break;
 513                                 }
 514                                 case "pink":
 515                                 {
 516                                         selection = NUM_TEAM_4;
 517                                         break;
 518                                 }
 519                                 case "auto":
 520                                 {
 521                                         selection = (-1);
 522                                         break;
 523                                 }
 524                                 default:
 525                                 {
 526                                         return;
 527                                 }
 528                         }
 529                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 530                         {
 531                                 sprint(caller, "^7You already are on that team.\n");
 532                                 return;
 533                         }
 534                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 535                         {
 536                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 537                                 return;
 538                         }
 539                         if ((selection != -1) && autocvar_g_balance_teams &&
 540                                 autocvar_g_balance_teams_prevent_imbalance)
 541                         {
 542                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 543                                 TeamBalance_GetTeamCounts(balance, caller);
 544                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 545                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 546                                 {
 547                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 548                                         TeamBalance_Destroy(balance);
 549                                         return;
 550                                 }
 551                                 TeamBalance_Destroy(balance);
 552                         }
 553                         ClientKill_TeamChange(caller, selection);
 554                         if (!IS_PLAYER(caller))
 555                         {
 556                                 caller.team_selected = true; // avoids asking again for team selection on join
 557                         }
 558                         return;
 559                 }
 560                 default:
 561                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 562                 case CMD_REQUEST_USAGE:
 563                 {
 564                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 565                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 566                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 567                         return;
 568                 }
 569         }
 570 }
 571
 572 void ClientCommand_selfstuff(entity caller, int request, string command)
 573 {
 574         switch (request)
 575         {
 576                 case CMD_REQUEST_COMMAND:
 577                 {
 578                         if (argv(1) != "")
 579                         {
 580                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 581                                 return;
 582                         }
 583                 }
 584
 585                 default:
 586                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 587                 case CMD_REQUEST_USAGE:
 588                 {
 589                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 590                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 591                         return;
 592                 }
 593         }
 594 }
 595
 596 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 597 {
 598         switch (request)
 599         {
 600                 case CMD_REQUEST_COMMAND:
 601                 {
 602                         if (argv(1) != "")
 603                         {
 604                                 // float tokens;
 605                                 string s;
 606
 607                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 608                                 {
 609                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 610                                         tokenize_console(s);
 611                                 }
 612
 613                                 GetCvars(caller, CS(caller), 1);
 614
 615                                 return;
 616                         }
 617                 }
 618
 619                 default:
 620                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 621                 case CMD_REQUEST_USAGE:
 622                 {
 623                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 624                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 625                         return;
 626                 }
 627         }
 628 }
 629
 630 void ClientCommand_spectate(entity caller, int request)
 631 {
 632         switch (request)
 633         {
 634                 case CMD_REQUEST_COMMAND:
 635                 {
 636                         if (!intermission_running && IS_CLIENT(caller))
 637                         {
 638                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 639                                 {
 640                                         entity client = GetFilteredEntity(argv(1));
 641                                         int spec_accepted = VerifyClientEntity(client, false, false);
 642                                         if(spec_accepted > 0 && IS_PLAYER(client))
 643                                         {
 644                                                 if(Spectate(caller, client))
 645                                                         return; // fall back to regular handling
 646                                         }
 647                                 }
 648
 649                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 650
 651                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 652
 653                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 654                                 if (autocvar_sv_spectate == 1)
 655                                         ClientKill_TeamChange(caller, -2); // observe
 656                         }
 657                         return; // never fall through to usage
 658                 }
 659
 660                 default:
 661                 case CMD_REQUEST_USAGE:
 662                 {
 663                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 664                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 665                         return;
 666                 }
 667         }
 668 }
 669
 670 void ClientCommand_suggestmap(entity caller, int request, int argc)
 671 {
 672         switch (request)
 673         {
 674                 case CMD_REQUEST_COMMAND:
 675                 {
 676                         if (argv(1) != "")
 677                         {
 678                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 679                                 return;
 680                         }
 681                 }
 682
 683                 default:
 684                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 685                 case CMD_REQUEST_USAGE:
 686                 {
 687                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 688                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 689                         return;
 690                 }
 691         }
 692 }
 693
 694 void ClientCommand_tell(entity caller, int request, int argc, string command)
 695 {
 696         switch (request)
 697         {
 698                 case CMD_REQUEST_COMMAND:
 699                 {
 700                         if (argc >= 3)
 701                         {
 702                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 703                                 {
 704                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 705                                         return;
 706                                 }
 707
 708                                 entity tell_to = GetIndexedEntity(argc, 1);
 709                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 710
 711                                 if (tell_accepted > 0)   // the target is a real client
 712                                 {
 713                                         if (tell_to != caller) // and we're allowed to send to them :D
 714                                         {
 715                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 716                                                 // In this case when the player name contains utf8 chars
 717                                                 // the message gets partially trimmed in the beginning.
 718                                                 // Potentially this bug affects any substring call that uses
 719                                                 // argv_start_index and argv_end_index.
 720
 721                                                 string utf8_enable_save = cvar_string("utf8_enable");
 722                                                 cvar_set("utf8_enable", "0");
 723                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 724                                                 cvar_set("utf8_enable", utf8_enable_save);
 725
 726                                                 Say(caller, false, tell_to, msg, true);
 727                                                 return;
 728                                         }
 729                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 730                                 }
 731                                 else if (argv(1) == "#0")
 732                                 {
 733                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 734                                         return;
 735                                 }
 736                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 737                         }
 738                 }
 739
 740                 default:
 741                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 742                 case CMD_REQUEST_USAGE:
 743                 {
 744                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 745                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 746                         return;
 747                 }
 748         }
 749 }
 750
 751 void ClientCommand_voice(entity caller, int request, int argc, string command)
 752 {
 753         switch (request)
 754         {
 755                 case CMD_REQUEST_COMMAND:
 756                 {
 757                         if (argv(1) != "")
 758                         {
 759                                 entity e = GetVoiceMessage(argv(1));
 760                                 if (!e)
 761                                 {
 762                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 763                                         return;
 764                                 }
 765                                 if (IS_DEAD(caller))
 766                                 {
 767                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 768                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 769                                         return;
 770                                 }
 771                                 string msg = "";
 772                                 if (argc >= 3)
 773                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 774                                 VoiceMessage(caller, e, msg);
 775
 776                                 return;
 777                         }
 778                 }
 779
 780                 default:
 781                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 782                 case CMD_REQUEST_USAGE:
 783                 {
 784                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 785                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 786                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 787                         return;
 788                 }
 789         }
 790 }
 791
 792 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 793 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 794 void ClientCommand_(entity caller, int request)
 795 {
 796     switch(request)
 797     {
 798         case CMD_REQUEST_COMMAND:
 799         {
 800
 801             return; // never fall through to usage
 802         }
 803
 804         default:
 805         case CMD_REQUEST_USAGE:
 806         {
 807             sprint(caller, "\nUsage:^3 cmd \n");
 808             sprint(caller, "  No arguments required.\n");
 809             return;
 810         }
 811     }
 812 }
 813 */
 814
 815
 816 // =====================================
 817 //  Macro system for networked commands
 818 // =====================================
 819
 820 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 821 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 822         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 823         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 824         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 825         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 826         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 827         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 828         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 829         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 830         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 831         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 832         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 833         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 834         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 835         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 836         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 837         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 838         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 839         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 840         /* nothing */
 841
 842 void ClientCommand_macro_help(entity caller)
 843 {
 844         #define CLIENT_COMMAND(name, function, description) \
 845                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 846
 847         CLIENT_COMMANDS(NULL, 0, 0, "");
 848 #undef CLIENT_COMMAND
 849 }
 850
 851 float ClientCommand_macro_command(int argc, entity caller, string command)
 852 {
 853         #define CLIENT_COMMAND(name, function, description) \
 854                 { if (name == strtolower(argv(0))) { function; return true; } }
 855
 856         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 857 #undef CLIENT_COMMAND
 858
 859         return false;
 860 }
 861
 862 float ClientCommand_macro_usage(int argc, entity caller)
 863 {
 864         #define CLIENT_COMMAND(name, function, description) \
 865                 { if (name == strtolower(argv(1))) { function; return true; } }
 866
 867         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 868 #undef CLIENT_COMMAND
 869
 870         return false;
 871 }
 872
 873 void ClientCommand_macro_write_aliases(float fh)
 874 {
 875         #define CLIENT_COMMAND(name, function, description) \
 876                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 877
 878         CLIENT_COMMANDS(NULL, 0, 0, "");
 879 #undef CLIENT_COMMAND
 880 }
 881
 882 // ======================================
 883 //  Main Function Called By Engine (cmd)
 884 // ======================================
 885 // If this function exists, server game code parses clientcommand before the engine code gets it.
 886
 887 void SV_ParseClientCommand(entity this, string command)
 888 {
 889         // If invalid UTF-8, don't even parse it
 890         string command2 = "";
 891         float len = strlen(command);
 892         float i;
 893         for (i = 0; i < len; ++i)
 894                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 895         if (command != command2) return;
 896
 897         // if we're banned, don't even parse the command
 898         if (Ban_MaybeEnforceBanOnce(this)) return;
 899
 900         int argc = tokenize_console(command);
 901
 902         // Guide for working with argc arguments by example:
 903         // argc:   1    - 2      - 3     - 4
 904         // argv:   0    - 1      - 2     - 3
 905         // cmd     vote - master - login - password
 906
 907         // for floodcheck
 908         switch (strtolower(argv(0)))
 909         {
 910                 // exempt commands which are not subject to floodcheck
 911                 case "begin": break;                               // handled by engine in host_cmd.c
 912                 case "download": break;                            // handled by engine in cl_parse.c
 913                 case "mv_getpicture": break;                       // handled by server in this file
 914                 case "wpeditor": break;                            // handled by server in this file
 915                 case "pause": break;                               // handled by engine in host_cmd.c
 916                 case "prespawn": break;                            // handled by engine in host_cmd.c
 917                 case "sentcvar": break;                            // handled by server in this file
 918                 case "spawn": break;                               // handled by engine in host_cmd.c
 919                 case "color": case "topcolor": case "bottomcolor": if(teamplay) return; else break; // handled by engine in host_cmd.c
 920                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 921
 922                 default:
 923                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 924                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 925         }
 926
 927         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 928         if (argv(0) == "help")
 929         {
 930                 if (argc == 1)
 931                 {
 932                         sprint(this, "\nClient networked commands:\n");
 933                         ClientCommand_macro_help(this);
 934
 935                         sprint(this, "\nCommon networked commands:\n");
 936                         CommonCommand_macro_help(this);
 937
 938                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 939                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 940                         return;
 941                 }
 942                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 943                 {
 944                         return;
 945                 }
 946                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 947                 {
 948                         return;
 949                 }
 950         }
 951         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 952         {
 953                 return;  // handled by a mutator
 954         }
 955         else if (CheatCommand(this, argc))
 956         {
 957                 return;  // handled by server/cheats.qc
 958         }
 959         else if (CommonCommand_macro_command(argc, this, command))
 960         {
 961                 return;                                          // handled by server/command/common.qc
 962         }
 963         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 964         {
 965                 return;                                          // handled by one of the above ClientCommand_* functions
 966         }
 967         else
 968         {
 969                 clientcommand(this, command);
 970         }
 971 }