qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3
   4 #include "common.qh"
   5
   6 #include "../g_damage.qh"
   7 #include "../g_world.qh"
   8 #include "../race.qh"
   9 #include "../round_handler.qh"
  10 #include "../scores.qh"
  11
  12 #include "../mutators/all.qh"
  13
  14 #include "../../common/constants.qh"
  15 #include "../../common/mapinfo.qh"
  16 #include "../../common/notifications.qh"
  17 #include "../../common/playerstats.qh"
  18 #include "../../common/util.qh"
  19
  20 // =============================================
  21 //  Server side voting code, reworked by Samual
  22 //  Last updated: December 27th, 2011
  23 // =============================================
  24
  25 //  Nagger for players to know status of voting
  26 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  27 {
  28         int nags, i, f, b;
  29         entity e;
  30         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  31
  32         // bits:
  33         //   1 = ready
  34         //   2 = player needs to ready up
  35         //   4 = vote
  36         //   8 = player needs to vote
  37         //  16 = warmup
  38         // sendflags:
  39         //  64 = vote counts
  40         // 128 = vote string
  41
  42         nags = 0;
  43         if (readycount)
  44         {
  45                 nags |= BIT(0);
  46                 if (to.ready == 0) nags |= BIT(1);
  47         }
  48         if (vote_called)
  49         {
  50                 nags |= BIT(2);
  51                 if (to.vote_selection == 0) nags |= BIT(3);
  52         }
  53         if (warmup_stage) nags |= BIT(4);
  54
  55         if (sendflags & BIT(6)) nags |= BIT(6);
  56
  57         if (sendflags & BIT(7)) nags |= BIT(7);
  58
  59         if (!(nags & 4))  // no vote called? send no string
  60                 nags &= ~(BIT(6) | BIT(7));
  61
  62         WriteByte(MSG_ENTITY, nags);
  63
  64         if (nags & BIT(6))
  65         {
  66                 WriteByte(MSG_ENTITY, vote_accept_count);
  67                 WriteByte(MSG_ENTITY, vote_reject_count);
  68                 WriteByte(MSG_ENTITY, vote_needed_overall);
  69                 WriteChar(MSG_ENTITY, to.vote_selection);
  70         }
  71
  72         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  73
  74         if (nags & 1)
  75         {
  76                 for (i = 1; i <= maxclients; i += 8)
  77                 {
  78                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  79                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  80                         WriteByte(MSG_ENTITY, f);
  81                 }
  82         }
  83
  84         return true;
  85 }
  86
  87 void Nagger_Init()
  88 {
  89         Net_LinkEntity(nagger = new(nagger), false, 0, Nagger_SendEntity);
  90         make_pure(nagger);
  91 }
  92
  93 void Nagger_VoteChanged()
  94 {
  95         if (nagger) nagger.SendFlags |= BIT(7);
  96 }
  97
  98 void Nagger_VoteCountChanged()
  99 {
 100         if (nagger) nagger.SendFlags |= BIT(6);
 101 }
 102
 103 void Nagger_ReadyCounted()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(0);
 106 }
 107
 108 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 109 string OriginalCallerName()
 110 {
 111         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 112         return vote_caller_name;
 113 }
 114
 115 // =======================
 116 //  Game logic for voting
 117 // =======================
 118
 119 void VoteReset()
 120 {
 121         entity tmp_player;
 122
 123         FOR_EACH_CLIENT(tmp_player)
 124         {
 125                 tmp_player.vote_selection = 0;
 126         }
 127
 128         if (vote_called)
 129         {
 130                 strunzone(vote_called_command);
 131                 strunzone(vote_called_display);
 132                 strunzone(vote_caller_name);
 133         }
 134
 135         vote_called = VOTE_NULL;
 136         vote_caller = world;
 137         vote_caller_name = string_null;
 138         vote_endtime = 0;
 139
 140         vote_called_command = string_null;
 141         vote_called_display = string_null;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 void VoteCount(float first_count)
 206 {
 207         // declarations
 208         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 209
 210         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 211             || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 212             || (autocvar_sv_vote_nospectators == 0));
 213
 214         float vote_player_count = 0, notvoters = 0;
 215         float vote_real_player_count = 0, vote_real_accept_count = 0;
 216         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 217         float vote_needed_of_voted, final_needed_votes;
 218         float vote_factor_overall, vote_factor_of_voted;
 219
 220         entity tmp_player;
 221
 222         Nagger_VoteCountChanged();
 223
 224         // add up all the votes from each connected client
 225         FOR_EACH_REALCLIENT(tmp_player)
 226         {
 227                 ++vote_player_count;
 228                 if (IS_PLAYER(tmp_player))   ++vote_real_player_count;
 229                 switch (tmp_player.vote_selection)
 230                 {
 231                         case VOTE_SELECT_REJECT:
 232                         { ++vote_reject_count;
 233                           { if (IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break;
 234                         }
 235                         case VOTE_SELECT_ACCEPT:
 236                         { ++vote_accept_count;
 237                           { if (IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break;
 238                         }
 239                         case VOTE_SELECT_ABSTAIN:
 240                         { ++vote_abstain_count;
 241                           { if (IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break;
 242                         }
 243                         default: break;
 244                 }
 245         }
 246
 247         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 248         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 249         {
 250                 if (vote_caller)   vote_caller.vote_waittime = 0;
 251                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 252                 VoteReset();
 253                 return;
 254         }
 255
 256         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 257         if (!spectators_allowed && (vote_real_player_count > 0))
 258         {
 259                 vote_accept_count = vote_real_accept_count;
 260                 vote_reject_count = vote_real_reject_count;
 261                 vote_abstain_count = vote_real_abstain_count;
 262                 vote_player_count = vote_real_player_count;
 263         }
 264
 265         // people who have no opinion in any way :D
 266         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 267
 268         // determine the goal for the vote to be passed or rejected normally
 269         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 270         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 271
 272         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 273         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 274         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 275
 276         // are there any players at all on the server? it could be an admin vote
 277         if (vote_player_count == 0 && first_count)
 278         {
 279                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 280                 VoteAccept();
 281                 return;
 282         }
 283
 284         // since there ARE players, finally calculate the result of the vote
 285         if (vote_accept_count >= vote_needed_overall)
 286         {
 287                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 288                 VoteAccept();
 289                 return;
 290         }
 291
 292         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 293         {
 294                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 295                 VoteReject();
 296                 return;
 297         }
 298
 299         // there is not enough votes in either direction, now lets just calculate what the voters have said
 300         if (time > vote_endtime)
 301         {
 302                 final_needed_votes = vote_needed_overall;
 303
 304                 if (autocvar_sv_vote_majority_factor_of_voted)
 305                 {
 306                         if (vote_accept_count >= vote_needed_of_voted)
 307                         {
 308                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 309                                 VoteAccept();
 310                                 return;
 311                         }
 312
 313                         if (vote_accept_count + vote_reject_count > 0)
 314                         {
 315                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 316                                 VoteReject();
 317                                 return;
 318                         }
 319
 320                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 321                 }
 322
 323                 // it didn't pass or fail, so not enough votes to even make a decision.
 324                 VoteSpam(notvoters, final_needed_votes, "timeout");
 325                 VoteTimeout();
 326         }
 327 }
 328
 329 void VoteThink()
 330 {
 331         if (vote_endtime > 0)        // a vote was called
 332         {
 333                 if (time > vote_endtime) // time is up
 334                         VoteCount(false);
 335         }
 336 }
 337
 338
 339 // =======================
 340 //  Game logic for warmup
 341 // =======================
 342
 343 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 344 void reset_map(bool dorespawn)
 345 {
 346         SELFPARAM();
 347
 348         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
 349
 350         MUTATOR_CALLHOOK(reset_map_global);
 351
 352         for (entity e = world; (e = nextent(e)); )
 353         {
 354                 if (IS_NOT_A_CLIENT(e))
 355                 {
 356                         if (e.reset)
 357                         {
 358                                 WITH(entity, self, e, e.reset(e));
 359                                 continue;
 360                         }
 361                         if (e.team_saved) e.team = e.team_saved;
 362                         if (e.flags & FL_PROJECTILE) remove(e);  // remove any projectiles left
 363                 }
 364         }
 365
 366         // Waypoints and assault start come LAST
 367         for (entity e = world; (e = nextent(e)); )
 368         {
 369                 setself(e);
 370                 if (IS_NOT_A_CLIENT(self))
 371                 {
 372                         if (self.reset2)
 373                         {
 374                                 self.reset2();
 375                                 continue;
 376                         }
 377                 }
 378         }
 379
 380         entity e;
 381         FOR_EACH_PLAYER(e)
 382         if (e.frozen) WITH(entity, self, e, Unfreeze(e));
 383
 384         // Moving the player reset code here since the player-reset depends
 385         // on spawnpoint entities which have to be reset first --blub
 386         if (dorespawn)
 387         {
 388                 if (!MUTATOR_CALLHOOK(reset_map_players))
 389                 {
 390                         FOR_EACH_CLIENT(e)  // reset all players
 391                         {
 392                                 setself(e);
 393                                 /*
 394                                 only reset players if a restart countdown is active
 395                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 396                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 397                                 sv_ready_restart_after_countdown is not used and countdown is still running
 398                                 */
 399                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 400                                 {
 401                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 402                                         if (IS_PLAYER(self))
 403                                         {
 404                                                 // PlayerScore_Clear(self);
 405                                                 self.killcount = 0;
 406                                                 // stop the player from moving so that he stands still once he gets respawned
 407                                                 self.velocity = '0 0 0';
 408                                                 self.avelocity = '0 0 0';
 409                                                 self.movement = '0 0 0';
 410                                                 PutClientInServer();
 411                                         }
 412                                 }
 413                         }
 414
 415                         setself(this);
 416                 }
 417         }
 418 }
 419
 420 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 421 void ReadyRestart_think()
 422 {
 423         SELFPARAM();
 424         restart_mapalreadyrestarted = true;
 425         reset_map(true);
 426         Score_ClearAll();
 427         remove(this);
 428 }
 429
 430 // Forces a restart of the game without actually reloading the map // this is a mess...
 431 void ReadyRestart_force()
 432 {
 433         bprint("^1Server is restarting...\n");
 434
 435         VoteReset();
 436
 437         // clear overtime, we have to decrease timelimit to its original value again.
 438         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 439                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 440         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 441
 442         readyrestart_happened = true;
 443         game_starttime = time + RESTART_COUNTDOWN;
 444
 445         entity tmp_player;
 446
 447         // clear player attributes
 448         FOR_EACH_CLIENT(tmp_player)
 449         {
 450                 tmp_player.alivetime = 0;
 451                 tmp_player.killcount = 0;
 452                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 453         }
 454
 455         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 456
 457         // disable the warmup global for the server
 458         warmup_stage = 0;                // once the game is restarted the game is in match stage
 459
 460         // reset the .ready status of all players (also spectators)
 461         FOR_EACH_REALCLIENT(tmp_player)
 462         {
 463                 tmp_player.ready = false;
 464         }
 465         readycount = 0;
 466         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 467
 468         // lock teams with lockonrestart
 469         if (autocvar_teamplay_lockonrestart && teamplay)
 470         {
 471                 lockteams = true;
 472                 bprint("^1The teams are now locked.\n");
 473         }
 474
 475         // initiate the restart-countdown-announcer entity
 476         if (autocvar_sv_ready_restart_after_countdown)
 477         {
 478                 entity restart_timer = new(restart_timer);
 479                 make_pure(restart_timer);
 480                 restart_timer.think = ReadyRestart_think;
 481                 restart_timer.nextthink = game_starttime;
 482         }
 483
 484         // after a restart every players number of allowed timeouts gets reset, too
 485         if (autocvar_sv_timeout)
 486         {
 487                 FOR_EACH_REALPLAYER(tmp_player)
 488                 {
 489                         tmp_player.allowed_timeouts = autocvar_sv_timeout_number;
 490                 }
 491         }
 492     // reset map immediately if this cvar is not set
 493     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 494         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 495 }
 496
 497 void ReadyRestart()
 498 {
 499         // no assault support yet...
 500         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 501         else localcmd("\nsv_hook_gamerestart\n");
 502
 503         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 504         // Otherwise scores could be manipulated during the countdown.
 505         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 506         ReadyRestart_force();
 507 }
 508
 509 // Count the players who are ready and determine whether or not to restart the match
 510 void ReadyCount()
 511 {
 512         entity tmp_player;
 513         float ready_needed_factor, ready_needed_count;
 514         float t_ready = 0, t_players = 0;
 515
 516         FOR_EACH_REALCLIENT(tmp_player)
 517         {
 518                 if (IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 519                 {
 520                         ++t_players;
 521                         if (tmp_player.ready)   ++t_ready; }
 522         }
 523
 524         readycount = t_ready;
 525
 526         Nagger_ReadyCounted();
 527
 528         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 529         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 530
 531         if (readycount >= ready_needed_count) ReadyRestart();
 532 }
 533
 534
 535 // ======================================
 536 //  Supporting functions for VoteCommand
 537 // ======================================
 538
 539 float Votecommand_check_assignment(entity caller, float assignment)
 540 {
 541         float from_server = (!caller);
 542
 543         if ((assignment == VC_ASGNMNT_BOTH)
 544             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 545             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 546
 547         return false;
 548 }
 549
 550 string VoteCommand_extractcommand(string input, float startpos, float argc)
 551 {
 552         string output;
 553
 554         if ((argc - 1) < startpos) output = "";
 555         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 556
 557         return output;
 558 }
 559
 560 float VoteCommand_checknasty(string vote_command)
 561 {
 562         if ((strstrofs(vote_command, ";", 0) >= 0)
 563             || (strstrofs(vote_command, "\n", 0) >= 0)
 564             || (strstrofs(vote_command, "\r", 0) >= 0)
 565             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 566
 567         return true;
 568 }
 569
 570 float VoteCommand_checkinlist(string vote_command, string list)
 571 {
 572         string l = strcat(" ", list, " ");
 573
 574         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 575
 576         return false;
 577 }
 578
 579 string ValidateMap(string validated_map, entity caller)
 580 {
 581         validated_map = MapInfo_FixName(validated_map);
 582
 583         if (!validated_map)
 584         {
 585                 print_to(caller, "This map is not available on this server.");
 586                 return string_null;
 587         }
 588
 589         if (!autocvar_sv_vote_override_mostrecent && caller)
 590         {
 591                 if (Map_IsRecent(validated_map))
 592                 {
 593                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 594                         return string_null;
 595                 }
 596         }
 597
 598         if (!MapInfo_CheckMap(validated_map))
 599         {
 600                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 601                 return string_null;
 602         }
 603
 604         return validated_map;
 605 }
 606
 607 float VoteCommand_checkargs(float startpos, float argc)
 608 {
 609         float p, q, check, minargs;
 610         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 611         string cmdrestriction = cvar_string(cvarname);  // note: this warns on undefined cvar. We want that.
 612         string charlist, arg;
 613         float checkmate;
 614
 615         if (cmdrestriction == "") return true;
 616
 617         ++startpos;  // skip command name
 618
 619         // check minimum arg count
 620
 621         // 0 args: argc == startpos
 622         // 1 args: argc == startpos + 1
 623         // ...
 624
 625         minargs = stof(cmdrestriction);
 626         if (argc - startpos < minargs) return false;
 627
 628         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 629
 630         for ( ; ; )
 631         {
 632                 // we know that at any time, startpos <= argc - minargs
 633                 // so this means: argc-minargs >= startpos >= argc, thus
 634                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 635                 // have been seen already
 636
 637                 if (startpos >= argc) // all args checked? GOOD
 638                         break;
 639
 640                 if (p < 0)            // no more args? FAIL
 641                 {
 642                         // exception: exactly minargs left, this one included
 643                         if (argc - startpos == minargs) break;
 644
 645                         // otherwise fail
 646                         return false;
 647                 }
 648
 649                 // cut to next semicolon
 650                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 651                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 652                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 653
 654                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 655                 // charlist = strreplace("^^", ";", charlist);
 656
 657                 if (charlist != "")
 658                 {
 659                         // verify the arg only contains allowed chars
 660                         arg = argv(startpos);
 661                         checkmate = strlen(arg);
 662                         for (check = 0; check < checkmate; ++check)
 663                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 664                         // not allowed character
 665                         // all characters are allowed. FINE.
 666                 }
 667
 668                 ++startpos;
 669                 --minargs;
 670                 p = q;
 671         }
 672
 673         return true;
 674 }
 675
 676 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 677 {
 678         string first_command;
 679
 680         first_command = argv(startpos);
 681
 682         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 683             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 684             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 685         );*/
 686
 687         if (
 688             (autocvar_sv_vote_limit > 0)
 689             &&
 690             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 691            )   return false;
 692
 693         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 694
 695         if (!VoteCommand_checkargs(startpos, argc)) return false;
 696
 697         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 698         {
 699                 case "kick":
 700                 case "kickban":    // catch all kick/kickban commands
 701                 {
 702                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 703                         float accepted = VerifyClientEntity(victim, true, false);
 704
 705                         if (accepted > 0)
 706                         {
 707                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 708                                 string command_arguments;
 709
 710                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 711                                 else command_arguments = reason;
 712
 713                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 714                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 715                         }
 716                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 717
 718                         break;
 719                 }
 720
 721                 case "map":
 722                 case "chmap":
 723                 case "gotomap":  // re-direct all map selection commands to gotomap
 724                 {
 725                         vote_command = ValidateMap(argv(startpos + 1), caller);
 726                         if (!vote_command)   return false;
 727                         vote_parsed_command = strcat("gotomap ", vote_command);
 728                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 729
 730                         break;
 731                 }
 732
 733                 default:
 734                 {
 735                         vote_parsed_command = vote_command;
 736                         vote_parsed_display = strzone(strcat("^1", vote_command));
 737
 738                         break;
 739                 }
 740         }
 741
 742         return true;
 743 }
 744
 745
 746 // =======================
 747 //  Command Sub-Functions
 748 // =======================
 749
 750 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 751 {
 752         switch (request)
 753         {
 754                 case CMD_REQUEST_COMMAND:
 755                 {
 756                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 757                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 758                         {
 759                                 print_to(caller, "^1You have already voted.");
 760                         }
 761
 762                         else  // everything went okay, continue changing vote
 763                         {
 764                                 print_to(caller, "^1You abstained from your vote.");
 765                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 766                                 msg_entity = caller;
 767                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 768
 769                         return;
 770                 }
 771
 772                 default:
 773                 case CMD_REQUEST_USAGE:
 774                 {
 775                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 776                         print_to(caller, "  No arguments required.");
 777                         return;
 778                 }
 779         }
 780 }
 781
 782 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 783 {
 784         switch (request)
 785         {
 786                 case CMD_REQUEST_COMMAND:
 787                 {
 788                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 789                             || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 790                             || (autocvar_sv_vote_nospectators == 0));
 791
 792                         float tmp_playercount = 0;
 793                         entity tmp_player;
 794
 795                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 796
 797                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 798                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 799                         {
 800                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 801                         }
 802                         else if (vote_called)
 803                         {
 804                                 print_to(caller, "^1There is already a vote called.");
 805                         }
 806                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 807                         {
 808                                 print_to(caller, "^1Only players can call a vote.");
 809                         }
 810                         else if (caller && !IS_CLIENT(caller))
 811                         {
 812                                 print_to(caller, "^1Only connected clients can vote.");
 813                         }
 814                         else if (timeout_status)
 815                         {
 816                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 817                         }
 818                         else if (caller && (time < caller.vote_waittime))
 819                         {
 820                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 821                         }
 822                         else if (!VoteCommand_checknasty(vote_command))
 823                         {
 824                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 825                         }
 826                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 827                         {
 828                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 829                         }
 830
 831                         else  // everything went okay, continue with calling the vote
 832                         {
 833                                 vote_caller = caller;  // remember who called the vote
 834                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 835                                 vote_called = VOTE_NORMAL;
 836                                 vote_called_command = strzone(vote_parsed_command);
 837                                 vote_called_display = strzone(vote_parsed_display);
 838                                 vote_endtime = time + autocvar_sv_vote_timeout;
 839
 840                                 if (caller)
 841                                 {
 842                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 843                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 844                                         msg_entity = caller;
 845                                 }
 846
 847                                 FOR_EACH_REALCLIENT(tmp_player)
 848                                 {
 849                                         ++tmp_playercount;
 850                                 }
 851                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 852
 853                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 854                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 855                                 Nagger_VoteChanged();
 856                                 VoteCount(true);  // needed if you are the only one
 857                         }
 858
 859                         return;
 860                 }
 861
 862                 default:
 863                 case CMD_REQUEST_USAGE:
 864                 {
 865                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 866                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 867                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 868                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 869                         return;
 870                 }
 871         }
 872 }
 873
 874 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 875 {
 876         switch (request)
 877         {
 878                 case CMD_REQUEST_COMMAND:
 879                 {
 880                         if (autocvar_sv_vote_master)
 881                         {
 882                                 switch (strtolower(argv(2)))
 883                                 {
 884                                         case "do":
 885                                         {
 886                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 887
 888                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 889                                                 else if (!VoteCommand_checknasty(vote_command))
 890                                                 {
 891                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 892                                                 }
 893                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 894                                                 {
 895                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 896                                                 }
 897
 898                                                 else  // everything went okay, proceed with command
 899                                                 {
 900                                                         localcmd(strcat(vote_parsed_command, "\n"));
 901                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 902                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 903                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 904
 905                                                 return;
 906                                         }
 907
 908                                         case "login":
 909                                         {
 910                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 911                                                 else if (caller.vote_master)
 912                                                 {
 913                                                         print_to(caller, "^1You are already logged in as vote master.");
 914                                                 }
 915                                                 else if (autocvar_sv_vote_master_password != argv(3))
 916                                                 {
 917                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 918                                                 }
 919
 920                                                 else  // everything went okay, proceed with giving this player master privilages
 921                                                 {
 922                                                         caller.vote_master = true;
 923                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 924                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 925                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 926
 927                                                 return;
 928                                         }
 929
 930                                         default:  // calling a vote for master
 931                                         {
 932                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 933                                                     || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 934                                                     || (autocvar_sv_vote_nospectators == 0));
 935
 936                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 937                                                 else if (vote_called)
 938                                                 {
 939                                                         print_to(caller, "^1There is already a vote called.");
 940                                                 }
 941                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 942                                                 {
 943                                                         print_to(caller, "^1Only players can call a vote.");
 944                                                 }
 945                                                 else if (timeout_status)
 946                                                 {
 947                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 948                                                 }
 949
 950                                                 else  // everything went okay, continue with creating vote
 951                                                 {
 952                                                         vote_caller = caller;
 953                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 954                                                         vote_called = VOTE_MASTER;
 955                                                         vote_called_command = strzone("XXX");
 956                                                         vote_called_display = strzone("^3master");
 957                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 958
 959                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 960                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 961
 962                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 963                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 964                                                         Nagger_VoteChanged();
 965                                                         VoteCount(true);  // needed if you are the only one
 966                                                 }
 967
 968                                                 return;
 969                                         }
 970                                 }
 971                         }
 972                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 973
 974                         return;
 975                 }
 976
 977                 default:
 978                 case CMD_REQUEST_USAGE:
 979                 {
 980                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 981                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 982                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 983                         return;
 984                 }
 985         }
 986 }
 987
 988 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 989 {
 990         switch (request)
 991         {
 992                 case CMD_REQUEST_COMMAND:
 993                 {
 994                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 995                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 996                         {
 997                                 print_to(caller, "^1You have already voted.");
 998                         }
 999                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1000                         {
1001                                 VoteStop(caller);
1002                         }
1003
1004                         else  // everything went okay, continue changing vote
1005                         {
1006                                 print_to(caller, "^1You rejected the vote.");
1007                                 caller.vote_selection = VOTE_SELECT_REJECT;
1008                                 msg_entity = caller;
1009                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1010
1011                         return;
1012                 }
1013
1014                 default:
1015                 case CMD_REQUEST_USAGE:
1016                 {
1017                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1018                         print_to(caller, "  No arguments required.");
1019                         return;
1020                 }
1021         }
1022 }
1023
1024 void VoteCommand_status(float request, entity caller)  // BOTH
1025 {
1026         switch (request)
1027         {
1028                 case CMD_REQUEST_COMMAND:
1029                 {
1030                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1031                         else print_to(caller, "^1No vote called.");
1032
1033                         return;
1034                 }
1035
1036                 default:
1037                 case CMD_REQUEST_USAGE:
1038                 {
1039                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1040                         print_to(caller, "  No arguments required.");
1041                         return;
1042                 }
1043         }
1044 }
1045
1046 void VoteCommand_stop(float request, entity caller)  // BOTH
1047 {
1048         switch (request)
1049         {
1050                 case CMD_REQUEST_COMMAND:
1051                 {
1052                         if (!vote_called)   print_to(caller, "^1No vote called.");
1053                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1054                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1055                         return;
1056                 }
1057
1058                 default:
1059                 case CMD_REQUEST_USAGE:
1060                 {
1061                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1062                         print_to(caller, "  No arguments required.");
1063                         return;
1064                 }
1065         }
1066 }
1067
1068 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1069 {
1070         switch (request)
1071         {
1072                 case CMD_REQUEST_COMMAND:
1073                 {
1074                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1075                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1076                         {
1077                                 print_to(caller, "^1You have already voted.");
1078                         }
1079
1080                         else  // everything went okay, continue changing vote
1081                         {
1082                                 print_to(caller, "^1You accepted the vote.");
1083                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1084                                 msg_entity = caller;
1085                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1086
1087                         return;
1088                 }
1089
1090                 default:
1091                 case CMD_REQUEST_USAGE:
1092                 {
1093                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1094                         print_to(caller, "  No arguments required.");
1095                         return;
1096                 }
1097         }
1098 }
1099
1100 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1101 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1102 void VoteCommand_(float request)
1103 {
1104     switch(request)
1105     {
1106         case CMD_REQUEST_COMMAND:
1107         {
1108
1109             return;
1110         }
1111
1112         default:
1113         case CMD_REQUEST_USAGE:
1114         {
1115             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1116             print_to(caller, "  No arguments required.");
1117             return;
1118         }
1119     }
1120 }
1121 */
1122
1123
1124 // ================================
1125 //  Macro system for vote commands
1126 // ================================
1127
1128 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1129 #define VOTE_COMMANDS(request, caller, arguments, command) \
1130         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1131         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1132         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1133         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1134         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1135         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1136         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1137         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1138         /* nothing */
1139
1140 void VoteCommand_macro_help(entity caller, float argc)
1141 {
1142         string command_origin = GetCommandPrefix(caller);
1143
1144         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1145         {
1146                 print_to(caller, "\nVoting commands:\n");
1147                 #define VOTE_COMMAND(name, function, description, assignment) \
1148                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1149
1150                 VOTE_COMMANDS(0, caller, 0, "");
1151 #undef VOTE_COMMAND
1152
1153                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1154                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1155                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1156         }
1157         else  // usage for individual command
1158         {
1159                 #define VOTE_COMMAND(name, function, description, assignment) \
1160                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1161
1162                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1163 #undef VOTE_COMMAND
1164         }
1165 }
1166
1167 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1168 {
1169         #define VOTE_COMMAND(name, function, description, assignment) \
1170                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1171
1172         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1173 #undef VOTE_COMMAND
1174
1175         return false;
1176 }
1177
1178
1179 // ======================================
1180 //  Main function handling vote commands
1181 // ======================================
1182
1183 void VoteCommand(float request, entity caller, float argc, string vote_command)
1184 {
1185         // Guide for working with argc arguments by example:
1186         // argc:   1    - 2      - 3     - 4
1187         // argv:   0    - 1      - 2     - 3
1188         // cmd     vote - master - login - password
1189
1190         switch (request)
1191         {
1192                 case CMD_REQUEST_COMMAND:
1193                 {
1194                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1195                 }
1196
1197                 default:
1198                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1199                 case CMD_REQUEST_USAGE:
1200                 {
1201                         VoteCommand_macro_help(caller, argc);
1202                         return;
1203                 }
1204         }
1205 }