qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../bot/api.qh"
  12
  13 #include "../campaign.qh"
  14 #include "../cheats.qh"
  15 #include "../client.qh"
  16 #include "../clientkill.qh"
  17 #include "../player.qh"
  18 #include "../ipban.qh"
  19 #include "../mapvoting.qh"
  20 #include "../scores.qh"
  21 #include "../teamplay.qh"
  22
  23 #include <server/mutators/_mod.qh>
  24 #include <common/gamemodes/_mod.qh>
  25
  26 #ifdef SVQC
  27         #include <common/vehicles/all.qh>
  28 #endif
  29
  30 #include <common/constants.qh>
  31 #include <common/deathtypes/all.qh>
  32 #include <common/effects/all.qh>
  33 #include <common/mapinfo.qh>
  34 #include <common/notifications/all.qh>
  35 #include <common/physics/player.qh>
  36 #include <common/teams.qh>
  37 #include <common/util.qh>
  38 #include <common/mapobjects/triggers.qh>
  39
  40 #include <common/minigames/sv_minigames.qh>
  41
  42 #include <common/monsters/_mod.qh>
  43 #include <common/monsters/sv_spawn.qh>
  44 #include <common/monsters/sv_monsters.qh>
  45
  46 #include <lib/warpzone/common.qh>
  47
  48 // =========================================================
  49 //  Server side networked commands code, reworked by Samual
  50 //  Last updated: December 28th, 2011
  51 // =========================================================
  52
  53 bool SV_ParseClientCommand_floodcheck(entity this)
  54 {
  55         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  56
  57         if (!timeout_status)  // not while paused
  58         {
  59                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  60                 {
  61                         store.cmd_floodcount += 1;
  62                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  63                 }
  64                 else
  65                 {
  66                         store.cmd_floodtime = time;
  67                         store.cmd_floodcount = 1;
  68                 }
  69         }
  70         return true;  // continue, as we're not flooding yet
  71 }
  72
  73
  74 // =======================
  75 //  Command Sub-Functions
  76 // =======================
  77
  78 void ClientCommand_autoswitch(entity caller, int request, int argc)
  79 {
  80         switch (request)
  81         {
  82                 case CMD_REQUEST_COMMAND:
  83                 {
  84                         if (argv(1) != "")
  85                         {
  86                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  87                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  88                                 return;
  89                         }
  90                 }
  91
  92                 default:
  93                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  94                 case CMD_REQUEST_USAGE:
  95                 {
  96                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  97                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  98                         return;
  99                 }
 100         }
 101 }
 102
 103 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 104 {
 105         switch (request)
 106         {
 107                 case CMD_REQUEST_COMMAND:
 108                 {
 109                         if (argv(1) != "")
 110                         {
 111                                 if (IS_CLIENT(caller))
 112                                 {
 113                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 114
 115                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 116                                         {
 117                                                 CS(caller).version_mismatch = true;
 118                                                 ClientKill_TeamChange(caller, -2);  // observe
 119                                         }
 120                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 121                                         {
 122                                                 // JoinBestTeam(caller, false, true);
 123                                         }
 124                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 125                                         {
 126                                                 TRANSMUTE(Observer, caller);  // really?
 127                                                 stuffcmd(caller, "menu_showteamselect\n");
 128                                         }
 129                                 }
 130
 131                                 return;
 132                         }
 133                 }
 134
 135                 default:
 136                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 137                 case CMD_REQUEST_USAGE:
 138                 {
 139                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 140                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 141                         return;
 142                 }
 143         }
 144 }
 145
 146 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 147 {
 148         switch (request)
 149         {
 150                 case CMD_REQUEST_COMMAND:
 151                 {
 152                         if (argv(1) != "")
 153                         {
 154                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 155
 156                                 return;
 157                         }
 158                 }
 159
 160                 default:
 161                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 162                 case CMD_REQUEST_USAGE:
 163                 {
 164                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 165                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 166                         return;
 167                 }
 168         }
 169 }
 170
 171 void ClientCommand_wpeditor(entity caller, int request, int argc)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         if (!autocvar_g_waypointeditor)
 178                         {
 179                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 180                                 return;
 181                         }
 182
 183                         if (argv(1) != "")
 184                         {
 185                                 if (argv(1) == "spawn")
 186                                 {
 187                                         string s = argv(2);
 188                                         if (!IS_PLAYER(caller))
 189                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 190                                         else
 191                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 192                                         return;
 193                                 }
 194                                 else if (argv(1) == "remove")
 195                                 {
 196                                         if (!IS_PLAYER(caller))
 197                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 198                                         else
 199                                                 waypoint_remove_fromeditor(caller);
 200                                         return;
 201                                 }
 202                                 else if (argv(1) == "hardwire")
 203                                 {
 204                                         waypoint_start_hardwiredlink(caller);
 205                                         return;
 206                                 }
 207                                 else if (argv(1) == "unreachable")
 208                                 {
 209                                         if (!IS_PLAYER(caller))
 210                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 211                                         else
 212                                                 waypoint_unreachable(caller);
 213                                         return;
 214                                 }
 215                                 else if (argv(1) == "saveall")
 216                                 {
 217                                         waypoint_saveall();
 218                                         return;
 219                                 }
 220                                 else if (argv(1) == "relinkall")
 221                                 {
 222                                         waypoint_schedulerelinkall();
 223                                         return;
 224                                 }
 225                                 else if (argv(1) == "symaxis")
 226                                 {
 227                                         if (argv(2) == "set" || argv(2) == "get")
 228                                         {
 229                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 230                                                 return;
 231                                         }
 232                                 }
 233                                 else if (argv(1) == "symorigin")
 234                                 {
 235                                         if (argv(2) == "set" || argv(2) == "get")
 236                                         {
 237                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 238                                                 return;
 239                                         }
 240                                 }
 241                         }
 242                 }
 243
 244                 default:
 245                         sprint(caller, "Incorrect parameters for ^2wpeditor^7\n");
 246                 case CMD_REQUEST_USAGE:
 247                 {
 248                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 249                         sprint(caller, "  Where 'action' can be:\n");
 250                         sprint(caller, "   ^5spawn^7: spawns a waypoint at player's position\n");
 251                         sprint(caller, "   ^5remove^7: remove player's nearest waypoint\n");
 252                         sprint(caller, "   ^5unreachable^7: useful to reveal waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 253                         sprint(caller, "   ^5saveall^7: saves all waypoints and links to file\n");
 254                         sprint(caller, "   ^5relinkall^7: relink all waypoints as if they were respawned\n");
 255                         sprint(caller, "   ^5spawn crosshair^7: spawns a waypoint at crosshair's position (useful to spawn custom jumppad waypoints (spawn another waypoint to create destination))\n");
 256                         sprint(caller, "   ^5spawn jump^7: spawns a jump waypoint (spawn another waypoint to create destination)\n");
 257                         sprint(caller, "   ^5spawn crouch^7: spawns a crouch waypoint\n");
 258                         sprint(caller, "   ^5hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 259                         sprint(caller, "   ^5symorigin get|set\n");
 260                         sprint(caller, "   ^5symorigin get|set p1 p2 ... pX\n");
 261                         sprint(caller, "   ^5symaxis get|set p1 p2\n");
 262                         sprint(caller, "   ^7 where p1 p2 ... pX are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical");
 263                         sprint(caller, "   ^7 so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 264                         return;
 265                 }
 266         }
 267 }
 268
 269 void ClientCommand_join(entity caller, int request)
 270 {
 271         switch (request)
 272         {
 273                 case CMD_REQUEST_COMMAND:
 274                 {
 275                         if (!game_stopped)
 276                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 277                         if (joinAllowed(caller))
 278                                 Join(caller);
 279
 280                         return;  // never fall through to usage
 281                 }
 282
 283                 default:
 284                 case CMD_REQUEST_USAGE:
 285                 {
 286                         sprint(caller, "\nUsage:^3 cmd join\n");
 287                         sprint(caller, "  No arguments required.\n");
 288                         return;
 289                 }
 290         }
 291 }
 292
 293 void ClientCommand_kill(entity caller, int request)
 294 {
 295         switch (request)
 296         {
 297                 case CMD_REQUEST_COMMAND:
 298                 {
 299                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 300                                 return; // no point warning about this, command does nothing
 301
 302                         if(GetResource(caller, RES_HEALTH) <= 0)
 303                         {
 304                                 sprint(caller, "Can't die - you are already dead!\n");
 305                                 return;
 306                         }
 307
 308                         ClientKill(caller);
 309
 310                         return;  // never fall through to usage
 311                 }
 312
 313                 default:
 314                 case CMD_REQUEST_USAGE:
 315                 {
 316                         sprint(caller, "\nUsage:^3 cmd kill\n");
 317                         sprint(caller, "  No arguments required.\n");
 318                         return;
 319                 }
 320         }
 321 }
 322
 323 void ClientCommand_physics(entity caller, int request, int argc)
 324 {
 325         switch (request)
 326         {
 327                 case CMD_REQUEST_COMMAND:
 328                 {
 329                         string command = strtolower(argv(1));
 330
 331                         if (!autocvar_g_physics_clientselect)
 332                         {
 333                                 sprint(caller, "Client physics selection is currently disabled.\n");
 334                                 return;
 335                         }
 336
 337                         if (command == "list" || command == "help")
 338                         {
 339                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 340                                 return;
 341                         }
 342
 343                         if (Physics_Valid(command) || command == "default")
 344                         {
 345                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 346                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 347                                 return;
 348                         }
 349                 }
 350
 351                 default:
 352                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 353                 case CMD_REQUEST_USAGE:
 354                 {
 355                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 356                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 357                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 358                         return;
 359                 }
 360         }
 361 }
 362
 363 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 364 {
 365         switch (request)
 366         {
 367                 case CMD_REQUEST_COMMAND:
 368                 {
 369                         if (IS_CLIENT(caller))
 370                         {
 371                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 372                                 {
 373                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 374                                         {
 375                                                 if (time < game_starttime) // game is already restarting
 376                                                         return;
 377                                                 if (caller.ready)            // toggle
 378                                                 {
 379                                                         caller.ready = false;
 380                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 381                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 382                                                 }
 383                                                 else
 384                                                 {
 385                                                         caller.ready = true;
 386                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 387                                                                 bprint(playername(caller, false), "^2 is ready\n");
 388                                                 }
 389
 390                                                 // cannot reset the game while a timeout is active!
 391                                                 if (!timeout_status) ReadyCount();
 392                                         }
 393                                         else
 394                                         {
 395                                                 sprint(caller, "^1Game has already been restarted\n");
 396                                         }
 397                                 }
 398                         }
 399                         return;  // never fall through to usage
 400                 }
 401
 402                 default:
 403                 case CMD_REQUEST_USAGE:
 404                 {
 405                         sprint(caller, "\nUsage:^3 cmd ready\n");
 406                         sprint(caller, "  No arguments required.\n");
 407                         return;
 408                 }
 409         }
 410 }
 411
 412 void ClientCommand_say(entity caller, int request, int argc, string command)
 413 {
 414         switch (request)
 415         {
 416                 case CMD_REQUEST_COMMAND:
 417                 {
 418                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 419                         return;  // never fall through to usage
 420                 }
 421
 422                 default:
 423                 case CMD_REQUEST_USAGE:
 424                 {
 425                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 426                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 427                         return;
 428                 }
 429         }
 430 }
 431
 432 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 433 {
 434         switch (request)
 435         {
 436                 case CMD_REQUEST_COMMAND:
 437                 {
 438                         if (argc >= 2)
 439                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 440                         return;  // never fall through to usage
 441                 }
 442
 443                 default:
 444                 case CMD_REQUEST_USAGE:
 445                 {
 446                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 447                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 448                         return;
 449                 }
 450         }
 451 }
 452
 453 .bool team_selected;
 454 void ClientCommand_selectteam(entity caller, int request, int argc)
 455 {
 456         switch (request)
 457         {
 458                 case CMD_REQUEST_COMMAND:
 459                 {
 460                         if (argv(1) == "")
 461                         {
 462                                 return;
 463                         }
 464                         if (!IS_CLIENT(caller))
 465                         {
 466                                 return;
 467                         }
 468                         if (!teamplay)
 469                         {
 470                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 471                                 return;
 472                         }
 473                         if (Player_GetForcedTeamIndex(caller) > 0)
 474                         {
 475                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 476                                 return;
 477                         }
 478                         if (lockteams)
 479                         {
 480                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 481                                 return;
 482                         }
 483                         float selection;
 484                         switch (argv(1))
 485                         {
 486                                 case "red":
 487                                 {
 488                                         selection = NUM_TEAM_1;
 489                                         break;
 490                                 }
 491                                 case "blue":
 492                                 {
 493                                         selection = NUM_TEAM_2;
 494                                         break;
 495                                 }
 496                                 case "yellow":
 497                                 {
 498                                         selection = NUM_TEAM_3;
 499                                         break;
 500                                 }
 501                                 case "pink":
 502                                 {
 503                                         selection = NUM_TEAM_4;
 504                                         break;
 505                                 }
 506                                 case "auto":
 507                                 {
 508                                         selection = (-1);
 509                                         break;
 510                                 }
 511                                 default:
 512                                 {
 513                                         return;
 514                                 }
 515                         }
 516                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 517                         {
 518                                 sprint(caller, "^7You already are on that team.\n");
 519                                 return;
 520                         }
 521                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 522                         {
 523                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 524                                 return;
 525                         }
 526                         if ((selection != -1) && autocvar_g_balance_teams &&
 527                                 autocvar_g_balance_teams_prevent_imbalance)
 528                         {
 529                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 530                                 TeamBalance_GetTeamCounts(balance, caller);
 531                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 532                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 533                                 {
 534                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 535                                         TeamBalance_Destroy(balance);
 536                                         return;
 537                                 }
 538                                 TeamBalance_Destroy(balance);
 539                         }
 540                         ClientKill_TeamChange(caller, selection);
 541                         if (!IS_PLAYER(caller))
 542                         {
 543                                 caller.team_selected = true; // avoids asking again for team selection on join
 544                         }
 545                         return;
 546                 }
 547                 default:
 548                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 549                 case CMD_REQUEST_USAGE:
 550                 {
 551                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 552                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 553                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 554                         return;
 555                 }
 556         }
 557 }
 558
 559 void ClientCommand_selfstuff(entity caller, int request, string command)
 560 {
 561         switch (request)
 562         {
 563                 case CMD_REQUEST_COMMAND:
 564                 {
 565                         if (argv(1) != "")
 566                         {
 567                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 568                                 return;
 569                         }
 570                 }
 571
 572                 default:
 573                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 574                 case CMD_REQUEST_USAGE:
 575                 {
 576                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 577                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 578                         return;
 579                 }
 580         }
 581 }
 582
 583 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 584 {
 585         switch (request)
 586         {
 587                 case CMD_REQUEST_COMMAND:
 588                 {
 589                         if (argv(1) != "")
 590                         {
 591                                 // float tokens;
 592                                 string s;
 593
 594                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 595                                 {
 596                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 597                                         tokenize_console(s);
 598                                 }
 599
 600                                 GetCvars(caller, CS(caller), 1);
 601
 602                                 return;
 603                         }
 604                 }
 605
 606                 default:
 607                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 608                 case CMD_REQUEST_USAGE:
 609                 {
 610                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 611                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 612                         return;
 613                 }
 614         }
 615 }
 616
 617 void ClientCommand_spectate(entity caller, int request)
 618 {
 619         switch (request)
 620         {
 621                 case CMD_REQUEST_COMMAND:
 622                 {
 623                         if (!intermission_running && IS_CLIENT(caller))
 624                         {
 625                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 626                                 {
 627                                         entity client = GetFilteredEntity(argv(1));
 628                                         int spec_accepted = VerifyClientEntity(client, false, false);
 629                                         if(spec_accepted > 0 && IS_PLAYER(client))
 630                                         {
 631                                                 if(Spectate(caller, client))
 632                                                         return; // fall back to regular handling
 633                                         }
 634                                 }
 635
 636                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 637
 638                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 639
 640                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 641                                 if (autocvar_sv_spectate == 1)
 642                                         ClientKill_TeamChange(caller, -2); // observe
 643                         }
 644                         return; // never fall through to usage
 645                 }
 646
 647                 default:
 648                 case CMD_REQUEST_USAGE:
 649                 {
 650                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 651                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 652                         return;
 653                 }
 654         }
 655 }
 656
 657 void ClientCommand_suggestmap(entity caller, int request, int argc)
 658 {
 659         switch (request)
 660         {
 661                 case CMD_REQUEST_COMMAND:
 662                 {
 663                         if (argv(1) != "")
 664                         {
 665                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 666                                 return;
 667                         }
 668                 }
 669
 670                 default:
 671                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 672                 case CMD_REQUEST_USAGE:
 673                 {
 674                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 675                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 676                         return;
 677                 }
 678         }
 679 }
 680
 681 void ClientCommand_tell(entity caller, int request, int argc, string command)
 682 {
 683         switch (request)
 684         {
 685                 case CMD_REQUEST_COMMAND:
 686                 {
 687                         if (argc >= 3)
 688                         {
 689                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 690                                 {
 691                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 692                                         return;
 693                                 }
 694
 695                                 entity tell_to = GetIndexedEntity(argc, 1);
 696                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 697
 698                                 if (tell_accepted > 0)   // the target is a real client
 699                                 {
 700                                         if (tell_to != caller) // and we're allowed to send to them :D
 701                                         {
 702                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 703                                                 // In this case when the player name contains utf8 chars
 704                                                 // the message gets partially trimmed in the beginning.
 705                                                 // Potentially this bug affects any substring call that uses
 706                                                 // argv_start_index and argv_end_index.
 707
 708                                                 string utf8_enable_save = cvar_string("utf8_enable");
 709                                                 cvar_set("utf8_enable", "0");
 710                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 711                                                 cvar_set("utf8_enable", utf8_enable_save);
 712
 713                                                 Say(caller, false, tell_to, msg, true);
 714                                                 return;
 715                                         }
 716                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 717                                 }
 718                                 else if (argv(1) == "#0")
 719                                 {
 720                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 721                                         return;
 722                                 }
 723                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 724                         }
 725                 }
 726
 727                 default:
 728                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 729                 case CMD_REQUEST_USAGE:
 730                 {
 731                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 732                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 733                         return;
 734                 }
 735         }
 736 }
 737
 738 void ClientCommand_voice(entity caller, int request, int argc, string command)
 739 {
 740         switch (request)
 741         {
 742                 case CMD_REQUEST_COMMAND:
 743                 {
 744                         if (argv(1) != "")
 745                         {
 746                                 entity e = GetVoiceMessage(argv(1));
 747                                 if (!e)
 748                                 {
 749                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 750                                         return;
 751                                 }
 752                                 string msg = "";
 753                                 if (argc >= 3)
 754                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 755                                 VoiceMessage(caller, e, msg);
 756
 757                                 return;
 758                         }
 759                 }
 760
 761                 default:
 762                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 763                 case CMD_REQUEST_USAGE:
 764                 {
 765                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 766                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 767                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 768                         return;
 769                 }
 770         }
 771 }
 772
 773 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 774 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 775 void ClientCommand_(entity caller, int request)
 776 {
 777     switch(request)
 778     {
 779         case CMD_REQUEST_COMMAND:
 780         {
 781
 782             return; // never fall through to usage
 783         }
 784
 785         default:
 786         case CMD_REQUEST_USAGE:
 787         {
 788             sprint(caller, "\nUsage:^3 cmd \n");
 789             sprint(caller, "  No arguments required.\n");
 790             return;
 791         }
 792     }
 793 }
 794 */
 795
 796
 797 // =====================================
 798 //  Macro system for networked commands
 799 // =====================================
 800
 801 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 802 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 803         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 804         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 805         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 806         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 807         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 808         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 809         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 810         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 811         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 812         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 813         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 814         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 815         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 816         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 817         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 818         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 819         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 820         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 821         /* nothing */
 822
 823 void ClientCommand_macro_help(entity caller)
 824 {
 825         #define CLIENT_COMMAND(name, function, description) \
 826                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 827
 828         CLIENT_COMMANDS(NULL, 0, 0, "");
 829 #undef CLIENT_COMMAND
 830 }
 831
 832 float ClientCommand_macro_command(int argc, entity caller, string command)
 833 {
 834         #define CLIENT_COMMAND(name, function, description) \
 835                 { if (name == strtolower(argv(0))) { function; return true; } }
 836
 837         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 838 #undef CLIENT_COMMAND
 839
 840         return false;
 841 }
 842
 843 float ClientCommand_macro_usage(int argc, entity caller)
 844 {
 845         #define CLIENT_COMMAND(name, function, description) \
 846                 { if (name == strtolower(argv(1))) { function; return true; } }
 847
 848         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 849 #undef CLIENT_COMMAND
 850
 851         return false;
 852 }
 853
 854 void ClientCommand_macro_write_aliases(float fh)
 855 {
 856         #define CLIENT_COMMAND(name, function, description) \
 857                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 858
 859         CLIENT_COMMANDS(NULL, 0, 0, "");
 860 #undef CLIENT_COMMAND
 861 }
 862
 863 // ======================================
 864 //  Main Function Called By Engine (cmd)
 865 // ======================================
 866 // If this function exists, server game code parses clientcommand before the engine code gets it.
 867
 868 void SV_ParseClientCommand(entity this, string command)
 869 {
 870         // If invalid UTF-8, don't even parse it
 871         string command2 = "";
 872         float len = strlen(command);
 873         float i;
 874         for (i = 0; i < len; ++i)
 875                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 876         if (command != command2) return;
 877
 878         // if we're banned, don't even parse the command
 879         if (Ban_MaybeEnforceBanOnce(this)) return;
 880
 881         int argc = tokenize_console(command);
 882
 883         // Guide for working with argc arguments by example:
 884         // argc:   1    - 2      - 3     - 4
 885         // argv:   0    - 1      - 2     - 3
 886         // cmd     vote - master - login - password
 887
 888         // for floodcheck
 889         switch (strtolower(argv(0)))
 890         {
 891                 // exempt commands which are not subject to floodcheck
 892                 case "begin": break;                               // handled by engine in host_cmd.c
 893                 case "download": break;                            // handled by engine in cl_parse.c
 894                 case "mv_getpicture": break;                       // handled by server in this file
 895                 case "wpeditor": break;                            // handled by server in this file
 896                 case "pause": break;                               // handled by engine in host_cmd.c
 897                 case "prespawn": break;                            // handled by engine in host_cmd.c
 898                 case "sentcvar": break;                            // handled by server in this file
 899                 case "spawn": break;                               // handled by engine in host_cmd.c
 900                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 901
 902                 default:
 903                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 904                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 905         }
 906
 907         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 908         if (argv(0) == "help")
 909         {
 910                 if (argc == 1)
 911                 {
 912                         sprint(this, "\nClient networked commands:\n");
 913                         ClientCommand_macro_help(this);
 914
 915                         sprint(this, "\nCommon networked commands:\n");
 916                         CommonCommand_macro_help(this);
 917
 918                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 919                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 920                         return;
 921                 }
 922                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 923                 {
 924                         return;
 925                 }
 926                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 927                 {
 928                         return;
 929                 }
 930         }
 931         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 932         {
 933                 return;  // handled by a mutator
 934         }
 935         else if (CheatCommand(this, argc))
 936         {
 937                 return;  // handled by server/cheats.qc
 938         }
 939         else if (CommonCommand_macro_command(argc, this, command))
 940         {
 941                 return;                                          // handled by server/command/common.qc
 942         }
 943         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 944         {
 945                 return;                                          // handled by one of the above ClientCommand_* functions
 946         }
 947         else
 948         {
 949                 clientcommand(this, command);
 950         }
 951 }