qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/net_linked.qh>
   8 #include <common/notifications/all.qh>
   9 #include <common/playerstats.qh>
  10 #include <common/stats.qh>
  11 #include <common/util.qh>
  12 #include <common/weapons/_all.qh>
  13 #include <server/client.qh>
  14 #include <server/command/common.qh>
  15 #include <server/command/vote.qh>
  16 #include <server/damage.qh>
  17 #include <server/gamelog.qh>
  18 #include <server/intermission.qh>
  19 #include <server/mutators/_mod.qh>
  20 #include <server/race.qh>
  21 #include <server/round_handler.qh>
  22 #include <server/scores.qh>
  23 #include <server/teamplay.qh>
  24 #include <server/world.qh>
  25
  26 // =============================================
  27 //  Server side voting code, reworked by Samual
  28 //  Last updated: December 27th, 2011
  29 // =============================================
  30
  31 //  Nagger for players to know status of voting
  32 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  33 {
  34         int nags, i, f, b;
  35         entity e;
  36         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  37
  38         // bits:
  39         //   1 = ready
  40         //   2 = player needs to ready up
  41         //   4 = vote
  42         //   8 = player needs to vote
  43         //  16 = warmup
  44         // sendflags:
  45         //  64 = vote counts
  46         // 128 = vote string
  47
  48         nags = 0;
  49         if (readycount)
  50         {
  51                 nags |= BIT(0);
  52                 if (to.ready == 0) nags |= BIT(1);
  53         }
  54         if (vote_called)
  55         {
  56                 nags |= BIT(2);
  57                 if (to.vote_selection == 0) nags |= BIT(3);
  58         }
  59         if (warmup_stage) nags |= BIT(4);
  60
  61         if (sendflags & BIT(6)) nags |= BIT(6);
  62
  63         if (sendflags & BIT(7)) nags |= BIT(7);
  64
  65         if (!(nags & 4))  // no vote called? send no string
  66                 nags &= ~(BIT(6) | BIT(7));
  67
  68         WriteByte(MSG_ENTITY, nags);
  69
  70         if (nags & BIT(6))
  71         {
  72                 WriteByte(MSG_ENTITY, vote_accept_count);
  73                 WriteByte(MSG_ENTITY, vote_reject_count);
  74                 WriteByte(MSG_ENTITY, vote_needed_overall);
  75                 WriteChar(MSG_ENTITY, to.vote_selection);
  76         }
  77
  78         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  79
  80         if (nags & 1)
  81         {
  82                 for (i = 1; i <= maxclients; i += 8)
  83                 {
  84                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  85                                 if (!IS_REAL_CLIENT(e) || e.ready)
  86                                         f |= b;
  87                         WriteByte(MSG_ENTITY, f);
  88                 }
  89         }
  90
  91         return true;
  92 }
  93
  94 void Nagger_Init()
  95 {
  96         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  97 }
  98
  99 void Nagger_VoteChanged()
 100 {
 101         if (nagger) nagger.SendFlags |= BIT(7);
 102 }
 103
 104 void Nagger_VoteCountChanged()
 105 {
 106         if (nagger) nagger.SendFlags |= BIT(6);
 107 }
 108
 109 void Nagger_ReadyCounted()
 110 {
 111         if (nagger) nagger.SendFlags |= BIT(0);
 112 }
 113
 114 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 115 string OriginalCallerName()
 116 {
 117         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 118         return vote_caller_name;
 119 }
 120
 121 // =======================
 122 //  Game logic for voting
 123 // =======================
 124
 125 void VoteReset()
 126 {
 127         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 128
 129         if (vote_called)
 130         {
 131                 strfree(vote_called_command);
 132                 strfree(vote_called_display);
 133                 strfree(vote_caller_name);
 134         }
 135
 136         vote_called = VOTE_NULL;
 137         vote_caller = NULL;
 138         vote_endtime = 0;
 139
 140         vote_parsed_command = string_null;
 141         vote_parsed_display = string_null;
 142
 143         Nagger_VoteChanged();
 144 }
 145
 146 void VoteStop(entity stopper)
 147 {
 148         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 149         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 150         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 151         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 152         VoteReset();
 153 }
 154
 155 void VoteAccept()
 156 {
 157         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 158
 159         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 160         else localcmd(strcat(vote_called_command, "\n"));
 161
 162         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 163
 164         VoteReset();
 165         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 166 }
 167
 168 void VoteReject()
 169 {
 170         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 171         VoteReset();
 172         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 173 }
 174
 175 void VoteTimeout()
 176 {
 177         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 178         VoteReset();
 179         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 180 }
 181
 182 void VoteSpam(float notvoters, float mincount, string result)
 183 {
 184         bprint(strcat(
 185                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 186                 strcat("^2:^1", ftos(vote_reject_count)),
 187                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 188                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 189                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 190
 191         if (autocvar_sv_eventlog)
 192         {
 193                 GameLogEcho(strcat(
 194                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 195                         strcat(":", ftos(vote_reject_count)),
 196                         strcat(":", ftos(vote_abstain_count)),
 197                         strcat(":", ftos(notvoters)),
 198                         strcat(":", ftos(mincount))));
 199         }
 200 }
 201
 202 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 203
 204 void VoteCount(float first_count)
 205 {
 206         // declarations
 207         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 208
 209         float vote_player_count = 0, notvoters = 0;
 210         float vote_real_player_count = 0, vote_real_accept_count = 0;
 211         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 212         float vote_needed_of_voted, final_needed_votes;
 213         float vote_factor_overall, vote_factor_of_voted;
 214
 215         Nagger_VoteCountChanged();
 216
 217         // add up all the votes from each connected client
 218         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 219                 ++vote_player_count;
 220                 if (IS_PLAYER(it))   ++vote_real_player_count;
 221                 switch (it.vote_selection)
 222                 {
 223                         case VOTE_SELECT_REJECT:
 224                         { ++vote_reject_count;
 225                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 226                         }
 227                         case VOTE_SELECT_ACCEPT:
 228                         { ++vote_accept_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 230                         }
 231                         case VOTE_SELECT_ABSTAIN:
 232                         { ++vote_abstain_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 234                         }
 235                         default: break;
 236                 }
 237         });
 238
 239         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 240         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 241         {
 242                 if (vote_caller)   vote_caller.vote_waittime = 0;
 243                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 244                 VoteReset();
 245                 return;
 246         }
 247
 248         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 249         if (!spectators_allowed && (vote_real_player_count > 0))
 250         {
 251                 vote_accept_count = vote_real_accept_count;
 252                 vote_reject_count = vote_real_reject_count;
 253                 vote_abstain_count = vote_real_abstain_count;
 254                 vote_player_count = vote_real_player_count;
 255         }
 256
 257         // people who have no opinion in any way :D
 258         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 259
 260         // determine the goal for the vote to be passed or rejected normally
 261         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 262         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 263
 264         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 265         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 266         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 267
 268         // are there any players at all on the server? it could be an admin vote
 269         if (vote_player_count == 0 && first_count)
 270         {
 271                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 272                 VoteAccept();
 273                 return;
 274         }
 275
 276         // since there ARE players, finally calculate the result of the vote
 277         if (vote_accept_count >= vote_needed_overall)
 278         {
 279                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 280                 VoteAccept();
 281                 return;
 282         }
 283
 284         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 285         {
 286                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 287                 VoteReject();
 288                 return;
 289         }
 290
 291         // there is not enough votes in either direction, now lets just calculate what the voters have said
 292         if (time > vote_endtime)
 293         {
 294                 final_needed_votes = vote_needed_overall;
 295
 296                 if (autocvar_sv_vote_majority_factor_of_voted)
 297                 {
 298                         if (vote_accept_count >= vote_needed_of_voted)
 299                         {
 300                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 301                                 VoteAccept();
 302                                 return;
 303                         }
 304
 305                         if (vote_accept_count + vote_reject_count > 0)
 306                         {
 307                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 308                                 VoteReject();
 309                                 return;
 310                         }
 311
 312                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 313                 }
 314
 315                 // it didn't pass or fail, so not enough votes to even make a decision.
 316                 VoteSpam(notvoters, final_needed_votes, "timeout");
 317                 VoteTimeout();
 318         }
 319 }
 320
 321 void VoteThink()
 322 {
 323         if (vote_endtime > 0)        // a vote was called
 324         {
 325                 if (time > vote_endtime) // time is up
 326                         VoteCount(false);
 327         }
 328 }
 329
 330
 331 // =======================
 332 //  Game logic for warmup
 333 // =======================
 334
 335 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 336 void reset_map(bool dorespawn)
 337 {
 338         if (time <= game_starttime)
 339         {
 340                 if (game_stopped)
 341                         return;
 342                 if (round_handler_IsActive())
 343                         round_handler_Reset(game_starttime);
 344         }
 345
 346         if (shuffleteams_on_reset_map)
 347         {
 348                 shuffleteams();
 349                 shuffleteams_on_reset_map = false;
 350         }
 351         MUTATOR_CALLHOOK(reset_map_global);
 352
 353         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 354         {
 355                 if(IS_CLIENT(it))
 356                         continue;
 357                 if (it.reset)
 358                 {
 359                         it.reset(it);
 360                         continue;
 361                 }
 362                 if (it.team_saved) it.team = it.team_saved;
 363                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 364         });
 365
 366         // Waypoints and assault start come LAST
 367         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 368                 if (it.reset2) it.reset2(it);
 369         });
 370
 371         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it, false); });
 372
 373         // Moving the player reset code here since the player-reset depends
 374         // on spawnpoint entities which have to be reset first --blub
 375         if (dorespawn)
 376         {
 377                 if (!MUTATOR_CALLHOOK(reset_map_players))
 378                 {
 379                         if (restart_mapalreadyrestarted || (time < game_starttime))
 380                         {
 381                                 FOREACH_CLIENT(IS_PLAYER(it),
 382                                 {
 383                                         /*
 384                                         only reset players if a restart countdown is active
 385                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 386                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 387                                         sv_ready_restart_after_countdown is not used and countdown is still running
 388                                         */
 389                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 390                                         // PlayerScore_Clear(it);
 391                                         CS(it).killcount = 0;
 392                                         // stop the player from moving so that he stands still once he gets respawned
 393                                         it.velocity = '0 0 0';
 394                                         it.avelocity = '0 0 0';
 395                                         CS(it).movement = '0 0 0';
 396                                         PutClientInServer(it);
 397                                 });
 398                         }
 399                 }
 400         }
 401 }
 402
 403 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 404 void ReadyRestart_think(entity this)
 405 {
 406         restart_mapalreadyrestarted = true;
 407         reset_map(true);
 408         Score_ClearAll();
 409         delete(this);
 410 }
 411
 412 // Forces a restart of the game without actually reloading the map // this is a mess...
 413 void ReadyRestart_force()
 414 {
 415         if (time <= game_starttime && game_stopped)
 416                 return;
 417
 418         bprint("^1Server is restarting...\n");
 419
 420         VoteReset();
 421
 422         // clear overtime, we have to decrease timelimit to its original value again.
 423         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 424                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 425         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 426
 427         readyrestart_happened = true;
 428         game_starttime = time + RESTART_COUNTDOWN;
 429
 430         // clear player attributes
 431         FOREACH_CLIENT(IS_PLAYER(it), {
 432                 it.alivetime = 0;
 433                 CS(it).killcount = 0;
 434                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 435                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 436         });
 437
 438         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 439
 440         // disable the warmup global for the server
 441         if(warmup_stage)
 442                 localcmd("\nsv_hook_warmupend\n");
 443         warmup_stage = 0;                // once the game is restarted the game is in match stage
 444
 445         // reset the .ready status of all players (also spectators)
 446         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 447         readycount = 0;
 448         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 449
 450         // lock teams with lockonrestart
 451         if (autocvar_teamplay_lockonrestart && teamplay)
 452         {
 453                 lockteams = true;
 454                 bprint("^1The teams are now locked.\n");
 455         }
 456
 457         // initiate the restart-countdown-announcer entity
 458         if (sv_ready_restart_after_countdown)
 459         {
 460                 entity restart_timer = new_pure(restart_timer);
 461                 setthink(restart_timer, ReadyRestart_think);
 462                 restart_timer.nextthink = game_starttime;
 463         }
 464
 465         // after a restart every players number of allowed timeouts gets reset, too
 466         if (autocvar_sv_timeout)
 467         {
 468                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 469         }
 470
 471         if (!sv_ready_restart_after_countdown) reset_map(true);
 472         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 473 }
 474
 475 void ReadyRestart()
 476 {
 477         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 478         else localcmd("\nsv_hook_readyrestart\n");
 479
 480         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 481         // Otherwise scores could be manipulated during the countdown.
 482         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 483         ReadyRestart_force();
 484 }
 485
 486 // Count the players who are ready and determine whether or not to restart the match
 487 void ReadyCount()
 488 {
 489         float ready_needed_factor, ready_needed_count;
 490         float t_ready = 0, t_players = 0;
 491
 492         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 493                 ++t_players;
 494                 if (it.ready) ++t_ready;
 495         });
 496
 497         readycount = t_ready;
 498
 499         Nagger_ReadyCounted();
 500
 501         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 502         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 503
 504         if (readycount >= ready_needed_count) ReadyRestart();
 505 }
 506
 507
 508 // ======================================
 509 //  Supporting functions for VoteCommand
 510 // ======================================
 511
 512 float Votecommand_check_assignment(entity caller, float assignment)
 513 {
 514         float from_server = (!caller);
 515
 516         if ((assignment == VC_ASGNMNT_BOTH)
 517             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 518             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 519
 520         return false;
 521 }
 522
 523 string VoteCommand_extractcommand(string input, float startpos, int argc)
 524 {
 525         string output;
 526
 527         if ((argc - 1) < startpos) output = "";
 528         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 529
 530         return output;
 531 }
 532
 533 float VoteCommand_checknasty(string vote_command)
 534 {
 535         if ((strstrofs(vote_command, ";", 0) >= 0)
 536             || (strstrofs(vote_command, "\n", 0) >= 0)
 537             || (strstrofs(vote_command, "\r", 0) >= 0)
 538             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 539
 540         return true;
 541 }
 542
 543 // NOTE: requires input to be surrounded by spaces
 544 string VoteCommand_checkreplacements(string input)
 545 {
 546         string output = input;
 547         // allow gotomap replacements
 548         output = strreplace(" map ", " gotomap ", output);
 549         output = strreplace(" chmap ", " gotomap ", output);
 550         return output;
 551 }
 552
 553 float VoteCommand_checkinlist(string vote_command, string list)
 554 {
 555         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 556
 557         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 558
 559         return false;
 560 }
 561
 562 string ValidateMap(string validated_map, entity caller)
 563 {
 564         validated_map = MapInfo_FixName(validated_map);
 565
 566         if (!validated_map)
 567         {
 568                 print_to(caller, "This map is not available on this server.");
 569                 return string_null;
 570         }
 571
 572         if (!autocvar_sv_vote_override_mostrecent && caller)
 573         {
 574                 if (Map_IsRecent(validated_map))
 575                 {
 576                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 577                         return string_null;
 578                 }
 579         }
 580
 581         if (!MapInfo_CheckMap(validated_map))
 582         {
 583                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 584                 return string_null;
 585         }
 586
 587         return validated_map;
 588 }
 589
 590 float VoteCommand_checkargs(float startpos, int argc)
 591 {
 592         float p, q, check, minargs;
 593         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 594         string cmdrestriction = "";  // No we don't.
 595         string charlist, arg;
 596         float checkmate;
 597
 598         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 599                 cmdrestriction = cvar_string(cvarname);
 600         else
 601                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 602
 603         if (cmdrestriction == "") return true;
 604
 605         ++startpos;  // skip command name
 606
 607         // check minimum arg count
 608
 609         // 0 args: argc == startpos
 610         // 1 args: argc == startpos + 1
 611         // ...
 612
 613         minargs = stof(cmdrestriction);
 614         if (argc - startpos < minargs) return false;
 615
 616         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 617
 618         for ( ; ; )
 619         {
 620                 // we know that at any time, startpos <= argc - minargs
 621                 // so this means: argc-minargs >= startpos >= argc, thus
 622                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 623                 // have been seen already
 624
 625                 if (startpos >= argc) // all args checked? GOOD
 626                         break;
 627
 628                 if (p < 0)            // no more args? FAIL
 629                 {
 630                         // exception: exactly minargs left, this one included
 631                         if (argc - startpos == minargs) break;
 632
 633                         // otherwise fail
 634                         return false;
 635                 }
 636
 637                 // cut to next semicolon
 638                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 639                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 640                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 641
 642                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 643                 // charlist = strreplace("^^", ";", charlist);
 644
 645                 if (charlist != "")
 646                 {
 647                         // verify the arg only contains allowed chars
 648                         arg = argv(startpos);
 649                         checkmate = strlen(arg);
 650                         for (check = 0; check < checkmate; ++check)
 651                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 652                         // not allowed character
 653                         // all characters are allowed. FINE.
 654                 }
 655
 656                 ++startpos;
 657                 --minargs;
 658                 p = q;
 659         }
 660
 661         return true;
 662 }
 663
 664 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 665 {
 666         string first_command = argv(startpos);
 667         int missing_chars = argv_start_index(startpos);
 668
 669         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 670                 return 0;
 671
 672         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 673
 674         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 675
 676         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 677         {
 678                 case MUT_VOTEPARSE_CONTINUE: { break; }
 679                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 680                 case MUT_VOTEPARSE_INVALID: { return -1; }
 681                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 682         }
 683
 684         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 685         {
 686                 case "kick":
 687                 case "kickban":    // catch all kick/kickban commands
 688                 {
 689                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 690                         float accepted = VerifyClientEntity(victim, true, false);
 691
 692                         if (accepted > 0)
 693                         {
 694                                 string reason = "No reason provided";
 695                                 if(argc > next_token)
 696                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 697
 698                                 string command_arguments = reason;
 699                                 if (first_command == "kickban")
 700                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 701
 702                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 703                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 704                         }
 705                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 706
 707                         break;
 708                 }
 709
 710                 case "map":
 711                 case "chmap":
 712                 case "gotomap":  // re-direct all map selection commands to gotomap
 713                 {
 714                         vote_command = ValidateMap(argv(startpos + 1), caller);
 715                         if (!vote_command)  return -1;
 716                         vote_parsed_command = strcat("gotomap ", vote_command);
 717                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 718
 719                         break;
 720                 }
 721
 722                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 723                 // maybe fallback instead of aborting if map name is invalid?
 724                 case "nextmap":
 725                 {
 726                         vote_command = ValidateMap(argv(startpos + 1), caller);
 727                         if (!vote_command)  return -1;
 728                         vote_parsed_command = strcat("nextmap ", vote_command);
 729                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 730
 731                         break;
 732                 }
 733
 734                 case "timelimit": // include restrictions on the maximum votable time limit
 735                 {
 736                         float timelimit_vote = stof(argv(startpos + 1));
 737                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 738                         {
 739                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 740                                 return -1;
 741                         }
 742                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 743                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 744                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 745
 746                         break;
 747                 }
 748
 749                 case "restart":
 750                 {
 751                         // add a delay so that vote result can be seen and announcer can be heard
 752                         // if the vote is accepted
 753                         vote_parsed_command = strcat("defer 1 ", vote_command);
 754                         vote_parsed_display = strzone(strcat("^1", vote_command));
 755
 756                         break;
 757                 }
 758
 759                 default:
 760                 {
 761                         vote_parsed_command = vote_command;
 762                         vote_parsed_display = strzone(strcat("^1", vote_command));
 763
 764                         break;
 765                 }
 766         }
 767
 768         return 1;
 769 }
 770
 771
 772 // =======================
 773 //  Command Sub-Functions
 774 // =======================
 775
 776 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 777 {
 778         switch (request)
 779         {
 780                 case CMD_REQUEST_COMMAND:
 781                 {
 782                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 783                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 784                         {
 785                                 print_to(caller, "^1You have already voted.");
 786                         }
 787
 788                         else  // everything went okay, continue changing vote
 789                         {
 790                                 print_to(caller, "^1You abstained from your vote.");
 791                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 792                                 msg_entity = caller;
 793                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 794
 795                         return;
 796                 }
 797
 798                 default:
 799                 case CMD_REQUEST_USAGE:
 800                 {
 801                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 802                         print_to(caller, "  No arguments required.");
 803                         return;
 804                 }
 805         }
 806 }
 807
 808 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 809 {
 810         switch (request)
 811         {
 812                 case CMD_REQUEST_COMMAND:
 813                 {
 814                         float tmp_playercount = 0;
 815                         int parse_error;
 816
 817                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 818
 819                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 820                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 821                         {
 822                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 823                         }
 824                         else if (vote_called)
 825                         {
 826                                 print_to(caller, "^1There is already a vote called.");
 827                         }
 828                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 829                         {
 830                                 print_to(caller, "^1Only players can call a vote.");
 831                         }
 832                         else if (caller && !IS_CLIENT(caller))
 833                         {
 834                                 print_to(caller, "^1Only connected clients can vote.");
 835                         }
 836                         else if (timeout_status && vote_command != "timein")
 837                         {
 838                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 839                         }
 840                         else if (caller && (time < caller.vote_waittime))
 841                         {
 842                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 843                         }
 844                         else if (!VoteCommand_checknasty(vote_command))
 845                         {
 846                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 847                         }
 848                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 849                         {
 850                                 if(parse_error == 0)
 851                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 852                         }
 853                         else  // everything went okay, continue with calling the vote
 854                         {
 855                                 vote_caller = caller;  // remember who called the vote
 856                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 857                                 vote_called = VOTE_NORMAL;
 858                                 vote_called_command = strzone(vote_parsed_command);
 859                                 vote_called_display = strzone(vote_parsed_display);
 860                                 vote_endtime = time + autocvar_sv_vote_timeout;
 861
 862                                 if (caller)
 863                                 {
 864                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 865                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 866                                         msg_entity = caller;
 867                                 }
 868
 869                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 870
 871                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 872                                 if (autocvar_sv_eventlog)
 873                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 874                                 Nagger_VoteChanged();
 875                                 VoteCount(true);  // needed if you are the only one
 876
 877                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 878                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 879                         }
 880
 881                         return;
 882                 }
 883
 884                 default:
 885                 case CMD_REQUEST_USAGE:
 886                 {
 887                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 888                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 889                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 890                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 891                         return;
 892                 }
 893         }
 894 }
 895
 896 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 897 {
 898         switch (request)
 899         {
 900                 case CMD_REQUEST_COMMAND:
 901                 {
 902                         if (autocvar_sv_vote_master)
 903                         {
 904                                 switch (strtolower(argv(2)))
 905                                 {
 906                                         case "do":
 907                                         {
 908                                                 int parse_error;
 909                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 910
 911                                                 if (!caller.vote_master)
 912                                                         print_to(caller, "^1You do not have vote master privileges.");
 913                                                 else if (!VoteCommand_checknasty(vote_command))
 914                                                 {
 915                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 916                                                 }
 917                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 918                                                 {
 919                                                         if(parse_error == 0)
 920                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 921                                                 }
 922                                                 else  // everything went okay, proceed with command
 923                                                 {
 924                                                         localcmd(strcat(vote_parsed_command, "\n"));
 925                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 926                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 927                                                         if (autocvar_sv_eventlog)
 928                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 929                                                 }
 930
 931                                                 return;
 932                                         }
 933
 934                                         case "login":
 935                                         {
 936                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 937                                                 else if (caller.vote_master)
 938                                                 {
 939                                                         print_to(caller, "^1You are already logged in as vote master.");
 940                                                 }
 941                                                 else if (autocvar_sv_vote_master_password != argv(3))
 942                                                 {
 943                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 944                                                 }
 945                                                 else  // everything went okay, proceed with giving this player master privilages
 946                                                 {
 947                                                         caller.vote_master = true;
 948                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 949                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 950                                                         if (autocvar_sv_eventlog)
 951                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 952                                                 }
 953
 954                                                 return;
 955                                         }
 956
 957                                         default:  // calling a vote for master
 958                                         {
 959                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 960                                                 else if (vote_called)
 961                                                 {
 962                                                         print_to(caller, "^1There is already a vote called.");
 963                                                 }
 964                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 965                                                 {
 966                                                         print_to(caller, "^1Only players can call a vote.");
 967                                                 }
 968                                                 else if (timeout_status)
 969                                                 {
 970                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 971                                                 }
 972                                                 else  // everything went okay, continue with creating vote
 973                                                 {
 974                                                         vote_caller = caller;
 975                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 976                                                         vote_called = VOTE_MASTER;
 977                                                         vote_called_command = strzone("XXX");
 978                                                         vote_called_display = strzone("^3master");
 979                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 980
 981                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 982                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 983
 984                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 985                                                         if (autocvar_sv_eventlog)
 986                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 987                                                         Nagger_VoteChanged();
 988                                                         VoteCount(true);  // needed if you are the only one
 989                                                 }
 990
 991                                                 return;
 992                                         }
 993                                 }
 994                         }
 995                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 996
 997                         return;
 998                 }
 999
1000                 default:
1001                 case CMD_REQUEST_USAGE:
1002                 {
1003                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
1004                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
1005                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
1006                         return;
1007                 }
1008         }
1009 }
1010
1011 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1012 {
1013         switch (request)
1014         {
1015                 case CMD_REQUEST_COMMAND:
1016                 {
1017                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1018                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1019                         {
1020                                 print_to(caller, "^1You have already voted.");
1021                         }
1022                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1023                         {
1024                                 VoteStop(caller);
1025                         }
1026
1027                         else  // everything went okay, continue changing vote
1028                         {
1029                                 print_to(caller, "^1You rejected the vote.");
1030                                 caller.vote_selection = VOTE_SELECT_REJECT;
1031                                 msg_entity = caller;
1032                                 if (!autocvar_sv_vote_singlecount)
1033                                         VoteCount(false);
1034                         }
1035
1036                         return;
1037                 }
1038
1039                 default:
1040                 case CMD_REQUEST_USAGE:
1041                 {
1042                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1043                         print_to(caller, "  No arguments required.");
1044                         return;
1045                 }
1046         }
1047 }
1048
1049 void VoteCommand_status(int request, entity caller)  // BOTH
1050 {
1051         switch (request)
1052         {
1053                 case CMD_REQUEST_COMMAND:
1054                 {
1055                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1056                         else print_to(caller, "^1No vote called.");
1057
1058                         return;
1059                 }
1060
1061                 default:
1062                 case CMD_REQUEST_USAGE:
1063                 {
1064                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1065                         print_to(caller, "  No arguments required.");
1066                         return;
1067                 }
1068         }
1069 }
1070
1071 void VoteCommand_stop(int request, entity caller)  // BOTH
1072 {
1073         switch (request)
1074         {
1075                 case CMD_REQUEST_COMMAND:
1076                 {
1077                         if (!vote_called)   print_to(caller, "^1No vote called.");
1078                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1079                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1080                         return;
1081                 }
1082
1083                 default:
1084                 case CMD_REQUEST_USAGE:
1085                 {
1086                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1087                         print_to(caller, "  No arguments required.");
1088                         return;
1089                 }
1090         }
1091 }
1092
1093 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1094 {
1095         switch (request)
1096         {
1097                 case CMD_REQUEST_COMMAND:
1098                 {
1099                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1100                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1101                         {
1102                                 print_to(caller, "^1You have already voted.");
1103                         }
1104                         else  // everything went okay, continue changing vote
1105                         {
1106                                 print_to(caller, "^1You accepted the vote.");
1107                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1108                                 msg_entity = caller;
1109                                 if (!autocvar_sv_vote_singlecount)
1110                                         VoteCount(false);
1111                         }
1112
1113                         return;
1114                 }
1115
1116                 default:
1117                 case CMD_REQUEST_USAGE:
1118                 {
1119                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1120                         print_to(caller, "  No arguments required.");
1121                         return;
1122                 }
1123         }
1124 }
1125
1126 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1127 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1128 void VoteCommand_(int request)
1129 {
1130     switch(request)
1131     {
1132         case CMD_REQUEST_COMMAND:
1133         {
1134
1135             return;
1136         }
1137
1138         default:
1139         case CMD_REQUEST_USAGE:
1140         {
1141             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1142             print_to(caller, "  No arguments required.");
1143             return;
1144         }
1145     }
1146 }
1147 */
1148
1149
1150 // ================================
1151 //  Macro system for vote commands
1152 // ================================
1153
1154 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1155 #define VOTE_COMMANDS(request, caller, arguments, command) \
1156         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1157         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1158         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1159         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1160         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1161         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1162         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1163         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1164         /* nothing */
1165
1166 void VoteCommand_macro_help(entity caller, int argc)
1167 {
1168         string command_origin = GetCommandPrefix(caller);
1169
1170         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1171         {
1172                 print_to(caller, "\nVoting commands:\n");
1173                 #define VOTE_COMMAND(name, function, description, assignment) \
1174                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1175
1176                 VOTE_COMMANDS(0, caller, 0, "");
1177 #undef VOTE_COMMAND
1178
1179                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1180                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1181                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1182         }
1183         else  // usage for individual command
1184         {
1185                 #define VOTE_COMMAND(name, function, description, assignment) \
1186                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1187
1188                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1189 #undef VOTE_COMMAND
1190
1191                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1192                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1193                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1194                 else
1195                         print_to(caller, "No documentation exists for this vote");
1196         }
1197 }
1198
1199 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1200 {
1201         #define VOTE_COMMAND(name, function, description, assignment) \
1202                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1203
1204         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1205 #undef VOTE_COMMAND
1206
1207         return false;
1208 }
1209
1210
1211 // ======================================
1212 //  Main function handling vote commands
1213 // ======================================
1214
1215 void VoteCommand(int request, entity caller, int argc, string vote_command)
1216 {
1217         // Guide for working with argc arguments by example:
1218         // argc:   1    - 2      - 3     - 4
1219         // argv:   0    - 1      - 2     - 3
1220         // cmd     vote - master - login - password
1221
1222         switch (request)
1223         {
1224                 case CMD_REQUEST_COMMAND:
1225                 {
1226                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1227                 }
1228
1229                 default:
1230                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1231                 case CMD_REQUEST_USAGE:
1232                 {
1233                         VoteCommand_macro_help(caller, argc);
1234                         return;
1235                 }
1236         }
1237 }