qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if not(accepted > 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_butcher(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         if(g_td) { print("This command doesn't work in Tower Defense.\n"); return; }
 149                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 150
 151             float removed_count = 0;
 152                         entity montokill, head;
 153
 154             FOR_EACH_MONSTER(montokill)
 155             {
 156                                 WaypointSprite_Kill(montokill.sprite);
 157
 158                                 if(montokill.weaponentity)
 159                                         remove(montokill.weaponentity);
 160
 161                 remove(montokill);
 162                 removed_count += 1;
 163             }
 164
 165                         FOR_EACH_PLAYER(head)
 166                                 head.monstercount = 0;
 167
 168                         monsters_total = 0; // reset stats?
 169                         monsters_killed = 0;
 170
 171                         totalspawned = 0;
 172
 173                         if(removed_count <= 0)
 174                                 print("No monsters to kill\n");
 175                         else
 176                                 print(strcat("Killed ", ftos(removed_count), " monster", ((removed_count == 1) ? "\n" : "s\n")));
 177
 178                         return; // never fall through to usage
 179                 }
 180
 181                 default:
 182                 case CMD_REQUEST_USAGE:
 183                 {
 184                         print("\nUsage:^3 sv_cmd butcher\n");
 185                         print("  No arguments required.\n");
 186                         return;
 187                 }
 188         }
 189 }
 190
 191 void GameCommand_allready(float request)
 192 {
 193         switch(request)
 194         {
 195                 case CMD_REQUEST_COMMAND:
 196                 {
 197                         ReadyRestart();
 198                         return;
 199                 }
 200
 201                 default:
 202                 case CMD_REQUEST_USAGE:
 203                 {
 204                         print("\nUsage:^3 sv_cmd allready\n");
 205                         print("  No arguments required.\n");
 206                         return;
 207                 }
 208         }
 209 }
 210
 211 void GameCommand_allspec(float request, float argc)
 212 {
 213         switch(request)
 214         {
 215                 case CMD_REQUEST_COMMAND:
 216                 {
 217                         entity client;
 218                         string reason = argv(1);
 219                         float i = 0;
 220
 221                         FOR_EACH_REALPLAYER(client)
 222                         {
 223                                 self = client;
 224                                 PutObserverInServer();
 225                                 ++i;
 226                         }
 227                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 228                         else { print("No players found to spectate.\n"); }
 229                         return;
 230                 }
 231
 232                 default:
 233                 case CMD_REQUEST_USAGE:
 234                 {
 235                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 236                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 237                         print("See also: ^2moveplayer, shuffleteams^7\n");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 void GameCommand_anticheat(float request, float argc)
 244 {
 245         switch(request)
 246         {
 247                 case CMD_REQUEST_COMMAND:
 248                 {
 249                         entity client = GetIndexedEntity(argc, 1);
 250                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 251
 252                         if(accepted > 0)
 253                         {
 254                                 self = client;
 255                                 anticheat_report();
 256                                 return;
 257                         }
 258                         else
 259                         {
 260                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 261                         }
 262                 }
 263
 264                 default:
 265                         print("Incorrect parameters for ^2anticheat^7\n");
 266                 case CMD_REQUEST_USAGE:
 267                 {
 268                         print("\nUsage:^3 sv_cmd anticheat client\n");
 269                         print("  'client' is the entity number or name of the player.\n");
 270                         return;
 271                 }
 272         }
 273 }
 274
 275 void GameCommand_bbox(float request)
 276 {
 277         switch(request)
 278         {
 279                 case CMD_REQUEST_COMMAND:
 280                 {
 281                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 282                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 283                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 284                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 285                         print("Solid bounding box size:");
 286
 287                         tracebox('1 0 0' * world.absmin_x,
 288                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 289                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 290                                                         '1 0 0' * world.absmax_x,
 291                                         MOVE_WORLDONLY,
 292                                         world);
 293                         if(trace_startsolid)
 294                                 print(" ", ftos(world.absmin_x));
 295                         else
 296                                 print(" ", ftos(trace_endpos_x));
 297
 298                         tracebox('0 1 0' * world.absmin_y,
 299                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 300                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 301                                                         '0 1 0' * world.absmax_y,
 302                                         MOVE_WORLDONLY,
 303                                         world);
 304                         if(trace_startsolid)
 305                                 print(" ", ftos(world.absmin_y));
 306                         else
 307                                 print(" ", ftos(trace_endpos_y));
 308
 309                         tracebox('0 0 1' * world.absmin_z,
 310                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 311                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 312                                                         '0 0 1' * world.absmax_z,
 313                                         MOVE_WORLDONLY,
 314                                         world);
 315                         if(trace_startsolid)
 316                                 print(" ", ftos(world.absmin_z));
 317                         else
 318                                 print(" ", ftos(trace_endpos_z));
 319
 320                         tracebox('1 0 0' * world.absmax_x,
 321                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 322                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 323                                                         '1 0 0' * world.absmin_x,
 324                                         MOVE_WORLDONLY,
 325                                         world);
 326                         if(trace_startsolid)
 327                                 print(" ", ftos(world.absmax_x));
 328                         else
 329                                 print(" ", ftos(trace_endpos_x));
 330
 331                         tracebox('0 1 0' * world.absmax_y,
 332                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 333                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 334                                                         '0 1 0' * world.absmin_y,
 335                                         MOVE_WORLDONLY,
 336                                         world);
 337                         if(trace_startsolid)
 338                                 print(" ", ftos(world.absmax_y));
 339                         else
 340                                 print(" ", ftos(trace_endpos_y));
 341
 342                         tracebox('0 0 1' * world.absmax_z,
 343                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 344                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 345                                                         '0 0 1' * world.absmin_z,
 346                                         MOVE_WORLDONLY,
 347                                         world);
 348                         if(trace_startsolid)
 349                                 print(" ", ftos(world.absmax_z));
 350                         else
 351                                 print(" ", ftos(trace_endpos_z));
 352
 353                         print("\n");
 354                         return;
 355                 }
 356
 357                 default:
 358                 case CMD_REQUEST_USAGE:
 359                 {
 360                         print("\nUsage:^3 sv_cmd bbox\n");
 361                         print("  No arguments required.\n");
 362                         print("See also: ^2gettaginfo, trace^7\n");
 363                         return;
 364                 }
 365         }
 366 }
 367
 368 void GameCommand_bot_cmd(float request, float argc, string command)
 369 {
 370         switch(request)
 371         {
 372                 case CMD_REQUEST_COMMAND:
 373                 {
 374                         entity bot;
 375
 376                         if(argv(1) == "reset")
 377                         {
 378                                 bot_resetqueues();
 379                                 return;
 380                         }
 381                         else if(argv(1) == "setbots")
 382                         {
 383                                 cvar_settemp("bot_vs_human", "0");
 384                                 cvar_settemp("minplayers", "0");
 385                                 cvar_settemp("bot_number", "0");
 386                                 bot_fixcount();
 387                                 cvar_settemp("bot_number", argv(2));
 388                                 if(!bot_fixcount())
 389                                         print("Sorry, could not set requested bot count\n");
 390                                 return;
 391                         }
 392                         else if(argv(1) == "load" && argc == 3)
 393                         {
 394                                 float fh, i;
 395                                 string s;
 396                                 fh = fopen(argv(2), FILE_READ);
 397                                 if(fh < 0)
 398                                 {
 399                                         print("cannot open the file\n");
 400                                         return;
 401                                 }
 402
 403                                 i = 0;
 404                                 while((s = fgets(fh)))
 405                                 {
 406                                         argc = tokenize_console(s);
 407
 408                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 409                                         {
 410                                                 if(argv(2) == "reset")
 411                                                 {
 412                                                         bot_resetqueues();
 413                                                 }
 414                                                 else if(argv(2) == "setbots")
 415                                                 {
 416                                                         cvar_settemp("bot_vs_human", "0");
 417                                                         cvar_settemp("minplayers", "0");
 418                                                         cvar_settemp("bot_number", "0");
 419                                                         bot_fixcount();
 420                                                         cvar_settemp("bot_number", argv(3));
 421                                                         if(!bot_fixcount())
 422                                                                 print("Sorry, could not set requested bot count\n");
 423                                                 }
 424                                                 else
 425                                                 {
 426                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 427                                                         bot = find_bot_by_number(stof(argv(2)));
 428                                                         if(bot == world)
 429                                                                 bot = find_bot_by_name(argv(2));
 430                                                         if(bot)
 431                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 432                                                 }
 433                                         }
 434                                         else
 435                                                 localcmd(strcat(s, "\n"));
 436
 437                                         ++i;
 438                                 }
 439                                 print(ftos(i), " commands read\n");
 440                                 fclose(fh);
 441                                 return;
 442                         }
 443                         else if(argv(1) == "help")
 444                         {
 445                                 if(argv(2))
 446                                         bot_cmdhelp(argv(2));
 447                                 else
 448                                         bot_list_commands();
 449                                 return;
 450                         }
 451                         else if(argc >= 3) // this comes last
 452                         {
 453                                 bot = find_bot_by_number(stof(argv(1)));
 454                                 if(bot == world)
 455                                         bot = find_bot_by_name(argv(1));
 456                                 if(bot)
 457                                 {
 458                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 459                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 460                                         return;
 461                                 }
 462                                 else
 463                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 464                         }
 465                 }
 466
 467                 default:
 468                         print("Incorrect parameters for ^2bot_cmd^7\n");
 469                 case CMD_REQUEST_USAGE:
 470                 {
 471                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 472                         print("  'client' can be either the name or entity id of the bot\n");
 473                         print("  For full list of commands, see bot_cmd help [command].\n");
 474                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 475                         print("          sv_cmd bot_cmd client presskey jump\n");
 476                         return;
 477                 }
 478         }
 479 }
 480
 481 void GameCommand_cointoss(float request, float argc)
 482 {
 483         switch(request)
 484         {
 485                 case CMD_REQUEST_COMMAND:
 486                 {
 487                         entity client;
 488                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 489                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 490                         string choice = ((random() > 0.5) ? result1 : result2);
 491
 492                         FOR_EACH_CLIENT(client)
 493                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 494                         bprint(strcat("^3Throwing coin... Result: ", choice));
 495                         return;
 496                 }
 497
 498                 default:
 499                 case CMD_REQUEST_USAGE:
 500                 {
 501                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 502                         print("  Where 'result1' and 'result2' are user created options.\n");
 503                         return;
 504                 }
 505         }
 506 }
 507
 508 void GameCommand_database(float request, float argc)
 509 {
 510         switch(request)
 511         {
 512                 case CMD_REQUEST_COMMAND:
 513                 {
 514                         if(argc == 3)
 515                         {
 516                                 if(argv(1) == "save")
 517                                 {
 518                                         db_save(ServerProgsDB, argv(2));
 519                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 520                                         return;
 521                                 }
 522                                 else if(argv(1) == "dump")
 523                                 {
 524                                         db_dump(ServerProgsDB, argv(2));
 525                                         print("DB dumped.\n"); // wtf does this do?
 526                                         return;
 527                                 }
 528                                 else if(argv(1) == "load")
 529                                 {
 530                                         db_close(ServerProgsDB);
 531                                         ServerProgsDB = db_load(argv(2));
 532                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 533                                         return;
 534                                 }
 535                         }
 536                 }
 537
 538                 default:
 539                         print("Incorrect parameters for ^2database^7\n");
 540                 case CMD_REQUEST_USAGE:
 541                 {
 542                         print("\nUsage:^3 sv_cmd database action filename\n");
 543                         print("  Where 'action' is the command to complete,\n");
 544                         print("  and 'filename' is what it acts upon.\n");
 545                         print("  Full list of commands here: \"save, dump, load.\"\n");
 546                         return;
 547                 }
 548         }
 549 }
 550
 551 void GameCommand_defer_clear(float request, float argc)
 552 {
 553         switch(request)
 554         {
 555                 case CMD_REQUEST_COMMAND:
 556                 {
 557                         entity client;
 558                         float accepted;
 559
 560                         if(argc >= 2)
 561                         {
 562                                 client = GetIndexedEntity(argc, 1);
 563                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 564
 565                                 if(accepted > 0)
 566                                 {
 567                                         stuffcmd(client, "defer clear\n");
 568                                         print("defer clear stuffed to ", client.netname, "\n");
 569                                 }
 570                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 571
 572                                 return;
 573                         }
 574                 }
 575
 576                 default:
 577                         print("Incorrect parameters for ^2defer_clear^7\n");
 578                 case CMD_REQUEST_USAGE:
 579                 {
 580                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 581                         print("  'client' is the entity number or name of the player.\n");
 582                         print("See also: ^2defer_clear_all^7\n");
 583                         return;
 584                 }
 585         }
 586 }
 587
 588 void GameCommand_defer_clear_all(float request)
 589 {
 590         switch(request)
 591         {
 592                 case CMD_REQUEST_COMMAND:
 593                 {
 594                         entity client;
 595                         float i = 0;
 596                         float argc;
 597
 598                         FOR_EACH_CLIENT(client)
 599                         {
 600                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 601                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 602                                 ++i;
 603                         }
 604                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 605                         return;
 606                 }
 607
 608                 default:
 609                 case CMD_REQUEST_USAGE:
 610                 {
 611                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 612                         print("  No arguments required.\n");
 613                         print("See also: ^2defer_clear^7\n");
 614                         return;
 615                 }
 616         }
 617 }
 618
 619 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 620 {
 621         switch(request)
 622         {
 623                 case CMD_REQUEST_COMMAND:
 624                 {
 625                         if(argv(1))
 626                         {
 627                                 if(argv(2))
 628                                         race_deleteTime(argv(2), stof(argv(1)));
 629                                 else
 630                                         race_deleteTime(GetMapname(), stof(argv(1)));
 631                                 return;
 632                         }
 633                 }
 634
 635                 default:
 636                         print("Incorrect parameters for ^2delrec^7\n");
 637                 case CMD_REQUEST_USAGE:
 638                 {
 639                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 640                         print("  'ranking' is which ranking level to clear up to, \n");
 641                         print("  it will clear all records up to nth place.\n");
 642                         print("  if 'map' is not provided it will use current map.\n");
 643                         return;
 644                 }
 645         }
 646 }
 647
 648 void GameCommand_effectindexdump(float request)
 649 {
 650         switch(request)
 651         {
 652                 case CMD_REQUEST_COMMAND:
 653                 {
 654                         float fh, d;
 655                         string s;
 656
 657                         d = db_create();
 658                         print("begin of effects list\n");
 659                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 660                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 661                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 662                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 663                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 664                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 665                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 666                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 667                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 668                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 669                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 670                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 671                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 672                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 673                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 674                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 675                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 676                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 677                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 678                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 679                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 680                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 681                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 682                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 683                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 684                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 685                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 686                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 687                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 688                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 689                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 690                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 691                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 692                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 693                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 694                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 695
 696                         fh = fopen("effectinfo.txt", FILE_READ);
 697                         while((s = fgets(fh)))
 698                         {
 699                                 tokenize_console(s);
 700                                 if(argv(0) == "effect")
 701                                 {
 702                                         if(db_get(d, argv(1)) != "1")
 703                                         {
 704                                                 if(particleeffectnum(argv(1)) >= 0)
 705                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 706                                                 db_put(d, argv(1), "1");
 707                                         }
 708                                 }
 709                         }
 710                         print("end of effects list\n");
 711
 712                         db_close(d);
 713                         return;
 714                 }
 715
 716                 default:
 717                 case CMD_REQUEST_USAGE:
 718                 {
 719                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 720                         print("  No arguments required.\n");
 721                         return;
 722                 }
 723         }
 724 }
 725
 726 void GameCommand_extendmatchtime(float request)
 727 {
 728         switch(request)
 729         {
 730                 case CMD_REQUEST_COMMAND:
 731                 {
 732                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 733                         return;
 734                 }
 735
 736                 default:
 737                 case CMD_REQUEST_USAGE:
 738                 {
 739                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 740                         print("  No arguments required.\n");
 741                         print("See also: ^2reducematchtime^7\n");
 742                         return;
 743                 }
 744         }
 745 }
 746
 747 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 748 {
 749         switch(request)
 750         {
 751                 case CMD_REQUEST_COMMAND:
 752                 {
 753                         entity client;
 754
 755                         for(client = world; (client = find(client, classname, argv(1))); )
 756                                 print(etos(client), "\n");
 757
 758                         return;
 759                 }
 760
 761                 default:
 762                         print("Incorrect parameters for ^2find^7\n");
 763                 case CMD_REQUEST_USAGE:
 764                 {
 765                         print("\nUsage:^3 sv_cmd find classname\n");
 766                         print("  Where 'classname' is the classname to search for.\n");
 767                         return;
 768                 }
 769         }
 770 }
 771
 772 void GameCommand_gametype(float request, float argc)
 773 {
 774         switch(request)
 775         {
 776                 case CMD_REQUEST_COMMAND:
 777                 {
 778                         if(argv(1) != "")
 779                         {
 780                                 string s = argv(1);
 781                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 782
 783                                 if(t)
 784                                 {
 785                                         MapInfo_SwitchGameType(t);
 786                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 787                                         if(MapInfo_count > 0)
 788                                                 bprint("Game type successfully switched to ", s, "\n");
 789                                         else
 790                                         {
 791                                                 bprint("Cannot use this game type: no map for it found\n");
 792                                                 MapInfo_SwitchGameType(tsave);
 793                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 794                                         }
 795                                 }
 796                                 else
 797                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 798
 799                                 return;
 800                         }
 801                 }
 802
 803                 default:
 804                         print("Incorrect parameters for ^2gametype^7\n");
 805                 case CMD_REQUEST_USAGE:
 806                 {
 807                         print("\nUsage:^3 sv_cmd gametype mode\n");
 808                         print("  Where 'mode' is the gametype mode to switch to.\n");
 809                         print("See also: ^2gotomap^7\n");
 810                         return;
 811                 }
 812         }
 813 }
 814
 815 void GameCommand_gettaginfo(float request, float argc)
 816 {
 817         switch(request)
 818         {
 819                 case CMD_REQUEST_COMMAND:
 820                 {
 821                         entity tmp_entity;
 822                         float i;
 823                         vector v;
 824
 825                         if(argc >= 4)
 826                         {
 827                                 tmp_entity = spawn();
 828                                 if(argv(1) == "w")
 829                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 830                                 else
 831                                 {
 832                                         precache_model(argv(1));
 833                                         setmodel(tmp_entity, argv(1));
 834                                 }
 835                                 tmp_entity.frame = stof(argv(2));
 836                                 if(substring(argv(3), 0, 1) == "#")
 837                                         i = stof(substring(argv(3), 1, -1));
 838                                 else
 839                                         i = gettagindex(tmp_entity, argv(3));
 840                                 if(i)
 841                                 {
 842                                         v = gettaginfo(tmp_entity, i);
 843                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 844                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 845                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 846                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 847                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 848                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 849                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 850                                         if(argc >= 6)
 851                                         {
 852                                                 v_y = -v_y;
 853                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 854                                         }
 855                                 }
 856                                 else
 857                                         print("bone not found\n");
 858
 859                                 remove(tmp_entity);
 860                                 return;
 861                         }
 862                 }
 863
 864                 default:
 865                         print("Incorrect parameters for ^2gettaginfo^7\n");
 866                 case CMD_REQUEST_USAGE:
 867                 {
 868                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 869                         print("See also: ^2bbox, trace^7\n");
 870                         return;
 871                 }
 872         }
 873 }
 874
 875 void GameCommand_animbench(float request, float argc)
 876 {
 877         switch(request)
 878         {
 879                 case CMD_REQUEST_COMMAND:
 880                 {
 881                         entity tmp_entity;
 882
 883                         if(argc >= 4)
 884                         {
 885                                 tmp_entity = spawn();
 886                                 if(argv(1) == "w")
 887                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 888                                 else
 889                                 {
 890                                         precache_model(argv(1));
 891                                         setmodel(tmp_entity, argv(1));
 892                                 }
 893                                 float f1 = stof(argv(2));
 894                                 float f2 = stof(argv(3));
 895                                 float t0;
 896                                 float t1 = 0;
 897                                 float t2 = 0;
 898                                 float n = 0;
 899
 900                                 while(t1 + t2 < 1)
 901                                 {
 902                                         tmp_entity.frame = f1;
 903                                         t0 = gettime(GETTIME_HIRES);
 904                                         getsurfacepoint(tmp_entity, 0, 0);
 905                                         t1 += gettime(GETTIME_HIRES) - t0;
 906                                         tmp_entity.frame = f2;
 907                                         t0 = gettime(GETTIME_HIRES);
 908                                         getsurfacepoint(tmp_entity, 0, 0);
 909                                         t2 += gettime(GETTIME_HIRES) - t0;
 910                                         n += 1;
 911                                 }
 912                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 913                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 914
 915                                 remove(tmp_entity);
 916                                 return;
 917                         }
 918                 }
 919
 920                 default:
 921                         print("Incorrect parameters for ^2gettaginfo^7\n");
 922                 case CMD_REQUEST_USAGE:
 923                 {
 924                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 925                         print("See also: ^2bbox, trace^7\n");
 926                         return;
 927                 }
 928         }
 929 }
 930
 931 void GameCommand_gotomap(float request, float argc)
 932 {
 933         switch(request)
 934         {
 935                 case CMD_REQUEST_COMMAND:
 936                 {
 937                         if(argv(1))
 938                         {
 939                                 print(GotoMap(argv(1)), "\n");
 940                                 return;
 941                         }
 942                 }
 943
 944                 default:
 945                         print("Incorrect parameters for ^2gotomap^7\n");
 946                 case CMD_REQUEST_USAGE:
 947                 {
 948                         print("\nUsage:^3 sv_cmd gotomap map\n");
 949                         print("  Where 'map' is the *.bsp file to change to.\n");
 950                         print("See also: ^2gametype^7\n");
 951                         return;
 952                 }
 953         }
 954 }
 955
 956 void GameCommand_lockteams(float request)
 957 {
 958         switch(request)
 959         {
 960                 case CMD_REQUEST_COMMAND:
 961                 {
 962                         if(teamplay)
 963                         {
 964                                 lockteams = 1;
 965                                 bprint("^1The teams are now locked.\n");
 966                         }
 967                         else
 968                         {
 969                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 970                         }
 971                         return;
 972                 }
 973
 974                 default:
 975                 case CMD_REQUEST_USAGE:
 976                 {
 977                         print("\nUsage:^3 sv_cmd lockteams\n");
 978                         print("  No arguments required.\n");
 979                         print("See also: ^2unlockteams^7\n");
 980                         return;
 981                 }
 982         }
 983 }
 984
 985 void GameCommand_make_mapinfo(float request)
 986 {
 987         switch(request)
 988         {
 989                 case CMD_REQUEST_COMMAND:
 990                 {
 991                         entity tmp_entity;
 992
 993                         tmp_entity = spawn();
 994                         tmp_entity.classname = "make_mapinfo";
 995                         tmp_entity.think = make_mapinfo_Think;
 996                         tmp_entity.nextthink = time;
 997                         MapInfo_Enumerate();
 998                         return;
 999                 }
1000
1001                 default:
1002                 case CMD_REQUEST_USAGE:
1003                 {
1004                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1005                         print("  No arguments required.\n");
1006                         print("See also: ^2radarmap^7\n");
1007                         return;
1008                 }
1009         }
1010 }
1011
1012 void GameCommand_moveplayer(float request, float argc)
1013 {
1014         switch(request)
1015         {
1016                 case CMD_REQUEST_COMMAND:
1017                 {
1018                         float accepted;
1019                         entity client;
1020
1021                         string targets = strreplace(",", " ", argv(1));
1022                         string original_targets = strreplace(" ", ", ", targets);
1023                         string destination = argv(2);
1024
1025                         string successful, t;
1026                         successful = string_null;
1027
1028                         // lets see if the target(s) even actually exist.
1029                         if((targets) && (destination))
1030                         {
1031                                 for(;targets;)
1032                                 {
1033                                         t = car(targets); targets = cdr(targets);
1034
1035                                         // Check to see if the player is a valid target
1036                                         client = GetFilteredEntity(t);
1037                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
1038
1039                                         if not(accepted > 0)
1040                                         {
1041                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1042                                                 continue;
1043                                         }
1044
1045                                         // Where are we putting this player?
1046                                         if(destination == "spec" || destination == "spectator")
1047                                         {
1048                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1049                                                 {
1050                                                         self = client;
1051                                                         PutObserverInServer();
1052
1053                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1054                                                 }
1055                                                 else
1056                                                 {
1057                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1058                                                 }
1059                                                 continue;
1060                                         }
1061                                         else
1062                                         {
1063                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1064                                                 {
1065                                                         if(teamplay)
1066                                                         {
1067                                                                 // set up
1068                                                                 float team_id;
1069                                                                 float save = client.team_forced;
1070                                                                 client.team_forced = 0;
1071
1072                                                                 // find the team to move the player to
1073                                                                 team_id = Team_ColorToTeam(destination);
1074                                                                 if(team_id == client.team) // already on the destination team
1075                                                                 {
1076                                                                         // keep the forcing undone
1077                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1078                                                                         continue;
1079                                                                 }
1080                                                                 else if(team_id == 0)  // auto team
1081                                                                 {
1082                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1083                                                                 }
1084                                                                 else
1085                                                                 {
1086                                                                         CheckAllowedTeams(client);
1087                                                                 }
1088                                                                 client.team_forced = save;
1089
1090                                                                 // Check to see if the destination team is even available
1091                                                                 switch(team_id)
1092                                                                 {
1093                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1094                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1095                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1096                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1097
1098                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1099                                                                 }
1100
1101                                                                 // If so, lets continue and finally move the player
1102                                                                 client.team_forced = 0;
1103                                                                 MoveToTeam(client, team_id, 6);
1104                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1105                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1106                                                                 continue;
1107                                                         }
1108                                                         else
1109                                                         {
1110                                                                 print("Can't change teams when currently not playing a team game.\n");
1111                                                                 return;
1112                                                         }
1113                                                 }
1114                                                 else
1115                                                 {
1116                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1117                                                         return;
1118                                                 }
1119                                         }
1120                                 }
1121
1122                                 if(successful)
1123                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1124                                 else
1125                                         print("No players given (", original_targets, ") are able to move.\n");
1126
1127                                 return; // still correct parameters so return to avoid usage print
1128                         }
1129                 }
1130
1131                 default:
1132                         print("Incorrect parameters for ^2moveplayer^7\n");
1133                 case CMD_REQUEST_USAGE:
1134                 {
1135                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1136                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1137                         print("  'destination' is what to send the player to, be it team or spectating\n");
1138                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1139                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1140                         print("          sv_cmd moveplayer 2 spec \n");
1141                         print("See also: ^2allspec, shuffleteams^7\n");
1142                         return;
1143                 }
1144         }
1145 }
1146
1147 void GameCommand_nospectators(float request)
1148 {
1149         switch(request)
1150         {
1151                 case CMD_REQUEST_COMMAND:
1152                 {
1153                         blockSpectators = 1;
1154                         entity plr;
1155                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1156                         {
1157                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1158                                 {
1159                                         plr.spectatortime = time;
1160                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1161                                 }
1162                         }
1163                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1164                         return;
1165                 }
1166
1167                 default:
1168                 case CMD_REQUEST_USAGE:
1169                 {
1170                         print("\nUsage:^3 sv_cmd nospectators\n");
1171                         print("  No arguments required.\n");
1172                         return;
1173                 }
1174         }
1175 }
1176
1177 void GameCommand_playerdemo(float request, float argc)
1178 {
1179         switch(request)
1180         {
1181                 case CMD_REQUEST_COMMAND:
1182                 {
1183                         if(argv(2) && argv(3))
1184                         {
1185                                 entity client;
1186                                 float i, n, accepted;
1187
1188                                 switch(argv(1))
1189                                 {
1190                                         case "read":
1191                                         {
1192                                                 client = GetIndexedEntity(argc, 2);
1193                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1194
1195                                                 if not(accepted > 0)
1196                                                 {
1197                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1198                                                         return;
1199                                                 }
1200
1201                                                 self = client;
1202                                                 playerdemo_open_read(argv(next_token));
1203                                                 return;
1204                                         }
1205
1206                                         case "write":
1207                                         {
1208                                                 client = GetIndexedEntity(argc, 2);
1209                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1210
1211                                                 if not(accepted > 0)
1212                                                 {
1213                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1214                                                         return;
1215                                                 }
1216
1217                                                 self = client;
1218                                                 playerdemo_open_write(argv(next_token));
1219                                                 return;
1220                                         }
1221
1222                                         case "auto_read_and_write":
1223                                         {
1224                                                 n = GetFilteredNumber(argv(3));
1225                                                 cvar_set("bot_number", ftos(n));
1226
1227                                                 localcmd("wait; wait; wait\n");
1228                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1229
1230                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1231                                                 return;
1232                                         }
1233
1234                                         case "auto_read":
1235                                         {
1236                                                 n = GetFilteredNumber(argv(3));
1237                                                 cvar_set("bot_number", ftos(n));
1238
1239                                                 localcmd("wait; wait; wait\n");
1240                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1241                                                 return;
1242                                         }
1243                                 }
1244                         }
1245                 }
1246
1247                 default:
1248                         print("Incorrect parameters for ^2playerdemo^7\n");
1249                 case CMD_REQUEST_USAGE:
1250                 {
1251                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1252                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1253                         return;
1254                 }
1255         }
1256 }
1257
1258 void GameCommand_printstats(float request)
1259 {
1260         switch(request)
1261         {
1262                 case CMD_REQUEST_COMMAND:
1263                 {
1264                         DumpStats(FALSE);
1265                         print("stats dumped.\n");
1266                         return;
1267                 }
1268
1269                 default:
1270                 case CMD_REQUEST_USAGE:
1271                 {
1272                         print("\nUsage:^3 sv_cmd printstats\n");
1273                         print("  No arguments required.\n");
1274                         return;
1275                 }
1276         }
1277 }
1278
1279 void GameCommand_radarmap(float request, float argc)
1280 {
1281         switch(request)
1282         {
1283                 case CMD_REQUEST_COMMAND:
1284                 {
1285                         if(RadarMap_Make(argc))
1286                                 return;
1287                 }
1288
1289                 default:
1290                         print("Incorrect parameters for ^2radarmap^7\n");
1291                 case CMD_REQUEST_USAGE:
1292                 {
1293                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1294                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1295                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1296                         print("See also: ^2make_mapinfo^7\n");
1297                         return;
1298                 }
1299         }
1300 }
1301
1302 void GameCommand_reducematchtime(float request)
1303 {
1304         switch(request)
1305         {
1306                 case CMD_REQUEST_COMMAND:
1307                 {
1308                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1309                         return;
1310                 }
1311
1312                 default:
1313                 case CMD_REQUEST_USAGE:
1314                 {
1315                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1316                         print("  No arguments required.\n");
1317                         print("See also: ^2extendmatchtime^7\n");
1318                         return;
1319                 }
1320         }
1321 }
1322
1323 void GameCommand_setbots(float request, float argc)
1324 {
1325         switch(request)
1326         {
1327                 case CMD_REQUEST_COMMAND:
1328                 {
1329                         if(argc >= 2)
1330                         {
1331                                 cvar_settemp("minplayers", "0");
1332                                 cvar_settemp("bot_number", argv(1));
1333                                 bot_fixcount();
1334                                 return;
1335                         }
1336                 }
1337
1338                 default:
1339                         print("Incorrect parameters for ^2setbots^7\n");
1340                 case CMD_REQUEST_USAGE:
1341                 {
1342                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1343                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1344                         print("See also: ^2bot_cmd^7\n");
1345                         return;
1346                 }
1347         }
1348 }
1349
1350 void GameCommand_shuffleteams(float request)
1351 {
1352         switch(request)
1353         {
1354                 case CMD_REQUEST_COMMAND:
1355                 {
1356                         if(teamplay)
1357                         {
1358                                 entity tmp_player;
1359                                 float i, x, z, t_teams, t_players, team_color;
1360
1361                                 // count the total amount of players and total amount of teams
1362                                 t_players = 0;
1363                                 t_teams = 0;
1364                                 FOR_EACH_PLAYER(tmp_player)
1365                                 {
1366                                         CheckAllowedTeams(tmp_player);
1367
1368                                         if(c1 >= 0) t_teams = max(1, t_teams);
1369                                         if(c2 >= 0) t_teams = max(2, t_teams);
1370                                         if(c3 >= 0) t_teams = max(3, t_teams);
1371                                         if(c4 >= 0) t_teams = max(4, t_teams);
1372
1373                                         ++t_players;
1374                                 }
1375
1376                                 // build a list of the players in a random order
1377                                 FOR_EACH_PLAYER(tmp_player)
1378                                 {
1379                                         for(;;)
1380                                         {
1381                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1382
1383                                                 if(shuffleteams_players[i])
1384                                                 {
1385                                                         continue; // a player is already assigned to this slot
1386                                                 }
1387                                                 else
1388                                                 {
1389                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1390                                                         break;
1391                                                 }
1392                                         }
1393                                 }
1394
1395                                 // finally, from the list made earlier, re-join the players in different order.
1396                                 for(i = 1; i <= t_teams; ++i)
1397                                 {
1398                                         // find out how many players to assign to this team
1399                                         x = (t_players / t_teams);
1400                                         x = ((i == 1) ? ceil(x) : floor(x));
1401
1402                                         team_color = Team_NumberToTeam(i);
1403
1404                                         // sort through the random list of players made earlier
1405                                         for(z = 1; z <= maxclients; ++z)
1406                                         {
1407                                                 if not(shuffleteams_teams[i] >= x)
1408                                                 {
1409                                                         if not(shuffleteams_players[z])
1410                                                                 continue; // not a player, move on to next random slot
1411
1412                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1413                                                                 self = edict_num(shuffleteams_players[z]);
1414
1415                                                         if(self.team != team_color)
1416                                                                 MoveToTeam(self, team_color, 6);
1417
1418                                                         shuffleteams_players[z] = 0;
1419                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1420                                                 }
1421                                                 else
1422                                                 {
1423                                                         break; // move on to next team
1424                                                 }
1425                                         }
1426                                 }
1427
1428                                 bprint("Successfully shuffled the players around randomly.\n");
1429
1430                                 // clear the buffers now
1431                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1432                                         shuffleteams_players[i] = 0;
1433
1434                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1435                                         shuffleteams_teams[i] = 0;
1436                         }
1437                         else
1438                         {
1439                                 print("Can't shuffle teams when currently not playing a team game.\n");
1440                         }
1441
1442                         return;
1443                 }
1444
1445                 default:
1446                 case CMD_REQUEST_USAGE:
1447                 {
1448                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1449                         print("  No arguments required.\n");
1450                         print("See also: ^2moveplayer, allspec^7\n");
1451                         return;
1452                 }
1453         }
1454 }
1455
1456 void GameCommand_stuffto(float request, float argc)
1457 {
1458         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1459         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1460         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1461
1462         #ifdef STUFFTO_ENABLED
1463         #message "stuffto command enabled"
1464         switch(request)
1465         {
1466                 case CMD_REQUEST_COMMAND:
1467                 {
1468                         if(argv(2))
1469                         {
1470                                 entity client = GetIndexedEntity(argc, 1);
1471                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1472
1473                                 if(accepted > 0)
1474                                 {
1475                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1476                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1477                                 }
1478                                 else
1479                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1480
1481                                 return;
1482                         }
1483                 }
1484
1485                 default:
1486                         print("Incorrect parameters for ^2stuffto^7\n");
1487                 case CMD_REQUEST_USAGE:
1488                 {
1489                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1490                         print("  'client' is the entity number or name of the player,\n");
1491                         print("  and 'command' is the command to be sent to that player.\n");
1492                         return;
1493                 }
1494         }
1495         #else
1496         if(request)
1497         {
1498                 print("stuffto command is not enabled on this server.\n");
1499                 return;
1500         }
1501         #endif
1502 }
1503
1504 void GameCommand_trace(float request, float argc)
1505 {
1506         switch(request)
1507         {
1508                 case CMD_REQUEST_COMMAND:
1509                 {
1510                         entity e;
1511                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1512                         float i, f, safe, unsafe, dq, dqf;
1513
1514                         switch(argv(1))
1515                         {
1516                                 case "debug":
1517                                 {
1518                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1519                                         for(;;)
1520                                         {
1521                                                 org = world.mins;
1522                                                 delta = world.maxs - world.mins;
1523
1524                                                 start_x = org_x + random() * delta_x;
1525                                                 start_y = org_y + random() * delta_y;
1526                                                 start_z = org_z + random() * delta_z;
1527
1528                                                 end_x = org_x + random() * delta_x;
1529                                                 end_y = org_y + random() * delta_y;
1530                                                 end_z = org_z + random() * delta_z;
1531
1532                                                 start = stov(vtos(start));
1533                                                 end = stov(vtos(end));
1534
1535                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1536                                                 if(!trace_startsolid)
1537                                                 {
1538                                                         p = trace_endpos;
1539                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1540                                                         if(trace_startsolid || trace_fraction == 1)
1541                                                         {
1542                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1543                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1544
1545                                                                 if(trace_startsolid)
1546                                                                 {
1547                                                                         // how much do we need to back off?
1548                                                                         safe = 1;
1549                                                                         unsafe = 0;
1550                                                                         for(;;)
1551                                                                         {
1552                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1553                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1554                                                                                 if(trace_startsolid)
1555                                                                                 {
1556                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1557                                                                                                 break;
1558                                                                                         unsafe = (safe + unsafe) * 0.5;
1559                                                                                 }
1560                                                                                 else
1561                                                                                 {
1562                                                                                         if((safe + unsafe) * 0.5 == safe)
1563                                                                                                 break;
1564                                                                                         safe = (safe + unsafe) * 0.5;
1565                                                                                 }
1566                                                                         }
1567
1568                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1569                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1570
1571                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1572                                                                         if(trace_startsolid)
1573                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1574                                                                         else
1575                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1576                                                                         break;
1577                                                                 }
1578
1579                                                                 q0 = p;
1580                                                                 dq = 0;
1581                                                                 dqf = 1;
1582                                                                 for(;;)
1583                                                                 {
1584                                                                         q = p + normalize(end - p) * (dq + dqf);
1585                                                                         if(q == q0)
1586                                                                                 break;
1587                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1588                                                                         if(trace_startsolid)
1589                                                                                 error("THIS ONE cannot happen");
1590                                                                         if(trace_fraction > 0)
1591                                                                                 dq += dqf * trace_fraction;
1592                                                                         dqf *= 0.5;
1593                                                                         q0 = q;
1594                                                                 }
1595                                                                 if(dq > 0)
1596                                                                 {
1597                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1598                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1599                                                                         break;
1600                                                                 }
1601                                                         }
1602                                                 }
1603                                         }
1604                                         return;
1605                                 }
1606
1607                                 case "debug2":
1608                                 {
1609                                         e = nextent(world);
1610                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1611                                         vv = trace_endpos;
1612                                         if(trace_fraction == 1)
1613                                         {
1614                                                 print("not above ground, aborting\n");
1615                                                 return;
1616                                         }
1617                                         f = 0;
1618                                         for(i = 0; i < 100000; ++i)
1619                                         {
1620                                                 dv = randomvec();
1621                                                 if(dv_z > 0)
1622                                                         dv = -1 * dv;
1623                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1624                                                 if(trace_startsolid)
1625                                                         print("bug 1\n");
1626                                                 if(trace_fraction == 1)
1627                                                 if(dv_z < f)
1628                                                 {
1629                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1630                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1631                                                         f = dv_z;
1632                                                 }
1633                                         }
1634                                         print("highest possible dist: ", ftos(f), "\n");
1635                                         return;
1636                                 }
1637
1638                                 case "walk":
1639                                 {
1640                                         if(argc == 3)
1641                                         {
1642                                                 e = nextent(world);
1643                                                 if(tracewalk(e, stov(argv(1)), e.mins, e.maxs, stov(argv(2)), MOVE_NORMAL))
1644                                                         print("can walk\n");
1645                                                 else
1646                                                         print("cannot walk\n");
1647                                                 return;
1648                                         }
1649                                 }
1650
1651                                 case "showline":
1652                                 {
1653                                         if(argc == 3)
1654                                         {
1655                                                 vv = stov(argv(1));
1656                                                 dv = stov(argv(2));
1657                                                 traceline(vv, dv, MOVE_NORMAL, world);
1658                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1659                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1660                                                 return;
1661                                         }
1662                                 }
1663
1664                                 // no default case, just go straight to invalid
1665                         }
1666                 }
1667
1668                 default:
1669                         print("Incorrect parameters for ^2trace^7\n");
1670                 case CMD_REQUEST_USAGE:
1671                 {
1672                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1673                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1674                         print("See also: ^2bbox, gettaginfo^7\n");
1675                         return;
1676                 }
1677         }
1678 }
1679
1680 void GameCommand_unlockteams(float request)
1681 {
1682         switch(request)
1683         {
1684                 case CMD_REQUEST_COMMAND:
1685                 {
1686                         if(teamplay)
1687                         {
1688                                 lockteams = 0;
1689                                 bprint("^1The teams are now unlocked.\n");
1690                         }
1691                         else
1692                         {
1693                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1694                         }
1695                         return;
1696                 }
1697
1698                 default:
1699                 case CMD_REQUEST_USAGE:
1700                 {
1701                         print("\nUsage:^3 sv_cmd unlockteams\n");
1702                         print("  No arguments required.\n");
1703                         print("See also: ^2lockteams^7\n");
1704                         return;
1705                 }
1706         }
1707 }
1708
1709 void GameCommand_warp(float request, float argc)
1710 {
1711         switch (request)
1712         {
1713                 case CMD_REQUEST_COMMAND:
1714                 {
1715                         if(autocvar_g_campaign)
1716                         {
1717                                 if(argc >= 2)
1718                                 {
1719                                         CampaignLevelWarp(stof(argv(1)));
1720                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1721                                 }
1722                                 else
1723                                 {
1724                                         CampaignLevelWarp(-1);
1725                                         print("Successfully warped to next campaign level.\n");
1726                                 }
1727                         }
1728                         else
1729                                 print("Not in campaign, can't level warp\n");
1730                         return;
1731                 }
1732
1733                 default:
1734                 case CMD_REQUEST_USAGE:
1735                 {
1736                         print("\nUsage:^3 sv_cmd warp [level]\n");
1737                         print("  'level' is the level to change campaign mode to.\n");
1738                         print("  if 'level' is not provided it will change to the next level.\n");
1739                         return;
1740                 }
1741         }
1742 }
1743
1744 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1745 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1746 void GameCommand_(float request)
1747 {
1748         switch(request)
1749         {
1750                 case CMD_REQUEST_COMMAND:
1751                 {
1752
1753                         return;
1754                 }
1755
1756                 default:
1757                 case CMD_REQUEST_USAGE:
1758                 {
1759                         print("\nUsage:^3 sv_cmd \n");
1760                         print("  No arguments required.\n");
1761                         return;
1762                 }
1763         }
1764 }
1765 */
1766
1767
1768 // ==================================
1769 //  Macro system for server commands
1770 // ==================================
1771
1772 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1773 // Common commands have double indentation to separate them a bit.
1774 #define SERVER_COMMANDS(request,arguments,command) \
1775         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1776         SERVER_COMMAND("butcher", GameCommand_butcher(request), "Instantly removes all monsters on the map") \
1777         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1778         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1779         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1780         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1781         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1782         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1783         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1784         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1785         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1786         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1787         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1788         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1789         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1790         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1791         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1792         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1793         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1794         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1795         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1796         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1797         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1798         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1799         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1800         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1801         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1802         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1803         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1804         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1805         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1806         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1807         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1808         /* nothing */
1809
1810 void GameCommand_macro_help()
1811 {
1812         #define SERVER_COMMAND(name,function,description) \
1813                 { print("  ^2", name, "^7: ", description, "\n"); }
1814
1815         SERVER_COMMANDS(0, 0, "")
1816         #undef SERVER_COMMAND
1817
1818         return;
1819 }
1820
1821 float GameCommand_macro_command(float argc, string command)
1822 {
1823         #define SERVER_COMMAND(name,function,description) \
1824                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1825
1826         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1827         #undef SERVER_COMMAND
1828
1829         return FALSE;
1830 }
1831
1832 float GameCommand_macro_usage(float argc)
1833 {
1834         #define SERVER_COMMAND(name,function,description) \
1835                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1836
1837         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1838         #undef SERVER_COMMAND
1839
1840         return FALSE;
1841 }
1842
1843 void GameCommand_macro_write_aliases(float fh)
1844 {
1845         #define SERVER_COMMAND(name,function,description) \
1846                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1847
1848         SERVER_COMMANDS(0, 0, "")
1849         #undef SERVER_COMMAND
1850
1851         return;
1852 }
1853
1854
1855 // =========================================
1856 //  Main Function Called By Engine (sv_cmd)
1857 // =========================================
1858 // If this function exists, game code handles gamecommand instead of the engine code.
1859
1860 void GameCommand(string command)
1861 {
1862         float argc = tokenize_console(command);
1863
1864         // Guide for working with argc arguments by example:
1865         // argc:   1    - 2      - 3     - 4
1866         // argv:   0    - 1      - 2     - 3
1867         // cmd     vote - master - login - password
1868
1869         if(strtolower(argv(0)) == "help")
1870         {
1871                 if(argc == 1)
1872                 {
1873                         print("\nServer console commands:\n");
1874                         GameCommand_macro_help();
1875
1876                         print("\nBanning commands:\n");
1877                         BanCommand_macro_help();
1878
1879                         print("\nCommon networked commands:\n");
1880                         CommonCommand_macro_help(world);
1881
1882                         print("\nGeneric commands shared by all programs:\n");
1883                         GenericCommand_macro_help();
1884
1885                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1886                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1887
1888                         return;
1889                 }
1890                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1891                 {
1892                         return;
1893                 }
1894                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1895                 {
1896                         return;
1897                 }
1898                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1899                 {
1900                         return;
1901                 }
1902                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1903                 {
1904                         return;
1905                 }
1906         }
1907         else if(BanCommand(command))
1908         {
1909                 return; // handled by server/command/ipban.qc
1910         }
1911         else if(CommonCommand_macro_command(argc, world, command))
1912         {
1913                 return; // handled by server/command/common.qc
1914         }
1915         else if(GenericCommand(command))
1916         {
1917                 return; // handled by common/command/generic.qc
1918         }
1919         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1920         {
1921                 return; // handled by one of the above GameCommand_* functions
1922         }
1923
1924         // nothing above caught the command, must be invalid
1925         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1926
1927         return;
1928 }