qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/net_linked.qh>
   8 #include <common/notifications/all.qh>
   9 #include <common/playerstats.qh>
  10 #include <common/stats.qh>
  11 #include <common/util.qh>
  12 #include <common/weapons/_all.qh>
  13 #include <server/client.qh>
  14 #include <server/command/banning.qh>
  15 #include <server/command/common.qh>
  16 #include <server/command/vote.qh>
  17 #include <server/damage.qh>
  18 #include <server/gamelog.qh>
  19 #include <server/intermission.qh>
  20 #include <server/mutators/_mod.qh>
  21 #include <server/race.qh>
  22 #include <server/round_handler.qh>
  23 #include <server/scores.qh>
  24 #include <server/teamplay.qh>
  25 #include <server/world.qh>
  26
  27 // =============================================
  28 //  Server side voting code, reworked by Samual
  29 //  Last updated: December 27th, 2011
  30 // =============================================
  31
  32 //  Nagger for players to know status of voting
  33 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  34 {
  35         int nags, i, f, b;
  36         entity e;
  37         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  38
  39         // bits:
  40         //   1 = ready
  41         //   2 = player needs to ready up
  42         //   4 = vote
  43         //   8 = player needs to vote
  44         //  16 = warmup
  45         // sendflags:
  46         //  64 = vote counts
  47         // 128 = vote string
  48
  49         nags = 0;
  50         if (readycount)
  51         {
  52                 nags |= BIT(0);
  53                 if (to.ready == 0) nags |= BIT(1);
  54         }
  55         if (vote_called)
  56         {
  57                 nags |= BIT(2);
  58                 if (to.vote_selection == 0) nags |= BIT(3);
  59         }
  60         if (warmup_stage) nags |= BIT(4);
  61
  62         if (sendflags & BIT(6)) nags |= BIT(6);
  63
  64         if (sendflags & BIT(7)) nags |= BIT(7);
  65
  66         if (!(nags & 4))  // no vote called? send no string
  67                 nags &= ~(BIT(6) | BIT(7));
  68
  69         WriteByte(MSG_ENTITY, nags);
  70
  71         if (nags & BIT(6))
  72         {
  73                 WriteByte(MSG_ENTITY, vote_accept_count);
  74                 WriteByte(MSG_ENTITY, vote_reject_count);
  75                 WriteByte(MSG_ENTITY, vote_needed_overall);
  76                 WriteChar(MSG_ENTITY, to.vote_selection);
  77         }
  78
  79         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if (nags & 1)
  82         {
  83                 for (i = 1; i <= maxclients; i += 8)
  84                 {
  85                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  86                                 if (!IS_REAL_CLIENT(e) || e.ready)
  87                                         f |= b;
  88                         WriteByte(MSG_ENTITY, f);
  89                 }
  90         }
  91
  92         return true;
  93 }
  94
  95 void Nagger_Init()
  96 {
  97         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  98 }
  99
 100 void Nagger_VoteChanged()
 101 {
 102         if (nagger) nagger.SendFlags |= BIT(7);
 103 }
 104
 105 void Nagger_VoteCountChanged()
 106 {
 107         if (nagger) nagger.SendFlags |= BIT(6);
 108 }
 109
 110 void Nagger_ReadyCounted()
 111 {
 112         if (nagger) nagger.SendFlags |= BIT(0);
 113 }
 114
 115 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 116 string OriginalCallerName()
 117 {
 118         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 119         return vote_caller_name;
 120 }
 121
 122 // =======================
 123 //  Game logic for voting
 124 // =======================
 125
 126 void VoteReset()
 127 {
 128         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 129
 130         if (vote_called)
 131         {
 132                 strfree(vote_called_command);
 133                 strfree(vote_called_display);
 134                 strfree(vote_caller_name);
 135         }
 136
 137         vote_called = VOTE_NULL;
 138         vote_caller = NULL;
 139         vote_endtime = 0;
 140
 141         vote_parsed_command = string_null;
 142         vote_parsed_display = string_null;
 143
 144         Nagger_VoteChanged();
 145 }
 146
 147 void VoteStop(entity stopper)
 148 {
 149         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 150         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 151         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 152         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 153         VoteReset();
 154 }
 155
 156 void VoteAccept()
 157 {
 158         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 159
 160         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 161         else localcmd(strcat(vote_called_command, "\n"));
 162
 163         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 164
 165         VoteReset();
 166         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 167 }
 168
 169 void VoteReject()
 170 {
 171         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 172         VoteReset();
 173         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 174 }
 175
 176 void VoteTimeout()
 177 {
 178         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 179         VoteReset();
 180         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 181 }
 182
 183 void VoteSpam(float notvoters, float mincount, string result)
 184 {
 185         bprint(strcat(
 186                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 187                 strcat("^2:^1", ftos(vote_reject_count)),
 188                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 189                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 190                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 191
 192         if (autocvar_sv_eventlog)
 193         {
 194                 GameLogEcho(strcat(
 195                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 196                         strcat(":", ftos(vote_reject_count)),
 197                         strcat(":", ftos(vote_abstain_count)),
 198                         strcat(":", ftos(notvoters)),
 199                         strcat(":", ftos(mincount))));
 200         }
 201 }
 202
 203 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 204
 205 void VoteCount(float first_count)
 206 {
 207         // declarations
 208         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 209
 210         float vote_player_count = 0, notvoters = 0;
 211         float vote_real_player_count = 0, vote_real_accept_count = 0;
 212         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 213         float vote_needed_of_voted, final_needed_votes;
 214         float vote_factor_overall, vote_factor_of_voted;
 215
 216         Nagger_VoteCountChanged();
 217
 218         // add up all the votes from each connected client
 219         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 220                 ++vote_player_count;
 221                 if (IS_PLAYER(it))   ++vote_real_player_count;
 222                 switch (it.vote_selection)
 223                 {
 224                         case VOTE_SELECT_REJECT:
 225                         { ++vote_reject_count;
 226                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 227                         }
 228                         case VOTE_SELECT_ACCEPT:
 229                         { ++vote_accept_count;
 230                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 231                         }
 232                         case VOTE_SELECT_ABSTAIN:
 233                         { ++vote_abstain_count;
 234                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 235                         }
 236                         default: break;
 237                 }
 238         });
 239
 240         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 241         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 242         {
 243                 if (vote_caller)   vote_caller.vote_waittime = 0;
 244                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 245                 VoteReset();
 246                 return;
 247         }
 248
 249         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 250         if (!spectators_allowed && (vote_real_player_count > 0))
 251         {
 252                 vote_accept_count = vote_real_accept_count;
 253                 vote_reject_count = vote_real_reject_count;
 254                 vote_abstain_count = vote_real_abstain_count;
 255                 vote_player_count = vote_real_player_count;
 256         }
 257
 258         // people who have no opinion in any way :D
 259         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 260
 261         // determine the goal for the vote to be passed or rejected normally
 262         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 263         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 264
 265         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 266         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 267         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 268
 269         // are there any players at all on the server? it could be an admin vote
 270         if (vote_player_count == 0 && first_count)
 271         {
 272                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 273                 VoteAccept();
 274                 return;
 275         }
 276
 277         // since there ARE players, finally calculate the result of the vote
 278         if (vote_accept_count >= vote_needed_overall)
 279         {
 280                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 281                 VoteAccept();
 282                 return;
 283         }
 284
 285         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 286         {
 287                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 288                 VoteReject();
 289                 return;
 290         }
 291
 292         // there is not enough votes in either direction, now lets just calculate what the voters have said
 293         if (time > vote_endtime)
 294         {
 295                 final_needed_votes = vote_needed_overall;
 296
 297                 if (autocvar_sv_vote_majority_factor_of_voted)
 298                 {
 299                         if (vote_accept_count >= vote_needed_of_voted)
 300                         {
 301                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 302                                 VoteAccept();
 303                                 return;
 304                         }
 305
 306                         if (vote_accept_count + vote_reject_count > 0)
 307                         {
 308                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 309                                 VoteReject();
 310                                 return;
 311                         }
 312
 313                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 314                 }
 315
 316                 // it didn't pass or fail, so not enough votes to even make a decision.
 317                 VoteSpam(notvoters, final_needed_votes, "timeout");
 318                 VoteTimeout();
 319         }
 320 }
 321
 322 void VoteThink()
 323 {
 324         if (vote_endtime > 0)        // a vote was called
 325         {
 326                 if (time > vote_endtime) // time is up
 327                         VoteCount(false);
 328         }
 329 }
 330
 331
 332 // =======================
 333 //  Game logic for warmup
 334 // =======================
 335
 336 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 337 void reset_map(bool dorespawn)
 338 {
 339         if (time <= game_starttime)
 340         {
 341                 if (game_stopped)
 342                         return;
 343                 if (round_handler_IsActive())
 344                         round_handler_Reset(game_starttime);
 345         }
 346
 347         if (shuffleteams_on_reset_map)
 348         {
 349                 shuffleteams();
 350                 shuffleteams_on_reset_map = false;
 351         }
 352         MUTATOR_CALLHOOK(reset_map_global);
 353
 354         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 355         {
 356                 if(IS_CLIENT(it))
 357                         continue;
 358                 if (it.reset)
 359                 {
 360                         it.reset(it);
 361                         continue;
 362                 }
 363                 if (it.team_saved) it.team = it.team_saved;
 364                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 365         });
 366
 367         // Waypoints and assault start come LAST
 368         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 369                 if (it.reset2) it.reset2(it);
 370         });
 371
 372         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it, false); });
 373
 374         // Moving the player reset code here since the player-reset depends
 375         // on spawnpoint entities which have to be reset first --blub
 376         if (dorespawn)
 377         {
 378                 if (!MUTATOR_CALLHOOK(reset_map_players))
 379                 {
 380                         if (restart_mapalreadyrestarted || (time < game_starttime))
 381                         {
 382                                 FOREACH_CLIENT(IS_PLAYER(it),
 383                                 {
 384                                         /*
 385                                         only reset players if a restart countdown is active
 386                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 387                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 388                                         sv_ready_restart_after_countdown is not used and countdown is still running
 389                                         */
 390                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 391                                         // PlayerScore_Clear(it);
 392                                         CS(it).killcount = 0;
 393                                         // stop the player from moving so that he stands still once he gets respawned
 394                                         it.velocity = '0 0 0';
 395                                         it.avelocity = '0 0 0';
 396                                         CS(it).movement = '0 0 0';
 397                                         PutClientInServer(it);
 398                                 });
 399                         }
 400                 }
 401         }
 402 }
 403
 404 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 405 void ReadyRestart_think(entity this)
 406 {
 407         restart_mapalreadyrestarted = true;
 408         reset_map(true);
 409         Score_ClearAll();
 410         delete(this);
 411 }
 412
 413 // Forces a restart of the game without actually reloading the map // this is a mess...
 414 void ReadyRestart_force()
 415 {
 416         if (time <= game_starttime && game_stopped)
 417                 return;
 418
 419         bprint("^1Server is restarting...\n");
 420
 421         VoteReset();
 422
 423         // clear overtime, we have to decrease timelimit to its original value again.
 424         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 425                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 426         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 427
 428         readyrestart_happened = true;
 429         game_starttime = time + RESTART_COUNTDOWN;
 430
 431         // clear player attributes
 432         FOREACH_CLIENT(IS_PLAYER(it), {
 433                 it.alivetime = 0;
 434                 CS(it).killcount = 0;
 435                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 436                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 437         });
 438
 439         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 440
 441         // disable the warmup global for the server
 442         if(warmup_stage)
 443                 localcmd("\nsv_hook_warmupend\n");
 444         warmup_stage = 0;                // once the game is restarted the game is in match stage
 445
 446         // reset the .ready status of all players (also spectators)
 447         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 448         readycount = 0;
 449         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 450
 451         // lock teams with lockonrestart
 452         if (autocvar_teamplay_lockonrestart && teamplay)
 453         {
 454                 lockteams = true;
 455                 bprint("^1The teams are now locked.\n");
 456         }
 457
 458         // initiate the restart-countdown-announcer entity
 459         if (sv_ready_restart_after_countdown)
 460         {
 461                 entity restart_timer = new_pure(restart_timer);
 462                 setthink(restart_timer, ReadyRestart_think);
 463                 restart_timer.nextthink = game_starttime;
 464         }
 465
 466         // after a restart every players number of allowed timeouts gets reset, too
 467         if (autocvar_sv_timeout)
 468         {
 469                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 470         }
 471
 472         if (!sv_ready_restart_after_countdown) reset_map(true);
 473         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 474 }
 475
 476 void ReadyRestart()
 477 {
 478         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 479         else localcmd("\nsv_hook_readyrestart\n");
 480
 481         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 482         // Otherwise scores could be manipulated during the countdown.
 483         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 484         ReadyRestart_force();
 485 }
 486
 487 // Count the players who are ready and determine whether or not to restart the match
 488 void ReadyCount()
 489 {
 490         float ready_needed_factor, ready_needed_count;
 491         float t_ready = 0, t_players = 0;
 492
 493         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 494                 ++t_players;
 495                 if (it.ready) ++t_ready;
 496         });
 497
 498         readycount = t_ready;
 499
 500         Nagger_ReadyCounted();
 501
 502         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 503         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 504
 505         if (readycount >= ready_needed_count) ReadyRestart();
 506 }
 507
 508
 509 // ======================================
 510 //  Supporting functions for VoteCommand
 511 // ======================================
 512
 513 float Votecommand_check_assignment(entity caller, float assignment)
 514 {
 515         float from_server = (!caller);
 516
 517         if ((assignment == VC_ASGNMNT_BOTH)
 518             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 519             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 520
 521         return false;
 522 }
 523
 524 string VoteCommand_extractcommand(string input, float startpos, int argc)
 525 {
 526         string output;
 527
 528         if ((argc - 1) < startpos) output = "";
 529         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 530
 531         return output;
 532 }
 533
 534 float VoteCommand_checknasty(string vote_command)
 535 {
 536         if ((strstrofs(vote_command, ";", 0) >= 0)
 537             || (strstrofs(vote_command, "\n", 0) >= 0)
 538             || (strstrofs(vote_command, "\r", 0) >= 0)
 539             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 540
 541         return true;
 542 }
 543
 544 // NOTE: requires input to be surrounded by spaces
 545 string VoteCommand_checkreplacements(string input)
 546 {
 547         string output = input;
 548         // allow gotomap replacements
 549         output = strreplace(" map ", " gotomap ", output);
 550         output = strreplace(" chmap ", " gotomap ", output);
 551         return output;
 552 }
 553
 554 float VoteCommand_checkinlist(string vote_command, string list)
 555 {
 556         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 557
 558         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 559
 560         return false;
 561 }
 562
 563 string ValidateMap(string validated_map, entity caller)
 564 {
 565         validated_map = MapInfo_FixName(validated_map);
 566
 567         if (!validated_map)
 568         {
 569                 print_to(caller, "This map is not available on this server.");
 570                 return string_null;
 571         }
 572
 573         if (!autocvar_sv_vote_override_mostrecent && caller)
 574         {
 575                 if (Map_IsRecent(validated_map))
 576                 {
 577                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 578                         return string_null;
 579                 }
 580         }
 581
 582         if (!MapInfo_CheckMap(validated_map))
 583         {
 584                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 585                 return string_null;
 586         }
 587
 588         return validated_map;
 589 }
 590
 591 float VoteCommand_checkargs(float startpos, int argc)
 592 {
 593         float p, q, check, minargs;
 594         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 595         string cmdrestriction = "";  // No we don't.
 596         string charlist, arg;
 597         float checkmate;
 598
 599         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 600                 cmdrestriction = cvar_string(cvarname);
 601         else
 602                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 603
 604         if (cmdrestriction == "") return true;
 605
 606         ++startpos;  // skip command name
 607
 608         // check minimum arg count
 609
 610         // 0 args: argc == startpos
 611         // 1 args: argc == startpos + 1
 612         // ...
 613
 614         minargs = stof(cmdrestriction);
 615         if (argc - startpos < minargs) return false;
 616
 617         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 618
 619         for ( ; ; )
 620         {
 621                 // we know that at any time, startpos <= argc - minargs
 622                 // so this means: argc-minargs >= startpos >= argc, thus
 623                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 624                 // have been seen already
 625
 626                 if (startpos >= argc) // all args checked? GOOD
 627                         break;
 628
 629                 if (p < 0)            // no more args? FAIL
 630                 {
 631                         // exception: exactly minargs left, this one included
 632                         if (argc - startpos == minargs) break;
 633
 634                         // otherwise fail
 635                         return false;
 636                 }
 637
 638                 // cut to next semicolon
 639                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 640                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 641                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 642
 643                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 644                 // charlist = strreplace("^^", ";", charlist);
 645
 646                 if (charlist != "")
 647                 {
 648                         // verify the arg only contains allowed chars
 649                         arg = argv(startpos);
 650                         checkmate = strlen(arg);
 651                         for (check = 0; check < checkmate; ++check)
 652                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 653                         // not allowed character
 654                         // all characters are allowed. FINE.
 655                 }
 656
 657                 ++startpos;
 658                 --minargs;
 659                 p = q;
 660         }
 661
 662         return true;
 663 }
 664
 665 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 666 {
 667         string first_command = argv(startpos);
 668         int missing_chars = argv_start_index(startpos);
 669
 670         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 671                 return 0;
 672
 673         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 674
 675         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 676
 677         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 678         {
 679                 case MUT_VOTEPARSE_CONTINUE: { break; }
 680                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 681                 case MUT_VOTEPARSE_INVALID: { return -1; }
 682                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 683         }
 684
 685         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 686         {
 687                 case "kick":
 688                 case "kickban":    // catch all kick/kickban commands
 689                 {
 690                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 691                         float accepted = VerifyClientEntity(victim, true, false);
 692
 693                         if (accepted > 0)
 694                         {
 695                                 string reason = "No reason provided";
 696                                 if(argc > next_token)
 697                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 698
 699                                 string command_arguments = reason;
 700                                 if (first_command == "kickban")
 701                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 702
 703                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 704                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 705                         }
 706                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 707
 708                         break;
 709                 }
 710
 711                 case "map":
 712                 case "chmap":
 713                 case "gotomap":  // re-direct all map selection commands to gotomap
 714                 {
 715                         vote_command = ValidateMap(argv(startpos + 1), caller);
 716                         if (!vote_command)  return -1;
 717                         vote_parsed_command = strcat("gotomap ", vote_command);
 718                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 719
 720                         break;
 721                 }
 722
 723                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 724                 // maybe fallback instead of aborting if map name is invalid?
 725                 case "nextmap":
 726                 {
 727                         vote_command = ValidateMap(argv(startpos + 1), caller);
 728                         if (!vote_command)  return -1;
 729                         vote_parsed_command = strcat("nextmap ", vote_command);
 730                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 731
 732                         break;
 733                 }
 734
 735                 case "timelimit": // include restrictions on the maximum votable time limit
 736                 {
 737                         float timelimit_vote = stof(argv(startpos + 1));
 738                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 739                         {
 740                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 741                                 return -1;
 742                         }
 743                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 744                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 745                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 746
 747                         break;
 748                 }
 749
 750                 case "restart":
 751                 {
 752                         // add a delay so that vote result can be seen and announcer can be heard
 753                         // if the vote is accepted
 754                         vote_parsed_command = strcat("defer 1 ", vote_command);
 755                         vote_parsed_display = strzone(strcat("^1", vote_command));
 756
 757                         break;
 758                 }
 759
 760                 default:
 761                 {
 762                         vote_parsed_command = vote_command;
 763                         vote_parsed_display = strzone(strcat("^1", vote_command));
 764
 765                         break;
 766                 }
 767         }
 768
 769         return 1;
 770 }
 771
 772
 773 // =======================
 774 //  Command Sub-Functions
 775 // =======================
 776
 777 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 778 {
 779         switch (request)
 780         {
 781                 case CMD_REQUEST_COMMAND:
 782                 {
 783                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 784                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 785                         {
 786                                 print_to(caller, "^1You have already voted.");
 787                         }
 788
 789                         else  // everything went okay, continue changing vote
 790                         {
 791                                 print_to(caller, "^1You abstained from your vote.");
 792                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 793                                 msg_entity = caller;
 794                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 795
 796                         return;
 797                 }
 798
 799                 default:
 800                 case CMD_REQUEST_USAGE:
 801                 {
 802                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 803                         print_to(caller, "  No arguments required.");
 804                         return;
 805                 }
 806         }
 807 }
 808
 809 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 810 {
 811         switch (request)
 812         {
 813                 case CMD_REQUEST_COMMAND:
 814                 {
 815                         float tmp_playercount = 0;
 816                         int parse_error;
 817
 818                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 819
 820                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 821                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 822                         {
 823                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 824                         }
 825                         else if (vote_called)
 826                         {
 827                                 print_to(caller, "^1There is already a vote called.");
 828                         }
 829                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 830                         {
 831                                 print_to(caller, "^1Only players can call a vote.");
 832                         }
 833                         else if (caller && !IS_CLIENT(caller))
 834                         {
 835                                 print_to(caller, "^1Only connected clients can vote.");
 836                         }
 837                         else if (timeout_status && vote_command != "timein")
 838                         {
 839                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 840                         }
 841                         else if (caller && (time < caller.vote_waittime))
 842                         {
 843                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 844                         }
 845                         else if (!VoteCommand_checknasty(vote_command))
 846                         {
 847                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 848                         }
 849                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 850                         {
 851                                 if(parse_error == 0)
 852                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 853                         }
 854                         else  // everything went okay, continue with calling the vote
 855                         {
 856                                 vote_caller = caller;  // remember who called the vote
 857                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 858                                 vote_called = VOTE_NORMAL;
 859                                 vote_called_command = strzone(vote_parsed_command);
 860                                 vote_called_display = strzone(vote_parsed_display);
 861                                 vote_endtime = time + autocvar_sv_vote_timeout;
 862
 863                                 if (caller)
 864                                 {
 865                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 866                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 867                                         msg_entity = caller;
 868                                 }
 869
 870                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 871
 872                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 873                                 if (autocvar_sv_eventlog)
 874                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 875                                 Nagger_VoteChanged();
 876                                 VoteCount(true);  // needed if you are the only one
 877
 878                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 879                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 880                         }
 881
 882                         return;
 883                 }
 884
 885                 default:
 886                 case CMD_REQUEST_USAGE:
 887                 {
 888                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 889                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 890                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 891                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 892                         return;
 893                 }
 894         }
 895 }
 896
 897 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 898 {
 899         switch (request)
 900         {
 901                 case CMD_REQUEST_COMMAND:
 902                 {
 903                         if (autocvar_sv_vote_master)
 904                         {
 905                                 switch (strtolower(argv(2)))
 906                                 {
 907                                         case "do":
 908                                         {
 909                                                 int parse_error;
 910                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 911
 912                                                 if (!caller.vote_master)
 913                                                         print_to(caller, "^1You do not have vote master privileges.");
 914                                                 else if (!VoteCommand_checknasty(vote_command))
 915                                                 {
 916                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 917                                                 }
 918                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 919                                                 {
 920                                                         if(parse_error == 0)
 921                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 922                                                 }
 923                                                 else  // everything went okay, proceed with command
 924                                                 {
 925                                                         localcmd(strcat(vote_parsed_command, "\n"));
 926                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 927                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 928                                                         if (autocvar_sv_eventlog)
 929                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 930                                                 }
 931
 932                                                 return;
 933                                         }
 934
 935                                         case "login":
 936                                         {
 937                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 938                                                 else if (caller.vote_master)
 939                                                 {
 940                                                         print_to(caller, "^1You are already logged in as vote master.");
 941                                                 }
 942                                                 else if (autocvar_sv_vote_master_password != argv(3))
 943                                                 {
 944                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 945                                                 }
 946                                                 else  // everything went okay, proceed with giving this player master privilages
 947                                                 {
 948                                                         caller.vote_master = true;
 949                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 950                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 951                                                         if (autocvar_sv_eventlog)
 952                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 953                                                 }
 954
 955                                                 return;
 956                                         }
 957
 958                                         default:  // calling a vote for master
 959                                         {
 960                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 961                                                 else if (vote_called)
 962                                                 {
 963                                                         print_to(caller, "^1There is already a vote called.");
 964                                                 }
 965                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 966                                                 {
 967                                                         print_to(caller, "^1Only players can call a vote.");
 968                                                 }
 969                                                 else if (timeout_status)
 970                                                 {
 971                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 972                                                 }
 973                                                 else  // everything went okay, continue with creating vote
 974                                                 {
 975                                                         vote_caller = caller;
 976                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 977                                                         vote_called = VOTE_MASTER;
 978                                                         vote_called_command = strzone("XXX");
 979                                                         vote_called_display = strzone("^3master");
 980                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 981
 982                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 983                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 984
 985                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 986                                                         if (autocvar_sv_eventlog)
 987                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 988                                                         Nagger_VoteChanged();
 989                                                         VoteCount(true);  // needed if you are the only one
 990                                                 }
 991
 992                                                 return;
 993                                         }
 994                                 }
 995                         }
 996                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 997
 998                         return;
 999                 }
1000
1001                 default:
1002                 case CMD_REQUEST_USAGE:
1003                 {
1004                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
1005                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
1006                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
1007                         return;
1008                 }
1009         }
1010 }
1011
1012 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1013 {
1014         switch (request)
1015         {
1016                 case CMD_REQUEST_COMMAND:
1017                 {
1018                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1019                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1020                         {
1021                                 print_to(caller, "^1You have already voted.");
1022                         }
1023                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1024                         {
1025                                 VoteStop(caller);
1026                         }
1027
1028                         else  // everything went okay, continue changing vote
1029                         {
1030                                 print_to(caller, "^1You rejected the vote.");
1031                                 caller.vote_selection = VOTE_SELECT_REJECT;
1032                                 msg_entity = caller;
1033                                 if (!autocvar_sv_vote_singlecount)
1034                                         VoteCount(false);
1035                         }
1036
1037                         return;
1038                 }
1039
1040                 default:
1041                 case CMD_REQUEST_USAGE:
1042                 {
1043                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1044                         print_to(caller, "  No arguments required.");
1045                         return;
1046                 }
1047         }
1048 }
1049
1050 void VoteCommand_status(int request, entity caller)  // BOTH
1051 {
1052         switch (request)
1053         {
1054                 case CMD_REQUEST_COMMAND:
1055                 {
1056                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1057                         else print_to(caller, "^1No vote called.");
1058
1059                         return;
1060                 }
1061
1062                 default:
1063                 case CMD_REQUEST_USAGE:
1064                 {
1065                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1066                         print_to(caller, "  No arguments required.");
1067                         return;
1068                 }
1069         }
1070 }
1071
1072 void VoteCommand_stop(int request, entity caller)  // BOTH
1073 {
1074         switch (request)
1075         {
1076                 case CMD_REQUEST_COMMAND:
1077                 {
1078                         if (!vote_called)   print_to(caller, "^1No vote called.");
1079                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1080                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1081                         return;
1082                 }
1083
1084                 default:
1085                 case CMD_REQUEST_USAGE:
1086                 {
1087                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1088                         print_to(caller, "  No arguments required.");
1089                         return;
1090                 }
1091         }
1092 }
1093
1094 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1095 {
1096         switch (request)
1097         {
1098                 case CMD_REQUEST_COMMAND:
1099                 {
1100                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1101                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1102                         {
1103                                 print_to(caller, "^1You have already voted.");
1104                         }
1105                         else  // everything went okay, continue changing vote
1106                         {
1107                                 print_to(caller, "^1You accepted the vote.");
1108                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1109                                 msg_entity = caller;
1110                                 if (!autocvar_sv_vote_singlecount)
1111                                         VoteCount(false);
1112                         }
1113
1114                         return;
1115                 }
1116
1117                 default:
1118                 case CMD_REQUEST_USAGE:
1119                 {
1120                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1121                         print_to(caller, "  No arguments required.");
1122                         return;
1123                 }
1124         }
1125 }
1126
1127 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1128 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1129 void VoteCommand_(int request)
1130 {
1131     switch(request)
1132     {
1133         case CMD_REQUEST_COMMAND:
1134         {
1135
1136             return;
1137         }
1138
1139         default:
1140         case CMD_REQUEST_USAGE:
1141         {
1142             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1143             print_to(caller, "  No arguments required.");
1144             return;
1145         }
1146     }
1147 }
1148 */
1149
1150
1151 // ================================
1152 //  Macro system for vote commands
1153 // ================================
1154
1155 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1156 #define VOTE_COMMANDS(request, caller, arguments, command) \
1157         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1158         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1159         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1160         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1161         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1162         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1163         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1164         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1165         /* nothing */
1166
1167 void VoteCommand_macro_help(entity caller, int argc)
1168 {
1169         string command_origin = GetCommandPrefix(caller);
1170
1171         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1172         {
1173                 print_to(caller, "\nVoting commands:\n");
1174                 #define VOTE_COMMAND(name, function, description, assignment) \
1175                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1176
1177                 VOTE_COMMANDS(0, caller, 0, "");
1178 #undef VOTE_COMMAND
1179
1180                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1181                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1182                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1183         }
1184         else  // usage for individual command
1185         {
1186                 #define VOTE_COMMAND(name, function, description, assignment) \
1187                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1188
1189                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1190 #undef VOTE_COMMAND
1191
1192                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1193                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1194                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1195                 else
1196                         print_to(caller, "No documentation exists for this vote");
1197         }
1198 }
1199
1200 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1201 {
1202         #define VOTE_COMMAND(name, function, description, assignment) \
1203                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1204
1205         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1206 #undef VOTE_COMMAND
1207
1208         return false;
1209 }
1210
1211
1212 // ======================================
1213 //  Main function handling vote commands
1214 // ======================================
1215
1216 void VoteCommand(int request, entity caller, int argc, string vote_command)
1217 {
1218         // Guide for working with argc arguments by example:
1219         // argc:   1    - 2      - 3     - 4
1220         // argv:   0    - 1      - 2     - 3
1221         // cmd     vote - master - login - password
1222
1223         switch (request)
1224         {
1225                 case CMD_REQUEST_COMMAND:
1226                 {
1227                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1228                 }
1229
1230                 default:
1231                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1232                 case CMD_REQUEST_USAGE:
1233                 {
1234                         VoteCommand_macro_help(caller, argc);
1235                         return;
1236                 }
1237         }
1238 }