qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         return TRUE;
  18 }
  19
  20 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, entity dmgowner)
  21 {
  22         // TODO maybe call this from non-edgedamage too?
  23         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  24
  25         entity e;
  26
  27         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  28                 deathtype |= 0x8000;
  29
  30         e = spawn();
  31         setorigin(e, org);
  32         e.projectiledeathtype = deathtype;
  33         e.dmg = coredamage;
  34         e.dmg_edge = edgedamage;
  35         e.dmg_radius = rad;
  36         e.dmg_force = vlen(force);
  37         e.velocity = force;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  42 }
  43
  44 #define DAMAGE_CENTERPRINT_SPACER NEWLINES
  45
  46 float checkrules_firstblood;
  47
  48 float yoda;
  49 float damage_goodhits;
  50 float damage_gooddamage;
  51 float headshot;
  52 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  53
  54 .float dmg_team;
  55 .float teamkill_complain;
  56 .float teamkill_soundtime;
  57 .entity teamkill_soundsource;
  58 .entity pusher;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teams_matter)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 void GiveFrags (entity attacker, entity targ, float f)
 106 {
 107         float w;
 108
 109         // TODO route through PlayerScores instead
 110         if(gameover) return;
 111
 112         if(f < 0)
 113         {
 114                 if(targ == attacker)
 115                 {
 116                         // suicide
 117                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 118                 }
 119                 else
 120                 {
 121                         // teamkill
 122                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 123                 }
 124         }
 125         else
 126         {
 127                 // regular frag
 128                 PlayerScore_Add(attacker, SP_KILLS, 1);
 129         }
 130
 131         PlayerScore_Add(targ, SP_DEATHS, 1);
 132
 133         if(g_arena || g_ca)
 134                 if(cvar("g_arena_roundbased"))
 135                         return;
 136
 137         if(targ != attacker) // not for suicides
 138         if(g_weaponarena_random)
 139         {
 140                 // after a frag, choose another random weapon set
 141                 if(inWarmupStage)
 142                         w = warmup_start_weapons;
 143                 else
 144                         w = start_weapons;
 145
 146                 attacker.weapons = randombits(w - (w & W_WeaponBit(attacker.weapon)), g_weaponarena_random, TRUE);
 147                 if(attacker.weapons < 0)
 148                 {
 149                         // error from randombits: no weapon available
 150                         // this means we can just give ALL weapons
 151                         attacker.weapons = w;
 152                 }
 153                 if not(attacker.weapons & W_WeaponBit(attacker.weapon))
 154                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 155         }
 156
 157         // FIXME fix the mess this is (we have REAL points now!)
 158         entity oldself;
 159         oldself = self;
 160         self = attacker;
 161         frag_attacker = attacker;
 162         frag_target = targ;
 163         frag_score = f;
 164         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 165         {
 166                 f = frag_score;
 167                 self = oldself;
 168         }
 169         else
 170         {
 171                 self = oldself;
 172                 if(g_runematch)
 173                 {
 174                         f = RunematchHandleFrags(attacker, targ, f);
 175                 }
 176                 else if(g_lms)
 177                 {
 178                         // remove a life
 179                         float tl;
 180                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 181                         if(tl < lms_lowest_lives)
 182                                 lms_lowest_lives = tl;
 183                         if(tl <= 0)
 184                         {
 185                                 if(!lms_next_place)
 186                                         lms_next_place = player_count;
 187                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 188                                 --lms_next_place;
 189                         }
 190                         f = 0;
 191                 }
 192                 else if(g_ctf)
 193                 {
 194                         if(g_ctf_ignore_frags)
 195                                 f = 0;
 196                 }
 197         }
 198
 199         attacker.totalfrags += f;
 200
 201         if(f)
 202                 UpdateFrags(attacker, f);
 203 }
 204
 205 string AppendItemcodes(string s, entity player)
 206 {
 207         float w;
 208         w = player.weapon;
 209         //if(w == 0)
 210         //      w = player.switchweapon;
 211         if(w == 0)
 212                 w = player.cnt; // previous weapon!
 213         s = strcat(s, ftos(w));
 214         if(time < player.strength_finished)
 215                 s = strcat(s, "S");
 216         if(time < player.invincible_finished)
 217                 s = strcat(s, "I");
 218         if(player.flagcarried != world)
 219                 s = strcat(s, "F");
 220         if(player.BUTTON_CHAT)
 221                 s = strcat(s, "T");
 222         if(player.kh_next)
 223                 s = strcat(s, "K");
 224         if(player.runes)
 225                 s = strcat(s, "|", ftos(player.runes));
 226         return s;
 227 }
 228
 229 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 230 {
 231         string s;
 232         if(!cvar("sv_eventlog"))
 233                 return;
 234         s = strcat(":kill:", mode);
 235         s = strcat(s, ":", ftos(killer.playerid));
 236         s = strcat(s, ":", ftos(killed.playerid));
 237         s = strcat(s, ":type=", ftos(deathtype));
 238         s = strcat(s, ":items=");
 239         s = AppendItemcodes(s, killer);
 240         if(killed != killer)
 241         {
 242                 s = strcat(s, ":victimitems=");
 243                 s = AppendItemcodes(s, killed);
 244         }
 245         GameLogEcho(s);
 246 }
 247
 248 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 249 {
 250         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 251         WriteByte(MSG_ALL, TE_CSQC_NOTIFY);
 252         WriteByte(MSG_ALL, CSQC_KILLNOTIFY);
 253         WriteString(MSG_ALL, s1);
 254         WriteString(MSG_ALL, s2);
 255         WriteString(MSG_ALL, s3);
 256         WriteShort(MSG_ALL, msg);
 257         WriteByte(MSG_ALL, type);
 258 }
 259
 260 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 261 void Send_CSQC_Centerprint(entity e, string s1, string s2, float msg, float type)
 262 {
 263         if (clienttype(e) == CLIENTTYPE_REAL)
 264         {
 265                 msg_entity = e;
 266                 WRITESPECTATABLE_MSG_ONE({
 267                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 268                         WriteByte(MSG_ONE, TE_CSQC_NOTIFY);
 269                         WriteByte(MSG_ONE, CSQC_CENTERPRINT);
 270                         WriteString(MSG_ONE, s1);
 271                         WriteString(MSG_ONE, s2);
 272                         WriteShort(MSG_ONE, msg);
 273                         WriteByte(MSG_ONE, type);
 274                 });
 275         }
 276 }
 277
 278 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 279 {
 280         string  s, a, msg;
 281         float w, type;
 282
 283         if (targ.classname == "player" || targ.classname == "corpse")
 284         {
 285                 if (targ.classname == "corpse")
 286                         s = "A corpse";
 287                 else
 288                         s = targ.netname;
 289
 290                 a = attacker.netname;
 291
 292                 if (targ == attacker) // suicides
 293                 {
 294                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 295                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 296                         Send_CSQC_Centerprint(targ, msg, "", deathtype, MSG_SUICIDE);
 297
 298                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 299                         {
 300                                 LogDeath("suicide", deathtype, targ, targ);
 301                                 GiveFrags(attacker, targ, -1);
 302                         }
 303
 304                         if (targ.killcount > 2)
 305                                 msg = ftos(targ.killcount);
 306                         if(teams_matter && deathtype == DEATH_MIRRORDAMAGE)
 307                         {
 308                                 if(attacker.team == COLOR_TEAM1)
 309                                         deathtype = KILL_TEAM_RED;
 310                                 else
 311                                         deathtype = KILL_TEAM_BLUE;
 312                         }
 313
 314                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 315                 }
 316                 else if (attacker.classname == "player" || attacker.classname == "gib")
 317                 {
 318                         if(teams_matter && attacker.team == targ.team)
 319                         {
 320                                 if(attacker.team == COLOR_TEAM1)
 321                                         type = KILL_TEAM_RED;
 322                                 else
 323                                         type = KILL_TEAM_BLUE;
 324
 325                                 GiveFrags(attacker, targ, -1);
 326
 327                                 Send_CSQC_Centerprint(attacker, s, "", type, MSG_KILL);
 328
 329                                 if (targ.killcount > 2) {
 330                                         msg = ftos(targ.killcount);
 331                                 }
 332
 333                                 if (attacker.killcount > 2) {
 334                                         msg = ftos(attacker.killcount);
 335                                         type = KILL_TEAM_SPREE;
 336                                 }
 337                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 338
 339                                 attacker.killcount = 0;
 340
 341                                 LogDeath("tk", deathtype, attacker, targ);
 342                         }
 343                         else
 344                         {
 345                                 if (!checkrules_firstblood)
 346                                 {
 347                                         checkrules_firstblood = TRUE;
 348                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 349                                         // TODO: make these print a newline if they dont
 350                                         Send_CSQC_Centerprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 351                                         Send_CSQC_Centerprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 352                                 }
 353
 354                                 if((cvar("sv_fragmessage_information_typefrag")) && (targ.BUTTON_CHAT)) {
 355                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_TYPEFRAG, MSG_KILL);
 356                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 357                                 } else {
 358                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_FRAG, MSG_KILL);
 359                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_FRAGGED, MSG_KILL);
 360                                 }
 361
 362                                 attacker.taunt_soundtime = time + 1;
 363
 364                                 // TODO: fix this?
 365                                 if (deathtype == DEATH_CUSTOM)
 366                                         msg = deathmessage;
 367                                 else
 368                                         msg = inflictor.message2;
 369
 370                                 if(strstrofs(msg, "%", 0) < 0)
 371                                         msg = strcat("%s ", msg, " by %s");
 372
 373                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 374
 375                                 if(g_ctf && targ.flagcarried)
 376                                 {
 377                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
 378                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
 379                                         GiveFrags(attacker, targ, 0); // for logging
 380                                 }
 381                                 else
 382                                         GiveFrags(attacker, targ, 1);
 383
 384                                 if (targ.killcount > 2) {
 385                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 386                                 }
 387
 388                                 attacker.killcount = attacker.killcount + 1;
 389
 390                                 if (attacker.killcount > 2) {
 391                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 392                                 }
 393                                 else if (attacker.killcount == 3)
 394                                 {
 395                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 396                                         AnnounceTo(attacker, "03kills");
 397                                 }
 398                                 else if (attacker.killcount == 5)
 399                                 {
 400                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 401                                         AnnounceTo(attacker, "05kills");
 402                                 }
 403                                 else if (attacker.killcount == 10)
 404                                 {
 405                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 406                                         AnnounceTo(attacker, "10kills");
 407                                 }
 408                                 else if (attacker.killcount == 15)
 409                                 {
 410                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 411                                         AnnounceTo(attacker, "15kills");
 412                                 }
 413                                 else if (attacker.killcount == 20)
 414                                 {
 415                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 416                                         AnnounceTo(attacker, "20kills");
 417                                 }
 418                                 else if (attacker.killcount == 25)
 419                                 {
 420                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 421                                         AnnounceTo(attacker, "25kills");
 422                                 }
 423                                 else if (attacker.killcount == 30)
 424                                 {
 425                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 426                                         AnnounceTo(attacker, "30kills");
 427                                 }
 428                                 LogDeath("frag", deathtype, attacker, targ);
 429                         }
 430                 }
 431                 else
 432                 {
 433                         Send_CSQC_Centerprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 434                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 435                                 msg = inflictor.message;
 436                         else if (deathtype == DEATH_CUSTOM)
 437                                 msg = deathmessage;
 438                         if(strstrofs(msg, "%", 0) < 0)
 439                                 msg = strcat("%s ", msg);
 440
 441                         GiveFrags(targ, targ, -1);
 442                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 443                                 AnnounceTo(targ, "botlike");
 444                         }
 445                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 446
 447                         if (targ.killcount > 2)
 448                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 449
 450                         LogDeath("accident", deathtype, targ, targ);
 451                 }
 452
 453                 targ.death_origin = targ.origin;
 454                 if(targ != attacker)
 455                         targ.killer_origin = attacker.origin;
 456
 457                 // FIXME: this should go in PutClientInServer
 458                 if (targ.killcount)
 459                         targ.killcount = 0;
 460         }
 461 }
 462
 463 // these are updated by each Damage call for use in button triggering and such
 464 entity damage_targ;
 465 entity damage_inflictor;
 466 entity damage_attacker;
 467 .float prevhitsound;
 468
 469 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 470 {
 471         float mirrordamage;
 472         float mirrorforce;
 473         float teamdamage0;
 474         entity attacker_save;
 475         mirrordamage = 0;
 476         mirrorforce = 0;
 477
 478         if (gameover || targ.killcount == -666)
 479                 return;
 480
 481         local entity oldself;
 482         oldself = self;
 483         self = targ;
 484         damage_targ = targ;
 485         damage_inflictor = inflictor;
 486         damage_attacker = attacker;
 487                 attacker_save = attacker;
 488
 489         if(targ.classname == "player")
 490                 if(targ.hook)
 491                         if(targ.hook.aiment)
 492                                 if(targ.hook.aiment == attacker)
 493                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 494
 495         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 496         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 497         {
 498                 if(targ.classname == "player")
 499                         if not(IsDifferentTeam(targ, attacker))
 500                         {
 501                                 self = oldself;
 502                                 return;
 503                         }
 504         }
 505
 506         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 507         {
 508                 // These are ALWAYS lethal
 509                 // No damage modification here
 510                 // Instead, prepare the victim for his death...
 511                 targ.armorvalue = 0;
 512                 targ.spawnshieldtime = 0;
 513                 targ.health = 0.9; // this is < 1
 514                 targ.flags -= targ.flags & FL_GODMODE;
 515                 damage = 100000;
 516         }
 517         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 518         {
 519                 // no processing
 520         }
 521         else
 522         {
 523                 if (targ.classname == "player")
 524                 if (attacker.classname == "player")
 525                 if (!targ.isbot)
 526                 if (attacker.isbot)
 527                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 528
 529                 if(g_freezetag)
 530                 {
 531                         if(targ.freezetag_frozen == 1)
 532                         {
 533                                 damage = 0;
 534                                 force = force * cvar("g_freezetag_frozen_force");
 535                         }
 536                 }
 537
 538                 // nullify damage if teamplay is on
 539                 if(deathtype != DEATH_TELEFRAG)
 540                 if(attacker.classname == "player")
 541                 {
 542                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 543                         {
 544                                 damage = 0;
 545                                 force = '0 0 0';
 546                         }
 547                         else if(attacker.team == targ.team)
 548                         {
 549                                 if(teamplay == 1)
 550                                         damage = 0;
 551                                 else if(attacker != targ)
 552                                 {
 553                                         if(teamplay == 3)
 554                                                 damage = 0;
 555                                         else if(teamplay == 4)
 556                                         {
 557                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 558                                                 {
 559                                                         teamdamage0 = max(attacker.dmg_team, cvar("g_teamdamage_threshold"));
 560                                                         attacker.dmg_team = attacker.dmg_team + damage;
 561                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 562                                                                 mirrordamage = cvar("g_mirrordamage") * (attacker.dmg_team - teamdamage0);
 563                                                         mirrorforce = cvar("g_mirrordamage") * vlen(force);
 564                                                         if(g_minstagib)
 565                                                         {
 566                                                                 if(cvar("g_friendlyfire") == 0)
 567                                                                         damage = 0;
 568                                                         }
 569                                                         else if(g_ca)
 570                                                                 damage = 0;
 571                                                         else
 572                                                                 damage = cvar("g_friendlyfire") * damage;
 573                                                         // mirrordamage will be used LATER
 574                                                 }
 575                                                 else
 576                                                         damage = 0;
 577                                         }
 578                                 }
 579                         }
 580                 }
 581
 582                 if(targ.classname == "player")
 583                 if(attacker.classname == "player")
 584                 if(attacker != targ)
 585                 {
 586                         targ.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 587                         attacker.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 588                 }
 589
 590                 if(targ.classname == "player")
 591                 if (g_minstagib)
 592                 {
 593                         if ((deathtype == DEATH_FALL)  ||
 594                                 (deathtype == DEATH_DROWN) ||
 595                                 (deathtype == DEATH_SLIME) ||
 596                                 (deathtype == DEATH_LAVA)  ||
 597                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 598                         {
 599                                 self = oldself;
 600                                 return;
 601                         }
 602                         if(damage > 0)
 603                             damage = 10000;
 604                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 605                         {
 606                                 targ.armorvalue -= 1;
 607                                 centerprint(targ, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(targ.armorvalue)));
 608                                 damage = 0;
 609                                 targ.hitsound += 1;
 610                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 611                         }
 612                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 613                         {
 614                                 damage = 0;
 615                                 if (targ != attacker)
 616                                 {
 617                                         if ((targ.health >= 1) && (targ.classname == "player"))
 618                                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "Secondary fire inflicts no damage!"));
 619                                         damage = 0;
 620                                         mirrordamage = 0;
 621                                         force = '0 0 0';
 622                                         // keep mirrorforce
 623                                         attacker = targ;
 624                                 }
 625                         }
 626                 }
 627
 628                 if not(DEATH_ISSPECIAL(deathtype))
 629                 {
 630                         damage *= g_weapondamagefactor;
 631                         mirrordamage *= g_weapondamagefactor;
 632                         force = force * g_weaponforcefactor;
 633                         mirrorforce *= g_weaponforcefactor;
 634                 }
 635
 636                 // apply strength multiplier
 637                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 638                 {
 639                         if(targ == attacker)
 640                         {
 641                                 damage = damage * cvar("g_balance_powerup_strength_selfdamage");
 642                                 force = force * cvar("g_balance_powerup_strength_selfforce");
 643                         }
 644                         else
 645                         {
 646                                 damage = damage * cvar("g_balance_powerup_strength_damage");
 647                                 force = force * cvar("g_balance_powerup_strength_force");
 648                         }
 649                 }
 650
 651                 // apply invincibility multiplier
 652                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 653                         damage = damage * cvar("g_balance_powerup_invincible_takedamage");
 654
 655                 if (targ == attacker)
 656                 {
 657                         if(g_ca || (g_cts && !cvar("g_cts_selfdamage")))
 658                                 damage = 0;
 659                         else
 660                                 damage = damage * cvar("g_balance_selfdamagepercent");  // Partial damage if the attacker hits himself
 661                 }
 662
 663                 // CTF: reduce damage/force
 664                 if(g_ctf)
 665                 if(targ == attacker)
 666                 if(targ.flagcarried)
 667                 {
 668                         damage = damage * cvar("g_ctf_flagcarrier_selfdamage");
 669                         force = force * cvar("g_ctf_flagcarrier_selfforce");
 670                 }
 671
 672                 if(g_runematch)
 673                 {
 674                         // apply strength rune
 675                         if (attacker.runes & RUNE_STRENGTH)
 676                         {
 677                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 678                                 {
 679                                         damage = damage * cvar("g_balance_rune_strength_combo_damage");
 680                                         force = force * cvar("g_balance_rune_strength_combo_force");
 681                                 }
 682                                 else
 683                                 {
 684                                         damage = damage * cvar("g_balance_rune_strength_damage");
 685                                         force = force * cvar("g_balance_rune_strength_force");
 686                                 }
 687                         }
 688                         else if (attacker.runes & CURSE_WEAK)
 689                         {
 690                                 damage = damage * cvar("g_balance_curse_weak_damage");
 691                                 force = force * cvar("g_balance_curse_weak_force");
 692                         }
 693
 694                         // apply defense rune
 695                         if (targ.runes & RUNE_DEFENSE)
 696                         {
 697                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 698                                         damage = damage * cvar("g_balance_rune_defense_combo_takedamage");
 699                                 else
 700                                         damage = damage * cvar("g_balance_rune_defense_takedamage");
 701                         }
 702                         else if (targ.runes & CURSE_VULNER)
 703                                 damage = damage * cvar("g_balance_curse_vulner_takedamage");
 704                 }
 705
 706                 // count the damage
 707                 if(attacker)
 708                 if(!targ.deadflag)
 709                 if(targ.takedamage == DAMAGE_AIM)
 710                 if(targ != attacker)
 711                 {
 712                         if(targ.classname == "player")
 713                         {
 714                                 // HEAD SHOT:
 715                                 // find height of hit on player axis
 716                                 // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 717                                 vector headmins, headmaxs, org;
 718                                 org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 719                                 headmins = org + GetHeadshotMins(targ);
 720                                 headmaxs = org + GetHeadshotMaxs(targ);
 721                                 if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 722                                 {
 723                                         deathtype |= HITTYPE_HEADSHOT;
 724                                 }
 725                         }
 726                         else if(targ.classname == "turret_head")
 727                         {
 728                                 deathtype |= HITTYPE_HEADSHOT;
 729                         }
 730                         if(deathtype & HITTYPE_HEADSHOT)
 731                                 damage *= 1 + damage_headshotbonus;
 732
 733                         if(targ.classname == "player")
 734                         {
 735                                 if(IsDifferentTeam(targ, attacker))
 736                                 {
 737                                         if(damage > 0)
 738                                         {
 739                                                 if(attacker.weapon != WEP_ELECTRO && attacker.weapon != WEP_LASER || ((attacker.weapon == WEP_ELECTRO && cvar("g_balance_electro_lightning") || attacker.weapon == WEP_LASER) && attacker.prevhitsound + cvar("sv_hitsound_antispam_time") < time))
 740                                                 {
 741                                                         if(targ.BUTTON_CHAT)
 742                                                                 attacker.typehitsound += 1;
 743                                                         else
 744                                                                 attacker.hitsound += 1;
 745                                                         attacker.prevhitsound = time;
 746                                                 }
 747
 748                                                 damage_goodhits += 1;
 749                                                 damage_gooddamage += damage;
 750
 751                                                 if not(DEATH_ISSPECIAL(deathtype))
 752                                                 {
 753                                                         if(!g_minstagib)
 754                                                         if(IsFlying(targ))
 755                                                                 yoda = 1;
 756
 757                                                         if(g_minstagib)
 758                                                         if(targ.items & IT_STRENGTH)
 759                                                                 yoda = 1;
 760
 761                                                         if(deathtype & HITTYPE_HEADSHOT)
 762                                                                 headshot = 1;
 763                                                 }
 764                                                 if(g_ca)
 765                                                         PlayerScore_Add(attacker, SP_SCORE, damage * cvar("g_ca_damage2score_multiplier"));
 766                                         }
 767                                 }
 768                                 else
 769                                 {
 770                                         if(deathtype != DEATH_FIRE)
 771                                                 attacker.typehitsound += 1;
 772                                         if(mirrordamage > 0)
 773                                                 if(time > attacker.teamkill_complain)
 774                                                 {
 775                                                         attacker.teamkill_complain = time + 5;
 776                                                         attacker.teamkill_soundtime = time + 0.4;
 777                                                         attacker.teamkill_soundsource = targ;
 778                                                 }
 779                                 }
 780                         }
 781                 }
 782         }
 783
 784         // apply push
 785         if (self.damageforcescale)
 786         if (vlen(force))
 787         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 788         {
 789                 self.velocity = self.velocity + self.damageforcescale * force;
 790                 self.flags &~= FL_ONGROUND;
 791                 UpdateCSQCProjectile(self);
 792         }
 793         // apply damage
 794         if (damage != 0 || (self.damageforcescale && vlen(force)))
 795         if (self.event_damage)
 796                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 797         self = oldself;
 798
 799         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 800         {
 801                 if(g_runematch)
 802                 {
 803                         if (attacker.runes & RUNE_VAMPIRE)
 804                         {
 805                         // apply vampire rune
 806                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 807                                 {
 808                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb");
 809                                         attacker.health = bound(
 810                                                 cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 40
 811                                                 attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb"),
 812                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 813                                 }
 814                                 else
 815                                 {
 816                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_absorb");
 817                                         attacker.health = bound(
 818                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 819                                                                                         // empathy won't let you gain health in the same way...
 820                                                 attacker.health + damage * cvar("g_balance_rune_vampire_absorb"),
 821                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 822                                         }
 823                         }
 824                         // apply empathy curse
 825                         else if (attacker.runes & CURSE_EMPATHY)
 826                         {
 827                                 attacker.health = bound(
 828                                         cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 20
 829                                         attacker.health + damage * cvar("g_balance_curse_empathy_takedamage"),
 830                                         attacker.health);
 831                         }
 832                 }
 833         }
 834
 835         // apply mirror damage if any
 836         if(mirrordamage > 0 || mirrorforce > 0)
 837         {
 838                 attacker = attacker_save;
 839                 if(g_minstagib)
 840                         if(mirrordamage > 0)
 841                         {
 842                                 // just lose extra LIVES, don't kill the player for mirror damage
 843                                 if(attacker.armorvalue > 0)
 844                                 {
 845                                         attacker.armorvalue = attacker.armorvalue - 1;
 846                                         centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 847                                         attacker.hitsound += 1;
 848                                 }
 849                                 mirrordamage = 0;
 850                         }
 851                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 852                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 853         }
 854 }
 855
 856 void Damage_RecordDamage(entity attacker, float deathtype, float damage)
 857 {
 858         float weaponid;
 859         weaponid = DEATH_WEAPONOF(deathtype);
 860
 861         if not(inWarmupStage)
 862         if (weaponid)
 863         if ((clienttype(attacker) == CLIENTTYPE_REAL) | (clienttype(attacker) == CLIENTTYPE_BOT)) {
 864                 attacker.stats_hit[weaponid - 1] += damage;
 865                 attacker.stat_hit = weaponid + 64 * floor(attacker.stats_hit[weaponid - 1]);
 866         }
 867 }
 868
 869 float RadiusDamage_running;
 870 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 871 // Returns total damage applies to creatures
 872 {
 873         entity  targ;
 874         float   finaldmg;
 875         float   power;
 876         vector  blastorigin;
 877         vector  force;
 878         vector  diff;
 879         vector  center;
 880         vector  nearest;
 881         float   total_damage_to_creatures;
 882         entity  next;
 883         float   tfloordmg;
 884         float   tfloorforce;
 885
 886         float stat_damagedone;
 887         float stat_maxdamage;
 888
 889         if(RadiusDamage_running)
 890         {
 891                 string save;
 892                 print("RadiusDamage called recursively!\n");
 893                 print("Expect stuff to go HORRIBLY wrong.\n");
 894                 print("Causing a stack trace...\n");
 895                 save = cvar_string("prvm_backtraceforwarnings");
 896                 cvar_set("prvm_backtraceforwarnings", "1");
 897                 fclose(-1); // calls VM_Warning
 898                 cvar_set("prvm_backtraceforwarnings", save);
 899                 return 0;
 900         }
 901
 902         RadiusDamage_running = 1;
 903
 904         tfloordmg = cvar("g_throughfloor_damage");
 905         tfloorforce = cvar("g_throughfloor_force");
 906
 907         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 908         total_damage_to_creatures = 0;
 909
 910         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 911         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 912         {
 913                 force = inflictor.velocity;
 914                 if(vlen(force) == 0)
 915                         force = '0 0 -1';
 916                 else
 917                         force = normalize(force);
 918                 if(forceintensity >= 0)
 919                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, attacker);
 920                 else
 921                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, attacker);
 922         }
 923
 924         stat_damagedone = 0;
 925         stat_maxdamage = 0;
 926
 927         targ = WarpZone_FindRadius (blastorigin, rad, FALSE);
 928         while (targ)
 929         {
 930                 next = targ.chain;
 931                 if (targ != inflictor)
 932                         if (ignore != targ) if(targ.takedamage)
 933                         {
 934                                 // LordHavoc: measure distance to nearest point on target (not origin)
 935                                 // (this guarentees 100% damage on a touch impact)
 936                                 nearest = targ.WarpZone_findradius_nearest;
 937                                 diff = targ.WarpZone_findradius_dist;
 938                                 // round up a little on the damage to ensure full damage on impacts
 939                                 // and turn the distance into a fraction of the radius
 940                                 power = 1 - ((vlen (diff) - 2) / rad);
 941                                 //bprint(" ");
 942                                 //bprint(ftos(power));
 943                                 //if (targ == attacker)
 944                                 //      print(ftos(power), "\n");
 945                                 if (power > 0)
 946                                 {
 947                                         if (power > 1)
 948                                                 power = 1;
 949                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 950                                         if (finaldmg > 0)
 951                                         {
 952                                                 local float a;
 953                                                 local float c;
 954                                                 local float hits;
 955                                                 local float total;
 956                                                 local float hitratio;
 957                                                 local vector hitloc;
 958                                                 local vector myblastorigin;
 959                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 960                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
 961                                                 // if it's a player, use the view origin as reference
 962                                                 if (targ.classname == "player")
 963                                                         center = targ.origin + targ.view_ofs;
 964                                                 force = normalize(center - myblastorigin);
 965                                                 force = force * (finaldmg / coredamage) * forceintensity;
 966                                                 // test line of sight to multiple positions on box,
 967                                                 // and do damage if any of them hit
 968                                                 hits = 0;
 969                                                 if (targ.classname == "player")
 970                                                         total = ceil(bound(1, finaldmg, 50));
 971                                                 else
 972                                                         total = ceil(bound(1, finaldmg/10, 5));
 973                                                 hitloc = nearest;
 974                                                 c = 0;
 975                                                 while (c < total)
 976                                                 {
 977                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 978                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 979                                                         if (trace_fraction == 1 || trace_ent == targ)
 980                                                         {
 981                                                                 hits = hits + 1;
 982                                                                 if (hits > 1)
 983                                                                         hitloc = hitloc + nearest;
 984                                                                 else
 985                                                                         hitloc = nearest;
 986                                                         }
 987                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 988                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 989                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 990                                                         c = c + 1;
 991                                                 }
 992                                                 nearest = hitloc * (1 / max(1, hits));
 993                                                 hitratio = (hits / total);
 994                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 995                                                 finaldmg = finaldmg * a;
 996                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 997                                                 force = force * a;
 998
 999                                                 // laser force adjustments :P
1000                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1001                                                 {
1002                                                         vector vel;
1003
1004                                                         float force_zscale;
1005                                                         float force_velocitybiasramp;
1006                                                         float force_velocitybias;
1007
1008                                                         force_velocitybiasramp = cvar("sv_maxspeed");
1009                                                         if(deathtype & HITTYPE_SECONDARY)
1010                                                         {
1011                                                                 force_zscale = cvar("g_balance_laser_secondary_force_zscale");
1012                                                                 force_velocitybias = cvar("g_balance_laser_secondary_force_velocitybias");
1013                                                         }
1014                                                         else
1015                                                         {
1016                                                                 force_zscale = cvar("g_balance_laser_primary_force_zscale");
1017                                                                 force_velocitybias = cvar("g_balance_laser_primary_force_velocitybias");
1018                                                         }
1019
1020                                                         vel = targ.velocity;
1021                                                         vel_z = 0;
1022                                                         vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1023                                                         force =
1024                                                                 vlen(force)
1025                                                                 *
1026                                                                 normalize(normalize(force) + vel);
1027
1028                                                         force_z *= force_zscale;
1029                                                 }
1030
1031                                                 //if (targ == attacker)
1032                                                 //{
1033                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1034                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1035                                                 //      print(" (", ftos(a), ")\n");
1036                                                 //}
1037                                                 if(hits || tfloordmg || tfloorforce)
1038                                                 {
1039                                                         if(targ.iscreature)
1040                                                         {
1041                                                                 total_damage_to_creatures += finaldmg;
1042
1043                                                                 if(targ.flags & FL_CLIENT)
1044                                                                 if(targ.deadflag == DEAD_NO)
1045                                                                 if(targ != attacker)
1046                                                                 if(!teamplay || targ.team != attacker.team)
1047                                                                 {
1048                                                                         stat_damagedone += finaldmg;
1049                                                                         stat_maxdamage += coredamage;
1050                                                                 }
1051                                                         }
1052
1053                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1054                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1055                                                         else
1056                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1057                                                 }
1058                                         }
1059                                 }
1060                         }
1061                 targ = next;
1062         }
1063
1064         RadiusDamage_running = 0;
1065
1066         Damage_RecordDamage(attacker, deathtype, min(stat_maxdamage, stat_damagedone));
1067
1068         return total_damage_to_creatures;
1069 }
1070
1071 .float fire_damagepersec;
1072 .float fire_endtime;
1073 .float fire_deathtype;
1074 .entity fire_owner;
1075 .float fire_hitsound;
1076 .entity fire_burner;
1077
1078 void fireburner_think();
1079
1080 float Fire_IsBurning(entity e)
1081 {
1082         return (time < e.fire_endtime);
1083 }
1084
1085 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1086 {
1087         float dps;
1088         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1089
1090         if(e.classname == "player")
1091         {
1092                 if(e.deadflag)
1093                         return -1;
1094         }
1095         else
1096         {
1097                 if(!e.fire_burner)
1098                 {
1099                         // print("adding a fire burner to ", e.classname, "\n");
1100                         e.fire_burner = spawn();
1101                         e.fire_burner.classname = "fireburner";
1102                         e.fire_burner.think = fireburner_think;
1103                         e.fire_burner.nextthink = time;
1104                         e.fire_burner.owner = e;
1105                 }
1106         }
1107
1108         t = max(t, 0.1);
1109         dps = d / t;
1110         if(Fire_IsBurning(e))
1111         {
1112                 mintime = e.fire_endtime - time;
1113                 maxtime = max(mintime, t);
1114
1115                 mindps = e.fire_damagepersec;
1116                 maxdps = max(mindps, dps);
1117
1118                 if(maxtime > mintime || maxdps > mindps)
1119                 {
1120                         mindamage = mindps * mintime;
1121                         maxdamage = mindamage + d;
1122
1123                         // interval [mintime, maxtime] * [mindps, maxdps]
1124                         // intersected with
1125                         // [mindamage, maxdamage]
1126                         // maximum of this!
1127
1128                         if(maxdamage >= maxtime * maxdps)
1129                         {
1130                                 totaltime = maxtime;
1131                                 totaldamage = maxtime * maxdps;
1132
1133                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1134                         }
1135                         else
1136                         {
1137                                 // maxdamage is inside the interval!
1138                                 // first, try to use mindps; only if this fails, increase dps as needed
1139                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1140                                 totaldamage = maxdamage;
1141                                 // can totaldamage / totaltime be >= maxdps?
1142                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1143                                 // we know maxdamage < maxtime * maxdps
1144                                 // so it cannot be
1145
1146                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1147                         }
1148
1149                         // total conditions for increasing:
1150                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1151                         // however:
1152                         //     if maxtime = mintime, maxdps = mindps
1153                         // then:
1154                         //     maxdamage = mindamage + d
1155                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1156                         // so the last condition is not needed
1157
1158                         e.fire_damagepersec = totaldamage / totaltime;
1159                         e.fire_endtime = time + totaltime;
1160                         if(totaldamage > 1.2 * mindamage)
1161                         {
1162                                 e.fire_deathtype = dt;
1163                                 if(e.fire_owner != o)
1164                                 {
1165                                         e.fire_owner = o;
1166                                         e.fire_hitsound = FALSE;
1167                                 }
1168                         }
1169                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1170                 }
1171                 else
1172                         return 0;
1173         }
1174         else
1175         {
1176                 e.fire_damagepersec = dps;
1177                 e.fire_endtime = time + t;
1178                 e.fire_deathtype = dt;
1179                 e.fire_owner = o;
1180                 e.fire_hitsound = FALSE;
1181                 return d;
1182         }
1183 }
1184
1185 void Fire_ApplyDamage(entity e)
1186 {
1187         float t, d, hi, ty;
1188         entity o;
1189
1190         if not(Fire_IsBurning(e))
1191                 return;
1192
1193         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1194         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1195                 o = e.fire_owner;
1196
1197         // water and slime stop fire
1198         if(e.waterlevel)
1199         if(e.watertype != CONTENT_LAVA)
1200                 e.fire_endtime = 0;
1201
1202         t = min(frametime, e.fire_endtime - time);
1203         d = e.fire_damagepersec * t;
1204
1205         hi = e.fire_owner.hitsound;
1206         ty = e.fire_owner.typehitsound;
1207         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1208         if(e.fire_hitsound && e.fire_owner)
1209         {
1210                 e.fire_owner.hitsound = hi;
1211                 e.fire_owner.typehitsound = ty;
1212         }
1213         e.fire_hitsound = TRUE;
1214
1215         Damage_RecordDamage(e.fire_owner, e.fire_deathtype, d);
1216
1217         if not(IS_INDEPENDENT_PLAYER(e))
1218         FOR_EACH_PLAYER(other) if(e != other)
1219         {
1220                 if(other.classname == "player")
1221                 if(other.deadflag == DEAD_NO)
1222                 if not(IS_INDEPENDENT_PLAYER(other))
1223                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1224                 {
1225                         t = cvar("g_balance_firetransfer_time") * (e.fire_endtime - time);
1226                         d = cvar("g_balance_firetransfer_damage") * e.fire_damagepersec * t;
1227                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1228                 }
1229         }
1230 }
1231
1232 void Fire_ApplyEffect(entity e)
1233 {
1234         if(Fire_IsBurning(e))
1235                 e.effects |= EF_FLAME;
1236         else
1237                 e.effects &~= EF_FLAME;
1238 }
1239
1240 void fireburner_think()
1241 {
1242         // for players, this is done in the regular loop
1243         if(wasfreed(self.owner))
1244         {
1245                 remove(self);
1246                 return;
1247         }
1248         Fire_ApplyEffect(self.owner);
1249         if(!Fire_IsBurning(self.owner))
1250         {
1251                 self.owner.fire_burner = world;
1252                 remove(self);
1253                 return;
1254         }
1255         Fire_ApplyDamage(self.owner);
1256         self.nextthink = time;
1257 }