qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../campaign.qh"
  12 #include "../cheats.qh"
  13 #include "../player.qh"
  14 #include "../ipban.qh"
  15 #include "../mapvoting.qh"
  16 #include "../scores.qh"
  17 #include "../teamplay.qh"
  18
  19 #include "../mutators/_mod.qh"
  20
  21 #ifdef SVQC
  22         #include <common/vehicles/all.qh>
  23 #endif
  24
  25 #include <common/constants.qh>
  26 #include <common/deathtypes/all.qh>
  27 #include <common/effects/all.qh>
  28 #include <common/mapinfo.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/teams.qh>
  32 #include <common/util.qh>
  33 #include <common/triggers/triggers.qh>
  34
  35 #include <common/minigames/sv_minigames.qh>
  36
  37 #include <common/monsters/_mod.qh>
  38 #include <common/monsters/sv_spawn.qh>
  39 #include <common/monsters/sv_monsters.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42
  43 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
  44
  45 // =========================================================
  46 //  Server side networked commands code, reworked by Samual
  47 //  Last updated: December 28th, 2011
  48 // =========================================================
  49
  50 bool SV_ParseClientCommand_floodcheck(entity this)
  51 {
  52         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  53
  54         if (!timeout_status)  // not while paused
  55         {
  56                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  57                 {
  58                         store.cmd_floodcount += 1;
  59                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  60                 }
  61                 else
  62                 {
  63                         store.cmd_floodtime = time;
  64                         store.cmd_floodcount = 1;
  65                 }
  66         }
  67         return true;  // continue, as we're not flooding yet
  68 }
  69
  70
  71 // =======================
  72 //  Command Sub-Functions
  73 // =======================
  74
  75 void ClientCommand_autoswitch(entity caller, float request, float argc)
  76 {
  77         switch (request)
  78         {
  79                 case CMD_REQUEST_COMMAND:
  80                 {
  81                         if (argv(1) != "")
  82                         {
  83                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  84                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  85                                 return;
  86                         }
  87                 }
  88
  89                 default:
  90                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  91                 case CMD_REQUEST_USAGE:
  92                 {
  93                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  94                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  95                         return;
  96                 }
  97         }
  98 }
  99
 100 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
 101 {
 102         switch (request)
 103         {
 104                 case CMD_REQUEST_COMMAND:
 105                 {
 106                         if (argv(1) != "")
 107                         {
 108                                 if (IS_CLIENT(caller))
 109                                 {
 110                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 111
 112                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 113                                         {
 114                                                 CS(caller).version_mismatch = true;
 115                                                 ClientKill_TeamChange(caller, -2);  // observe
 116                                         }
 117                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 118                                         {
 119                                                 // JoinBestTeam(caller, false, true);
 120                                         }
 121                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 122                                         {
 123                                                 TRANSMUTE(Observer, caller);  // really?
 124                                                 stuffcmd(caller, "menu_showteamselect\n");
 125                                         }
 126                                 }
 127
 128                                 return;
 129                         }
 130                 }
 131
 132                 default:
 133                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 134                 case CMD_REQUEST_USAGE:
 135                 {
 136                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 137                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 138                         return;
 139                 }
 140         }
 141 }
 142
 143 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 144 {
 145         switch (request)
 146         {
 147                 case CMD_REQUEST_COMMAND:
 148                 {
 149                         if (argv(1) != "")
 150                         {
 151                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 152
 153                                 return;
 154                         }
 155                 }
 156
 157                 default:
 158                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 159                 case CMD_REQUEST_USAGE:
 160                 {
 161                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 162                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 163                         return;
 164                 }
 165         }
 166 }
 167
 168 bool joinAllowed(entity this);
 169 void Join(entity this);
 170 void ClientCommand_join(entity caller, float request)
 171 {
 172         switch (request)
 173         {
 174                 case CMD_REQUEST_COMMAND:
 175                 {
 176                         if (!game_stopped)
 177                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 178                         if (joinAllowed(caller))
 179                                 Join(caller);
 180
 181                         return;  // never fall through to usage
 182                 }
 183
 184                 default:
 185                 case CMD_REQUEST_USAGE:
 186                 {
 187                         sprint(caller, "\nUsage:^3 cmd join\n");
 188                         sprint(caller, "  No arguments required.\n");
 189                         return;
 190                 }
 191         }
 192 }
 193
 194 void ClientCommand_physics(entity caller, float request, float argc)
 195 {
 196         switch (request)
 197         {
 198                 case CMD_REQUEST_COMMAND:
 199                 {
 200                         string command = strtolower(argv(1));
 201
 202                         if (!autocvar_g_physics_clientselect)
 203                         {
 204                                 sprint(caller, "Client physics selection is currently disabled.\n");
 205                                 return;
 206                         }
 207
 208                         if (command == "list" || command == "help")
 209                         {
 210                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 211                                 return;
 212                         }
 213
 214                         if (Physics_Valid(command) || command == "default")
 215                         {
 216                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 217                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 218                                 return;
 219                         }
 220                 }
 221
 222                 default:
 223                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 224                 case CMD_REQUEST_USAGE:
 225                 {
 226                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 227                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 228                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 229                         return;
 230                 }
 231         }
 232 }
 233
 234 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 235 {
 236         switch (request)
 237         {
 238                 case CMD_REQUEST_COMMAND:
 239                 {
 240                         if (IS_CLIENT(caller))
 241                         {
 242                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 243                                 {
 244                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 245                                         {
 246                                                 if (time < game_starttime) // game is already restarting
 247                                                         return;
 248                                                 if (caller.ready)            // toggle
 249                                                 {
 250                                                         caller.ready = false;
 251                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 252                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 253                                                 }
 254                                                 else
 255                                                 {
 256                                                         caller.ready = true;
 257                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 258                                                                 bprint(playername(caller, false), "^2 is ready\n");
 259                                                 }
 260
 261                                                 // cannot reset the game while a timeout is active!
 262                                                 if (!timeout_status) ReadyCount();
 263                                         }
 264                                         else
 265                                         {
 266                                                 sprint(caller, "^1Game has already been restarted\n");
 267                                         }
 268                                 }
 269                         }
 270                         return;  // never fall through to usage
 271                 }
 272
 273                 default:
 274                 case CMD_REQUEST_USAGE:
 275                 {
 276                         sprint(caller, "\nUsage:^3 cmd ready\n");
 277                         sprint(caller, "  No arguments required.\n");
 278                         return;
 279                 }
 280         }
 281 }
 282
 283 void ClientCommand_say(entity caller, float request, float argc, string command)
 284 {
 285         switch (request)
 286         {
 287                 case CMD_REQUEST_COMMAND:
 288                 {
 289                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 290                         return;  // never fall through to usage
 291                 }
 292
 293                 default:
 294                 case CMD_REQUEST_USAGE:
 295                 {
 296                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 297                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 298                         return;
 299                 }
 300         }
 301 }
 302
 303 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 304 {
 305         switch (request)
 306         {
 307                 case CMD_REQUEST_COMMAND:
 308                 {
 309                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 310                         return;  // never fall through to usage
 311                 }
 312
 313                 default:
 314                 case CMD_REQUEST_USAGE:
 315                 {
 316                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 317                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 318                         return;
 319                 }
 320         }
 321 }
 322
 323 .bool team_selected;
 324 void ClientCommand_selectteam(entity caller, float request, float argc)
 325 {
 326         switch (request)
 327         {
 328                 case CMD_REQUEST_COMMAND:
 329                 {
 330                         if (argv(1) == "")
 331                         {
 332                                 return;
 333                         }
 334                         if (!IS_CLIENT(caller))
 335                         {
 336                                 return;
 337                         }
 338                         if (!teamplay)
 339                         {
 340                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 341                                 return;
 342                         }
 343                         if (caller.team_forced > 0)
 344                         {
 345                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 346                                 return;
 347                         }
 348                         if (lockteams)
 349                         {
 350                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 351                                 return;
 352                         }
 353                         float selection;
 354                         switch (argv(1))
 355                         {
 356                                 case "red":
 357                                 {
 358                                         selection = NUM_TEAM_1;
 359                                         break;
 360                                 }
 361                                 case "blue":
 362                                 {
 363                                         selection = NUM_TEAM_2;
 364                                         break;
 365                                 }
 366                                 case "yellow":
 367                                 {
 368                                         selection = NUM_TEAM_3;
 369                                         break;
 370                                 }
 371                                 case "pink":
 372                                 {
 373                                         selection = NUM_TEAM_4;
 374                                         break;
 375                                 }
 376                                 case "auto":
 377                                 {
 378                                         selection = (-1);
 379                                         break;
 380                                 }
 381                                 default:
 382                                 {
 383                                         return;
 384                                 }
 385                         }
 386                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 387                         {
 388                                 sprint(caller, "^7You already are on that team.\n");
 389                                 return;
 390                         }
 391                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 392                         {
 393                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 394                                 return;
 395                         }
 396                         if ((selection != -1) && autocvar_g_balance_teams &&
 397                                 autocvar_g_balance_teams_prevent_imbalance)
 398                         {
 399                                 CheckAllowedTeams(caller);
 400                                 GetTeamCounts(caller);
 401                                 if ((BIT(Team_TeamToNumber(selection) - 1) & FindBestTeams(caller, false)) == 0)
 402                                 {
 403                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 404                                         return;
 405                                 }
 406                         }
 407                         ClientKill_TeamChange(caller, selection);
 408                         if (!IS_PLAYER(caller))
 409                         {
 410                                 caller.team_selected = true; // avoids asking again for team selection on join
 411                         }
 412                         return;
 413                 }
 414                 default:
 415                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 416                 case CMD_REQUEST_USAGE:
 417                 {
 418                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 419                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 420                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 421                         return;
 422                 }
 423         }
 424 }
 425
 426 void ClientCommand_selfstuff(entity caller, float request, string command)
 427 {
 428         switch (request)
 429         {
 430                 case CMD_REQUEST_COMMAND:
 431                 {
 432                         if (argv(1) != "")
 433                         {
 434                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 435                                 return;
 436                         }
 437                 }
 438
 439                 default:
 440                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 441                 case CMD_REQUEST_USAGE:
 442                 {
 443                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 444                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 445                         return;
 446                 }
 447         }
 448 }
 449
 450 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 451 {
 452         switch (request)
 453         {
 454                 case CMD_REQUEST_COMMAND:
 455                 {
 456                         if (argv(1) != "")
 457                         {
 458                                 // float tokens;
 459                                 string s;
 460
 461                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 462                                 {
 463                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 464                                         tokenize_console(s);
 465                                 }
 466
 467                                 GetCvars(caller, CS(caller), 1);
 468
 469                                 return;
 470                         }
 471                 }
 472
 473                 default:
 474                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 475                 case CMD_REQUEST_USAGE:
 476                 {
 477                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 478                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 479                         return;
 480                 }
 481         }
 482 }
 483
 484 void ClientCommand_spectate(entity caller, float request)
 485 {
 486         switch (request)
 487         {
 488                 case CMD_REQUEST_COMMAND:
 489                 {
 490                         if (!intermission_running && IS_CLIENT(caller))
 491                         {
 492                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 493                                 {
 494                                         entity client = GetFilteredEntity(argv(1));
 495                                         int spec_accepted = VerifyClientEntity(client, false, false);
 496                                         if(spec_accepted > 0 && IS_PLAYER(client))
 497                                         {
 498                                                 if(Spectate(caller, client))
 499                                                         return; // fall back to regular handling
 500                                         }
 501                                 }
 502
 503                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 504
 505                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 506
 507                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 508                                 if (autocvar_sv_spectate == 1)
 509                                         ClientKill_TeamChange(caller, -2); // observe
 510                         }
 511                         return; // never fall through to usage
 512                 }
 513
 514                 default:
 515                 case CMD_REQUEST_USAGE:
 516                 {
 517                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 518                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 519                         return;
 520                 }
 521         }
 522 }
 523
 524 void ClientCommand_suggestmap(entity caller, float request, float argc)
 525 {
 526         switch (request)
 527         {
 528                 case CMD_REQUEST_COMMAND:
 529                 {
 530                         if (argv(1) != "")
 531                         {
 532                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 533                                 return;
 534                         }
 535                 }
 536
 537                 default:
 538                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 539                 case CMD_REQUEST_USAGE:
 540                 {
 541                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 542                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 543                         return;
 544                 }
 545         }
 546 }
 547
 548 void ClientCommand_tell(entity caller, float request, float argc, string command)
 549 {
 550         switch (request)
 551         {
 552                 case CMD_REQUEST_COMMAND:
 553                 {
 554                         if (argc >= 3)
 555                         {
 556                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 557                                 {
 558                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 559                                         return;
 560                                 }
 561
 562                                 entity tell_to = GetIndexedEntity(argc, 1);
 563                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 564
 565                                 if (tell_accepted > 0)   // the target is a real client
 566                                 {
 567                                         if (tell_to != caller) // and we're allowed to send to them :D
 568                                         {
 569                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 570                                                 // In this case when the player name contains utf8 chars
 571                                                 // the message gets partially trimmed in the beginning.
 572                                                 // Potentially this bug affects any substring call that uses
 573                                                 // argv_start_index and argv_end_index.
 574
 575                                                 string utf8_enable_save = cvar_string("utf8_enable");
 576                                                 cvar_set("utf8_enable", "0");
 577                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 578                                                 cvar_set("utf8_enable", utf8_enable_save);
 579
 580                                                 Say(caller, false, tell_to, msg, true);
 581                                                 return;
 582                                         }
 583                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 584                                 }
 585                                 else if (argv(1) == "#0")
 586                                 {
 587                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 588                                         return;
 589                                 }
 590                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 591                         }
 592                 }
 593
 594                 default:
 595                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 596                 case CMD_REQUEST_USAGE:
 597                 {
 598                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 599                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 600                         return;
 601                 }
 602         }
 603 }
 604
 605 void ClientCommand_voice(entity caller, float request, float argc, string command)
 606 {
 607         switch (request)
 608         {
 609                 case CMD_REQUEST_COMMAND:
 610                 {
 611                         if (argv(1) != "")
 612                         {
 613                                 entity e = GetVoiceMessage(argv(1));
 614                                 if (!e)
 615                                 {
 616                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 617                                         return;
 618                                 }
 619                                 string msg = "";
 620                                 if (argc >= 3)
 621                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 622                                 VoiceMessage(caller, e, msg);
 623
 624                                 return;
 625                         }
 626                 }
 627
 628                 default:
 629                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 630                 case CMD_REQUEST_USAGE:
 631                 {
 632                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 633                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 634                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 635                         return;
 636                 }
 637         }
 638 }
 639
 640 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 641 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 642 void ClientCommand_(entity caller, float request)
 643 {
 644     switch(request)
 645     {
 646         case CMD_REQUEST_COMMAND:
 647         {
 648
 649             return; // never fall through to usage
 650         }
 651
 652         default:
 653         case CMD_REQUEST_USAGE:
 654         {
 655             sprint(caller, "\nUsage:^3 cmd \n");
 656             sprint(caller, "  No arguments required.\n");
 657             return;
 658         }
 659     }
 660 }
 661 */
 662
 663
 664 // =====================================
 665 //  Macro system for networked commands
 666 // =====================================
 667
 668 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 669 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 670         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 671         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 672         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 673         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 674         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 675         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 676         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 677         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 678         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 679         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 680         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 681         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 682         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 683         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 684         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 685         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 686         /* nothing */
 687
 688 void ClientCommand_macro_help(entity caller)
 689 {
 690         #define CLIENT_COMMAND(name, function, description) \
 691                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 692
 693         CLIENT_COMMANDS(NULL, 0, 0, "");
 694 #undef CLIENT_COMMAND
 695 }
 696
 697 float ClientCommand_macro_command(float argc, entity caller, string command)
 698 {
 699         #define CLIENT_COMMAND(name, function, description) \
 700                 { if (name == strtolower(argv(0))) { function; return true; } }
 701
 702         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 703 #undef CLIENT_COMMAND
 704
 705         return false;
 706 }
 707
 708 float ClientCommand_macro_usage(float argc, entity caller)
 709 {
 710         #define CLIENT_COMMAND(name, function, description) \
 711                 { if (name == strtolower(argv(1))) { function; return true; } }
 712
 713         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 714 #undef CLIENT_COMMAND
 715
 716         return false;
 717 }
 718
 719 void ClientCommand_macro_write_aliases(float fh)
 720 {
 721         #define CLIENT_COMMAND(name, function, description) \
 722                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 723
 724         CLIENT_COMMANDS(NULL, 0, 0, "");
 725 #undef CLIENT_COMMAND
 726 }
 727
 728 // ======================================
 729 //  Main Function Called By Engine (cmd)
 730 // ======================================
 731 // If this function exists, server game code parses clientcommand before the engine code gets it.
 732
 733 void SV_ParseClientCommand(entity this, string command)
 734 {
 735         // If invalid UTF-8, don't even parse it
 736         string command2 = "";
 737         float len = strlen(command);
 738         float i;
 739         for (i = 0; i < len; ++i)
 740                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 741         if (command != command2) return;
 742
 743         // if we're banned, don't even parse the command
 744         if (Ban_MaybeEnforceBanOnce(this)) return;
 745
 746         float argc = tokenize_console(command);
 747
 748         // Guide for working with argc arguments by example:
 749         // argc:   1    - 2      - 3     - 4
 750         // argv:   0    - 1      - 2     - 3
 751         // cmd     vote - master - login - password
 752
 753         // for floodcheck
 754         switch (strtolower(argv(0)))
 755         {
 756                 // exempt commands which are not subject to floodcheck
 757                 case "begin": break;                               // handled by engine in host_cmd.c
 758                 case "download": break;                            // handled by engine in cl_parse.c
 759                 case "mv_getpicture": break;                       // handled by server in this file
 760                 case "pause": break;                               // handled by engine in host_cmd.c
 761                 case "prespawn": break;                            // handled by engine in host_cmd.c
 762                 case "sentcvar": break;                            // handled by server in this file
 763                 case "spawn": break;                               // handled by engine in host_cmd.c
 764                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 765
 766                 default:
 767                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 768                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 769         }
 770
 771         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 772         if (argv(0) == "help")
 773         {
 774                 if (argc == 1)
 775                 {
 776                         sprint(this, "\nClient networked commands:\n");
 777                         ClientCommand_macro_help(this);
 778
 779                         sprint(this, "\nCommon networked commands:\n");
 780                         CommonCommand_macro_help(this);
 781
 782                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 783                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 784                         return;
 785                 }
 786                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 787                 {
 788                         return;
 789                 }
 790                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 791                 {
 792                         return;
 793                 }
 794         }
 795         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 796         {
 797                 return;  // handled by a mutator
 798         }
 799         else if (CheatCommand(this, argc))
 800         {
 801                 return;  // handled by server/cheats.qc
 802         }
 803         else if (CommonCommand_macro_command(argc, this, command))
 804         {
 805                 return;                                          // handled by server/command/common.qc
 806         }
 807         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 808         {
 809                 return;                                          // handled by one of the above ClientCommand_* functions
 810         }
 811         else
 812         {
 813                 clientcommand(this, command);
 814         }
 815 }