qcsrc/server/command/vote.qc

   1 #include <common/command/command.qh>
   2 #include "vote.qh"
   3
   4 #include "common.qh"
   5
   6 #include "../g_damage.qh"
   7 #include "../g_world.qh"
   8 #include "../race.qh"
   9 #include "../round_handler.qh"
  10 #include "../scores.qh"
  11
  12 #include "../mutators/all.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/playerstats.qh>
  18 #include <common/util.qh>
  19
  20 // =============================================
  21 //  Server side voting code, reworked by Samual
  22 //  Last updated: December 27th, 2011
  23 // =============================================
  24
  25 //  Nagger for players to know status of voting
  26 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  27 {
  28         int nags, i, f, b;
  29         entity e;
  30         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  31
  32         // bits:
  33         //   1 = ready
  34         //   2 = player needs to ready up
  35         //   4 = vote
  36         //   8 = player needs to vote
  37         //  16 = warmup
  38         // sendflags:
  39         //  64 = vote counts
  40         // 128 = vote string
  41
  42         nags = 0;
  43         if (readycount)
  44         {
  45                 nags |= BIT(0);
  46                 if (to.ready == 0) nags |= BIT(1);
  47         }
  48         if (vote_called)
  49         {
  50                 nags |= BIT(2);
  51                 if (to.vote_selection == 0) nags |= BIT(3);
  52         }
  53         if (warmup_stage) nags |= BIT(4);
  54
  55         if (sendflags & BIT(6)) nags |= BIT(6);
  56
  57         if (sendflags & BIT(7)) nags |= BIT(7);
  58
  59         if (!(nags & 4))  // no vote called? send no string
  60                 nags &= ~(BIT(6) | BIT(7));
  61
  62         WriteByte(MSG_ENTITY, nags);
  63
  64         if (nags & BIT(6))
  65         {
  66                 WriteByte(MSG_ENTITY, vote_accept_count);
  67                 WriteByte(MSG_ENTITY, vote_reject_count);
  68                 WriteByte(MSG_ENTITY, vote_needed_overall);
  69                 WriteChar(MSG_ENTITY, to.vote_selection);
  70         }
  71
  72         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  73
  74         if (nags & 1)
  75         {
  76                 for (i = 1; i <= maxclients; i += 8)
  77                 {
  78                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  79                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  80                         WriteByte(MSG_ENTITY, f);
  81                 }
  82         }
  83
  84         return true;
  85 }
  86
  87 void Nagger_Init()
  88 {
  89         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  90 }
  91
  92 void Nagger_VoteChanged()
  93 {
  94         if (nagger) nagger.SendFlags |= BIT(7);
  95 }
  96
  97 void Nagger_VoteCountChanged()
  98 {
  99         if (nagger) nagger.SendFlags |= BIT(6);
 100 }
 101
 102 void Nagger_ReadyCounted()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(0);
 105 }
 106
 107 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 108 string OriginalCallerName()
 109 {
 110         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 111         return vote_caller_name;
 112 }
 113
 114 // =======================
 115 //  Game logic for voting
 116 // =======================
 117
 118 void VoteReset()
 119 {
 120         FOREACH_CLIENT(true, LAMBDA(it.vote_selection = 0));
 121
 122         if (vote_called)
 123         {
 124                 strunzone(vote_called_command);
 125                 strunzone(vote_called_display);
 126                 strunzone(vote_caller_name);
 127         }
 128
 129         vote_called = VOTE_NULL;
 130         vote_caller = world;
 131         vote_caller_name = string_null;
 132         vote_endtime = 0;
 133
 134         vote_called_command = string_null;
 135         vote_called_display = string_null;
 136
 137         vote_parsed_command = string_null;
 138         vote_parsed_display = string_null;
 139
 140         Nagger_VoteChanged();
 141 }
 142
 143 void VoteStop(entity stopper)
 144 {
 145         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 146         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 147         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 148         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 149         VoteReset();
 150 }
 151
 152 void VoteAccept()
 153 {
 154         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 155
 156         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 157         else localcmd(strcat(vote_called_command, "\n"));
 158
 159         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 160
 161         VoteReset();
 162         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 163 }
 164
 165 void VoteReject()
 166 {
 167         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 168         VoteReset();
 169         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 170 }
 171
 172 void VoteTimeout()
 173 {
 174         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 175         VoteReset();
 176         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 177 }
 178
 179 void VoteSpam(float notvoters, float mincount, string result)
 180 {
 181         bprint(strcat(
 182                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 183                 strcat("^2:^1", ftos(vote_reject_count)),
 184                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 185                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 186                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 187
 188         if (autocvar_sv_eventlog)
 189         {
 190                 GameLogEcho(strcat(
 191                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 192                         strcat(":", ftos(vote_reject_count)),
 193                         strcat(":", ftos(vote_abstain_count)),
 194                         strcat(":", ftos(notvoters)),
 195                         strcat(":", ftos(mincount))));
 196         }
 197 }
 198
 199 void VoteCount(float first_count)
 200 {
 201         // declarations
 202         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 203
 204         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 205             || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 206             || (autocvar_sv_vote_nospectators == 0));
 207
 208         float vote_player_count = 0, notvoters = 0;
 209         float vote_real_player_count = 0, vote_real_accept_count = 0;
 210         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 211         float vote_needed_of_voted, final_needed_votes;
 212         float vote_factor_overall, vote_factor_of_voted;
 213
 214         Nagger_VoteCountChanged();
 215
 216         // add up all the votes from each connected client
 217         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), LAMBDA(
 218                 ++vote_player_count;
 219                 if (IS_PLAYER(it))   ++vote_real_player_count;
 220                 switch (it.vote_selection)
 221                 {
 222                         case VOTE_SELECT_REJECT:
 223                         { ++vote_reject_count;
 224                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 225                         }
 226                         case VOTE_SELECT_ACCEPT:
 227                         { ++vote_accept_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 229                         }
 230                         case VOTE_SELECT_ABSTAIN:
 231                         { ++vote_abstain_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 233                         }
 234                         default: break;
 235                 }
 236         ));
 237
 238         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 239         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 240         {
 241                 if (vote_caller)   vote_caller.vote_waittime = 0;
 242                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 243                 VoteReset();
 244                 return;
 245         }
 246
 247         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 248         if (!spectators_allowed && (vote_real_player_count > 0))
 249         {
 250                 vote_accept_count = vote_real_accept_count;
 251                 vote_reject_count = vote_real_reject_count;
 252                 vote_abstain_count = vote_real_abstain_count;
 253                 vote_player_count = vote_real_player_count;
 254         }
 255
 256         // people who have no opinion in any way :D
 257         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 258
 259         // determine the goal for the vote to be passed or rejected normally
 260         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 261         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 262
 263         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 264         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 265         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 266
 267         // are there any players at all on the server? it could be an admin vote
 268         if (vote_player_count == 0 && first_count)
 269         {
 270                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 271                 VoteAccept();
 272                 return;
 273         }
 274
 275         // since there ARE players, finally calculate the result of the vote
 276         if (vote_accept_count >= vote_needed_overall)
 277         {
 278                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 279                 VoteAccept();
 280                 return;
 281         }
 282
 283         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 284         {
 285                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 286                 VoteReject();
 287                 return;
 288         }
 289
 290         // there is not enough votes in either direction, now lets just calculate what the voters have said
 291         if (time > vote_endtime)
 292         {
 293                 final_needed_votes = vote_needed_overall;
 294
 295                 if (autocvar_sv_vote_majority_factor_of_voted)
 296                 {
 297                         if (vote_accept_count >= vote_needed_of_voted)
 298                         {
 299                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 300                                 VoteAccept();
 301                                 return;
 302                         }
 303
 304                         if (vote_accept_count + vote_reject_count > 0)
 305                         {
 306                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 307                                 VoteReject();
 308                                 return;
 309                         }
 310
 311                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 312                 }
 313
 314                 // it didn't pass or fail, so not enough votes to even make a decision.
 315                 VoteSpam(notvoters, final_needed_votes, "timeout");
 316                 VoteTimeout();
 317         }
 318 }
 319
 320 void VoteThink()
 321 {
 322         if (vote_endtime > 0)        // a vote was called
 323         {
 324                 if (time > vote_endtime) // time is up
 325                         VoteCount(false);
 326         }
 327 }
 328
 329
 330 // =======================
 331 //  Game logic for warmup
 332 // =======================
 333
 334 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 335 void reset_map(bool dorespawn)
 336 {
 337         SELFPARAM();
 338
 339         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
 340
 341         MUTATOR_CALLHOOK(reset_map_global);
 342
 343         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), LAMBDA(
 344                 if (it.reset)
 345                 {
 346                         WITH(entity, self, it, it.reset(it));
 347                         continue;
 348                 }
 349                 if (it.team_saved) it.team = it.team_saved;
 350                 if (it.flags & FL_PROJECTILE) remove(it);  // remove any projectiles left
 351         ));
 352
 353         // Waypoints and assault start come LAST
 354         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), LAMBDA(
 355                 if (it.reset2) WITH(entity, self, it, it.reset2());
 356         ));
 357
 358         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), LAMBDA(WITH(entity, self, it, Unfreeze(it))));
 359
 360         // Moving the player reset code here since the player-reset depends
 361         // on spawnpoint entities which have to be reset first --blub
 362         if (dorespawn)
 363         {
 364                 if (!MUTATOR_CALLHOOK(reset_map_players))
 365                 {
 366                         FOREACH_CLIENT(true, LAMBDA(
 367                                 setself(it);
 368                                 /*
 369                                 only reset players if a restart countdown is active
 370                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 371                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 372                                 sv_ready_restart_after_countdown is not used and countdown is still running
 373                                 */
 374                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 375                                 {
 376                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 377                                         if (IS_PLAYER(self))
 378                                         {
 379                                                 // PlayerScore_Clear(self);
 380                                                 self.killcount = 0;
 381                                                 // stop the player from moving so that he stands still once he gets respawned
 382                                                 self.velocity = '0 0 0';
 383                                                 self.avelocity = '0 0 0';
 384                                                 self.movement = '0 0 0';
 385                                                 PutClientInServer();
 386                                         }
 387                                 }
 388                         ));
 389
 390                         setself(this);
 391                 }
 392         }
 393 }
 394
 395 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 396 void ReadyRestart_think()
 397 {
 398         SELFPARAM();
 399         restart_mapalreadyrestarted = true;
 400         reset_map(true);
 401         Score_ClearAll();
 402         remove(this);
 403 }
 404
 405 // Forces a restart of the game without actually reloading the map // this is a mess...
 406 void ReadyRestart_force()
 407 {
 408         bprint("^1Server is restarting...\n");
 409
 410         VoteReset();
 411
 412         // clear overtime, we have to decrease timelimit to its original value again.
 413         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 414                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 415         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 416
 417         readyrestart_happened = true;
 418         game_starttime = time + RESTART_COUNTDOWN;
 419
 420         // clear player attributes
 421         FOREACH_CLIENT(true, LAMBDA(
 422                 it.alivetime = 0;
 423                 it.killcount = 0;
 424                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 425         ));
 426
 427         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 428
 429         // disable the warmup global for the server
 430         warmup_stage = 0;                // once the game is restarted the game is in match stage
 431
 432         // reset the .ready status of all players (also spectators)
 433         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(it.ready = false));
 434         readycount = 0;
 435         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 436
 437         // lock teams with lockonrestart
 438         if (autocvar_teamplay_lockonrestart && teamplay)
 439         {
 440                 lockteams = true;
 441                 bprint("^1The teams are now locked.\n");
 442         }
 443
 444         // initiate the restart-countdown-announcer entity
 445         if (autocvar_sv_ready_restart_after_countdown)
 446         {
 447                 entity restart_timer = new_pure(restart_timer);
 448                 restart_timer.think = ReadyRestart_think;
 449                 restart_timer.nextthink = game_starttime;
 450         }
 451
 452         // after a restart every players number of allowed timeouts gets reset, too
 453         if (autocvar_sv_timeout)
 454         {
 455                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(it.allowed_timeouts = autocvar_sv_timeout_number));
 456         }
 457     // reset map immediately if this cvar is not set
 458     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 459         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 460 }
 461
 462 void ReadyRestart()
 463 {
 464         // no assault support yet...
 465         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 466         else localcmd("\nsv_hook_gamerestart\n");
 467
 468         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 469         // Otherwise scores could be manipulated during the countdown.
 470         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 471         ReadyRestart_force();
 472 }
 473
 474 // Count the players who are ready and determine whether or not to restart the match
 475 void ReadyCount()
 476 {
 477         float ready_needed_factor, ready_needed_count;
 478         float t_ready = 0, t_players = 0;
 479
 480         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), LAMBDA(
 481                 ++t_players;
 482                 if (it.ready) ++t_ready;
 483         ));
 484
 485         readycount = t_ready;
 486
 487         Nagger_ReadyCounted();
 488
 489         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 490         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 491
 492         if (readycount >= ready_needed_count) ReadyRestart();
 493 }
 494
 495
 496 // ======================================
 497 //  Supporting functions for VoteCommand
 498 // ======================================
 499
 500 float Votecommand_check_assignment(entity caller, float assignment)
 501 {
 502         float from_server = (!caller);
 503
 504         if ((assignment == VC_ASGNMNT_BOTH)
 505             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 506             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 507
 508         return false;
 509 }
 510
 511 string VoteCommand_extractcommand(string input, float startpos, float argc)
 512 {
 513         string output;
 514
 515         if ((argc - 1) < startpos) output = "";
 516         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 517
 518         return output;
 519 }
 520
 521 float VoteCommand_checknasty(string vote_command)
 522 {
 523         if ((strstrofs(vote_command, ";", 0) >= 0)
 524             || (strstrofs(vote_command, "\n", 0) >= 0)
 525             || (strstrofs(vote_command, "\r", 0) >= 0)
 526             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 527
 528         return true;
 529 }
 530
 531 float VoteCommand_checkinlist(string vote_command, string list)
 532 {
 533         string l = strcat(" ", list, " ");
 534
 535         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 536
 537         return false;
 538 }
 539
 540 string ValidateMap(string validated_map, entity caller)
 541 {
 542         validated_map = MapInfo_FixName(validated_map);
 543
 544         if (!validated_map)
 545         {
 546                 print_to(caller, "This map is not available on this server.");
 547                 return string_null;
 548         }
 549
 550         if (!autocvar_sv_vote_override_mostrecent && caller)
 551         {
 552                 if (Map_IsRecent(validated_map))
 553                 {
 554                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 555                         return string_null;
 556                 }
 557         }
 558
 559         if (!MapInfo_CheckMap(validated_map))
 560         {
 561                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 562                 return string_null;
 563         }
 564
 565         return validated_map;
 566 }
 567
 568 float VoteCommand_checkargs(float startpos, float argc)
 569 {
 570         float p, q, check, minargs;
 571         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 572         string cmdrestriction = cvar_string(cvarname);  // note: this warns on undefined cvar. We want that.
 573         string charlist, arg;
 574         float checkmate;
 575
 576         if (cmdrestriction == "") return true;
 577
 578         ++startpos;  // skip command name
 579
 580         // check minimum arg count
 581
 582         // 0 args: argc == startpos
 583         // 1 args: argc == startpos + 1
 584         // ...
 585
 586         minargs = stof(cmdrestriction);
 587         if (argc - startpos < minargs) return false;
 588
 589         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 590
 591         for ( ; ; )
 592         {
 593                 // we know that at any time, startpos <= argc - minargs
 594                 // so this means: argc-minargs >= startpos >= argc, thus
 595                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 596                 // have been seen already
 597
 598                 if (startpos >= argc) // all args checked? GOOD
 599                         break;
 600
 601                 if (p < 0)            // no more args? FAIL
 602                 {
 603                         // exception: exactly minargs left, this one included
 604                         if (argc - startpos == minargs) break;
 605
 606                         // otherwise fail
 607                         return false;
 608                 }
 609
 610                 // cut to next semicolon
 611                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 612                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 613                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 614
 615                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 616                 // charlist = strreplace("^^", ";", charlist);
 617
 618                 if (charlist != "")
 619                 {
 620                         // verify the arg only contains allowed chars
 621                         arg = argv(startpos);
 622                         checkmate = strlen(arg);
 623                         for (check = 0; check < checkmate; ++check)
 624                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 625                         // not allowed character
 626                         // all characters are allowed. FINE.
 627                 }
 628
 629                 ++startpos;
 630                 --minargs;
 631                 p = q;
 632         }
 633
 634         return true;
 635 }
 636
 637 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 638 {
 639         string first_command;
 640
 641         first_command = argv(startpos);
 642
 643         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 644             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 645             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 646         );*/
 647
 648         if (
 649             (autocvar_sv_vote_limit > 0)
 650             &&
 651             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 652            )   return false;
 653
 654         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 655
 656         if (!VoteCommand_checkargs(startpos, argc)) return false;
 657
 658         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 659         {
 660                 case "kick":
 661                 case "kickban":    // catch all kick/kickban commands
 662                 {
 663                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 664                         float accepted = VerifyClientEntity(victim, true, false);
 665
 666                         if (accepted > 0)
 667                         {
 668                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 669                                 string command_arguments;
 670
 671                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 672                                 else command_arguments = reason;
 673
 674                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 675                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 676                         }
 677                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 678
 679                         break;
 680                 }
 681
 682                 case "map":
 683                 case "chmap":
 684                 case "gotomap":  // re-direct all map selection commands to gotomap
 685                 {
 686                         vote_command = ValidateMap(argv(startpos + 1), caller);
 687                         if (!vote_command)   return false;
 688                         vote_parsed_command = strcat("gotomap ", vote_command);
 689                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 690
 691                         break;
 692                 }
 693
 694                 default:
 695                 {
 696                         vote_parsed_command = vote_command;
 697                         vote_parsed_display = strzone(strcat("^1", vote_command));
 698
 699                         break;
 700                 }
 701         }
 702
 703         return true;
 704 }
 705
 706
 707 // =======================
 708 //  Command Sub-Functions
 709 // =======================
 710
 711 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 712 {
 713         switch (request)
 714         {
 715                 case CMD_REQUEST_COMMAND:
 716                 {
 717                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 718                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 719                         {
 720                                 print_to(caller, "^1You have already voted.");
 721                         }
 722
 723                         else  // everything went okay, continue changing vote
 724                         {
 725                                 print_to(caller, "^1You abstained from your vote.");
 726                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 727                                 msg_entity = caller;
 728                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 729
 730                         return;
 731                 }
 732
 733                 default:
 734                 case CMD_REQUEST_USAGE:
 735                 {
 736                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 737                         print_to(caller, "  No arguments required.");
 738                         return;
 739                 }
 740         }
 741 }
 742
 743 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 744 {
 745         switch (request)
 746         {
 747                 case CMD_REQUEST_COMMAND:
 748                 {
 749                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 750                             || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 751                             || (autocvar_sv_vote_nospectators == 0));
 752
 753                         float tmp_playercount = 0;
 754
 755                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 756
 757                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 758                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 759                         {
 760                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 761                         }
 762                         else if (vote_called)
 763                         {
 764                                 print_to(caller, "^1There is already a vote called.");
 765                         }
 766                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 767                         {
 768                                 print_to(caller, "^1Only players can call a vote.");
 769                         }
 770                         else if (caller && !IS_CLIENT(caller))
 771                         {
 772                                 print_to(caller, "^1Only connected clients can vote.");
 773                         }
 774                         else if (timeout_status)
 775                         {
 776                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 777                         }
 778                         else if (caller && (time < caller.vote_waittime))
 779                         {
 780                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 781                         }
 782                         else if (!VoteCommand_checknasty(vote_command))
 783                         {
 784                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 785                         }
 786                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 787                         {
 788                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 789                         }
 790
 791                         else  // everything went okay, continue with calling the vote
 792                         {
 793                                 vote_caller = caller;  // remember who called the vote
 794                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 795                                 vote_called = VOTE_NORMAL;
 796                                 vote_called_command = strzone(vote_parsed_command);
 797                                 vote_called_display = strzone(vote_parsed_display);
 798                                 vote_endtime = time + autocvar_sv_vote_timeout;
 799
 800                                 if (caller)
 801                                 {
 802                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 803                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 804                                         msg_entity = caller;
 805                                 }
 806
 807                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(++tmp_playercount));
 808                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 809
 810                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 811                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 812                                 Nagger_VoteChanged();
 813                                 VoteCount(true);  // needed if you are the only one
 814                         }
 815
 816                         return;
 817                 }
 818
 819                 default:
 820                 case CMD_REQUEST_USAGE:
 821                 {
 822                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 823                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 824                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 825                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 826                         return;
 827                 }
 828         }
 829 }
 830
 831 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 832 {
 833         switch (request)
 834         {
 835                 case CMD_REQUEST_COMMAND:
 836                 {
 837                         if (autocvar_sv_vote_master)
 838                         {
 839                                 switch (strtolower(argv(2)))
 840                                 {
 841                                         case "do":
 842                                         {
 843                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 844
 845                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 846                                                 else if (!VoteCommand_checknasty(vote_command))
 847                                                 {
 848                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 849                                                 }
 850                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 851                                                 {
 852                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 853                                                 }
 854
 855                                                 else  // everything went okay, proceed with command
 856                                                 {
 857                                                         localcmd(strcat(vote_parsed_command, "\n"));
 858                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 859                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 860                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 861
 862                                                 return;
 863                                         }
 864
 865                                         case "login":
 866                                         {
 867                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 868                                                 else if (caller.vote_master)
 869                                                 {
 870                                                         print_to(caller, "^1You are already logged in as vote master.");
 871                                                 }
 872                                                 else if (autocvar_sv_vote_master_password != argv(3))
 873                                                 {
 874                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 875                                                 }
 876
 877                                                 else  // everything went okay, proceed with giving this player master privilages
 878                                                 {
 879                                                         caller.vote_master = true;
 880                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 881                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 882                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 883
 884                                                 return;
 885                                         }
 886
 887                                         default:  // calling a vote for master
 888                                         {
 889                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 890                                                     || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 891                                                     || (autocvar_sv_vote_nospectators == 0));
 892
 893                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 894                                                 else if (vote_called)
 895                                                 {
 896                                                         print_to(caller, "^1There is already a vote called.");
 897                                                 }
 898                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 899                                                 {
 900                                                         print_to(caller, "^1Only players can call a vote.");
 901                                                 }
 902                                                 else if (timeout_status)
 903                                                 {
 904                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 905                                                 }
 906
 907                                                 else  // everything went okay, continue with creating vote
 908                                                 {
 909                                                         vote_caller = caller;
 910                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 911                                                         vote_called = VOTE_MASTER;
 912                                                         vote_called_command = strzone("XXX");
 913                                                         vote_called_display = strzone("^3master");
 914                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 915
 916                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 917                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 918
 919                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 920                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 921                                                         Nagger_VoteChanged();
 922                                                         VoteCount(true);  // needed if you are the only one
 923                                                 }
 924
 925                                                 return;
 926                                         }
 927                                 }
 928                         }
 929                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 930
 931                         return;
 932                 }
 933
 934                 default:
 935                 case CMD_REQUEST_USAGE:
 936                 {
 937                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 938                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 939                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 940                         return;
 941                 }
 942         }
 943 }
 944
 945 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 946 {
 947         switch (request)
 948         {
 949                 case CMD_REQUEST_COMMAND:
 950                 {
 951                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 952                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 953                         {
 954                                 print_to(caller, "^1You have already voted.");
 955                         }
 956                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 957                         {
 958                                 VoteStop(caller);
 959                         }
 960
 961                         else  // everything went okay, continue changing vote
 962                         {
 963                                 print_to(caller, "^1You rejected the vote.");
 964                                 caller.vote_selection = VOTE_SELECT_REJECT;
 965                                 msg_entity = caller;
 966                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 967
 968                         return;
 969                 }
 970
 971                 default:
 972                 case CMD_REQUEST_USAGE:
 973                 {
 974                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 975                         print_to(caller, "  No arguments required.");
 976                         return;
 977                 }
 978         }
 979 }
 980
 981 void VoteCommand_status(float request, entity caller)  // BOTH
 982 {
 983         switch (request)
 984         {
 985                 case CMD_REQUEST_COMMAND:
 986                 {
 987                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 988                         else print_to(caller, "^1No vote called.");
 989
 990                         return;
 991                 }
 992
 993                 default:
 994                 case CMD_REQUEST_USAGE:
 995                 {
 996                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 997                         print_to(caller, "  No arguments required.");
 998                         return;
 999                 }
1000         }
1001 }
1002
1003 void VoteCommand_stop(float request, entity caller)  // BOTH
1004 {
1005         switch (request)
1006         {
1007                 case CMD_REQUEST_COMMAND:
1008                 {
1009                         if (!vote_called)   print_to(caller, "^1No vote called.");
1010                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1011                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1012                         return;
1013                 }
1014
1015                 default:
1016                 case CMD_REQUEST_USAGE:
1017                 {
1018                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1019                         print_to(caller, "  No arguments required.");
1020                         return;
1021                 }
1022         }
1023 }
1024
1025 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1026 {
1027         switch (request)
1028         {
1029                 case CMD_REQUEST_COMMAND:
1030                 {
1031                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1032                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1033                         {
1034                                 print_to(caller, "^1You have already voted.");
1035                         }
1036
1037                         else  // everything went okay, continue changing vote
1038                         {
1039                                 print_to(caller, "^1You accepted the vote.");
1040                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1041                                 msg_entity = caller;
1042                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1043
1044                         return;
1045                 }
1046
1047                 default:
1048                 case CMD_REQUEST_USAGE:
1049                 {
1050                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1051                         print_to(caller, "  No arguments required.");
1052                         return;
1053                 }
1054         }
1055 }
1056
1057 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1058 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1059 void VoteCommand_(float request)
1060 {
1061     switch(request)
1062     {
1063         case CMD_REQUEST_COMMAND:
1064         {
1065
1066             return;
1067         }
1068
1069         default:
1070         case CMD_REQUEST_USAGE:
1071         {
1072             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1073             print_to(caller, "  No arguments required.");
1074             return;
1075         }
1076     }
1077 }
1078 */
1079
1080
1081 // ================================
1082 //  Macro system for vote commands
1083 // ================================
1084
1085 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1086 #define VOTE_COMMANDS(request, caller, arguments, command) \
1087         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1088         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1089         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1090         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1091         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1092         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1093         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1094         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1095         /* nothing */
1096
1097 void VoteCommand_macro_help(entity caller, float argc)
1098 {
1099         string command_origin = GetCommandPrefix(caller);
1100
1101         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1102         {
1103                 print_to(caller, "\nVoting commands:\n");
1104                 #define VOTE_COMMAND(name, function, description, assignment) \
1105                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1106
1107                 VOTE_COMMANDS(0, caller, 0, "");
1108 #undef VOTE_COMMAND
1109
1110                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1111                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1112                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1113         }
1114         else  // usage for individual command
1115         {
1116                 #define VOTE_COMMAND(name, function, description, assignment) \
1117                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1118
1119                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1120 #undef VOTE_COMMAND
1121         }
1122 }
1123
1124 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1125 {
1126         #define VOTE_COMMAND(name, function, description, assignment) \
1127                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1128
1129         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1130 #undef VOTE_COMMAND
1131
1132         return false;
1133 }
1134
1135
1136 // ======================================
1137 //  Main function handling vote commands
1138 // ======================================
1139
1140 void VoteCommand(float request, entity caller, float argc, string vote_command)
1141 {
1142         // Guide for working with argc arguments by example:
1143         // argc:   1    - 2      - 3     - 4
1144         // argv:   0    - 1      - 2     - 3
1145         // cmd     vote - master - login - password
1146
1147         switch (request)
1148         {
1149                 case CMD_REQUEST_COMMAND:
1150                 {
1151                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1152                 }
1153
1154                 default:
1155                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1156                 case CMD_REQUEST_USAGE:
1157                 {
1158                         VoteCommand_macro_help(caller, argc);
1159                         return;
1160                 }
1161         }
1162 }