qcsrc/server/command/common.qc

   1 #include "common.qh"
   2 #include <common/command/command.qh>
   3 #include "common.qh"
   4
   5 #include "../scores.qh"
   6
   7 #include <common/monsters/all.qh>
   8 #include <common/notifications/all.qh>
   9 #include <lib/warpzone/common.qh>
  10
  11
  12 // ====================================================
  13 //  Shared code for server commands, written by Samual
  14 //  Last updated: December 27th, 2011
  15 // ====================================================
  16
  17 // select the proper prefix for usage and other messages
  18 string GetCommandPrefix(entity caller)
  19 {
  20         if (caller) return "cmd";
  21         else return "sv_cmd";
  22 }
  23
  24 // if client return player nickname, or if server return admin nickname
  25 string GetCallerName(entity caller)
  26 {
  27         if (caller) return caller.netname;
  28         else return admin_name();  // ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  29 }
  30
  31 // verify that the client provided is acceptable for kicking
  32 float VerifyKickableEntity(entity client)
  33 {
  34         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  35         return CLIENT_ACCEPTABLE;
  36 }
  37
  38 // verify that the client provided is acceptable for use
  39 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  40 {
  41         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  42         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  43         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  44
  45         return CLIENT_ACCEPTABLE;
  46 }
  47
  48 // if the client is not acceptable, return a string to be used for error messages
  49 string GetClientErrorString_color(float clienterror, string original_input, string col)
  50 {
  51         switch (clienterror)
  52         {
  53                 case CLIENT_DOESNT_EXIST:
  54                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  55                 }
  56                 case CLIENT_NOT_REAL:
  57                 { return strcat(col, "Client '", original_input, col, "' is not real");
  58                 }
  59                 case CLIENT_NOT_BOT:
  60                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  61                 }
  62                 default:
  63                 { return "Incorrect usage of GetClientErrorString";
  64                 }
  65         }
  66 }
  67
  68 // is this entity number even in the possible range of entities?
  69 float VerifyClientNumber(float tmp_number)
  70 {
  71         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  72         else return true;
  73 }
  74
  75 entity GetIndexedEntity(float argc, float start_index)
  76 {
  77         entity selection;
  78         float tmp_number, index;
  79         string tmp_string;
  80
  81         next_token = -1;
  82         index = start_index;
  83         selection = NULL;
  84
  85         if (argc > start_index)
  86         {
  87                 if (substring(argv(index), 0, 1) == "#")
  88                 {
  89                         tmp_string = substring(argv(index), 1, -1);
  90                         ++index;
  91
  92                         if (tmp_string != "")  // is it all one token? like #1
  93                         {
  94                                 tmp_number = stof(tmp_string);
  95                         }
  96                         else if (argc > index)  // no, it's two tokens? # 1
  97                         {
  98                                 tmp_number = stof(argv(index));
  99                                 ++index;
 100                         }
 101                         else
 102                         {
 103                                 tmp_number = 0;
 104                         }
 105                 }
 106                 else  // maybe it's ONLY a number?
 107                 {
 108                         tmp_number = stof(argv(index));
 109                         ++index;
 110                 }
 111
 112                 if (VerifyClientNumber(tmp_number))
 113                 {
 114                         selection = edict_num(tmp_number);  // yes, it was a number
 115                 }
 116                 else  // no, maybe it's a name?
 117                 {
 118                         FOREACH_CLIENT(true, LAMBDA(
 119                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 120                                 {
 121                                         selection = it;
 122                                         break; // no reason to keep looking
 123                                 }
 124                         ));
 125
 126                         index = (start_index + 1);
 127                 }
 128         }
 129
 130         next_token = index;
 131         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 132         return selection;
 133 }
 134
 135 // find a player which matches the input string, and return their entity
 136 entity GetFilteredEntity(string input)
 137 {
 138         entity selection;
 139         float tmp_number;
 140
 141         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 142         else tmp_number = stof(input);
 143
 144         if (VerifyClientNumber(tmp_number))
 145         {
 146                 selection = edict_num(tmp_number);
 147         }
 148         else
 149         {
 150                 selection = NULL;
 151                 FOREACH_CLIENT(true, LAMBDA(
 152                         if(strdecolorize(it.netname) == strdecolorize(input))
 153                         {
 154                                 selection = it;
 155                                 break; // no reason to keep looking
 156                         }
 157                 ));
 158         }
 159
 160         return selection;
 161 }
 162
 163 // same thing, but instead return their edict number
 164 float GetFilteredNumber(string input)
 165 {
 166         entity selection = GetFilteredEntity(input);
 167         float output;
 168
 169         output = etof(selection);
 170
 171         return output;
 172 }
 173
 174 // switch between sprint and print depending on whether the receiver is the server or a player
 175 void print_to(entity to, string input)
 176 {
 177         if (to) sprint(to, strcat(input, "\n"));
 178         else LOG_INFO(input, "\n");
 179 }
 180
 181 // ==========================================
 182 //  Supporting functions for common commands
 183 // ==========================================
 184
 185 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 186 void timeout_handler_reset(entity this)
 187 {
 188         timeout_caller = NULL;
 189         timeout_time = 0;
 190         timeout_leadtime = 0;
 191
 192         remove(this);
 193 }
 194
 195 void timeout_handler_think(entity this)
 196 {
 197         switch (timeout_status)
 198         {
 199                 case TIMEOUT_ACTIVE:
 200                 {
 201                         if (timeout_time > 0)  // countdown is still going
 202                         {
 203                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 204
 205                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 206                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_PREPARE);
 207
 208                                 this.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 209                                 timeout_time -= 1;                                  // decrease the time counter
 210                         }
 211                         else  // time to end the timeout
 212                         {
 213                                 timeout_status = TIMEOUT_INACTIVE;
 214
 215                                 // reset the slowmo value back to normal
 216                                 cvar_set("slowmo", ftos(orig_slowmo));
 217
 218                                 // unlock the view for players so they can move around again
 219                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 220                                         it.fixangle = false;
 221                                 ));
 222
 223                                 timeout_handler_reset(this);
 224                         }
 225
 226                         return;
 227                 }
 228
 229                 case TIMEOUT_LEADTIME:
 230                 {
 231                         if (timeout_leadtime > 0)  // countdown is still going
 232                         {
 233                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 234
 235                                 this.nextthink = time + 1; // think again in one second
 236                                 timeout_leadtime -= 1;     // decrease the time counter
 237                         }
 238                         else  // time to begin the timeout
 239                         {
 240                                 timeout_status = TIMEOUT_ACTIVE;
 241
 242                                 // set the slowmo value to the timeout default slowmo value
 243                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 244
 245                                 // reset all the flood variables
 246                                 FOREACH_CLIENT(true, LAMBDA(
 247                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 248                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 249                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 250                                 ));
 251
 252                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 253                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 254                                         it.lastV_angle = it.v_angle;
 255                                 ));
 256
 257                                 this.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 258                         }
 259
 260                         return;
 261                 }
 262
 263
 264                 case TIMEOUT_INACTIVE:
 265                 default:
 266                 {
 267                         timeout_handler_reset(this);
 268                         return;
 269                 }
 270         }
 271 }
 272
 273
 274 // ===================================================
 275 //  Common commands used in both sv_cmd.qc and cmd.qc
 276 // ===================================================
 277
 278 void CommonCommand_cvar_changes(float request, entity caller)
 279 {
 280         switch (request)
 281         {
 282                 case CMD_REQUEST_COMMAND:
 283                 {
 284                         print_to(caller, cvar_changes);
 285                         return;  // never fall through to usage
 286                 }
 287
 288                 default:
 289                 case CMD_REQUEST_USAGE:
 290                 {
 291                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 292                         print_to(caller, "  No arguments required.");
 293                         print_to(caller, "See also: ^2cvar_purechanges^7");
 294                         return;
 295                 }
 296         }
 297 }
 298
 299 void CommonCommand_cvar_purechanges(float request, entity caller)
 300 {
 301         switch (request)
 302         {
 303                 case CMD_REQUEST_COMMAND:
 304                 {
 305                         print_to(caller, cvar_purechanges);
 306                         return;  // never fall through to usage
 307                 }
 308
 309                 default:
 310                 case CMD_REQUEST_USAGE:
 311                 {
 312                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 313                         print_to(caller, "  No arguments required.");
 314                         print_to(caller, "See also: ^2cvar_changes^7");
 315                         return;
 316                 }
 317         }
 318 }
 319
 320 void CommonCommand_editmob(int request, entity caller, int argc)
 321 {
 322         switch (request)
 323         {
 324                 case CMD_REQUEST_COMMAND:
 325                 {
 326                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 327                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 328
 329                         if (caller)
 330                         {
 331                                 makevectors(caller.v_angle);
 332                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 333                         }
 334
 335                         entity mon = trace_ent;
 336                         bool is_visible = IS_MONSTER(mon);
 337                         string argument = argv(2);
 338
 339                         switch (argv(1))
 340                         {
 341                                 case "name":
 342                                 {
 343                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 344                                         if (!argument)   break;  // escape to usage
 345                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 346                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 347                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 348
 349                                         string mon_oldname = mon.monster_name;
 350
 351                                         mon.monster_name = argument;
 352                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 353                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 354                                         return;
 355                                 }
 356                                 case "spawn":
 357                                 {
 358                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 359                                         if (!argv(2))   break;  // escape to usage
 360
 361                                         int moveflag, tmp_moncount = 0;
 362                                         string arg_lower = strtolower(argument);
 363                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 364
 365                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 366
 367                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 368                                                 if(it.realowner == caller)
 369                                                         ++tmp_moncount;
 370                                         ));
 371
 372                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 373                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 374                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 375                                         if (MUTATOR_CALLHOOK(AllowMobSpawning, caller)) { print_to(caller, M_ARGV(1, string)); return; }
 376                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 377                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 378                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 379                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 380                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 381
 382                                         bool found = false;
 383                                         for (int i = MON_FIRST; i <= MON_LAST; ++i)
 384                                         {
 385                                                 mon = get_monsterinfo(i);
 386                                                 if (mon.netname == arg_lower) { found = true; break; }
 387                                         }
 388
 389                                         if (!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 390
 391                                         totalspawned += 1;
 392                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 393                                         mon = spawnmonster(arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 394                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 395                                         return;
 396                                 }
 397                                 case "kill":
 398                                 {
 399                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 400                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 401                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 402
 403                                         Damage(mon, NULL, NULL, mon.health + mon.max_health + 200, DEATH_KILL.m_id, mon.origin, '0 0 0');
 404                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 405                                         return;
 406                                 }
 407                                 case "skin":
 408                                 {
 409                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 410                                         if (!argument)   break;  // escape to usage
 411                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 412                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 413                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 414                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 415
 416                                         mon.skin = stof(argument);
 417                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 418                                         return;
 419                                 }
 420                                 case "movetarget":
 421                                 {
 422                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 423                                         if (!argument)   break;  // escape to usage
 424                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 425                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 426                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 427
 428                                         mon.monster_moveflags = stof(argument);
 429                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 430                                         return;
 431                                 }
 432                                 case "butcher":
 433                                 {
 434                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 435                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(M_ARGV(0, string), "\n"); return; }
 436
 437                                         int tmp_remcount = 0;
 438
 439                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 440                                                 Monster_Remove(it);
 441                                                 ++tmp_remcount;
 442                                         ));
 443
 444                                         monsters_total = monsters_killed = totalspawned = 0;
 445
 446                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 447                                         return;
 448                                 }
 449                         }
 450                 }
 451
 452                 default:
 453                 case CMD_REQUEST_USAGE:
 454                 {
 455                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 456                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 457                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 458                         print_to(caller, "  spawn also takes arguments list and random");
 459                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 460                         return;
 461                 }
 462         }
 463 }
 464
 465 void CommonCommand_info(float request, entity caller, float argc)
 466 {
 467         switch (request)
 468         {
 469                 case CMD_REQUEST_COMMAND:
 470                 {
 471                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 472
 473                         if (command) wordwrap_sprint(caller, command, 1000);
 474                         else print_to(caller, "ERROR: unsupported info command");
 475
 476                         return;  // never fall through to usage
 477                 }
 478
 479                 default:
 480                 case CMD_REQUEST_USAGE:
 481                 {
 482                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 483                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 484                         return;
 485                 }
 486         }
 487 }
 488
 489 void CommonCommand_ladder(float request, entity caller)
 490 {
 491         switch (request)
 492         {
 493                 case CMD_REQUEST_COMMAND:
 494                 {
 495                         print_to(caller, ladder_reply);
 496                         return;  // never fall through to usage
 497                 }
 498
 499                 default:
 500                 case CMD_REQUEST_USAGE:
 501                 {
 502                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 503                         print_to(caller, "  No arguments required.");
 504                         return;
 505                 }
 506         }
 507 }
 508
 509 void CommonCommand_lsmaps(float request, entity caller)
 510 {
 511         switch (request)
 512         {
 513                 case CMD_REQUEST_COMMAND:
 514                 {
 515                         print_to(caller, lsmaps_reply);
 516                         return;  // never fall through to usage
 517                 }
 518
 519                 default:
 520                 case CMD_REQUEST_USAGE:
 521                 {
 522                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 523                         print_to(caller, "  No arguments required.");
 524                         return;
 525                 }
 526         }
 527 }
 528
 529 void CommonCommand_printmaplist(float request, entity caller)
 530 {
 531         switch (request)
 532         {
 533                 case CMD_REQUEST_COMMAND:
 534                 {
 535                         print_to(caller, maplist_reply);
 536                         return;  // never fall through to usage
 537                 }
 538
 539                 default:
 540                 case CMD_REQUEST_USAGE:
 541                 {
 542                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 543                         print_to(caller, "  No arguments required.");
 544                         return;
 545                 }
 546         }
 547 }
 548
 549 void CommonCommand_rankings(float request, entity caller)
 550 {
 551         switch (request)
 552         {
 553                 case CMD_REQUEST_COMMAND:
 554                 {
 555                         print_to(caller, rankings_reply);
 556                         return;  // never fall through to usage
 557                 }
 558
 559                 default:
 560                 case CMD_REQUEST_USAGE:
 561                 {
 562                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 563                         print_to(caller, "  No arguments required.");
 564                         return;
 565                 }
 566         }
 567 }
 568
 569 void CommonCommand_records(float request, entity caller)
 570 {
 571         switch (request)
 572         {
 573                 case CMD_REQUEST_COMMAND:
 574                 {
 575                         for (int i = 0; i < 10; ++i)
 576                                 if (records_reply[i] != "") print_to(caller, records_reply[i]);
 577
 578                         return;  // never fall through to usage
 579                 }
 580
 581                 default:
 582                 case CMD_REQUEST_USAGE:
 583                 {
 584                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 585                         print_to(caller, "  No arguments required.");
 586                         return;
 587                 }
 588         }
 589 }
 590
 591 void CommonCommand_teamstatus(float request, entity caller)
 592 {
 593         switch (request)
 594         {
 595                 case CMD_REQUEST_COMMAND:
 596                 {
 597                         Score_NicePrint(caller);
 598                         return;  // never fall through to usage
 599                 }
 600
 601                 default:
 602                 case CMD_REQUEST_USAGE:
 603                 {
 604                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 605                         print_to(caller, "  No arguments required.");
 606                         return;
 607                 }
 608         }
 609 }
 610
 611 void CommonCommand_time(float request, entity caller)
 612 {
 613         switch (request)
 614         {
 615                 case CMD_REQUEST_COMMAND:
 616                 {
 617                         print_to(caller, strcat("time = ", ftos(time)));
 618                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 619                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 620                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 621                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 622                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 623                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 624                         return;
 625                 }
 626
 627                 default:
 628                 case CMD_REQUEST_USAGE:
 629                 {
 630                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 631                         print_to(caller, "  No arguments required.");
 632                         return;
 633                 }
 634         }
 635 }
 636
 637 void CommonCommand_timein(float request, entity caller)
 638 {
 639         switch (request)
 640         {
 641                 case CMD_REQUEST_COMMAND:
 642                 {
 643                         if (!caller || autocvar_sv_timeout)
 644                         {
 645                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 646                                 else if (caller && (caller != timeout_caller))
 647                                 {
 648                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 649                                 }
 650
 651                                 else  // everything should be okay, continue aborting timeout
 652                                 {
 653                                         switch (timeout_status)
 654                                         {
 655                                                 case TIMEOUT_LEADTIME:
 656                                                 {
 657                                                         timeout_status = TIMEOUT_INACTIVE;
 658                                                         timeout_time = 0;
 659                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 660                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 661                                                         return;
 662                                                 }
 663
 664                                                 case TIMEOUT_ACTIVE:
 665                                                 {
 666                                                         timeout_time = autocvar_sv_timeout_resumetime;
 667                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 668                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 669                                                         return;
 670                                                 }
 671
 672                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 673                                                         return;
 674                                         }
 675                                 }
 676                         }
 677                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 678
 679                         return;  // never fall through to usage
 680                 }
 681
 682                 default:
 683                 case CMD_REQUEST_USAGE:
 684                 {
 685                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 686                         print_to(caller, "  No arguments required.");
 687                         return;
 688                 }
 689         }
 690 }
 691
 692 void CommonCommand_timeout(float request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 693 {
 694         switch (request)
 695         {
 696                 case CMD_REQUEST_COMMAND:
 697                 {
 698                         if (!caller || autocvar_sv_timeout)
 699                         {
 700                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 701
 702                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 703                                 else if (vote_called)
 704                                 {
 705                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 706                                 }
 707                                 else if (warmup_stage && !g_warmup_allow_timeout)
 708                                 {
 709                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 710                                 }
 711                                 else if (time < game_starttime)
 712                                 {
 713                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 714                                 }
 715                                 else if (caller && (caller.allowed_timeouts < 1))
 716                                 {
 717                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 718                                 }
 719                                 else if (caller && !IS_PLAYER(caller))
 720                                 {
 721                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 722                                 }
 723                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 724                                 {
 725                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 726                                 }
 727
 728                                 else  // everything should be okay, proceed with starting the timeout
 729                                 {
 730                                         if (caller)   caller.allowed_timeouts -= 1;
 731                                         // write a bprint who started the timeout (and how many they have left)
 732                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 733
 734                                         timeout_status = TIMEOUT_LEADTIME;
 735                                         timeout_caller = caller;
 736                                         timeout_time = autocvar_sv_timeout_length;
 737                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 738
 739                                         timeout_handler = spawn();
 740                                         setthink(timeout_handler, timeout_handler_think);
 741                                         timeout_handler.nextthink = time;  // always let the entity think asap
 742
 743                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_TIMEOUT);
 744                                 }
 745                         }
 746                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 747
 748                         return;  // never fall through to usage
 749                 }
 750
 751                 default:
 752                 case CMD_REQUEST_USAGE:
 753                 {
 754                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 755                         print_to(caller, "  No arguments required.");
 756                         return;
 757                 }
 758         }
 759 }
 760
 761 void CommonCommand_who(float request, entity caller, float argc)
 762 {
 763         switch (request)
 764         {
 765                 case CMD_REQUEST_COMMAND:
 766                 {
 767                         float total_listed_players, is_bot;
 768
 769                         float privacy = (caller && autocvar_sv_status_privacy);
 770                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 771                         string tmp_netaddress, tmp_crypto_idfp;
 772
 773                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 774                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 775                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 776
 777                         total_listed_players = 0;
 778                         FOREACH_CLIENT(true, LAMBDA(
 779                                 is_bot = (IS_BOT_CLIENT(it));
 780
 781                                 if (is_bot)
 782                                 {
 783                                         tmp_netaddress = "null/botclient";
 784                                         tmp_crypto_idfp = "null/botclient";
 785                                 }
 786                                 else if (privacy)
 787                                 {
 788                                         tmp_netaddress = "hidden";
 789                                         tmp_crypto_idfp = "hidden";
 790                                 }
 791                                 else
 792                                 {
 793                                         tmp_netaddress = it.netaddress;
 794                                         tmp_crypto_idfp = it.crypto_idfp;
 795                                 }
 796
 797                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 798                                         etof(it),
 799                                         it.netname,
 800                                         it.ping,
 801                                         it.ping_packetloss,
 802                                         process_time(1, time - it.jointime),
 803                                         tmp_netaddress,
 804                                         tmp_crypto_idfp));
 805
 806                                 ++total_listed_players;
 807                         ));
 808
 809                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 810
 811                         return;  // never fall through to usage
 812                 }
 813
 814                 default:
 815                 case CMD_REQUEST_USAGE:
 816                 {
 817                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 818                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 819                         return;
 820                 }
 821         }
 822 }
 823
 824 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 825 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 826 void CommonCommand_(float request, entity caller)
 827 {
 828     switch(request)
 829     {
 830         case CMD_REQUEST_COMMAND:
 831         {
 832
 833             return; // never fall through to usage
 834         }
 835
 836         default:
 837         case CMD_REQUEST_USAGE:
 838         {
 839             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 840             print_to(caller, "  No arguments required.");
 841             return;
 842         }
 843     }
 844 }
 845 */