qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if not(accepted > 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_allready(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         ReadyRestart();
 149                         return;
 150                 }
 151
 152                 default:
 153                 case CMD_REQUEST_USAGE:
 154                 {
 155                         print("\nUsage:^3 sv_cmd allready\n");
 156                         print("  No arguments required.\n");
 157                         return;
 158                 }
 159         }
 160 }
 161
 162 void GameCommand_allspec(float request, float argc)
 163 {
 164         switch(request)
 165         {
 166                 case CMD_REQUEST_COMMAND:
 167                 {
 168                         entity client;
 169                         string reason = argv(1);
 170                         float i = 0;
 171
 172                         FOR_EACH_REALPLAYER(client)
 173                         {
 174                                 self = client;
 175                                 PutObserverInServer();
 176                                 ++i;
 177                         }
 178                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 179                         else { print("No players found to spectate.\n"); }
 180                         return;
 181                 }
 182
 183                 default:
 184                 case CMD_REQUEST_USAGE:
 185                 {
 186                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 187                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 188                         print("See also: ^2moveplayer, shuffleteams^7\n");
 189                         return;
 190                 }
 191         }
 192 }
 193
 194 void GameCommand_anticheat(float request, float argc)
 195 {
 196         switch(request)
 197         {
 198                 case CMD_REQUEST_COMMAND:
 199                 {
 200                         entity client = GetIndexedEntity(argc, 1);
 201                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 202
 203                         if(accepted > 0)
 204                         {
 205                                 self = client;
 206                                 anticheat_report();
 207                                 return;
 208                         }
 209                         else
 210                         {
 211                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 212                         }
 213                 }
 214
 215                 default:
 216                         print("Incorrect parameters for ^2anticheat^7\n");
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         print("\nUsage:^3 sv_cmd anticheat client\n");
 220                         print("  'client' is the entity number or name of the player.\n");
 221                         return;
 222                 }
 223         }
 224 }
 225
 226 void GameCommand_bbox(float request)
 227 {
 228         switch(request)
 229         {
 230                 case CMD_REQUEST_COMMAND:
 231                 {
 232                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 233                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 234                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 235                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 236                         print("Solid bounding box size:");
 237
 238                         tracebox('1 0 0' * world.absmin_x,
 239                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 240                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 241                                                         '1 0 0' * world.absmax_x,
 242                                         MOVE_WORLDONLY,
 243                                         world);
 244                         if(trace_startsolid)
 245                                 print(" ", ftos(world.absmin_x));
 246                         else
 247                                 print(" ", ftos(trace_endpos_x));
 248
 249                         tracebox('0 1 0' * world.absmin_y,
 250                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 251                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 252                                                         '0 1 0' * world.absmax_y,
 253                                         MOVE_WORLDONLY,
 254                                         world);
 255                         if(trace_startsolid)
 256                                 print(" ", ftos(world.absmin_y));
 257                         else
 258                                 print(" ", ftos(trace_endpos_y));
 259
 260                         tracebox('0 0 1' * world.absmin_z,
 261                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 262                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 263                                                         '0 0 1' * world.absmax_z,
 264                                         MOVE_WORLDONLY,
 265                                         world);
 266                         if(trace_startsolid)
 267                                 print(" ", ftos(world.absmin_z));
 268                         else
 269                                 print(" ", ftos(trace_endpos_z));
 270
 271                         tracebox('1 0 0' * world.absmax_x,
 272                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 273                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 274                                                         '1 0 0' * world.absmin_x,
 275                                         MOVE_WORLDONLY,
 276                                         world);
 277                         if(trace_startsolid)
 278                                 print(" ", ftos(world.absmax_x));
 279                         else
 280                                 print(" ", ftos(trace_endpos_x));
 281
 282                         tracebox('0 1 0' * world.absmax_y,
 283                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 284                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 285                                                         '0 1 0' * world.absmin_y,
 286                                         MOVE_WORLDONLY,
 287                                         world);
 288                         if(trace_startsolid)
 289                                 print(" ", ftos(world.absmax_y));
 290                         else
 291                                 print(" ", ftos(trace_endpos_y));
 292
 293                         tracebox('0 0 1' * world.absmax_z,
 294                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 295                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 296                                                         '0 0 1' * world.absmin_z,
 297                                         MOVE_WORLDONLY,
 298                                         world);
 299                         if(trace_startsolid)
 300                                 print(" ", ftos(world.absmax_z));
 301                         else
 302                                 print(" ", ftos(trace_endpos_z));
 303
 304                         print("\n");
 305                         return;
 306                 }
 307
 308                 default:
 309                 case CMD_REQUEST_USAGE:
 310                 {
 311                         print("\nUsage:^3 sv_cmd bbox\n");
 312                         print("  No arguments required.\n");
 313                         print("See also: ^2gettaginfo, trace^7\n");
 314                         return;
 315                 }
 316         }
 317 }
 318
 319 void GameCommand_bot_cmd(float request, float argc, string command)
 320 {
 321         switch(request)
 322         {
 323                 case CMD_REQUEST_COMMAND:
 324                 {
 325                         entity bot;
 326
 327                         if(argv(1) == "reset")
 328                         {
 329                                 bot_resetqueues();
 330                                 return;
 331                         }
 332                         else if(argv(1) == "setbots")
 333                         {
 334                                 cvar_settemp("bot_vs_human", "0");
 335                                 cvar_settemp("minplayers", "0");
 336                                 cvar_settemp("bot_number", "0");
 337                                 bot_fixcount();
 338                                 cvar_settemp("bot_number", argv(2));
 339                                 if(!bot_fixcount())
 340                                         print("Sorry, could not set requested bot count\n");
 341                                 return;
 342                         }
 343                         else if(argv(1) == "load" && argc == 3)
 344                         {
 345                                 float fh, i;
 346                                 string s;
 347                                 fh = fopen(argv(2), FILE_READ);
 348                                 if(fh < 0)
 349                                 {
 350                                         print("cannot open the file\n");
 351                                         return;
 352                                 }
 353
 354                                 i = 0;
 355                                 while((s = fgets(fh)))
 356                                 {
 357                                         argc = tokenize_console(s);
 358
 359                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 360                                         {
 361                                                 if(argv(2) == "reset")
 362                                                 {
 363                                                         bot_resetqueues();
 364                                                 }
 365                                                 else if(argv(2) == "setbots")
 366                                                 {
 367                                                         cvar_settemp("bot_vs_human", "0");
 368                                                         cvar_settemp("minplayers", "0");
 369                                                         cvar_settemp("bot_number", "0");
 370                                                         bot_fixcount();
 371                                                         cvar_settemp("bot_number", argv(3));
 372                                                         if(!bot_fixcount())
 373                                                                 print("Sorry, could not set requested bot count\n");
 374                                                 }
 375                                                 else
 376                                                 {
 377                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 378                                                         bot = find_bot_by_number(stof(argv(2)));
 379                                                         if(bot == world)
 380                                                                 bot = find_bot_by_name(argv(2));
 381                                                         if(bot)
 382                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 383                                                 }
 384                                         }
 385                                         else
 386                                                 localcmd(strcat(s, "\n"));
 387
 388                                         ++i;
 389                                 }
 390                                 print(ftos(i), " commands read\n");
 391                                 fclose(fh);
 392                                 return;
 393                         }
 394                         else if(argv(1) == "help")
 395                         {
 396                                 if(argv(2))
 397                                         bot_cmdhelp(argv(2));
 398                                 else
 399                                         bot_list_commands();
 400                                 return;
 401                         }
 402                         else if(argc >= 3) // this comes last
 403                         {
 404                                 bot = find_bot_by_number(stof(argv(1)));
 405                                 if(bot == world)
 406                                         bot = find_bot_by_name(argv(1));
 407                                 if(bot)
 408                                 {
 409                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 410                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 411                                         return;
 412                                 }
 413                                 else
 414                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 415                         }
 416                 }
 417
 418                 default:
 419                         print("Incorrect parameters for ^2bot_cmd^7\n");
 420                 case CMD_REQUEST_USAGE:
 421                 {
 422                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 423                         print("  'client' can be either the name or entity id of the bot\n");
 424                         print("  For full list of commands, see bot_cmd help [command].\n");
 425                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 426                         print("          sv_cmd bot_cmd client presskey jump\n");
 427                         return;
 428                 }
 429         }
 430 }
 431
 432 void GameCommand_cointoss(float request, float argc)
 433 {
 434         switch(request)
 435         {
 436                 case CMD_REQUEST_COMMAND:
 437                 {
 438                         entity client;
 439                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 440                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 441                         string choice = ((random() > 0.5) ? result1 : result2);
 442
 443                         FOR_EACH_CLIENT(client)
 444                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 445                         bprint(strcat("^3Throwing coin... Result: ", choice));
 446                         return;
 447                 }
 448
 449                 default:
 450                 case CMD_REQUEST_USAGE:
 451                 {
 452                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 453                         print("  Where 'result1' and 'result2' are user created options.\n");
 454                         return;
 455                 }
 456         }
 457 }
 458
 459 void GameCommand_database(float request, float argc)
 460 {
 461         switch(request)
 462         {
 463                 case CMD_REQUEST_COMMAND:
 464                 {
 465                         if(argc == 3)
 466                         {
 467                                 if(argv(1) == "save")
 468                                 {
 469                                         db_save(ServerProgsDB, argv(2));
 470                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 471                                         return;
 472                                 }
 473                                 else if(argv(1) == "dump")
 474                                 {
 475                                         db_dump(ServerProgsDB, argv(2));
 476                                         print("DB dumped.\n"); // wtf does this do?
 477                                         return;
 478                                 }
 479                                 else if(argv(1) == "load")
 480                                 {
 481                                         db_close(ServerProgsDB);
 482                                         ServerProgsDB = db_load(argv(2));
 483                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 484                                         return;
 485                                 }
 486                         }
 487                 }
 488
 489                 default:
 490                         print("Incorrect parameters for ^2database^7\n");
 491                 case CMD_REQUEST_USAGE:
 492                 {
 493                         print("\nUsage:^3 sv_cmd database action filename\n");
 494                         print("  Where 'action' is the command to complete,\n");
 495                         print("  and 'filename' is what it acts upon.\n");
 496                         print("  Full list of commands here: \"save, dump, load.\"\n");
 497                         return;
 498                 }
 499         }
 500 }
 501
 502 void GameCommand_defer_clear(float request, float argc)
 503 {
 504         switch(request)
 505         {
 506                 case CMD_REQUEST_COMMAND:
 507                 {
 508                         entity client;
 509                         float accepted;
 510
 511                         if(argc >= 2)
 512                         {
 513                                 client = GetIndexedEntity(argc, 1);
 514                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 515
 516                                 if(accepted > 0)
 517                                 {
 518                                         stuffcmd(client, "defer clear\n");
 519                                         print("defer clear stuffed to ", client.netname, "\n");
 520                                 }
 521                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 522
 523                                 return;
 524                         }
 525                 }
 526
 527                 default:
 528                         print("Incorrect parameters for ^2defer_clear^7\n");
 529                 case CMD_REQUEST_USAGE:
 530                 {
 531                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 532                         print("  'client' is the entity number or name of the player.\n");
 533                         print("See also: ^2defer_clear_all^7\n");
 534                         return;
 535                 }
 536         }
 537 }
 538
 539 void GameCommand_defer_clear_all(float request)
 540 {
 541         switch(request)
 542         {
 543                 case CMD_REQUEST_COMMAND:
 544                 {
 545                         entity client;
 546                         float i = 0;
 547                         float argc;
 548
 549                         FOR_EACH_CLIENT(client)
 550                         {
 551                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 552                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 553                                 ++i;
 554                         }
 555                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 556                         return;
 557                 }
 558
 559                 default:
 560                 case CMD_REQUEST_USAGE:
 561                 {
 562                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 563                         print("  No arguments required.\n");
 564                         print("See also: ^2defer_clear^7\n");
 565                         return;
 566                 }
 567         }
 568 }
 569
 570 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 571 {
 572         switch(request)
 573         {
 574                 case CMD_REQUEST_COMMAND:
 575                 {
 576                         if(argv(1))
 577                         {
 578                                 if(argv(2))
 579                                         race_deleteTime(argv(2), stof(argv(1)));
 580                                 else
 581                                         race_deleteTime(GetMapname(), stof(argv(1)));
 582                                 return;
 583                         }
 584                 }
 585
 586                 default:
 587                         print("Incorrect parameters for ^2delrec^7\n");
 588                 case CMD_REQUEST_USAGE:
 589                 {
 590                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 591                         print("  'ranking' is which ranking level to clear up to, \n");
 592                         print("  it will clear all records up to nth place.\n");
 593                         print("  if 'map' is not provided it will use current map.\n");
 594                         return;
 595                 }
 596         }
 597 }
 598
 599 void GameCommand_effectindexdump(float request)
 600 {
 601         switch(request)
 602         {
 603                 case CMD_REQUEST_COMMAND:
 604                 {
 605                         float fh, d;
 606                         string s;
 607
 608                         d = db_create();
 609                         print("begin of effects list\n");
 610                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 611                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 612                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 613                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 614                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 615                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 616                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 617                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 618                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 619                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 620                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 621                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 622                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 623                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 624                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 625                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 626                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 627                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 628                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 629                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 630                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 631                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 632                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 633                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 634                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 635                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 636                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 637                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 638                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 639                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 640                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 641                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 642                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 643                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 644                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 645                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 646
 647                         fh = fopen("effectinfo.txt", FILE_READ);
 648                         while((s = fgets(fh)))
 649                         {
 650                                 tokenize_console(s);
 651                                 if(argv(0) == "effect")
 652                                 {
 653                                         if(db_get(d, argv(1)) != "1")
 654                                         {
 655                                                 if(particleeffectnum(argv(1)) >= 0)
 656                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 657                                                 db_put(d, argv(1), "1");
 658                                         }
 659                                 }
 660                         }
 661                         print("end of effects list\n");
 662
 663                         db_close(d);
 664                         return;
 665                 }
 666
 667                 default:
 668                 case CMD_REQUEST_USAGE:
 669                 {
 670                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 671                         print("  No arguments required.\n");
 672                         return;
 673                 }
 674         }
 675 }
 676
 677 void GameCommand_extendmatchtime(float request)
 678 {
 679         switch(request)
 680         {
 681                 case CMD_REQUEST_COMMAND:
 682                 {
 683                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 684                         return;
 685                 }
 686
 687                 default:
 688                 case CMD_REQUEST_USAGE:
 689                 {
 690                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 691                         print("  No arguments required.\n");
 692                         print("See also: ^2reducematchtime^7\n");
 693                         return;
 694                 }
 695         }
 696 }
 697
 698 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 699 {
 700         switch(request)
 701         {
 702                 case CMD_REQUEST_COMMAND:
 703                 {
 704                         entity client;
 705
 706                         for(client = world; (client = find(client, classname, argv(1))); )
 707                                 print(etos(client), "\n");
 708
 709                         return;
 710                 }
 711
 712                 default:
 713                         print("Incorrect parameters for ^2find^7\n");
 714                 case CMD_REQUEST_USAGE:
 715                 {
 716                         print("\nUsage:^3 sv_cmd find classname\n");
 717                         print("  Where 'classname' is the classname to search for.\n");
 718                         return;
 719                 }
 720         }
 721 }
 722
 723 void GameCommand_gametype(float request, float argc)
 724 {
 725         switch(request)
 726         {
 727                 case CMD_REQUEST_COMMAND:
 728                 {
 729                         if(argv(1) != "")
 730                         {
 731                                 string s = argv(1);
 732                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 733
 734                                 if(t)
 735                                 {
 736                                         MapInfo_SwitchGameType(t);
 737                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 738                                         if(MapInfo_count > 0)
 739                                         {
 740                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 741                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 742                                                 lsmaps_reply = strzone(getlsmaps());
 743                                                 bprint("Game type successfully switched to ", s, "\n");
 744                                         }
 745                                         else
 746                                         {
 747                                                 bprint("Cannot use this game type: no map for it found\n");
 748                                                 MapInfo_SwitchGameType(tsave);
 749                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 750                                         }
 751                                 }
 752                                 else
 753                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 754
 755                                 return;
 756                         }
 757                 }
 758
 759                 default:
 760                         print("Incorrect parameters for ^2gametype^7\n");
 761                 case CMD_REQUEST_USAGE:
 762                 {
 763                         print("\nUsage:^3 sv_cmd gametype mode\n");
 764                         print("  Where 'mode' is the gametype mode to switch to.\n");
 765                         print("See also: ^2gotomap^7\n");
 766                         return;
 767                 }
 768         }
 769 }
 770
 771 void GameCommand_gettaginfo(float request, float argc)
 772 {
 773         switch(request)
 774         {
 775                 case CMD_REQUEST_COMMAND:
 776                 {
 777                         entity tmp_entity;
 778                         float i;
 779                         vector v;
 780
 781                         if(argc >= 4)
 782                         {
 783                                 tmp_entity = spawn();
 784                                 if(argv(1) == "w")
 785                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 786                                 else
 787                                 {
 788                                         precache_model(argv(1));
 789                                         setmodel(tmp_entity, argv(1));
 790                                 }
 791                                 tmp_entity.frame = stof(argv(2));
 792                                 if(substring(argv(3), 0, 1) == "#")
 793                                         i = stof(substring(argv(3), 1, -1));
 794                                 else
 795                                         i = gettagindex(tmp_entity, argv(3));
 796                                 if(i)
 797                                 {
 798                                         v = gettaginfo(tmp_entity, i);
 799                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 800                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 801                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 802                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 803                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 804                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 805                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 806                                         if(argc >= 6)
 807                                         {
 808                                                 v_y = -v_y;
 809                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 810                                         }
 811                                 }
 812                                 else
 813                                         print("bone not found\n");
 814
 815                                 remove(tmp_entity);
 816                                 return;
 817                         }
 818                 }
 819
 820                 default:
 821                         print("Incorrect parameters for ^2gettaginfo^7\n");
 822                 case CMD_REQUEST_USAGE:
 823                 {
 824                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 825                         print("See also: ^2bbox, trace^7\n");
 826                         return;
 827                 }
 828         }
 829 }
 830
 831 void GameCommand_animbench(float request, float argc)
 832 {
 833         switch(request)
 834         {
 835                 case CMD_REQUEST_COMMAND:
 836                 {
 837                         entity tmp_entity;
 838
 839                         if(argc >= 4)
 840                         {
 841                                 tmp_entity = spawn();
 842                                 if(argv(1) == "w")
 843                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 844                                 else
 845                                 {
 846                                         precache_model(argv(1));
 847                                         setmodel(tmp_entity, argv(1));
 848                                 }
 849                                 float f1 = stof(argv(2));
 850                                 float f2 = stof(argv(3));
 851                                 float t0;
 852                                 float t1 = 0;
 853                                 float t2 = 0;
 854                                 float n = 0;
 855
 856                                 while(t1 + t2 < 1)
 857                                 {
 858                                         tmp_entity.frame = f1;
 859                                         t0 = gettime(GETTIME_HIRES);
 860                                         getsurfacepoint(tmp_entity, 0, 0);
 861                                         t1 += gettime(GETTIME_HIRES) - t0;
 862                                         tmp_entity.frame = f2;
 863                                         t0 = gettime(GETTIME_HIRES);
 864                                         getsurfacepoint(tmp_entity, 0, 0);
 865                                         t2 += gettime(GETTIME_HIRES) - t0;
 866                                         n += 1;
 867                                 }
 868                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 869                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 870
 871                                 remove(tmp_entity);
 872                                 return;
 873                         }
 874                 }
 875
 876                 default:
 877                         print("Incorrect parameters for ^2gettaginfo^7\n");
 878                 case CMD_REQUEST_USAGE:
 879                 {
 880                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 881                         print("See also: ^2bbox, trace^7\n");
 882                         return;
 883                 }
 884         }
 885 }
 886
 887 void GameCommand_gotomap(float request, float argc)
 888 {
 889         switch(request)
 890         {
 891                 case CMD_REQUEST_COMMAND:
 892                 {
 893                         if(argv(1))
 894                         {
 895                                 print(GotoMap(argv(1)), "\n");
 896                                 return;
 897                         }
 898                 }
 899
 900                 default:
 901                         print("Incorrect parameters for ^2gotomap^7\n");
 902                 case CMD_REQUEST_USAGE:
 903                 {
 904                         print("\nUsage:^3 sv_cmd gotomap map\n");
 905                         print("  Where 'map' is the *.bsp file to change to.\n");
 906                         print("See also: ^2gametype^7\n");
 907                         return;
 908                 }
 909         }
 910 }
 911
 912 void GameCommand_lockteams(float request)
 913 {
 914         switch(request)
 915         {
 916                 case CMD_REQUEST_COMMAND:
 917                 {
 918                         if(teamplay)
 919                         {
 920                                 lockteams = 1;
 921                                 bprint("^1The teams are now locked.\n");
 922                         }
 923                         else
 924                         {
 925                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 926                         }
 927                         return;
 928                 }
 929
 930                 default:
 931                 case CMD_REQUEST_USAGE:
 932                 {
 933                         print("\nUsage:^3 sv_cmd lockteams\n");
 934                         print("  No arguments required.\n");
 935                         print("See also: ^2unlockteams^7\n");
 936                         return;
 937                 }
 938         }
 939 }
 940
 941 void GameCommand_make_mapinfo(float request)
 942 {
 943         switch(request)
 944         {
 945                 case CMD_REQUEST_COMMAND:
 946                 {
 947                         entity tmp_entity;
 948
 949                         tmp_entity = spawn();
 950                         tmp_entity.classname = "make_mapinfo";
 951                         tmp_entity.think = make_mapinfo_Think;
 952                         tmp_entity.nextthink = time;
 953                         MapInfo_Enumerate();
 954                         return;
 955                 }
 956
 957                 default:
 958                 case CMD_REQUEST_USAGE:
 959                 {
 960                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
 961                         print("  No arguments required.\n");
 962                         print("See also: ^2radarmap^7\n");
 963                         return;
 964                 }
 965         }
 966 }
 967
 968 void GameCommand_moveplayer(float request, float argc)
 969 {
 970         switch(request)
 971         {
 972                 case CMD_REQUEST_COMMAND:
 973                 {
 974                         float accepted;
 975                         entity client;
 976
 977                         string targets = strreplace(",", " ", argv(1));
 978                         string original_targets = strreplace(" ", ", ", targets);
 979                         string destination = argv(2);
 980
 981                         string successful, t;
 982                         successful = string_null;
 983
 984                         // lets see if the target(s) even actually exist.
 985                         if((targets) && (destination))
 986                         {
 987                                 for(;targets;)
 988                                 {
 989                                         t = car(targets); targets = cdr(targets);
 990
 991                                         // Check to see if the player is a valid target
 992                                         client = GetFilteredEntity(t);
 993                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
 994
 995                                         if not(accepted > 0)
 996                                         {
 997                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 998                                                 continue;
 999                                         }
1000
1001                                         // Where are we putting this player?
1002                                         if(destination == "spec" || destination == "spectator")
1003                                         {
1004                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1005                                                 {
1006                                                         self = client;
1007                                                         PutObserverInServer();
1008
1009                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1010                                                 }
1011                                                 else
1012                                                 {
1013                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1014                                                 }
1015                                                 continue;
1016                                         }
1017                                         else
1018                                         {
1019                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1020                                                 {
1021                                                         if(teamplay)
1022                                                         {
1023                                                                 // set up
1024                                                                 float team_id;
1025                                                                 float save = client.team_forced;
1026                                                                 client.team_forced = 0;
1027
1028                                                                 // find the team to move the player to
1029                                                                 team_id = Team_ColorToTeam(destination);
1030                                                                 if(team_id == client.team) // already on the destination team
1031                                                                 {
1032                                                                         // keep the forcing undone
1033                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1034                                                                         continue;
1035                                                                 }
1036                                                                 else if(team_id == 0)  // auto team
1037                                                                 {
1038                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1039                                                                 }
1040                                                                 else
1041                                                                 {
1042                                                                         CheckAllowedTeams(client);
1043                                                                 }
1044                                                                 client.team_forced = save;
1045
1046                                                                 // Check to see if the destination team is even available
1047                                                                 switch(team_id)
1048                                                                 {
1049                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1050                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1051                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1052                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1053
1054                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1055                                                                 }
1056
1057                                                                 // If so, lets continue and finally move the player
1058                                                                 client.team_forced = 0;
1059                                                                 MoveToTeam(client, team_id, 6);
1060                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1061                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1062                                                                 continue;
1063                                                         }
1064                                                         else
1065                                                         {
1066                                                                 print("Can't change teams when currently not playing a team game.\n");
1067                                                                 return;
1068                                                         }
1069                                                 }
1070                                                 else
1071                                                 {
1072                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1073                                                         return;
1074                                                 }
1075                                         }
1076                                 }
1077
1078                                 if(successful)
1079                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1080                                 else
1081                                         print("No players given (", original_targets, ") are able to move.\n");
1082
1083                                 return; // still correct parameters so return to avoid usage print
1084                         }
1085                 }
1086
1087                 default:
1088                         print("Incorrect parameters for ^2moveplayer^7\n");
1089                 case CMD_REQUEST_USAGE:
1090                 {
1091                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1092                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1093                         print("  'destination' is what to send the player to, be it team or spectating\n");
1094                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1095                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1096                         print("          sv_cmd moveplayer 2 spec \n");
1097                         print("See also: ^2allspec, shuffleteams^7\n");
1098                         return;
1099                 }
1100         }
1101 }
1102
1103 void GameCommand_nospectators(float request)
1104 {
1105         switch(request)
1106         {
1107                 case CMD_REQUEST_COMMAND:
1108                 {
1109                         blockSpectators = 1;
1110                         entity plr;
1111                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1112                         {
1113                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1114                                 {
1115                                         plr.spectatortime = time;
1116                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1117                                 }
1118                         }
1119                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1120                         return;
1121                 }
1122
1123                 default:
1124                 case CMD_REQUEST_USAGE:
1125                 {
1126                         print("\nUsage:^3 sv_cmd nospectators\n");
1127                         print("  No arguments required.\n");
1128                         return;
1129                 }
1130         }
1131 }
1132
1133 void GameCommand_playerdemo(float request, float argc)
1134 {
1135         switch(request)
1136         {
1137                 case CMD_REQUEST_COMMAND:
1138                 {
1139                         if(argv(2) && argv(3))
1140                         {
1141                                 entity client;
1142                                 float i, n, accepted;
1143
1144                                 switch(argv(1))
1145                                 {
1146                                         case "read":
1147                                         {
1148                                                 client = GetIndexedEntity(argc, 2);
1149                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1150
1151                                                 if not(accepted > 0)
1152                                                 {
1153                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1154                                                         return;
1155                                                 }
1156
1157                                                 self = client;
1158                                                 playerdemo_open_read(argv(next_token));
1159                                                 return;
1160                                         }
1161
1162                                         case "write":
1163                                         {
1164                                                 client = GetIndexedEntity(argc, 2);
1165                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1166
1167                                                 if not(accepted > 0)
1168                                                 {
1169                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1170                                                         return;
1171                                                 }
1172
1173                                                 self = client;
1174                                                 playerdemo_open_write(argv(next_token));
1175                                                 return;
1176                                         }
1177
1178                                         case "auto_read_and_write":
1179                                         {
1180                                                 n = GetFilteredNumber(argv(3));
1181                                                 cvar_set("bot_number", ftos(n));
1182
1183                                                 localcmd("wait; wait; wait\n");
1184                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1185
1186                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1187                                                 return;
1188                                         }
1189
1190                                         case "auto_read":
1191                                         {
1192                                                 n = GetFilteredNumber(argv(3));
1193                                                 cvar_set("bot_number", ftos(n));
1194
1195                                                 localcmd("wait; wait; wait\n");
1196                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1197                                                 return;
1198                                         }
1199                                 }
1200                         }
1201                 }
1202
1203                 default:
1204                         print("Incorrect parameters for ^2playerdemo^7\n");
1205                 case CMD_REQUEST_USAGE:
1206                 {
1207                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1208                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1209                         return;
1210                 }
1211         }
1212 }
1213
1214 void GameCommand_printstats(float request)
1215 {
1216         switch(request)
1217         {
1218                 case CMD_REQUEST_COMMAND:
1219                 {
1220                         DumpStats(FALSE);
1221                         print("stats dumped.\n");
1222                         return;
1223                 }
1224
1225                 default:
1226                 case CMD_REQUEST_USAGE:
1227                 {
1228                         print("\nUsage:^3 sv_cmd printstats\n");
1229                         print("  No arguments required.\n");
1230                         return;
1231                 }
1232         }
1233 }
1234
1235 void GameCommand_radarmap(float request, float argc)
1236 {
1237         switch(request)
1238         {
1239                 case CMD_REQUEST_COMMAND:
1240                 {
1241                         if(RadarMap_Make(argc))
1242                                 return;
1243                 }
1244
1245                 default:
1246                         print("Incorrect parameters for ^2radarmap^7\n");
1247                 case CMD_REQUEST_USAGE:
1248                 {
1249                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1250                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1251                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1252                         print("See also: ^2make_mapinfo^7\n");
1253                         return;
1254                 }
1255         }
1256 }
1257
1258 void GameCommand_reducematchtime(float request)
1259 {
1260         switch(request)
1261         {
1262                 case CMD_REQUEST_COMMAND:
1263                 {
1264                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1265                         return;
1266                 }
1267
1268                 default:
1269                 case CMD_REQUEST_USAGE:
1270                 {
1271                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1272                         print("  No arguments required.\n");
1273                         print("See also: ^2extendmatchtime^7\n");
1274                         return;
1275                 }
1276         }
1277 }
1278
1279 void GameCommand_setbots(float request, float argc)
1280 {
1281         switch(request)
1282         {
1283                 case CMD_REQUEST_COMMAND:
1284                 {
1285                         if(argc >= 2)
1286                         {
1287                                 cvar_settemp("minplayers", "0");
1288                                 cvar_settemp("bot_number", argv(1));
1289                                 bot_fixcount();
1290                                 return;
1291                         }
1292                 }
1293
1294                 default:
1295                         print("Incorrect parameters for ^2setbots^7\n");
1296                 case CMD_REQUEST_USAGE:
1297                 {
1298                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1299                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1300                         print("See also: ^2bot_cmd^7\n");
1301                         return;
1302                 }
1303         }
1304 }
1305
1306 void GameCommand_shuffleteams(float request)
1307 {
1308         switch(request)
1309         {
1310                 case CMD_REQUEST_COMMAND:
1311                 {
1312                         if(teamplay)
1313                         {
1314                                 entity tmp_player;
1315                                 float i, x, z, t_teams, t_players, team_color;
1316
1317                                 // count the total amount of players and total amount of teams
1318                                 t_players = 0;
1319                                 t_teams = 0;
1320                                 FOR_EACH_PLAYER(tmp_player)
1321                                 {
1322                                         CheckAllowedTeams(tmp_player);
1323
1324                                         if(c1 >= 0) t_teams = max(1, t_teams);
1325                                         if(c2 >= 0) t_teams = max(2, t_teams);
1326                                         if(c3 >= 0) t_teams = max(3, t_teams);
1327                                         if(c4 >= 0) t_teams = max(4, t_teams);
1328
1329                                         ++t_players;
1330                                 }
1331
1332                                 // build a list of the players in a random order
1333                                 FOR_EACH_PLAYER(tmp_player)
1334                                 {
1335                                         for(;;)
1336                                         {
1337                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1338
1339                                                 if(shuffleteams_players[i])
1340                                                 {
1341                                                         continue; // a player is already assigned to this slot
1342                                                 }
1343                                                 else
1344                                                 {
1345                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1346                                                         break;
1347                                                 }
1348                                         }
1349                                 }
1350
1351                                 // finally, from the list made earlier, re-join the players in different order.
1352                                 for(i = 1; i <= t_teams; ++i)
1353                                 {
1354                                         // find out how many players to assign to this team
1355                                         x = (t_players / t_teams);
1356                                         x = ((i == 1) ? ceil(x) : floor(x));
1357
1358                                         team_color = Team_NumberToTeam(i);
1359
1360                                         // sort through the random list of players made earlier
1361                                         for(z = 1; z <= maxclients; ++z)
1362                                         {
1363                                                 if not(shuffleteams_teams[i] >= x)
1364                                                 {
1365                                                         if not(shuffleteams_players[z])
1366                                                                 continue; // not a player, move on to next random slot
1367
1368                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1369                                                                 self = edict_num(shuffleteams_players[z]);
1370
1371                                                         if(self.team != team_color)
1372                                                                 MoveToTeam(self, team_color, 6);
1373
1374                                                         shuffleteams_players[z] = 0;
1375                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1376                                                 }
1377                                                 else
1378                                                 {
1379                                                         break; // move on to next team
1380                                                 }
1381                                         }
1382                                 }
1383
1384                                 bprint("Successfully shuffled the players around randomly.\n");
1385
1386                                 // clear the buffers now
1387                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1388                                         shuffleteams_players[i] = 0;
1389
1390                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1391                                         shuffleteams_teams[i] = 0;
1392                         }
1393                         else
1394                         {
1395                                 print("Can't shuffle teams when currently not playing a team game.\n");
1396                         }
1397
1398                         return;
1399                 }
1400
1401                 default:
1402                 case CMD_REQUEST_USAGE:
1403                 {
1404                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1405                         print("  No arguments required.\n");
1406                         print("See also: ^2moveplayer, allspec^7\n");
1407                         return;
1408                 }
1409         }
1410 }
1411
1412 void GameCommand_stuffto(float request, float argc)
1413 {
1414         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1415         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1416         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1417
1418         #ifdef STUFFTO_ENABLED
1419         #message "stuffto command enabled"
1420         switch(request)
1421         {
1422                 case CMD_REQUEST_COMMAND:
1423                 {
1424                         if(argv(2))
1425                         {
1426                                 entity client = GetIndexedEntity(argc, 1);
1427                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1428
1429                                 if(accepted > 0)
1430                                 {
1431                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1432                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1433                                 }
1434                                 else
1435                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1436
1437                                 return;
1438                         }
1439                 }
1440
1441                 default:
1442                         print("Incorrect parameters for ^2stuffto^7\n");
1443                 case CMD_REQUEST_USAGE:
1444                 {
1445                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1446                         print("  'client' is the entity number or name of the player,\n");
1447                         print("  and 'command' is the command to be sent to that player.\n");
1448                         return;
1449                 }
1450         }
1451         #else
1452         if(request)
1453         {
1454                 print("stuffto command is not enabled on this server.\n");
1455                 return;
1456         }
1457         #endif
1458 }
1459
1460 void GameCommand_trace(float request, float argc)
1461 {
1462         switch(request)
1463         {
1464                 case CMD_REQUEST_COMMAND:
1465                 {
1466                         entity e;
1467                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1468                         float i, f, safe, unsafe, dq, dqf;
1469
1470                         switch(argv(1))
1471                         {
1472                                 case "debug":
1473                                 {
1474                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1475                                         for(;;)
1476                                         {
1477                                                 org = world.mins;
1478                                                 delta = world.maxs - world.mins;
1479
1480                                                 start_x = org_x + random() * delta_x;
1481                                                 start_y = org_y + random() * delta_y;
1482                                                 start_z = org_z + random() * delta_z;
1483
1484                                                 end_x = org_x + random() * delta_x;
1485                                                 end_y = org_y + random() * delta_y;
1486                                                 end_z = org_z + random() * delta_z;
1487
1488                                                 start = stov(vtos(start));
1489                                                 end = stov(vtos(end));
1490
1491                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1492                                                 if(!trace_startsolid)
1493                                                 {
1494                                                         p = trace_endpos;
1495                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1496                                                         if(trace_startsolid || trace_fraction == 1)
1497                                                         {
1498                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1499                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1500
1501                                                                 if(trace_startsolid)
1502                                                                 {
1503                                                                         // how much do we need to back off?
1504                                                                         safe = 1;
1505                                                                         unsafe = 0;
1506                                                                         for(;;)
1507                                                                         {
1508                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1509                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1510                                                                                 if(trace_startsolid)
1511                                                                                 {
1512                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1513                                                                                                 break;
1514                                                                                         unsafe = (safe + unsafe) * 0.5;
1515                                                                                 }
1516                                                                                 else
1517                                                                                 {
1518                                                                                         if((safe + unsafe) * 0.5 == safe)
1519                                                                                                 break;
1520                                                                                         safe = (safe + unsafe) * 0.5;
1521                                                                                 }
1522                                                                         }
1523
1524                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1525                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1526
1527                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1528                                                                         if(trace_startsolid)
1529                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1530                                                                         else
1531                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1532                                                                         break;
1533                                                                 }
1534
1535                                                                 q0 = p;
1536                                                                 dq = 0;
1537                                                                 dqf = 1;
1538                                                                 for(;;)
1539                                                                 {
1540                                                                         q = p + normalize(end - p) * (dq + dqf);
1541                                                                         if(q == q0)
1542                                                                                 break;
1543                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1544                                                                         if(trace_startsolid)
1545                                                                                 error("THIS ONE cannot happen");
1546                                                                         if(trace_fraction > 0)
1547                                                                                 dq += dqf * trace_fraction;
1548                                                                         dqf *= 0.5;
1549                                                                         q0 = q;
1550                                                                 }
1551                                                                 if(dq > 0)
1552                                                                 {
1553                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1554                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1555                                                                         break;
1556                                                                 }
1557                                                         }
1558                                                 }
1559                                         }
1560                                         return;
1561                                 }
1562
1563                                 case "debug2":
1564                                 {
1565                                         e = nextent(world);
1566                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1567                                         vv = trace_endpos;
1568                                         if(trace_fraction == 1)
1569                                         {
1570                                                 print("not above ground, aborting\n");
1571                                                 return;
1572                                         }
1573                                         f = 0;
1574                                         for(i = 0; i < 100000; ++i)
1575                                         {
1576                                                 dv = randomvec();
1577                                                 if(dv_z > 0)
1578                                                         dv = -1 * dv;
1579                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1580                                                 if(trace_startsolid)
1581                                                         print("bug 1\n");
1582                                                 if(trace_fraction == 1)
1583                                                 if(dv_z < f)
1584                                                 {
1585                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1586                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1587                                                         f = dv_z;
1588                                                 }
1589                                         }
1590                                         print("highest possible dist: ", ftos(f), "\n");
1591                                         return;
1592                                 }
1593
1594                                 case "walk":
1595                                 {
1596                                         if(argc == 4)
1597                                         {
1598                                                 e = nextent(world);
1599                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1600                                                         print("can walk\n");
1601                                                 else
1602                                                         print("cannot walk\n");
1603                                                 return;
1604                                         }
1605                                 }
1606
1607                                 case "showline":
1608                                 {
1609                                         if(argc == 4)
1610                                         {
1611                                                 vv = stov(argv(2));
1612                                                 dv = stov(argv(3));
1613                                                 traceline(vv, dv, MOVE_NORMAL, world);
1614                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1615                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1616                                                 return;
1617                                         }
1618                                 }
1619
1620                                 // no default case, just go straight to invalid
1621                         }
1622                 }
1623
1624                 default:
1625                         print("Incorrect parameters for ^2trace^7\n");
1626                 case CMD_REQUEST_USAGE:
1627                 {
1628                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1629                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1630                         print("See also: ^2bbox, gettaginfo^7\n");
1631                         return;
1632                 }
1633         }
1634 }
1635
1636 void GameCommand_unlockteams(float request)
1637 {
1638         switch(request)
1639         {
1640                 case CMD_REQUEST_COMMAND:
1641                 {
1642                         if(teamplay)
1643                         {
1644                                 lockteams = 0;
1645                                 bprint("^1The teams are now unlocked.\n");
1646                         }
1647                         else
1648                         {
1649                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1650                         }
1651                         return;
1652                 }
1653
1654                 default:
1655                 case CMD_REQUEST_USAGE:
1656                 {
1657                         print("\nUsage:^3 sv_cmd unlockteams\n");
1658                         print("  No arguments required.\n");
1659                         print("See also: ^2lockteams^7\n");
1660                         return;
1661                 }
1662         }
1663 }
1664
1665 void GameCommand_warp(float request, float argc)
1666 {
1667         switch (request)
1668         {
1669                 case CMD_REQUEST_COMMAND:
1670                 {
1671                         if(autocvar_g_campaign)
1672                         {
1673                                 if(argc >= 2)
1674                                 {
1675                                         CampaignLevelWarp(stof(argv(1)));
1676                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1677                                 }
1678                                 else
1679                                 {
1680                                         CampaignLevelWarp(-1);
1681                                         print("Successfully warped to next campaign level.\n");
1682                                 }
1683                         }
1684                         else
1685                                 print("Not in campaign, can't level warp\n");
1686                         return;
1687                 }
1688
1689                 default:
1690                 case CMD_REQUEST_USAGE:
1691                 {
1692                         print("\nUsage:^3 sv_cmd warp [level]\n");
1693                         print("  'level' is the level to change campaign mode to.\n");
1694                         print("  if 'level' is not provided it will change to the next level.\n");
1695                         return;
1696                 }
1697         }
1698 }
1699
1700 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1701 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1702 void GameCommand_(float request)
1703 {
1704         switch(request)
1705         {
1706                 case CMD_REQUEST_COMMAND:
1707                 {
1708
1709                         return;
1710                 }
1711
1712                 default:
1713                 case CMD_REQUEST_USAGE:
1714                 {
1715                         print("\nUsage:^3 sv_cmd \n");
1716                         print("  No arguments required.\n");
1717                         return;
1718                 }
1719         }
1720 }
1721 */
1722
1723
1724 // ==================================
1725 //  Macro system for server commands
1726 // ==================================
1727
1728 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1729 #define SERVER_COMMANDS(request,arguments,command) \
1730         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1731         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1732         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1733         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1734         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1735         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1736         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1737         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1738         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1739         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1740         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1741         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1742         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1743         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1744         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1745         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1746         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1747         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1748         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1749         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1750         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1751         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1752         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1753         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1754         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1755         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1756         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1757         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1758         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1759         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1760         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1761         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1762         /* nothing */
1763
1764 void GameCommand_macro_help()
1765 {
1766         #define SERVER_COMMAND(name,function,description) \
1767                 { print("  ^2", name, "^7: ", description, "\n"); }
1768
1769         SERVER_COMMANDS(0, 0, "")
1770         #undef SERVER_COMMAND
1771
1772         return;
1773 }
1774
1775 float GameCommand_macro_command(float argc, string command)
1776 {
1777         #define SERVER_COMMAND(name,function,description) \
1778                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1779
1780         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1781         #undef SERVER_COMMAND
1782
1783         return FALSE;
1784 }
1785
1786 float GameCommand_macro_usage(float argc)
1787 {
1788         #define SERVER_COMMAND(name,function,description) \
1789                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1790
1791         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1792         #undef SERVER_COMMAND
1793
1794         return FALSE;
1795 }
1796
1797 void GameCommand_macro_write_aliases(float fh)
1798 {
1799         #define SERVER_COMMAND(name,function,description) \
1800                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1801
1802         SERVER_COMMANDS(0, 0, "")
1803         #undef SERVER_COMMAND
1804
1805         return;
1806 }
1807
1808
1809 // =========================================
1810 //  Main Function Called By Engine (sv_cmd)
1811 // =========================================
1812 // If this function exists, game code handles gamecommand instead of the engine code.
1813
1814 void GameCommand(string command)
1815 {
1816         float argc = tokenize_console(command);
1817
1818         // Guide for working with argc arguments by example:
1819         // argc:   1    - 2      - 3     - 4
1820         // argv:   0    - 1      - 2     - 3
1821         // cmd     vote - master - login - password
1822
1823         if(strtolower(argv(0)) == "help")
1824         {
1825                 if(argc == 1)
1826                 {
1827                         print("\nServer console commands:\n");
1828                         GameCommand_macro_help();
1829
1830                         print("\nBanning commands:\n");
1831                         BanCommand_macro_help();
1832
1833                         print("\nCommon networked commands:\n");
1834                         CommonCommand_macro_help(world);
1835
1836                         print("\nGeneric commands shared by all programs:\n");
1837                         GenericCommand_macro_help();
1838
1839                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1840                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1841
1842                         return;
1843                 }
1844                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1845                 {
1846                         return;
1847                 }
1848                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1849                 {
1850                         return;
1851                 }
1852                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1853                 {
1854                         return;
1855                 }
1856                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1857                 {
1858                         return;
1859                 }
1860         }
1861         else if(BanCommand(command))
1862         {
1863                 return; // handled by server/command/ipban.qc
1864         }
1865         else if(CommonCommand_macro_command(argc, world, command))
1866         {
1867                 return; // handled by server/command/common.qc
1868         }
1869         else if(GenericCommand(command))
1870         {
1871                 return; // handled by common/command/generic.qc
1872         }
1873         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1874         {
1875                 return; // handled by one of the above GameCommand_* functions
1876         }
1877
1878         // nothing above caught the command, must be invalid
1879         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1880
1881         return;
1882 }