qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3
   4 #include "common.qh"
   5
   6 #include "../g_damage.qh"
   7 #include "../g_world.qh"
   8 #include "../race.qh"
   9 #include "../round_handler.qh"
  10 #include "../scores.qh"
  11
  12 #include "../mutators/all.qh"
  13
  14 #include "../../common/constants.qh"
  15 #include "../../common/mapinfo.qh"
  16 #include "../../common/notifications.qh"
  17 #include "../../common/playerstats.qh"
  18 #include "../../common/util.qh"
  19
  20 // =============================================
  21 //  Server side voting code, reworked by Samual
  22 //  Last updated: December 27th, 2011
  23 // =============================================
  24
  25 //  Nagger for players to know status of voting
  26 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  27 {
  28         int nags, i, f, b;
  29         entity e;
  30         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  31
  32         // bits:
  33         //   1 = ready
  34         //   2 = player needs to ready up
  35         //   4 = vote
  36         //   8 = player needs to vote
  37         //  16 = warmup
  38         // sendflags:
  39         //  64 = vote counts
  40         // 128 = vote string
  41
  42         nags = 0;
  43         if (readycount)
  44         {
  45                 nags |= BIT(0);
  46                 if (to.ready == 0) nags |= BIT(1);
  47         }
  48         if (vote_called)
  49         {
  50                 nags |= BIT(2);
  51                 if (to.vote_selection == 0) nags |= BIT(3);
  52         }
  53         if (warmup_stage) nags |= BIT(4);
  54
  55         if (sendflags & BIT(6)) nags |= BIT(6);
  56
  57         if (sendflags & BIT(7)) nags |= BIT(7);
  58
  59         if (!(nags & 4))  // no vote called? send no string
  60                 nags &= ~(BIT(6) | BIT(7));
  61
  62         WriteByte(MSG_ENTITY, nags);
  63
  64         if (nags & BIT(6))
  65         {
  66                 WriteByte(MSG_ENTITY, vote_accept_count);
  67                 WriteByte(MSG_ENTITY, vote_reject_count);
  68                 WriteByte(MSG_ENTITY, vote_needed_overall);
  69                 WriteChar(MSG_ENTITY, to.vote_selection);
  70         }
  71
  72         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  73
  74         if (nags & 1)
  75         {
  76                 for (i = 1; i <= maxclients; i += 8)
  77                 {
  78                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  79                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  80                         WriteByte(MSG_ENTITY, f);
  81                 }
  82         }
  83
  84         return true;
  85 }
  86
  87 void Nagger_Init()
  88 {
  89         Net_LinkEntity(nagger = new(nagger), false, 0, Nagger_SendEntity);
  90         make_pure(nagger);
  91 }
  92
  93 void Nagger_VoteChanged()
  94 {
  95         if (nagger) nagger.SendFlags |= BIT(7);
  96 }
  97
  98 void Nagger_VoteCountChanged()
  99 {
 100         if (nagger) nagger.SendFlags |= BIT(6);
 101 }
 102
 103 void Nagger_ReadyCounted()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(0);
 106 }
 107
 108 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 109 string OriginalCallerName()
 110 {
 111         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 112         return vote_caller_name;
 113 }
 114
 115 // =======================
 116 //  Game logic for voting
 117 // =======================
 118
 119 void VoteReset()
 120 {
 121         entity tmp_player;
 122
 123         FOR_EACH_CLIENT(tmp_player)
 124         {
 125                 tmp_player.vote_selection = 0;
 126         }
 127
 128         if (vote_called)
 129         {
 130                 strunzone(vote_called_command);
 131                 strunzone(vote_called_display);
 132                 strunzone(vote_caller_name);
 133         }
 134
 135         vote_called = VOTE_NULL;
 136         vote_caller = world;
 137         vote_caller_name = string_null;
 138         vote_endtime = 0;
 139
 140         vote_called_command = string_null;
 141         vote_called_display = string_null;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 void VoteCount(float first_count)
 206 {
 207         // declarations
 208         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 209
 210         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 211             || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 212             || (autocvar_sv_vote_nospectators == 0));
 213
 214         float vote_player_count = 0, notvoters = 0;
 215         float vote_real_player_count = 0, vote_real_accept_count = 0;
 216         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 217         float vote_needed_of_voted, final_needed_votes;
 218         float vote_factor_overall, vote_factor_of_voted;
 219
 220         entity tmp_player;
 221
 222         Nagger_VoteCountChanged();
 223
 224         // add up all the votes from each connected client
 225         FOR_EACH_REALCLIENT(tmp_player)
 226         {
 227                 ++vote_player_count;
 228                 if (IS_PLAYER(tmp_player))   ++vote_real_player_count;
 229                 switch (tmp_player.vote_selection)
 230                 {
 231                         case VOTE_SELECT_REJECT:
 232                         { ++vote_reject_count;
 233                           { if (IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break;
 234                         }
 235                         case VOTE_SELECT_ACCEPT:
 236                         { ++vote_accept_count;
 237                           { if (IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break;
 238                         }
 239                         case VOTE_SELECT_ABSTAIN:
 240                         { ++vote_abstain_count;
 241                           { if (IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break;
 242                         }
 243                         default: break;
 244                 }
 245         }
 246
 247         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 248         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 249         {
 250                 if (vote_caller)   vote_caller.vote_waittime = 0;
 251                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 252                 VoteReset();
 253                 return;
 254         }
 255
 256         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 257         if (!spectators_allowed && (vote_real_player_count > 0))
 258         {
 259                 vote_accept_count = vote_real_accept_count;
 260                 vote_reject_count = vote_real_reject_count;
 261                 vote_abstain_count = vote_real_abstain_count;
 262                 vote_player_count = vote_real_player_count;
 263         }
 264
 265         // people who have no opinion in any way :D
 266         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 267
 268         // determine the goal for the vote to be passed or rejected normally
 269         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 270         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 271
 272         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 273         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 274         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 275
 276         // are there any players at all on the server? it could be an admin vote
 277         if (vote_player_count == 0 && first_count)
 278         {
 279                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 280                 VoteAccept();
 281                 return;
 282         }
 283
 284         // since there ARE players, finally calculate the result of the vote
 285         if (vote_accept_count >= vote_needed_overall)
 286         {
 287                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 288                 VoteAccept();
 289                 return;
 290         }
 291
 292         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 293         {
 294                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 295                 VoteReject();
 296                 return;
 297         }
 298
 299         // there is not enough votes in either direction, now lets just calculate what the voters have said
 300         if (time > vote_endtime)
 301         {
 302                 final_needed_votes = vote_needed_overall;
 303
 304                 if (autocvar_sv_vote_majority_factor_of_voted)
 305                 {
 306                         if (vote_accept_count >= vote_needed_of_voted)
 307                         {
 308                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 309                                 VoteAccept();
 310                                 return;
 311                         }
 312
 313                         if (vote_accept_count + vote_reject_count > 0)
 314                         {
 315                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 316                                 VoteReject();
 317                                 return;
 318                         }
 319
 320                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 321                 }
 322
 323                 // it didn't pass or fail, so not enough votes to even make a decision.
 324                 VoteSpam(notvoters, final_needed_votes, "timeout");
 325                 VoteTimeout();
 326         }
 327 }
 328
 329 void VoteThink()
 330 {
 331         if (vote_endtime > 0)        // a vote was called
 332         {
 333                 if (time > vote_endtime) // time is up
 334                         VoteCount(false);
 335         }
 336 }
 337
 338
 339 // =======================
 340 //  Game logic for warmup
 341 // =======================
 342
 343 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 344 void reset_map(bool dorespawn)
 345 {
 346         SELFPARAM();
 347
 348         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
 349
 350         MUTATOR_CALLHOOK(reset_map_global);
 351
 352         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), LAMBDA(
 353                 if (it.reset)
 354                 {
 355                         WITH(entity, self, it, it.reset(it));
 356                         continue;
 357                 }
 358                 if (it.team_saved) it.team = it.team_saved;
 359                 if (it.flags & FL_PROJECTILE) remove(it);  // remove any projectiles left
 360         ));
 361
 362         // Waypoints and assault start come LAST
 363         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), LAMBDA(
 364                 if (it.reset2) WITH(entity, self, it, it.reset2());
 365         ));
 366
 367         entity e;
 368         FOR_EACH_PLAYER(e)
 369         if (e.frozen) WITH(entity, self, e, Unfreeze(e));
 370
 371         // Moving the player reset code here since the player-reset depends
 372         // on spawnpoint entities which have to be reset first --blub
 373         if (dorespawn)
 374         {
 375                 if (!MUTATOR_CALLHOOK(reset_map_players))
 376                 {
 377                         FOR_EACH_CLIENT(e)  // reset all players
 378                         {
 379                                 setself(e);
 380                                 /*
 381                                 only reset players if a restart countdown is active
 382                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 383                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 384                                 sv_ready_restart_after_countdown is not used and countdown is still running
 385                                 */
 386                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 387                                 {
 388                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 389                                         if (IS_PLAYER(self))
 390                                         {
 391                                                 // PlayerScore_Clear(self);
 392                                                 self.killcount = 0;
 393                                                 // stop the player from moving so that he stands still once he gets respawned
 394                                                 self.velocity = '0 0 0';
 395                                                 self.avelocity = '0 0 0';
 396                                                 self.movement = '0 0 0';
 397                                                 PutClientInServer();
 398                                         }
 399                                 }
 400                         }
 401
 402                         setself(this);
 403                 }
 404         }
 405 }
 406
 407 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 408 void ReadyRestart_think()
 409 {
 410         SELFPARAM();
 411         restart_mapalreadyrestarted = true;
 412         reset_map(true);
 413         Score_ClearAll();
 414         remove(this);
 415 }
 416
 417 // Forces a restart of the game without actually reloading the map // this is a mess...
 418 void ReadyRestart_force()
 419 {
 420         bprint("^1Server is restarting...\n");
 421
 422         VoteReset();
 423
 424         // clear overtime, we have to decrease timelimit to its original value again.
 425         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 426                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 427         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 428
 429         readyrestart_happened = true;
 430         game_starttime = time + RESTART_COUNTDOWN;
 431
 432         entity tmp_player;
 433
 434         // clear player attributes
 435         FOR_EACH_CLIENT(tmp_player)
 436         {
 437                 tmp_player.alivetime = 0;
 438                 tmp_player.killcount = 0;
 439                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 440         }
 441
 442         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 443
 444         // disable the warmup global for the server
 445         warmup_stage = 0;                // once the game is restarted the game is in match stage
 446
 447         // reset the .ready status of all players (also spectators)
 448         FOR_EACH_REALCLIENT(tmp_player)
 449         {
 450                 tmp_player.ready = false;
 451         }
 452         readycount = 0;
 453         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 454
 455         // lock teams with lockonrestart
 456         if (autocvar_teamplay_lockonrestart && teamplay)
 457         {
 458                 lockteams = true;
 459                 bprint("^1The teams are now locked.\n");
 460         }
 461
 462         // initiate the restart-countdown-announcer entity
 463         if (autocvar_sv_ready_restart_after_countdown)
 464         {
 465                 entity restart_timer = new(restart_timer);
 466                 make_pure(restart_timer);
 467                 restart_timer.think = ReadyRestart_think;
 468                 restart_timer.nextthink = game_starttime;
 469         }
 470
 471         // after a restart every players number of allowed timeouts gets reset, too
 472         if (autocvar_sv_timeout)
 473         {
 474                 FOR_EACH_REALPLAYER(tmp_player)
 475                 {
 476                         tmp_player.allowed_timeouts = autocvar_sv_timeout_number;
 477                 }
 478         }
 479     // reset map immediately if this cvar is not set
 480     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 481         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 482 }
 483
 484 void ReadyRestart()
 485 {
 486         // no assault support yet...
 487         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 488         else localcmd("\nsv_hook_gamerestart\n");
 489
 490         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 491         // Otherwise scores could be manipulated during the countdown.
 492         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 493         ReadyRestart_force();
 494 }
 495
 496 // Count the players who are ready and determine whether or not to restart the match
 497 void ReadyCount()
 498 {
 499         entity tmp_player;
 500         float ready_needed_factor, ready_needed_count;
 501         float t_ready = 0, t_players = 0;
 502
 503         FOR_EACH_REALCLIENT(tmp_player)
 504         {
 505                 if (IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 506                 {
 507                         ++t_players;
 508                         if (tmp_player.ready)   ++t_ready; }
 509         }
 510
 511         readycount = t_ready;
 512
 513         Nagger_ReadyCounted();
 514
 515         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 516         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 517
 518         if (readycount >= ready_needed_count) ReadyRestart();
 519 }
 520
 521
 522 // ======================================
 523 //  Supporting functions for VoteCommand
 524 // ======================================
 525
 526 float Votecommand_check_assignment(entity caller, float assignment)
 527 {
 528         float from_server = (!caller);
 529
 530         if ((assignment == VC_ASGNMNT_BOTH)
 531             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 532             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 533
 534         return false;
 535 }
 536
 537 string VoteCommand_extractcommand(string input, float startpos, float argc)
 538 {
 539         string output;
 540
 541         if ((argc - 1) < startpos) output = "";
 542         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 543
 544         return output;
 545 }
 546
 547 float VoteCommand_checknasty(string vote_command)
 548 {
 549         if ((strstrofs(vote_command, ";", 0) >= 0)
 550             || (strstrofs(vote_command, "\n", 0) >= 0)
 551             || (strstrofs(vote_command, "\r", 0) >= 0)
 552             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 553
 554         return true;
 555 }
 556
 557 float VoteCommand_checkinlist(string vote_command, string list)
 558 {
 559         string l = strcat(" ", list, " ");
 560
 561         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 562
 563         return false;
 564 }
 565
 566 string ValidateMap(string validated_map, entity caller)
 567 {
 568         validated_map = MapInfo_FixName(validated_map);
 569
 570         if (!validated_map)
 571         {
 572                 print_to(caller, "This map is not available on this server.");
 573                 return string_null;
 574         }
 575
 576         if (!autocvar_sv_vote_override_mostrecent && caller)
 577         {
 578                 if (Map_IsRecent(validated_map))
 579                 {
 580                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 581                         return string_null;
 582                 }
 583         }
 584
 585         if (!MapInfo_CheckMap(validated_map))
 586         {
 587                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 588                 return string_null;
 589         }
 590
 591         return validated_map;
 592 }
 593
 594 float VoteCommand_checkargs(float startpos, float argc)
 595 {
 596         float p, q, check, minargs;
 597         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 598         string cmdrestriction = cvar_string(cvarname);  // note: this warns on undefined cvar. We want that.
 599         string charlist, arg;
 600         float checkmate;
 601
 602         if (cmdrestriction == "") return true;
 603
 604         ++startpos;  // skip command name
 605
 606         // check minimum arg count
 607
 608         // 0 args: argc == startpos
 609         // 1 args: argc == startpos + 1
 610         // ...
 611
 612         minargs = stof(cmdrestriction);
 613         if (argc - startpos < minargs) return false;
 614
 615         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 616
 617         for ( ; ; )
 618         {
 619                 // we know that at any time, startpos <= argc - minargs
 620                 // so this means: argc-minargs >= startpos >= argc, thus
 621                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 622                 // have been seen already
 623
 624                 if (startpos >= argc) // all args checked? GOOD
 625                         break;
 626
 627                 if (p < 0)            // no more args? FAIL
 628                 {
 629                         // exception: exactly minargs left, this one included
 630                         if (argc - startpos == minargs) break;
 631
 632                         // otherwise fail
 633                         return false;
 634                 }
 635
 636                 // cut to next semicolon
 637                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 638                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 639                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 640
 641                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 642                 // charlist = strreplace("^^", ";", charlist);
 643
 644                 if (charlist != "")
 645                 {
 646                         // verify the arg only contains allowed chars
 647                         arg = argv(startpos);
 648                         checkmate = strlen(arg);
 649                         for (check = 0; check < checkmate; ++check)
 650                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 651                         // not allowed character
 652                         // all characters are allowed. FINE.
 653                 }
 654
 655                 ++startpos;
 656                 --minargs;
 657                 p = q;
 658         }
 659
 660         return true;
 661 }
 662
 663 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 664 {
 665         string first_command;
 666
 667         first_command = argv(startpos);
 668
 669         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 670             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 671             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 672         );*/
 673
 674         if (
 675             (autocvar_sv_vote_limit > 0)
 676             &&
 677             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 678            )   return false;
 679
 680         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 681
 682         if (!VoteCommand_checkargs(startpos, argc)) return false;
 683
 684         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 685         {
 686                 case "kick":
 687                 case "kickban":    // catch all kick/kickban commands
 688                 {
 689                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 690                         float accepted = VerifyClientEntity(victim, true, false);
 691
 692                         if (accepted > 0)
 693                         {
 694                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 695                                 string command_arguments;
 696
 697                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 698                                 else command_arguments = reason;
 699
 700                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 701                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 702                         }
 703                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 704
 705                         break;
 706                 }
 707
 708                 case "map":
 709                 case "chmap":
 710                 case "gotomap":  // re-direct all map selection commands to gotomap
 711                 {
 712                         vote_command = ValidateMap(argv(startpos + 1), caller);
 713                         if (!vote_command)   return false;
 714                         vote_parsed_command = strcat("gotomap ", vote_command);
 715                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 716
 717                         break;
 718                 }
 719
 720                 default:
 721                 {
 722                         vote_parsed_command = vote_command;
 723                         vote_parsed_display = strzone(strcat("^1", vote_command));
 724
 725                         break;
 726                 }
 727         }
 728
 729         return true;
 730 }
 731
 732
 733 // =======================
 734 //  Command Sub-Functions
 735 // =======================
 736
 737 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 738 {
 739         switch (request)
 740         {
 741                 case CMD_REQUEST_COMMAND:
 742                 {
 743                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 744                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 745                         {
 746                                 print_to(caller, "^1You have already voted.");
 747                         }
 748
 749                         else  // everything went okay, continue changing vote
 750                         {
 751                                 print_to(caller, "^1You abstained from your vote.");
 752                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 753                                 msg_entity = caller;
 754                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 755
 756                         return;
 757                 }
 758
 759                 default:
 760                 case CMD_REQUEST_USAGE:
 761                 {
 762                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 763                         print_to(caller, "  No arguments required.");
 764                         return;
 765                 }
 766         }
 767 }
 768
 769 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 770 {
 771         switch (request)
 772         {
 773                 case CMD_REQUEST_COMMAND:
 774                 {
 775                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 776                             || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 777                             || (autocvar_sv_vote_nospectators == 0));
 778
 779                         float tmp_playercount = 0;
 780                         entity tmp_player;
 781
 782                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 783
 784                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 785                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 786                         {
 787                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 788                         }
 789                         else if (vote_called)
 790                         {
 791                                 print_to(caller, "^1There is already a vote called.");
 792                         }
 793                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 794                         {
 795                                 print_to(caller, "^1Only players can call a vote.");
 796                         }
 797                         else if (caller && !IS_CLIENT(caller))
 798                         {
 799                                 print_to(caller, "^1Only connected clients can vote.");
 800                         }
 801                         else if (timeout_status)
 802                         {
 803                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 804                         }
 805                         else if (caller && (time < caller.vote_waittime))
 806                         {
 807                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 808                         }
 809                         else if (!VoteCommand_checknasty(vote_command))
 810                         {
 811                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 812                         }
 813                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 814                         {
 815                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 816                         }
 817
 818                         else  // everything went okay, continue with calling the vote
 819                         {
 820                                 vote_caller = caller;  // remember who called the vote
 821                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 822                                 vote_called = VOTE_NORMAL;
 823                                 vote_called_command = strzone(vote_parsed_command);
 824                                 vote_called_display = strzone(vote_parsed_display);
 825                                 vote_endtime = time + autocvar_sv_vote_timeout;
 826
 827                                 if (caller)
 828                                 {
 829                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 830                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 831                                         msg_entity = caller;
 832                                 }
 833
 834                                 FOR_EACH_REALCLIENT(tmp_player)
 835                                 {
 836                                         ++tmp_playercount;
 837                                 }
 838                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 839
 840                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 841                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 842                                 Nagger_VoteChanged();
 843                                 VoteCount(true);  // needed if you are the only one
 844                         }
 845
 846                         return;
 847                 }
 848
 849                 default:
 850                 case CMD_REQUEST_USAGE:
 851                 {
 852                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 853                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 854                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 855                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 856                         return;
 857                 }
 858         }
 859 }
 860
 861 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 862 {
 863         switch (request)
 864         {
 865                 case CMD_REQUEST_COMMAND:
 866                 {
 867                         if (autocvar_sv_vote_master)
 868                         {
 869                                 switch (strtolower(argv(2)))
 870                                 {
 871                                         case "do":
 872                                         {
 873                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 874
 875                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 876                                                 else if (!VoteCommand_checknasty(vote_command))
 877                                                 {
 878                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 879                                                 }
 880                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 881                                                 {
 882                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 883                                                 }
 884
 885                                                 else  // everything went okay, proceed with command
 886                                                 {
 887                                                         localcmd(strcat(vote_parsed_command, "\n"));
 888                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 889                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 890                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 891
 892                                                 return;
 893                                         }
 894
 895                                         case "login":
 896                                         {
 897                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 898                                                 else if (caller.vote_master)
 899                                                 {
 900                                                         print_to(caller, "^1You are already logged in as vote master.");
 901                                                 }
 902                                                 else if (autocvar_sv_vote_master_password != argv(3))
 903                                                 {
 904                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 905                                                 }
 906
 907                                                 else  // everything went okay, proceed with giving this player master privilages
 908                                                 {
 909                                                         caller.vote_master = true;
 910                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 911                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 912                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 913
 914                                                 return;
 915                                         }
 916
 917                                         default:  // calling a vote for master
 918                                         {
 919                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 920                                                     || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 921                                                     || (autocvar_sv_vote_nospectators == 0));
 922
 923                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 924                                                 else if (vote_called)
 925                                                 {
 926                                                         print_to(caller, "^1There is already a vote called.");
 927                                                 }
 928                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 929                                                 {
 930                                                         print_to(caller, "^1Only players can call a vote.");
 931                                                 }
 932                                                 else if (timeout_status)
 933                                                 {
 934                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 935                                                 }
 936
 937                                                 else  // everything went okay, continue with creating vote
 938                                                 {
 939                                                         vote_caller = caller;
 940                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 941                                                         vote_called = VOTE_MASTER;
 942                                                         vote_called_command = strzone("XXX");
 943                                                         vote_called_display = strzone("^3master");
 944                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 945
 946                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 947                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 948
 949                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 950                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 951                                                         Nagger_VoteChanged();
 952                                                         VoteCount(true);  // needed if you are the only one
 953                                                 }
 954
 955                                                 return;
 956                                         }
 957                                 }
 958                         }
 959                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 960
 961                         return;
 962                 }
 963
 964                 default:
 965                 case CMD_REQUEST_USAGE:
 966                 {
 967                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 968                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 969                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 970                         return;
 971                 }
 972         }
 973 }
 974
 975 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 976 {
 977         switch (request)
 978         {
 979                 case CMD_REQUEST_COMMAND:
 980                 {
 981                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 982                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 983                         {
 984                                 print_to(caller, "^1You have already voted.");
 985                         }
 986                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 987                         {
 988                                 VoteStop(caller);
 989                         }
 990
 991                         else  // everything went okay, continue changing vote
 992                         {
 993                                 print_to(caller, "^1You rejected the vote.");
 994                                 caller.vote_selection = VOTE_SELECT_REJECT;
 995                                 msg_entity = caller;
 996                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 997
 998                         return;
 999                 }
1000
1001                 default:
1002                 case CMD_REQUEST_USAGE:
1003                 {
1004                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1005                         print_to(caller, "  No arguments required.");
1006                         return;
1007                 }
1008         }
1009 }
1010
1011 void VoteCommand_status(float request, entity caller)  // BOTH
1012 {
1013         switch (request)
1014         {
1015                 case CMD_REQUEST_COMMAND:
1016                 {
1017                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1018                         else print_to(caller, "^1No vote called.");
1019
1020                         return;
1021                 }
1022
1023                 default:
1024                 case CMD_REQUEST_USAGE:
1025                 {
1026                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1027                         print_to(caller, "  No arguments required.");
1028                         return;
1029                 }
1030         }
1031 }
1032
1033 void VoteCommand_stop(float request, entity caller)  // BOTH
1034 {
1035         switch (request)
1036         {
1037                 case CMD_REQUEST_COMMAND:
1038                 {
1039                         if (!vote_called)   print_to(caller, "^1No vote called.");
1040                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1041                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1042                         return;
1043                 }
1044
1045                 default:
1046                 case CMD_REQUEST_USAGE:
1047                 {
1048                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1049                         print_to(caller, "  No arguments required.");
1050                         return;
1051                 }
1052         }
1053 }
1054
1055 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1056 {
1057         switch (request)
1058         {
1059                 case CMD_REQUEST_COMMAND:
1060                 {
1061                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1062                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1063                         {
1064                                 print_to(caller, "^1You have already voted.");
1065                         }
1066
1067                         else  // everything went okay, continue changing vote
1068                         {
1069                                 print_to(caller, "^1You accepted the vote.");
1070                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1071                                 msg_entity = caller;
1072                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1073
1074                         return;
1075                 }
1076
1077                 default:
1078                 case CMD_REQUEST_USAGE:
1079                 {
1080                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1081                         print_to(caller, "  No arguments required.");
1082                         return;
1083                 }
1084         }
1085 }
1086
1087 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1088 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1089 void VoteCommand_(float request)
1090 {
1091     switch(request)
1092     {
1093         case CMD_REQUEST_COMMAND:
1094         {
1095
1096             return;
1097         }
1098
1099         default:
1100         case CMD_REQUEST_USAGE:
1101         {
1102             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1103             print_to(caller, "  No arguments required.");
1104             return;
1105         }
1106     }
1107 }
1108 */
1109
1110
1111 // ================================
1112 //  Macro system for vote commands
1113 // ================================
1114
1115 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1116 #define VOTE_COMMANDS(request, caller, arguments, command) \
1117         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1118         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1119         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1120         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1121         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1122         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1123         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1124         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1125         /* nothing */
1126
1127 void VoteCommand_macro_help(entity caller, float argc)
1128 {
1129         string command_origin = GetCommandPrefix(caller);
1130
1131         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1132         {
1133                 print_to(caller, "\nVoting commands:\n");
1134                 #define VOTE_COMMAND(name, function, description, assignment) \
1135                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1136
1137                 VOTE_COMMANDS(0, caller, 0, "");
1138 #undef VOTE_COMMAND
1139
1140                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1141                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1142                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1143         }
1144         else  // usage for individual command
1145         {
1146                 #define VOTE_COMMAND(name, function, description, assignment) \
1147                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1148
1149                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1150 #undef VOTE_COMMAND
1151         }
1152 }
1153
1154 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1155 {
1156         #define VOTE_COMMAND(name, function, description, assignment) \
1157                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1158
1159         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1160 #undef VOTE_COMMAND
1161
1162         return false;
1163 }
1164
1165
1166 // ======================================
1167 //  Main function handling vote commands
1168 // ======================================
1169
1170 void VoteCommand(float request, entity caller, float argc, string vote_command)
1171 {
1172         // Guide for working with argc arguments by example:
1173         // argc:   1    - 2      - 3     - 4
1174         // argv:   0    - 1      - 2     - 3
1175         // cmd     vote - master - login - password
1176
1177         switch (request)
1178         {
1179                 case CMD_REQUEST_COMMAND:
1180                 {
1181                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1182                 }
1183
1184                 default:
1185                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1186                 case CMD_REQUEST_USAGE:
1187                 {
1188                         VoteCommand_macro_help(caller, argc);
1189                         return;
1190                 }
1191         }
1192 }