qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3
   4 #include "common.qh"
   5
   6 #include "../g_damage.qh"
   7 #include "../g_world.qh"
   8 #include "../race.qh"
   9 #include "../round_handler.qh"
  10 #include "../scores.qh"
  11
  12 #include "../mutators/mutators_include.qh"
  13
  14 #include "../../common/constants.qh"
  15 #include "../../common/mapinfo.qh"
  16 #include "../../common/notifications.qh"
  17 #include "../../common/playerstats.qh"
  18 #include "../../common/util.qh"
  19
  20 // =============================================
  21 //  Server side voting code, reworked by Samual
  22 //  Last updated: December 27th, 2011
  23 // =============================================
  24
  25 //  Nagger for players to know status of voting
  26 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  27 {
  28         int nags, i, f, b;
  29         entity e;
  30         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  31
  32         // bits:
  33         //   1 = ready
  34         //   2 = player needs to ready up
  35         //   4 = vote
  36         //   8 = player needs to vote
  37         //  16 = warmup
  38         // sendflags:
  39         //  64 = vote counts
  40         // 128 = vote string
  41
  42         nags = 0;
  43         if(readycount)
  44         {
  45                 nags |= 1;
  46                 if(to.ready == 0)
  47                         nags |= 2;
  48         }
  49         if(vote_called)
  50         {
  51                 nags |= 4;
  52                 if(to.vote_selection == 0)
  53                         nags |= 8;
  54         }
  55         if(warmup_stage)
  56                 nags |= 16;
  57
  58         if(sendflags & 64)
  59                 nags |= 64;
  60
  61         if(sendflags & 128)
  62                 nags |= 128;
  63
  64         if(!(nags & 4)) // no vote called? send no string
  65                 nags &= ~(64 | 128);
  66
  67         WriteByte(MSG_ENTITY, nags);
  68
  69         if(nags & 64)
  70         {
  71                 WriteByte(MSG_ENTITY, vote_accept_count);
  72                 WriteByte(MSG_ENTITY, vote_reject_count);
  73                 WriteByte(MSG_ENTITY, vote_needed_overall);
  74                 WriteChar(MSG_ENTITY, to.vote_selection);
  75         }
  76
  77         if(nags & 128)
  78                 WriteString(MSG_ENTITY, vote_called_display);
  79
  80         if(nags & 1)
  81         {
  82                 for(i = 1; i <= maxclients; i += 8)
  83                 {
  84                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  85                                 if(!IS_REAL_CLIENT(e) || e.ready)
  86                                         f |= b;
  87                         WriteByte(MSG_ENTITY, f);
  88                 }
  89         }
  90
  91         return true;
  92 }
  93
  94 void Nagger_Init()
  95 {
  96         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
  97 }
  98
  99 void Nagger_VoteChanged()
 100 {
 101         if(nagger)
 102                 nagger.SendFlags |= 128;
 103 }
 104
 105 void Nagger_VoteCountChanged()
 106 {
 107         if(nagger)
 108                 nagger.SendFlags |= 64;
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if(nagger)
 114                 nagger.SendFlags |= 1;
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller))
 121                 return vote_caller.netname;
 122         return vote_caller_name;
 123 }
 124
 125 // =======================
 126 //  Game logic for voting
 127 // =======================
 128
 129 void VoteReset()
 130 {
 131         entity tmp_player;
 132
 133         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 134
 135         if(vote_called)
 136         {
 137                 strunzone(vote_called_command);
 138                 strunzone(vote_called_display);
 139                 strunzone(vote_caller_name);
 140         }
 141
 142         vote_called = VOTE_NULL;
 143         vote_caller = world;
 144         vote_caller_name = string_null;
 145         vote_endtime = 0;
 146
 147         vote_called_command = string_null;
 148         vote_called_display = string_null;
 149
 150         vote_parsed_command = string_null;
 151         vote_parsed_display = string_null;
 152
 153         Nagger_VoteChanged();
 154 }
 155
 156 void VoteStop(entity stopper)
 157 {
 158         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 159         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 160
 161         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 162         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 163
 164         VoteReset();
 165 }
 166
 167 void VoteAccept()
 168 {
 169         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 170
 171         if((vote_called == VOTE_MASTER) && vote_caller)
 172                 vote_caller.vote_master = 1;
 173         else
 174                 localcmd(strcat(vote_called_command, "\n"));
 175
 176         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 177
 178         VoteReset();
 179         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 180 }
 181
 182 void VoteReject()
 183 {
 184         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 185         VoteReset();
 186         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 187 }
 188
 189 void VoteTimeout()
 190 {
 191         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 192         VoteReset();
 193         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 194 }
 195
 196 void VoteSpam(float notvoters, float mincount, string result)
 197 {
 198         bprint(strcat(
 199                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 200                 strcat("^2:^1", ftos(vote_reject_count)),
 201                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 202                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 203                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 204
 205         if(autocvar_sv_eventlog)
 206         {
 207                 GameLogEcho(strcat(
 208                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 209                         strcat(":", ftos(vote_reject_count)),
 210                         strcat(":", ftos(vote_abstain_count)),
 211                         strcat(":", ftos(notvoters)),
 212                         strcat(":", ftos(mincount))));
 213         }
 214 }
 215
 216 void VoteCount(float first_count)
 217 {
 218         // declarations
 219         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 220
 221         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 222                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 223                                 || (autocvar_sv_vote_nospectators == 0));
 224
 225         float vote_player_count = 0, notvoters = 0;
 226         float vote_real_player_count = 0, vote_real_accept_count = 0;
 227         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 228         float vote_needed_of_voted, final_needed_votes;
 229         float vote_factor_overall, vote_factor_of_voted;
 230
 231         entity tmp_player;
 232
 233         Nagger_VoteCountChanged();
 234
 235         // add up all the votes from each connected client
 236         FOR_EACH_REALCLIENT(tmp_player)
 237         {
 238                 ++vote_player_count;
 239                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 240
 241                 switch(tmp_player.vote_selection)
 242                 {
 243                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 244                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break; }
 245                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 246                         default: break;
 247                 }
 248         }
 249
 250         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 251         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 252         {
 253                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 254                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 255                 VoteReset();
 256                 return;
 257         }
 258
 259         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 260         if(!spectators_allowed && (vote_real_player_count > 0))
 261         {
 262                 vote_accept_count = vote_real_accept_count;
 263                 vote_reject_count = vote_real_reject_count;
 264                 vote_abstain_count = vote_real_abstain_count;
 265                 vote_player_count = vote_real_player_count;
 266         }
 267
 268         // people who have no opinion in any way :D
 269         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 270
 271         // determine the goal for the vote to be passed or rejected normally
 272         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 273         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 274
 275         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 276         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 277         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 278
 279         // are there any players at all on the server? it could be an admin vote
 280         if(vote_player_count == 0 && first_count)
 281         {
 282                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 283                 VoteAccept();
 284                 return;
 285         }
 286
 287         // since there ARE players, finally calculate the result of the vote
 288         if(vote_accept_count >= vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 291                 VoteAccept();
 292                 return;
 293         }
 294
 295         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 296         {
 297                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 298                 VoteReject();
 299                 return;
 300         }
 301
 302         // there is not enough votes in either direction, now lets just calculate what the voters have said
 303         if(time > vote_endtime)
 304         {
 305                 final_needed_votes = vote_needed_overall;
 306
 307                 if(autocvar_sv_vote_majority_factor_of_voted)
 308                 {
 309                         if(vote_accept_count >= vote_needed_of_voted)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 312                                 VoteAccept();
 313                                 return;
 314                         }
 315
 316                         if(vote_accept_count + vote_reject_count > 0)
 317                         {
 318                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 319                                 VoteReject();
 320                                 return;
 321                         }
 322
 323                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 324                 }
 325
 326                 // it didn't pass or fail, so not enough votes to even make a decision.
 327                 VoteSpam(notvoters, final_needed_votes, "timeout");
 328                 VoteTimeout();
 329         }
 330 }
 331
 332 void VoteThink()
 333 {
 334         if(vote_endtime > 0) // a vote was called
 335         if(time > vote_endtime) // time is up
 336         {
 337                 VoteCount(false);
 338         }
 339
 340         return;
 341 }
 342
 343
 344 // =======================
 345 //  Game logic for warmup
 346 // =======================
 347
 348 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 349 void reset_map(float dorespawn)
 350 {SELFPARAM();
 351
 352         if(time <= game_starttime && round_handler_IsActive())
 353                 round_handler_Reset(game_starttime);
 354
 355         MUTATOR_CALLHOOK(reset_map_global);
 356
 357         for(entity e = world; (e = nextent(e)); )
 358         {
 359                 setself(e);
 360                 if(IS_NOT_A_CLIENT(self))
 361                 {
 362                         if(self.reset)
 363                         {
 364                                 self.reset();
 365                                 continue;
 366                         }
 367
 368                         if(self.team_saved)
 369                                 self.team = self.team_saved;
 370
 371                         if(self.flags & FL_PROJECTILE) // remove any projectiles left
 372                                 remove(self);
 373                 }
 374         }
 375
 376         // Waypoints and assault start come LAST
 377         for(entity e = world; (e = nextent(e)); )
 378         {
 379                 setself(e);
 380                 if(IS_NOT_A_CLIENT(self))
 381                 {
 382                         if(self.reset2)
 383                         {
 384                                 self.reset2();
 385                                 continue;
 386                         }
 387                 }
 388         }
 389
 390         entity e;
 391         FOR_EACH_PLAYER(e)
 392         if(e.frozen)
 393         {
 394                 WITH(entity, self, e, Unfreeze(self));
 395         }
 396
 397         // Moving the player reset code here since the player-reset depends
 398         // on spawnpoint entities which have to be reset first --blub
 399         if(dorespawn)
 400         if(!MUTATOR_CALLHOOK(reset_map_players))
 401         FOR_EACH_CLIENT(e) // reset all players
 402         {
 403                 setself(e);
 404                 /*
 405                 only reset players if a restart countdown is active
 406                 this can either be due to cvar sv_ready_restart_after_countdown having set
 407                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 408                 sv_ready_restart_after_countdown is not used and countdown is still running
 409                 */
 410                 if (restart_mapalreadyrestarted || (time < game_starttime))
 411                 {
 412                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 413                         if (IS_PLAYER(self)) {
 414                                 //PlayerScore_Clear(self);
 415                                 self.killcount = 0;
 416                                 //stop the player from moving so that he stands still once he gets respawned
 417                                 self.velocity = '0 0 0';
 418                                 self.avelocity = '0 0 0';
 419                                 self.movement = '0 0 0';
 420                                 PutClientInServer();
 421                         }
 422                 }
 423         }
 424
 425         if(g_keyhunt)
 426                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
 427
 428         setself(this);
 429 }
 430
 431 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 432 void ReadyRestart_think()
 433 {SELFPARAM();
 434         restart_mapalreadyrestarted = 1;
 435         reset_map(true);
 436         Score_ClearAll();
 437         remove(self);
 438
 439         return;
 440 }
 441
 442 // Forces a restart of the game without actually reloading the map // this is a mess...
 443 void ReadyRestart_force()
 444 {
 445         entity tmp_player, restart_timer;
 446
 447         bprint("^1Server is restarting...\n");
 448
 449         VoteReset();
 450
 451         // clear overtime, we have to decrease timelimit to its original value again.
 452         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 453
 454         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 455
 456         readyrestart_happened = 1;
 457         game_starttime = time + RESTART_COUNTDOWN;
 458
 459         // clear player attributes
 460         FOR_EACH_CLIENT(tmp_player)
 461         {
 462                 tmp_player.alivetime = 0;
 463                 tmp_player.killcount = 0;
 464                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 465         }
 466
 467         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 468
 469         // disable the warmup global for the server
 470         warmup_stage = 0; // once the game is restarted the game is in match stage
 471
 472         // reset the .ready status of all players (also spectators)
 473         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 474         readycount = 0;
 475         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 476
 477         // lock teams with lockonrestart
 478         if(autocvar_teamplay_lockonrestart && teamplay)
 479         {
 480                 lockteams = 1;
 481                 bprint("^1The teams are now locked.\n");
 482         }
 483
 484         //initiate the restart-countdown-announcer entity
 485         if(autocvar_sv_ready_restart_after_countdown)
 486         {
 487                 restart_timer = spawn();
 488                 restart_timer.think = ReadyRestart_think;
 489                 restart_timer.nextthink = game_starttime;
 490         }
 491
 492         // after a restart every players number of allowed timeouts gets reset, too
 493         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 494
 495         //reset map immediately if this cvar is not set
 496         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(true); }
 497
 498         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 499 }
 500
 501 void ReadyRestart()
 502 {
 503         // no arena, assault support yet...
 504         if(g_assault | gameover | intermission_running | race_completing)
 505                 localcmd("restart\n");
 506         else
 507                 localcmd("\nsv_hook_gamerestart\n");
 508
 509         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 510         // Otherwise scores could be manipulated during the countdown.
 511         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 512
 513         ReadyRestart_force();
 514
 515         return;
 516 }
 517
 518 // Count the players who are ready and determine whether or not to restart the match
 519 void ReadyCount()
 520 {
 521         entity tmp_player;
 522         float ready_needed_factor, ready_needed_count;
 523         float t_ready = 0, t_players = 0;
 524
 525         FOR_EACH_REALCLIENT(tmp_player)
 526         {
 527                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 528                 {
 529                         ++t_players;
 530                         if(tmp_player.ready) { ++t_ready; }
 531                 }
 532         }
 533
 534         readycount = t_ready;
 535
 536         Nagger_ReadyCounted();
 537
 538         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 539         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 540
 541         if(readycount >= ready_needed_count)
 542         {
 543                 ReadyRestart();
 544         }
 545
 546         return;
 547 }
 548
 549
 550 // ======================================
 551 //  Supporting functions for VoteCommand
 552 // ======================================
 553
 554 float Votecommand_check_assignment(entity caller, float assignment)
 555 {
 556         float from_server = (!caller);
 557
 558         if((assignment == VC_ASGNMNT_BOTH)
 559                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 560                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 561         {
 562                 return true;
 563         }
 564
 565         return false;
 566 }
 567
 568 string VoteCommand_extractcommand(string input, float startpos, float argc)
 569 {
 570         string output;
 571
 572         if((argc - 1) < startpos)
 573                 output = "";
 574         else
 575                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 576
 577         return output;
 578 }
 579
 580 float VoteCommand_checknasty(string vote_command)
 581 {
 582         if((strstrofs(vote_command, ";", 0) >= 0)
 583                 || (strstrofs(vote_command, "\n", 0) >= 0)
 584                 || (strstrofs(vote_command, "\r", 0) >= 0)
 585                 || (strstrofs(vote_command, "$", 0) >= 0))
 586                 return false;
 587
 588         return true;
 589 }
 590
 591 float VoteCommand_checkinlist(string vote_command, string list)
 592 {
 593         string l = strcat(" ", list, " ");
 594
 595         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 596                 return true;
 597
 598         return false;
 599 }
 600
 601 string ValidateMap(string validated_map, entity caller)
 602 {
 603         validated_map = MapInfo_FixName(validated_map);
 604
 605         if (!validated_map)
 606         {
 607                 print_to(caller, "This map is not available on this server.");
 608                 return string_null;
 609         }
 610
 611         if(!autocvar_sv_vote_override_mostrecent && caller)
 612         {
 613                 if(Map_IsRecent(validated_map))
 614                 {
 615                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 616                         return string_null;
 617                 }
 618         }
 619
 620         if(!MapInfo_CheckMap(validated_map))
 621         {
 622                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 623                 return string_null;
 624         }
 625
 626         return validated_map;
 627 }
 628
 629 float VoteCommand_checkargs(float startpos, float argc)
 630 {
 631         float p, q, check, minargs;
 632         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 633         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 634         string charlist, arg;
 635         float checkmate;
 636
 637         if(cmdrestriction == "")
 638                 return true;
 639
 640         ++startpos; // skip command name
 641
 642         // check minimum arg count
 643
 644         // 0 args: argc == startpos
 645         // 1 args: argc == startpos + 1
 646         // ...
 647
 648         minargs = stof(cmdrestriction);
 649         if(argc - startpos < minargs)
 650                 return false;
 651
 652         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 653
 654         for (;;)
 655         {
 656                 // we know that at any time, startpos <= argc - minargs
 657                 // so this means: argc-minargs >= startpos >= argc, thus
 658                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 659                 // have been seen already
 660
 661                 if(startpos >= argc) // all args checked? GOOD
 662                         break;
 663
 664                 if(p < 0) // no more args? FAIL
 665                 {
 666                         // exception: exactly minargs left, this one included
 667                         if(argc - startpos == minargs)
 668                                 break;
 669
 670                         // otherwise fail
 671                         return false;
 672                 }
 673
 674                 // cut to next semicolon
 675                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 676                 if(q < 0)
 677                         charlist = substring(cmdrestriction, p+1, -1);
 678                 else
 679                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 680
 681                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 682                 // charlist = strreplace("^^", ";", charlist);
 683
 684                 if(charlist != "")
 685                 {
 686                         // verify the arg only contains allowed chars
 687                         arg = argv(startpos);
 688                         checkmate = strlen(arg);
 689                         for(check = 0; check < checkmate; ++check)
 690                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 691                                         return false; // not allowed character
 692                         // all characters are allowed. FINE.
 693                 }
 694
 695                 ++startpos;
 696                 --minargs;
 697                 p = q;
 698         }
 699
 700         return true;
 701 }
 702
 703 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 704 {
 705         string first_command;
 706
 707         first_command = argv(startpos);
 708
 709         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 710                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 711                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 712         );*/
 713
 714         if(
 715                 (autocvar_sv_vote_limit > 0)
 716                 &&
 717                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 718         )
 719                 return false;
 720
 721         if (!VoteCommand_checkinlist(first_command, vote_list))
 722                 return false;
 723
 724         if (!VoteCommand_checkargs(startpos, argc))
 725                 return false;
 726
 727         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 728         {
 729                 case "kick":
 730                 case "kickban": // catch all kick/kickban commands
 731                 {
 732                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 733                         float accepted = VerifyClientEntity(victim, true, false);
 734
 735                         if(accepted > 0)
 736                         {
 737                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 738                                 string command_arguments;
 739
 740                                 if(first_command == "kickban")
 741                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 742                                 else
 743                                         command_arguments = reason;
 744
 745                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 746                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 747                         }
 748                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 749
 750                         break;
 751                 }
 752
 753                 case "map":
 754                 case "chmap":
 755                 case "gotomap": // re-direct all map selection commands to gotomap
 756                 {
 757                         vote_command = ValidateMap(argv(startpos + 1), caller);
 758                         if (!vote_command) { return false; }
 759                         vote_parsed_command = strcat("gotomap ", vote_command);
 760                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 761
 762                         break;
 763                 }
 764
 765                 default:
 766                 {
 767                         vote_parsed_command = vote_command;
 768                         vote_parsed_display = strzone(strcat("^1", vote_command));
 769
 770                         break;
 771                 }
 772         }
 773
 774         return true;
 775 }
 776
 777
 778 // =======================
 779 //  Command Sub-Functions
 780 // =======================
 781
 782 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 783 {
 784         switch(request)
 785         {
 786                 case CMD_REQUEST_COMMAND:
 787                 {
 788                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 789                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 790
 791                         else // everything went okay, continue changing vote
 792                         {
 793                                 print_to(caller, "^1You abstained from your vote.");
 794                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 795                                 msg_entity = caller;
 796                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 797                         }
 798
 799                         return;
 800                 }
 801
 802                 default:
 803                 case CMD_REQUEST_USAGE:
 804                 {
 805                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 806                         print_to(caller, "  No arguments required.");
 807                         return;
 808                 }
 809         }
 810 }
 811
 812 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 813 {
 814         switch(request)
 815         {
 816                 case CMD_REQUEST_COMMAND:
 817                 {
 818                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 819                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 820                                 || (autocvar_sv_vote_nospectators == 0));
 821
 822                         float tmp_playercount = 0;
 823                         entity tmp_player;
 824
 825                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 826
 827                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 828                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 829                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 830                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 831                         else if(caller && !IS_CLIENT(caller)) { print_to(caller, "^1Only connected clients can vote."); }
 832                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 833                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 834                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 835                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 836
 837                         else // everything went okay, continue with calling the vote
 838                         {
 839                                 vote_caller = caller; // remember who called the vote
 840                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 841                                 vote_called = VOTE_NORMAL;
 842                                 vote_called_command = strzone(vote_parsed_command);
 843                                 vote_called_display = strzone(vote_parsed_display);
 844                                 vote_endtime = time + autocvar_sv_vote_timeout;
 845
 846                                 if(caller)
 847                                 {
 848                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 849                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 850                                         msg_entity = caller;
 851                                 }
 852
 853                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 854                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 855
 856                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 857                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 858                                 Nagger_VoteChanged();
 859                                 VoteCount(true); // needed if you are the only one
 860                         }
 861
 862                         return;
 863                 }
 864
 865                 default:
 866                 case CMD_REQUEST_USAGE:
 867                 {
 868                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 869                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 870                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 871                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 872                         return;
 873                 }
 874         }
 875 }
 876
 877 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 878 {
 879         switch(request)
 880         {
 881                 case CMD_REQUEST_COMMAND:
 882                 {
 883                         if(autocvar_sv_vote_master)
 884                         {
 885                                 switch(strtolower(argv(2)))
 886                                 {
 887                                         case "do":
 888                                         {
 889                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 890
 891                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 892                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 893                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 894
 895                                                 else // everything went okay, proceed with command
 896                                                 {
 897                                                         localcmd(strcat(vote_parsed_command, "\n"));
 898                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 899                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 900                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 901                                                 }
 902
 903                                                 return;
 904                                         }
 905
 906                                         case "login":
 907                                         {
 908                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 909                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 910                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 911
 912                                                 else // everything went okay, proceed with giving this player master privilages
 913                                                 {
 914                                                         caller.vote_master = true;
 915                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 916                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 917                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 918                                                 }
 919
 920                                                 return;
 921                                         }
 922
 923                                         default: // calling a vote for master
 924                                         {
 925                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 926                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 927                                                         || (autocvar_sv_vote_nospectators == 0));
 928
 929                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 930                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 931                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 932                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 933
 934                                                 else // everything went okay, continue with creating vote
 935                                                 {
 936                                                         vote_caller = caller;
 937                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 938                                                         vote_called = VOTE_MASTER;
 939                                                         vote_called_command = strzone("XXX");
 940                                                         vote_called_display = strzone("^3master");
 941                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 942
 943                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 944                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 945
 946                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 947                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 948                                                         Nagger_VoteChanged();
 949                                                         VoteCount(true); // needed if you are the only one
 950                                                 }
 951
 952                                                 return;
 953                                         }
 954                                 }
 955                         }
 956                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 957
 958                         return;
 959                 }
 960
 961                 default:
 962                 case CMD_REQUEST_USAGE:
 963                 {
 964                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 965                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 966                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 967                         return;
 968                 }
 969         }
 970 }
 971
 972 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 973 {
 974         switch(request)
 975         {
 976                 case CMD_REQUEST_COMMAND:
 977                 {
 978                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 979                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 980                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 981
 982                         else // everything went okay, continue changing vote
 983                         {
 984                                 print_to(caller, "^1You rejected the vote.");
 985                                 caller.vote_selection = VOTE_SELECT_REJECT;
 986                                 msg_entity = caller;
 987                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 988                         }
 989
 990                         return;
 991                 }
 992
 993                 default:
 994                 case CMD_REQUEST_USAGE:
 995                 {
 996                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 997                         print_to(caller, "  No arguments required.");
 998                         return;
 999                 }
1000         }
1001 }
1002
1003 void VoteCommand_status(float request, entity caller) // BOTH
1004 {
1005         switch(request)
1006         {
1007                 case CMD_REQUEST_COMMAND:
1008                 {
1009                         if(vote_called)
1010                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1011                         else
1012                                 print_to(caller, "^1No vote called.");
1013
1014                         return;
1015                 }
1016
1017                 default:
1018                 case CMD_REQUEST_USAGE:
1019                 {
1020                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1021                         print_to(caller, "  No arguments required.");
1022                         return;
1023                 }
1024         }
1025 }
1026
1027 void VoteCommand_stop(float request, entity caller) // BOTH
1028 {
1029         switch(request)
1030         {
1031                 case CMD_REQUEST_COMMAND:
1032                 {
1033                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1034                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
1035                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
1036
1037                         return;
1038                 }
1039
1040                 default:
1041                 case CMD_REQUEST_USAGE:
1042                 {
1043                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1044                         print_to(caller, "  No arguments required.");
1045                         return;
1046                 }
1047         }
1048 }
1049
1050 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1051 {
1052         switch(request)
1053         {
1054                 case CMD_REQUEST_COMMAND:
1055                 {
1056                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1057                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1058
1059                         else // everything went okay, continue changing vote
1060                         {
1061                                 print_to(caller, "^1You accepted the vote.");
1062                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1063                                 msg_entity = caller;
1064                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
1065                         }
1066
1067                         return;
1068                 }
1069
1070                 default:
1071                 case CMD_REQUEST_USAGE:
1072                 {
1073                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1074                         print_to(caller, "  No arguments required.");
1075                         return;
1076                 }
1077         }
1078 }
1079
1080 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1081 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1082 void VoteCommand_(float request)
1083 {
1084         switch(request)
1085         {
1086                 case CMD_REQUEST_COMMAND:
1087                 {
1088
1089                         return;
1090                 }
1091
1092                 default:
1093                 case CMD_REQUEST_USAGE:
1094                 {
1095                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1096                         print_to(caller, "  No arguments required.");
1097                         return;
1098                 }
1099         }
1100 }
1101 */
1102
1103
1104 // ================================
1105 //  Macro system for vote commands
1106 // ================================
1107
1108 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1109 #define VOTE_COMMANDS(request,caller,arguments,command) \
1110         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1111         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1112         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1113         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1114         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1115         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1116         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1117         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1118         /* nothing */
1119
1120 void VoteCommand_macro_help(entity caller, float argc)
1121 {
1122         string command_origin = GetCommandPrefix(caller);
1123
1124         if(argc == 2 || argv(2) == "help") // help display listing all commands
1125         {
1126                 print_to(caller, "\nVoting commands:\n");
1127                 #define VOTE_COMMAND(name,function,description,assignment) \
1128                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1129
1130                 VOTE_COMMANDS(0, caller, 0, "");
1131                 #undef VOTE_COMMAND
1132
1133                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1134                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1135                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1136         }
1137         else // usage for individual command
1138         {
1139                 #define VOTE_COMMAND(name,function,description,assignment) \
1140                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1141
1142                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1143                 #undef VOTE_COMMAND
1144         }
1145
1146         return;
1147 }
1148
1149 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1150 {
1151         #define VOTE_COMMAND(name,function,description,assignment) \
1152                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return true; } } }
1153
1154         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1155         #undef VOTE_COMMAND
1156
1157         return false;
1158 }
1159
1160
1161 // ======================================
1162 //  Main function handling vote commands
1163 // ======================================
1164
1165 void VoteCommand(float request, entity caller, float argc, string vote_command)
1166 {
1167         // Guide for working with argc arguments by example:
1168         // argc:   1    - 2      - 3     - 4
1169         // argv:   0    - 1      - 2     - 3
1170         // cmd     vote - master - login - password
1171
1172         switch(request)
1173         {
1174                 case CMD_REQUEST_COMMAND:
1175                 {
1176                         if(VoteCommand_macro_command(caller, argc, vote_command))
1177                                 return;
1178                 }
1179
1180                 default:
1181                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1182                 case CMD_REQUEST_USAGE:
1183                 {
1184                         VoteCommand_macro_help(caller, argc);
1185                         return;
1186                 }
1187         }
1188 }