qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if not(accepted > 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_butcher(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         if(g_td) { print("This command doesn't work in Tower Defense.\n"); return; }
 149                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 150
 151             float removed_count = 0;
 152                         entity montokill, head;
 153
 154             FOR_EACH_MONSTER(montokill)
 155             {
 156                                 WaypointSprite_Kill(montokill.sprite);
 157
 158                                 if(montokill.weaponentity)
 159                                         remove(montokill.weaponentity);
 160
 161                                 if(montokill.iceblock)
 162                                         remove(montokill.iceblock);
 163
 164                 remove(montokill);
 165                 removed_count += 1;
 166             }
 167
 168                         FOR_EACH_PLAYER(head)
 169                                 head.monstercount = 0;
 170
 171                         monsters_total = 0; // reset stats?
 172                         monsters_killed = 0;
 173
 174                         totalspawned = 0;
 175
 176                         if(removed_count <= 0)
 177                                 print("No monsters to kill\n");
 178                         else
 179                                 print(strcat("Killed ", ftos(removed_count), " monster", ((removed_count == 1) ? "\n" : "s\n")));
 180
 181                         return; // never fall through to usage
 182                 }
 183
 184                 default:
 185                 case CMD_REQUEST_USAGE:
 186                 {
 187                         print("\nUsage:^3 sv_cmd butcher\n");
 188                         print("  No arguments required.\n");
 189                         return;
 190                 }
 191         }
 192 }
 193
 194 void GameCommand_allready(float request)
 195 {
 196         switch(request)
 197         {
 198                 case CMD_REQUEST_COMMAND:
 199                 {
 200                         ReadyRestart();
 201                         return;
 202                 }
 203
 204                 default:
 205                 case CMD_REQUEST_USAGE:
 206                 {
 207                         print("\nUsage:^3 sv_cmd allready\n");
 208                         print("  No arguments required.\n");
 209                         return;
 210                 }
 211         }
 212 }
 213
 214 void GameCommand_allspec(float request, float argc)
 215 {
 216         switch(request)
 217         {
 218                 case CMD_REQUEST_COMMAND:
 219                 {
 220                         entity client;
 221                         string reason = argv(1);
 222                         float i = 0;
 223
 224                         FOR_EACH_REALPLAYER(client)
 225                         {
 226                                 self = client;
 227                                 PutObserverInServer();
 228                                 ++i;
 229                         }
 230                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 231                         else { print("No players found to spectate.\n"); }
 232                         return;
 233                 }
 234
 235                 default:
 236                 case CMD_REQUEST_USAGE:
 237                 {
 238                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 239                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 240                         print("See also: ^2moveplayer, shuffleteams^7\n");
 241                         return;
 242                 }
 243         }
 244 }
 245
 246 void GameCommand_anticheat(float request, float argc)
 247 {
 248         switch(request)
 249         {
 250                 case CMD_REQUEST_COMMAND:
 251                 {
 252                         entity client = GetIndexedEntity(argc, 1);
 253                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 254
 255                         if(accepted > 0)
 256                         {
 257                                 self = client;
 258                                 anticheat_report();
 259                                 return;
 260                         }
 261                         else
 262                         {
 263                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 264                         }
 265                 }
 266
 267                 default:
 268                         print("Incorrect parameters for ^2anticheat^7\n");
 269                 case CMD_REQUEST_USAGE:
 270                 {
 271                         print("\nUsage:^3 sv_cmd anticheat client\n");
 272                         print("  'client' is the entity number or name of the player.\n");
 273                         return;
 274                 }
 275         }
 276 }
 277
 278 void GameCommand_bbox(float request)
 279 {
 280         switch(request)
 281         {
 282                 case CMD_REQUEST_COMMAND:
 283                 {
 284                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 285                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 286                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 287                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 288                         print("Solid bounding box size:");
 289
 290                         tracebox('1 0 0' * world.absmin_x,
 291                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 292                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 293                                                         '1 0 0' * world.absmax_x,
 294                                         MOVE_WORLDONLY,
 295                                         world);
 296                         if(trace_startsolid)
 297                                 print(" ", ftos(world.absmin_x));
 298                         else
 299                                 print(" ", ftos(trace_endpos_x));
 300
 301                         tracebox('0 1 0' * world.absmin_y,
 302                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 303                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 304                                                         '0 1 0' * world.absmax_y,
 305                                         MOVE_WORLDONLY,
 306                                         world);
 307                         if(trace_startsolid)
 308                                 print(" ", ftos(world.absmin_y));
 309                         else
 310                                 print(" ", ftos(trace_endpos_y));
 311
 312                         tracebox('0 0 1' * world.absmin_z,
 313                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 314                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 315                                                         '0 0 1' * world.absmax_z,
 316                                         MOVE_WORLDONLY,
 317                                         world);
 318                         if(trace_startsolid)
 319                                 print(" ", ftos(world.absmin_z));
 320                         else
 321                                 print(" ", ftos(trace_endpos_z));
 322
 323                         tracebox('1 0 0' * world.absmax_x,
 324                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 325                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 326                                                         '1 0 0' * world.absmin_x,
 327                                         MOVE_WORLDONLY,
 328                                         world);
 329                         if(trace_startsolid)
 330                                 print(" ", ftos(world.absmax_x));
 331                         else
 332                                 print(" ", ftos(trace_endpos_x));
 333
 334                         tracebox('0 1 0' * world.absmax_y,
 335                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 336                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 337                                                         '0 1 0' * world.absmin_y,
 338                                         MOVE_WORLDONLY,
 339                                         world);
 340                         if(trace_startsolid)
 341                                 print(" ", ftos(world.absmax_y));
 342                         else
 343                                 print(" ", ftos(trace_endpos_y));
 344
 345                         tracebox('0 0 1' * world.absmax_z,
 346                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 347                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 348                                                         '0 0 1' * world.absmin_z,
 349                                         MOVE_WORLDONLY,
 350                                         world);
 351                         if(trace_startsolid)
 352                                 print(" ", ftos(world.absmax_z));
 353                         else
 354                                 print(" ", ftos(trace_endpos_z));
 355
 356                         print("\n");
 357                         return;
 358                 }
 359
 360                 default:
 361                 case CMD_REQUEST_USAGE:
 362                 {
 363                         print("\nUsage:^3 sv_cmd bbox\n");
 364                         print("  No arguments required.\n");
 365                         print("See also: ^2gettaginfo, trace^7\n");
 366                         return;
 367                 }
 368         }
 369 }
 370
 371 void GameCommand_bot_cmd(float request, float argc, string command)
 372 {
 373         switch(request)
 374         {
 375                 case CMD_REQUEST_COMMAND:
 376                 {
 377                         entity bot;
 378
 379                         if(argv(1) == "reset")
 380                         {
 381                                 bot_resetqueues();
 382                                 return;
 383                         }
 384                         else if(argv(1) == "setbots")
 385                         {
 386                                 cvar_settemp("bot_vs_human", "0");
 387                                 cvar_settemp("minplayers", "0");
 388                                 cvar_settemp("bot_number", "0");
 389                                 bot_fixcount();
 390                                 cvar_settemp("bot_number", argv(2));
 391                                 if(!bot_fixcount())
 392                                         print("Sorry, could not set requested bot count\n");
 393                                 return;
 394                         }
 395                         else if(argv(1) == "load" && argc == 3)
 396                         {
 397                                 float fh, i;
 398                                 string s;
 399                                 fh = fopen(argv(2), FILE_READ);
 400                                 if(fh < 0)
 401                                 {
 402                                         print("cannot open the file\n");
 403                                         return;
 404                                 }
 405
 406                                 i = 0;
 407                                 while((s = fgets(fh)))
 408                                 {
 409                                         argc = tokenize_console(s);
 410
 411                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 412                                         {
 413                                                 if(argv(2) == "reset")
 414                                                 {
 415                                                         bot_resetqueues();
 416                                                 }
 417                                                 else if(argv(2) == "setbots")
 418                                                 {
 419                                                         cvar_settemp("bot_vs_human", "0");
 420                                                         cvar_settemp("minplayers", "0");
 421                                                         cvar_settemp("bot_number", "0");
 422                                                         bot_fixcount();
 423                                                         cvar_settemp("bot_number", argv(3));
 424                                                         if(!bot_fixcount())
 425                                                                 print("Sorry, could not set requested bot count\n");
 426                                                 }
 427                                                 else
 428                                                 {
 429                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 430                                                         bot = find_bot_by_number(stof(argv(2)));
 431                                                         if(bot == world)
 432                                                                 bot = find_bot_by_name(argv(2));
 433                                                         if(bot)
 434                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 435                                                 }
 436                                         }
 437                                         else
 438                                                 localcmd(strcat(s, "\n"));
 439
 440                                         ++i;
 441                                 }
 442                                 print(ftos(i), " commands read\n");
 443                                 fclose(fh);
 444                                 return;
 445                         }
 446                         else if(argv(1) == "help")
 447                         {
 448                                 if(argv(2))
 449                                         bot_cmdhelp(argv(2));
 450                                 else
 451                                         bot_list_commands();
 452                                 return;
 453                         }
 454                         else if(argc >= 3) // this comes last
 455                         {
 456                                 bot = find_bot_by_number(stof(argv(1)));
 457                                 if(bot == world)
 458                                         bot = find_bot_by_name(argv(1));
 459                                 if(bot)
 460                                 {
 461                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 462                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 463                                         return;
 464                                 }
 465                                 else
 466                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 467                         }
 468                 }
 469
 470                 default:
 471                         print("Incorrect parameters for ^2bot_cmd^7\n");
 472                 case CMD_REQUEST_USAGE:
 473                 {
 474                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 475                         print("  'client' can be either the name or entity id of the bot\n");
 476                         print("  For full list of commands, see bot_cmd help [command].\n");
 477                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 478                         print("          sv_cmd bot_cmd client presskey jump\n");
 479                         return;
 480                 }
 481         }
 482 }
 483
 484 void GameCommand_cointoss(float request, float argc)
 485 {
 486         switch(request)
 487         {
 488                 case CMD_REQUEST_COMMAND:
 489                 {
 490                         entity client;
 491                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 492                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 493                         string choice = ((random() > 0.5) ? result1 : result2);
 494
 495                         FOR_EACH_CLIENT(client)
 496                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 497                         bprint(strcat("^3Throwing coin... Result: ", choice));
 498                         return;
 499                 }
 500
 501                 default:
 502                 case CMD_REQUEST_USAGE:
 503                 {
 504                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 505                         print("  Where 'result1' and 'result2' are user created options.\n");
 506                         return;
 507                 }
 508         }
 509 }
 510
 511 void GameCommand_database(float request, float argc)
 512 {
 513         switch(request)
 514         {
 515                 case CMD_REQUEST_COMMAND:
 516                 {
 517                         if(argc == 3)
 518                         {
 519                                 if(argv(1) == "save")
 520                                 {
 521                                         db_save(ServerProgsDB, argv(2));
 522                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 523                                         return;
 524                                 }
 525                                 else if(argv(1) == "dump")
 526                                 {
 527                                         db_dump(ServerProgsDB, argv(2));
 528                                         print("DB dumped.\n"); // wtf does this do?
 529                                         return;
 530                                 }
 531                                 else if(argv(1) == "load")
 532                                 {
 533                                         db_close(ServerProgsDB);
 534                                         ServerProgsDB = db_load(argv(2));
 535                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 536                                         return;
 537                                 }
 538                         }
 539                 }
 540
 541                 default:
 542                         print("Incorrect parameters for ^2database^7\n");
 543                 case CMD_REQUEST_USAGE:
 544                 {
 545                         print("\nUsage:^3 sv_cmd database action filename\n");
 546                         print("  Where 'action' is the command to complete,\n");
 547                         print("  and 'filename' is what it acts upon.\n");
 548                         print("  Full list of commands here: \"save, dump, load.\"\n");
 549                         return;
 550                 }
 551         }
 552 }
 553
 554 void GameCommand_defer_clear(float request, float argc)
 555 {
 556         switch(request)
 557         {
 558                 case CMD_REQUEST_COMMAND:
 559                 {
 560                         entity client;
 561                         float accepted;
 562
 563                         if(argc >= 2)
 564                         {
 565                                 client = GetIndexedEntity(argc, 1);
 566                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 567
 568                                 if(accepted > 0)
 569                                 {
 570                                         stuffcmd(client, "defer clear\n");
 571                                         print("defer clear stuffed to ", client.netname, "\n");
 572                                 }
 573                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 574
 575                                 return;
 576                         }
 577                 }
 578
 579                 default:
 580                         print("Incorrect parameters for ^2defer_clear^7\n");
 581                 case CMD_REQUEST_USAGE:
 582                 {
 583                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 584                         print("  'client' is the entity number or name of the player.\n");
 585                         print("See also: ^2defer_clear_all^7\n");
 586                         return;
 587                 }
 588         }
 589 }
 590
 591 void GameCommand_defer_clear_all(float request)
 592 {
 593         switch(request)
 594         {
 595                 case CMD_REQUEST_COMMAND:
 596                 {
 597                         entity client;
 598                         float i = 0;
 599                         float argc;
 600
 601                         FOR_EACH_CLIENT(client)
 602                         {
 603                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 604                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 605                                 ++i;
 606                         }
 607                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 608                         return;
 609                 }
 610
 611                 default:
 612                 case CMD_REQUEST_USAGE:
 613                 {
 614                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 615                         print("  No arguments required.\n");
 616                         print("See also: ^2defer_clear^7\n");
 617                         return;
 618                 }
 619         }
 620 }
 621
 622 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 623 {
 624         switch(request)
 625         {
 626                 case CMD_REQUEST_COMMAND:
 627                 {
 628                         if(argv(1))
 629                         {
 630                                 if(argv(2))
 631                                         race_deleteTime(argv(2), stof(argv(1)));
 632                                 else
 633                                         race_deleteTime(GetMapname(), stof(argv(1)));
 634                                 return;
 635                         }
 636                 }
 637
 638                 default:
 639                         print("Incorrect parameters for ^2delrec^7\n");
 640                 case CMD_REQUEST_USAGE:
 641                 {
 642                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 643                         print("  'ranking' is which ranking level to clear up to, \n");
 644                         print("  it will clear all records up to nth place.\n");
 645                         print("  if 'map' is not provided it will use current map.\n");
 646                         return;
 647                 }
 648         }
 649 }
 650
 651 void GameCommand_effectindexdump(float request)
 652 {
 653         switch(request)
 654         {
 655                 case CMD_REQUEST_COMMAND:
 656                 {
 657                         float fh, d;
 658                         string s;
 659
 660                         d = db_create();
 661                         print("begin of effects list\n");
 662                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 663                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 664                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 665                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 666                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 667                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 668                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 669                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 670                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 671                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 672                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 673                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 674                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 675                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 676                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 677                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 678                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 679                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 680                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 681                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 682                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 683                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 684                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 685                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 686                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 687                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 688                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 689                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 690                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 691                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 692                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 693                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 694                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 695                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 696                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 697                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 698
 699                         fh = fopen("effectinfo.txt", FILE_READ);
 700                         while((s = fgets(fh)))
 701                         {
 702                                 tokenize_console(s);
 703                                 if(argv(0) == "effect")
 704                                 {
 705                                         if(db_get(d, argv(1)) != "1")
 706                                         {
 707                                                 if(particleeffectnum(argv(1)) >= 0)
 708                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 709                                                 db_put(d, argv(1), "1");
 710                                         }
 711                                 }
 712                         }
 713                         print("end of effects list\n");
 714
 715                         db_close(d);
 716                         return;
 717                 }
 718
 719                 default:
 720                 case CMD_REQUEST_USAGE:
 721                 {
 722                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 723                         print("  No arguments required.\n");
 724                         return;
 725                 }
 726         }
 727 }
 728
 729 void GameCommand_extendmatchtime(float request)
 730 {
 731         switch(request)
 732         {
 733                 case CMD_REQUEST_COMMAND:
 734                 {
 735                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 736                         return;
 737                 }
 738
 739                 default:
 740                 case CMD_REQUEST_USAGE:
 741                 {
 742                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 743                         print("  No arguments required.\n");
 744                         print("See also: ^2reducematchtime^7\n");
 745                         return;
 746                 }
 747         }
 748 }
 749
 750 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 751 {
 752         switch(request)
 753         {
 754                 case CMD_REQUEST_COMMAND:
 755                 {
 756                         entity client;
 757
 758                         for(client = world; (client = find(client, classname, argv(1))); )
 759                                 print(etos(client), "\n");
 760
 761                         return;
 762                 }
 763
 764                 default:
 765                         print("Incorrect parameters for ^2find^7\n");
 766                 case CMD_REQUEST_USAGE:
 767                 {
 768                         print("\nUsage:^3 sv_cmd find classname\n");
 769                         print("  Where 'classname' is the classname to search for.\n");
 770                         return;
 771                 }
 772         }
 773 }
 774
 775 void GameCommand_gametype(float request, float argc)
 776 {
 777         switch(request)
 778         {
 779                 case CMD_REQUEST_COMMAND:
 780                 {
 781                         if(argv(1) != "")
 782                         {
 783                                 string s = argv(1);
 784                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 785
 786                                 if(t)
 787                                 {
 788                                         MapInfo_SwitchGameType(t);
 789                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 790                                         if(MapInfo_count > 0)
 791                                                 bprint("Game type successfully switched to ", s, "\n");
 792                                         else
 793                                         {
 794                                                 bprint("Cannot use this game type: no map for it found\n");
 795                                                 MapInfo_SwitchGameType(tsave);
 796                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 797                                         }
 798                                 }
 799                                 else
 800                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 801
 802                                 return;
 803                         }
 804                 }
 805
 806                 default:
 807                         print("Incorrect parameters for ^2gametype^7\n");
 808                 case CMD_REQUEST_USAGE:
 809                 {
 810                         print("\nUsage:^3 sv_cmd gametype mode\n");
 811                         print("  Where 'mode' is the gametype mode to switch to.\n");
 812                         print("See also: ^2gotomap^7\n");
 813                         return;
 814                 }
 815         }
 816 }
 817
 818 void GameCommand_gettaginfo(float request, float argc)
 819 {
 820         switch(request)
 821         {
 822                 case CMD_REQUEST_COMMAND:
 823                 {
 824                         entity tmp_entity;
 825                         float i;
 826                         vector v;
 827
 828                         if(argc >= 4)
 829                         {
 830                                 tmp_entity = spawn();
 831                                 if(argv(1) == "w")
 832                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 833                                 else
 834                                 {
 835                                         precache_model(argv(1));
 836                                         setmodel(tmp_entity, argv(1));
 837                                 }
 838                                 tmp_entity.frame = stof(argv(2));
 839                                 if(substring(argv(3), 0, 1) == "#")
 840                                         i = stof(substring(argv(3), 1, -1));
 841                                 else
 842                                         i = gettagindex(tmp_entity, argv(3));
 843                                 if(i)
 844                                 {
 845                                         v = gettaginfo(tmp_entity, i);
 846                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 847                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 848                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 849                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 850                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 851                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 852                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 853                                         if(argc >= 6)
 854                                         {
 855                                                 v_y = -v_y;
 856                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 857                                         }
 858                                 }
 859                                 else
 860                                         print("bone not found\n");
 861
 862                                 remove(tmp_entity);
 863                                 return;
 864                         }
 865                 }
 866
 867                 default:
 868                         print("Incorrect parameters for ^2gettaginfo^7\n");
 869                 case CMD_REQUEST_USAGE:
 870                 {
 871                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 872                         print("See also: ^2bbox, trace^7\n");
 873                         return;
 874                 }
 875         }
 876 }
 877
 878 void GameCommand_animbench(float request, float argc)
 879 {
 880         switch(request)
 881         {
 882                 case CMD_REQUEST_COMMAND:
 883                 {
 884                         entity tmp_entity;
 885
 886                         if(argc >= 4)
 887                         {
 888                                 tmp_entity = spawn();
 889                                 if(argv(1) == "w")
 890                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 891                                 else
 892                                 {
 893                                         precache_model(argv(1));
 894                                         setmodel(tmp_entity, argv(1));
 895                                 }
 896                                 float f1 = stof(argv(2));
 897                                 float f2 = stof(argv(3));
 898                                 float t0;
 899                                 float t1 = 0;
 900                                 float t2 = 0;
 901                                 float n = 0;
 902
 903                                 while(t1 + t2 < 1)
 904                                 {
 905                                         tmp_entity.frame = f1;
 906                                         t0 = gettime(GETTIME_HIRES);
 907                                         getsurfacepoint(tmp_entity, 0, 0);
 908                                         t1 += gettime(GETTIME_HIRES) - t0;
 909                                         tmp_entity.frame = f2;
 910                                         t0 = gettime(GETTIME_HIRES);
 911                                         getsurfacepoint(tmp_entity, 0, 0);
 912                                         t2 += gettime(GETTIME_HIRES) - t0;
 913                                         n += 1;
 914                                 }
 915                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 916                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 917
 918                                 remove(tmp_entity);
 919                                 return;
 920                         }
 921                 }
 922
 923                 default:
 924                         print("Incorrect parameters for ^2gettaginfo^7\n");
 925                 case CMD_REQUEST_USAGE:
 926                 {
 927                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 928                         print("See also: ^2bbox, trace^7\n");
 929                         return;
 930                 }
 931         }
 932 }
 933
 934 void GameCommand_gotomap(float request, float argc)
 935 {
 936         switch(request)
 937         {
 938                 case CMD_REQUEST_COMMAND:
 939                 {
 940                         if(argv(1))
 941                         {
 942                                 print(GotoMap(argv(1)), "\n");
 943                                 return;
 944                         }
 945                 }
 946
 947                 default:
 948                         print("Incorrect parameters for ^2gotomap^7\n");
 949                 case CMD_REQUEST_USAGE:
 950                 {
 951                         print("\nUsage:^3 sv_cmd gotomap map\n");
 952                         print("  Where 'map' is the *.bsp file to change to.\n");
 953                         print("See also: ^2gametype^7\n");
 954                         return;
 955                 }
 956         }
 957 }
 958
 959 void GameCommand_lockteams(float request)
 960 {
 961         switch(request)
 962         {
 963                 case CMD_REQUEST_COMMAND:
 964                 {
 965                         if(teamplay)
 966                         {
 967                                 lockteams = 1;
 968                                 bprint("^1The teams are now locked.\n");
 969                         }
 970                         else
 971                         {
 972                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 973                         }
 974                         return;
 975                 }
 976
 977                 default:
 978                 case CMD_REQUEST_USAGE:
 979                 {
 980                         print("\nUsage:^3 sv_cmd lockteams\n");
 981                         print("  No arguments required.\n");
 982                         print("See also: ^2unlockteams^7\n");
 983                         return;
 984                 }
 985         }
 986 }
 987
 988 void GameCommand_make_mapinfo(float request)
 989 {
 990         switch(request)
 991         {
 992                 case CMD_REQUEST_COMMAND:
 993                 {
 994                         entity tmp_entity;
 995
 996                         tmp_entity = spawn();
 997                         tmp_entity.classname = "make_mapinfo";
 998                         tmp_entity.think = make_mapinfo_Think;
 999                         tmp_entity.nextthink = time;
1000                         MapInfo_Enumerate();
1001                         return;
1002                 }
1003
1004                 default:
1005                 case CMD_REQUEST_USAGE:
1006                 {
1007                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1008                         print("  No arguments required.\n");
1009                         print("See also: ^2radarmap^7\n");
1010                         return;
1011                 }
1012         }
1013 }
1014
1015 void GameCommand_moveplayer(float request, float argc)
1016 {
1017         switch(request)
1018         {
1019                 case CMD_REQUEST_COMMAND:
1020                 {
1021                         float accepted;
1022                         entity client;
1023
1024                         string targets = strreplace(",", " ", argv(1));
1025                         string original_targets = strreplace(" ", ", ", targets);
1026                         string destination = argv(2);
1027
1028                         string successful, t;
1029                         successful = string_null;
1030
1031                         // lets see if the target(s) even actually exist.
1032                         if((targets) && (destination))
1033                         {
1034                                 for(;targets;)
1035                                 {
1036                                         t = car(targets); targets = cdr(targets);
1037
1038                                         // Check to see if the player is a valid target
1039                                         client = GetFilteredEntity(t);
1040                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
1041
1042                                         if not(accepted > 0)
1043                                         {
1044                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1045                                                 continue;
1046                                         }
1047
1048                                         // Where are we putting this player?
1049                                         if(destination == "spec" || destination == "spectator")
1050                                         {
1051                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1052                                                 {
1053                                                         self = client;
1054                                                         PutObserverInServer();
1055
1056                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1057                                                 }
1058                                                 else
1059                                                 {
1060                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1061                                                 }
1062                                                 continue;
1063                                         }
1064                                         else
1065                                         {
1066                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1067                                                 {
1068                                                         if(teamplay)
1069                                                         {
1070                                                                 // set up
1071                                                                 float team_id;
1072                                                                 float save = client.team_forced;
1073                                                                 client.team_forced = 0;
1074
1075                                                                 // find the team to move the player to
1076                                                                 team_id = Team_ColorToTeam(destination);
1077                                                                 if(team_id == client.team) // already on the destination team
1078                                                                 {
1079                                                                         // keep the forcing undone
1080                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1081                                                                         continue;
1082                                                                 }
1083                                                                 else if(team_id == 0)  // auto team
1084                                                                 {
1085                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1086                                                                 }
1087                                                                 else
1088                                                                 {
1089                                                                         CheckAllowedTeams(client);
1090                                                                 }
1091                                                                 client.team_forced = save;
1092
1093                                                                 // Check to see if the destination team is even available
1094                                                                 switch(team_id)
1095                                                                 {
1096                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1097                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1098                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1099                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1100
1101                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1102                                                                 }
1103
1104                                                                 // If so, lets continue and finally move the player
1105                                                                 client.team_forced = 0;
1106                                                                 MoveToTeam(client, team_id, 6);
1107                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1108                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1109                                                                 continue;
1110                                                         }
1111                                                         else
1112                                                         {
1113                                                                 print("Can't change teams when currently not playing a team game.\n");
1114                                                                 return;
1115                                                         }
1116                                                 }
1117                                                 else
1118                                                 {
1119                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1120                                                         return;
1121                                                 }
1122                                         }
1123                                 }
1124
1125                                 if(successful)
1126                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1127                                 else
1128                                         print("No players given (", original_targets, ") are able to move.\n");
1129
1130                                 return; // still correct parameters so return to avoid usage print
1131                         }
1132                 }
1133
1134                 default:
1135                         print("Incorrect parameters for ^2moveplayer^7\n");
1136                 case CMD_REQUEST_USAGE:
1137                 {
1138                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1139                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1140                         print("  'destination' is what to send the player to, be it team or spectating\n");
1141                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1142                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1143                         print("          sv_cmd moveplayer 2 spec \n");
1144                         print("See also: ^2allspec, shuffleteams^7\n");
1145                         return;
1146                 }
1147         }
1148 }
1149
1150 void GameCommand_nospectators(float request)
1151 {
1152         switch(request)
1153         {
1154                 case CMD_REQUEST_COMMAND:
1155                 {
1156                         blockSpectators = 1;
1157                         entity plr;
1158                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1159                         {
1160                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1161                                 {
1162                                         plr.spectatortime = time;
1163                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1164                                 }
1165                         }
1166                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1167                         return;
1168                 }
1169
1170                 default:
1171                 case CMD_REQUEST_USAGE:
1172                 {
1173                         print("\nUsage:^3 sv_cmd nospectators\n");
1174                         print("  No arguments required.\n");
1175                         return;
1176                 }
1177         }
1178 }
1179
1180 void GameCommand_playerdemo(float request, float argc)
1181 {
1182         switch(request)
1183         {
1184                 case CMD_REQUEST_COMMAND:
1185                 {
1186                         if(argv(2) && argv(3))
1187                         {
1188                                 entity client;
1189                                 float i, n, accepted;
1190
1191                                 switch(argv(1))
1192                                 {
1193                                         case "read":
1194                                         {
1195                                                 client = GetIndexedEntity(argc, 2);
1196                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1197
1198                                                 if not(accepted > 0)
1199                                                 {
1200                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1201                                                         return;
1202                                                 }
1203
1204                                                 self = client;
1205                                                 playerdemo_open_read(argv(next_token));
1206                                                 return;
1207                                         }
1208
1209                                         case "write":
1210                                         {
1211                                                 client = GetIndexedEntity(argc, 2);
1212                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1213
1214                                                 if not(accepted > 0)
1215                                                 {
1216                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1217                                                         return;
1218                                                 }
1219
1220                                                 self = client;
1221                                                 playerdemo_open_write(argv(next_token));
1222                                                 return;
1223                                         }
1224
1225                                         case "auto_read_and_write":
1226                                         {
1227                                                 n = GetFilteredNumber(argv(3));
1228                                                 cvar_set("bot_number", ftos(n));
1229
1230                                                 localcmd("wait; wait; wait\n");
1231                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1232
1233                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1234                                                 return;
1235                                         }
1236
1237                                         case "auto_read":
1238                                         {
1239                                                 n = GetFilteredNumber(argv(3));
1240                                                 cvar_set("bot_number", ftos(n));
1241
1242                                                 localcmd("wait; wait; wait\n");
1243                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1244                                                 return;
1245                                         }
1246                                 }
1247                         }
1248                 }
1249
1250                 default:
1251                         print("Incorrect parameters for ^2playerdemo^7\n");
1252                 case CMD_REQUEST_USAGE:
1253                 {
1254                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1255                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1256                         return;
1257                 }
1258         }
1259 }
1260
1261 void GameCommand_printstats(float request)
1262 {
1263         switch(request)
1264         {
1265                 case CMD_REQUEST_COMMAND:
1266                 {
1267                         DumpStats(FALSE);
1268                         print("stats dumped.\n");
1269                         return;
1270                 }
1271
1272                 default:
1273                 case CMD_REQUEST_USAGE:
1274                 {
1275                         print("\nUsage:^3 sv_cmd printstats\n");
1276                         print("  No arguments required.\n");
1277                         return;
1278                 }
1279         }
1280 }
1281
1282 void GameCommand_radarmap(float request, float argc)
1283 {
1284         switch(request)
1285         {
1286                 case CMD_REQUEST_COMMAND:
1287                 {
1288                         if(RadarMap_Make(argc))
1289                                 return;
1290                 }
1291
1292                 default:
1293                         print("Incorrect parameters for ^2radarmap^7\n");
1294                 case CMD_REQUEST_USAGE:
1295                 {
1296                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1297                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1298                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1299                         print("See also: ^2make_mapinfo^7\n");
1300                         return;
1301                 }
1302         }
1303 }
1304
1305 void GameCommand_reducematchtime(float request)
1306 {
1307         switch(request)
1308         {
1309                 case CMD_REQUEST_COMMAND:
1310                 {
1311                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1312                         return;
1313                 }
1314
1315                 default:
1316                 case CMD_REQUEST_USAGE:
1317                 {
1318                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1319                         print("  No arguments required.\n");
1320                         print("See also: ^2extendmatchtime^7\n");
1321                         return;
1322                 }
1323         }
1324 }
1325
1326 void GameCommand_setbots(float request, float argc)
1327 {
1328         switch(request)
1329         {
1330                 case CMD_REQUEST_COMMAND:
1331                 {
1332                         if(argc >= 2)
1333                         {
1334                                 cvar_settemp("minplayers", "0");
1335                                 cvar_settemp("bot_number", argv(1));
1336                                 bot_fixcount();
1337                                 return;
1338                         }
1339                 }
1340
1341                 default:
1342                         print("Incorrect parameters for ^2setbots^7\n");
1343                 case CMD_REQUEST_USAGE:
1344                 {
1345                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1346                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1347                         print("See also: ^2bot_cmd^7\n");
1348                         return;
1349                 }
1350         }
1351 }
1352
1353 void GameCommand_shuffleteams(float request)
1354 {
1355         switch(request)
1356         {
1357                 case CMD_REQUEST_COMMAND:
1358                 {
1359                         if(teamplay)
1360                         {
1361                                 entity tmp_player;
1362                                 float i, x, z, t_teams, t_players, team_color;
1363
1364                                 // count the total amount of players and total amount of teams
1365                                 t_players = 0;
1366                                 t_teams = 0;
1367                                 FOR_EACH_PLAYER(tmp_player)
1368                                 {
1369                                         CheckAllowedTeams(tmp_player);
1370
1371                                         if(c1 >= 0) t_teams = max(1, t_teams);
1372                                         if(c2 >= 0) t_teams = max(2, t_teams);
1373                                         if(c3 >= 0) t_teams = max(3, t_teams);
1374                                         if(c4 >= 0) t_teams = max(4, t_teams);
1375
1376                                         ++t_players;
1377                                 }
1378
1379                                 // build a list of the players in a random order
1380                                 FOR_EACH_PLAYER(tmp_player)
1381                                 {
1382                                         for(;;)
1383                                         {
1384                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1385
1386                                                 if(shuffleteams_players[i])
1387                                                 {
1388                                                         continue; // a player is already assigned to this slot
1389                                                 }
1390                                                 else
1391                                                 {
1392                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1393                                                         break;
1394                                                 }
1395                                         }
1396                                 }
1397
1398                                 // finally, from the list made earlier, re-join the players in different order.
1399                                 for(i = 1; i <= t_teams; ++i)
1400                                 {
1401                                         // find out how many players to assign to this team
1402                                         x = (t_players / t_teams);
1403                                         x = ((i == 1) ? ceil(x) : floor(x));
1404
1405                                         team_color = Team_NumberToTeam(i);
1406
1407                                         // sort through the random list of players made earlier
1408                                         for(z = 1; z <= maxclients; ++z)
1409                                         {
1410                                                 if not(shuffleteams_teams[i] >= x)
1411                                                 {
1412                                                         if not(shuffleteams_players[z])
1413                                                                 continue; // not a player, move on to next random slot
1414
1415                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1416                                                                 self = edict_num(shuffleteams_players[z]);
1417
1418                                                         if(self.team != team_color)
1419                                                                 MoveToTeam(self, team_color, 6);
1420
1421                                                         shuffleteams_players[z] = 0;
1422                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1423                                                 }
1424                                                 else
1425                                                 {
1426                                                         break; // move on to next team
1427                                                 }
1428                                         }
1429                                 }
1430
1431                                 bprint("Successfully shuffled the players around randomly.\n");
1432
1433                                 // clear the buffers now
1434                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1435                                         shuffleteams_players[i] = 0;
1436
1437                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1438                                         shuffleteams_teams[i] = 0;
1439                         }
1440                         else
1441                         {
1442                                 print("Can't shuffle teams when currently not playing a team game.\n");
1443                         }
1444
1445                         return;
1446                 }
1447
1448                 default:
1449                 case CMD_REQUEST_USAGE:
1450                 {
1451                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1452                         print("  No arguments required.\n");
1453                         print("See also: ^2moveplayer, allspec^7\n");
1454                         return;
1455                 }
1456         }
1457 }
1458
1459 void GameCommand_stuffto(float request, float argc)
1460 {
1461         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1462         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1463         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1464
1465         #ifdef STUFFTO_ENABLED
1466         #message "stuffto command enabled"
1467         switch(request)
1468         {
1469                 case CMD_REQUEST_COMMAND:
1470                 {
1471                         if(argv(2))
1472                         {
1473                                 entity client = GetIndexedEntity(argc, 1);
1474                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1475
1476                                 if(accepted > 0)
1477                                 {
1478                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1479                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1480                                 }
1481                                 else
1482                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1483
1484                                 return;
1485                         }
1486                 }
1487
1488                 default:
1489                         print("Incorrect parameters for ^2stuffto^7\n");
1490                 case CMD_REQUEST_USAGE:
1491                 {
1492                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1493                         print("  'client' is the entity number or name of the player,\n");
1494                         print("  and 'command' is the command to be sent to that player.\n");
1495                         return;
1496                 }
1497         }
1498         #else
1499         if(request)
1500         {
1501                 print("stuffto command is not enabled on this server.\n");
1502                 return;
1503         }
1504         #endif
1505 }
1506
1507 void GameCommand_trace(float request, float argc)
1508 {
1509         switch(request)
1510         {
1511                 case CMD_REQUEST_COMMAND:
1512                 {
1513                         entity e;
1514                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1515                         float i, f, safe, unsafe, dq, dqf;
1516
1517                         switch(argv(1))
1518                         {
1519                                 case "debug":
1520                                 {
1521                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1522                                         for(;;)
1523                                         {
1524                                                 org = world.mins;
1525                                                 delta = world.maxs - world.mins;
1526
1527                                                 start_x = org_x + random() * delta_x;
1528                                                 start_y = org_y + random() * delta_y;
1529                                                 start_z = org_z + random() * delta_z;
1530
1531                                                 end_x = org_x + random() * delta_x;
1532                                                 end_y = org_y + random() * delta_y;
1533                                                 end_z = org_z + random() * delta_z;
1534
1535                                                 start = stov(vtos(start));
1536                                                 end = stov(vtos(end));
1537
1538                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1539                                                 if(!trace_startsolid)
1540                                                 {
1541                                                         p = trace_endpos;
1542                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1543                                                         if(trace_startsolid || trace_fraction == 1)
1544                                                         {
1545                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1546                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1547
1548                                                                 if(trace_startsolid)
1549                                                                 {
1550                                                                         // how much do we need to back off?
1551                                                                         safe = 1;
1552                                                                         unsafe = 0;
1553                                                                         for(;;)
1554                                                                         {
1555                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1556                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1557                                                                                 if(trace_startsolid)
1558                                                                                 {
1559                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1560                                                                                                 break;
1561                                                                                         unsafe = (safe + unsafe) * 0.5;
1562                                                                                 }
1563                                                                                 else
1564                                                                                 {
1565                                                                                         if((safe + unsafe) * 0.5 == safe)
1566                                                                                                 break;
1567                                                                                         safe = (safe + unsafe) * 0.5;
1568                                                                                 }
1569                                                                         }
1570
1571                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1572                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1573
1574                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1575                                                                         if(trace_startsolid)
1576                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1577                                                                         else
1578                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1579                                                                         break;
1580                                                                 }
1581
1582                                                                 q0 = p;
1583                                                                 dq = 0;
1584                                                                 dqf = 1;
1585                                                                 for(;;)
1586                                                                 {
1587                                                                         q = p + normalize(end - p) * (dq + dqf);
1588                                                                         if(q == q0)
1589                                                                                 break;
1590                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1591                                                                         if(trace_startsolid)
1592                                                                                 error("THIS ONE cannot happen");
1593                                                                         if(trace_fraction > 0)
1594                                                                                 dq += dqf * trace_fraction;
1595                                                                         dqf *= 0.5;
1596                                                                         q0 = q;
1597                                                                 }
1598                                                                 if(dq > 0)
1599                                                                 {
1600                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1601                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1602                                                                         break;
1603                                                                 }
1604                                                         }
1605                                                 }
1606                                         }
1607                                         return;
1608                                 }
1609
1610                                 case "debug2":
1611                                 {
1612                                         e = nextent(world);
1613                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1614                                         vv = trace_endpos;
1615                                         if(trace_fraction == 1)
1616                                         {
1617                                                 print("not above ground, aborting\n");
1618                                                 return;
1619                                         }
1620                                         f = 0;
1621                                         for(i = 0; i < 100000; ++i)
1622                                         {
1623                                                 dv = randomvec();
1624                                                 if(dv_z > 0)
1625                                                         dv = -1 * dv;
1626                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1627                                                 if(trace_startsolid)
1628                                                         print("bug 1\n");
1629                                                 if(trace_fraction == 1)
1630                                                 if(dv_z < f)
1631                                                 {
1632                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1633                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1634                                                         f = dv_z;
1635                                                 }
1636                                         }
1637                                         print("highest possible dist: ", ftos(f), "\n");
1638                                         return;
1639                                 }
1640
1641                                 case "walk":
1642                                 {
1643                                         if(argc == 4)
1644                                         {
1645                                                 e = nextent(world);
1646                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1647                                                         print("can walk\n");
1648                                                 else
1649                                                         print("cannot walk\n");
1650                                                 return;
1651                                         }
1652                                 }
1653
1654                                 case "showline":
1655                                 {
1656                                         if(argc == 4)
1657                                         {
1658                                                 vv = stov(argv(2));
1659                                                 dv = stov(argv(3));
1660                                                 traceline(vv, dv, MOVE_NORMAL, world);
1661                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1662                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1663                                                 return;
1664                                         }
1665                                 }
1666
1667                                 // no default case, just go straight to invalid
1668                         }
1669                 }
1670
1671                 default:
1672                         print("Incorrect parameters for ^2trace^7\n");
1673                 case CMD_REQUEST_USAGE:
1674                 {
1675                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1676                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1677                         print("See also: ^2bbox, gettaginfo^7\n");
1678                         return;
1679                 }
1680         }
1681 }
1682
1683 void GameCommand_unlockteams(float request)
1684 {
1685         switch(request)
1686         {
1687                 case CMD_REQUEST_COMMAND:
1688                 {
1689                         if(teamplay)
1690                         {
1691                                 lockteams = 0;
1692                                 bprint("^1The teams are now unlocked.\n");
1693                         }
1694                         else
1695                         {
1696                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1697                         }
1698                         return;
1699                 }
1700
1701                 default:
1702                 case CMD_REQUEST_USAGE:
1703                 {
1704                         print("\nUsage:^3 sv_cmd unlockteams\n");
1705                         print("  No arguments required.\n");
1706                         print("See also: ^2lockteams^7\n");
1707                         return;
1708                 }
1709         }
1710 }
1711
1712 void GameCommand_warp(float request, float argc)
1713 {
1714         switch (request)
1715         {
1716                 case CMD_REQUEST_COMMAND:
1717                 {
1718                         if(autocvar_g_campaign)
1719                         {
1720                                 if(argc >= 2)
1721                                 {
1722                                         CampaignLevelWarp(stof(argv(1)));
1723                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1724                                 }
1725                                 else
1726                                 {
1727                                         CampaignLevelWarp(-1);
1728                                         print("Successfully warped to next campaign level.\n");
1729                                 }
1730                         }
1731                         else
1732                                 print("Not in campaign, can't level warp\n");
1733                         return;
1734                 }
1735
1736                 default:
1737                 case CMD_REQUEST_USAGE:
1738                 {
1739                         print("\nUsage:^3 sv_cmd warp [level]\n");
1740                         print("  'level' is the level to change campaign mode to.\n");
1741                         print("  if 'level' is not provided it will change to the next level.\n");
1742                         return;
1743                 }
1744         }
1745 }
1746
1747 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1748 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1749 void GameCommand_(float request)
1750 {
1751         switch(request)
1752         {
1753                 case CMD_REQUEST_COMMAND:
1754                 {
1755
1756                         return;
1757                 }
1758
1759                 default:
1760                 case CMD_REQUEST_USAGE:
1761                 {
1762                         print("\nUsage:^3 sv_cmd \n");
1763                         print("  No arguments required.\n");
1764                         return;
1765                 }
1766         }
1767 }
1768 */
1769
1770
1771 // ==================================
1772 //  Macro system for server commands
1773 // ==================================
1774
1775 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1776 // Common commands have double indentation to separate them a bit.
1777 #define SERVER_COMMANDS(request,arguments,command) \
1778         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1779         SERVER_COMMAND("butcher", GameCommand_butcher(request), "Instantly removes all monsters on the map") \
1780         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1781         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1782         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1783         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1784         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1785         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1786         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1787         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1788         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1789         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1790         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1791         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1792         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1793         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1794         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1795         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1796         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1797         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1798         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1799         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1800         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1801         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1802         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1803         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1804         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1805         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1806         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1807         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1808         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1809         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1810         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1811         /* nothing */
1812
1813 void GameCommand_macro_help()
1814 {
1815         #define SERVER_COMMAND(name,function,description) \
1816                 { print("  ^2", name, "^7: ", description, "\n"); }
1817
1818         SERVER_COMMANDS(0, 0, "")
1819         #undef SERVER_COMMAND
1820
1821         return;
1822 }
1823
1824 float GameCommand_macro_command(float argc, string command)
1825 {
1826         #define SERVER_COMMAND(name,function,description) \
1827                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1828
1829         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1830         #undef SERVER_COMMAND
1831
1832         return FALSE;
1833 }
1834
1835 float GameCommand_macro_usage(float argc)
1836 {
1837         #define SERVER_COMMAND(name,function,description) \
1838                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1839
1840         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1841         #undef SERVER_COMMAND
1842
1843         return FALSE;
1844 }
1845
1846 void GameCommand_macro_write_aliases(float fh)
1847 {
1848         #define SERVER_COMMAND(name,function,description) \
1849                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1850
1851         SERVER_COMMANDS(0, 0, "")
1852         #undef SERVER_COMMAND
1853
1854         return;
1855 }
1856
1857
1858 // =========================================
1859 //  Main Function Called By Engine (sv_cmd)
1860 // =========================================
1861 // If this function exists, game code handles gamecommand instead of the engine code.
1862
1863 void GameCommand(string command)
1864 {
1865         float argc = tokenize_console(command);
1866
1867         // Guide for working with argc arguments by example:
1868         // argc:   1    - 2      - 3     - 4
1869         // argv:   0    - 1      - 2     - 3
1870         // cmd     vote - master - login - password
1871
1872         if(strtolower(argv(0)) == "help")
1873         {
1874                 if(argc == 1)
1875                 {
1876                         print("\nServer console commands:\n");
1877                         GameCommand_macro_help();
1878
1879                         print("\nBanning commands:\n");
1880                         BanCommand_macro_help();
1881
1882                         print("\nCommon networked commands:\n");
1883                         CommonCommand_macro_help(world);
1884
1885                         print("\nGeneric commands shared by all programs:\n");
1886                         GenericCommand_macro_help();
1887
1888                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1889                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1890
1891                         return;
1892                 }
1893                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1894                 {
1895                         return;
1896                 }
1897                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1898                 {
1899                         return;
1900                 }
1901                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1902                 {
1903                         return;
1904                 }
1905                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1906                 {
1907                         return;
1908                 }
1909         }
1910         else if(BanCommand(command))
1911         {
1912                 return; // handled by server/command/ipban.qc
1913         }
1914         else if(CommonCommand_macro_command(argc, world, command))
1915         {
1916                 return; // handled by server/command/common.qc
1917         }
1918         else if(GenericCommand(command))
1919         {
1920                 return; // handled by common/command/generic.qc
1921         }
1922         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1923         {
1924                 return; // handled by one of the above GameCommand_* functions
1925         }
1926
1927         // nothing above caught the command, must be invalid
1928         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1929
1930         return;
1931 }