qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2 #include <common/command/command.qh>
   3 #include "vote.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/all.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/mapinfo.qh>
  17 #include <common/notifications/all.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/util.qh>
  20
  21 // =============================================
  22 //  Server side voting code, reworked by Samual
  23 //  Last updated: December 27th, 2011
  24 // =============================================
  25
  26 //  Nagger for players to know status of voting
  27 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  28 {
  29         int nags, i, f, b;
  30         entity e;
  31         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  32
  33         // bits:
  34         //   1 = ready
  35         //   2 = player needs to ready up
  36         //   4 = vote
  37         //   8 = player needs to vote
  38         //  16 = warmup
  39         // sendflags:
  40         //  64 = vote counts
  41         // 128 = vote string
  42
  43         nags = 0;
  44         if (readycount)
  45         {
  46                 nags |= BIT(0);
  47                 if (to.ready == 0) nags |= BIT(1);
  48         }
  49         if (vote_called)
  50         {
  51                 nags |= BIT(2);
  52                 if (to.vote_selection == 0) nags |= BIT(3);
  53         }
  54         if (warmup_stage) nags |= BIT(4);
  55
  56         if (sendflags & BIT(6)) nags |= BIT(6);
  57
  58         if (sendflags & BIT(7)) nags |= BIT(7);
  59
  60         if (!(nags & 4))  // no vote called? send no string
  61                 nags &= ~(BIT(6) | BIT(7));
  62
  63         WriteByte(MSG_ENTITY, nags);
  64
  65         if (nags & BIT(6))
  66         {
  67                 WriteByte(MSG_ENTITY, vote_accept_count);
  68                 WriteByte(MSG_ENTITY, vote_reject_count);
  69                 WriteByte(MSG_ENTITY, vote_needed_overall);
  70                 WriteChar(MSG_ENTITY, to.vote_selection);
  71         }
  72
  73         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  74
  75         if (nags & 1)
  76         {
  77                 for (i = 1; i <= maxclients; i += 8)
  78                 {
  79                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  80                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  81                         WriteByte(MSG_ENTITY, f);
  82                 }
  83         }
  84
  85         return true;
  86 }
  87
  88 void Nagger_Init()
  89 {
  90         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  91 }
  92
  93 void Nagger_VoteChanged()
  94 {
  95         if (nagger) nagger.SendFlags |= BIT(7);
  96 }
  97
  98 void Nagger_VoteCountChanged()
  99 {
 100         if (nagger) nagger.SendFlags |= BIT(6);
 101 }
 102
 103 void Nagger_ReadyCounted()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(0);
 106 }
 107
 108 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 109 string OriginalCallerName()
 110 {
 111         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 112         return vote_caller_name;
 113 }
 114
 115 // =======================
 116 //  Game logic for voting
 117 // =======================
 118
 119 void VoteReset()
 120 {
 121         FOREACH_CLIENT(true, LAMBDA(it.vote_selection = 0));
 122
 123         if (vote_called)
 124         {
 125                 strunzone(vote_called_command);
 126                 strunzone(vote_called_display);
 127                 strunzone(vote_caller_name);
 128         }
 129
 130         vote_called = VOTE_NULL;
 131         vote_caller = world;
 132         vote_caller_name = string_null;
 133         vote_endtime = 0;
 134
 135         vote_called_command = string_null;
 136         vote_called_display = string_null;
 137
 138         vote_parsed_command = string_null;
 139         vote_parsed_display = string_null;
 140
 141         Nagger_VoteChanged();
 142 }
 143
 144 void VoteStop(entity stopper)
 145 {
 146         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 147         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 148         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 149         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 150         VoteReset();
 151 }
 152
 153 void VoteAccept()
 154 {
 155         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 156
 157         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 158         else localcmd(strcat(vote_called_command, "\n"));
 159
 160         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 161
 162         VoteReset();
 163         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 164 }
 165
 166 void VoteReject()
 167 {
 168         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 169         VoteReset();
 170         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 171 }
 172
 173 void VoteTimeout()
 174 {
 175         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 176         VoteReset();
 177         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 178 }
 179
 180 void VoteSpam(float notvoters, float mincount, string result)
 181 {
 182         bprint(strcat(
 183                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 184                 strcat("^2:^1", ftos(vote_reject_count)),
 185                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 186                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 187                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 188
 189         if (autocvar_sv_eventlog)
 190         {
 191                 GameLogEcho(strcat(
 192                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 193                         strcat(":", ftos(vote_reject_count)),
 194                         strcat(":", ftos(vote_abstain_count)),
 195                         strcat(":", ftos(notvoters)),
 196                         strcat(":", ftos(mincount))));
 197         }
 198 }
 199
 200 void VoteCount(float first_count)
 201 {
 202         // declarations
 203         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 204
 205         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 206             || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 207             || (autocvar_sv_vote_nospectators == 0));
 208
 209         float vote_player_count = 0, notvoters = 0;
 210         float vote_real_player_count = 0, vote_real_accept_count = 0;
 211         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 212         float vote_needed_of_voted, final_needed_votes;
 213         float vote_factor_overall, vote_factor_of_voted;
 214
 215         Nagger_VoteCountChanged();
 216
 217         // add up all the votes from each connected client
 218         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), LAMBDA(
 219                 ++vote_player_count;
 220                 if (IS_PLAYER(it))   ++vote_real_player_count;
 221                 switch (it.vote_selection)
 222                 {
 223                         case VOTE_SELECT_REJECT:
 224                         { ++vote_reject_count;
 225                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 226                         }
 227                         case VOTE_SELECT_ACCEPT:
 228                         { ++vote_accept_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 230                         }
 231                         case VOTE_SELECT_ABSTAIN:
 232                         { ++vote_abstain_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 234                         }
 235                         default: break;
 236                 }
 237         ));
 238
 239         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 240         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 241         {
 242                 if (vote_caller)   vote_caller.vote_waittime = 0;
 243                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 244                 VoteReset();
 245                 return;
 246         }
 247
 248         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 249         if (!spectators_allowed && (vote_real_player_count > 0))
 250         {
 251                 vote_accept_count = vote_real_accept_count;
 252                 vote_reject_count = vote_real_reject_count;
 253                 vote_abstain_count = vote_real_abstain_count;
 254                 vote_player_count = vote_real_player_count;
 255         }
 256
 257         // people who have no opinion in any way :D
 258         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 259
 260         // determine the goal for the vote to be passed or rejected normally
 261         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 262         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 263
 264         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 265         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 266         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 267
 268         // are there any players at all on the server? it could be an admin vote
 269         if (vote_player_count == 0 && first_count)
 270         {
 271                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 272                 VoteAccept();
 273                 return;
 274         }
 275
 276         // since there ARE players, finally calculate the result of the vote
 277         if (vote_accept_count >= vote_needed_overall)
 278         {
 279                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 280                 VoteAccept();
 281                 return;
 282         }
 283
 284         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 285         {
 286                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 287                 VoteReject();
 288                 return;
 289         }
 290
 291         // there is not enough votes in either direction, now lets just calculate what the voters have said
 292         if (time > vote_endtime)
 293         {
 294                 final_needed_votes = vote_needed_overall;
 295
 296                 if (autocvar_sv_vote_majority_factor_of_voted)
 297                 {
 298                         if (vote_accept_count >= vote_needed_of_voted)
 299                         {
 300                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 301                                 VoteAccept();
 302                                 return;
 303                         }
 304
 305                         if (vote_accept_count + vote_reject_count > 0)
 306                         {
 307                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 308                                 VoteReject();
 309                                 return;
 310                         }
 311
 312                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 313                 }
 314
 315                 // it didn't pass or fail, so not enough votes to even make a decision.
 316                 VoteSpam(notvoters, final_needed_votes, "timeout");
 317                 VoteTimeout();
 318         }
 319 }
 320
 321 void VoteThink()
 322 {
 323         if (vote_endtime > 0)        // a vote was called
 324         {
 325                 if (time > vote_endtime) // time is up
 326                         VoteCount(false);
 327         }
 328 }
 329
 330
 331 // =======================
 332 //  Game logic for warmup
 333 // =======================
 334
 335 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 336 void reset_map(bool dorespawn)
 337 {
 338         SELFPARAM();
 339
 340         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
 341
 342         MUTATOR_CALLHOOK(reset_map_global);
 343
 344         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 345                 if (it.reset)
 346                 {
 347                         WITHSELF(it, it.reset(it));
 348                         continue;
 349                 }
 350                 if (it.team_saved) it.team = it.team_saved;
 351                 if (it.flags & FL_PROJECTILE) remove(it);  // remove any projectiles left
 352         });
 353
 354         // Waypoints and assault start come LAST
 355         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 356                 if (it.reset2) WITHSELF(it, it.reset2());
 357         });
 358
 359         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), LAMBDA(WITHSELF(it, Unfreeze(it))));
 360
 361         // Moving the player reset code here since the player-reset depends
 362         // on spawnpoint entities which have to be reset first --blub
 363         if (dorespawn)
 364         {
 365                 if (!MUTATOR_CALLHOOK(reset_map_players))
 366                 {
 367                         FOREACH_CLIENT(true, LAMBDA(
 368                                 setself(it);
 369                                 /*
 370                                 only reset players if a restart countdown is active
 371                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 372                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 373                                 sv_ready_restart_after_countdown is not used and countdown is still running
 374                                 */
 375                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 376                                 {
 377                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 378                                         if (IS_PLAYER(self))
 379                                         {
 380                                                 // PlayerScore_Clear(self);
 381                                                 self.killcount = 0;
 382                                                 // stop the player from moving so that he stands still once he gets respawned
 383                                                 self.velocity = '0 0 0';
 384                                                 self.avelocity = '0 0 0';
 385                                                 self.movement = '0 0 0';
 386                                                 PutClientInServer();
 387                                         }
 388                                 }
 389                         ));
 390
 391                         setself(this);
 392                 }
 393         }
 394 }
 395
 396 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 397 void ReadyRestart_think()
 398 {
 399         SELFPARAM();
 400         restart_mapalreadyrestarted = true;
 401         reset_map(true);
 402         Score_ClearAll();
 403         remove(this);
 404 }
 405
 406 // Forces a restart of the game without actually reloading the map // this is a mess...
 407 void ReadyRestart_force()
 408 {
 409         bprint("^1Server is restarting...\n");
 410
 411         VoteReset();
 412
 413         // clear overtime, we have to decrease timelimit to its original value again.
 414         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 415                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 416         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 417
 418         readyrestart_happened = true;
 419         game_starttime = time + RESTART_COUNTDOWN;
 420
 421         // clear player attributes
 422         FOREACH_CLIENT(true, LAMBDA(
 423                 it.alivetime = 0;
 424                 it.killcount = 0;
 425                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 426         ));
 427
 428         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 429
 430         // disable the warmup global for the server
 431         warmup_stage = 0;                // once the game is restarted the game is in match stage
 432
 433         // reset the .ready status of all players (also spectators)
 434         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(it.ready = false));
 435         readycount = 0;
 436         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 437
 438         // lock teams with lockonrestart
 439         if (autocvar_teamplay_lockonrestart && teamplay)
 440         {
 441                 lockteams = true;
 442                 bprint("^1The teams are now locked.\n");
 443         }
 444
 445         // initiate the restart-countdown-announcer entity
 446         if (autocvar_sv_ready_restart_after_countdown)
 447         {
 448                 entity restart_timer = new_pure(restart_timer);
 449                 restart_timer.think = ReadyRestart_think;
 450                 restart_timer.nextthink = game_starttime;
 451         }
 452
 453         // after a restart every players number of allowed timeouts gets reset, too
 454         if (autocvar_sv_timeout)
 455         {
 456                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(it.allowed_timeouts = autocvar_sv_timeout_number));
 457         }
 458     // reset map immediately if this cvar is not set
 459     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 460         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 461 }
 462
 463 void ReadyRestart()
 464 {
 465         // no assault support yet...
 466         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 467         else localcmd("\nsv_hook_gamerestart\n");
 468
 469         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 470         // Otherwise scores could be manipulated during the countdown.
 471         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 472         ReadyRestart_force();
 473 }
 474
 475 // Count the players who are ready and determine whether or not to restart the match
 476 void ReadyCount()
 477 {
 478         float ready_needed_factor, ready_needed_count;
 479         float t_ready = 0, t_players = 0;
 480
 481         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), LAMBDA(
 482                 ++t_players;
 483                 if (it.ready) ++t_ready;
 484         ));
 485
 486         readycount = t_ready;
 487
 488         Nagger_ReadyCounted();
 489
 490         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 491         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 492
 493         if (readycount >= ready_needed_count) ReadyRestart();
 494 }
 495
 496
 497 // ======================================
 498 //  Supporting functions for VoteCommand
 499 // ======================================
 500
 501 float Votecommand_check_assignment(entity caller, float assignment)
 502 {
 503         float from_server = (!caller);
 504
 505         if ((assignment == VC_ASGNMNT_BOTH)
 506             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 507             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 508
 509         return false;
 510 }
 511
 512 string VoteCommand_extractcommand(string input, float startpos, float argc)
 513 {
 514         string output;
 515
 516         if ((argc - 1) < startpos) output = "";
 517         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 518
 519         return output;
 520 }
 521
 522 float VoteCommand_checknasty(string vote_command)
 523 {
 524         if ((strstrofs(vote_command, ";", 0) >= 0)
 525             || (strstrofs(vote_command, "\n", 0) >= 0)
 526             || (strstrofs(vote_command, "\r", 0) >= 0)
 527             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 528
 529         return true;
 530 }
 531
 532 float VoteCommand_checkinlist(string vote_command, string list)
 533 {
 534         string l = strcat(" ", list, " ");
 535
 536         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 537
 538         return false;
 539 }
 540
 541 string ValidateMap(string validated_map, entity caller)
 542 {
 543         validated_map = MapInfo_FixName(validated_map);
 544
 545         if (!validated_map)
 546         {
 547                 print_to(caller, "This map is not available on this server.");
 548                 return string_null;
 549         }
 550
 551         if (!autocvar_sv_vote_override_mostrecent && caller)
 552         {
 553                 if (Map_IsRecent(validated_map))
 554                 {
 555                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 556                         return string_null;
 557                 }
 558         }
 559
 560         if (!MapInfo_CheckMap(validated_map))
 561         {
 562                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 563                 return string_null;
 564         }
 565
 566         return validated_map;
 567 }
 568
 569 float VoteCommand_checkargs(float startpos, float argc)
 570 {
 571         float p, q, check, minargs;
 572         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 573         string cmdrestriction = "";  // No we don't.
 574         string charlist, arg;
 575         float checkmate;
 576
 577         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 578                 cmdrestriction = cvar_string(cvarname);
 579         else
 580                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.\n");
 581
 582         if (cmdrestriction == "") return true;
 583
 584         ++startpos;  // skip command name
 585
 586         // check minimum arg count
 587
 588         // 0 args: argc == startpos
 589         // 1 args: argc == startpos + 1
 590         // ...
 591
 592         minargs = stof(cmdrestriction);
 593         if (argc - startpos < minargs) return false;
 594
 595         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 596
 597         for ( ; ; )
 598         {
 599                 // we know that at any time, startpos <= argc - minargs
 600                 // so this means: argc-minargs >= startpos >= argc, thus
 601                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 602                 // have been seen already
 603
 604                 if (startpos >= argc) // all args checked? GOOD
 605                         break;
 606
 607                 if (p < 0)            // no more args? FAIL
 608                 {
 609                         // exception: exactly minargs left, this one included
 610                         if (argc - startpos == minargs) break;
 611
 612                         // otherwise fail
 613                         return false;
 614                 }
 615
 616                 // cut to next semicolon
 617                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 618                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 619                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 620
 621                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 622                 // charlist = strreplace("^^", ";", charlist);
 623
 624                 if (charlist != "")
 625                 {
 626                         // verify the arg only contains allowed chars
 627                         arg = argv(startpos);
 628                         checkmate = strlen(arg);
 629                         for (check = 0; check < checkmate; ++check)
 630                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 631                         // not allowed character
 632                         // all characters are allowed. FINE.
 633                 }
 634
 635                 ++startpos;
 636                 --minargs;
 637                 p = q;
 638         }
 639
 640         return true;
 641 }
 642
 643 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 644 {
 645         string first_command;
 646
 647         first_command = argv(startpos);
 648
 649         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 650             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 651             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 652         );*/
 653
 654         if (
 655             (autocvar_sv_vote_limit > 0)
 656             &&
 657             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 658            )   return false;
 659
 660         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 661
 662         if (!VoteCommand_checkargs(startpos, argc)) return false;
 663
 664         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 665         {
 666                 case "kick":
 667                 case "kickban":    // catch all kick/kickban commands
 668                 {
 669                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 670                         float accepted = VerifyClientEntity(victim, true, false);
 671
 672                         if (accepted > 0)
 673                         {
 674                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 675                                 string command_arguments;
 676
 677                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 678                                 else command_arguments = reason;
 679
 680                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 681                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 682                         }
 683                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 684
 685                         break;
 686                 }
 687
 688                 case "map":
 689                 case "chmap":
 690                 case "gotomap":  // re-direct all map selection commands to gotomap
 691                 {
 692                         vote_command = ValidateMap(argv(startpos + 1), caller);
 693                         if (!vote_command)   return false;
 694                         vote_parsed_command = strcat("gotomap ", vote_command);
 695                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 696
 697                         break;
 698                 }
 699
 700                 default:
 701                 {
 702                         vote_parsed_command = vote_command;
 703                         vote_parsed_display = strzone(strcat("^1", vote_command));
 704
 705                         break;
 706                 }
 707         }
 708
 709         return true;
 710 }
 711
 712
 713 // =======================
 714 //  Command Sub-Functions
 715 // =======================
 716
 717 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 718 {
 719         switch (request)
 720         {
 721                 case CMD_REQUEST_COMMAND:
 722                 {
 723                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 724                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 725                         {
 726                                 print_to(caller, "^1You have already voted.");
 727                         }
 728
 729                         else  // everything went okay, continue changing vote
 730                         {
 731                                 print_to(caller, "^1You abstained from your vote.");
 732                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 733                                 msg_entity = caller;
 734                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 735
 736                         return;
 737                 }
 738
 739                 default:
 740                 case CMD_REQUEST_USAGE:
 741                 {
 742                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 743                         print_to(caller, "  No arguments required.");
 744                         return;
 745                 }
 746         }
 747 }
 748
 749 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 750 {
 751         switch (request)
 752         {
 753                 case CMD_REQUEST_COMMAND:
 754                 {
 755                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 756                             || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 757                             || (autocvar_sv_vote_nospectators == 0));
 758
 759                         float tmp_playercount = 0;
 760
 761                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 762
 763                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 764                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 765                         {
 766                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 767                         }
 768                         else if (vote_called)
 769                         {
 770                                 print_to(caller, "^1There is already a vote called.");
 771                         }
 772                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 773                         {
 774                                 print_to(caller, "^1Only players can call a vote.");
 775                         }
 776                         else if (caller && !IS_CLIENT(caller))
 777                         {
 778                                 print_to(caller, "^1Only connected clients can vote.");
 779                         }
 780                         else if (timeout_status)
 781                         {
 782                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 783                         }
 784                         else if (caller && (time < caller.vote_waittime))
 785                         {
 786                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 787                         }
 788                         else if (!VoteCommand_checknasty(vote_command))
 789                         {
 790                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 791                         }
 792                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 793                         {
 794                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 795                         }
 796
 797                         else  // everything went okay, continue with calling the vote
 798                         {
 799                                 vote_caller = caller;  // remember who called the vote
 800                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 801                                 vote_called = VOTE_NORMAL;
 802                                 vote_called_command = strzone(vote_parsed_command);
 803                                 vote_called_display = strzone(vote_parsed_display);
 804                                 vote_endtime = time + autocvar_sv_vote_timeout;
 805
 806                                 if (caller)
 807                                 {
 808                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 809                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 810                                         msg_entity = caller;
 811                                 }
 812
 813                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(++tmp_playercount));
 814                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 815
 816                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 817                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 818                                 Nagger_VoteChanged();
 819                                 VoteCount(true);  // needed if you are the only one
 820                         }
 821
 822                         return;
 823                 }
 824
 825                 default:
 826                 case CMD_REQUEST_USAGE:
 827                 {
 828                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 829                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 830                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 831                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 832                         return;
 833                 }
 834         }
 835 }
 836
 837 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 838 {
 839         switch (request)
 840         {
 841                 case CMD_REQUEST_COMMAND:
 842                 {
 843                         if (autocvar_sv_vote_master)
 844                         {
 845                                 switch (strtolower(argv(2)))
 846                                 {
 847                                         case "do":
 848                                         {
 849                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 850
 851                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 852                                                 else if (!VoteCommand_checknasty(vote_command))
 853                                                 {
 854                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 855                                                 }
 856                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 857                                                 {
 858                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 859                                                 }
 860
 861                                                 else  // everything went okay, proceed with command
 862                                                 {
 863                                                         localcmd(strcat(vote_parsed_command, "\n"));
 864                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 865                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 866                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 867
 868                                                 return;
 869                                         }
 870
 871                                         case "login":
 872                                         {
 873                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 874                                                 else if (caller.vote_master)
 875                                                 {
 876                                                         print_to(caller, "^1You are already logged in as vote master.");
 877                                                 }
 878                                                 else if (autocvar_sv_vote_master_password != argv(3))
 879                                                 {
 880                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 881                                                 }
 882
 883                                                 else  // everything went okay, proceed with giving this player master privilages
 884                                                 {
 885                                                         caller.vote_master = true;
 886                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 887                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 888                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 889
 890                                                 return;
 891                                         }
 892
 893                                         default:  // calling a vote for master
 894                                         {
 895                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 896                                                     || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 897                                                     || (autocvar_sv_vote_nospectators == 0));
 898
 899                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 900                                                 else if (vote_called)
 901                                                 {
 902                                                         print_to(caller, "^1There is already a vote called.");
 903                                                 }
 904                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 905                                                 {
 906                                                         print_to(caller, "^1Only players can call a vote.");
 907                                                 }
 908                                                 else if (timeout_status)
 909                                                 {
 910                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 911                                                 }
 912
 913                                                 else  // everything went okay, continue with creating vote
 914                                                 {
 915                                                         vote_caller = caller;
 916                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 917                                                         vote_called = VOTE_MASTER;
 918                                                         vote_called_command = strzone("XXX");
 919                                                         vote_called_display = strzone("^3master");
 920                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 921
 922                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 923                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 924
 925                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 926                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 927                                                         Nagger_VoteChanged();
 928                                                         VoteCount(true);  // needed if you are the only one
 929                                                 }
 930
 931                                                 return;
 932                                         }
 933                                 }
 934                         }
 935                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 936
 937                         return;
 938                 }
 939
 940                 default:
 941                 case CMD_REQUEST_USAGE:
 942                 {
 943                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 944                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 945                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 946                         return;
 947                 }
 948         }
 949 }
 950
 951 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 952 {
 953         switch (request)
 954         {
 955                 case CMD_REQUEST_COMMAND:
 956                 {
 957                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 958                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 959                         {
 960                                 print_to(caller, "^1You have already voted.");
 961                         }
 962                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 963                         {
 964                                 VoteStop(caller);
 965                         }
 966
 967                         else  // everything went okay, continue changing vote
 968                         {
 969                                 print_to(caller, "^1You rejected the vote.");
 970                                 caller.vote_selection = VOTE_SELECT_REJECT;
 971                                 msg_entity = caller;
 972                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 973
 974                         return;
 975                 }
 976
 977                 default:
 978                 case CMD_REQUEST_USAGE:
 979                 {
 980                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 981                         print_to(caller, "  No arguments required.");
 982                         return;
 983                 }
 984         }
 985 }
 986
 987 void VoteCommand_status(float request, entity caller)  // BOTH
 988 {
 989         switch (request)
 990         {
 991                 case CMD_REQUEST_COMMAND:
 992                 {
 993                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 994                         else print_to(caller, "^1No vote called.");
 995
 996                         return;
 997                 }
 998
 999                 default:
1000                 case CMD_REQUEST_USAGE:
1001                 {
1002                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1003                         print_to(caller, "  No arguments required.");
1004                         return;
1005                 }
1006         }
1007 }
1008
1009 void VoteCommand_stop(float request, entity caller)  // BOTH
1010 {
1011         switch (request)
1012         {
1013                 case CMD_REQUEST_COMMAND:
1014                 {
1015                         if (!vote_called)   print_to(caller, "^1No vote called.");
1016                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1017                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1018                         return;
1019                 }
1020
1021                 default:
1022                 case CMD_REQUEST_USAGE:
1023                 {
1024                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1025                         print_to(caller, "  No arguments required.");
1026                         return;
1027                 }
1028         }
1029 }
1030
1031 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1032 {
1033         switch (request)
1034         {
1035                 case CMD_REQUEST_COMMAND:
1036                 {
1037                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1038                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1039                         {
1040                                 print_to(caller, "^1You have already voted.");
1041                         }
1042
1043                         else  // everything went okay, continue changing vote
1044                         {
1045                                 print_to(caller, "^1You accepted the vote.");
1046                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1047                                 msg_entity = caller;
1048                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1049
1050                         return;
1051                 }
1052
1053                 default:
1054                 case CMD_REQUEST_USAGE:
1055                 {
1056                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1057                         print_to(caller, "  No arguments required.");
1058                         return;
1059                 }
1060         }
1061 }
1062
1063 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1064 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1065 void VoteCommand_(float request)
1066 {
1067     switch(request)
1068     {
1069         case CMD_REQUEST_COMMAND:
1070         {
1071
1072             return;
1073         }
1074
1075         default:
1076         case CMD_REQUEST_USAGE:
1077         {
1078             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1079             print_to(caller, "  No arguments required.");
1080             return;
1081         }
1082     }
1083 }
1084 */
1085
1086
1087 // ================================
1088 //  Macro system for vote commands
1089 // ================================
1090
1091 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1092 #define VOTE_COMMANDS(request, caller, arguments, command) \
1093         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1094         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1095         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1096         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1097         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1098         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1099         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1100         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1101         /* nothing */
1102
1103 void VoteCommand_macro_help(entity caller, float argc)
1104 {
1105         string command_origin = GetCommandPrefix(caller);
1106
1107         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1108         {
1109                 print_to(caller, "\nVoting commands:\n");
1110                 #define VOTE_COMMAND(name, function, description, assignment) \
1111                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1112
1113                 VOTE_COMMANDS(0, caller, 0, "");
1114 #undef VOTE_COMMAND
1115
1116                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1117                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1118                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1119         }
1120         else  // usage for individual command
1121         {
1122                 #define VOTE_COMMAND(name, function, description, assignment) \
1123                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1124
1125                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1126 #undef VOTE_COMMAND
1127         }
1128 }
1129
1130 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1131 {
1132         #define VOTE_COMMAND(name, function, description, assignment) \
1133                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1134
1135         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1136 #undef VOTE_COMMAND
1137
1138         return false;
1139 }
1140
1141
1142 // ======================================
1143 //  Main function handling vote commands
1144 // ======================================
1145
1146 void VoteCommand(float request, entity caller, float argc, string vote_command)
1147 {
1148         // Guide for working with argc arguments by example:
1149         // argc:   1    - 2      - 3     - 4
1150         // argv:   0    - 1      - 2     - 3
1151         // cmd     vote - master - login - password
1152
1153         switch (request)
1154         {
1155                 case CMD_REQUEST_COMMAND:
1156                 {
1157                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1158                 }
1159
1160                 default:
1161                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1162                 case CMD_REQUEST_USAGE:
1163                 {
1164                         VoteCommand_macro_help(caller, argc);
1165                         return;
1166                 }
1167         }
1168 }