qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if not(accepted > 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_butcher(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 149
 150             float removed_count = 0;
 151                         entity montokill, head;
 152
 153             FOR_EACH_MONSTER(montokill)
 154             {
 155                                 WaypointSprite_Kill(montokill.sprite);
 156
 157                                 if(montokill.weaponentity)
 158                                         remove(montokill.weaponentity);
 159
 160                                 if(montokill.iceblock)
 161                                         remove(montokill.iceblock);
 162
 163                 remove(montokill);
 164                 removed_count += 1;
 165             }
 166
 167                         FOR_EACH_PLAYER(head)
 168                                 head.monstercount = 0;
 169
 170                         monsters_total = 0; // reset stats?
 171                         monsters_killed = 0;
 172
 173                         totalspawned = 0;
 174
 175                         if(removed_count <= 0)
 176                                 print("No monsters to kill\n");
 177                         else
 178                                 print(strcat("Killed ", ftos(removed_count), " monster", ((removed_count == 1) ? "\n" : "s\n")));
 179
 180                         return; // never fall through to usage
 181                 }
 182
 183                 default:
 184                 case CMD_REQUEST_USAGE:
 185                 {
 186                         print("\nUsage:^3 sv_cmd butcher\n");
 187                         print("  No arguments required.\n");
 188                         return;
 189                 }
 190         }
 191 }
 192
 193 void GameCommand_allready(float request)
 194 {
 195         switch(request)
 196         {
 197                 case CMD_REQUEST_COMMAND:
 198                 {
 199                         ReadyRestart();
 200                         return;
 201                 }
 202
 203                 default:
 204                 case CMD_REQUEST_USAGE:
 205                 {
 206                         print("\nUsage:^3 sv_cmd allready\n");
 207                         print("  No arguments required.\n");
 208                         return;
 209                 }
 210         }
 211 }
 212
 213 void GameCommand_allspec(float request, float argc)
 214 {
 215         switch(request)
 216         {
 217                 case CMD_REQUEST_COMMAND:
 218                 {
 219                         entity client;
 220                         string reason = argv(1);
 221                         float i = 0;
 222
 223                         FOR_EACH_REALPLAYER(client)
 224                         {
 225                                 self = client;
 226                                 PutObserverInServer();
 227                                 ++i;
 228                         }
 229                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 230                         else { print("No players found to spectate.\n"); }
 231                         return;
 232                 }
 233
 234                 default:
 235                 case CMD_REQUEST_USAGE:
 236                 {
 237                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 238                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 239                         print("See also: ^2moveplayer, shuffleteams^7\n");
 240                         return;
 241                 }
 242         }
 243 }
 244
 245 void GameCommand_anticheat(float request, float argc)
 246 {
 247         switch(request)
 248         {
 249                 case CMD_REQUEST_COMMAND:
 250                 {
 251                         entity client = GetIndexedEntity(argc, 1);
 252                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 253
 254                         if(accepted > 0)
 255                         {
 256                                 self = client;
 257                                 anticheat_report();
 258                                 return;
 259                         }
 260                         else
 261                         {
 262                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 263                         }
 264                 }
 265
 266                 default:
 267                         print("Incorrect parameters for ^2anticheat^7\n");
 268                 case CMD_REQUEST_USAGE:
 269                 {
 270                         print("\nUsage:^3 sv_cmd anticheat client\n");
 271                         print("  'client' is the entity number or name of the player.\n");
 272                         return;
 273                 }
 274         }
 275 }
 276
 277 void GameCommand_bbox(float request)
 278 {
 279         switch(request)
 280         {
 281                 case CMD_REQUEST_COMMAND:
 282                 {
 283                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 284                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 285                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 286                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 287                         print("Solid bounding box size:");
 288
 289                         tracebox('1 0 0' * world.absmin_x,
 290                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 291                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 292                                                         '1 0 0' * world.absmax_x,
 293                                         MOVE_WORLDONLY,
 294                                         world);
 295                         if(trace_startsolid)
 296                                 print(" ", ftos(world.absmin_x));
 297                         else
 298                                 print(" ", ftos(trace_endpos_x));
 299
 300                         tracebox('0 1 0' * world.absmin_y,
 301                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 302                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 303                                                         '0 1 0' * world.absmax_y,
 304                                         MOVE_WORLDONLY,
 305                                         world);
 306                         if(trace_startsolid)
 307                                 print(" ", ftos(world.absmin_y));
 308                         else
 309                                 print(" ", ftos(trace_endpos_y));
 310
 311                         tracebox('0 0 1' * world.absmin_z,
 312                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 313                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 314                                                         '0 0 1' * world.absmax_z,
 315                                         MOVE_WORLDONLY,
 316                                         world);
 317                         if(trace_startsolid)
 318                                 print(" ", ftos(world.absmin_z));
 319                         else
 320                                 print(" ", ftos(trace_endpos_z));
 321
 322                         tracebox('1 0 0' * world.absmax_x,
 323                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 324                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 325                                                         '1 0 0' * world.absmin_x,
 326                                         MOVE_WORLDONLY,
 327                                         world);
 328                         if(trace_startsolid)
 329                                 print(" ", ftos(world.absmax_x));
 330                         else
 331                                 print(" ", ftos(trace_endpos_x));
 332
 333                         tracebox('0 1 0' * world.absmax_y,
 334                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 335                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 336                                                         '0 1 0' * world.absmin_y,
 337                                         MOVE_WORLDONLY,
 338                                         world);
 339                         if(trace_startsolid)
 340                                 print(" ", ftos(world.absmax_y));
 341                         else
 342                                 print(" ", ftos(trace_endpos_y));
 343
 344                         tracebox('0 0 1' * world.absmax_z,
 345                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 346                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 347                                                         '0 0 1' * world.absmin_z,
 348                                         MOVE_WORLDONLY,
 349                                         world);
 350                         if(trace_startsolid)
 351                                 print(" ", ftos(world.absmax_z));
 352                         else
 353                                 print(" ", ftos(trace_endpos_z));
 354
 355                         print("\n");
 356                         return;
 357                 }
 358
 359                 default:
 360                 case CMD_REQUEST_USAGE:
 361                 {
 362                         print("\nUsage:^3 sv_cmd bbox\n");
 363                         print("  No arguments required.\n");
 364                         print("See also: ^2gettaginfo, trace^7\n");
 365                         return;
 366                 }
 367         }
 368 }
 369
 370 void GameCommand_bot_cmd(float request, float argc, string command)
 371 {
 372         switch(request)
 373         {
 374                 case CMD_REQUEST_COMMAND:
 375                 {
 376                         entity bot;
 377
 378                         if(argv(1) == "reset")
 379                         {
 380                                 bot_resetqueues();
 381                                 return;
 382                         }
 383                         else if(argv(1) == "setbots")
 384                         {
 385                                 cvar_settemp("bot_vs_human", "0");
 386                                 cvar_settemp("minplayers", "0");
 387                                 cvar_settemp("bot_number", "0");
 388                                 bot_fixcount();
 389                                 cvar_settemp("bot_number", argv(2));
 390                                 if(!bot_fixcount())
 391                                         print("Sorry, could not set requested bot count\n");
 392                                 return;
 393                         }
 394                         else if(argv(1) == "load" && argc == 3)
 395                         {
 396                                 float fh, i;
 397                                 string s;
 398                                 fh = fopen(argv(2), FILE_READ);
 399                                 if(fh < 0)
 400                                 {
 401                                         print("cannot open the file\n");
 402                                         return;
 403                                 }
 404
 405                                 i = 0;
 406                                 while((s = fgets(fh)))
 407                                 {
 408                                         argc = tokenize_console(s);
 409
 410                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 411                                         {
 412                                                 if(argv(2) == "reset")
 413                                                 {
 414                                                         bot_resetqueues();
 415                                                 }
 416                                                 else if(argv(2) == "setbots")
 417                                                 {
 418                                                         cvar_settemp("bot_vs_human", "0");
 419                                                         cvar_settemp("minplayers", "0");
 420                                                         cvar_settemp("bot_number", "0");
 421                                                         bot_fixcount();
 422                                                         cvar_settemp("bot_number", argv(3));
 423                                                         if(!bot_fixcount())
 424                                                                 print("Sorry, could not set requested bot count\n");
 425                                                 }
 426                                                 else
 427                                                 {
 428                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 429                                                         bot = find_bot_by_number(stof(argv(2)));
 430                                                         if(bot == world)
 431                                                                 bot = find_bot_by_name(argv(2));
 432                                                         if(bot)
 433                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 434                                                 }
 435                                         }
 436                                         else
 437                                                 localcmd(strcat(s, "\n"));
 438
 439                                         ++i;
 440                                 }
 441                                 print(ftos(i), " commands read\n");
 442                                 fclose(fh);
 443                                 return;
 444                         }
 445                         else if(argv(1) == "help")
 446                         {
 447                                 if(argv(2))
 448                                         bot_cmdhelp(argv(2));
 449                                 else
 450                                         bot_list_commands();
 451                                 return;
 452                         }
 453                         else if(argc >= 3) // this comes last
 454                         {
 455                                 bot = find_bot_by_number(stof(argv(1)));
 456                                 if(bot == world)
 457                                         bot = find_bot_by_name(argv(1));
 458                                 if(bot)
 459                                 {
 460                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 461                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 462                                         return;
 463                                 }
 464                                 else
 465                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 466                         }
 467                 }
 468
 469                 default:
 470                         print("Incorrect parameters for ^2bot_cmd^7\n");
 471                 case CMD_REQUEST_USAGE:
 472                 {
 473                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 474                         print("  'client' can be either the name or entity id of the bot\n");
 475                         print("  For full list of commands, see bot_cmd help [command].\n");
 476                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 477                         print("          sv_cmd bot_cmd client presskey jump\n");
 478                         return;
 479                 }
 480         }
 481 }
 482
 483 void GameCommand_cointoss(float request, float argc)
 484 {
 485         switch(request)
 486         {
 487                 case CMD_REQUEST_COMMAND:
 488                 {
 489                         entity client;
 490                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 491                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 492                         string choice = ((random() > 0.5) ? result1 : result2);
 493
 494                         FOR_EACH_CLIENT(client)
 495                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 496                         bprint(strcat("^3Throwing coin... Result: ", choice));
 497                         return;
 498                 }
 499
 500                 default:
 501                 case CMD_REQUEST_USAGE:
 502                 {
 503                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 504                         print("  Where 'result1' and 'result2' are user created options.\n");
 505                         return;
 506                 }
 507         }
 508 }
 509
 510 void GameCommand_database(float request, float argc)
 511 {
 512         switch(request)
 513         {
 514                 case CMD_REQUEST_COMMAND:
 515                 {
 516                         if(argc == 3)
 517                         {
 518                                 if(argv(1) == "save")
 519                                 {
 520                                         db_save(ServerProgsDB, argv(2));
 521                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 522                                         return;
 523                                 }
 524                                 else if(argv(1) == "dump")
 525                                 {
 526                                         db_dump(ServerProgsDB, argv(2));
 527                                         print("DB dumped.\n"); // wtf does this do?
 528                                         return;
 529                                 }
 530                                 else if(argv(1) == "load")
 531                                 {
 532                                         db_close(ServerProgsDB);
 533                                         ServerProgsDB = db_load(argv(2));
 534                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 535                                         return;
 536                                 }
 537                         }
 538                 }
 539
 540                 default:
 541                         print("Incorrect parameters for ^2database^7\n");
 542                 case CMD_REQUEST_USAGE:
 543                 {
 544                         print("\nUsage:^3 sv_cmd database action filename\n");
 545                         print("  Where 'action' is the command to complete,\n");
 546                         print("  and 'filename' is what it acts upon.\n");
 547                         print("  Full list of commands here: \"save, dump, load.\"\n");
 548                         return;
 549                 }
 550         }
 551 }
 552
 553 void GameCommand_defer_clear(float request, float argc)
 554 {
 555         switch(request)
 556         {
 557                 case CMD_REQUEST_COMMAND:
 558                 {
 559                         entity client;
 560                         float accepted;
 561
 562                         if(argc >= 2)
 563                         {
 564                                 client = GetIndexedEntity(argc, 1);
 565                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 566
 567                                 if(accepted > 0)
 568                                 {
 569                                         stuffcmd(client, "defer clear\n");
 570                                         print("defer clear stuffed to ", client.netname, "\n");
 571                                 }
 572                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 573
 574                                 return;
 575                         }
 576                 }
 577
 578                 default:
 579                         print("Incorrect parameters for ^2defer_clear^7\n");
 580                 case CMD_REQUEST_USAGE:
 581                 {
 582                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 583                         print("  'client' is the entity number or name of the player.\n");
 584                         print("See also: ^2defer_clear_all^7\n");
 585                         return;
 586                 }
 587         }
 588 }
 589
 590 void GameCommand_defer_clear_all(float request)
 591 {
 592         switch(request)
 593         {
 594                 case CMD_REQUEST_COMMAND:
 595                 {
 596                         entity client;
 597                         float i = 0;
 598                         float argc;
 599
 600                         FOR_EACH_CLIENT(client)
 601                         {
 602                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 603                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 604                                 ++i;
 605                         }
 606                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 607                         return;
 608                 }
 609
 610                 default:
 611                 case CMD_REQUEST_USAGE:
 612                 {
 613                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 614                         print("  No arguments required.\n");
 615                         print("See also: ^2defer_clear^7\n");
 616                         return;
 617                 }
 618         }
 619 }
 620
 621 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 622 {
 623         switch(request)
 624         {
 625                 case CMD_REQUEST_COMMAND:
 626                 {
 627                         if(argv(1))
 628                         {
 629                                 if(argv(2))
 630                                         race_deleteTime(argv(2), stof(argv(1)));
 631                                 else
 632                                         race_deleteTime(GetMapname(), stof(argv(1)));
 633                                 return;
 634                         }
 635                 }
 636
 637                 default:
 638                         print("Incorrect parameters for ^2delrec^7\n");
 639                 case CMD_REQUEST_USAGE:
 640                 {
 641                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 642                         print("  'ranking' is which ranking level to clear up to, \n");
 643                         print("  it will clear all records up to nth place.\n");
 644                         print("  if 'map' is not provided it will use current map.\n");
 645                         return;
 646                 }
 647         }
 648 }
 649
 650 void GameCommand_effectindexdump(float request)
 651 {
 652         switch(request)
 653         {
 654                 case CMD_REQUEST_COMMAND:
 655                 {
 656                         float fh, d;
 657                         string s;
 658
 659                         d = db_create();
 660                         print("begin of effects list\n");
 661                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 662                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 663                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 664                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 665                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 666                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 667                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 668                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 669                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 670                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 671                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 672                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 673                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 674                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 675                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 676                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 677                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 678                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 679                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 680                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 681                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 682                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 683                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 684                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 685                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 686                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 687                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 688                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 689                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 690                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 691                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 692                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 693                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 694                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 695                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 696                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 697
 698                         fh = fopen("effectinfo.txt", FILE_READ);
 699                         while((s = fgets(fh)))
 700                         {
 701                                 tokenize_console(s);
 702                                 if(argv(0) == "effect")
 703                                 {
 704                                         if(db_get(d, argv(1)) != "1")
 705                                         {
 706                                                 if(particleeffectnum(argv(1)) >= 0)
 707                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 708                                                 db_put(d, argv(1), "1");
 709                                         }
 710                                 }
 711                         }
 712                         print("end of effects list\n");
 713
 714                         db_close(d);
 715                         return;
 716                 }
 717
 718                 default:
 719                 case CMD_REQUEST_USAGE:
 720                 {
 721                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 722                         print("  No arguments required.\n");
 723                         return;
 724                 }
 725         }
 726 }
 727
 728 void GameCommand_extendmatchtime(float request)
 729 {
 730         switch(request)
 731         {
 732                 case CMD_REQUEST_COMMAND:
 733                 {
 734                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 735                         return;
 736                 }
 737
 738                 default:
 739                 case CMD_REQUEST_USAGE:
 740                 {
 741                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 742                         print("  No arguments required.\n");
 743                         print("See also: ^2reducematchtime^7\n");
 744                         return;
 745                 }
 746         }
 747 }
 748
 749 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 750 {
 751         switch(request)
 752         {
 753                 case CMD_REQUEST_COMMAND:
 754                 {
 755                         entity client;
 756
 757                         for(client = world; (client = find(client, classname, argv(1))); )
 758                                 print(etos(client), "\n");
 759
 760                         return;
 761                 }
 762
 763                 default:
 764                         print("Incorrect parameters for ^2find^7\n");
 765                 case CMD_REQUEST_USAGE:
 766                 {
 767                         print("\nUsage:^3 sv_cmd find classname\n");
 768                         print("  Where 'classname' is the classname to search for.\n");
 769                         return;
 770                 }
 771         }
 772 }
 773
 774 void GameCommand_gametype(float request, float argc)
 775 {
 776         switch(request)
 777         {
 778                 case CMD_REQUEST_COMMAND:
 779                 {
 780                         if(argv(1) != "")
 781                         {
 782                                 string s = argv(1);
 783                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 784
 785                                 if(t)
 786                                 {
 787                                         MapInfo_SwitchGameType(t);
 788                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 789                                         if(MapInfo_count > 0)
 790                                                 bprint("Game type successfully switched to ", s, "\n");
 791                                         else
 792                                         {
 793                                                 bprint("Cannot use this game type: no map for it found\n");
 794                                                 MapInfo_SwitchGameType(tsave);
 795                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 796                                         }
 797                                 }
 798                                 else
 799                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 800
 801                                 return;
 802                         }
 803                 }
 804
 805                 default:
 806                         print("Incorrect parameters for ^2gametype^7\n");
 807                 case CMD_REQUEST_USAGE:
 808                 {
 809                         print("\nUsage:^3 sv_cmd gametype mode\n");
 810                         print("  Where 'mode' is the gametype mode to switch to.\n");
 811                         print("See also: ^2gotomap^7\n");
 812                         return;
 813                 }
 814         }
 815 }
 816
 817 void GameCommand_gettaginfo(float request, float argc)
 818 {
 819         switch(request)
 820         {
 821                 case CMD_REQUEST_COMMAND:
 822                 {
 823                         entity tmp_entity;
 824                         float i;
 825                         vector v;
 826
 827                         if(argc >= 4)
 828                         {
 829                                 tmp_entity = spawn();
 830                                 if(argv(1) == "w")
 831                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 832                                 else
 833                                 {
 834                                         precache_model(argv(1));
 835                                         setmodel(tmp_entity, argv(1));
 836                                 }
 837                                 tmp_entity.frame = stof(argv(2));
 838                                 if(substring(argv(3), 0, 1) == "#")
 839                                         i = stof(substring(argv(3), 1, -1));
 840                                 else
 841                                         i = gettagindex(tmp_entity, argv(3));
 842                                 if(i)
 843                                 {
 844                                         v = gettaginfo(tmp_entity, i);
 845                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 846                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 847                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 848                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 849                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 850                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 851                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 852                                         if(argc >= 6)
 853                                         {
 854                                                 v_y = -v_y;
 855                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 856                                         }
 857                                 }
 858                                 else
 859                                         print("bone not found\n");
 860
 861                                 remove(tmp_entity);
 862                                 return;
 863                         }
 864                 }
 865
 866                 default:
 867                         print("Incorrect parameters for ^2gettaginfo^7\n");
 868                 case CMD_REQUEST_USAGE:
 869                 {
 870                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 871                         print("See also: ^2bbox, trace^7\n");
 872                         return;
 873                 }
 874         }
 875 }
 876
 877 void GameCommand_animbench(float request, float argc)
 878 {
 879         switch(request)
 880         {
 881                 case CMD_REQUEST_COMMAND:
 882                 {
 883                         entity tmp_entity;
 884
 885                         if(argc >= 4)
 886                         {
 887                                 tmp_entity = spawn();
 888                                 if(argv(1) == "w")
 889                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 890                                 else
 891                                 {
 892                                         precache_model(argv(1));
 893                                         setmodel(tmp_entity, argv(1));
 894                                 }
 895                                 float f1 = stof(argv(2));
 896                                 float f2 = stof(argv(3));
 897                                 float t0;
 898                                 float t1 = 0;
 899                                 float t2 = 0;
 900                                 float n = 0;
 901
 902                                 while(t1 + t2 < 1)
 903                                 {
 904                                         tmp_entity.frame = f1;
 905                                         t0 = gettime(GETTIME_HIRES);
 906                                         getsurfacepoint(tmp_entity, 0, 0);
 907                                         t1 += gettime(GETTIME_HIRES) - t0;
 908                                         tmp_entity.frame = f2;
 909                                         t0 = gettime(GETTIME_HIRES);
 910                                         getsurfacepoint(tmp_entity, 0, 0);
 911                                         t2 += gettime(GETTIME_HIRES) - t0;
 912                                         n += 1;
 913                                 }
 914                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 915                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 916
 917                                 remove(tmp_entity);
 918                                 return;
 919                         }
 920                 }
 921
 922                 default:
 923                         print("Incorrect parameters for ^2gettaginfo^7\n");
 924                 case CMD_REQUEST_USAGE:
 925                 {
 926                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 927                         print("See also: ^2bbox, trace^7\n");
 928                         return;
 929                 }
 930         }
 931 }
 932
 933 void GameCommand_gotomap(float request, float argc)
 934 {
 935         switch(request)
 936         {
 937                 case CMD_REQUEST_COMMAND:
 938                 {
 939                         if(argv(1))
 940                         {
 941                                 print(GotoMap(argv(1)), "\n");
 942                                 return;
 943                         }
 944                 }
 945
 946                 default:
 947                         print("Incorrect parameters for ^2gotomap^7\n");
 948                 case CMD_REQUEST_USAGE:
 949                 {
 950                         print("\nUsage:^3 sv_cmd gotomap map\n");
 951                         print("  Where 'map' is the *.bsp file to change to.\n");
 952                         print("See also: ^2gametype^7\n");
 953                         return;
 954                 }
 955         }
 956 }
 957
 958 void GameCommand_lockteams(float request)
 959 {
 960         switch(request)
 961         {
 962                 case CMD_REQUEST_COMMAND:
 963                 {
 964                         if(teamplay)
 965                         {
 966                                 lockteams = 1;
 967                                 bprint("^1The teams are now locked.\n");
 968                         }
 969                         else
 970                         {
 971                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 972                         }
 973                         return;
 974                 }
 975
 976                 default:
 977                 case CMD_REQUEST_USAGE:
 978                 {
 979                         print("\nUsage:^3 sv_cmd lockteams\n");
 980                         print("  No arguments required.\n");
 981                         print("See also: ^2unlockteams^7\n");
 982                         return;
 983                 }
 984         }
 985 }
 986
 987 void GameCommand_make_mapinfo(float request)
 988 {
 989         switch(request)
 990         {
 991                 case CMD_REQUEST_COMMAND:
 992                 {
 993                         entity tmp_entity;
 994
 995                         tmp_entity = spawn();
 996                         tmp_entity.classname = "make_mapinfo";
 997                         tmp_entity.think = make_mapinfo_Think;
 998                         tmp_entity.nextthink = time;
 999                         MapInfo_Enumerate();
1000                         return;
1001                 }
1002
1003                 default:
1004                 case CMD_REQUEST_USAGE:
1005                 {
1006                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1007                         print("  No arguments required.\n");
1008                         print("See also: ^2radarmap^7\n");
1009                         return;
1010                 }
1011         }
1012 }
1013
1014 void GameCommand_moveplayer(float request, float argc)
1015 {
1016         switch(request)
1017         {
1018                 case CMD_REQUEST_COMMAND:
1019                 {
1020                         float accepted;
1021                         entity client;
1022
1023                         string targets = strreplace(",", " ", argv(1));
1024                         string original_targets = strreplace(" ", ", ", targets);
1025                         string destination = argv(2);
1026
1027                         string successful, t;
1028                         successful = string_null;
1029
1030                         // lets see if the target(s) even actually exist.
1031                         if((targets) && (destination))
1032                         {
1033                                 for(;targets;)
1034                                 {
1035                                         t = car(targets); targets = cdr(targets);
1036
1037                                         // Check to see if the player is a valid target
1038                                         client = GetFilteredEntity(t);
1039                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
1040
1041                                         if not(accepted > 0)
1042                                         {
1043                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1044                                                 continue;
1045                                         }
1046
1047                                         // Where are we putting this player?
1048                                         if(destination == "spec" || destination == "spectator")
1049                                         {
1050                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1051                                                 {
1052                                                         self = client;
1053                                                         PutObserverInServer();
1054
1055                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1056                                                 }
1057                                                 else
1058                                                 {
1059                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1060                                                 }
1061                                                 continue;
1062                                         }
1063                                         else
1064                                         {
1065                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1066                                                 {
1067                                                         if(teamplay)
1068                                                         {
1069                                                                 // set up
1070                                                                 float team_id;
1071                                                                 float save = client.team_forced;
1072                                                                 client.team_forced = 0;
1073
1074                                                                 // find the team to move the player to
1075                                                                 team_id = Team_ColorToTeam(destination);
1076                                                                 if(team_id == client.team) // already on the destination team
1077                                                                 {
1078                                                                         // keep the forcing undone
1079                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1080                                                                         continue;
1081                                                                 }
1082                                                                 else if(team_id == 0)  // auto team
1083                                                                 {
1084                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1085                                                                 }
1086                                                                 else
1087                                                                 {
1088                                                                         CheckAllowedTeams(client);
1089                                                                 }
1090                                                                 client.team_forced = save;
1091
1092                                                                 // Check to see if the destination team is even available
1093                                                                 switch(team_id)
1094                                                                 {
1095                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1096                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1097                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1098                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1099
1100                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1101                                                                 }
1102
1103                                                                 // If so, lets continue and finally move the player
1104                                                                 client.team_forced = 0;
1105                                                                 MoveToTeam(client, team_id, 6);
1106                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1107                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1108                                                                 continue;
1109                                                         }
1110                                                         else
1111                                                         {
1112                                                                 print("Can't change teams when currently not playing a team game.\n");
1113                                                                 return;
1114                                                         }
1115                                                 }
1116                                                 else
1117                                                 {
1118                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1119                                                         return;
1120                                                 }
1121                                         }
1122                                 }
1123
1124                                 if(successful)
1125                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1126                                 else
1127                                         print("No players given (", original_targets, ") are able to move.\n");
1128
1129                                 return; // still correct parameters so return to avoid usage print
1130                         }
1131                 }
1132
1133                 default:
1134                         print("Incorrect parameters for ^2moveplayer^7\n");
1135                 case CMD_REQUEST_USAGE:
1136                 {
1137                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1138                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1139                         print("  'destination' is what to send the player to, be it team or spectating\n");
1140                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1141                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1142                         print("          sv_cmd moveplayer 2 spec \n");
1143                         print("See also: ^2allspec, shuffleteams^7\n");
1144                         return;
1145                 }
1146         }
1147 }
1148
1149 void GameCommand_nospectators(float request)
1150 {
1151         switch(request)
1152         {
1153                 case CMD_REQUEST_COMMAND:
1154                 {
1155                         blockSpectators = 1;
1156                         entity plr;
1157                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1158                         {
1159                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1160                                 {
1161                                         plr.spectatortime = time;
1162                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1163                                 }
1164                         }
1165                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1166                         return;
1167                 }
1168
1169                 default:
1170                 case CMD_REQUEST_USAGE:
1171                 {
1172                         print("\nUsage:^3 sv_cmd nospectators\n");
1173                         print("  No arguments required.\n");
1174                         return;
1175                 }
1176         }
1177 }
1178
1179 void GameCommand_playerdemo(float request, float argc)
1180 {
1181         switch(request)
1182         {
1183                 case CMD_REQUEST_COMMAND:
1184                 {
1185                         if(argv(2) && argv(3))
1186                         {
1187                                 entity client;
1188                                 float i, n, accepted;
1189
1190                                 switch(argv(1))
1191                                 {
1192                                         case "read":
1193                                         {
1194                                                 client = GetIndexedEntity(argc, 2);
1195                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1196
1197                                                 if not(accepted > 0)
1198                                                 {
1199                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1200                                                         return;
1201                                                 }
1202
1203                                                 self = client;
1204                                                 playerdemo_open_read(argv(next_token));
1205                                                 return;
1206                                         }
1207
1208                                         case "write":
1209                                         {
1210                                                 client = GetIndexedEntity(argc, 2);
1211                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1212
1213                                                 if not(accepted > 0)
1214                                                 {
1215                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1216                                                         return;
1217                                                 }
1218
1219                                                 self = client;
1220                                                 playerdemo_open_write(argv(next_token));
1221                                                 return;
1222                                         }
1223
1224                                         case "auto_read_and_write":
1225                                         {
1226                                                 n = GetFilteredNumber(argv(3));
1227                                                 cvar_set("bot_number", ftos(n));
1228
1229                                                 localcmd("wait; wait; wait\n");
1230                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1231
1232                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1233                                                 return;
1234                                         }
1235
1236                                         case "auto_read":
1237                                         {
1238                                                 n = GetFilteredNumber(argv(3));
1239                                                 cvar_set("bot_number", ftos(n));
1240
1241                                                 localcmd("wait; wait; wait\n");
1242                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1243                                                 return;
1244                                         }
1245                                 }
1246                         }
1247                 }
1248
1249                 default:
1250                         print("Incorrect parameters for ^2playerdemo^7\n");
1251                 case CMD_REQUEST_USAGE:
1252                 {
1253                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1254                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1255                         return;
1256                 }
1257         }
1258 }
1259
1260 void GameCommand_printstats(float request)
1261 {
1262         switch(request)
1263         {
1264                 case CMD_REQUEST_COMMAND:
1265                 {
1266                         DumpStats(FALSE);
1267                         print("stats dumped.\n");
1268                         return;
1269                 }
1270
1271                 default:
1272                 case CMD_REQUEST_USAGE:
1273                 {
1274                         print("\nUsage:^3 sv_cmd printstats\n");
1275                         print("  No arguments required.\n");
1276                         return;
1277                 }
1278         }
1279 }
1280
1281 void GameCommand_radarmap(float request, float argc)
1282 {
1283         switch(request)
1284         {
1285                 case CMD_REQUEST_COMMAND:
1286                 {
1287                         if(RadarMap_Make(argc))
1288                                 return;
1289                 }
1290
1291                 default:
1292                         print("Incorrect parameters for ^2radarmap^7\n");
1293                 case CMD_REQUEST_USAGE:
1294                 {
1295                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1296                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1297                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1298                         print("See also: ^2make_mapinfo^7\n");
1299                         return;
1300                 }
1301         }
1302 }
1303
1304 void GameCommand_reducematchtime(float request)
1305 {
1306         switch(request)
1307         {
1308                 case CMD_REQUEST_COMMAND:
1309                 {
1310                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1311                         return;
1312                 }
1313
1314                 default:
1315                 case CMD_REQUEST_USAGE:
1316                 {
1317                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1318                         print("  No arguments required.\n");
1319                         print("See also: ^2extendmatchtime^7\n");
1320                         return;
1321                 }
1322         }
1323 }
1324
1325 void GameCommand_setbots(float request, float argc)
1326 {
1327         switch(request)
1328         {
1329                 case CMD_REQUEST_COMMAND:
1330                 {
1331                         if(argc >= 2)
1332                         {
1333                                 cvar_settemp("minplayers", "0");
1334                                 cvar_settemp("bot_number", argv(1));
1335                                 bot_fixcount();
1336                                 return;
1337                         }
1338                 }
1339
1340                 default:
1341                         print("Incorrect parameters for ^2setbots^7\n");
1342                 case CMD_REQUEST_USAGE:
1343                 {
1344                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1345                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1346                         print("See also: ^2bot_cmd^7\n");
1347                         return;
1348                 }
1349         }
1350 }
1351
1352 void GameCommand_shuffleteams(float request)
1353 {
1354         switch(request)
1355         {
1356                 case CMD_REQUEST_COMMAND:
1357                 {
1358                         if(teamplay)
1359                         {
1360                                 entity tmp_player;
1361                                 float i, x, z, t_teams, t_players, team_color;
1362
1363                                 // count the total amount of players and total amount of teams
1364                                 t_players = 0;
1365                                 t_teams = 0;
1366                                 FOR_EACH_PLAYER(tmp_player)
1367                                 {
1368                                         CheckAllowedTeams(tmp_player);
1369
1370                                         if(c1 >= 0) t_teams = max(1, t_teams);
1371                                         if(c2 >= 0) t_teams = max(2, t_teams);
1372                                         if(c3 >= 0) t_teams = max(3, t_teams);
1373                                         if(c4 >= 0) t_teams = max(4, t_teams);
1374
1375                                         ++t_players;
1376                                 }
1377
1378                                 // build a list of the players in a random order
1379                                 FOR_EACH_PLAYER(tmp_player)
1380                                 {
1381                                         for(;;)
1382                                         {
1383                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1384
1385                                                 if(shuffleteams_players[i])
1386                                                 {
1387                                                         continue; // a player is already assigned to this slot
1388                                                 }
1389                                                 else
1390                                                 {
1391                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1392                                                         break;
1393                                                 }
1394                                         }
1395                                 }
1396
1397                                 // finally, from the list made earlier, re-join the players in different order.
1398                                 for(i = 1; i <= t_teams; ++i)
1399                                 {
1400                                         // find out how many players to assign to this team
1401                                         x = (t_players / t_teams);
1402                                         x = ((i == 1) ? ceil(x) : floor(x));
1403
1404                                         team_color = Team_NumberToTeam(i);
1405
1406                                         // sort through the random list of players made earlier
1407                                         for(z = 1; z <= maxclients; ++z)
1408                                         {
1409                                                 if not(shuffleteams_teams[i] >= x)
1410                                                 {
1411                                                         if not(shuffleteams_players[z])
1412                                                                 continue; // not a player, move on to next random slot
1413
1414                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1415                                                                 self = edict_num(shuffleteams_players[z]);
1416
1417                                                         if(self.team != team_color)
1418                                                                 MoveToTeam(self, team_color, 6);
1419
1420                                                         shuffleteams_players[z] = 0;
1421                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1422                                                 }
1423                                                 else
1424                                                 {
1425                                                         break; // move on to next team
1426                                                 }
1427                                         }
1428                                 }
1429
1430                                 bprint("Successfully shuffled the players around randomly.\n");
1431
1432                                 // clear the buffers now
1433                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1434                                         shuffleteams_players[i] = 0;
1435
1436                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1437                                         shuffleteams_teams[i] = 0;
1438                         }
1439                         else
1440                         {
1441                                 print("Can't shuffle teams when currently not playing a team game.\n");
1442                         }
1443
1444                         return;
1445                 }
1446
1447                 default:
1448                 case CMD_REQUEST_USAGE:
1449                 {
1450                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1451                         print("  No arguments required.\n");
1452                         print("See also: ^2moveplayer, allspec^7\n");
1453                         return;
1454                 }
1455         }
1456 }
1457
1458 void GameCommand_stuffto(float request, float argc)
1459 {
1460         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1461         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1462         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1463
1464         #ifdef STUFFTO_ENABLED
1465         #message "stuffto command enabled"
1466         switch(request)
1467         {
1468                 case CMD_REQUEST_COMMAND:
1469                 {
1470                         if(argv(2))
1471                         {
1472                                 entity client = GetIndexedEntity(argc, 1);
1473                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1474
1475                                 if(accepted > 0)
1476                                 {
1477                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1478                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1479                                 }
1480                                 else
1481                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1482
1483                                 return;
1484                         }
1485                 }
1486
1487                 default:
1488                         print("Incorrect parameters for ^2stuffto^7\n");
1489                 case CMD_REQUEST_USAGE:
1490                 {
1491                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1492                         print("  'client' is the entity number or name of the player,\n");
1493                         print("  and 'command' is the command to be sent to that player.\n");
1494                         return;
1495                 }
1496         }
1497         #else
1498         if(request)
1499         {
1500                 print("stuffto command is not enabled on this server.\n");
1501                 return;
1502         }
1503         #endif
1504 }
1505
1506 void GameCommand_trace(float request, float argc)
1507 {
1508         switch(request)
1509         {
1510                 case CMD_REQUEST_COMMAND:
1511                 {
1512                         entity e;
1513                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1514                         float i, f, safe, unsafe, dq, dqf;
1515
1516                         switch(argv(1))
1517                         {
1518                                 case "debug":
1519                                 {
1520                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1521                                         for(;;)
1522                                         {
1523                                                 org = world.mins;
1524                                                 delta = world.maxs - world.mins;
1525
1526                                                 start_x = org_x + random() * delta_x;
1527                                                 start_y = org_y + random() * delta_y;
1528                                                 start_z = org_z + random() * delta_z;
1529
1530                                                 end_x = org_x + random() * delta_x;
1531                                                 end_y = org_y + random() * delta_y;
1532                                                 end_z = org_z + random() * delta_z;
1533
1534                                                 start = stov(vtos(start));
1535                                                 end = stov(vtos(end));
1536
1537                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1538                                                 if(!trace_startsolid)
1539                                                 {
1540                                                         p = trace_endpos;
1541                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1542                                                         if(trace_startsolid || trace_fraction == 1)
1543                                                         {
1544                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1545                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1546
1547                                                                 if(trace_startsolid)
1548                                                                 {
1549                                                                         // how much do we need to back off?
1550                                                                         safe = 1;
1551                                                                         unsafe = 0;
1552                                                                         for(;;)
1553                                                                         {
1554                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1555                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1556                                                                                 if(trace_startsolid)
1557                                                                                 {
1558                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1559                                                                                                 break;
1560                                                                                         unsafe = (safe + unsafe) * 0.5;
1561                                                                                 }
1562                                                                                 else
1563                                                                                 {
1564                                                                                         if((safe + unsafe) * 0.5 == safe)
1565                                                                                                 break;
1566                                                                                         safe = (safe + unsafe) * 0.5;
1567                                                                                 }
1568                                                                         }
1569
1570                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1571                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1572
1573                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1574                                                                         if(trace_startsolid)
1575                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1576                                                                         else
1577                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1578                                                                         break;
1579                                                                 }
1580
1581                                                                 q0 = p;
1582                                                                 dq = 0;
1583                                                                 dqf = 1;
1584                                                                 for(;;)
1585                                                                 {
1586                                                                         q = p + normalize(end - p) * (dq + dqf);
1587                                                                         if(q == q0)
1588                                                                                 break;
1589                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1590                                                                         if(trace_startsolid)
1591                                                                                 error("THIS ONE cannot happen");
1592                                                                         if(trace_fraction > 0)
1593                                                                                 dq += dqf * trace_fraction;
1594                                                                         dqf *= 0.5;
1595                                                                         q0 = q;
1596                                                                 }
1597                                                                 if(dq > 0)
1598                                                                 {
1599                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1600                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1601                                                                         break;
1602                                                                 }
1603                                                         }
1604                                                 }
1605                                         }
1606                                         return;
1607                                 }
1608
1609                                 case "debug2":
1610                                 {
1611                                         e = nextent(world);
1612                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1613                                         vv = trace_endpos;
1614                                         if(trace_fraction == 1)
1615                                         {
1616                                                 print("not above ground, aborting\n");
1617                                                 return;
1618                                         }
1619                                         f = 0;
1620                                         for(i = 0; i < 100000; ++i)
1621                                         {
1622                                                 dv = randomvec();
1623                                                 if(dv_z > 0)
1624                                                         dv = -1 * dv;
1625                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1626                                                 if(trace_startsolid)
1627                                                         print("bug 1\n");
1628                                                 if(trace_fraction == 1)
1629                                                 if(dv_z < f)
1630                                                 {
1631                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1632                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1633                                                         f = dv_z;
1634                                                 }
1635                                         }
1636                                         print("highest possible dist: ", ftos(f), "\n");
1637                                         return;
1638                                 }
1639
1640                                 case "walk":
1641                                 {
1642                                         if(argc == 4)
1643                                         {
1644                                                 e = nextent(world);
1645                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1646                                                         print("can walk\n");
1647                                                 else
1648                                                         print("cannot walk\n");
1649                                                 return;
1650                                         }
1651                                 }
1652
1653                                 case "showline":
1654                                 {
1655                                         if(argc == 4)
1656                                         {
1657                                                 vv = stov(argv(2));
1658                                                 dv = stov(argv(3));
1659                                                 traceline(vv, dv, MOVE_NORMAL, world);
1660                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1661                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1662                                                 return;
1663                                         }
1664                                 }
1665
1666                                 // no default case, just go straight to invalid
1667                         }
1668                 }
1669
1670                 default:
1671                         print("Incorrect parameters for ^2trace^7\n");
1672                 case CMD_REQUEST_USAGE:
1673                 {
1674                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1675                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1676                         print("See also: ^2bbox, gettaginfo^7\n");
1677                         return;
1678                 }
1679         }
1680 }
1681
1682 void GameCommand_unlockteams(float request)
1683 {
1684         switch(request)
1685         {
1686                 case CMD_REQUEST_COMMAND:
1687                 {
1688                         if(teamplay)
1689                         {
1690                                 lockteams = 0;
1691                                 bprint("^1The teams are now unlocked.\n");
1692                         }
1693                         else
1694                         {
1695                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1696                         }
1697                         return;
1698                 }
1699
1700                 default:
1701                 case CMD_REQUEST_USAGE:
1702                 {
1703                         print("\nUsage:^3 sv_cmd unlockteams\n");
1704                         print("  No arguments required.\n");
1705                         print("See also: ^2lockteams^7\n");
1706                         return;
1707                 }
1708         }
1709 }
1710
1711 void GameCommand_warp(float request, float argc)
1712 {
1713         switch (request)
1714         {
1715                 case CMD_REQUEST_COMMAND:
1716                 {
1717                         if(autocvar_g_campaign)
1718                         {
1719                                 if(argc >= 2)
1720                                 {
1721                                         CampaignLevelWarp(stof(argv(1)));
1722                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1723                                 }
1724                                 else
1725                                 {
1726                                         CampaignLevelWarp(-1);
1727                                         print("Successfully warped to next campaign level.\n");
1728                                 }
1729                         }
1730                         else
1731                                 print("Not in campaign, can't level warp\n");
1732                         return;
1733                 }
1734
1735                 default:
1736                 case CMD_REQUEST_USAGE:
1737                 {
1738                         print("\nUsage:^3 sv_cmd warp [level]\n");
1739                         print("  'level' is the level to change campaign mode to.\n");
1740                         print("  if 'level' is not provided it will change to the next level.\n");
1741                         return;
1742                 }
1743         }
1744 }
1745
1746 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1747 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1748 void GameCommand_(float request)
1749 {
1750         switch(request)
1751         {
1752                 case CMD_REQUEST_COMMAND:
1753                 {
1754
1755                         return;
1756                 }
1757
1758                 default:
1759                 case CMD_REQUEST_USAGE:
1760                 {
1761                         print("\nUsage:^3 sv_cmd \n");
1762                         print("  No arguments required.\n");
1763                         return;
1764                 }
1765         }
1766 }
1767 */
1768
1769
1770 // ==================================
1771 //  Macro system for server commands
1772 // ==================================
1773
1774 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1775 #define SERVER_COMMANDS(request,arguments,command) \
1776         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1777         SERVER_COMMAND("butcher", GameCommand_butcher(request), "Instantly removes all monsters on the map") \
1778         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1779         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1780         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1781         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1782         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1783         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1784         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1785         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1786         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1787         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1788         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1789         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1790         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1791         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1792         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1793         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1794         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1795         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1796         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1797         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1798         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1799         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1800         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1801         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1802         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1803         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1804         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1805         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1806         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1807         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1808         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1809         /* nothing */
1810
1811 void GameCommand_macro_help()
1812 {
1813         #define SERVER_COMMAND(name,function,description) \
1814                 { print("  ^2", name, "^7: ", description, "\n"); }
1815
1816         SERVER_COMMANDS(0, 0, "")
1817         #undef SERVER_COMMAND
1818
1819         return;
1820 }
1821
1822 float GameCommand_macro_command(float argc, string command)
1823 {
1824         #define SERVER_COMMAND(name,function,description) \
1825                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1826
1827         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1828         #undef SERVER_COMMAND
1829
1830         return FALSE;
1831 }
1832
1833 float GameCommand_macro_usage(float argc)
1834 {
1835         #define SERVER_COMMAND(name,function,description) \
1836                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1837
1838         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1839         #undef SERVER_COMMAND
1840
1841         return FALSE;
1842 }
1843
1844 void GameCommand_macro_write_aliases(float fh)
1845 {
1846         #define SERVER_COMMAND(name,function,description) \
1847                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1848
1849         SERVER_COMMANDS(0, 0, "")
1850         #undef SERVER_COMMAND
1851
1852         return;
1853 }
1854
1855
1856 // =========================================
1857 //  Main Function Called By Engine (sv_cmd)
1858 // =========================================
1859 // If this function exists, game code handles gamecommand instead of the engine code.
1860
1861 void GameCommand(string command)
1862 {
1863         float argc = tokenize_console(command);
1864
1865         // Guide for working with argc arguments by example:
1866         // argc:   1    - 2      - 3     - 4
1867         // argv:   0    - 1      - 2     - 3
1868         // cmd     vote - master - login - password
1869
1870         if(strtolower(argv(0)) == "help")
1871         {
1872                 if(argc == 1)
1873                 {
1874                         print("\nServer console commands:\n");
1875                         GameCommand_macro_help();
1876
1877                         print("\nBanning commands:\n");
1878                         BanCommand_macro_help();
1879
1880                         print("\nCommon networked commands:\n");
1881                         CommonCommand_macro_help(world);
1882
1883                         print("\nGeneric commands shared by all programs:\n");
1884                         GenericCommand_macro_help();
1885
1886                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1887                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1888
1889                         return;
1890                 }
1891                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1892                 {
1893                         return;
1894                 }
1895                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1896                 {
1897                         return;
1898                 }
1899                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1900                 {
1901                         return;
1902                 }
1903                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1904                 {
1905                         return;
1906                 }
1907         }
1908         else if(BanCommand(command))
1909         {
1910                 return; // handled by server/command/ipban.qc
1911         }
1912         else if(CommonCommand_macro_command(argc, world, command))
1913         {
1914                 return; // handled by server/command/common.qc
1915         }
1916         else if(GenericCommand(command))
1917         {
1918                 return; // handled by common/command/generic.qc
1919         }
1920         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1921         {
1922                 return; // handled by one of the above GameCommand_* functions
1923         }
1924
1925         // nothing above caught the command, must be invalid
1926         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1927
1928         return;
1929 }