qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2 #include "_mod.qh"
   3
   4 #include "banning.qh"
   5 #include "cmd.qh"
   6 #include "common.qh"
   7 #include "getreplies.qh"
   8 #include "radarmap.qh"
   9
  10 #include "../anticheat.qh"
  11 #include "../campaign.qh"
  12 #include "../client.qh"
  13 #include "../player.qh"
  14 #include "../g_world.qh"
  15 #include "../ipban.qh"
  16 #include "../playerdemo.qh"
  17 #include "../teamplay.qh"
  18
  19 #include "../bot/api.qh"
  20
  21 #include "../mutators/_mod.qh"
  22
  23 #include <common/constants.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/mapinfo.qh>
  26 #include <common/notifications/all.qh>
  27 #include <common/teams.qh>
  28 #include <common/util.qh>
  29
  30 #include <common/monsters/sv_monsters.qh>
  31
  32
  33 void PutObserverInServer(entity this);
  34
  35 // =====================================================
  36 //  Server side game commands code, reworked by Samual
  37 // =====================================================
  38
  39 //  used by GameCommand_make_mapinfo()
  40 void make_mapinfo_Think(entity this)
  41 {
  42         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  43         {
  44                 LOG_INFO("Done rebuiling mapinfos.\n");
  45                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  46                 delete(this);
  47         }
  48         else
  49         {
  50                 setthink(this, make_mapinfo_Think);
  51                 this.nextthink = time;
  52         }
  53 }
  54
  55 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  56 void changematchtime(float delta, float mi, float ma)
  57 {
  58         float cur;
  59         float update;
  60         float lim;
  61
  62         if (delta == 0) return;
  63         if (autocvar_timelimit < 0) return;
  64
  65         if (mi <= 10) mi = 10;  // at least ten sec in the future
  66         cur = time - game_starttime;
  67         if (cur > 0) mi += cur; // from current time!
  68
  69         lim = autocvar_timelimit * 60;
  70
  71         if (delta > 0)
  72         {
  73                 if (lim == 0) return; // cannot increase any further
  74                 else if (lim < ma) update = min(ma, lim + delta);
  75                 else                  // already above maximum: FAIL
  76                         return;
  77         }
  78         else
  79         {
  80                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  81                         update = max(mi, ma);
  82                 else if (lim > mi) // above minimum: decrease
  83                         update = max(mi, lim + delta);
  84                 else               // already below minimum: FAIL
  85                         return;
  86         }
  87
  88         cvar_set("timelimit", ftos(update / 60));
  89 }
  90
  91
  92 // =======================
  93 //  Command Sub-Functions
  94 // =======================
  95
  96 void GameCommand_adminmsg(float request, float argc)
  97 {
  98         switch (request)
  99         {
 100                 case CMD_REQUEST_COMMAND:
 101                 {
 102                         entity client;
 103                         float accepted;
 104
 105                         string targets = strreplace(",", " ", argv(1));
 106                         string original_targets = strreplace(" ", ", ", targets);
 107                         string admin_message = argv(2);
 108                         float infobartime = stof(argv(3));
 109
 110                         string successful, t;
 111                         successful = string_null;
 112
 113                         if ((targets) && (admin_message))
 114                         {
 115                                 for ( ; targets; )
 116                                 {
 117                                         t = car(targets);
 118                                         targets = cdr(targets);
 119
 120                                         // Check to see if the player is a valid target
 121                                         client = GetFilteredEntity(t);
 122                                         accepted = VerifyClientEntity(client, true, false);
 123
 124                                         if (accepted <= 0)
 125                                         {
 126                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 127                                                 continue;
 128                                         }
 129
 130                                         // send the centerprint/console print or infomessage
 131                                         if (infobartime)
 132                                         {
 133                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 134                                         }
 135                                         else
 136                                         {
 137                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 138                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 139                                         }
 140
 141                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
 142                                         LOG_TRACE("Message sent to ", playername(client, false));
 143                                         continue;
 144                                 }
 145
 146                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 147                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.\n");
 148
 149                                 return;
 150                         }
 151                 }
 152
 153                 default:
 154                         LOG_INFO("Incorrect parameters for ^2adminmsg^7\n");
 155                 case CMD_REQUEST_USAGE:
 156                 {
 157                         LOG_INFO("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 158                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 159                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.\n");
 160                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.\n");
 161                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 162                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 163                         return;
 164                 }
 165         }
 166 }
 167
 168 void GameCommand_allready(float request)
 169 {
 170         switch (request)
 171         {
 172                 case CMD_REQUEST_COMMAND:
 173                 {
 174                         ReadyRestart();
 175                         return;
 176                 }
 177
 178                 default:
 179                 case CMD_REQUEST_USAGE:
 180                 {
 181                         LOG_INFO("\nUsage:^3 sv_cmd allready\n");
 182                         LOG_INFO("  No arguments required.\n");
 183                         return;
 184                 }
 185         }
 186 }
 187
 188 void GameCommand_allspec(float request, float argc)
 189 {
 190         switch (request)
 191         {
 192                 case CMD_REQUEST_COMMAND:
 193                 {
 194                         string reason = argv(1);
 195                         int n = 0;
 196                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 197                                 if (it.caplayer) it.caplayer = 0;
 198                                 PutObserverInServer(it);
 199                                 ++n;
 200                         ));
 201                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 202                         else   LOG_INFO("No players found to spectate.\n");
 203                         return;
 204                 }
 205
 206                 default:
 207                 case CMD_REQUEST_USAGE:
 208                 {
 209                         LOG_INFO("\nUsage:^3 sv_cmd allspec [reason]\n");
 210                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 211                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7\n");
 212                         return;
 213                 }
 214         }
 215 }
 216
 217 void GameCommand_anticheat(float request, float argc)
 218 {
 219         switch (request)
 220         {
 221                 case CMD_REQUEST_COMMAND:
 222                 {
 223                         entity client = GetIndexedEntity(argc, 1);
 224                         float accepted = VerifyClientEntity(client, false, false);
 225
 226                         if (accepted > 0)
 227                         {
 228                                 anticheat_report_to_eventlog(client);
 229                                 return;
 230                         }
 231                         else
 232                         {
 233                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 234                         }
 235                 }
 236
 237                 default:
 238                         LOG_INFO("Incorrect parameters for ^2anticheat^7\n");
 239                 case CMD_REQUEST_USAGE:
 240                 {
 241                         LOG_INFO("\nUsage:^3 sv_cmd anticheat client\n");
 242                         LOG_INFO("  'client' is the entity number or name of the player.\n");
 243                         return;
 244                 }
 245         }
 246 }
 247
 248 void GameCommand_bbox(float request)
 249 {
 250         switch (request)
 251         {
 252                 case CMD_REQUEST_COMMAND:
 253                 {
 254                         vector size_min = '0 0 0';
 255                         vector size_max = '0 0 0';
 256                         tracebox('1 0 0' * world.absmin.x,
 257                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 258                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 259                                 '1 0 0' * world.absmax.x,
 260                                 MOVE_WORLDONLY,
 261                                 NULL);
 262                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 263
 264                         tracebox('0 1 0' * world.absmin.y,
 265                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 266                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 267                                 '0 1 0' * world.absmax.y,
 268                                 MOVE_WORLDONLY,
 269                                 NULL);
 270                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 271
 272                         tracebox('0 0 1' * world.absmin.z,
 273                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 274                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 275                                 '0 0 1' * world.absmax.z,
 276                                 MOVE_WORLDONLY,
 277                                 NULL);
 278                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 279
 280                         tracebox('1 0 0' * world.absmax.x,
 281                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 282                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 283                                 '1 0 0' * world.absmin.x,
 284                                 MOVE_WORLDONLY,
 285                                 NULL);
 286                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 287
 288                         tracebox('0 1 0' * world.absmax.y,
 289                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 290                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 291                                 '0 1 0' * world.absmin.y,
 292                                 MOVE_WORLDONLY,
 293                                 NULL);
 294                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 295
 296                         tracebox('0 0 1' * world.absmax.z,
 297                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 298                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 299                                 '0 0 1' * world.absmin.z,
 300                                 MOVE_WORLDONLY,
 301                                 NULL);
 302                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 303
 304                         LOG_INFOF("Original size: %v %v\n", world.absmin, world.absmax);
 305                         LOG_INFOF("Currently set size: %v %v\n", world.mins, world.maxs);
 306                         LOG_INFOF("Solid bounding box size: %v %v\n", size_min, size_max);
 307                         return;
 308                 }
 309
 310                 default:
 311                 case CMD_REQUEST_USAGE:
 312                 {
 313                         LOG_INFO("\nUsage:^3 sv_cmd bbox\n");
 314                         LOG_INFO("  No arguments required.\n");
 315                         LOG_INFO("See also: ^2gettaginfo, trace^7\n");
 316                         return;
 317                 }
 318         }
 319 }
 320
 321 void GameCommand_bot_cmd(float request, float argc, string command)
 322 {
 323         switch (request)
 324         {
 325                 case CMD_REQUEST_COMMAND:
 326                 {
 327                         entity bot;
 328
 329                         if (argv(1) == "reset")
 330                         {
 331                                 bot_resetqueues();
 332                                 return;
 333                         }
 334                         else if (argv(1) == "setbots")
 335                         {
 336                                 cvar_settemp("bot_vs_human", "0");
 337                                 cvar_settemp("minplayers", "0");
 338                                 cvar_settemp("bot_number", "0");
 339                                 bot_fixcount();
 340                                 cvar_settemp("bot_number", argv(2));
 341                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count\n");
 342                                 return;
 343                         }
 344                         else if (argv(1) == "load" && argc == 3)
 345                         {
 346                                 float fh, i;
 347                                 string s;
 348                                 fh = fopen(argv(2), FILE_READ);
 349                                 if (fh < 0)
 350                                 {
 351                                         LOG_INFO("cannot open the file\n");
 352                                         return;
 353                                 }
 354
 355                                 i = 0;
 356                                 while ((s = fgets(fh)))
 357                                 {
 358                                         argc = tokenize_console(s);
 359
 360                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 361                                         {
 362                                                 if (argv(2) == "reset")
 363                                                 {
 364                                                         bot_resetqueues();
 365                                                 }
 366                                                 else if (argv(2) == "setbots")
 367                                                 {
 368                                                         cvar_settemp("bot_vs_human", "0");
 369                                                         cvar_settemp("minplayers", "0");
 370                                                         cvar_settemp("bot_number", "0");
 371                                                         bot_fixcount();
 372                                                         cvar_settemp("bot_number", argv(3));
 373                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count\n");
 374                                                 }
 375                                                 else
 376                                                 {
 377                                                         if(argv(2) == "*" || argv(2) == "all")
 378                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 379                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 380                                                                 });
 381                                                         else
 382                                                         {
 383                                                                 bot = find_bot_by_number(stof(argv(2)));
 384                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 385                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 386                                                         }
 387                                                 }
 388                                         }
 389                                         else
 390                                         {
 391                                                 localcmd(strcat(s, "\n"));
 392                                         }
 393
 394                                         ++i;
 395                                 }
 396                                 LOG_INFO(ftos(i), " commands read\n");
 397                                 fclose(fh);
 398                                 return;
 399                         }
 400                         else if (argv(1) == "help")
 401                         {
 402                                 if (argv(2)) bot_cmdhelp(argv(2));
 403                                 else bot_list_commands();
 404                                 return;
 405                         }
 406                         else if (argc >= 3)  // this comes last
 407                         {
 408                                 if(argv(1) == "*" || argv(1) == "all")
 409                                 {
 410                                         int bot_num = 0;
 411                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 412                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 413                                                 bot_num++;
 414                                         });
 415                                         if(bot_num)
 416                                                 LOG_INFO(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")\n"));
 417                                         return;
 418                                 }
 419                                 else
 420                                 {
 421                                         bot = find_bot_by_number(stof(argv(1)));
 422                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 423                                         if (bot)
 424                                         {
 425                                                 LOG_INFO(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 426                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 427                                                 return;
 428                                         }
 429                                         else
 430                                         {
 431                                                 LOG_INFO(strcat("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?\n"));  // don't return so that usage is shown
 432                                         }
 433                                 }
 434                         }
 435                 }
 436
 437                 default:
 438                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7\n");
 439                 case CMD_REQUEST_USAGE:
 440                 {
 441                         LOG_INFO("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 442                         LOG_INFO("  'client' can be either the name of the bot or a progressive number (not the entity number!)\n");
 443                         LOG_INFO("           can also be '*' or 'all' to allow sending the command to all the bots\n");
 444                         LOG_INFO("  For full list of commands, see bot_cmd help [command].\n");
 445                         LOG_INFO("Examples: sv_cmd bot_cmd 1 cc \"say something\"\n");
 446                         LOG_INFO("          sv_cmd bot_cmd 1 presskey jump\n");
 447                         LOG_INFO("          sv_cmd bot_cmd * pause\n");
 448                         return;
 449                 }
 450         }
 451 }
 452
 453 void GameCommand_cointoss(float request, float argc)
 454 {
 455         switch (request)
 456         {
 457                 case CMD_REQUEST_COMMAND:
 458                 {
 459                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 460                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 461                         string choice = ((random() > 0.5) ? result1 : result2);
 462
 463                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 464                         return;
 465                 }
 466
 467                 default:
 468                 case CMD_REQUEST_USAGE:
 469                 {
 470                         LOG_INFO("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 471                         LOG_INFO("  Where 'result1' and 'result2' are user created options.\n");
 472                         return;
 473                 }
 474         }
 475 }
 476
 477 void GameCommand_database(float request, float argc)
 478 {
 479         switch (request)
 480         {
 481                 case CMD_REQUEST_COMMAND:
 482                 {
 483                         if (argc == 3)
 484                         {
 485                                 if (argv(1) == "save")
 486                                 {
 487                                         db_save(ServerProgsDB, argv(2));
 488                                         LOG_INFO(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 489                                         return;
 490                                 }
 491                                 else if (argv(1) == "dump")
 492                                 {
 493                                         db_dump(ServerProgsDB, argv(2));
 494                                         LOG_INFO("DB dumped.\n");  // wtf does this do?
 495                                         return;
 496                                 }
 497                                 else if (argv(1) == "load")
 498                                 {
 499                                         db_close(ServerProgsDB);
 500                                         ServerProgsDB = db_load(argv(2));
 501                                         LOG_INFO(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 502                                         return;
 503                                 }
 504                         }
 505                 }
 506
 507                 default:
 508                         LOG_INFO("Incorrect parameters for ^2database^7\n");
 509                 case CMD_REQUEST_USAGE:
 510                 {
 511                         LOG_INFO("\nUsage:^3 sv_cmd database action filename\n");
 512                         LOG_INFO("  Where 'action' is the command to complete,\n");
 513                         LOG_INFO("  and 'filename' is what it acts upon.\n");
 514                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"\n");
 515                         return;
 516                 }
 517         }
 518 }
 519
 520 void GameCommand_defer_clear(float request, float argc)
 521 {
 522         switch (request)
 523         {
 524                 case CMD_REQUEST_COMMAND:
 525                 {
 526                         entity client;
 527                         float accepted;
 528
 529                         if (argc >= 2)
 530                         {
 531                                 client = GetIndexedEntity(argc, 1);
 532                                 accepted = VerifyClientEntity(client, true, false);
 533
 534                                 if (accepted > 0)
 535                                 {
 536                                         stuffcmd(client, "defer clear\n");
 537                                         LOG_INFO("defer clear stuffed to ", playername(client, false), "\n");
 538                                 }
 539                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 540
 541                                 return;
 542                         }
 543                 }
 544
 545                 default:
 546                         LOG_INFO("Incorrect parameters for ^2defer_clear^7\n");
 547                 case CMD_REQUEST_USAGE:
 548                 {
 549                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear client\n");
 550                         LOG_INFO("  'client' is the entity number or name of the player.\n");
 551                         LOG_INFO("See also: ^2defer_clear_all^7\n");
 552                         return;
 553                 }
 554         }
 555 }
 556
 557 void GameCommand_defer_clear_all(float request)
 558 {
 559         switch (request)
 560         {
 561                 case CMD_REQUEST_COMMAND:
 562                 {
 563                         int n = 0;
 564                         float argc;
 565
 566                         FOREACH_CLIENT(true, LAMBDA(
 567                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 568                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 569                                 ++n;
 570                         ));
 571                         if (n)   LOG_INFO(strcat("Successfully stuffed defer clear to all clients (", ftos(n), ")\n"));  // should a message be added if no players were found?
 572                         return;
 573                 }
 574
 575                 default:
 576                 case CMD_REQUEST_USAGE:
 577                 {
 578                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear_all\n");
 579                         LOG_INFO("  No arguments required.\n");
 580                         LOG_INFO("See also: ^2defer_clear^7\n");
 581                         return;
 582                 }
 583         }
 584 }
 585
 586 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 587 {
 588         switch (request)
 589         {
 590                 case CMD_REQUEST_COMMAND:
 591                 {
 592                         if (argv(1))
 593                         {
 594                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 595                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 596                                 return;
 597                         }
 598                 }
 599
 600                 default:
 601                         LOG_INFO("Incorrect parameters for ^2delrec^7\n");
 602                 case CMD_REQUEST_USAGE:
 603                 {
 604                         LOG_INFO("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 605                         LOG_INFO("  'ranking' is which ranking level to clear up to, \n");
 606                         LOG_INFO("  it will clear all records up to nth place.\n");
 607                         LOG_INFO("  if 'map' is not provided it will use current map.\n");
 608                         return;
 609                 }
 610         }
 611 }
 612
 613 void GameCommand_effectindexdump(float request)
 614 {
 615         switch (request)
 616         {
 617                 case CMD_REQUEST_COMMAND:
 618                 {
 619                         float fh, d;
 620                         string s;
 621
 622                         d = db_create();
 623                         LOG_INFO("begin of effects list\n");
 624                         db_put(d, "TE_GUNSHOT", "1");
 625                         LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")), "\n");
 626                         db_put(d, "TE_GUNSHOTQUAD", "1");
 627                         LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 628                         db_put(d, "TE_SPIKE", "1");
 629                         LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")), "\n");
 630                         db_put(d, "TE_SPIKEQUAD", "1");
 631                         LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")), "\n");
 632                         db_put(d, "TE_SUPERSPIKE", "1");
 633                         LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")), "\n");
 634                         db_put(d, "TE_SUPERSPIKEQUAD", "1");
 635                         LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 636                         db_put(d, "TE_WIZSPIKE", "1");
 637                         LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")), "\n");
 638                         db_put(d, "TE_KNIGHTSPIKE", "1");
 639                         LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 640                         db_put(d, "TE_EXPLOSION", "1");
 641                         LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")), "\n");
 642                         db_put(d, "TE_EXPLOSIONQUAD", "1");
 643                         LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 644                         db_put(d, "TE_TAREXPLOSION", "1");
 645                         LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")), "\n");
 646                         db_put(d, "TE_TELEPORT", "1");
 647                         LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")), "\n");
 648                         db_put(d, "TE_LAVASPLASH", "1");
 649                         LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")), "\n");
 650                         db_put(d, "TE_SMALLFLASH", "1");
 651                         LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")), "\n");
 652                         db_put(d, "TE_FLAMEJET", "1");
 653                         LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")), "\n");
 654                         db_put(d, "EF_FLAME", "1");
 655                         LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")), "\n");
 656                         db_put(d, "TE_BLOOD", "1");
 657                         LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")), "\n");
 658                         db_put(d, "TE_SPARK", "1");
 659                         LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")), "\n");
 660                         db_put(d, "TE_PLASMABURN", "1");
 661                         LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")), "\n");
 662                         db_put(d, "TE_TEI_G3", "1");
 663                         LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")), "\n");
 664                         db_put(d, "TE_TEI_SMOKE", "1");
 665                         LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")), "\n");
 666                         db_put(d, "TE_TEI_BIGEXPLOSION", "1");
 667                         LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 668                         db_put(d, "TE_TEI_PLASMAHIT", "1");
 669                         LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 670                         db_put(d, "EF_STARDUST", "1");
 671                         LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")), "\n");
 672                         db_put(d, "TR_ROCKET", "1");
 673                         LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")), "\n");
 674                         db_put(d, "TR_GRENADE", "1");
 675                         LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")), "\n");
 676                         db_put(d, "TR_BLOOD", "1");
 677                         LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")), "\n");
 678                         db_put(d, "TR_WIZSPIKE", "1");
 679                         LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")), "\n");
 680                         db_put(d, "TR_SLIGHTBLOOD", "1");
 681                         LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 682                         db_put(d, "TR_KNIGHTSPIKE", "1");
 683                         LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 684                         db_put(d, "TR_VORESPIKE", "1");
 685                         LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")), "\n");
 686                         db_put(d, "TR_NEHAHRASMOKE", "1");
 687                         LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 688                         db_put(d, "TR_NEXUIZPLASMA", "1");
 689                         LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 690                         db_put(d, "TR_GLOWTRAIL", "1");
 691                         LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")), "\n");
 692                         db_put(d, "TR_SEEKER", "1");
 693                         LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")), "\n");
 694                         db_put(d, "SVC_PARTICLE", "1");
 695                         LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")), "\n");
 696
 697                         fh = fopen("effectinfo.txt", FILE_READ);
 698                         while ((s = fgets(fh)))
 699                         {
 700                                 tokenize_console(s);
 701                                 if (argv(0) == "effect")
 702                                 {
 703                                         if (db_get(d, argv(1)) != "1")
 704                                         {
 705                                                 int i = _particleeffectnum(argv(1));
 706                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i), "\n");
 707                                                 db_put(d, argv(1), "1");
 708                                         }
 709                                 }
 710                         }
 711                         LOG_INFO("end of effects list\n");
 712
 713                         db_close(d);
 714                         return;
 715                 }
 716
 717                 default:
 718                 case CMD_REQUEST_USAGE:
 719                 {
 720                         LOG_INFO("\nUsage:^3 sv_cmd effectindexdump\n");
 721                         LOG_INFO("  No arguments required.\n");
 722                         return;
 723                 }
 724         }
 725 }
 726
 727 void GameCommand_extendmatchtime(float request)
 728 {
 729         switch (request)
 730         {
 731                 case CMD_REQUEST_COMMAND:
 732                 {
 733                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 734                         return;
 735                 }
 736
 737                 default:
 738                 case CMD_REQUEST_USAGE:
 739                 {
 740                         LOG_INFO("\nUsage:^3 sv_cmd extendmatchtime\n");
 741                         LOG_INFO("  No arguments required.\n");
 742                         LOG_INFO("See also: ^2reducematchtime^7\n");
 743                         return;
 744                 }
 745         }
 746 }
 747
 748 void GameCommand_gametype(float request, float argc)
 749 {
 750         switch (request)
 751         {
 752                 case CMD_REQUEST_COMMAND:
 753                 {
 754                         if (argv(1) != "")
 755                         {
 756                                 string s = argv(1);
 757                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 758
 759                                 if (t)
 760                                 {
 761                                         MapInfo_SwitchGameType(t);
 762                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 763                                         if (MapInfo_count > 0)
 764                                         {
 765                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 766                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 767                                                 lsmaps_reply = strzone(getlsmaps());
 768                                                 bprint("Game type successfully switched to ", s, "\n");
 769                                         }
 770                                         else
 771                                         {
 772                                                 bprint("Cannot use this game type: no map for it found\n");
 773                                                 MapInfo_SwitchGameType(tsave);
 774                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 775                                         }
 776                                 }
 777                                 else
 778                                 {
 779                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 780                                 }
 781
 782                                 return;
 783                         }
 784                 }
 785
 786                 default:
 787                         LOG_INFO("Incorrect parameters for ^2gametype^7\n");
 788                 case CMD_REQUEST_USAGE:
 789                 {
 790                         LOG_INFO("\nUsage:^3 sv_cmd gametype mode\n");
 791                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.\n");
 792                         LOG_INFO("See also: ^2gotomap^7\n");
 793                         return;
 794                 }
 795         }
 796 }
 797
 798 void GameCommand_gettaginfo(float request, float argc)
 799 {
 800         switch (request)
 801         {
 802                 case CMD_REQUEST_COMMAND:
 803                 {
 804                         entity tmp_entity;
 805                         float i;
 806                         vector v;
 807
 808                         if (argc >= 4)
 809                         {
 810                                 tmp_entity = spawn();
 811                                 if (argv(1) == "w")
 812                                 {
 813                                         .entity weaponentity = weaponentities[0];
 814                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 815                                 }
 816                                 else
 817                                 {
 818                                         precache_model(argv(1));
 819                                         _setmodel(tmp_entity, argv(1));
 820                                 }
 821                                 tmp_entity.frame = stof(argv(2));
 822                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 823                                 else i = gettagindex(tmp_entity, argv(3));
 824                                 if (i)
 825                                 {
 826                                         v = gettaginfo(tmp_entity, i);
 827                                         LOG_INFO("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 828                                         LOG_INFO(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 829                                         LOG_INFO(" vector = ", ftos(v.x), " ", ftos(v.y), " ", ftos(v.z), "\n");
 830                                         LOG_INFO(" offset = ", ftos(gettaginfo_offset.x), " ", ftos(gettaginfo_offset.y), " ", ftos(gettaginfo_offset.z), "\n");
 831                                         LOG_INFO(" forward = ", ftos(gettaginfo_forward.x), " ", ftos(gettaginfo_forward.y), " ", ftos(gettaginfo_forward.z), "\n");
 832                                         LOG_INFO(" right = ", ftos(gettaginfo_right.x), " ", ftos(gettaginfo_right.y), " ", ftos(gettaginfo_right.z), "\n");
 833                                         LOG_INFO(" up = ", ftos(gettaginfo_up.x), " ", ftos(gettaginfo_up.y), " ", ftos(gettaginfo_up.z), "\n");
 834                                         if (argc >= 6)
 835                                         {
 836                                                 v.y = -v.y;
 837                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 838                                         }
 839                                 }
 840                                 else
 841                                 {
 842                                         LOG_INFO("bone not found\n");
 843                                 }
 844
 845                                 delete(tmp_entity);
 846                                 return;
 847                         }
 848                 }
 849
 850                 default:
 851                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
 852                 case CMD_REQUEST_USAGE:
 853                 {
 854                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 855                         LOG_INFO("See also: ^2bbox, trace^7\n");
 856                         return;
 857                 }
 858         }
 859 }
 860
 861 void GameCommand_animbench(float request, float argc)
 862 {
 863         switch (request)
 864         {
 865                 case CMD_REQUEST_COMMAND:
 866                 {
 867                         entity tmp_entity;
 868
 869                         if (argc >= 4)
 870                         {
 871                                 tmp_entity = spawn();
 872                                 if (argv(1) == "w")
 873                                 {
 874                                         .entity weaponentity = weaponentities[0];
 875                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 876                                 }
 877                                 else
 878                                 {
 879                                         precache_model(argv(1));
 880                                         _setmodel(tmp_entity, argv(1));
 881                                 }
 882                                 float f1 = stof(argv(2));
 883                                 float f2 = stof(argv(3));
 884                                 float t0;
 885                                 float t1 = 0;
 886                                 float t2 = 0;
 887                                 float n = 0;
 888
 889                                 while (t1 + t2 < 1)
 890                                 {
 891                                         tmp_entity.frame = f1;
 892                                         t0 = gettime(GETTIME_HIRES);
 893                                         getsurfacepoint(tmp_entity, 0, 0);
 894                                         t1 += gettime(GETTIME_HIRES) - t0;
 895                                         tmp_entity.frame = f2;
 896                                         t0 = gettime(GETTIME_HIRES);
 897                                         getsurfacepoint(tmp_entity, 0, 0);
 898                                         t2 += gettime(GETTIME_HIRES) - t0;
 899                                         n += 1;
 900                                 }
 901                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 902                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 903
 904                                 delete(tmp_entity);
 905                                 return;
 906                         }
 907                 }
 908
 909                 default:
 910                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
 911                 case CMD_REQUEST_USAGE:
 912                 {
 913                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 914                         LOG_INFO("See also: ^2bbox, trace^7\n");
 915                         return;
 916                 }
 917         }
 918 }
 919
 920 void GameCommand_gotomap(float request, float argc)
 921 {
 922         switch (request)
 923         {
 924                 case CMD_REQUEST_COMMAND:
 925                 {
 926                         if (argv(1))
 927                         {
 928                                 LOG_INFO(GotoMap(argv(1)), "\n");
 929                                 return;
 930                         }
 931                 }
 932
 933                 default:
 934                         LOG_INFO("Incorrect parameters for ^2gotomap^7\n");
 935                 case CMD_REQUEST_USAGE:
 936                 {
 937                         LOG_INFO("\nUsage:^3 sv_cmd gotomap map\n");
 938                         LOG_INFO("  Where 'map' is the *.bsp file to change to.\n");
 939                         LOG_INFO("See also: ^2gametype^7\n");
 940                         return;
 941                 }
 942         }
 943 }
 944
 945 void GameCommand_lockteams(float request)
 946 {
 947         switch (request)
 948         {
 949                 case CMD_REQUEST_COMMAND:
 950                 {
 951                         if (teamplay)
 952                         {
 953                                 lockteams = 1;
 954                                 bprint("^1The teams are now locked.\n");
 955                         }
 956                         else
 957                         {
 958                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 959                         }
 960                         return;
 961                 }
 962
 963                 default:
 964                 case CMD_REQUEST_USAGE:
 965                 {
 966                         LOG_INFO("\nUsage:^3 sv_cmd lockteams\n");
 967                         LOG_INFO("  No arguments required.\n");
 968                         LOG_INFO("See also: ^2unlockteams^7\n");
 969                         return;
 970                 }
 971         }
 972 }
 973
 974 void GameCommand_make_mapinfo(float request)
 975 {
 976         switch (request)
 977         {
 978                 case CMD_REQUEST_COMMAND:
 979                 {
 980                         entity tmp_entity;
 981
 982                         tmp_entity = new(make_mapinfo);
 983                         setthink(tmp_entity, make_mapinfo_Think);
 984                         tmp_entity.nextthink = time;
 985                         MapInfo_Enumerate();
 986                         return;
 987                 }
 988
 989                 default:
 990                 case CMD_REQUEST_USAGE:
 991                 {
 992                         LOG_INFO("\nUsage:^3 sv_cmd make_mapinfo\n");
 993                         LOG_INFO("  No arguments required.\n");
 994                         LOG_INFO("See also: ^2radarmap^7\n");
 995                         return;
 996                 }
 997         }
 998 }
 999
1000 void GameCommand_moveplayer(float request, float argc)
1001 {
1002         switch (request)
1003         {
1004                 case CMD_REQUEST_COMMAND:
1005                 {
1006                         float accepted;
1007                         entity client;
1008
1009                         string targets = strreplace(",", " ", argv(1));
1010                         string original_targets = strreplace(" ", ", ", targets);
1011                         string destination = argv(2);
1012
1013                         string successful, t;
1014                         successful = string_null;
1015
1016                         // lets see if the target(s) even actually exist.
1017                         if ((targets) && (destination))
1018                         {
1019                                 for ( ; targets; )
1020                                 {
1021                                         t = car(targets);
1022                                         targets = cdr(targets);
1023
1024                                         // Check to see if the player is a valid target
1025                                         client = GetFilteredEntity(t);
1026                                         accepted = VerifyClientEntity(client, false, false);
1027
1028                                         if (accepted <= 0)
1029                                         {
1030                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1031                                                 continue;
1032                                         }
1033
1034                                         // Where are we putting this player?
1035                                         if (destination == "spec" || destination == "spectator")
1036                                         {
1037                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1038                                                 {
1039                                                         if (client.caplayer) client.caplayer = 0;
1040                                                         PutObserverInServer(client);
1041
1042                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1043                                                 }
1044                                                 else
1045                                                 {
1046                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already spectating.\n");
1047                                                 }
1048                                                 continue;
1049                                         }
1050                                         else
1051                                         {
1052                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1053                                                 {
1054                                                         if (teamplay)
1055                                                         {
1056                                                                 // set up
1057                                                                 float team_id;
1058                                                                 float save = client.team_forced;
1059                                                                 client.team_forced = 0;
1060
1061                                                                 // find the team to move the player to
1062                                                                 team_id = Team_ColorToTeam(destination);
1063                                                                 if (team_id == client.team)  // already on the destination team
1064                                                                 {
1065                                                                         // keep the forcing undone
1066                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1067                                                                         continue;
1068                                                                 }
1069                                                                 else if (team_id == 0)  // auto team
1070                                                                 {
1071                                                                         CheckAllowedTeams(client);
1072                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1073                                                                 }
1074                                                                 else
1075                                                                 {
1076                                                                         CheckAllowedTeams(client);
1077                                                                 }
1078                                                                 client.team_forced = save;
1079
1080                                                                 // Check to see if the destination team is even available
1081                                                                 switch (team_id)
1082                                                                 {
1083                                                                         case NUM_TEAM_1: if (c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1084                                                                         case NUM_TEAM_2: if (c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1085                                                                         case NUM_TEAM_3: if (c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1086                                                                         case NUM_TEAM_4: if (c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1087
1088                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.\n");
1089                                                                                 return;
1090                                                                 }
1091
1092                                                                 // If so, lets continue and finally move the player
1093                                                                 client.team_forced = 0;
1094                                                                 MoveToTeam(client, team_id, 6);
1095                                                                 successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1096                                                                 LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1097                                                                 continue;
1098                                                         }
1099                                                         else
1100                                                         {
1101                                                                 LOG_INFO("Can't change teams when currently not playing a team game.\n");
1102                                                                 return;
1103                                                         }
1104                                                 }
1105                                                 else
1106                                                 {
1107                                                         LOG_INFO("Can't change teams if the player isn't in the game.\n");  // well technically we could, but should we allow that? :P
1108                                                         return;
1109                                                 }
1110                                         }
1111                                 }
1112
1113                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1114                                 else LOG_INFO("No players given (", original_targets, ") are able to move.\n");
1115
1116                                 return;  // still correct parameters so return to avoid usage print
1117                         }
1118                 }
1119
1120                 default:
1121                         LOG_INFO("Incorrect parameters for ^2moveplayer^7\n");
1122                 case CMD_REQUEST_USAGE:
1123                 {
1124                         LOG_INFO("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1125                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1126                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating\n");
1127                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1128                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1129                         LOG_INFO("          sv_cmd moveplayer 2 spec \n");
1130                         LOG_INFO("See also: ^2allspec, shuffleteams^7\n");
1131                         return;
1132                 }
1133         }
1134 }
1135
1136 void GameCommand_nospectators(float request)
1137 {
1138         switch (request)
1139         {
1140                 case CMD_REQUEST_COMMAND:
1141                 {
1142                         blockSpectators = 1;
1143                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1144                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, LAMBDA(
1145                                 if(!it.caplayer)
1146                                 {
1147                                         CS(it).spectatortime = time;
1148                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1149                                 }
1150                         ));
1151                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1152                         return;
1153                 }
1154
1155                 default:
1156                 case CMD_REQUEST_USAGE:
1157                 {
1158                         LOG_INFO("\nUsage:^3 sv_cmd nospectators\n");
1159                         LOG_INFO("  No arguments required.\n");
1160                         return;
1161                 }
1162         }
1163 }
1164
1165 void GameCommand_playerdemo(float request, float argc)
1166 {
1167         switch (request)
1168         {
1169                 case CMD_REQUEST_COMMAND:
1170                 {
1171                         if (argv(2) && argv(3))
1172                         {
1173                                 entity client;
1174                                 float i, n, accepted;
1175
1176                                 switch (argv(1))
1177                                 {
1178                                         case "read":
1179                                         {
1180                                                 client = GetIndexedEntity(argc, 2);
1181                                                 accepted = VerifyClientEntity(client, false, true);
1182
1183                                                 if (accepted <= 0)
1184                                                 {
1185                                                         LOG_INFO("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1186                                                         return;
1187                                                 }
1188
1189                                                 playerdemo_open_read(client, argv(next_token));
1190                                                 return;
1191                                         }
1192
1193                                         case "write":
1194                                         {
1195                                                 client = GetIndexedEntity(argc, 2);
1196                                                 accepted = VerifyClientEntity(client, false, false);
1197
1198                                                 if (accepted <= 0)
1199                                                 {
1200                                                         LOG_INFO("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1201                                                         return;
1202                                                 }
1203
1204                                                 playerdemo_open_write(client, argv(next_token));
1205                                                 return;
1206                                         }
1207
1208                                         case "auto_read_and_write":
1209                                         {
1210                                                 n = GetFilteredNumber(argv(3));
1211                                                 cvar_set("bot_number", ftos(n));
1212
1213                                                 localcmd("wait; wait; wait\n");
1214                                                 for (i = 0; i < n; ++i)
1215                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1216                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n + 1), "\n");
1217                                                 return;
1218                                         }
1219
1220                                         case "auto_read":
1221                                         {
1222                                                 n = GetFilteredNumber(argv(3));
1223                                                 cvar_set("bot_number", ftos(n));
1224
1225                                                 localcmd("wait; wait; wait\n");
1226                                                 for (i = 0; i < n; ++i)
1227                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1228                                                 return;
1229                                         }
1230                                 }
1231                         }
1232                 }
1233
1234                 default:
1235                         LOG_INFO("Incorrect parameters for ^2playerdemo^7\n");
1236                 case CMD_REQUEST_USAGE:
1237                 {
1238                         LOG_INFO("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1239                         LOG_INFO("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1240                         return;
1241                 }
1242         }
1243 }
1244
1245 void GameCommand_printstats(float request)
1246 {
1247         switch (request)
1248         {
1249                 case CMD_REQUEST_COMMAND:
1250                 {
1251                         DumpStats(false);
1252                         LOG_INFO("stats dumped.\n");
1253                         return;
1254                 }
1255
1256                 default:
1257                 case CMD_REQUEST_USAGE:
1258                 {
1259                         LOG_INFO("\nUsage:^3 sv_cmd printstats\n");
1260                         LOG_INFO("  No arguments required.\n");
1261                         return;
1262                 }
1263         }
1264 }
1265
1266 void GameCommand_radarmap(float request, float argc)
1267 {
1268         switch (request)
1269         {
1270                 case CMD_REQUEST_COMMAND:
1271                 {
1272                         if (RadarMap_Make(argc)) return;
1273                 }
1274
1275                 default:
1276                         LOG_INFO("Incorrect parameters for ^2radarmap^7\n");
1277                 case CMD_REQUEST_USAGE:
1278                 {
1279                         LOG_INFO("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1280                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.\n");
1281                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1282                         LOG_INFO("See also: ^2make_mapinfo^7\n");
1283                         return;
1284                 }
1285         }
1286 }
1287
1288 void GameCommand_reducematchtime(float request)
1289 {
1290         switch (request)
1291         {
1292                 case CMD_REQUEST_COMMAND:
1293                 {
1294                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1295                         return;
1296                 }
1297
1298                 default:
1299                 case CMD_REQUEST_USAGE:
1300                 {
1301                         LOG_INFO("\nUsage:^3 sv_cmd reducematchtime\n");
1302                         LOG_INFO("  No arguments required.\n");
1303                         LOG_INFO("See also: ^2extendmatchtime^7\n");
1304                         return;
1305                 }
1306         }
1307 }
1308
1309 void GameCommand_setbots(float request, float argc)
1310 {
1311         switch (request)
1312         {
1313                 case CMD_REQUEST_COMMAND:
1314                 {
1315                         if (argc >= 2)
1316                         {
1317                                 cvar_settemp("minplayers", "0");
1318                                 cvar_settemp("bot_number", argv(1));
1319                                 bot_fixcount();
1320                                 return;
1321                         }
1322                 }
1323
1324                 default:
1325                         LOG_INFO("Incorrect parameters for ^2setbots^7\n");
1326                 case CMD_REQUEST_USAGE:
1327                 {
1328                         LOG_INFO("\nUsage:^3 sv_cmd setbots botnumber\n");
1329                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1330                         LOG_INFO("See also: ^2bot_cmd^7\n");
1331                         return;
1332                 }
1333         }
1334 }
1335
1336 void GameCommand_shuffleteams(float request)
1337 {
1338         switch (request)
1339         {
1340                 case CMD_REQUEST_COMMAND:
1341                 {
1342                         if (!teamplay)
1343                         {
1344                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.\n");
1345                                 return;
1346                         }
1347
1348                         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, LAMBDA(
1349                                 if (it.team_forced) {
1350                                         // we could theoretically assign forced players to their teams
1351                                         // and shuffle the rest to fill the empty spots but in practise
1352                                         // either all players or none are gonna have forced teams
1353                                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.\n");
1354                                         return;
1355                                 }
1356                         ));
1357
1358                         int number_of_teams = 0;
1359                         CheckAllowedTeams(NULL);
1360                         if (c1 >= 0) number_of_teams = max(1, number_of_teams);
1361                         if (c2 >= 0) number_of_teams = max(2, number_of_teams);
1362                         if (c3 >= 0) number_of_teams = max(3, number_of_teams);
1363                         if (c4 >= 0) number_of_teams = max(4, number_of_teams);
1364
1365                         int team_index = 0;
1366                         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, LAMBDA(
1367                                 int target_team_number = Team_NumberToTeam(team_index + 1);
1368                                 if (it.team != target_team_number) MoveToTeam(it, target_team_number, 6);
1369                                 team_index = (team_index + 1) % number_of_teams;
1370                         ));
1371
1372                         bprint("Successfully shuffled the players around randomly.\n");
1373                         return;
1374                 }
1375
1376                 default:
1377                 case CMD_REQUEST_USAGE:
1378                 {
1379                         LOG_INFO("\nUsage:^3 sv_cmd shuffleteams\n");
1380                         LOG_INFO("  No arguments required.\n");
1381                         LOG_INFO("See also: ^2moveplayer, allspec^7\n");
1382                         return;
1383                 }
1384         }
1385 }
1386
1387 void GameCommand_stuffto(float request, float argc)
1388 {
1389         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1390         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1391         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1392
1393 #ifdef STUFFTO_ENABLED
1394                 switch (request)
1395                 {
1396                         case CMD_REQUEST_COMMAND:
1397                         {
1398                                 if (argv(2))
1399                                 {
1400                                         entity client = GetIndexedEntity(argc, 1);
1401                                         float accepted = VerifyClientEntity(client, true, false);
1402
1403                                         if (accepted > 0)
1404                                         {
1405                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1406                                                 LOG_INFO(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").\n"));
1407                                         }
1408                                         else
1409                                         {
1410                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1411                                         }
1412
1413                                         return;
1414                                 }
1415                         }
1416
1417                         default:
1418                                 LOG_INFO("Incorrect parameters for ^2stuffto^7\n");
1419                         case CMD_REQUEST_USAGE:
1420                         {
1421                                 LOG_INFO("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1422                                 LOG_INFO("  'client' is the entity number or name of the player,\n");
1423                                 LOG_INFO("  and 'command' is the command to be sent to that player.\n");
1424                                 return;
1425                         }
1426                 }
1427 #else
1428                 if (request)
1429                 {
1430                         LOG_INFO("stuffto command is not enabled on this server.\n");
1431                         return;
1432                 }
1433 #endif
1434 }
1435
1436 void GameCommand_trace(float request, float argc)
1437 {
1438         switch (request)
1439         {
1440                 case CMD_REQUEST_COMMAND:
1441                 {
1442                         entity e;
1443                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1444                         float i, f, safe, unsafe, dq, dqf;
1445
1446                         switch (argv(1))
1447                         {
1448                                 case "debug":
1449                                 {
1450                                         float hitcount = 0;
1451                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1452                                         float worst_endpos_bug = 0;
1453                                         for ( ; ; )
1454                                         {
1455                                                 org = world.mins;
1456                                                 delta = world.maxs - world.mins;
1457
1458                                                 start.x = org.x + random() * delta.x;
1459                                                 start.y = org.y + random() * delta.y;
1460                                                 start.z = org.z + random() * delta.z;
1461
1462                                                 end.x = org.x + random() * delta.x;
1463                                                 end.y = org.y + random() * delta.y;
1464                                                 end.z = org.z + random() * delta.z;
1465
1466                                                 start = stov(vtos(start));
1467                                                 end = stov(vtos(end));
1468
1469                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1470                                                 if (!trace_startsolid && trace_fraction < 1)
1471                                                 {
1472                                                         p = trace_endpos;
1473                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1474                                                         if (trace_startsolid)
1475                                                         {
1476                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1477                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1478
1479                                                                 // how much do we need to back off?
1480                                                                 safe = 1;
1481                                                                 unsafe = 0;
1482                                                                 for ( ; ; )
1483                                                                 {
1484                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1485                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1486                                                                         if (trace_startsolid)
1487                                                                         {
1488                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1489                                                                                 unsafe = (safe + unsafe) * 0.5;
1490                                                                         }
1491                                                                         else
1492                                                                         {
1493                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1494                                                                                 safe = (safe + unsafe) * 0.5;
1495                                                                         }
1496                                                                 }
1497
1498                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1499                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1500
1501                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1502                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1503                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1504                                                                 if (++hitcount >= 10) break;
1505                                                         }
1506                                                         else
1507                                                         {
1508                                                                 q0 = p;
1509                                                                 dq = 0;
1510                                                                 dqf = 1;
1511                                                                 for ( ; ; )
1512                                                                 {
1513                                                                         q = p + normalize(end - p) * (dq + dqf);
1514                                                                         if (q == q0) break;
1515                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1516                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1517                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1518                                                                         dqf *= 0.5;
1519                                                                         q0 = q;
1520                                                                 }
1521                                                                 if (dq > worst_endpos_bug)
1522                                                                 {
1523                                                                         worst_endpos_bug = dq;
1524                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1525                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1526                                                                         if (++hitcount >= 10) break;
1527                                                                 }
1528                                                         }
1529                                                 }
1530                                         }
1531                                         return;
1532                                 }
1533
1534                                 case "debug2":
1535                                 {
1536                                         e = nextent(NULL);
1537                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1538                                         vv = trace_endpos;
1539                                         if (trace_fraction == 1)
1540                                         {
1541                                                 LOG_INFO("not above ground, aborting\n");
1542                                                 return;
1543                                         }
1544                                         f = 0;
1545                                         for (i = 0; i < 100000; ++i)
1546                                         {
1547                                                 dv = randomvec();
1548                                                 if (dv.z > 0) dv = -1 * dv;
1549                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1550                                                 if (trace_startsolid) LOG_INFO("bug 1\n");
1551                                                 if (trace_fraction == 1)
1552                                                 {
1553                                                         if (dv.z < f)
1554                                                         {
1555                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1556                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1557                                                                 f = dv.z;
1558                                                         }
1559                                                 }
1560                                         }
1561                                         LOG_INFO("highest possible dist: ", ftos(f), "\n");
1562                                         return;
1563                                 }
1564
1565                                 case "walk":
1566                                 {
1567                                         if (argc == 4)
1568                                         {
1569                                                 e = nextent(NULL);
1570                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL)) LOG_INFO("can walk\n");
1571                                                 else LOG_INFO("cannot walk\n");
1572                                                 return;
1573                                         }
1574                                 }
1575
1576                                 case "showline":
1577                                 {
1578                                         if (argc == 4)
1579                                         {
1580                                                 vv = stov(argv(2));
1581                                                 dv = stov(argv(3));
1582                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1583                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1584                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1585                                                 return;
1586                                         }
1587                                 }
1588
1589                                         // no default case, just go straight to invalid
1590                         }
1591                 }
1592
1593                 default:
1594                         LOG_INFO("Incorrect parameters for ^2trace^7\n");
1595                 case CMD_REQUEST_USAGE:
1596                 {
1597                         LOG_INFO("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1598                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1599                         LOG_INFO("See also: ^2bbox, gettaginfo^7\n");
1600                         return;
1601                 }
1602         }
1603 }
1604
1605 void GameCommand_unlockteams(float request)
1606 {
1607         switch (request)
1608         {
1609                 case CMD_REQUEST_COMMAND:
1610                 {
1611                         if (teamplay)
1612                         {
1613                                 lockteams = 0;
1614                                 bprint("^1The teams are now unlocked.\n");
1615                         }
1616                         else
1617                         {
1618                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1619                         }
1620                         return;
1621                 }
1622
1623                 default:
1624                 case CMD_REQUEST_USAGE:
1625                 {
1626                         LOG_INFO("\nUsage:^3 sv_cmd unlockteams\n");
1627                         LOG_INFO("  No arguments required.\n");
1628                         LOG_INFO("See also: ^2lockteams^7\n");
1629                         return;
1630                 }
1631         }
1632 }
1633
1634 void GameCommand_warp(float request, float argc)
1635 {
1636         switch (request)
1637         {
1638                 case CMD_REQUEST_COMMAND:
1639                 {
1640                         if (autocvar_g_campaign)
1641                         {
1642                                 if (argc >= 2)
1643                                 {
1644                                         CampaignLevelWarp(stof(argv(1)));
1645                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".\n");
1646                                 }
1647                                 else
1648                                 {
1649                                         CampaignLevelWarp(-1);
1650                                         LOG_INFO("Successfully warped to next campaign level.\n");
1651                                 }
1652                         }
1653                         else
1654                         {
1655                                 LOG_INFO("Not in campaign, can't level warp\n");
1656                         }
1657                         return;
1658                 }
1659
1660                 default:
1661                 case CMD_REQUEST_USAGE:
1662                 {
1663                         LOG_INFO("\nUsage:^3 sv_cmd warp [level]\n");
1664                         LOG_INFO("  'level' is the level to change campaign mode to.\n");
1665                         LOG_INFO("  if 'level' is not provided it will change to the next level.\n");
1666                         return;
1667                 }
1668         }
1669 }
1670
1671 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1672 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1673 void GameCommand_(float request)
1674 {
1675     switch(request)
1676     {
1677         case CMD_REQUEST_COMMAND:
1678         {
1679
1680             return;
1681         }
1682
1683         default:
1684         case CMD_REQUEST_USAGE:
1685         {
1686             print("\nUsage:^3 sv_cmd \n");
1687             print("  No arguments required.\n");
1688             return;
1689         }
1690     }
1691 }
1692 */
1693
1694
1695 // ==================================
1696 //  Macro system for server commands
1697 // ==================================
1698
1699 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1700 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1701 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1702 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1703 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1704 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1705 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1706 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1707 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1708 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1709 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1710 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1711 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1712 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1713 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1714 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1715 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1716 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1717 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1718 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1719 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1720 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1721 SERVER_COMMAND(playerdemo, "Control the ability to save demos of players") { GameCommand_playerdemo(request, arguments); }
1722 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1723 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1724 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1725 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1726 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1727 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1728 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1729 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1730 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1731
1732 void GameCommand_macro_help()
1733 {
1734         FOREACH(SERVER_COMMANDS, true, LAMBDA(LOG_INFOF("  ^2%s^7: %s\n", it.m_name, it.m_description)));
1735 }
1736
1737 float GameCommand_macro_command(float argc, string command)
1738 {
1739         string c = strtolower(argv(0));
1740         FOREACH(SERVER_COMMANDS, it.m_name == c, LAMBDA(
1741                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1742                 return true;
1743         ));
1744         return false;
1745 }
1746
1747 float GameCommand_macro_usage(float argc)
1748 {
1749         string c = strtolower(argv(1));
1750         FOREACH(SERVER_COMMANDS, it.m_name == c, LAMBDA(
1751                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1752                 return true;
1753         ));
1754         return false;
1755 }
1756
1757 void GameCommand_macro_write_aliases(float fh)
1758 {
1759         FOREACH(SERVER_COMMANDS, true, LAMBDA(CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description)));
1760 }
1761
1762
1763 // =========================================
1764 //  Main Function Called By Engine (sv_cmd)
1765 // =========================================
1766 // If this function exists, game code handles gamecommand instead of the engine code.
1767
1768 void GameCommand(string command)
1769 {
1770         float argc = tokenize_console(command);
1771
1772         // Guide for working with argc arguments by example:
1773         // argc:   1    - 2      - 3     - 4
1774         // argv:   0    - 1      - 2     - 3
1775         // cmd     vote - master - login - password
1776
1777         if (strtolower(argv(0)) == "help")
1778         {
1779                 if (argc == 1)
1780                 {
1781                         LOG_INFO("\nServer console commands:\n");
1782                         GameCommand_macro_help();
1783
1784                         LOG_INFO("\nBanning commands:\n");
1785                         BanCommand_macro_help();
1786
1787                         LOG_INFO("\nCommon networked commands:\n");
1788                         CommonCommand_macro_help(NULL);
1789
1790                         LOG_INFO("\nGeneric commands shared by all programs:\n");
1791                         GenericCommand_macro_help();
1792
1793                         LOG_INFO("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1794                         LOG_INFO("For help about a specific command, type sv_cmd help COMMAND\n");
1795
1796                         return;
1797                 }
1798                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1799                 {
1800                         return;
1801                 }
1802                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1803                 {
1804                         return;
1805                 }
1806                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1807                 {
1808                         return;
1809                 }
1810                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1811                 {
1812                         return;
1813                 }
1814         }
1815         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1816         {
1817                 return;  // handled by a mutator
1818         }
1819         else if (BanCommand(command))
1820         {
1821                 return;  // handled by server/command/ipban.qc
1822         }
1823         else if (CommonCommand_macro_command(argc, NULL, command))
1824         {
1825                 return;  // handled by server/command/common.qc
1826         }
1827         else if (GenericCommand(command))
1828         {
1829                 return;                                        // handled by common/command/generic.qc
1830         }
1831         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1832         {
1833                 return;                                        // handled by one of the above GameCommand_* functions
1834         }
1835
1836         // nothing above caught the command, must be invalid
1837         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1838 }