qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2 #include <common/command/_mod.qh>
   3 #include "vote.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/_mod.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/notifications/all.qh>
  19 #include <common/playerstats.qh>
  20 #include <common/util.qh>
  21
  22 // =============================================
  23 //  Server side voting code, reworked by Samual
  24 //  Last updated: December 27th, 2011
  25 // =============================================
  26
  27 //  Nagger for players to know status of voting
  28 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  29 {
  30         int nags, i, f, b;
  31         entity e;
  32         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  33
  34         // bits:
  35         //   1 = ready
  36         //   2 = player needs to ready up
  37         //   4 = vote
  38         //   8 = player needs to vote
  39         //  16 = warmup
  40         // sendflags:
  41         //  64 = vote counts
  42         // 128 = vote string
  43
  44         nags = 0;
  45         if (readycount)
  46         {
  47                 nags |= BIT(0);
  48                 if (to.ready == 0) nags |= BIT(1);
  49         }
  50         if (vote_called)
  51         {
  52                 nags |= BIT(2);
  53                 if (to.vote_selection == 0) nags |= BIT(3);
  54         }
  55         if (warmup_stage) nags |= BIT(4);
  56
  57         if (sendflags & BIT(6)) nags |= BIT(6);
  58
  59         if (sendflags & BIT(7)) nags |= BIT(7);
  60
  61         if (!(nags & 4))  // no vote called? send no string
  62                 nags &= ~(BIT(6) | BIT(7));
  63
  64         WriteByte(MSG_ENTITY, nags);
  65
  66         if (nags & BIT(6))
  67         {
  68                 WriteByte(MSG_ENTITY, vote_accept_count);
  69                 WriteByte(MSG_ENTITY, vote_reject_count);
  70                 WriteByte(MSG_ENTITY, vote_needed_overall);
  71                 WriteChar(MSG_ENTITY, to.vote_selection);
  72         }
  73
  74         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  75
  76         if (nags & 1)
  77         {
  78                 for (i = 1; i <= maxclients; i += 8)
  79                 {
  80                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  81                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  82                         WriteByte(MSG_ENTITY, f);
  83                 }
  84         }
  85
  86         return true;
  87 }
  88
  89 void Nagger_Init()
  90 {
  91         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  92 }
  93
  94 void Nagger_VoteChanged()
  95 {
  96         if (nagger) nagger.SendFlags |= BIT(7);
  97 }
  98
  99 void Nagger_VoteCountChanged()
 100 {
 101         if (nagger) nagger.SendFlags |= BIT(6);
 102 }
 103
 104 void Nagger_ReadyCounted()
 105 {
 106         if (nagger) nagger.SendFlags |= BIT(0);
 107 }
 108
 109 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 110 string OriginalCallerName()
 111 {
 112         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 113         return vote_caller_name;
 114 }
 115
 116 // =======================
 117 //  Game logic for voting
 118 // =======================
 119
 120 void VoteReset()
 121 {
 122         FOREACH_CLIENT(true, LAMBDA(it.vote_selection = 0));
 123
 124         if (vote_called)
 125         {
 126                 strunzone(vote_called_command);
 127                 strunzone(vote_called_display);
 128                 strunzone(vote_caller_name);
 129         }
 130
 131         vote_called = VOTE_NULL;
 132         vote_caller = NULL;
 133         vote_caller_name = string_null;
 134         vote_endtime = 0;
 135
 136         vote_called_command = string_null;
 137         vote_called_display = string_null;
 138
 139         vote_parsed_command = string_null;
 140         vote_parsed_display = string_null;
 141
 142         Nagger_VoteChanged();
 143 }
 144
 145 void VoteStop(entity stopper)
 146 {
 147         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 148         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 149         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 150         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 151         VoteReset();
 152 }
 153
 154 void VoteAccept()
 155 {
 156         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 157
 158         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 159         else localcmd(strcat(vote_called_command, "\n"));
 160
 161         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 162
 163         VoteReset();
 164         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 165 }
 166
 167 void VoteReject()
 168 {
 169         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 170         VoteReset();
 171         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 172 }
 173
 174 void VoteTimeout()
 175 {
 176         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 177         VoteReset();
 178         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 179 }
 180
 181 void VoteSpam(float notvoters, float mincount, string result)
 182 {
 183         bprint(strcat(
 184                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 185                 strcat("^2:^1", ftos(vote_reject_count)),
 186                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 187                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 188                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 189
 190         if (autocvar_sv_eventlog)
 191         {
 192                 GameLogEcho(strcat(
 193                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 194                         strcat(":", ftos(vote_reject_count)),
 195                         strcat(":", ftos(vote_abstain_count)),
 196                         strcat(":", ftos(notvoters)),
 197                         strcat(":", ftos(mincount))));
 198         }
 199 }
 200
 201 void VoteCount(float first_count)
 202 {
 203         // declarations
 204         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 205
 206         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 207
 208         float vote_player_count = 0, notvoters = 0;
 209         float vote_real_player_count = 0, vote_real_accept_count = 0;
 210         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 211         float vote_needed_of_voted, final_needed_votes;
 212         float vote_factor_overall, vote_factor_of_voted;
 213
 214         Nagger_VoteCountChanged();
 215
 216         // add up all the votes from each connected client
 217         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), LAMBDA(
 218                 ++vote_player_count;
 219                 if (IS_PLAYER(it))   ++vote_real_player_count;
 220                 switch (it.vote_selection)
 221                 {
 222                         case VOTE_SELECT_REJECT:
 223                         { ++vote_reject_count;
 224                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 225                         }
 226                         case VOTE_SELECT_ACCEPT:
 227                         { ++vote_accept_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 229                         }
 230                         case VOTE_SELECT_ABSTAIN:
 231                         { ++vote_abstain_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 233                         }
 234                         default: break;
 235                 }
 236         ));
 237
 238         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 239         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 240         {
 241                 if (vote_caller)   vote_caller.vote_waittime = 0;
 242                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 243                 VoteReset();
 244                 return;
 245         }
 246
 247         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 248         if (!spectators_allowed && (vote_real_player_count > 0))
 249         {
 250                 vote_accept_count = vote_real_accept_count;
 251                 vote_reject_count = vote_real_reject_count;
 252                 vote_abstain_count = vote_real_abstain_count;
 253                 vote_player_count = vote_real_player_count;
 254         }
 255
 256         // people who have no opinion in any way :D
 257         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 258
 259         // determine the goal for the vote to be passed or rejected normally
 260         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 261         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 262
 263         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 264         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 265         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 266
 267         // are there any players at all on the server? it could be an admin vote
 268         if (vote_player_count == 0 && first_count)
 269         {
 270                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 271                 VoteAccept();
 272                 return;
 273         }
 274
 275         // since there ARE players, finally calculate the result of the vote
 276         if (vote_accept_count >= vote_needed_overall)
 277         {
 278                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 279                 VoteAccept();
 280                 return;
 281         }
 282
 283         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 284         {
 285                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 286                 VoteReject();
 287                 return;
 288         }
 289
 290         // there is not enough votes in either direction, now lets just calculate what the voters have said
 291         if (time > vote_endtime)
 292         {
 293                 final_needed_votes = vote_needed_overall;
 294
 295                 if (autocvar_sv_vote_majority_factor_of_voted)
 296                 {
 297                         if (vote_accept_count >= vote_needed_of_voted)
 298                         {
 299                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 300                                 VoteAccept();
 301                                 return;
 302                         }
 303
 304                         if (vote_accept_count + vote_reject_count > 0)
 305                         {
 306                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 307                                 VoteReject();
 308                                 return;
 309                         }
 310
 311                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 312                 }
 313
 314                 // it didn't pass or fail, so not enough votes to even make a decision.
 315                 VoteSpam(notvoters, final_needed_votes, "timeout");
 316                 VoteTimeout();
 317         }
 318 }
 319
 320 void VoteThink()
 321 {
 322         if (vote_endtime > 0)        // a vote was called
 323         {
 324                 if (time > vote_endtime) // time is up
 325                         VoteCount(false);
 326         }
 327 }
 328
 329
 330 // =======================
 331 //  Game logic for warmup
 332 // =======================
 333
 334 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 335 void reset_map(bool dorespawn)
 336 {
 337         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
 338
 339         MUTATOR_CALLHOOK(reset_map_global);
 340
 341         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 342                 if (it.reset)
 343                 {
 344                         it.reset(it);
 345                         continue;
 346                 }
 347                 if (it.team_saved) it.team = it.team_saved;
 348                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 349         });
 350
 351         // Waypoints and assault start come LAST
 352         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 353                 if (it.reset2) it.reset2(it);
 354         });
 355
 356         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), LAMBDA(Unfreeze(it)));
 357
 358         // Moving the player reset code here since the player-reset depends
 359         // on spawnpoint entities which have to be reset first --blub
 360         if (dorespawn)
 361         {
 362                 if (!MUTATOR_CALLHOOK(reset_map_players))
 363                 {
 364                         FOREACH_CLIENT(true, LAMBDA(
 365                                 /*
 366                                 only reset players if a restart countdown is active
 367                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 368                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 369                                 sv_ready_restart_after_countdown is not used and countdown is still running
 370                                 */
 371                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 372                                 {
 373                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 374                                         if (IS_PLAYER(it))
 375                                         {
 376                                                 // PlayerScore_Clear(it);
 377                                                 it.killcount = 0;
 378                                                 // stop the player from moving so that he stands still once he gets respawned
 379                                                 it.velocity = '0 0 0';
 380                                                 it.avelocity = '0 0 0';
 381                                                 it.movement = '0 0 0';
 382                                                 PutClientInServer(it);
 383                                         }
 384                                 }
 385                         ));
 386                 }
 387         }
 388 }
 389
 390 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 391 void ReadyRestart_think(entity this)
 392 {
 393         restart_mapalreadyrestarted = true;
 394         reset_map(true);
 395         Score_ClearAll();
 396         delete(this);
 397 }
 398
 399 // Forces a restart of the game without actually reloading the map // this is a mess...
 400 void ReadyRestart_force()
 401 {
 402         bprint("^1Server is restarting...\n");
 403
 404         VoteReset();
 405
 406         // clear overtime, we have to decrease timelimit to its original value again.
 407         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 408                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 409         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 410
 411         readyrestart_happened = true;
 412         game_starttime = time + RESTART_COUNTDOWN;
 413
 414         // clear player attributes
 415         FOREACH_CLIENT(true, LAMBDA(
 416                 it.alivetime = 0;
 417                 it.killcount = 0;
 418                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 419         ));
 420
 421         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 422
 423         // disable the warmup global for the server
 424         warmup_stage = 0;                // once the game is restarted the game is in match stage
 425
 426         // reset the .ready status of all players (also spectators)
 427         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(it.ready = false));
 428         readycount = 0;
 429         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 430
 431         // lock teams with lockonrestart
 432         if (autocvar_teamplay_lockonrestart && teamplay)
 433         {
 434                 lockteams = true;
 435                 bprint("^1The teams are now locked.\n");
 436         }
 437
 438         // initiate the restart-countdown-announcer entity
 439         if (autocvar_sv_ready_restart_after_countdown)
 440         {
 441                 entity restart_timer = new_pure(restart_timer);
 442                 setthink(restart_timer, ReadyRestart_think);
 443                 restart_timer.nextthink = game_starttime;
 444         }
 445
 446         // after a restart every players number of allowed timeouts gets reset, too
 447         if (autocvar_sv_timeout)
 448         {
 449                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(it.allowed_timeouts = autocvar_sv_timeout_number));
 450         }
 451     // reset map immediately if this cvar is not set
 452     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 453         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 454 }
 455
 456 void ReadyRestart()
 457 {
 458         // no assault support yet...
 459         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 460         else localcmd("\nsv_hook_gamerestart\n");
 461
 462         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 463         // Otherwise scores could be manipulated during the countdown.
 464         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 465         ReadyRestart_force();
 466 }
 467
 468 // Count the players who are ready and determine whether or not to restart the match
 469 void ReadyCount()
 470 {
 471         float ready_needed_factor, ready_needed_count;
 472         float t_ready = 0, t_players = 0;
 473
 474         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), LAMBDA(
 475                 ++t_players;
 476                 if (it.ready) ++t_ready;
 477         ));
 478
 479         readycount = t_ready;
 480
 481         Nagger_ReadyCounted();
 482
 483         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 484         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 485
 486         if (readycount >= ready_needed_count) ReadyRestart();
 487 }
 488
 489
 490 // ======================================
 491 //  Supporting functions for VoteCommand
 492 // ======================================
 493
 494 float Votecommand_check_assignment(entity caller, float assignment)
 495 {
 496         float from_server = (!caller);
 497
 498         if ((assignment == VC_ASGNMNT_BOTH)
 499             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 500             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 501
 502         return false;
 503 }
 504
 505 string VoteCommand_extractcommand(string input, float startpos, float argc)
 506 {
 507         string output;
 508
 509         if ((argc - 1) < startpos) output = "";
 510         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 511
 512         return output;
 513 }
 514
 515 float VoteCommand_checknasty(string vote_command)
 516 {
 517         if ((strstrofs(vote_command, ";", 0) >= 0)
 518             || (strstrofs(vote_command, "\n", 0) >= 0)
 519             || (strstrofs(vote_command, "\r", 0) >= 0)
 520             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 521
 522         return true;
 523 }
 524
 525 float VoteCommand_checkinlist(string vote_command, string list)
 526 {
 527         string l = strcat(" ", list, " ");
 528
 529         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 530
 531         return false;
 532 }
 533
 534 string ValidateMap(string validated_map, entity caller)
 535 {
 536         validated_map = MapInfo_FixName(validated_map);
 537
 538         if (!validated_map)
 539         {
 540                 print_to(caller, "This map is not available on this server.");
 541                 return string_null;
 542         }
 543
 544         if (!autocvar_sv_vote_override_mostrecent && caller)
 545         {
 546                 if (Map_IsRecent(validated_map))
 547                 {
 548                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 549                         return string_null;
 550                 }
 551         }
 552
 553         if (!MapInfo_CheckMap(validated_map))
 554         {
 555                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 556                 return string_null;
 557         }
 558
 559         return validated_map;
 560 }
 561
 562 float VoteCommand_checkargs(float startpos, float argc)
 563 {
 564         float p, q, check, minargs;
 565         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 566         string cmdrestriction = "";  // No we don't.
 567         string charlist, arg;
 568         float checkmate;
 569
 570         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 571                 cmdrestriction = cvar_string(cvarname);
 572         else
 573                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.\n");
 574
 575         if (cmdrestriction == "") return true;
 576
 577         ++startpos;  // skip command name
 578
 579         // check minimum arg count
 580
 581         // 0 args: argc == startpos
 582         // 1 args: argc == startpos + 1
 583         // ...
 584
 585         minargs = stof(cmdrestriction);
 586         if (argc - startpos < minargs) return false;
 587
 588         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 589
 590         for ( ; ; )
 591         {
 592                 // we know that at any time, startpos <= argc - minargs
 593                 // so this means: argc-minargs >= startpos >= argc, thus
 594                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 595                 // have been seen already
 596
 597                 if (startpos >= argc) // all args checked? GOOD
 598                         break;
 599
 600                 if (p < 0)            // no more args? FAIL
 601                 {
 602                         // exception: exactly minargs left, this one included
 603                         if (argc - startpos == minargs) break;
 604
 605                         // otherwise fail
 606                         return false;
 607                 }
 608
 609                 // cut to next semicolon
 610                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 611                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 612                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 613
 614                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 615                 // charlist = strreplace("^^", ";", charlist);
 616
 617                 if (charlist != "")
 618                 {
 619                         // verify the arg only contains allowed chars
 620                         arg = argv(startpos);
 621                         checkmate = strlen(arg);
 622                         for (check = 0; check < checkmate; ++check)
 623                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 624                         // not allowed character
 625                         // all characters are allowed. FINE.
 626                 }
 627
 628                 ++startpos;
 629                 --minargs;
 630                 p = q;
 631         }
 632
 633         return true;
 634 }
 635
 636 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 637 {
 638         string first_command;
 639
 640         first_command = argv(startpos);
 641
 642         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 643             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 644             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 645         );*/
 646
 647         if (
 648             (autocvar_sv_vote_limit > 0)
 649             &&
 650             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 651            )   return false;
 652
 653         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 654
 655         if (!VoteCommand_checkargs(startpos, argc)) return false;
 656
 657         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 658         {
 659                 case "kick":
 660                 case "kickban":    // catch all kick/kickban commands
 661                 {
 662                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 663                         float accepted = VerifyClientEntity(victim, true, false);
 664
 665                         if (accepted > 0)
 666                         {
 667                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 668                                 string command_arguments;
 669
 670                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 671                                 else command_arguments = reason;
 672
 673                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 674                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 675                         }
 676                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 677
 678                         break;
 679                 }
 680
 681                 case "map":
 682                 case "chmap":
 683                 case "gotomap":  // re-direct all map selection commands to gotomap
 684                 {
 685                         vote_command = ValidateMap(argv(startpos + 1), caller);
 686                         if (!vote_command)   return false;
 687                         vote_parsed_command = strcat("gotomap ", vote_command);
 688                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 689
 690                         break;
 691                 }
 692
 693                 default:
 694                 {
 695                         vote_parsed_command = vote_command;
 696                         vote_parsed_display = strzone(strcat("^1", vote_command));
 697
 698                         break;
 699                 }
 700         }
 701
 702         return true;
 703 }
 704
 705
 706 // =======================
 707 //  Command Sub-Functions
 708 // =======================
 709
 710 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 711 {
 712         switch (request)
 713         {
 714                 case CMD_REQUEST_COMMAND:
 715                 {
 716                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 717                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 718                         {
 719                                 print_to(caller, "^1You have already voted.");
 720                         }
 721
 722                         else  // everything went okay, continue changing vote
 723                         {
 724                                 print_to(caller, "^1You abstained from your vote.");
 725                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 726                                 msg_entity = caller;
 727                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 728
 729                         return;
 730                 }
 731
 732                 default:
 733                 case CMD_REQUEST_USAGE:
 734                 {
 735                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 736                         print_to(caller, "  No arguments required.");
 737                         return;
 738                 }
 739         }
 740 }
 741
 742 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 743 {
 744         switch (request)
 745         {
 746                 case CMD_REQUEST_COMMAND:
 747                 {
 748                         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 749
 750                         float tmp_playercount = 0;
 751
 752                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 753
 754                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 755                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 756                         {
 757                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 758                         }
 759                         else if (vote_called)
 760                         {
 761                                 print_to(caller, "^1There is already a vote called.");
 762                         }
 763                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 764                         {
 765                                 print_to(caller, "^1Only players can call a vote.");
 766                         }
 767                         else if (caller && !IS_CLIENT(caller))
 768                         {
 769                                 print_to(caller, "^1Only connected clients can vote.");
 770                         }
 771                         else if (timeout_status)
 772                         {
 773                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 774                         }
 775                         else if (caller && (time < caller.vote_waittime))
 776                         {
 777                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 778                         }
 779                         else if (!VoteCommand_checknasty(vote_command))
 780                         {
 781                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 782                         }
 783                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 784                         {
 785                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 786                         }
 787
 788                         else  // everything went okay, continue with calling the vote
 789                         {
 790                                 vote_caller = caller;  // remember who called the vote
 791                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 792                                 vote_called = VOTE_NORMAL;
 793                                 vote_called_command = strzone(vote_parsed_command);
 794                                 vote_called_display = strzone(vote_parsed_display);
 795                                 vote_endtime = time + autocvar_sv_vote_timeout;
 796
 797                                 if (caller)
 798                                 {
 799                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 800                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 801                                         msg_entity = caller;
 802                                 }
 803
 804                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(++tmp_playercount));
 805                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 806
 807                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 808                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 809                                 Nagger_VoteChanged();
 810                                 VoteCount(true);  // needed if you are the only one
 811                         }
 812
 813                         return;
 814                 }
 815
 816                 default:
 817                 case CMD_REQUEST_USAGE:
 818                 {
 819                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 820                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 821                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 822                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 823                         return;
 824                 }
 825         }
 826 }
 827
 828 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 829 {
 830         switch (request)
 831         {
 832                 case CMD_REQUEST_COMMAND:
 833                 {
 834                         if (autocvar_sv_vote_master)
 835                         {
 836                                 switch (strtolower(argv(2)))
 837                                 {
 838                                         case "do":
 839                                         {
 840                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 841
 842                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 843                                                 else if (!VoteCommand_checknasty(vote_command))
 844                                                 {
 845                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 846                                                 }
 847                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 848                                                 {
 849                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 850                                                 }
 851
 852                                                 else  // everything went okay, proceed with command
 853                                                 {
 854                                                         localcmd(strcat(vote_parsed_command, "\n"));
 855                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 856                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 857                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 858
 859                                                 return;
 860                                         }
 861
 862                                         case "login":
 863                                         {
 864                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 865                                                 else if (caller.vote_master)
 866                                                 {
 867                                                         print_to(caller, "^1You are already logged in as vote master.");
 868                                                 }
 869                                                 else if (autocvar_sv_vote_master_password != argv(3))
 870                                                 {
 871                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 872                                                 }
 873
 874                                                 else  // everything went okay, proceed with giving this player master privilages
 875                                                 {
 876                                                         caller.vote_master = true;
 877                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 878                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 879                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 880
 881                                                 return;
 882                                         }
 883
 884                                         default:  // calling a vote for master
 885                                         {
 886                                                 bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 887
 888                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 889                                                 else if (vote_called)
 890                                                 {
 891                                                         print_to(caller, "^1There is already a vote called.");
 892                                                 }
 893                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 894                                                 {
 895                                                         print_to(caller, "^1Only players can call a vote.");
 896                                                 }
 897                                                 else if (timeout_status)
 898                                                 {
 899                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 900                                                 }
 901
 902                                                 else  // everything went okay, continue with creating vote
 903                                                 {
 904                                                         vote_caller = caller;
 905                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 906                                                         vote_called = VOTE_MASTER;
 907                                                         vote_called_command = strzone("XXX");
 908                                                         vote_called_display = strzone("^3master");
 909                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 910
 911                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 912                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 913
 914                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 915                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 916                                                         Nagger_VoteChanged();
 917                                                         VoteCount(true);  // needed if you are the only one
 918                                                 }
 919
 920                                                 return;
 921                                         }
 922                                 }
 923                         }
 924                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 925
 926                         return;
 927                 }
 928
 929                 default:
 930                 case CMD_REQUEST_USAGE:
 931                 {
 932                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 933                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 934                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 935                         return;
 936                 }
 937         }
 938 }
 939
 940 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 941 {
 942         switch (request)
 943         {
 944                 case CMD_REQUEST_COMMAND:
 945                 {
 946                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 947                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 948                         {
 949                                 print_to(caller, "^1You have already voted.");
 950                         }
 951                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 952                         {
 953                                 VoteStop(caller);
 954                         }
 955
 956                         else  // everything went okay, continue changing vote
 957                         {
 958                                 print_to(caller, "^1You rejected the vote.");
 959                                 caller.vote_selection = VOTE_SELECT_REJECT;
 960                                 msg_entity = caller;
 961                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 962
 963                         return;
 964                 }
 965
 966                 default:
 967                 case CMD_REQUEST_USAGE:
 968                 {
 969                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 970                         print_to(caller, "  No arguments required.");
 971                         return;
 972                 }
 973         }
 974 }
 975
 976 void VoteCommand_status(float request, entity caller)  // BOTH
 977 {
 978         switch (request)
 979         {
 980                 case CMD_REQUEST_COMMAND:
 981                 {
 982                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 983                         else print_to(caller, "^1No vote called.");
 984
 985                         return;
 986                 }
 987
 988                 default:
 989                 case CMD_REQUEST_USAGE:
 990                 {
 991                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 992                         print_to(caller, "  No arguments required.");
 993                         return;
 994                 }
 995         }
 996 }
 997
 998 void VoteCommand_stop(float request, entity caller)  // BOTH
 999 {
1000         switch (request)
1001         {
1002                 case CMD_REQUEST_COMMAND:
1003                 {
1004                         if (!vote_called)   print_to(caller, "^1No vote called.");
1005                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1006                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1007                         return;
1008                 }
1009
1010                 default:
1011                 case CMD_REQUEST_USAGE:
1012                 {
1013                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1014                         print_to(caller, "  No arguments required.");
1015                         return;
1016                 }
1017         }
1018 }
1019
1020 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1021 {
1022         switch (request)
1023         {
1024                 case CMD_REQUEST_COMMAND:
1025                 {
1026                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1027                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1028                         {
1029                                 print_to(caller, "^1You have already voted.");
1030                         }
1031
1032                         else  // everything went okay, continue changing vote
1033                         {
1034                                 print_to(caller, "^1You accepted the vote.");
1035                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1036                                 msg_entity = caller;
1037                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1038
1039                         return;
1040                 }
1041
1042                 default:
1043                 case CMD_REQUEST_USAGE:
1044                 {
1045                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1046                         print_to(caller, "  No arguments required.");
1047                         return;
1048                 }
1049         }
1050 }
1051
1052 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1053 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1054 void VoteCommand_(float request)
1055 {
1056     switch(request)
1057     {
1058         case CMD_REQUEST_COMMAND:
1059         {
1060
1061             return;
1062         }
1063
1064         default:
1065         case CMD_REQUEST_USAGE:
1066         {
1067             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1068             print_to(caller, "  No arguments required.");
1069             return;
1070         }
1071     }
1072 }
1073 */
1074
1075
1076 // ================================
1077 //  Macro system for vote commands
1078 // ================================
1079
1080 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1081 #define VOTE_COMMANDS(request, caller, arguments, command) \
1082         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1083         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1084         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1085         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1086         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1087         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1088         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1089         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1090         /* nothing */
1091
1092 void VoteCommand_macro_help(entity caller, float argc)
1093 {
1094         string command_origin = GetCommandPrefix(caller);
1095
1096         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1097         {
1098                 print_to(caller, "\nVoting commands:\n");
1099                 #define VOTE_COMMAND(name, function, description, assignment) \
1100                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1101
1102                 VOTE_COMMANDS(0, caller, 0, "");
1103 #undef VOTE_COMMAND
1104
1105                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1106                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1107                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1108         }
1109         else  // usage for individual command
1110         {
1111                 #define VOTE_COMMAND(name, function, description, assignment) \
1112                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1113
1114                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1115 #undef VOTE_COMMAND
1116         }
1117 }
1118
1119 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1120 {
1121         #define VOTE_COMMAND(name, function, description, assignment) \
1122                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1123
1124         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1125 #undef VOTE_COMMAND
1126
1127         return false;
1128 }
1129
1130
1131 // ======================================
1132 //  Main function handling vote commands
1133 // ======================================
1134
1135 void VoteCommand(float request, entity caller, float argc, string vote_command)
1136 {
1137         // Guide for working with argc arguments by example:
1138         // argc:   1    - 2      - 3     - 4
1139         // argv:   0    - 1      - 2     - 3
1140         // cmd     vote - master - login - password
1141
1142         switch (request)
1143         {
1144                 case CMD_REQUEST_COMMAND:
1145                 {
1146                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1147                 }
1148
1149                 default:
1150                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1151                 case CMD_REQUEST_USAGE:
1152                 {
1153                         VoteCommand_macro_help(caller, argc);
1154                         return;
1155                 }
1156         }
1157 }