qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags, i, f, b;
  39         entity e;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         nags = 0;
  53         if (readycount)
  54         {
  55                 nags |= BIT(0);
  56                 if (to.ready == 0) nags |= BIT(1);
  57         }
  58         if (vote_called)
  59         {
  60                 nags |= BIT(2);
  61                 if (to.vote_selection == 0) nags |= BIT(3);
  62         }
  63         if (warmup_stage) nags |= BIT(4);
  64
  65         if (sendflags & BIT(6)) nags |= BIT(6);
  66
  67         if (sendflags & BIT(7)) nags |= BIT(7);
  68
  69         if (!(nags & 4))  // no vote called? send no string
  70                 nags &= ~(BIT(6) | BIT(7));
  71
  72         WriteByte(MSG_ENTITY, nags);
  73
  74         if (nags & BIT(6))
  75         {
  76                 WriteByte(MSG_ENTITY, vote_accept_count);
  77                 WriteByte(MSG_ENTITY, vote_reject_count);
  78                 WriteByte(MSG_ENTITY, vote_needed_overall);
  79                 WriteChar(MSG_ENTITY, to.vote_selection);
  80         }
  81
  82         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  83
  84         if (nags & 1)
  85         {
  86                 for (i = 1; i <= maxclients; i += 8)
  87                 {
  88                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  89                                 if (!IS_REAL_CLIENT(e) || e.ready)
  90                                         f |= b;
  91                         WriteByte(MSG_ENTITY, f);
  92                 }
  93         }
  94
  95         return true;
  96 }
  97
  98 void Nagger_Init()
  99 {
 100         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 101 }
 102
 103 void Nagger_VoteChanged()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(7);
 106 }
 107
 108 void Nagger_VoteCountChanged()
 109 {
 110         if (nagger) nagger.SendFlags |= BIT(6);
 111 }
 112
 113 void Nagger_ReadyCounted()
 114 {
 115         if (nagger) nagger.SendFlags |= BIT(0);
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 122         return vote_caller_name;
 123 }
 124
 125 // =======================
 126 //  Game logic for voting
 127 // =======================
 128
 129 void VoteReset()
 130 {
 131         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 132
 133         if (vote_called)
 134         {
 135                 strfree(vote_called_command);
 136                 strfree(vote_called_display);
 137                 strfree(vote_caller_name);
 138         }
 139
 140         vote_called = VOTE_NULL;
 141         vote_caller = NULL;
 142         vote_endtime = 0;
 143
 144         vote_parsed_command = string_null;
 145         vote_parsed_display = string_null;
 146
 147         Nagger_VoteChanged();
 148 }
 149
 150 void VoteStop(entity stopper)
 151 {
 152         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 153         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 154         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 155         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 156         VoteReset();
 157 }
 158
 159 void VoteAccept()
 160 {
 161         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 162
 163         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 164         else localcmd(strcat(vote_called_command, "\n"));
 165
 166         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 167
 168         VoteReset();
 169         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 170 }
 171
 172 void VoteReject()
 173 {
 174         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 175         VoteReset();
 176         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 177 }
 178
 179 void VoteTimeout()
 180 {
 181         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 182         VoteReset();
 183         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 184 }
 185
 186 void VoteSpam(float notvoters, float mincount, string result)
 187 {
 188         bprint(strcat(
 189                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 190                 strcat("^2:^1", ftos(vote_reject_count)),
 191                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 192                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 193                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 194
 195         if (autocvar_sv_eventlog)
 196         {
 197                 GameLogEcho(strcat(
 198                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 199                         strcat(":", ftos(vote_reject_count)),
 200                         strcat(":", ftos(vote_abstain_count)),
 201                         strcat(":", ftos(notvoters)),
 202                         strcat(":", ftos(mincount))));
 203         }
 204 }
 205
 206 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 207
 208 void VoteCount(float first_count)
 209 {
 210         // declarations
 211         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 212
 213         float vote_player_count = 0, notvoters = 0;
 214         float vote_real_player_count = 0, vote_real_accept_count = 0;
 215         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 216         float vote_needed_of_voted, final_needed_votes;
 217         float vote_factor_overall, vote_factor_of_voted;
 218
 219         Nagger_VoteCountChanged();
 220
 221         // add up all the votes from each connected client
 222         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 223                 ++vote_player_count;
 224                 if (IS_PLAYER(it))   ++vote_real_player_count;
 225                 switch (it.vote_selection)
 226                 {
 227                         case VOTE_SELECT_REJECT:
 228                         { ++vote_reject_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 230                         }
 231                         case VOTE_SELECT_ACCEPT:
 232                         { ++vote_accept_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 234                         }
 235                         case VOTE_SELECT_ABSTAIN:
 236                         { ++vote_abstain_count;
 237                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 238                         }
 239                         default: break;
 240                 }
 241         });
 242
 243         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 244         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 245         {
 246                 if (vote_caller)   vote_caller.vote_waittime = 0;
 247                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 248                 VoteReset();
 249                 return;
 250         }
 251
 252         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 253         if (!spectators_allowed && (vote_real_player_count > 0))
 254         {
 255                 vote_accept_count = vote_real_accept_count;
 256                 vote_reject_count = vote_real_reject_count;
 257                 vote_abstain_count = vote_real_abstain_count;
 258                 vote_player_count = vote_real_player_count;
 259         }
 260
 261         // people who have no opinion in any way :D
 262         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 263
 264         // determine the goal for the vote to be passed or rejected normally
 265         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 266         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 267
 268         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 269         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 270         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 271
 272         // are there any players at all on the server? it could be an admin vote
 273         if (vote_player_count == 0 && first_count)
 274         {
 275                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 276                 VoteAccept();
 277                 return;
 278         }
 279
 280         // since there ARE players, finally calculate the result of the vote
 281         if (vote_accept_count >= vote_needed_overall)
 282         {
 283                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 291                 VoteReject();
 292                 return;
 293         }
 294
 295         // there is not enough votes in either direction, now lets just calculate what the voters have said
 296         if (time > vote_endtime)
 297         {
 298                 final_needed_votes = vote_needed_overall;
 299
 300                 if (autocvar_sv_vote_majority_factor_of_voted)
 301                 {
 302                         if (vote_accept_count >= vote_needed_of_voted)
 303                         {
 304                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 305                                 VoteAccept();
 306                                 return;
 307                         }
 308
 309                         if (vote_accept_count + vote_reject_count > 0)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 312                                 VoteReject();
 313                                 return;
 314                         }
 315
 316                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 317                 }
 318
 319                 // it didn't pass or fail, so not enough votes to even make a decision.
 320                 VoteSpam(notvoters, final_needed_votes, "timeout");
 321                 VoteTimeout();
 322         }
 323 }
 324
 325 void VoteThink()
 326 {
 327         if (vote_endtime > 0)        // a vote was called
 328         {
 329                 if (time > vote_endtime) // time is up
 330                         VoteCount(false);
 331         }
 332 }
 333
 334
 335 // =======================
 336 //  Game logic for warmup
 337 // =======================
 338
 339 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 340 void reset_map(bool dorespawn, bool is_fake_round_start)
 341 {
 342         if (time <= game_starttime)
 343         {
 344                 if (game_stopped)
 345                         return;
 346
 347                 if (!is_fake_round_start)
 348                 {
 349                         Score_ClearAll();
 350                         PlayerStats_GameReport_Reset_All();
 351                 }
 352
 353                 if (round_handler_IsActive())
 354                         round_handler_Reset(game_starttime);
 355         }
 356
 357         if (shuffleteams_on_reset_map)
 358         {
 359                 shuffleteams();
 360                 shuffleteams_on_reset_map = false;
 361         }
 362
 363         FOREACH_CLIENT(true, {
 364                 if (time <= game_starttime)
 365                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 366                 if (!IS_PLAYER(it))
 367                         continue;
 368                 if (STAT(FROZEN, it))
 369                         Unfreeze(it, false);
 370                 player_powerups_remove_all(it);
 371                 entity store = PS(it);
 372                 if (store)
 373                 {
 374                         Inventory_clear(store.inventory);
 375                         Inventory_update(store);
 376                 }
 377         });
 378
 379         MUTATOR_CALLHOOK(reset_map_global);
 380
 381         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 382         {
 383                 if(IS_CLIENT(it))
 384                         continue;
 385                 if (it.reset)
 386                 {
 387                         it.reset(it);
 388                         continue;
 389                 }
 390                 if (it.team_saved) it.team = it.team_saved;
 391                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 392         });
 393
 394         // Waypoints and assault start come LAST
 395         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 396                 if (it.reset2) it.reset2(it);
 397         });
 398
 399         // Moving the player reset code here since the player-reset depends
 400         // on spawnpoint entities which have to be reset first --blub
 401         if (dorespawn)
 402         {
 403                 if (!MUTATOR_CALLHOOK(reset_map_players))
 404                 {
 405                         FOREACH_CLIENT(IS_PLAYER(it),
 406                         {
 407                                 // PlayerScore_Clear(it);
 408                                 CS(it).killcount = 0;
 409                                 // stop the player from moving so that he stands still once he gets respawned
 410                                 it.velocity = '0 0 0';
 411                                 it.avelocity = '0 0 0';
 412                                 CS(it).movement = '0 0 0';
 413                                 PutClientInServer(it);
 414                         });
 415                 }
 416         }
 417 }
 418
 419 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 420 void ReadyRestart_think(entity this)
 421 {
 422         reset_map(true, false);
 423         delete(this);
 424 }
 425
 426 // Forces a restart of the game without actually reloading the map // this is a mess...
 427 void ReadyRestart_force(bool is_fake_round_start)
 428 {
 429         if (time <= game_starttime && game_stopped)
 430                 return;
 431         if (!is_fake_round_start)
 432                 bprint("^1Match is restarting...\n");
 433
 434         VoteReset();
 435
 436         // clear overtime, we have to decrease timelimit to its original value again.
 437         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 438                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 439         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 440
 441         if(warmup_stage)
 442                 game_starttime = time; // Warmup: No countdown in warmup
 443         else if (autocvar_g_campaign)
 444                 game_starttime = time + 3;
 445         else
 446                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 447
 448         // clear player attributes
 449         FOREACH_CLIENT(IS_PLAYER(it), {
 450                 it.alivetime = 0;
 451                 CS(it).killcount = 0;
 452         });
 453
 454         // if we're ending the warmup stage call the corresponding hook
 455         if(!is_fake_round_start && !warmup_stage)
 456                 localcmd("\nsv_hook_warmupend\n");
 457
 458         // reset the .ready status of all players (also spectators)
 459         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 460         readycount = 0;
 461         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 462
 463         // lock teams with lockonrestart
 464         if (autocvar_teamplay_lockonrestart && teamplay)
 465                 lockteams = !warmup_stage;
 466
 467         // initiate the restart-countdown-announcer entity
 468         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 469         {
 470                 entity restart_timer = new_pure(restart_timer);
 471                 setthink(restart_timer, ReadyRestart_think);
 472                 restart_timer.nextthink = game_starttime;
 473         }
 474
 475         // after a restart every players number of allowed timeouts gets reset, too
 476         if (autocvar_sv_timeout)
 477         {
 478                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 479         }
 480
 481         if (!sv_ready_restart_after_countdown || warmup_stage)
 482                 reset_map(true, is_fake_round_start);
 483
 484         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 485 }
 486
 487 void ReadyRestart(bool forceWarmupEnd)
 488 {
 489         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 490         {
 491                 // NOTE: ReadyRestart support is mandatory in campaign
 492                 if (autocvar_g_campaign)
 493                         error("ReadyRestart must be supported in campaign mode!");
 494                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 495         }
 496         else localcmd("\nsv_hook_readyrestart\n");
 497
 498         if(forceWarmupEnd || autocvar_g_campaign)
 499                 warmup_stage = 0; // forcefully end warmup and go to match stage
 500         else
 501                 warmup_stage = cvar("g_warmup"); // go into warmup if it's enabled, otherwise restart into match stage
 502
 503         ReadyRestart_force(false);
 504 }
 505
 506 // Count the players who are ready and determine whether or not to restart the match
 507 void ReadyCount()
 508 {
 509         float ready_needed_factor, ready_needed_count;
 510         float t_ready = 0, t_players = 0;
 511
 512         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME_JOINED(it)), {
 513                 ++t_players;
 514                 if (it.ready) ++t_ready;
 515         });
 516
 517         readycount = t_ready;
 518
 519         Nagger_ReadyCounted();
 520
 521         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 522         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 523
 524         if (readycount >= ready_needed_count) ReadyRestart(true);
 525 }
 526
 527
 528 // ======================================
 529 //  Supporting functions for VoteCommand
 530 // ======================================
 531
 532 float Votecommand_check_assignment(entity caller, float assignment)
 533 {
 534         float from_server = (!caller);
 535
 536         if ((assignment == VC_ASGNMNT_BOTH)
 537             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 538             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 539
 540         return false;
 541 }
 542
 543 string VoteCommand_extractcommand(string input, float startpos, int argc)
 544 {
 545         string output;
 546
 547         if ((argc - 1) < startpos) output = "";
 548         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 549
 550         return output;
 551 }
 552
 553 float VoteCommand_checknasty(string vote_command)
 554 {
 555         if ((strstrofs(vote_command, ";", 0) >= 0)
 556             || (strstrofs(vote_command, "\n", 0) >= 0)
 557             || (strstrofs(vote_command, "\r", 0) >= 0)
 558             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 559
 560         return true;
 561 }
 562
 563 // NOTE: requires input to be surrounded by spaces
 564 string VoteCommand_checkreplacements(string input)
 565 {
 566         string output = input;
 567         // allow gotomap replacements
 568         output = strreplace(" map ", " gotomap ", output);
 569         output = strreplace(" chmap ", " gotomap ", output);
 570         return output;
 571 }
 572
 573 float VoteCommand_checkinlist(string vote_command, string list)
 574 {
 575         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 576
 577         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 578
 579         return false;
 580 }
 581
 582 string ValidateMap(string validated_map, entity caller)
 583 {
 584         validated_map = MapInfo_FixName(validated_map);
 585
 586         if (!validated_map)
 587         {
 588                 print_to(caller, "This map is not available on this server.");
 589                 return string_null;
 590         }
 591
 592         if (!autocvar_sv_vote_override_mostrecent && caller)
 593         {
 594                 if (Map_IsRecent(validated_map))
 595                 {
 596                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 597                         return string_null;
 598                 }
 599         }
 600
 601         if (!MapInfo_CheckMap(validated_map))
 602         {
 603                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 604                 return string_null;
 605         }
 606
 607         return validated_map;
 608 }
 609
 610 float VoteCommand_checkargs(float startpos, int argc)
 611 {
 612         float p, q, check, minargs;
 613         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 614         string cmdrestriction = "";  // No we don't.
 615         string charlist, arg;
 616         float checkmate;
 617
 618         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 619                 cmdrestriction = cvar_string(cvarname);
 620         else
 621                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 622
 623         if (cmdrestriction == "") return true;
 624
 625         ++startpos;  // skip command name
 626
 627         // check minimum arg count
 628
 629         // 0 args: argc == startpos
 630         // 1 args: argc == startpos + 1
 631         // ...
 632
 633         minargs = stof(cmdrestriction);
 634         if (argc - startpos < minargs) return false;
 635
 636         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 637
 638         for ( ; ; )
 639         {
 640                 // we know that at any time, startpos <= argc - minargs
 641                 // so this means: argc-minargs >= startpos >= argc, thus
 642                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 643                 // have been seen already
 644
 645                 if (startpos >= argc) // all args checked? GOOD
 646                         break;
 647
 648                 if (p < 0)            // no more args? FAIL
 649                 {
 650                         // exception: exactly minargs left, this one included
 651                         if (argc - startpos == minargs) break;
 652
 653                         // otherwise fail
 654                         return false;
 655                 }
 656
 657                 // cut to next semicolon
 658                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 659                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 660                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 661
 662                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 663                 // charlist = strreplace("^^", ";", charlist);
 664
 665                 if (charlist != "")
 666                 {
 667                         // verify the arg only contains allowed chars
 668                         arg = argv(startpos);
 669                         checkmate = strlen(arg);
 670                         for (check = 0; check < checkmate; ++check)
 671                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 672                         // not allowed character
 673                         // all characters are allowed. FINE.
 674                 }
 675
 676                 ++startpos;
 677                 --minargs;
 678                 p = q;
 679         }
 680
 681         return true;
 682 }
 683
 684 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 685 {
 686         string first_command = argv(startpos);
 687         int missing_chars = argv_start_index(startpos);
 688
 689         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 690                 return 0;
 691
 692         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 693
 694         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 695
 696         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 697         {
 698                 case MUT_VOTEPARSE_CONTINUE: { break; }
 699                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 700                 case MUT_VOTEPARSE_INVALID: { return -1; }
 701                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 702         }
 703
 704         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 705         {
 706                 case "kick":
 707                 case "kickban":    // catch all kick/kickban commands
 708                 {
 709                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 710                         float accepted = VerifyClientEntity(victim, true, false);
 711
 712                         if (accepted > 0)
 713                         {
 714                                 string reason = "No reason provided";
 715                                 if(argc > next_token)
 716                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 717
 718                                 string command_arguments = reason;
 719                                 if (first_command == "kickban")
 720                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 721
 722                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 723                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 724                         }
 725                         else
 726                         {
 727                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 728                                 return 0;
 729                         }
 730
 731                         break;
 732                 }
 733
 734                 case "map":
 735                 case "chmap":
 736                 case "gotomap":  // re-direct all map selection commands to gotomap
 737                 {
 738                         vote_command = ValidateMap(argv(startpos + 1), caller);
 739                         if (!vote_command)  return -1;
 740                         vote_parsed_command = strcat("gotomap ", vote_command);
 741                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 742
 743                         break;
 744                 }
 745
 746                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 747                 // maybe fallback instead of aborting if map name is invalid?
 748                 case "nextmap":
 749                 {
 750                         vote_command = ValidateMap(argv(startpos + 1), caller);
 751                         if (!vote_command)  return -1;
 752                         vote_parsed_command = strcat("nextmap ", vote_command);
 753                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 754
 755                         break;
 756                 }
 757
 758                 case "timelimit": // include restrictions on the maximum votable time limit
 759                 {
 760                         float timelimit_vote = stof(argv(startpos + 1));
 761                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 762                         {
 763                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 764                                 return -1;
 765                         }
 766                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 767                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 768                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 769
 770                         break;
 771                 }
 772
 773                 case "restart":
 774                 {
 775                         // add a delay so that vote result can be seen and announcer can be heard
 776                         // if the vote is accepted
 777                         vote_parsed_command = strcat("defer 1 ", vote_command);
 778                         vote_parsed_display = strzone(strcat("^1", vote_command));
 779
 780                         break;
 781                 }
 782
 783                 case "allready":
 784                 {
 785                         if(!warmup_stage) {
 786                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 787                                 return -1;
 788                         }
 789
 790                         vote_parsed_command = vote_command;
 791                         vote_parsed_display = strzone(strcat("^1", vote_command));
 792                         break;
 793                 }
 794
 795                 default:
 796                 {
 797                         vote_parsed_command = vote_command;
 798                         vote_parsed_display = strzone(strcat("^1", vote_command));
 799
 800                         break;
 801                 }
 802         }
 803
 804         return 1;
 805 }
 806
 807
 808 // =======================
 809 //  Command Sub-Functions
 810 // =======================
 811
 812 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 813 {
 814         switch (request)
 815         {
 816                 case CMD_REQUEST_COMMAND:
 817                 {
 818                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 819                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 820                         {
 821                                 print_to(caller, "^1You have already voted.");
 822                         }
 823
 824                         else  // everything went okay, continue changing vote
 825                         {
 826                                 print_to(caller, "^1You abstained from your vote.");
 827                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 828                                 msg_entity = caller;
 829                                 if (!autocvar_sv_vote_singlecount)
 830                                         VoteCount(false);
 831                         }
 832
 833                         return;
 834                 }
 835
 836                 default:
 837                 case CMD_REQUEST_USAGE:
 838                 {
 839                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 840                         print_to(caller, "  No arguments required.");
 841                         return;
 842                 }
 843         }
 844 }
 845
 846 void print_available_commands_to(entity caller)
 847 {
 848         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 849 }
 850
 851 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 852 {
 853         switch (request)
 854         {
 855                 case CMD_REQUEST_COMMAND:
 856                 {
 857                         float tmp_playercount = 0;
 858                         int parse_error;
 859
 860                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 861
 862                         if (!autocvar_sv_vote_call && caller)
 863                         {
 864                                 print_to(caller, "^1Vote calling is not allowed.");
 865                         }
 866                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 867                         {
 868                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 869                         }
 870                         else if (vote_called)
 871                         {
 872                                 print_to(caller, "^1There is already a vote called.");
 873                         }
 874                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 875                         {
 876                                 print_to(caller, "^1Only players can call a vote.");
 877                         }
 878                         else if (caller && !IS_CLIENT(caller))
 879                         {
 880                                 print_to(caller, "^1Only connected clients can vote.");
 881                         }
 882                         else if (timeout_status && vote_command != "timein")
 883                         {
 884                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 885                         }
 886                         else if (caller && (time < caller.vote_waittime))
 887                         {
 888                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 889                         }
 890                         else if (!VoteCommand_checknasty(vote_command))
 891                         {
 892                                 print_to(caller, "^1Syntax error in command.");
 893                         }
 894                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 895                         {
 896                                 if(parse_error == 0)
 897                                 {
 898                                         if (vote_called_command == "")
 899                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 900                                         else
 901                                                 print_to(caller, "^1This command is not acceptable or not available.");
 902                                 }
 903                         }
 904                         else  // everything went okay, continue with calling the vote
 905                         {
 906                                 vote_caller = caller;  // remember who called the vote
 907                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 908                                 vote_called = VOTE_NORMAL;
 909                                 vote_called_command = strzone(vote_parsed_command);
 910                                 vote_called_display = strzone(vote_parsed_display);
 911                                 vote_endtime = time + autocvar_sv_vote_timeout;
 912
 913                                 if (caller)
 914                                 {
 915                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 916                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 917                                         msg_entity = caller;
 918                                 }
 919
 920                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 921
 922                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 923                                 if (autocvar_sv_eventlog)
 924                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 925                                 Nagger_VoteChanged();
 926                                 VoteCount(true);  // needed if you are the only one
 927
 928                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 929                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 930                         }
 931
 932                         return;
 933                 }
 934
 935                 default:
 936                 case CMD_REQUEST_USAGE:
 937                 {
 938                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 939                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 940                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 941                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 942                         print_available_commands_to(caller);
 943                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 944                         return;
 945                 }
 946         }
 947 }
 948
 949 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 950 {
 951         switch (request)
 952         {
 953                 case CMD_REQUEST_COMMAND:
 954                 {
 955                         if (autocvar_sv_vote_master)
 956                         {
 957                                 switch (strtolower(argv(2)))
 958                                 {
 959                                         case "do":
 960                                         {
 961                                                 int parse_error;
 962                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 963
 964                                                 if (!caller.vote_master)
 965                                                         print_to(caller, "^1You do not have vote master privileges.");
 966                                                 else if (!VoteCommand_checknasty(vote_command))
 967                                                 {
 968                                                         print_to(caller, "^1Syntax error in command.");
 969                                                 }
 970                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 971                                                 {
 972                                                         if(parse_error == 0)
 973                                                         {
 974                                                                 if (vote_called_command == "")
 975                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 976                                                                 else
 977                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 978                                                         }
 979                                                 }
 980                                                 else  // everything went okay, proceed with command
 981                                                 {
 982                                                         localcmd(strcat(vote_parsed_command, "\n"));
 983                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 984                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 985                                                         if (autocvar_sv_eventlog)
 986                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 987                                                 }
 988
 989                                                 return;
 990                                         }
 991
 992                                         case "login":
 993                                         {
 994                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 995                                                 else if (caller.vote_master)
 996                                                 {
 997                                                         print_to(caller, "^1You are already logged in as vote master.");
 998                                                 }
 999                                                 else if (autocvar_sv_vote_master_password != argv(3))
1000                                                 {
1001                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1002                                                 }
1003                                                 else  // everything went okay, proceed with giving this player master privilages
1004                                                 {
1005                                                         caller.vote_master = true;
1006                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1007                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1008                                                         if (autocvar_sv_eventlog)
1009                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1010                                                 }
1011
1012                                                 return;
1013                                         }
1014
1015                                         default:  // calling a vote for master
1016                                         {
1017                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1018                                                 else if (vote_called)
1019                                                 {
1020                                                         print_to(caller, "^1There is already a vote called.");
1021                                                 }
1022                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1023                                                 {
1024                                                         print_to(caller, "^1Only players can call a vote.");
1025                                                 }
1026                                                 else if (timeout_status)
1027                                                 {
1028                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1029                                                 }
1030                                                 else  // everything went okay, continue with creating vote
1031                                                 {
1032                                                         vote_caller = caller;
1033                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1034                                                         vote_called = VOTE_MASTER;
1035                                                         vote_called_command = strzone("XXX");
1036                                                         vote_called_display = strzone("^3master");
1037                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1038
1039                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1040                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1041
1042                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1043                                                         if (autocvar_sv_eventlog)
1044                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1045                                                         Nagger_VoteChanged();
1046                                                         VoteCount(true);  // needed if you are the only one
1047                                                 }
1048
1049                                                 return;
1050                                         }
1051                                 }
1052                         }
1053                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1054
1055                         return;
1056                 }
1057
1058                 default:
1059                 case CMD_REQUEST_USAGE:
1060                 {
1061                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1062                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1063                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1064                         return;
1065                 }
1066         }
1067 }
1068
1069 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1070 {
1071         switch (request)
1072         {
1073                 case CMD_REQUEST_COMMAND:
1074                 {
1075                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1076                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1077                         {
1078                                 print_to(caller, "^1You have already voted.");
1079                         }
1080                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1081                         {
1082                                 VoteStop(caller);
1083                         }
1084
1085                         else  // everything went okay, continue changing vote
1086                         {
1087                                 print_to(caller, "^1You rejected the vote.");
1088                                 caller.vote_selection = VOTE_SELECT_REJECT;
1089                                 msg_entity = caller;
1090                                 if (!autocvar_sv_vote_singlecount)
1091                                         VoteCount(false);
1092                         }
1093
1094                         return;
1095                 }
1096
1097                 default:
1098                 case CMD_REQUEST_USAGE:
1099                 {
1100                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1101                         print_to(caller, "  No arguments required.");
1102                         return;
1103                 }
1104         }
1105 }
1106
1107 void VoteCommand_status(int request, entity caller)  // BOTH
1108 {
1109         switch (request)
1110         {
1111                 case CMD_REQUEST_COMMAND:
1112                 {
1113                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1114                         else print_to(caller, "^1No vote called.");
1115
1116                         return;
1117                 }
1118
1119                 default:
1120                 case CMD_REQUEST_USAGE:
1121                 {
1122                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1123                         print_to(caller, "  No arguments required.");
1124                         return;
1125                 }
1126         }
1127 }
1128
1129 void VoteCommand_stop(int request, entity caller)  // BOTH
1130 {
1131         switch (request)
1132         {
1133                 case CMD_REQUEST_COMMAND:
1134                 {
1135                         if (!vote_called)   print_to(caller, "^1No vote called.");
1136                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1137                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1138                         return;
1139                 }
1140
1141                 default:
1142                 case CMD_REQUEST_USAGE:
1143                 {
1144                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1145                         print_to(caller, "  No arguments required.");
1146                         return;
1147                 }
1148         }
1149 }
1150
1151 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1152 {
1153         switch (request)
1154         {
1155                 case CMD_REQUEST_COMMAND:
1156                 {
1157                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1158                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1159                         {
1160                                 print_to(caller, "^1You have already voted.");
1161                         }
1162                         else  // everything went okay, continue changing vote
1163                         {
1164                                 print_to(caller, "^1You accepted the vote.");
1165                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1166                                 msg_entity = caller;
1167                                 if (!autocvar_sv_vote_singlecount)
1168                                         VoteCount(false);
1169                         }
1170
1171                         return;
1172                 }
1173
1174                 default:
1175                 case CMD_REQUEST_USAGE:
1176                 {
1177                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1178                         print_to(caller, "  No arguments required.");
1179                         return;
1180                 }
1181         }
1182 }
1183
1184 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1185 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1186 void VoteCommand_(int request)
1187 {
1188     switch(request)
1189     {
1190         case CMD_REQUEST_COMMAND:
1191         {
1192
1193             return;
1194         }
1195
1196         default:
1197         case CMD_REQUEST_USAGE:
1198         {
1199             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1200             print_to(caller, "  No arguments required.");
1201             return;
1202         }
1203     }
1204 }
1205 */
1206
1207
1208 // ================================
1209 //  Macro system for vote commands
1210 // ================================
1211
1212 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1213 #define VOTE_COMMANDS(request, caller, arguments, command) \
1214         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1215         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1216         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1217         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1218         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1219         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1220         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1221         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1222         /* nothing */
1223
1224 void VoteCommand_macro_help(entity caller, int argc)
1225 {
1226         string command_origin = GetCommandPrefix(caller);
1227
1228         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1229         {
1230                 print_to(caller, "\nVoting commands:\n");
1231                 #define VOTE_COMMAND(name, function, description, assignment) \
1232                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1233
1234                 VOTE_COMMANDS(0, caller, 0, "");
1235                 #undef VOTE_COMMAND
1236
1237                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1238                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1239                 print_available_commands_to(caller);
1240         }
1241         else  // usage for individual command
1242         {
1243                 #define VOTE_COMMAND(name, function, description, assignment) \
1244                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1245
1246                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1247                 #undef VOTE_COMMAND
1248
1249                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1250                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1251                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1252                 else if (argv(2) != "")
1253                         print_to(caller, "No documentation exists for this vote");
1254         }
1255 }
1256
1257 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1258 {
1259         #define VOTE_COMMAND(name, function, description, assignment) \
1260                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1261
1262         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1263         #undef VOTE_COMMAND
1264
1265         return false;
1266 }
1267
1268
1269 // ======================================
1270 //  Main function handling vote commands
1271 // ======================================
1272
1273 void VoteCommand(int request, entity caller, int argc, string vote_command)
1274 {
1275         // Guide for working with argc arguments by example:
1276         // argc:   1    - 2      - 3     - 4
1277         // argv:   0    - 1      - 2     - 3
1278         // cmd     vote - master - login - password
1279
1280         switch (request)
1281         {
1282                 case CMD_REQUEST_COMMAND:
1283                 {
1284                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1285                 }
1286
1287                 default:
1288                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1289                 case CMD_REQUEST_USAGE:
1290                 {
1291                         VoteCommand_macro_help(caller, argc);
1292                         return;
1293                 }
1294         }
1295 }