qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         return TRUE;
  18 }
  19
  20 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, entity dmgowner)
  21 {
  22         // TODO maybe call this from non-edgedamage too?
  23         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  24
  25         entity e;
  26
  27         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  28                 deathtype |= 0x8000;
  29
  30         e = spawn();
  31         setorigin(e, org);
  32         e.projectiledeathtype = deathtype;
  33         e.dmg = coredamage;
  34         e.dmg_edge = edgedamage;
  35         e.dmg_radius = rad;
  36         e.dmg_force = vlen(force);
  37         e.velocity = force;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  42 }
  43
  44 #define DAMAGE_CENTERPRINT_SPACER NEWLINES
  45
  46 float checkrules_firstblood;
  47
  48 float yoda;
  49 float damage_goodhits;
  50 float damage_gooddamage;
  51 float headshot;
  52 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  53
  54 .float dmg_team;
  55 .float teamkill_complain;
  56 .float teamkill_soundtime;
  57 .entity teamkill_soundsource;
  58 .entity pusher;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teams_matter)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '0.6 0 0' * targ.mins_x + '0 0.6 0' * targ.mins_y + '0 0 1' * (1.3 * targ.view_ofs_z - 0.3 * targ.maxs_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.6 0 0' * targ.maxs_x + '0 0.6 0' * targ.maxs_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 void GiveFrags (entity attacker, entity targ, float f)
 106 {
 107         float w;
 108
 109         // TODO route through PlayerScores instead
 110         if(gameover) return;
 111
 112         if(f < 0)
 113         {
 114                 if(targ == attacker)
 115                 {
 116                         // suicide
 117                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 118                 }
 119                 else
 120                 {
 121                         // teamkill
 122                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 123                 }
 124         }
 125         else
 126         {
 127                 // regular frag
 128                 PlayerScore_Add(attacker, SP_KILLS, 1);
 129         }
 130
 131         PlayerScore_Add(targ, SP_DEATHS, 1);
 132
 133         if(g_arena || g_ca)
 134                 if(cvar("g_arena_roundbased"))
 135                         return;
 136
 137         if(targ != attacker) // not for suicides
 138         if(g_weaponarena_random)
 139         {
 140                 // after a frag, choose another random weapon set
 141                 if(inWarmupStage)
 142                         w = warmup_start_weapons;
 143                 else
 144                         w = start_weapons;
 145
 146                 attacker.weapons = randombits(w - (w & W_WeaponBit(attacker.weapon)), g_weaponarena_random, TRUE);
 147                 if(attacker.weapons < 0)
 148                 {
 149                         // error from randombits: no weapon available
 150                         // this means we can just give ALL weapons
 151                         attacker.weapons = w;
 152                 }
 153                 if not(attacker.weapons & W_WeaponBit(attacker.weapon))
 154                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 155         }
 156
 157         // FIXME fix the mess this is (we have REAL points now!)
 158         entity oldself;
 159         oldself = self;
 160         self = attacker;
 161         frag_attacker = attacker;
 162         frag_target = targ;
 163         frag_score = f;
 164         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 165         {
 166                 f = frag_score;
 167                 self = oldself;
 168         }
 169         else
 170         {
 171                 self = oldself;
 172                 if(g_runematch)
 173                 {
 174                         f = RunematchHandleFrags(attacker, targ, f);
 175                 }
 176                 else if(g_lms)
 177                 {
 178                         // remove a life
 179                         float tl;
 180                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 181                         if(tl < lms_lowest_lives)
 182                                 lms_lowest_lives = tl;
 183                         if(tl <= 0)
 184                         {
 185                                 if(!lms_next_place)
 186                                         lms_next_place = player_count;
 187                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 188                                 --lms_next_place;
 189                         }
 190                         f = 0;
 191                 }
 192                 else if(g_ctf)
 193                 {
 194                         if(g_ctf_ignore_frags)
 195                                 f = 0;
 196                 }
 197         }
 198
 199         attacker.totalfrags += f;
 200
 201         if(f)
 202                 UpdateFrags(attacker, f);
 203 }
 204
 205 string AppendItemcodes(string s, entity player)
 206 {
 207         float w;
 208         w = player.weapon;
 209         //if(w == 0)
 210         //      w = player.switchweapon;
 211         if(w == 0)
 212                 w = player.cnt; // previous weapon!
 213         s = strcat(s, ftos(w));
 214         if(time < player.strength_finished)
 215                 s = strcat(s, "S");
 216         if(time < player.invincible_finished)
 217                 s = strcat(s, "I");
 218         if(player.flagcarried != world)
 219                 s = strcat(s, "F");
 220         if(player.BUTTON_CHAT)
 221                 s = strcat(s, "T");
 222         if(player.kh_next)
 223                 s = strcat(s, "K");
 224         if(player.runes)
 225                 s = strcat(s, "|", ftos(player.runes));
 226         return s;
 227 }
 228
 229 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 230 {
 231         string s;
 232         if(!cvar("sv_eventlog"))
 233                 return;
 234         s = strcat(":kill:", mode);
 235         s = strcat(s, ":", ftos(killer.playerid));
 236         s = strcat(s, ":", ftos(killed.playerid));
 237         s = strcat(s, ":type=", ftos(deathtype));
 238         s = strcat(s, ":items=");
 239         s = AppendItemcodes(s, killer);
 240         if(killed != killer)
 241         {
 242                 s = strcat(s, ":victimitems=");
 243                 s = AppendItemcodes(s, killed);
 244         }
 245         GameLogEcho(s);
 246 }
 247
 248 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 249 {
 250         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 251         WriteByte(MSG_ALL, TE_CSQC_NOTIFY);
 252         WriteByte(MSG_ALL, CSQC_KILLNOTIFY);
 253         WriteString(MSG_ALL, s1);
 254         WriteString(MSG_ALL, s2);
 255         WriteString(MSG_ALL, s3);
 256         WriteShort(MSG_ALL, msg);
 257         WriteByte(MSG_ALL, type);
 258 }
 259
 260 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 261 void Send_CSQC_Centerprint(entity e, string s1, string s2, float msg, float type)
 262 {
 263         if (clienttype(e) == CLIENTTYPE_REAL)
 264         {
 265                 msg_entity = e;
 266                 WRITESPECTATABLE_MSG_ONE({
 267                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 268                         WriteByte(MSG_ONE, TE_CSQC_NOTIFY);
 269                         WriteByte(MSG_ONE, CSQC_CENTERPRINT);
 270                         WriteString(MSG_ONE, s1);
 271                         WriteString(MSG_ONE, s2);
 272                         WriteShort(MSG_ONE, msg);
 273                         WriteByte(MSG_ONE, type);
 274                 });
 275         }
 276 }
 277
 278 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 279 {
 280         string  s, a, msg;
 281         float p, w, type;
 282
 283         if (targ.classname == "player" || targ.classname == "corpse")
 284         {
 285                 if (targ.classname == "corpse")
 286                         s = "A corpse";
 287                 else
 288                         s = targ.netname;
 289
 290                 a = attacker.netname;
 291
 292                 if (targ == attacker) // suicides
 293                 {
 294                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 295                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 296                         Send_CSQC_Centerprint(targ, msg, "", deathtype, MSG_SUICIDE);
 297
 298                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 299                         {
 300                                 LogDeath("suicide", deathtype, targ, targ);
 301                                 GiveFrags(attacker, targ, -1);
 302                         }
 303
 304                         if (targ.killcount > 2)
 305                                 msg = ftos(targ.killcount);
 306                         if(teams_matter && deathtype == DEATH_MIRRORDAMAGE)
 307                         {
 308                                 if(attacker.team == COLOR_TEAM1)
 309                                         deathtype = KILL_TEAM_RED;
 310                                 else
 311                                         deathtype = KILL_TEAM_BLUE;
 312                         }
 313
 314                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 315                 }
 316                 else if (attacker.classname == "player" || attacker.classname == "gib")
 317                 {
 318                         if(teams_matter && attacker.team == targ.team)
 319                         {
 320                                 if(attacker.team == COLOR_TEAM1)
 321                                         type = KILL_TEAM_RED;
 322                                 else
 323                                         type = KILL_TEAM_BLUE;
 324
 325                                 GiveFrags(attacker, targ, -1);
 326
 327                                 Send_CSQC_Centerprint(attacker, s, "", type, MSG_KILL);
 328
 329                                 if (targ.killcount > 2) {
 330                                         msg = ftos(targ.killcount);
 331                                 }
 332
 333                                 if (attacker.killcount > 2) {
 334                                         msg = ftos(attacker.killcount);
 335                                         type = KILL_TEAM_SPREE;
 336                                 }
 337                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 338
 339                                 attacker.killcount = 0;
 340
 341                                 LogDeath("tk", deathtype, attacker, targ);
 342                         }
 343                         else
 344                         {
 345                                 string blood_message, victim_message;
 346                                 if (!checkrules_firstblood)
 347                                 {
 348                                         checkrules_firstblood = TRUE;
 349                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 350                                         // TODO: make these print a newline if they dont
 351                                         Send_CSQC_Centerprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 352                                         Send_CSQC_Centerprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 353                                 }
 354
 355                                 if((cvar("sv_fragmessage_information_typefrag")) && (targ.BUTTON_CHAT)) {
 356                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_TYPEFRAG, MSG_KILL);
 357                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 358                                 } else {
 359                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_FRAG, MSG_KILL);
 360                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_FRAGGED, MSG_KILL);
 361                                 }
 362
 363                                 attacker.taunt_soundtime = time + 1;
 364
 365                                 // TODO: fix this?
 366                                         if (deathtype == DEATH_CUSTOM)
 367                                                 msg = strcat(deathmessage, " by ^1", msg);
 368                                         else if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 369                                         {
 370                                                 msg = ftos(strstrofs(inflictor.message2, "#", 0));
 371                                         }
 372                                         Send_KillNotification(s, a, msg, deathtype, MSG_KILL);
 373
 374                                 if(g_ctf && targ.flagcarried)
 375                                 {
 376                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
 377                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
 378                                         GiveFrags(attacker, targ, 0); // for logging
 379                                 }
 380                                 else
 381                                         GiveFrags(attacker, targ, 1);
 382
 383                                 if (targ.killcount > 2) {
 384                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 385                                 }
 386
 387                                 attacker.killcount = attacker.killcount + 1;
 388
 389                                 if (attacker.killcount > 2) {
 390                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 391                                 }
 392
 393                                 LogDeath("frag", deathtype, attacker, targ);
 394
 395                                 if (attacker.killcount == 3)
 396                                 {
 397                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 398                                         AnnounceTo(attacker, "03kills");
 399                                 }
 400                                 else if (attacker.killcount == 5)
 401                                 {
 402                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 403                                         AnnounceTo(attacker, "05kills");
 404                                 }
 405                                 else if (attacker.killcount == 10)
 406                                 {
 407                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 408                                         AnnounceTo(attacker, "10kills");
 409                                 }
 410                                 else if (attacker.killcount == 15)
 411                                 {
 412                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 413                                         AnnounceTo(attacker, "15kills");
 414                                 }
 415                                 else if (attacker.killcount == 20)
 416                                 {
 417                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 418                                         AnnounceTo(attacker, "20kills");
 419                                 }
 420                                 else if (attacker.killcount == 25)
 421                                 {
 422                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 423                                         AnnounceTo(attacker, "25kills");
 424                                 }
 425                                 else if (attacker.killcount == 30)
 426                                 {
 427                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 428                                         AnnounceTo(attacker, "30kills");
 429                                 }
 430                         }
 431                 }
 432                 else
 433                 {
 434                         Send_CSQC_Centerprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 435                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 436                                 msg = inflictor.message;
 437                         else if (deathtype == DEATH_CUSTOM)
 438                                 msg = deathmessage;
 439
 440                         GiveFrags(targ, targ, -1);
 441                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 442                                 AnnounceTo(targ, "botlike");
 443                         }
 444                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 445
 446                         if (targ.killcount > 2)
 447                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 448
 449                         LogDeath("accident", deathtype, targ, targ);
 450                 }
 451
 452                 targ.death_origin = targ.origin;
 453                 if(targ != attacker)
 454                         targ.killer_origin = attacker.origin;
 455
 456                 // FIXME: this should go in PutClientInServer
 457                 if (targ.killcount)
 458                         targ.killcount = 0;
 459         }
 460 }
 461
 462 // these are updated by each Damage call for use in button triggering and such
 463 entity damage_targ;
 464 entity damage_inflictor;
 465 entity damage_attacker;
 466
 467 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 468 {
 469         float mirrordamage;
 470         float mirrorforce;
 471         float teamdamage0;
 472         entity attacker_save;
 473         mirrordamage = 0;
 474         mirrorforce = 0;
 475
 476         if (gameover || targ.killcount == -666)
 477                 return;
 478
 479         local entity oldself;
 480         oldself = self;
 481         self = targ;
 482         damage_targ = targ;
 483         damage_inflictor = inflictor;
 484         damage_attacker = attacker;
 485                 attacker_save = attacker;
 486
 487         if(targ.classname == "player")
 488                 if(targ.hook)
 489                         if(targ.hook.aiment)
 490                                 if(targ.hook.aiment == attacker)
 491                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 492
 493         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 494         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 495         {
 496                 if(targ.classname == "player")
 497                         if not(IsDifferentTeam(targ, attacker))
 498                         {
 499                                 self = oldself;
 500                                 return;
 501                         }
 502         }
 503
 504         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 505         {
 506                 // These are ALWAYS lethal
 507                 // No damage modification here
 508                 // Instead, prepare the victim for his death...
 509                 targ.armorvalue = 0;
 510                 targ.spawnshieldtime = 0;
 511                 targ.health = 0.9; // this is < 1
 512                 targ.flags -= targ.flags & FL_GODMODE;
 513                 damage = 100000;
 514         }
 515         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 516         {
 517                 // no processing
 518         }
 519         else
 520         {
 521                 if (targ.classname == "player")
 522                 if (attacker.classname == "player")
 523                 if (!targ.isbot)
 524                 if (attacker.isbot)
 525                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 526
 527                 // nullify damage if teamplay is on
 528                 if(deathtype != DEATH_TELEFRAG)
 529                 if(attacker.classname == "player")
 530                 {
 531                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 532                         {
 533                                 damage = 0;
 534                                 force = '0 0 0';
 535                         }
 536                         else if(attacker.team == targ.team)
 537                         {
 538                                 if(teamplay == 1)
 539                                         damage = 0;
 540                                 else if(attacker != targ)
 541                                 {
 542                                         if(teamplay == 3)
 543                                                 damage = 0;
 544                                         else if(teamplay == 4)
 545                                         {
 546                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 547                                                 {
 548                                                         teamdamage0 = max(attacker.dmg_team, cvar("g_teamdamage_threshold"));
 549                                                         attacker.dmg_team = attacker.dmg_team + damage;
 550                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 551                                                                 mirrordamage = cvar("g_mirrordamage") * (attacker.dmg_team - teamdamage0);
 552                                                         mirrorforce = cvar("g_mirrordamage") * vlen(force);
 553                                                         if(g_minstagib)
 554                                                         {
 555                                                                 if(cvar("g_friendlyfire") == 0)
 556                                                                         damage = 0;
 557                                                         }
 558                                                         else if(g_ca)
 559                                                                 damage = 0;
 560                                                         else
 561                                                                 damage = cvar("g_friendlyfire") * damage;
 562                                                         // mirrordamage will be used LATER
 563                                                 }
 564                                                 else
 565                                                         damage = 0;
 566                                         }
 567                                 }
 568                         }
 569                 }
 570
 571                 if(targ.classname == "player")
 572                 if(attacker.classname == "player")
 573                 if(attacker != targ)
 574                 {
 575                         targ.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 576                         attacker.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 577                 }
 578
 579                 if(targ.classname == "player")
 580                 if (g_minstagib)
 581                 {
 582                         if ((deathtype == DEATH_FALL)  ||
 583                                 (deathtype == DEATH_DROWN) ||
 584                                 (deathtype == DEATH_SLIME) ||
 585                                 (deathtype == DEATH_LAVA)  ||
 586                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 587                         {
 588                                 self = oldself;
 589                                 return;
 590                         }
 591                         if(damage > 0)
 592                             damage = 10000;
 593                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 594                         {
 595                                 targ.armorvalue -= 1;
 596                                 centerprint(targ, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(targ.armorvalue)));
 597                                 damage = 0;
 598                                 targ.hitsound += 1;
 599                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 600                         }
 601                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 602                         {
 603                                 damage = 0;
 604                                 if (targ != attacker)
 605                                 {
 606                                         if ((targ.health >= 1) && (targ.classname == "player"))
 607                                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "Secondary fire inflicts no damage!"));
 608                                         damage = 0;
 609                                         mirrordamage = 0;
 610                                         force = '0 0 0';
 611                                         // keep mirrorforce
 612                                         attacker = targ;
 613                                 }
 614                         }
 615                 }
 616
 617                 if not(DEATH_ISSPECIAL(deathtype))
 618                 {
 619                         damage *= g_weapondamagefactor;
 620                         mirrordamage *= g_weapondamagefactor;
 621                         force = force * g_weaponforcefactor;
 622                         mirrorforce *= g_weaponforcefactor;
 623                 }
 624
 625                 // apply strength multiplier
 626                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 627                 {
 628                         if(targ == attacker)
 629                         {
 630                                 damage = damage * cvar("g_balance_powerup_strength_selfdamage");
 631                                 force = force * cvar("g_balance_powerup_strength_selfforce");
 632                         }
 633                         else
 634                         {
 635                                 damage = damage * cvar("g_balance_powerup_strength_damage");
 636                                 force = force * cvar("g_balance_powerup_strength_force");
 637                         }
 638                 }
 639
 640                 // apply invincibility multiplier
 641                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 642                         damage = damage * cvar("g_balance_powerup_invincible_takedamage");
 643
 644                 if (targ == attacker)
 645                 {
 646                         if(g_ca || (g_cts && !cvar("g_cts_selfdamage")))
 647                                 damage = 0;
 648                         else
 649                                 damage = damage * cvar("g_balance_selfdamagepercent");  // Partial damage if the attacker hits himself
 650                 }
 651
 652                 // CTF: reduce damage/force
 653                 if(g_ctf)
 654                 if(targ == attacker)
 655                 if(targ.flagcarried)
 656                 {
 657                         damage = damage * cvar("g_ctf_flagcarrier_selfdamage");
 658                         force = force * cvar("g_ctf_flagcarrier_selfforce");
 659                 }
 660
 661                 if(g_runematch)
 662                 {
 663                         // apply strength rune
 664                         if (attacker.runes & RUNE_STRENGTH)
 665                         {
 666                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 667                                 {
 668                                         damage = damage * cvar("g_balance_rune_strength_combo_damage");
 669                                         force = force * cvar("g_balance_rune_strength_combo_force");
 670                                 }
 671                                 else
 672                                 {
 673                                         damage = damage * cvar("g_balance_rune_strength_damage");
 674                                         force = force * cvar("g_balance_rune_strength_force");
 675                                 }
 676                         }
 677                         else if (attacker.runes & CURSE_WEAK)
 678                         {
 679                                 damage = damage * cvar("g_balance_curse_weak_damage");
 680                                 force = force * cvar("g_balance_curse_weak_force");
 681                         }
 682
 683                         // apply defense rune
 684                         if (targ.runes & RUNE_DEFENSE)
 685                         {
 686                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 687                                         damage = damage * cvar("g_balance_rune_defense_combo_takedamage");
 688                                 else
 689                                         damage = damage * cvar("g_balance_rune_defense_takedamage");
 690                         }
 691                         else if (targ.runes & CURSE_VULNER)
 692                                 damage = damage * cvar("g_balance_curse_vulner_takedamage");
 693                 }
 694
 695                 // count the damage
 696                 if(attacker)
 697                 if(!targ.deadflag)
 698                 if(targ.takedamage == DAMAGE_AIM)
 699                 if(targ != attacker)
 700                 {
 701                         if(targ.classname == "player")
 702                         {
 703                                 // HEAD SHOT:
 704                                 // find height of hit on player axis
 705                                 // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 706                                 vector headmins, headmaxs, org;
 707                                 org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 708                                 headmins = org + GetHeadshotMins(targ);
 709                                 headmaxs = org + GetHeadshotMaxs(targ);
 710                                 if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 711                                 {
 712                                         deathtype |= HITTYPE_HEADSHOT;
 713                                 }
 714                         }
 715                         else if(targ.classname == "turret_head")
 716                         {
 717                                 deathtype |= HITTYPE_HEADSHOT;
 718                         }
 719                         if(deathtype & HITTYPE_HEADSHOT)
 720                                 damage *= 1 + damage_headshotbonus;
 721
 722                         if(targ.classname == "player")
 723                         {
 724                                 if(IsDifferentTeam(targ, attacker))
 725                                 {
 726                                         if(damage > 0)
 727                                         {
 728                                                 if(targ.BUTTON_CHAT)
 729                                                         attacker.typehitsound += 1;
 730                                                 else
 731                                                         attacker.hitsound += 1;
 732
 733                                                 damage_goodhits += 1;
 734                                                 damage_gooddamage += damage;
 735
 736                                                 if not(DEATH_ISSPECIAL(deathtype))
 737                                                 {
 738                                                         if(!g_minstagib)
 739                                                         if(IsFlying(targ))
 740                                                                 yoda = 1;
 741
 742                                                         if(g_minstagib)
 743                                                         if(targ.items & IT_STRENGTH)
 744                                                                 yoda = 1;
 745
 746                                                         if(deathtype & HITTYPE_HEADSHOT)
 747                                                                 headshot = 1;
 748                                                 }
 749                                         }
 750                                 }
 751                                 else
 752                                 {
 753                                         if(deathtype != DEATH_FIRE)
 754                                                 attacker.typehitsound += 1;
 755                                         if(mirrordamage > 0)
 756                                                 if(time > attacker.teamkill_complain)
 757                                                 {
 758                                                         attacker.teamkill_complain = time + 5;
 759                                                         attacker.teamkill_soundtime = time + 0.4;
 760                                                         attacker.teamkill_soundsource = targ;
 761                                                 }
 762                                 }
 763                         }
 764                 }
 765         }
 766
 767         // apply push
 768         if (self.damageforcescale)
 769         if (vlen(force))
 770         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 771         {
 772                 self.velocity = self.velocity + self.damageforcescale * force;
 773                 self.flags &~= FL_ONGROUND;
 774                 UpdateCSQCProjectile(self);
 775         }
 776         // apply damage
 777         if (damage != 0 || (self.damageforcescale && vlen(force)))
 778         if (self.event_damage)
 779                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 780         self = oldself;
 781
 782         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 783         {
 784                 // Savage: vampire mode
 785                 if (g_vampire)
 786                 if (!g_minstagib)
 787                 if (time >= self.spawnshieldtime)
 788                 {
 789                         attacker.health += damage;
 790                 }
 791                 if(g_runematch)
 792                 {
 793                         if (attacker.runes & RUNE_VAMPIRE)
 794                         {
 795                         // apply vampire rune
 796                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 797                                 {
 798                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb");
 799                                         attacker.health = bound(
 800                                                 cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 40
 801                                                 attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb"),
 802                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 803                                 }
 804                                 else
 805                                 {
 806                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_absorb");
 807                                         attacker.health = bound(
 808                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 809                                                                                         // empathy won't let you gain health in the same way...
 810                                                 attacker.health + damage * cvar("g_balance_rune_vampire_absorb"),
 811                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 812                                         }
 813                         }
 814                         // apply empathy curse
 815                         else if (attacker.runes & CURSE_EMPATHY)
 816                         {
 817                                 attacker.health = bound(
 818                                         cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 20
 819                                         attacker.health + damage * cvar("g_balance_curse_empathy_takedamage"),
 820                                         attacker.health);
 821                         }
 822                 }
 823         }
 824
 825         // apply mirror damage if any
 826         if(mirrordamage > 0 || mirrorforce > 0)
 827         {
 828                 attacker = attacker_save;
 829                 if(g_minstagib)
 830                         if(mirrordamage > 0)
 831                         {
 832                                 // just lose extra LIVES, don't kill the player for mirror damage
 833                                 if(attacker.armorvalue > 0)
 834                                 {
 835                                         attacker.armorvalue = attacker.armorvalue - 1;
 836                                         centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 837                                         attacker.hitsound += 1;
 838                                 }
 839                                 mirrordamage = 0;
 840                         }
 841                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 842                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 843         }
 844 }
 845
 846 vector NearestPointOnBox(entity box, vector org)
 847 {
 848         vector m1, m2, nearest;
 849
 850         m1 = box.mins + box.origin;
 851         m2 = box.maxs + box.origin;
 852
 853         nearest_x = bound(m1_x, org_x, m2_x);
 854         nearest_y = bound(m1_y, org_y, m2_y);
 855         nearest_z = bound(m1_z, org_z, m2_z);
 856
 857         return nearest;
 858 }
 859
 860 void Damage_RecordDamage(entity attacker, float deathtype, float damage)
 861 {
 862         float weaponid;
 863         weaponid = DEATH_WEAPONOF(deathtype);
 864
 865         if not(inWarmupStage)
 866         if (weaponid)
 867         if ((clienttype(attacker) == CLIENTTYPE_REAL) | (clienttype(attacker) == CLIENTTYPE_BOT)) {
 868                 attacker.stats_hit[weaponid - 1] += damage;
 869                 attacker.stat_hit = weaponid + 64 * floor(attacker.stats_hit[weaponid - 1]);
 870         }
 871 }
 872
 873 float RadiusDamage_running;
 874 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 875 // Returns total damage applies to creatures
 876 {
 877         entity  targ;
 878         float   finaldmg;
 879         float   power;
 880         vector  blastorigin;
 881         vector  force;
 882         vector  diff;
 883         vector  center;
 884         vector  nearest;
 885         float   total_damage_to_creatures;
 886         entity  next;
 887         float   tfloordmg;
 888         float   tfloorforce;
 889
 890         float stat_damagedone;
 891         float stat_maxdamage;
 892
 893         if(RadiusDamage_running)
 894         {
 895                 string save;
 896                 print("RadiusDamage called recursively!\n");
 897                 print("Expect stuff to go HORRIBLY wrong.\n");
 898                 print("Causing a stack trace...\n");
 899                 save = cvar_string("prvm_backtraceforwarnings");
 900                 cvar_set("prvm_backtraceforwarnings", "1");
 901                 fclose(-1); // calls VM_Warning
 902                 cvar_set("prvm_backtraceforwarnings", save);
 903                 return 0;
 904         }
 905
 906         RadiusDamage_running = 1;
 907
 908         tfloordmg = cvar("g_throughfloor_damage");
 909         tfloorforce = cvar("g_throughfloor_force");
 910
 911         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 912         total_damage_to_creatures = 0;
 913
 914         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 915         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 916         {
 917                 force = inflictor.velocity;
 918                 if(vlen(force) == 0)
 919                         force = '0 0 -1';
 920                 else
 921                         force = normalize(force);
 922                 if(forceintensity >= 0)
 923                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, attacker);
 924                 else
 925                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, attacker);
 926         }
 927
 928         stat_damagedone = 0;
 929         stat_maxdamage = 0;
 930
 931         targ = WarpZone_FindRadius (blastorigin, rad, FALSE);
 932         while (targ)
 933         {
 934                 next = targ.chain;
 935                 if (targ != inflictor)
 936                         if (ignore != targ) if(targ.takedamage)
 937                         {
 938                                 // LordHavoc: measure distance to nearest point on target (not origin)
 939                                 // (this guarentees 100% damage on a touch impact)
 940                                 nearest = targ.WarpZone_findradius_nearest;
 941                                 diff = targ.WarpZone_findradius_dist;
 942                                 // round up a little on the damage to ensure full damage on impacts
 943                                 // and turn the distance into a fraction of the radius
 944                                 power = 1 - ((vlen (diff) - 2) / rad);
 945                                 //bprint(" ");
 946                                 //bprint(ftos(power));
 947                                 //if (targ == attacker)
 948                                 //      print(ftos(power), "\n");
 949                                 if (power > 0)
 950                                 {
 951                                         if (power > 1)
 952                                                 power = 1;
 953                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 954                                         if (finaldmg > 0)
 955                                         {
 956                                                 local float a;
 957                                                 local float c;
 958                                                 local float hits;
 959                                                 local float total;
 960                                                 local float hitratio;
 961                                                 local vector hitloc;
 962                                                 local vector myblastorigin;
 963                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 964                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
 965                                                 // if it's a player, use the view origin as reference
 966                                                 if (targ.classname == "player")
 967                                                         center = targ.origin + targ.view_ofs;
 968                                                 force = normalize(center - myblastorigin);
 969                                                 force = force * (finaldmg / coredamage) * forceintensity;
 970                                                 // test line of sight to multiple positions on box,
 971                                                 // and do damage if any of them hit
 972                                                 hits = 0;
 973                                                 if (targ.classname == "player")
 974                                                         total = ceil(bound(1, finaldmg, 50));
 975                                                 else
 976                                                         total = ceil(bound(1, finaldmg/10, 5));
 977                                                 hitloc = nearest;
 978                                                 c = 0;
 979                                                 while (c < total)
 980                                                 {
 981                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 982                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 983                                                         if (trace_fraction == 1 || trace_ent == targ)
 984                                                         {
 985                                                                 hits = hits + 1;
 986                                                                 if (hits > 1)
 987                                                                         hitloc = hitloc + nearest;
 988                                                                 else
 989                                                                         hitloc = nearest;
 990                                                         }
 991                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 992                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 993                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 994                                                         c = c + 1;
 995                                                 }
 996                                                 nearest = hitloc * (1 / max(1, hits));
 997                                                 hitratio = (hits / total);
 998                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 999                                                 finaldmg = finaldmg * a;
1000                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1001                                                 force = force * a;
1002                                                 //if (targ == attacker)
1003                                                 //{
1004                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1005                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1006                                                 //      print(" (", ftos(a), ")\n");
1007                                                 //}
1008                                                 if(hits || tfloordmg || tfloorforce)
1009                                                 {
1010                                                         if(targ.iscreature)
1011                                                         {
1012                                                                 total_damage_to_creatures += finaldmg;
1013
1014                                                                 if(targ.flags & FL_CLIENT)
1015                                                                 if(targ.deadflag == DEAD_NO)
1016                                                                 if(targ != attacker)
1017                                                                 if(!teamplay || targ.team != attacker.team)
1018                                                                 {
1019                                                                         stat_damagedone += finaldmg;
1020                                                                         stat_maxdamage += coredamage;
1021                                                                 }
1022                                                         }
1023
1024                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1025                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1026                                                         else
1027                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1028                                                 }
1029                                         }
1030                                 }
1031                         }
1032                 targ = next;
1033         }
1034
1035         RadiusDamage_running = 0;
1036
1037         Damage_RecordDamage(attacker, deathtype, min(stat_maxdamage, stat_damagedone));
1038
1039         return total_damage_to_creatures;
1040 }
1041
1042 .float fire_damagepersec;
1043 .float fire_endtime;
1044 .float fire_deathtype;
1045 .entity fire_owner;
1046 .float fire_hitsound;
1047 .entity fire_burner;
1048
1049 void fireburner_think();
1050
1051 float Fire_IsBurning(entity e)
1052 {
1053         return (time < e.fire_endtime);
1054 }
1055
1056 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1057 {
1058         float dps;
1059         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1060
1061         if(e.classname == "player")
1062         {
1063                 if(e.deadflag)
1064                         return -1;
1065         }
1066         else
1067         {
1068                 if(!e.fire_burner)
1069                 {
1070                         // print("adding a fire burner to ", e.classname, "\n");
1071                         e.fire_burner = spawn();
1072                         e.fire_burner.classname = "fireburner";
1073                         e.fire_burner.think = fireburner_think;
1074                         e.fire_burner.nextthink = time;
1075                         e.fire_burner.owner = e;
1076                 }
1077         }
1078
1079         t = max(t, 0.1);
1080         dps = d / t;
1081         if(Fire_IsBurning(e))
1082         {
1083                 mintime = e.fire_endtime - time;
1084                 maxtime = max(mintime, t);
1085
1086                 mindps = e.fire_damagepersec;
1087                 maxdps = max(mindps, dps);
1088
1089                 if(maxtime > mintime || maxdps > mindps)
1090                 {
1091                         mindamage = mindps * mintime;
1092                         maxdamage = mindamage + d;
1093
1094                         // interval [mintime, maxtime] * [mindps, maxdps]
1095                         // intersected with
1096                         // [mindamage, maxdamage]
1097                         // maximum of this!
1098
1099                         if(maxdamage >= maxtime * maxdps)
1100                         {
1101                                 totaltime = maxtime;
1102                                 totaldamage = maxtime * maxdps;
1103
1104                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1105                         }
1106                         else
1107                         {
1108                                 // maxdamage is inside the interval!
1109                                 // first, try to use mindps; only if this fails, increase dps as needed
1110                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1111                                 totaldamage = maxdamage;
1112                                 // can totaldamage / totaltime be >= maxdps?
1113                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1114                                 // we know maxdamage < maxtime * maxdps
1115                                 // so it cannot be
1116
1117                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1118                         }
1119
1120                         // total conditions for increasing:
1121                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1122                         // however:
1123                         //     if maxtime = mintime, maxdps = mindps
1124                         // then:
1125                         //     maxdamage = mindamage + d
1126                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1127                         // so the last condition is not needed
1128
1129                         e.fire_damagepersec = totaldamage / totaltime;
1130                         e.fire_endtime = time + totaltime;
1131                         if(totaldamage > 1.2 * mindamage)
1132                         {
1133                                 e.fire_deathtype = dt;
1134                                 if(e.fire_owner != o)
1135                                 {
1136                                         e.fire_owner = o;
1137                                         e.fire_hitsound = FALSE;
1138                                 }
1139                         }
1140                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1141                 }
1142                 else
1143                         return 0;
1144         }
1145         else
1146         {
1147                 e.fire_damagepersec = dps;
1148                 e.fire_endtime = time + t;
1149                 e.fire_deathtype = dt;
1150                 e.fire_owner = o;
1151                 e.fire_hitsound = FALSE;
1152                 return d;
1153         }
1154 }
1155
1156 void Fire_ApplyDamage(entity e)
1157 {
1158         float t, d, hi, ty;
1159         entity o;
1160
1161         if not(Fire_IsBurning(e))
1162                 return;
1163
1164         o = e.owner;
1165         while(o.owner)
1166                 o = o.owner;
1167         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1168                 o = e.fire_owner;
1169
1170         // water and slime stop fire
1171         if(e.waterlevel)
1172         if(e.watertype != CONTENT_LAVA)
1173                 e.fire_endtime = 0;
1174
1175         t = min(frametime, e.fire_endtime - time);
1176         d = e.fire_damagepersec * t;
1177
1178         hi = e.fire_owner.hitsound;
1179         ty = e.fire_owner.typehitsound;
1180         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1181         if(e.fire_hitsound && e.fire_owner)
1182         {
1183                 e.fire_owner.hitsound = hi;
1184                 e.fire_owner.typehitsound = ty;
1185         }
1186         e.fire_hitsound = TRUE;
1187
1188         Damage_RecordDamage(e.fire_owner, e.fire_deathtype, d);
1189
1190         if not(IS_INDEPENDENT_PLAYER(e))
1191         FOR_EACH_PLAYER(other) if(e != other)
1192         {
1193                 if(other.classname == "player")
1194                 if(other.deadflag == DEAD_NO)
1195                 if not(IS_INDEPENDENT_PLAYER(other))
1196                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1197                 {
1198                         t = cvar("g_balance_firetransfer_time") * (e.fire_endtime - time);
1199                         d = cvar("g_balance_firetransfer_damage") * e.fire_damagepersec * t;
1200                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1201                 }
1202         }
1203 }
1204
1205 void Fire_ApplyEffect(entity e)
1206 {
1207         if(Fire_IsBurning(e))
1208                 e.effects |= EF_FLAME;
1209         else
1210                 e.effects &~= EF_FLAME;
1211 }
1212
1213 void fireburner_think()
1214 {
1215         // for players, this is done in the regular loop
1216         if(wasfreed(self.owner))
1217         {
1218                 remove(self);
1219                 return;
1220         }
1221         Fire_ApplyEffect(self.owner);
1222         if(!Fire_IsBurning(self.owner))
1223         {
1224                 self.owner.fire_burner = world;
1225                 remove(self);
1226                 return;
1227         }
1228         Fire_ApplyDamage(self.owner);
1229         self.nextthink = time;
1230 }