qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2 #include <common/command/_mod.qh>
   3 #include "vote.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/_mod.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/notifications/all.qh>
  19 #include <common/playerstats.qh>
  20 #include <common/util.qh>
  21
  22 // =============================================
  23 //  Server side voting code, reworked by Samual
  24 //  Last updated: December 27th, 2011
  25 // =============================================
  26
  27 //  Nagger for players to know status of voting
  28 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  29 {
  30         int nags, i, f, b;
  31         entity e;
  32         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  33
  34         // bits:
  35         //   1 = ready
  36         //   2 = player needs to ready up
  37         //   4 = vote
  38         //   8 = player needs to vote
  39         //  16 = warmup
  40         // sendflags:
  41         //  64 = vote counts
  42         // 128 = vote string
  43
  44         nags = 0;
  45         if (readycount)
  46         {
  47                 nags |= BIT(0);
  48                 if (to.ready == 0) nags |= BIT(1);
  49         }
  50         if (vote_called)
  51         {
  52                 nags |= BIT(2);
  53                 if (to.vote_selection == 0) nags |= BIT(3);
  54         }
  55         if (warmup_stage) nags |= BIT(4);
  56
  57         if (sendflags & BIT(6)) nags |= BIT(6);
  58
  59         if (sendflags & BIT(7)) nags |= BIT(7);
  60
  61         if (!(nags & 4))  // no vote called? send no string
  62                 nags &= ~(BIT(6) | BIT(7));
  63
  64         WriteByte(MSG_ENTITY, nags);
  65
  66         if (nags & BIT(6))
  67         {
  68                 WriteByte(MSG_ENTITY, vote_accept_count);
  69                 WriteByte(MSG_ENTITY, vote_reject_count);
  70                 WriteByte(MSG_ENTITY, vote_needed_overall);
  71                 WriteChar(MSG_ENTITY, to.vote_selection);
  72         }
  73
  74         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  75
  76         if (nags & 1)
  77         {
  78                 for (i = 1; i <= maxclients; i += 8)
  79                 {
  80                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  81                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  82                         WriteByte(MSG_ENTITY, f);
  83                 }
  84         }
  85
  86         return true;
  87 }
  88
  89 void Nagger_Init()
  90 {
  91         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  92 }
  93
  94 void Nagger_VoteChanged()
  95 {
  96         if (nagger) nagger.SendFlags |= BIT(7);
  97 }
  98
  99 void Nagger_VoteCountChanged()
 100 {
 101         if (nagger) nagger.SendFlags |= BIT(6);
 102 }
 103
 104 void Nagger_ReadyCounted()
 105 {
 106         if (nagger) nagger.SendFlags |= BIT(0);
 107 }
 108
 109 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 110 string OriginalCallerName()
 111 {
 112         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 113         return vote_caller_name;
 114 }
 115
 116 // =======================
 117 //  Game logic for voting
 118 // =======================
 119
 120 void VoteReset()
 121 {
 122         FOREACH_CLIENT(true, LAMBDA(it.vote_selection = 0));
 123
 124         if (vote_called)
 125         {
 126                 strunzone(vote_called_command);
 127                 strunzone(vote_called_display);
 128                 strunzone(vote_caller_name);
 129         }
 130
 131         vote_called = VOTE_NULL;
 132         vote_caller = NULL;
 133         vote_caller_name = string_null;
 134         vote_endtime = 0;
 135
 136         vote_called_command = string_null;
 137         vote_called_display = string_null;
 138
 139         vote_parsed_command = string_null;
 140         vote_parsed_display = string_null;
 141
 142         Nagger_VoteChanged();
 143 }
 144
 145 void VoteStop(entity stopper)
 146 {
 147         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 148         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 149         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 150         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 151         VoteReset();
 152 }
 153
 154 void VoteAccept()
 155 {
 156         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 157
 158         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 159         else localcmd(strcat(vote_called_command, "\n"));
 160
 161         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 162
 163         VoteReset();
 164         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 165 }
 166
 167 void VoteReject()
 168 {
 169         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 170         VoteReset();
 171         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 172 }
 173
 174 void VoteTimeout()
 175 {
 176         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 177         VoteReset();
 178         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 179 }
 180
 181 void VoteSpam(float notvoters, float mincount, string result)
 182 {
 183         bprint(strcat(
 184                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 185                 strcat("^2:^1", ftos(vote_reject_count)),
 186                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 187                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 188                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 189
 190         if (autocvar_sv_eventlog)
 191         {
 192                 GameLogEcho(strcat(
 193                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 194                         strcat(":", ftos(vote_reject_count)),
 195                         strcat(":", ftos(vote_abstain_count)),
 196                         strcat(":", ftos(notvoters)),
 197                         strcat(":", ftos(mincount))));
 198         }
 199 }
 200
 201 void VoteCount(float first_count)
 202 {
 203         // declarations
 204         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 205
 206         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 207
 208         float vote_player_count = 0, notvoters = 0;
 209         float vote_real_player_count = 0, vote_real_accept_count = 0;
 210         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 211         float vote_needed_of_voted, final_needed_votes;
 212         float vote_factor_overall, vote_factor_of_voted;
 213
 214         Nagger_VoteCountChanged();
 215
 216         // add up all the votes from each connected client
 217         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), LAMBDA(
 218                 ++vote_player_count;
 219                 if (IS_PLAYER(it))   ++vote_real_player_count;
 220                 switch (it.vote_selection)
 221                 {
 222                         case VOTE_SELECT_REJECT:
 223                         { ++vote_reject_count;
 224                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 225                         }
 226                         case VOTE_SELECT_ACCEPT:
 227                         { ++vote_accept_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 229                         }
 230                         case VOTE_SELECT_ABSTAIN:
 231                         { ++vote_abstain_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 233                         }
 234                         default: break;
 235                 }
 236         ));
 237
 238         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 239         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 240         {
 241                 if (vote_caller)   vote_caller.vote_waittime = 0;
 242                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 243                 VoteReset();
 244                 return;
 245         }
 246
 247         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 248         if (!spectators_allowed && (vote_real_player_count > 0))
 249         {
 250                 vote_accept_count = vote_real_accept_count;
 251                 vote_reject_count = vote_real_reject_count;
 252                 vote_abstain_count = vote_real_abstain_count;
 253                 vote_player_count = vote_real_player_count;
 254         }
 255
 256         // people who have no opinion in any way :D
 257         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 258
 259         // determine the goal for the vote to be passed or rejected normally
 260         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 261         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 262
 263         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 264         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 265         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 266
 267         // are there any players at all on the server? it could be an admin vote
 268         if (vote_player_count == 0 && first_count)
 269         {
 270                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 271                 VoteAccept();
 272                 return;
 273         }
 274
 275         // since there ARE players, finally calculate the result of the vote
 276         if (vote_accept_count >= vote_needed_overall)
 277         {
 278                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 279                 VoteAccept();
 280                 return;
 281         }
 282
 283         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 284         {
 285                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 286                 VoteReject();
 287                 return;
 288         }
 289
 290         // there is not enough votes in either direction, now lets just calculate what the voters have said
 291         if (time > vote_endtime)
 292         {
 293                 final_needed_votes = vote_needed_overall;
 294
 295                 if (autocvar_sv_vote_majority_factor_of_voted)
 296                 {
 297                         if (vote_accept_count >= vote_needed_of_voted)
 298                         {
 299                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 300                                 VoteAccept();
 301                                 return;
 302                         }
 303
 304                         if (vote_accept_count + vote_reject_count > 0)
 305                         {
 306                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 307                                 VoteReject();
 308                                 return;
 309                         }
 310
 311                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 312                 }
 313
 314                 // it didn't pass or fail, so not enough votes to even make a decision.
 315                 VoteSpam(notvoters, final_needed_votes, "timeout");
 316                 VoteTimeout();
 317         }
 318 }
 319
 320 void VoteThink()
 321 {
 322         if (vote_endtime > 0)        // a vote was called
 323         {
 324                 if (time > vote_endtime) // time is up
 325                         VoteCount(false);
 326         }
 327 }
 328
 329
 330 // =======================
 331 //  Game logic for warmup
 332 // =======================
 333
 334 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 335 void reset_map(bool dorespawn)
 336 {
 337         if (time <= game_starttime)
 338         {
 339                 if (gameover)
 340                         return;
 341                 if (round_handler_IsActive())
 342                         round_handler_Reset(game_starttime);
 343         }
 344
 345         MUTATOR_CALLHOOK(reset_map_global);
 346
 347         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 348                 if (it.reset)
 349                 {
 350                         it.reset(it);
 351                         continue;
 352                 }
 353                 if (it.team_saved) it.team = it.team_saved;
 354                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 355         });
 356
 357         // Waypoints and assault start come LAST
 358         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 359                 if (it.reset2) it.reset2(it);
 360         });
 361
 362         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), LAMBDA(Unfreeze(it)));
 363
 364         // Moving the player reset code here since the player-reset depends
 365         // on spawnpoint entities which have to be reset first --blub
 366         if (dorespawn)
 367         {
 368                 if (!MUTATOR_CALLHOOK(reset_map_players))
 369                 {
 370                         FOREACH_CLIENT(true, LAMBDA(
 371                                 /*
 372                                 only reset players if a restart countdown is active
 373                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 374                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 375                                 sv_ready_restart_after_countdown is not used and countdown is still running
 376                                 */
 377                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 378                                 {
 379                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 380                                         if (IS_PLAYER(it))
 381                                         {
 382                                                 // PlayerScore_Clear(it);
 383                                                 it.killcount = 0;
 384                                                 // stop the player from moving so that he stands still once he gets respawned
 385                                                 it.velocity = '0 0 0';
 386                                                 it.avelocity = '0 0 0';
 387                                                 it.movement = '0 0 0';
 388                                                 PutClientInServer(it);
 389                                         }
 390                                 }
 391                         ));
 392                 }
 393         }
 394 }
 395
 396 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 397 void ReadyRestart_think(entity this)
 398 {
 399         restart_mapalreadyrestarted = true;
 400         reset_map(true);
 401         Score_ClearAll();
 402         delete(this);
 403 }
 404
 405 // Forces a restart of the game without actually reloading the map // this is a mess...
 406 void ReadyRestart_force()
 407 {
 408         if (time <= game_starttime && gameover)
 409                 return;
 410
 411         bprint("^1Server is restarting...\n");
 412
 413         VoteReset();
 414
 415         // clear overtime, we have to decrease timelimit to its original value again.
 416         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 417                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 418         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 419
 420         readyrestart_happened = true;
 421         game_starttime = time + RESTART_COUNTDOWN;
 422
 423         // clear player attributes
 424         FOREACH_CLIENT(true, LAMBDA(
 425                 it.alivetime = 0;
 426                 it.killcount = 0;
 427                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 428         ));
 429
 430         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 431
 432         // disable the warmup global for the server
 433         warmup_stage = 0;                // once the game is restarted the game is in match stage
 434
 435         // reset the .ready status of all players (also spectators)
 436         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(it.ready = false));
 437         readycount = 0;
 438         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 439
 440         // lock teams with lockonrestart
 441         if (autocvar_teamplay_lockonrestart && teamplay)
 442         {
 443                 lockteams = true;
 444                 bprint("^1The teams are now locked.\n");
 445         }
 446
 447         // initiate the restart-countdown-announcer entity
 448         if (autocvar_sv_ready_restart_after_countdown)
 449         {
 450                 entity restart_timer = new_pure(restart_timer);
 451                 setthink(restart_timer, ReadyRestart_think);
 452                 restart_timer.nextthink = game_starttime;
 453         }
 454
 455         // after a restart every players number of allowed timeouts gets reset, too
 456         if (autocvar_sv_timeout)
 457         {
 458                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(it.allowed_timeouts = autocvar_sv_timeout_number));
 459         }
 460     // reset map immediately if this cvar is not set
 461     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 462         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 463 }
 464
 465 void ReadyRestart()
 466 {
 467         // no assault support yet...
 468         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 469         else localcmd("\nsv_hook_gamerestart\n");
 470
 471         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 472         // Otherwise scores could be manipulated during the countdown.
 473         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 474         ReadyRestart_force();
 475 }
 476
 477 // Count the players who are ready and determine whether or not to restart the match
 478 void ReadyCount()
 479 {
 480         float ready_needed_factor, ready_needed_count;
 481         float t_ready = 0, t_players = 0;
 482
 483         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), LAMBDA(
 484                 ++t_players;
 485                 if (it.ready) ++t_ready;
 486         ));
 487
 488         readycount = t_ready;
 489
 490         Nagger_ReadyCounted();
 491
 492         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 493         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 494
 495         if (readycount >= ready_needed_count) ReadyRestart();
 496 }
 497
 498
 499 // ======================================
 500 //  Supporting functions for VoteCommand
 501 // ======================================
 502
 503 float Votecommand_check_assignment(entity caller, float assignment)
 504 {
 505         float from_server = (!caller);
 506
 507         if ((assignment == VC_ASGNMNT_BOTH)
 508             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 509             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 510
 511         return false;
 512 }
 513
 514 string VoteCommand_extractcommand(string input, float startpos, float argc)
 515 {
 516         string output;
 517
 518         if ((argc - 1) < startpos) output = "";
 519         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 520
 521         return output;
 522 }
 523
 524 float VoteCommand_checknasty(string vote_command)
 525 {
 526         if ((strstrofs(vote_command, ";", 0) >= 0)
 527             || (strstrofs(vote_command, "\n", 0) >= 0)
 528             || (strstrofs(vote_command, "\r", 0) >= 0)
 529             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 530
 531         return true;
 532 }
 533
 534 float VoteCommand_checkinlist(string vote_command, string list)
 535 {
 536         string l = strcat(" ", list, " ");
 537
 538         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 539
 540         return false;
 541 }
 542
 543 string ValidateMap(string validated_map, entity caller)
 544 {
 545         validated_map = MapInfo_FixName(validated_map);
 546
 547         if (!validated_map)
 548         {
 549                 print_to(caller, "This map is not available on this server.");
 550                 return string_null;
 551         }
 552
 553         if (!autocvar_sv_vote_override_mostrecent && caller)
 554         {
 555                 if (Map_IsRecent(validated_map))
 556                 {
 557                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 558                         return string_null;
 559                 }
 560         }
 561
 562         if (!MapInfo_CheckMap(validated_map))
 563         {
 564                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 565                 return string_null;
 566         }
 567
 568         return validated_map;
 569 }
 570
 571 float VoteCommand_checkargs(float startpos, float argc)
 572 {
 573         float p, q, check, minargs;
 574         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 575         string cmdrestriction = "";  // No we don't.
 576         string charlist, arg;
 577         float checkmate;
 578
 579         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 580                 cmdrestriction = cvar_string(cvarname);
 581         else
 582                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.\n");
 583
 584         if (cmdrestriction == "") return true;
 585
 586         ++startpos;  // skip command name
 587
 588         // check minimum arg count
 589
 590         // 0 args: argc == startpos
 591         // 1 args: argc == startpos + 1
 592         // ...
 593
 594         minargs = stof(cmdrestriction);
 595         if (argc - startpos < minargs) return false;
 596
 597         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 598
 599         for ( ; ; )
 600         {
 601                 // we know that at any time, startpos <= argc - minargs
 602                 // so this means: argc-minargs >= startpos >= argc, thus
 603                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 604                 // have been seen already
 605
 606                 if (startpos >= argc) // all args checked? GOOD
 607                         break;
 608
 609                 if (p < 0)            // no more args? FAIL
 610                 {
 611                         // exception: exactly minargs left, this one included
 612                         if (argc - startpos == minargs) break;
 613
 614                         // otherwise fail
 615                         return false;
 616                 }
 617
 618                 // cut to next semicolon
 619                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 620                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 621                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 622
 623                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 624                 // charlist = strreplace("^^", ";", charlist);
 625
 626                 if (charlist != "")
 627                 {
 628                         // verify the arg only contains allowed chars
 629                         arg = argv(startpos);
 630                         checkmate = strlen(arg);
 631                         for (check = 0; check < checkmate; ++check)
 632                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 633                         // not allowed character
 634                         // all characters are allowed. FINE.
 635                 }
 636
 637                 ++startpos;
 638                 --minargs;
 639                 p = q;
 640         }
 641
 642         return true;
 643 }
 644
 645 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 646 {
 647         string first_command;
 648
 649         first_command = argv(startpos);
 650
 651         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 652             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 653             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 654         );*/
 655
 656         if (
 657             (autocvar_sv_vote_limit > 0)
 658             &&
 659             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 660            )   return false;
 661
 662         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 663
 664         if (!VoteCommand_checkargs(startpos, argc)) return false;
 665
 666         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 667         {
 668                 case "kick":
 669                 case "kickban":    // catch all kick/kickban commands
 670                 {
 671                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 672                         float accepted = VerifyClientEntity(victim, true, false);
 673
 674                         if (accepted > 0)
 675                         {
 676                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 677                                 string command_arguments;
 678
 679                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 680                                 else command_arguments = reason;
 681
 682                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 683                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 684                         }
 685                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 686
 687                         break;
 688                 }
 689
 690                 case "map":
 691                 case "chmap":
 692                 case "gotomap":  // re-direct all map selection commands to gotomap
 693                 {
 694                         vote_command = ValidateMap(argv(startpos + 1), caller);
 695                         if (!vote_command)   return false;
 696                         vote_parsed_command = strcat("gotomap ", vote_command);
 697                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 698
 699                         break;
 700                 }
 701
 702                 default:
 703                 {
 704                         vote_parsed_command = vote_command;
 705                         vote_parsed_display = strzone(strcat("^1", vote_command));
 706
 707                         break;
 708                 }
 709         }
 710
 711         return true;
 712 }
 713
 714
 715 // =======================
 716 //  Command Sub-Functions
 717 // =======================
 718
 719 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 720 {
 721         switch (request)
 722         {
 723                 case CMD_REQUEST_COMMAND:
 724                 {
 725                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 726                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 727                         {
 728                                 print_to(caller, "^1You have already voted.");
 729                         }
 730
 731                         else  // everything went okay, continue changing vote
 732                         {
 733                                 print_to(caller, "^1You abstained from your vote.");
 734                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 735                                 msg_entity = caller;
 736                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 737
 738                         return;
 739                 }
 740
 741                 default:
 742                 case CMD_REQUEST_USAGE:
 743                 {
 744                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 745                         print_to(caller, "  No arguments required.");
 746                         return;
 747                 }
 748         }
 749 }
 750
 751 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 752 {
 753         switch (request)
 754         {
 755                 case CMD_REQUEST_COMMAND:
 756                 {
 757                         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 758
 759                         float tmp_playercount = 0;
 760
 761                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 762
 763                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 764                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 765                         {
 766                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 767                         }
 768                         else if (vote_called)
 769                         {
 770                                 print_to(caller, "^1There is already a vote called.");
 771                         }
 772                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 773                         {
 774                                 print_to(caller, "^1Only players can call a vote.");
 775                         }
 776                         else if (caller && !IS_CLIENT(caller))
 777                         {
 778                                 print_to(caller, "^1Only connected clients can vote.");
 779                         }
 780                         else if (timeout_status)
 781                         {
 782                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 783                         }
 784                         else if (caller && (time < caller.vote_waittime))
 785                         {
 786                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 787                         }
 788                         else if (!VoteCommand_checknasty(vote_command))
 789                         {
 790                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 791                         }
 792                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 793                         {
 794                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 795                         }
 796
 797                         else  // everything went okay, continue with calling the vote
 798                         {
 799                                 vote_caller = caller;  // remember who called the vote
 800                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 801                                 vote_called = VOTE_NORMAL;
 802                                 vote_called_command = strzone(vote_parsed_command);
 803                                 vote_called_display = strzone(vote_parsed_display);
 804                                 vote_endtime = time + autocvar_sv_vote_timeout;
 805
 806                                 if (caller)
 807                                 {
 808                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 809                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 810                                         msg_entity = caller;
 811                                 }
 812
 813                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(++tmp_playercount));
 814                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 815
 816                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 817                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 818                                 Nagger_VoteChanged();
 819                                 VoteCount(true);  // needed if you are the only one
 820                         }
 821
 822                         return;
 823                 }
 824
 825                 default:
 826                 case CMD_REQUEST_USAGE:
 827                 {
 828                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 829                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 830                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 831                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 832                         return;
 833                 }
 834         }
 835 }
 836
 837 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 838 {
 839         switch (request)
 840         {
 841                 case CMD_REQUEST_COMMAND:
 842                 {
 843                         if (autocvar_sv_vote_master)
 844                         {
 845                                 switch (strtolower(argv(2)))
 846                                 {
 847                                         case "do":
 848                                         {
 849                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 850
 851                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 852                                                 else if (!VoteCommand_checknasty(vote_command))
 853                                                 {
 854                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 855                                                 }
 856                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 857                                                 {
 858                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 859                                                 }
 860
 861                                                 else  // everything went okay, proceed with command
 862                                                 {
 863                                                         localcmd(strcat(vote_parsed_command, "\n"));
 864                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 865                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 866                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 867
 868                                                 return;
 869                                         }
 870
 871                                         case "login":
 872                                         {
 873                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 874                                                 else if (caller.vote_master)
 875                                                 {
 876                                                         print_to(caller, "^1You are already logged in as vote master.");
 877                                                 }
 878                                                 else if (autocvar_sv_vote_master_password != argv(3))
 879                                                 {
 880                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 881                                                 }
 882
 883                                                 else  // everything went okay, proceed with giving this player master privilages
 884                                                 {
 885                                                         caller.vote_master = true;
 886                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 887                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 888                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 889
 890                                                 return;
 891                                         }
 892
 893                                         default:  // calling a vote for master
 894                                         {
 895                                                 bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 896
 897                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 898                                                 else if (vote_called)
 899                                                 {
 900                                                         print_to(caller, "^1There is already a vote called.");
 901                                                 }
 902                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 903                                                 {
 904                                                         print_to(caller, "^1Only players can call a vote.");
 905                                                 }
 906                                                 else if (timeout_status)
 907                                                 {
 908                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 909                                                 }
 910
 911                                                 else  // everything went okay, continue with creating vote
 912                                                 {
 913                                                         vote_caller = caller;
 914                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 915                                                         vote_called = VOTE_MASTER;
 916                                                         vote_called_command = strzone("XXX");
 917                                                         vote_called_display = strzone("^3master");
 918                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 919
 920                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 921                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 922
 923                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 924                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 925                                                         Nagger_VoteChanged();
 926                                                         VoteCount(true);  // needed if you are the only one
 927                                                 }
 928
 929                                                 return;
 930                                         }
 931                                 }
 932                         }
 933                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 934
 935                         return;
 936                 }
 937
 938                 default:
 939                 case CMD_REQUEST_USAGE:
 940                 {
 941                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 942                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 943                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 944                         return;
 945                 }
 946         }
 947 }
 948
 949 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 950 {
 951         switch (request)
 952         {
 953                 case CMD_REQUEST_COMMAND:
 954                 {
 955                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 956                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 957                         {
 958                                 print_to(caller, "^1You have already voted.");
 959                         }
 960                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 961                         {
 962                                 VoteStop(caller);
 963                         }
 964
 965                         else  // everything went okay, continue changing vote
 966                         {
 967                                 print_to(caller, "^1You rejected the vote.");
 968                                 caller.vote_selection = VOTE_SELECT_REJECT;
 969                                 msg_entity = caller;
 970                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 971
 972                         return;
 973                 }
 974
 975                 default:
 976                 case CMD_REQUEST_USAGE:
 977                 {
 978                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 979                         print_to(caller, "  No arguments required.");
 980                         return;
 981                 }
 982         }
 983 }
 984
 985 void VoteCommand_status(float request, entity caller)  // BOTH
 986 {
 987         switch (request)
 988         {
 989                 case CMD_REQUEST_COMMAND:
 990                 {
 991                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 992                         else print_to(caller, "^1No vote called.");
 993
 994                         return;
 995                 }
 996
 997                 default:
 998                 case CMD_REQUEST_USAGE:
 999                 {
1000                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1001                         print_to(caller, "  No arguments required.");
1002                         return;
1003                 }
1004         }
1005 }
1006
1007 void VoteCommand_stop(float request, entity caller)  // BOTH
1008 {
1009         switch (request)
1010         {
1011                 case CMD_REQUEST_COMMAND:
1012                 {
1013                         if (!vote_called)   print_to(caller, "^1No vote called.");
1014                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1015                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1016                         return;
1017                 }
1018
1019                 default:
1020                 case CMD_REQUEST_USAGE:
1021                 {
1022                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1023                         print_to(caller, "  No arguments required.");
1024                         return;
1025                 }
1026         }
1027 }
1028
1029 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1030 {
1031         switch (request)
1032         {
1033                 case CMD_REQUEST_COMMAND:
1034                 {
1035                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1036                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1037                         {
1038                                 print_to(caller, "^1You have already voted.");
1039                         }
1040
1041                         else  // everything went okay, continue changing vote
1042                         {
1043                                 print_to(caller, "^1You accepted the vote.");
1044                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1045                                 msg_entity = caller;
1046                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1047
1048                         return;
1049                 }
1050
1051                 default:
1052                 case CMD_REQUEST_USAGE:
1053                 {
1054                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1055                         print_to(caller, "  No arguments required.");
1056                         return;
1057                 }
1058         }
1059 }
1060
1061 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1062 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1063 void VoteCommand_(float request)
1064 {
1065     switch(request)
1066     {
1067         case CMD_REQUEST_COMMAND:
1068         {
1069
1070             return;
1071         }
1072
1073         default:
1074         case CMD_REQUEST_USAGE:
1075         {
1076             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1077             print_to(caller, "  No arguments required.");
1078             return;
1079         }
1080     }
1081 }
1082 */
1083
1084
1085 // ================================
1086 //  Macro system for vote commands
1087 // ================================
1088
1089 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1090 #define VOTE_COMMANDS(request, caller, arguments, command) \
1091         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1092         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1093         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1094         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1095         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1096         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1097         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1098         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1099         /* nothing */
1100
1101 void VoteCommand_macro_help(entity caller, float argc)
1102 {
1103         string command_origin = GetCommandPrefix(caller);
1104
1105         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1106         {
1107                 print_to(caller, "\nVoting commands:\n");
1108                 #define VOTE_COMMAND(name, function, description, assignment) \
1109                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1110
1111                 VOTE_COMMANDS(0, caller, 0, "");
1112 #undef VOTE_COMMAND
1113
1114                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1115                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1116                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1117         }
1118         else  // usage for individual command
1119         {
1120                 #define VOTE_COMMAND(name, function, description, assignment) \
1121                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1122
1123                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1124 #undef VOTE_COMMAND
1125         }
1126 }
1127
1128 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1129 {
1130         #define VOTE_COMMAND(name, function, description, assignment) \
1131                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1132
1133         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1134 #undef VOTE_COMMAND
1135
1136         return false;
1137 }
1138
1139
1140 // ======================================
1141 //  Main function handling vote commands
1142 // ======================================
1143
1144 void VoteCommand(float request, entity caller, float argc, string vote_command)
1145 {
1146         // Guide for working with argc arguments by example:
1147         // argc:   1    - 2      - 3     - 4
1148         // argv:   0    - 1      - 2     - 3
1149         // cmd     vote - master - login - password
1150
1151         switch (request)
1152         {
1153                 case CMD_REQUEST_COMMAND:
1154                 {
1155                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1156                 }
1157
1158                 default:
1159                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1160                 case CMD_REQUEST_USAGE:
1161                 {
1162                         VoteCommand_macro_help(caller, argc);
1163                         return;
1164                 }
1165         }
1166 }