qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../campaign.qh"
  12 #include "../cheats.qh"
  13 #include "../player.qh"
  14 #include "../ipban.qh"
  15 #include "../mapvoting.qh"
  16 #include "../scores.qh"
  17 #include "../teamplay.qh"
  18
  19 #include "../mutators/_mod.qh"
  20 #include <common/gamemodes/_mod.qh>
  21
  22 #ifdef SVQC
  23         #include <common/vehicles/all.qh>
  24 #endif
  25
  26 #include <common/constants.qh>
  27 #include <common/deathtypes/all.qh>
  28 #include <common/effects/all.qh>
  29 #include <common/mapinfo.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34 #include <common/mapobjects/triggers.qh>
  35
  36 #include <common/minigames/sv_minigames.qh>
  37
  38 #include <common/monsters/_mod.qh>
  39 #include <common/monsters/sv_spawn.qh>
  40 #include <common/monsters/sv_monsters.qh>
  41
  42 #include <lib/warpzone/common.qh>
  43
  44 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
  45
  46 // =========================================================
  47 //  Server side networked commands code, reworked by Samual
  48 //  Last updated: December 28th, 2011
  49 // =========================================================
  50
  51 bool SV_ParseClientCommand_floodcheck(entity this)
  52 {
  53         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  54
  55         if (!timeout_status)  // not while paused
  56         {
  57                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  58                 {
  59                         store.cmd_floodcount += 1;
  60                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  61                 }
  62                 else
  63                 {
  64                         store.cmd_floodtime = time;
  65                         store.cmd_floodcount = 1;
  66                 }
  67         }
  68         return true;  // continue, as we're not flooding yet
  69 }
  70
  71
  72 // =======================
  73 //  Command Sub-Functions
  74 // =======================
  75
  76 void ClientCommand_autoswitch(entity caller, float request, float argc)
  77 {
  78         switch (request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if (argv(1) != "")
  83                         {
  84                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  85                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  86                                 return;
  87                         }
  88                 }
  89
  90                 default:
  91                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  92                 case CMD_REQUEST_USAGE:
  93                 {
  94                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  95                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  96                         return;
  97                 }
  98         }
  99 }
 100
 101 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
 102 {
 103         switch (request)
 104         {
 105                 case CMD_REQUEST_COMMAND:
 106                 {
 107                         if (argv(1) != "")
 108                         {
 109                                 if (IS_CLIENT(caller))
 110                                 {
 111                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 112
 113                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 114                                         {
 115                                                 CS(caller).version_mismatch = true;
 116                                                 ClientKill_TeamChange(caller, -2);  // observe
 117                                         }
 118                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 119                                         {
 120                                                 // JoinBestTeam(caller, false, true);
 121                                         }
 122                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 123                                         {
 124                                                 TRANSMUTE(Observer, caller);  // really?
 125                                                 stuffcmd(caller, "menu_showteamselect\n");
 126                                         }
 127                                 }
 128
 129                                 return;
 130                         }
 131                 }
 132
 133                 default:
 134                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 135                 case CMD_REQUEST_USAGE:
 136                 {
 137                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 138                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 139                         return;
 140                 }
 141         }
 142 }
 143
 144 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 145 {
 146         switch (request)
 147         {
 148                 case CMD_REQUEST_COMMAND:
 149                 {
 150                         if (argv(1) != "")
 151                         {
 152                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 153
 154                                 return;
 155                         }
 156                 }
 157
 158                 default:
 159                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 160                 case CMD_REQUEST_USAGE:
 161                 {
 162                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 163                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 164                         return;
 165                 }
 166         }
 167 }
 168
 169 bool joinAllowed(entity this);
 170 void Join(entity this);
 171 void ClientCommand_join(entity caller, float request)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         if (!game_stopped)
 178                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 179                         if (joinAllowed(caller))
 180                                 Join(caller);
 181
 182                         return;  // never fall through to usage
 183                 }
 184
 185                 default:
 186                 case CMD_REQUEST_USAGE:
 187                 {
 188                         sprint(caller, "\nUsage:^3 cmd join\n");
 189                         sprint(caller, "  No arguments required.\n");
 190                         return;
 191                 }
 192         }
 193 }
 194
 195 void ClientCommand_physics(entity caller, float request, float argc)
 196 {
 197         switch (request)
 198         {
 199                 case CMD_REQUEST_COMMAND:
 200                 {
 201                         string command = strtolower(argv(1));
 202
 203                         if (!autocvar_g_physics_clientselect)
 204                         {
 205                                 sprint(caller, "Client physics selection is currently disabled.\n");
 206                                 return;
 207                         }
 208
 209                         if (command == "list" || command == "help")
 210                         {
 211                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 212                                 return;
 213                         }
 214
 215                         if (Physics_Valid(command) || command == "default")
 216                         {
 217                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 218                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 219                                 return;
 220                         }
 221                 }
 222
 223                 default:
 224                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 225                 case CMD_REQUEST_USAGE:
 226                 {
 227                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 228                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 229                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 230                         return;
 231                 }
 232         }
 233 }
 234
 235 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 236 {
 237         switch (request)
 238         {
 239                 case CMD_REQUEST_COMMAND:
 240                 {
 241                         if (IS_CLIENT(caller))
 242                         {
 243                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 244                                 {
 245                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 246                                         {
 247                                                 if (time < game_starttime) // game is already restarting
 248                                                         return;
 249                                                 if (caller.ready)            // toggle
 250                                                 {
 251                                                         caller.ready = false;
 252                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 253                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 254                                                 }
 255                                                 else
 256                                                 {
 257                                                         caller.ready = true;
 258                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 259                                                                 bprint(playername(caller, false), "^2 is ready\n");
 260                                                 }
 261
 262                                                 // cannot reset the game while a timeout is active!
 263                                                 if (!timeout_status) ReadyCount();
 264                                         }
 265                                         else
 266                                         {
 267                                                 sprint(caller, "^1Game has already been restarted\n");
 268                                         }
 269                                 }
 270                         }
 271                         return;  // never fall through to usage
 272                 }
 273
 274                 default:
 275                 case CMD_REQUEST_USAGE:
 276                 {
 277                         sprint(caller, "\nUsage:^3 cmd ready\n");
 278                         sprint(caller, "  No arguments required.\n");
 279                         return;
 280                 }
 281         }
 282 }
 283
 284 void ClientCommand_say(entity caller, float request, float argc, string command)
 285 {
 286         switch (request)
 287         {
 288                 case CMD_REQUEST_COMMAND:
 289                 {
 290                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 291                         return;  // never fall through to usage
 292                 }
 293
 294                 default:
 295                 case CMD_REQUEST_USAGE:
 296                 {
 297                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 298                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 299                         return;
 300                 }
 301         }
 302 }
 303
 304 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 305 {
 306         switch (request)
 307         {
 308                 case CMD_REQUEST_COMMAND:
 309                 {
 310                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 311                         return;  // never fall through to usage
 312                 }
 313
 314                 default:
 315                 case CMD_REQUEST_USAGE:
 316                 {
 317                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 318                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 319                         return;
 320                 }
 321         }
 322 }
 323
 324 .bool team_selected;
 325 void ClientCommand_selectteam(entity caller, float request, float argc)
 326 {
 327         switch (request)
 328         {
 329                 case CMD_REQUEST_COMMAND:
 330                 {
 331                         if (argv(1) == "")
 332                         {
 333                                 return;
 334                         }
 335                         if (!IS_CLIENT(caller))
 336                         {
 337                                 return;
 338                         }
 339                         if (!teamplay)
 340                         {
 341                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 342                                 return;
 343                         }
 344                         if (caller.team_forced > 0)
 345                         {
 346                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 347                                 return;
 348                         }
 349                         if (lockteams)
 350                         {
 351                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 352                                 return;
 353                         }
 354                         float selection;
 355                         switch (argv(1))
 356                         {
 357                                 case "red":
 358                                 {
 359                                         selection = NUM_TEAM_1;
 360                                         break;
 361                                 }
 362                                 case "blue":
 363                                 {
 364                                         selection = NUM_TEAM_2;
 365                                         break;
 366                                 }
 367                                 case "yellow":
 368                                 {
 369                                         selection = NUM_TEAM_3;
 370                                         break;
 371                                 }
 372                                 case "pink":
 373                                 {
 374                                         selection = NUM_TEAM_4;
 375                                         break;
 376                                 }
 377                                 case "auto":
 378                                 {
 379                                         selection = (-1);
 380                                         break;
 381                                 }
 382                                 default:
 383                                 {
 384                                         return;
 385                                 }
 386                         }
 387                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 388                         {
 389                                 sprint(caller, "^7You already are on that team.\n");
 390                                 return;
 391                         }
 392                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 393                         {
 394                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 395                                 return;
 396                         }
 397                         if ((selection != -1) && autocvar_g_balance_teams &&
 398                                 autocvar_g_balance_teams_prevent_imbalance)
 399                         {
 400                                 CheckAllowedTeams(caller);
 401                                 GetTeamCounts(caller);
 402                                 if ((BIT(Team_TeamToNumber(selection) - 1) & FindBestTeams(caller, false)) == 0)
 403                                 {
 404                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 405                                         return;
 406                                 }
 407                         }
 408                         ClientKill_TeamChange(caller, selection);
 409                         if (!IS_PLAYER(caller))
 410                         {
 411                                 caller.team_selected = true; // avoids asking again for team selection on join
 412                         }
 413                         return;
 414                 }
 415                 default:
 416                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 417                 case CMD_REQUEST_USAGE:
 418                 {
 419                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 420                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 421                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 422                         return;
 423                 }
 424         }
 425 }
 426
 427 void ClientCommand_selfstuff(entity caller, float request, string command)
 428 {
 429         switch (request)
 430         {
 431                 case CMD_REQUEST_COMMAND:
 432                 {
 433                         if (argv(1) != "")
 434                         {
 435                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 436                                 return;
 437                         }
 438                 }
 439
 440                 default:
 441                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 442                 case CMD_REQUEST_USAGE:
 443                 {
 444                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 445                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 446                         return;
 447                 }
 448         }
 449 }
 450
 451 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 452 {
 453         switch (request)
 454         {
 455                 case CMD_REQUEST_COMMAND:
 456                 {
 457                         if (argv(1) != "")
 458                         {
 459                                 // float tokens;
 460                                 string s;
 461
 462                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 463                                 {
 464                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 465                                         tokenize_console(s);
 466                                 }
 467
 468                                 GetCvars(caller, CS(caller), 1);
 469
 470                                 return;
 471                         }
 472                 }
 473
 474                 default:
 475                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 476                 case CMD_REQUEST_USAGE:
 477                 {
 478                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 479                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 480                         return;
 481                 }
 482         }
 483 }
 484
 485 void ClientCommand_spectate(entity caller, float request)
 486 {
 487         switch (request)
 488         {
 489                 case CMD_REQUEST_COMMAND:
 490                 {
 491                         if (!intermission_running && IS_CLIENT(caller))
 492                         {
 493                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 494                                 {
 495                                         entity client = GetFilteredEntity(argv(1));
 496                                         int spec_accepted = VerifyClientEntity(client, false, false);
 497                                         if(spec_accepted > 0 && IS_PLAYER(client))
 498                                         {
 499                                                 if(Spectate(caller, client))
 500                                                         return; // fall back to regular handling
 501                                         }
 502                                 }
 503
 504                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 505
 506                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 507
 508                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 509                                 if (autocvar_sv_spectate == 1)
 510                                         ClientKill_TeamChange(caller, -2); // observe
 511                         }
 512                         return; // never fall through to usage
 513                 }
 514
 515                 default:
 516                 case CMD_REQUEST_USAGE:
 517                 {
 518                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 519                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 520                         return;
 521                 }
 522         }
 523 }
 524
 525 void ClientCommand_suggestmap(entity caller, float request, float argc)
 526 {
 527         switch (request)
 528         {
 529                 case CMD_REQUEST_COMMAND:
 530                 {
 531                         if (argv(1) != "")
 532                         {
 533                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 534                                 return;
 535                         }
 536                 }
 537
 538                 default:
 539                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 540                 case CMD_REQUEST_USAGE:
 541                 {
 542                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 543                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 544                         return;
 545                 }
 546         }
 547 }
 548
 549 void ClientCommand_tell(entity caller, float request, float argc, string command)
 550 {
 551         switch (request)
 552         {
 553                 case CMD_REQUEST_COMMAND:
 554                 {
 555                         if (argc >= 3)
 556                         {
 557                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 558                                 {
 559                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 560                                         return;
 561                                 }
 562
 563                                 entity tell_to = GetIndexedEntity(argc, 1);
 564                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 565
 566                                 if (tell_accepted > 0)   // the target is a real client
 567                                 {
 568                                         if (tell_to != caller) // and we're allowed to send to them :D
 569                                         {
 570                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 571                                                 // In this case when the player name contains utf8 chars
 572                                                 // the message gets partially trimmed in the beginning.
 573                                                 // Potentially this bug affects any substring call that uses
 574                                                 // argv_start_index and argv_end_index.
 575
 576                                                 string utf8_enable_save = cvar_string("utf8_enable");
 577                                                 cvar_set("utf8_enable", "0");
 578                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 579                                                 cvar_set("utf8_enable", utf8_enable_save);
 580
 581                                                 Say(caller, false, tell_to, msg, true);
 582                                                 return;
 583                                         }
 584                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 585                                 }
 586                                 else if (argv(1) == "#0")
 587                                 {
 588                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 589                                         return;
 590                                 }
 591                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 592                         }
 593                 }
 594
 595                 default:
 596                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 597                 case CMD_REQUEST_USAGE:
 598                 {
 599                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 600                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 601                         return;
 602                 }
 603         }
 604 }
 605
 606 void ClientCommand_voice(entity caller, float request, float argc, string command)
 607 {
 608         switch (request)
 609         {
 610                 case CMD_REQUEST_COMMAND:
 611                 {
 612                         if (argv(1) != "")
 613                         {
 614                                 entity e = GetVoiceMessage(argv(1));
 615                                 if (!e)
 616                                 {
 617                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 618                                         return;
 619                                 }
 620                                 string msg = "";
 621                                 if (argc >= 3)
 622                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 623                                 VoiceMessage(caller, e, msg);
 624
 625                                 return;
 626                         }
 627                 }
 628
 629                 default:
 630                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 631                 case CMD_REQUEST_USAGE:
 632                 {
 633                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 634                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 635                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 636                         return;
 637                 }
 638         }
 639 }
 640
 641 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 642 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 643 void ClientCommand_(entity caller, float request)
 644 {
 645     switch(request)
 646     {
 647         case CMD_REQUEST_COMMAND:
 648         {
 649
 650             return; // never fall through to usage
 651         }
 652
 653         default:
 654         case CMD_REQUEST_USAGE:
 655         {
 656             sprint(caller, "\nUsage:^3 cmd \n");
 657             sprint(caller, "  No arguments required.\n");
 658             return;
 659         }
 660     }
 661 }
 662 */
 663
 664
 665 // =====================================
 666 //  Macro system for networked commands
 667 // =====================================
 668
 669 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 670 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 671         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 672         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 673         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 674         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 675         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 676         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 677         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 678         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 679         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 680         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 681         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 682         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 683         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 684         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 685         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 686         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 687         /* nothing */
 688
 689 void ClientCommand_macro_help(entity caller)
 690 {
 691         #define CLIENT_COMMAND(name, function, description) \
 692                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 693
 694         CLIENT_COMMANDS(NULL, 0, 0, "");
 695 #undef CLIENT_COMMAND
 696 }
 697
 698 float ClientCommand_macro_command(float argc, entity caller, string command)
 699 {
 700         #define CLIENT_COMMAND(name, function, description) \
 701                 { if (name == strtolower(argv(0))) { function; return true; } }
 702
 703         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 704 #undef CLIENT_COMMAND
 705
 706         return false;
 707 }
 708
 709 float ClientCommand_macro_usage(float argc, entity caller)
 710 {
 711         #define CLIENT_COMMAND(name, function, description) \
 712                 { if (name == strtolower(argv(1))) { function; return true; } }
 713
 714         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 715 #undef CLIENT_COMMAND
 716
 717         return false;
 718 }
 719
 720 void ClientCommand_macro_write_aliases(float fh)
 721 {
 722         #define CLIENT_COMMAND(name, function, description) \
 723                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 724
 725         CLIENT_COMMANDS(NULL, 0, 0, "");
 726 #undef CLIENT_COMMAND
 727 }
 728
 729 // ======================================
 730 //  Main Function Called By Engine (cmd)
 731 // ======================================
 732 // If this function exists, server game code parses clientcommand before the engine code gets it.
 733
 734 void SV_ParseClientCommand(entity this, string command)
 735 {
 736         // If invalid UTF-8, don't even parse it
 737         string command2 = "";
 738         float len = strlen(command);
 739         float i;
 740         for (i = 0; i < len; ++i)
 741                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 742         if (command != command2) return;
 743
 744         // if we're banned, don't even parse the command
 745         if (Ban_MaybeEnforceBanOnce(this)) return;
 746
 747         float argc = tokenize_console(command);
 748
 749         // Guide for working with argc arguments by example:
 750         // argc:   1    - 2      - 3     - 4
 751         // argv:   0    - 1      - 2     - 3
 752         // cmd     vote - master - login - password
 753
 754         // for floodcheck
 755         switch (strtolower(argv(0)))
 756         {
 757                 // exempt commands which are not subject to floodcheck
 758                 case "begin": break;                               // handled by engine in host_cmd.c
 759                 case "download": break;                            // handled by engine in cl_parse.c
 760                 case "mv_getpicture": break;                       // handled by server in this file
 761                 case "pause": break;                               // handled by engine in host_cmd.c
 762                 case "prespawn": break;                            // handled by engine in host_cmd.c
 763                 case "sentcvar": break;                            // handled by server in this file
 764                 case "spawn": break;                               // handled by engine in host_cmd.c
 765                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 766
 767                 default:
 768                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 769                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 770         }
 771
 772         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 773         if (argv(0) == "help")
 774         {
 775                 if (argc == 1)
 776                 {
 777                         sprint(this, "\nClient networked commands:\n");
 778                         ClientCommand_macro_help(this);
 779
 780                         sprint(this, "\nCommon networked commands:\n");
 781                         CommonCommand_macro_help(this);
 782
 783                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 784                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 785                         return;
 786                 }
 787                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 788                 {
 789                         return;
 790                 }
 791                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 792                 {
 793                         return;
 794                 }
 795         }
 796         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 797         {
 798                 return;  // handled by a mutator
 799         }
 800         else if (CheatCommand(this, argc))
 801         {
 802                 return;  // handled by server/cheats.qc
 803         }
 804         else if (CommonCommand_macro_command(argc, this, command))
 805         {
 806                 return;                                          // handled by server/command/common.qc
 807         }
 808         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 809         {
 810                 return;                                          // handled by one of the above ClientCommand_* functions
 811         }
 812         else
 813         {
 814                 clientcommand(this, command);
 815         }
 816 }