qcsrc/server/command/common.qc

   1 #include "common.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/monsters/_mod.qh>
   6 #include <common/notifications/all.qh>
   7 #include <common/stats.qh>
   8 #include <common/vehicles/all.qh>
   9 #include <common/weapons/_all.qh>
  10 #include <lib/warpzone/common.qh>
  11 #include <server/campaign.qh>
  12 #include <server/chat.qh>
  13 #include <server/client.qh>
  14 #include <server/command/common.qh>
  15 #include <server/mutators/_mod.qh>
  16 #include <server/scores.qh>
  17 #include <server/world.qh>
  18
  19
  20 // ====================================================
  21 //  Shared code for server commands, written by Samual
  22 //  Last updated: December 27th, 2011
  23 // ====================================================
  24
  25 // select the proper prefix for usage and other messages
  26 string GetCommandPrefix(entity caller)
  27 {
  28         if (caller) return "cmd";
  29         else return "sv_cmd";
  30 }
  31
  32 // if client return player nickname, or if server return admin nickname
  33 string GetCallerName(entity caller)
  34 {
  35         if (caller) return playername(caller.netname, caller.team, false);
  36         else return ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : "SERVER ADMIN"); // autocvar_hostname
  37 }
  38
  39 // verify that the client provided is acceptable for kicking
  40 float VerifyKickableEntity(entity client)
  41 {
  42         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  43         return CLIENT_ACCEPTABLE;
  44 }
  45
  46 // verify that the client provided is acceptable for use
  47 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  48 {
  49         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  50         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  51         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  52
  53         return CLIENT_ACCEPTABLE;
  54 }
  55
  56 // if the client is not acceptable, return a string to be used for error messages
  57 string GetClientErrorString_color(float clienterror, string original_input, string col)
  58 {
  59         switch (clienterror)
  60         {
  61                 case CLIENT_DOESNT_EXIST:
  62                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  63                 }
  64                 case CLIENT_NOT_REAL:
  65                 { return strcat(col, "Client '", original_input, col, "' is not real");
  66                 }
  67                 case CLIENT_NOT_BOT:
  68                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  69                 }
  70                 default:
  71                 { return "Incorrect usage of GetClientErrorString";
  72                 }
  73         }
  74 }
  75
  76 // is this entity number even in the possible range of entities?
  77 float VerifyClientNumber(float tmp_number)
  78 {
  79         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  80         else return true;
  81 }
  82
  83 entity GetIndexedEntity(int argc, float start_index)
  84 {
  85         entity selection;
  86         float tmp_number, index;
  87         string tmp_string;
  88
  89         next_token = -1;
  90         index = start_index;
  91         selection = NULL;
  92
  93         if (argc > start_index)
  94         {
  95                 if (substring(argv(index), 0, 1) == "#")
  96                 {
  97                         tmp_string = substring(argv(index), 1, -1);
  98                         ++index;
  99
 100                         if (tmp_string != "")  // is it all one token? like #1
 101                         {
 102                                 tmp_number = stof(tmp_string);
 103                         }
 104                         else if (argc > index)  // no, it's two tokens? # 1
 105                         {
 106                                 tmp_number = stof(argv(index));
 107                                 ++index;
 108                         }
 109                         else
 110                         {
 111                                 tmp_number = 0;
 112                         }
 113                 }
 114                 else  // maybe it's ONLY a number?
 115                 {
 116                         tmp_number = stof(argv(index));
 117                         ++index;
 118                 }
 119
 120                 if (VerifyClientNumber(tmp_number))
 121                 {
 122                         selection = edict_num(tmp_number);  // yes, it was a number
 123                 }
 124                 else  // no, maybe it's a name?
 125                 {
 126                         FOREACH_CLIENT(true, {
 127                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 128                                 {
 129                                         selection = it;
 130                                         break; // no reason to keep looking
 131                                 }
 132                         });
 133
 134                         index = (start_index + 1);
 135                 }
 136         }
 137
 138         next_token = index;
 139         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 140         return selection;
 141 }
 142
 143 // find a player which matches the input string, and return their entity
 144 entity GetFilteredEntity(string input)
 145 {
 146         entity selection;
 147         float tmp_number;
 148
 149         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 150         else tmp_number = stof(input);
 151
 152         if (VerifyClientNumber(tmp_number))
 153         {
 154                 selection = edict_num(tmp_number);
 155         }
 156         else
 157         {
 158                 selection = NULL;
 159                 FOREACH_CLIENT(true, {
 160                         if(strdecolorize(it.netname) == strdecolorize(input))
 161                         {
 162                                 selection = it;
 163                                 break; // no reason to keep looking
 164                         }
 165                 });
 166         }
 167
 168         return selection;
 169 }
 170
 171 // same thing, but instead return their edict number
 172 float GetFilteredNumber(string input)
 173 {
 174         entity selection = GetFilteredEntity(input);
 175         float output;
 176
 177         output = etof(selection);
 178
 179         return output;
 180 }
 181
 182 // switch between sprint and print depending on whether the receiver is the server or a player
 183 void print_to(entity to, string input)
 184 {
 185         if (to) sprint(to, strcat(input, "\n"));
 186         else print(input, "\n");
 187 }
 188
 189 // ==========================================
 190 //  Supporting functions for common commands
 191 // ==========================================
 192
 193 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 194 void timeout_handler_reset(entity this)
 195 {
 196         timeout_caller = NULL;
 197         timeout_time = 0;
 198         timeout_leadtime = 0;
 199
 200         delete(this);
 201 }
 202
 203 void timeout_handler_think(entity this)
 204 {
 205         switch (timeout_status)
 206         {
 207                 case TIMEOUT_ACTIVE:
 208                 {
 209                         if (timeout_time > 0)  // countdown is still going
 210                         {
 211                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 212
 213                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 214                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_PREPARE);
 215
 216                                 this.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 217                                 timeout_time -= 1;                                  // decrease the time counter
 218                         }
 219                         else  // time to end the timeout
 220                         {
 221                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_TIMEIN);
 222                                 timeout_status = TIMEOUT_INACTIVE;
 223
 224                                 // reset the slowmo value back to normal
 225                                 cvar_set("slowmo", ftos(orig_slowmo));
 226
 227                                 // unlock the view for players so they can move around again
 228                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 229                                         it.fixangle = false;
 230                                 });
 231
 232                                 timeout_handler_reset(this);
 233                         }
 234
 235                         return;
 236                 }
 237
 238                 case TIMEOUT_LEADTIME:
 239                 {
 240                         if (timeout_leadtime > 0)  // countdown is still going
 241                         {
 242                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 243
 244                                 this.nextthink = time + 1; // think again in one second
 245                                 timeout_leadtime -= 1;     // decrease the time counter
 246                         }
 247                         else  // time to begin the timeout
 248                         {
 249                                 timeout_status = TIMEOUT_ACTIVE;
 250
 251                                 // set the slowmo value to the timeout default slowmo value
 252                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 253
 254                                 // reset all the flood variables
 255                                 FOREACH_CLIENT(true, {
 256                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 257                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 258                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 259                                 });
 260
 261                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 262                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 263                                         it.lastV_angle = it.v_angle;
 264                                 });
 265
 266                                 this.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 267                         }
 268
 269                         return;
 270                 }
 271
 272
 273                 case TIMEOUT_INACTIVE:
 274                 default:
 275                 {
 276                         timeout_handler_reset(this);
 277                         return;
 278                 }
 279         }
 280 }
 281
 282
 283 // ===================================================
 284 //  Common commands used in both sv_cmd.qc and cmd.qc
 285 // ===================================================
 286
 287 void CommonCommand_cvar_changes(int request, entity caller)
 288 {
 289         switch (request)
 290         {
 291                 case CMD_REQUEST_COMMAND:
 292                 {
 293                         print_to(caller, cvar_changes);
 294                         return;  // never fall through to usage
 295                 }
 296
 297                 default:
 298                 case CMD_REQUEST_USAGE:
 299                 {
 300                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 301                         print_to(caller, "  No arguments required.");
 302                         print_to(caller, "See also: ^2cvar_purechanges^7");
 303                         return;
 304                 }
 305         }
 306 }
 307
 308 void CommonCommand_cvar_purechanges(int request, entity caller)
 309 {
 310         switch (request)
 311         {
 312                 case CMD_REQUEST_COMMAND:
 313                 {
 314                         print_to(caller, cvar_purechanges);
 315                         return;  // never fall through to usage
 316                 }
 317
 318                 default:
 319                 case CMD_REQUEST_USAGE:
 320                 {
 321                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 322                         print_to(caller, "  No arguments required.");
 323                         print_to(caller, "See also: ^2cvar_changes^7");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void CommonCommand_editmob(int request, entity caller, int argc)
 330 {
 331         switch (request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 336                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 337
 338                         if (caller)
 339                         {
 340                                 makevectors(caller.v_angle);
 341                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 342                         }
 343
 344                         entity mon = trace_ent;
 345                         bool is_visible = IS_MONSTER(mon);
 346                         string argument = argv(2);
 347
 348                         switch (argv(1))
 349                         {
 350                                 case "name":
 351                                 {
 352                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 353                                         if (!argument)   break;  // escape to usage
 354                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 355                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 356                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 357
 358                                         string mon_oldname = mon.monster_name;
 359
 360                                         mon.monster_name = argument;
 361                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 362                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 363                                         return;
 364                                 }
 365                                 case "spawn":
 366                                 {
 367                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 368                                         if (!argv(2))   break;  // escape to usage
 369
 370                                         int moveflag, tmp_moncount = 0;
 371                                         string arg_lower = strtolower(argument);
 372                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 373
 374                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 375
 376                                         IL_EACH(g_monsters, it.realowner == caller,
 377                                         {
 378                                                 ++tmp_moncount;
 379                                         });
 380
 381                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 382                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 383                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 384                                         if (MUTATOR_CALLHOOK(AllowMobSpawning, caller)) { print_to(caller, M_ARGV(1, string)); return; }
 385                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 386                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 387                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 388                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 389                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 390
 391                                         bool found = false;
 392                                         FOREACH(Monsters, it != MON_Null && it.netname == arg_lower,
 393                                         {
 394                                                 found = true;
 395                                                 break;
 396                                         });
 397
 398                                         if (!found && arg_lower != "random" && arg_lower != "anyrandom") { print_to(caller, "Invalid monster"); return; }
 399
 400                                         totalspawned += 1;
 401                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 402                                         mon = spawnmonster(spawn(), arg_lower, MON_Null, caller, caller, trace_endpos, false, false, moveflag);
 403                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 404                                         return;
 405                                 }
 406                                 case "kill":
 407                                 {
 408                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 409                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 410                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 411
 412                                         Damage(mon, NULL, NULL, GetResource(mon, RES_HEALTH) + mon.max_health + 200, DEATH_KILL.m_id, DMG_NOWEP, mon.origin, '0 0 0');
 413                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 414                                         return;
 415                                 }
 416                                 case "skin":
 417                                 {
 418                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 419                                         if (!argument)   break;  // escape to usage
 420                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 421                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 422                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 423                                         if (mon.monsterdef == MON_MAGE) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 424
 425                                         mon.skin = stof(argument);
 426                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 427                                         return;
 428                                 }
 429                                 case "movetarget":
 430                                 {
 431                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 432                                         if (!argument)   break;  // escape to usage
 433                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 434                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 435                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 436
 437                                         mon.monster_moveflags = stof(argument);
 438                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 439                                         return;
 440                                 }
 441                                 case "butcher":
 442                                 {
 443                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 444                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(M_ARGV(0, string)); return; }
 445
 446                                         int tmp_remcount = 0;
 447
 448                                         IL_EACH(g_monsters, true,
 449                                         {
 450                                                 Monster_Remove(it);
 451                                                 ++tmp_remcount;
 452                                         });
 453                                         IL_CLEAR(g_monsters);
 454
 455                                         monsters_total = monsters_killed = totalspawned = 0;
 456
 457                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 458                                         return;
 459                                 }
 460                         }
 461                 }
 462
 463                 default:
 464                 case CMD_REQUEST_USAGE:
 465                 {
 466                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 467                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 468                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 469                         print_to(caller, "  spawn also takes arguments list and random");
 470                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 471                         return;
 472                 }
 473         }
 474 }
 475
 476 void CommonCommand_info(int request, entity caller, int argc)
 477 {
 478         switch (request)
 479         {
 480                 case CMD_REQUEST_COMMAND:
 481                 {
 482                         string command = cvar_string(strcat("sv_info_", argv(1)));
 483
 484                         if (command) wordwrap_sprint(caller, command, 1000);
 485                         else print_to(caller, "ERROR: unsupported info command");
 486
 487                         return;  // never fall through to usage
 488                 }
 489
 490                 default:
 491                 case CMD_REQUEST_USAGE:
 492                 {
 493                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 494                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 495                         return;
 496                 }
 497         }
 498 }
 499
 500 void CommonCommand_ladder(int request, entity caller)
 501 {
 502         switch (request)
 503         {
 504                 case CMD_REQUEST_COMMAND:
 505                 {
 506                         print_to(caller, ladder_reply);
 507                         return;  // never fall through to usage
 508                 }
 509
 510                 default:
 511                 case CMD_REQUEST_USAGE:
 512                 {
 513                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 514                         print_to(caller, "  No arguments required.");
 515                         return;
 516                 }
 517         }
 518 }
 519
 520 void CommonCommand_lsmaps(int request, entity caller)
 521 {
 522         switch (request)
 523         {
 524                 case CMD_REQUEST_COMMAND:
 525                 {
 526                         print_to(caller, lsmaps_reply);
 527                         return;  // never fall through to usage
 528                 }
 529
 530                 default:
 531                 case CMD_REQUEST_USAGE:
 532                 {
 533                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 534                         print_to(caller, "  No arguments required.");
 535                         return;
 536                 }
 537         }
 538 }
 539
 540 void CommonCommand_printmaplist(int request, entity caller)
 541 {
 542         switch (request)
 543         {
 544                 case CMD_REQUEST_COMMAND:
 545                 {
 546                         print_to(caller, maplist_reply);
 547                         return;  // never fall through to usage
 548                 }
 549
 550                 default:
 551                 case CMD_REQUEST_USAGE:
 552                 {
 553                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 554                         print_to(caller, "  No arguments required.");
 555                         return;
 556                 }
 557         }
 558 }
 559
 560 void CommonCommand_rankings(int request, entity caller)
 561 {
 562         switch (request)
 563         {
 564                 case CMD_REQUEST_COMMAND:
 565                 {
 566                         print_to(caller, rankings_reply);
 567                         return;  // never fall through to usage
 568                 }
 569
 570                 default:
 571                 case CMD_REQUEST_USAGE:
 572                 {
 573                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 574                         print_to(caller, "  No arguments required.");
 575                         return;
 576                 }
 577         }
 578 }
 579
 580 void CommonCommand_records(int request, entity caller)
 581 {
 582         switch (request)
 583         {
 584                 case CMD_REQUEST_COMMAND:
 585                 {
 586                         int num = stoi(argv(1));
 587                         if(num > 0 && num <= 10 && records_reply[num - 1] != "")
 588                                 print_to(caller, records_reply[num - 1]);
 589                         else
 590                         {
 591                                 for (int i = 0; i < 10; ++i)
 592                                         if (records_reply[i] != "") print_to(caller, records_reply[i]);
 593                         }
 594
 595                         return;  // never fall through to usage
 596                 }
 597
 598                 default:
 599                 case CMD_REQUEST_USAGE:
 600                 {
 601                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 602                         print_to(caller, "  No arguments required.");
 603                         return;
 604                 }
 605         }
 606 }
 607
 608 void CommonCommand_teamstatus(int request, entity caller)
 609 {
 610         switch (request)
 611         {
 612                 case CMD_REQUEST_COMMAND:
 613                 {
 614                         Score_NicePrint(caller);
 615                         return;  // never fall through to usage
 616                 }
 617
 618                 default:
 619                 case CMD_REQUEST_USAGE:
 620                 {
 621                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 622                         print_to(caller, "  No arguments required.");
 623                         return;
 624                 }
 625         }
 626 }
 627
 628 void CommonCommand_time(int request, entity caller)
 629 {
 630         switch (request)
 631         {
 632                 case CMD_REQUEST_COMMAND:
 633                 {
 634                         print_to(caller, strcat("time = ", ftos(time)));
 635                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 636                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 637                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 638                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 639                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %d %H:%M:%S %Z %Y")));
 640                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %d %H:%M:%S %Z %Y")));
 641                         return;
 642                 }
 643
 644                 default:
 645                 case CMD_REQUEST_USAGE:
 646                 {
 647                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 648                         print_to(caller, "  No arguments required.");
 649                         return;
 650                 }
 651         }
 652 }
 653
 654 void CommonCommand_timein(int request, entity caller)
 655 {
 656         switch (request)
 657         {
 658                 case CMD_REQUEST_COMMAND:
 659                 {
 660                         if (!caller || autocvar_sv_timeout)
 661                         {
 662                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 663                                 else if (caller && (caller != timeout_caller))
 664                                 {
 665                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 666                                 }
 667
 668                                 else  // everything should be okay, continue aborting timeout
 669                                 {
 670                                         switch (timeout_status)
 671                                         {
 672                                                 case TIMEOUT_LEADTIME:
 673                                                 {
 674                                                         timeout_status = TIMEOUT_INACTIVE;
 675                                                         timeout_time = 0;
 676                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 677                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 678                                                         return;
 679                                                 }
 680
 681                                                 case TIMEOUT_ACTIVE:
 682                                                 {
 683                                                         timeout_time = autocvar_sv_timeout_resumetime;
 684                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 685                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 686                                                         return;
 687                                                 }
 688
 689                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 690                                                         return;
 691                                         }
 692                                 }
 693                         }
 694                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 695
 696                         return;  // never fall through to usage
 697                 }
 698
 699                 default:
 700                 case CMD_REQUEST_USAGE:
 701                 {
 702                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 703                         print_to(caller, "  No arguments required.");
 704                         return;
 705                 }
 706         }
 707 }
 708
 709 void CommonCommand_timeout(int request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 710 {
 711         switch (request)
 712         {
 713                 case CMD_REQUEST_COMMAND:
 714                 {
 715                         if (!caller || autocvar_sv_timeout)
 716                         {
 717                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 718
 719                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 720                                 else if (vote_called)
 721                                 {
 722                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 723                                 }
 724                                 else if (warmup_stage && !autocvar_g_warmup_allow_timeout)
 725                                 {
 726                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 727                                 }
 728                                 else if (time < game_starttime)
 729                                 {
 730                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 731                                 }
 732                                 else if (caller && (CS(caller).allowed_timeouts < 1))
 733                                 {
 734                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 735                                 }
 736                                 else if (caller && !IS_PLAYER(caller))
 737                                 {
 738                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 739                                 }
 740                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 741                                 {
 742                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 743                                 }
 744
 745                                 else  // everything should be okay, proceed with starting the timeout
 746                                 {
 747                                         if (caller)   CS(caller).allowed_timeouts -= 1;
 748                                         // write a bprint who started the timeout (and how many they have left)
 749                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(CS(caller).allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 750
 751                                         timeout_status = TIMEOUT_LEADTIME;
 752                                         timeout_caller = caller;
 753                                         timeout_time = autocvar_sv_timeout_length;
 754                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 755
 756                                         timeout_handler = new(timeout_handler);
 757                                         setthink(timeout_handler, timeout_handler_think);
 758                                         timeout_handler.nextthink = time;  // always let the entity think asap
 759
 760                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_TIMEOUT);
 761                                 }
 762                         }
 763                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 764
 765                         return;  // never fall through to usage
 766                 }
 767
 768                 default:
 769                 case CMD_REQUEST_USAGE:
 770                 {
 771                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 772                         print_to(caller, "  No arguments required.");
 773                         return;
 774                 }
 775         }
 776 }
 777
 778 void CommonCommand_who(int request, entity caller, int argc)
 779 {
 780         switch (request)
 781         {
 782                 case CMD_REQUEST_COMMAND:
 783                 {
 784                         float total_listed_players, is_bot;
 785
 786                         float privacy = (caller && autocvar_sv_status_privacy);
 787                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 788                         string tmp_netaddress, tmp_crypto_idfp;
 789
 790                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 791                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 792                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 793
 794                         total_listed_players = 0;
 795                         FOREACH_CLIENT(true, {
 796                                 is_bot = (IS_BOT_CLIENT(it));
 797
 798                                 if (is_bot)
 799                                 {
 800                                         tmp_netaddress = "null/botclient";
 801                                         tmp_crypto_idfp = "null/botclient";
 802                                 }
 803                                 else if (privacy)
 804                                 {
 805                                         tmp_netaddress = "hidden";
 806                                         tmp_crypto_idfp = "hidden";
 807                                 }
 808                                 else
 809                                 {
 810                                         tmp_netaddress = it.netaddress;
 811                                         tmp_crypto_idfp = it.crypto_idfp;
 812                                 }
 813
 814                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 815                                         etof(it),
 816                                         it.netname,
 817                                         CS(it).ping,
 818                                         CS(it).ping_packetloss,
 819                                         process_time(1, time - CS(it).jointime),
 820                                         tmp_netaddress,
 821                                         tmp_crypto_idfp));
 822
 823                                 ++total_listed_players;
 824                         });
 825
 826                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 827
 828                         return;  // never fall through to usage
 829                 }
 830
 831                 default:
 832                 case CMD_REQUEST_USAGE:
 833                 {
 834                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 835                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 836                         return;
 837                 }
 838         }
 839 }
 840
 841 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 842 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 843 void CommonCommand_(int request, entity caller)
 844 {
 845     switch(request)
 846     {
 847         case CMD_REQUEST_COMMAND:
 848         {
 849
 850             return; // never fall through to usage
 851         }
 852
 853         default:
 854         case CMD_REQUEST_USAGE:
 855         {
 856             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 857             print_to(caller, "  No arguments required.");
 858             return;
 859         }
 860     }
 861 }
 862 */