qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 /*string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 220 {
 221         string health_output = string_null;
 222         string ping_output = string_null;
 223         string handicap_output = string_null;
 224         string output = string_null;
 225
 226         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 227         {
 228                 // health/armor of attacker (person who killed you)
 229                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 230                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 231
 232                 // ping display
 233                 if(autocvar_sv_fraginfo_ping)
 234                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 235
 236                 // handicap display
 237                 if(autocvar_sv_fraginfo_handicap)
 238                 {
 239                         if(autocvar_sv_fraginfo_handicap == 2)
 240                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 241                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 242                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 243                 }
 244
 245                 // format the string
 246                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 247                         ping_output, (handicap_output ? "^7 / " : ""),
 248                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 249
 250                 // add new line to the beginning if there is a message
 251                 if(output) { output = strcat("\n", output); }
 252         }
 253
 254         return output;
 255 }*/
 256
 257 string AppendItemcodes(string s, entity player)
 258 {
 259         float w;
 260         w = player.weapon;
 261         //if(w == 0)
 262         //      w = player.switchweapon;
 263         if(w == 0)
 264                 w = player.cnt; // previous weapon!
 265         s = strcat(s, ftos(w));
 266         if(time < player.strength_finished)
 267                 s = strcat(s, "S");
 268         if(time < player.invincible_finished)
 269                 s = strcat(s, "I");
 270         if(player.flagcarried != world)
 271                 s = strcat(s, "F");
 272         if(player.BUTTON_CHAT)
 273                 s = strcat(s, "T");
 274         if(player.kh_next)
 275                 s = strcat(s, "K");
 276         if(player.runes)
 277                 s = strcat(s, "|", ftos(player.runes));
 278         return s;
 279 }
 280
 281 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 282 {
 283         string s;
 284         if(!autocvar_sv_eventlog)
 285                 return;
 286         s = strcat(":kill:", mode);
 287         s = strcat(s, ":", ftos(killer.playerid));
 288         s = strcat(s, ":", ftos(killed.playerid));
 289         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 290         s = strcat(s, ":items=");
 291         s = AppendItemcodes(s, killer);
 292         if(killed != killer)
 293         {
 294                 s = strcat(s, ":victimitems=");
 295                 s = AppendItemcodes(s, killed);
 296         }
 297         GameLogEcho(s);
 298 }
 299
 300 #define INFO_NO_MSG 0
 301
 302 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2, float f3)
 303 {
 304         float handled = 0, hits = 0;
 305         if(DEATH_ISSPECIAL(deathtype))
 306         {
 307                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 308                         { if(deathtype == max(0, name)) \
 309                         { \
 310                                 #if msg_death != NO_MSG \
 311                                         if not(murder) \
 312                                         { \
 313                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 314                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 315                                                 ++handled; \
 316                                         } \
 317                                 #endif \
 318                                 #if msg_death_by != NO_MSG \
 319                                         if(murder) \
 320                                         { \
 321                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 322                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 323                                                 ++handled; \
 324                                         } \
 325                                 #endif \
 326                                 ++hits; \
 327                         } }
 328
 329                 DEATHTYPES
 330                 #undef DEATHTYPE
 331
 332                 if not(hits)
 333                 {
 334                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 335                 }
 336                 if not(handled)
 337                 {
 338                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 339                         return;
 340                 }
 341         }
 342 }
 343
 344 float w_deathtype;
 345 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2)
 346 {
 347         float death_weapon = DEATH_WEAPONOF(deathtype);
 348
 349         if(death_weapon)
 350         {
 351                 w_deathtype = deathtype;
 352                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 353                 w_deathtype = FALSE;
 354
 355                 if(death_message)
 356                 {
 357                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_WEAPON, death_message, s1, s2, s3, "", f1, f2, 0, 0);
 358                         Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_weapon_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, 0, 0);
 359                         //print(Get_Field_Value(F_INFVAL, MSG_WEAPON, death_message), "\n");
 360                 }
 361                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 362
 363                 return TRUE;
 364         }
 365         return FALSE;
 366 }
 367
 368 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 369 {
 370         // Sanity check
 371         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 372
 373         // Declarations
 374         float notif_firstblood = FALSE;
 375         string deathlocation = NearestLocation(targ.origin);
 376
 377         //dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 378
 379         // =======
 380         // SUICIDE
 381         // =======
 382         if(targ == attacker)
 383         {
 384                 if(DEATH_ISSPECIAL(deathtype))
 385                 {
 386                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 387                         {
 388                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 389                         }
 390                         else
 391                         {
 392                                 switch(deathtype)
 393                                 {
 394                                         case DEATH_MIRRORDAMAGE:
 395                                         {
 396                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 397                                                 break;
 398                                         }
 399
 400                                         default:
 401                                         {
 402                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 403                                                 break;
 404                                         }
 405                                 }
 406                                 LogDeath("suicide", deathtype, targ, targ);
 407                                 GiveFrags(attacker, targ, -1, deathtype);
 408                         }
 409                 }
 410                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 411                 {
 412                         backtrace("SUICIDE: what the hell happened here?\n");
 413                 }
 414         }
 415
 416         // ======
 417         // MURDER
 418         // ======
 419         else if(attacker.classname == "player")
 420         {
 421                 if(!IsDifferentTeam(attacker, targ))
 422                 {
 423                         LogDeath("tk", deathtype, attacker, targ);
 424                         GiveFrags(attacker, targ, -1, deathtype);
 425
 426                         attacker.killcount = 0;
 427
 428                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 429                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 430                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 431
 432                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 433                         // No need for specific death/weapon messages...
 434                 }
 435                 else
 436                 {
 437                         LogDeath("frag", deathtype, attacker, targ);
 438                         GiveFrags(attacker, targ, 1, deathtype);
 439
 440                         attacker.taunt_soundtime = time + 1;
 441                         attacker.killcount = attacker.killcount + 1;
 442
 443                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 444                                 case counta: \
 445                                 { \
 446                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 447                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 448                                         break; \
 449                                 }
 450                         switch(attacker.killcount)
 451                         {
 452                                 KILL_SPREE_LIST
 453                                 default: break;
 454                         }
 455                         #undef SPREE_ITEM
 456
 457                         if(!checkrules_firstblood)
 458                         {
 459                                 checkrules_firstblood = TRUE;
 460                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 461                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 462                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 463                         }
 464
 465                         float kill_count_to_attacker;
 466                         float kill_count_to_target;
 467                         if(notif_firstblood)
 468                         {
 469                                 kill_count_to_attacker = -1;
 470                                 kill_count_to_target = -2;
 471                         }
 472                         else
 473                         {
 474                                 kill_count_to_attacker = attacker.killcount;
 475                                 kill_count_to_target = 0;
 476                         }
 477
 478                         if(targ.istypefrag)
 479                         {
 480                                 if(attacker.FRAG_VERBOSE)
 481                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 482                                 else
 483                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 484
 485                                 if(targ.FRAG_VERBOSE)
 486                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 487                                 else
 488                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 489                         }
 490                         else
 491                         {
 492                                 if(attacker.FRAG_VERBOSE)
 493                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 494                                 else
 495                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 496
 497                                 if(targ.FRAG_VERBOSE)
 498                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 499                                 else
 500                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 501                         }
 502
 503                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 504                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 505                 }
 506         }
 507
 508         // =============
 509         // ACCIDENT/TRAP
 510         // =============
 511         else
 512         {
 513                 switch(deathtype)
 514                 {
 515                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 516                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 517                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 518                         /*case DEATH_HURTTRIGGER:
 519                         {
 520                                 s1 = targ.netname;
 521                                 s2 = inflictor.message;
 522                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 523                                 break;
 524                         }*/
 525
 526                         case DEATH_CUSTOM:
 527                         {
 528                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 529                                         targ.netname,
 530                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 531                                         deathlocation,
 532                                         targ.killcount,
 533                                         0,
 534                                         0);
 535                                 break;
 536                         }
 537
 538                         default:
 539                         {
 540                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 541                                 break;
 542                         }
 543                 }
 544
 545                 LogDeath("accident", deathtype, targ, targ);
 546                 GiveFrags(targ, targ, -1, deathtype);
 547
 548                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 549                 {
 550                         AnnounceTo(targ, "botlike");
 551                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 552                 }
 553         }
 554
 555         // Set final information for the death
 556         targ.death_origin = targ.origin;
 557         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 558         if(targ.killcount) { targ.killcount = 0; }
 559 }
 560
 561 // these are updated by each Damage call for use in button triggering and such
 562 entity damage_targ;
 563 entity damage_inflictor;
 564 entity damage_attacker;
 565
 566 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 567 {
 568         float mirrordamage;
 569         float mirrorforce;
 570         float complainteamdamage = 0;
 571         entity attacker_save;
 572         mirrordamage = 0;
 573         mirrorforce = 0;
 574
 575         if (gameover || targ.killcount == -666)
 576                 return;
 577
 578         entity oldself;
 579         oldself = self;
 580         self = targ;
 581         damage_targ = targ;
 582         damage_inflictor = inflictor;
 583         damage_attacker = attacker;
 584                 attacker_save = attacker;
 585
 586         if(targ.classname == "player")
 587                 if(targ.hook)
 588                         if(targ.hook.aiment)
 589                                 if(targ.hook.aiment == attacker)
 590                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 591
 592         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 593         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 594         {
 595                 if(targ.classname == "player")
 596                         if not(IsDifferentTeam(targ, attacker))
 597                         {
 598                                 self = oldself;
 599                                 return;
 600                         }
 601         }
 602
 603         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 604         {
 605                 // These are ALWAYS lethal
 606                 // No damage modification here
 607                 // Instead, prepare the victim for his death...
 608                 targ.armorvalue = 0;
 609                 targ.spawnshieldtime = 0;
 610                 targ.health = 0.9; // this is < 1
 611                 targ.flags -= targ.flags & FL_GODMODE;
 612                 damage = 100000;
 613         }
 614         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 615         {
 616                 // no processing
 617         }
 618         else
 619         {
 620                 /*
 621                 skill based bot damage? gtfo. (tZork)
 622                 if (targ.classname == "player")
 623                 if (attacker.classname == "player")
 624                 if (!targ.isbot)
 625                 if (attacker.isbot)
 626                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 627         */
 628
 629                 // nullify damage if teamplay is on
 630                 if(deathtype != DEATH_TELEFRAG)
 631                 if(attacker.classname == "player")
 632                 {
 633                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 634                         {
 635                                 damage = 0;
 636                                 force = '0 0 0';
 637                         }
 638                         else if(!IsDifferentTeam(attacker, targ))
 639                         {
 640                                 if(autocvar_teamplay_mode == 1)
 641                                         damage = 0;
 642                                 else if(attacker != targ)
 643                                 {
 644                                         if(autocvar_teamplay_mode == 3)
 645                                                 damage = 0;
 646                                         else if(autocvar_teamplay_mode == 4)
 647                                         {
 648                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 649                                                 {
 650                                                         attacker.dmg_team = attacker.dmg_team + damage;
 651                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 652                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 653                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 654                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 655                                                         if(g_minstagib)
 656                                                         {
 657                                                                 if(autocvar_g_friendlyfire == 0)
 658                                                                         damage = 0;
 659                                                         }
 660                                                         else if(g_ca)
 661                                                                 damage = 0;
 662                                                         else
 663                                                                 damage = autocvar_g_friendlyfire * damage;
 664                                                         // mirrordamage will be used LATER
 665
 666                                                         if(autocvar_g_mirrordamage_virtual)
 667                                                         {
 668                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 669                                                                 attacker.dmg_take += v_x;
 670                                                                 attacker.dmg_save += v_y;
 671                                                                 attacker.dmg_inflictor = inflictor;
 672                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 673                                                                 mirrorforce = 0;
 674                                                         }
 675
 676                                                         if(autocvar_g_friendlyfire_virtual)
 677                                                         {
 678                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 679                                                                 targ.dmg_take += v_x;
 680                                                                 targ.dmg_save += v_y;
 681                                                                 targ.dmg_inflictor = inflictor;
 682                                                                 damage = 0;
 683                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 684                                                                         force = '0 0 0';
 685                                                         }
 686                                                 }
 687                                                 else
 688                                                         damage = 0;
 689                                         }
 690                                 }
 691                         }
 692                 }
 693
 694                 if(targ.classname == "player")
 695                 if(attacker.classname == "player")
 696                 if(attacker != targ)
 697                 {
 698                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 699                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 700                 }
 701
 702                 if(targ.classname == "player")
 703                 if (g_minstagib)
 704                 {
 705                         if ((deathtype == DEATH_FALL)  ||
 706                                 (deathtype == DEATH_DROWN) ||
 707                                 (deathtype == DEATH_SLIME) ||
 708                                 (deathtype == DEATH_LAVA)  ||
 709                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 710                         {
 711                                 self = oldself;
 712                                 return;
 713                         }
 714                         if(damage > 0)
 715                             damage = 10000;
 716                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 717                         {
 718                                 targ.armorvalue -= 1;
 719                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 720                                 damage = 0;
 721                                 targ.hitsound += 1;
 722                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 723                         }
 724                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 725                         {
 726                                 damage = 0;
 727                                 mirrordamage = 0;
 728                                 complainteamdamage = 0;
 729                                 if (targ != attacker)
 730                                 {
 731                                         if ((targ.health >= 1) && (targ.classname == "player"))
 732                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 733                                         force = '0 0 0';
 734                                         // keep mirrorforce
 735                                         attacker = targ;
 736                                 }
 737                         }
 738                 }
 739
 740                 if not(DEATH_ISSPECIAL(deathtype))
 741                 {
 742                         damage *= g_weapondamagefactor;
 743                         mirrordamage *= g_weapondamagefactor;
 744                         complainteamdamage *= g_weapondamagefactor;
 745                         force = force * g_weaponforcefactor;
 746                         mirrorforce *= g_weaponforcefactor;
 747                 }
 748
 749                 // should this be changed at all? If so, in what way?
 750                 frag_attacker = attacker;
 751                 frag_target = targ;
 752                 frag_damage = damage;
 753                 frag_force = force;
 754         frag_deathtype = deathtype;
 755                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 756                 damage = frag_damage;
 757                 force = frag_force;
 758
 759                 // apply strength multiplier
 760                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 761                 {
 762                         if(targ == attacker)
 763                         {
 764                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 765                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 766                         }
 767                         else
 768                         {
 769                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 770                                 force = force * autocvar_g_balance_powerup_strength_force;
 771                         }
 772                 }
 773
 774                 // apply invincibility multiplier
 775                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 776                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 777
 778                 if (targ == attacker)
 779                 {
 780                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 781                                 damage = 0;
 782                         else
 783                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 784                 }
 785
 786                 if(g_runematch)
 787                 {
 788                         // apply strength rune
 789                         if (attacker.runes & RUNE_STRENGTH)
 790                         {
 791                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 792                                 {
 793                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 794                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 795                                 }
 796                                 else
 797                                 {
 798                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 799                                         force = force * autocvar_g_balance_rune_strength_force;
 800                                 }
 801                         }
 802                         else if (attacker.runes & CURSE_WEAK)
 803                         {
 804                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 805                                 force = force * autocvar_g_balance_curse_weak_force;
 806                         }
 807
 808                         // apply defense rune
 809                         if (targ.runes & RUNE_DEFENSE)
 810                         {
 811                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 812                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 813                                 else
 814                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 815                         }
 816                         else if (targ.runes & CURSE_VULNER)
 817                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 818                 }
 819
 820                 // count the damage
 821                 if(attacker)
 822                 if(!targ.deadflag)
 823                 if(targ.takedamage == DAMAGE_AIM)
 824                 if(targ != attacker)
 825                 {
 826                         entity victim;
 827                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 828                                 victim = targ.owner;
 829                         else
 830                                 victim = targ;
 831
 832                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 833                         {
 834                                 if(IsDifferentTeam(victim, attacker))
 835                                 {
 836                                         if(damage > 0)
 837                                         {
 838                                                 if(deathtype != DEATH_FIRE)
 839                                                 {
 840                                                         if(victim.BUTTON_CHAT)
 841                                                                 attacker.typehitsound += 1;
 842                                                         else
 843                                                                 attacker.hitsound += 1;
 844                                                 }
 845
 846                                                 damage_goodhits += 1;
 847                                                 damage_gooddamage += damage;
 848
 849                                                 if not(DEATH_ISSPECIAL(deathtype))
 850                                                 {
 851                                                         if(targ.classname == "player") // don't do this for vehicles
 852                                                         if(!g_minstagib)
 853                                                         if(IsFlying(victim))
 854                                                                 yoda = 1;
 855
 856                                                         if(g_minstagib)
 857                                                         if(victim.items & IT_STRENGTH)
 858                                                                 yoda = 1;
 859                                                 }
 860                                         }
 861                                 }
 862                                 else
 863                                 {
 864                                         if(deathtype != DEATH_FIRE)
 865                                         {
 866                                                 attacker.typehitsound += 1;
 867                                         }
 868                                         if(complainteamdamage > 0)
 869                                                 if(time > attacker.teamkill_complain)
 870                                                 {
 871                                                         attacker.teamkill_complain = time + 5;
 872                                                         attacker.teamkill_soundtime = time + 0.4;
 873                                                         attacker.teamkill_soundsource = targ;
 874                                                 }
 875                                 }
 876                         }
 877                 }
 878         }
 879
 880         // apply push
 881         if (self.damageforcescale)
 882         if (vlen(force))
 883         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 884         {
 885                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 886                 if(self.movetype == MOVETYPE_PHYSICS)
 887                 {
 888                         entity farcent;
 889                         farcent = spawn();
 890                         farcent.classname = "farce";
 891                         farcent.enemy = self;
 892                         farcent.movedir = farce * 10;
 893                         if(self.mass)
 894                                 farcent.movedir = farcent.movedir * self.mass;
 895                         farcent.origin = hitloc;
 896                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 897                         farcent.nextthink = time + 0.1;
 898                         farcent.think = SUB_Remove;
 899                 }
 900                 else
 901                         self.velocity = self.velocity + farce;
 902                 self.flags &~= FL_ONGROUND;
 903                 UpdateCSQCProjectile(self);
 904         }
 905         // apply damage
 906         if (damage != 0 || (self.damageforcescale && vlen(force)))
 907         if (self.event_damage)
 908                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 909         self = oldself;
 910
 911         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 912         {
 913                 if(g_runematch)
 914                 {
 915                         if (attacker.runes & RUNE_VAMPIRE)
 916                         {
 917                         // apply vampire rune
 918                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 919                                 {
 920                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 921                                         attacker.health = bound(
 922                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 923                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 924                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 925                                 }
 926                                 else
 927                                 {
 928                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 929                                         attacker.health = bound(
 930                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 931                                                                                         // empathy won't let you gain health in the same way...
 932                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 933                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 934                                         }
 935                         }
 936                         // apply empathy curse
 937                         else if (attacker.runes & CURSE_EMPATHY)
 938                         {
 939                                 attacker.health = bound(
 940                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 941                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 942                                         attacker.health);
 943                         }
 944                 }
 945         }
 946
 947         // apply mirror damage if any
 948         if(mirrordamage > 0 || mirrorforce > 0)
 949         {
 950                 attacker = attacker_save;
 951                 if(g_minstagib)
 952                 if(mirrordamage > 0)
 953                 {
 954                         // just lose extra LIVES, don't kill the player for mirror damage
 955                         if(attacker.armorvalue > 0)
 956                         {
 957                                 attacker.armorvalue = attacker.armorvalue - 1;
 958                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 959                                 attacker.hitsound += 1;
 960                         }
 961                         mirrordamage = 0;
 962                 }
 963
 964                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 965                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 966         }
 967 }
 968
 969 float RadiusDamage_running;
 970 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 971         // Returns total damage applies to creatures
 972 {
 973         entity  targ;
 974         vector  blastorigin;
 975         vector  force;
 976         float   total_damage_to_creatures;
 977         entity  next;
 978         float   tfloordmg;
 979         float   tfloorforce;
 980
 981         float stat_damagedone;
 982
 983         if(RadiusDamage_running)
 984         {
 985                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 986                 return 0;
 987         }
 988
 989         RadiusDamage_running = 1;
 990
 991         tfloordmg = autocvar_g_throughfloor_damage;
 992         tfloorforce = autocvar_g_throughfloor_force;
 993
 994         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 995         total_damage_to_creatures = 0;
 996
 997         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 998                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 999                 {
1000                         force = inflictor.velocity;
1001                         if(vlen(force) == 0)
1002                                 force = '0 0 -1';
1003                         else
1004                                 force = normalize(force);
1005                         if(forceintensity >= 0)
1006                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1007                         else
1008                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1009                 }
1010
1011         stat_damagedone = 0;
1012
1013         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1014         while (targ)
1015         {
1016                 next = targ.chain;
1017                 if (targ != inflictor)
1018                         if (ignore != targ) if(targ.takedamage)
1019                         {
1020                                 vector nearest;
1021                                 vector diff;
1022                                 float power;
1023
1024                                 // LordHavoc: measure distance to nearest point on target (not origin)
1025                                 // (this guarentees 100% damage on a touch impact)
1026                                 nearest = targ.WarpZone_findradius_nearest;
1027                                 diff = targ.WarpZone_findradius_dist;
1028                                 // round up a little on the damage to ensure full damage on impacts
1029                                 // and turn the distance into a fraction of the radius
1030                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1031                                 //bprint(" ");
1032                                 //bprint(ftos(power));
1033                                 //if (targ == attacker)
1034                                 //      print(ftos(power), "\n");
1035                                 if (power > 0)
1036                                 {
1037                                         float finaldmg;
1038                                         if (power > 1)
1039                                                 power = 1;
1040                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1041                                         if (finaldmg > 0)
1042                                         {
1043                                                 float a;
1044                                                 float c;
1045                                                 vector hitloc;
1046                                                 vector myblastorigin;
1047                                                 vector center;
1048
1049                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1050
1051                                                 // if it's a player, use the view origin as reference
1052                                                 center = CENTER_OR_VIEWOFS(targ);
1053
1054                                                 force = normalize(center - myblastorigin);
1055                                                 force = force * (finaldmg / coredamage) * forceintensity;
1056                                                 hitloc = nearest;
1057
1058                                                 if(targ != directhitentity)
1059                                                 {
1060                                                         float hits;
1061                                                         float total;
1062                                                         float hitratio;
1063                                                         float mininv_f, mininv_d;
1064
1065                                                         // test line of sight to multiple positions on box,
1066                                                         // and do damage if any of them hit
1067                                                         hits = 0;
1068
1069                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1070                                                         // so for a given max stddev:
1071                                                         // n = (1 / (2 * max stddev of hitratio))^2
1072
1073                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1074                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1075
1076                                                         if(autocvar_g_throughfloor_debug)
1077                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1078
1079                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1080
1081                                                         if(autocvar_g_throughfloor_debug)
1082                                                                 print(sprintf(" steps=%f", total));
1083
1084                                                         if (targ.classname == "player")
1085                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1086                                                         else
1087                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1088
1089                                                         if(autocvar_g_throughfloor_debug)
1090                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1091
1092                                                         for(c = 0; c < total; ++c)
1093                                                         {
1094                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1095                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1096                                                                 if (trace_fraction == 1 || trace_ent == targ)
1097                                                                 {
1098                                                                         ++hits;
1099                                                                         if (hits > 1)
1100                                                                                 hitloc = hitloc + nearest;
1101                                                                         else
1102                                                                                 hitloc = nearest;
1103                                                                 }
1104                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1105                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1106                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1107                                                         }
1108
1109                                                         nearest = hitloc * (1 / max(1, hits));
1110                                                         hitratio = (hits / total);
1111                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1112                                                         finaldmg = finaldmg * a;
1113                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1114                                                         force = force * a;
1115
1116                                                         if(autocvar_g_throughfloor_debug)
1117                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1118                                                 }
1119
1120                                                 // laser force adjustments :P
1121                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1122                                                 {
1123                                                         if (targ == attacker)
1124                                                         {
1125                                                                 vector vel;
1126
1127                                                                 float force_zscale;
1128                                                                 float force_velocitybiasramp;
1129                                                                 float force_velocitybias;
1130
1131                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1132                                                                 if(deathtype & HITTYPE_SECONDARY)
1133                                                                 {
1134                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1135                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1136                                                                 }
1137                                                                 else
1138                                                                 {
1139                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1140                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1141                                                                 }
1142
1143                                                                 vel = targ.velocity;
1144                                                                 vel_z = 0;
1145                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1146                                                                 force =
1147                                                                         vlen(force)
1148                                                                         *
1149                                                                         normalize(normalize(force) + vel);
1150
1151                                                                 force_z *= force_zscale;
1152                                                         }
1153                                                         else
1154                                                         {
1155                                                                 if(deathtype & HITTYPE_SECONDARY)
1156                                                                 {
1157                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1158                                                                 }
1159                                                                 else
1160                                                                 {
1161                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1162                                                                 }
1163                                                         }
1164                                                 }
1165
1166                                                 //if (targ == attacker)
1167                                                 //{
1168                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1169                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1170                                                 //      print(" (", ftos(a), ")\n");
1171                                                 //}
1172                                                 if(finaldmg || vlen(force))
1173                                                 {
1174                                                         if(targ.iscreature)
1175                                                         {
1176                                                                 total_damage_to_creatures += finaldmg;
1177
1178                                                                 if(accuracy_isgooddamage(attacker, targ))
1179                                                                         stat_damagedone += finaldmg;
1180                                                         }
1181
1182                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1183                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1184                                                         else
1185                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1186                                                 }
1187                                         }
1188                                 }
1189                         }
1190                 targ = next;
1191         }
1192
1193         RadiusDamage_running = 0;
1194
1195         if(!DEATH_ISSPECIAL(deathtype))
1196                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1197
1198         return total_damage_to_creatures;
1199 }
1200
1201 .float fire_damagepersec;
1202 .float fire_endtime;
1203 .float fire_deathtype;
1204 .entity fire_owner;
1205 .float fire_hitsound;
1206 .entity fire_burner;
1207
1208 void fireburner_think();
1209
1210 float Fire_IsBurning(entity e)
1211 {
1212         return (time < e.fire_endtime);
1213 }
1214
1215 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1216 {
1217         float dps;
1218         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1219
1220         if(e.classname == "player")
1221         {
1222                 if(e.deadflag)
1223                         return -1;
1224         }
1225         else
1226         {
1227                 if(!e.fire_burner)
1228                 {
1229                         // print("adding a fire burner to ", e.classname, "\n");
1230                         e.fire_burner = spawn();
1231                         e.fire_burner.classname = "fireburner";
1232                         e.fire_burner.think = fireburner_think;
1233                         e.fire_burner.nextthink = time;
1234                         e.fire_burner.owner = e;
1235                 }
1236         }
1237
1238         t = max(t, 0.1);
1239         dps = d / t;
1240         if(Fire_IsBurning(e))
1241         {
1242                 mintime = e.fire_endtime - time;
1243                 maxtime = max(mintime, t);
1244
1245                 mindps = e.fire_damagepersec;
1246                 maxdps = max(mindps, dps);
1247
1248                 if(maxtime > mintime || maxdps > mindps)
1249                 {
1250                         // Constraints:
1251
1252                         // damage we have right now
1253                         mindamage = mindps * mintime;
1254
1255                         // damage we want to get
1256                         maxdamage = mindamage + d;
1257
1258                         // but we can't exceed maxtime * maxdps!
1259                         totaldamage = min(maxdamage, maxtime * maxdps);
1260
1261                         // LEMMA:
1262                         // Look at:
1263                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1264                         // We see:
1265                         // totaldamage <= maxtime * maxdps
1266                         // ==> totaldamage / maxdps <= maxtime.
1267                         // We also see:
1268                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1269                         //                     >= min(mintime, maxtime)
1270                         // ==> totaldamage / maxdps >= mintime.
1271
1272                         /*
1273                         // how long do we damage then?
1274                         // at least as long as before
1275                         // but, never exceed maxdps
1276                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1277                         */
1278
1279                         // alternate:
1280                         // at most as long as maximum allowed
1281                         // but, never below mindps
1282                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1283
1284                         // assuming t > mintime, dps > mindps:
1285                         // we get d = t * dps = maxtime * maxdps
1286                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1287                         // totaldamage / maxdps = maxtime
1288                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1289                         // FROM THIS:
1290                         // a) totaltime = max(mintime, maxtime) = maxtime
1291                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1292
1293                         // assuming t <= mintime:
1294                         // we get maxtime = mintime
1295                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1296                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1297
1298                         // assuming dps <= mindps:
1299                         // we get mindps = maxdps.
1300                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1301                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1302                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1303
1304                         e.fire_damagepersec = totaldamage / totaltime;
1305                         e.fire_endtime = time + totaltime;
1306                         if(totaldamage > 1.2 * mindamage)
1307                         {
1308                                 e.fire_deathtype = dt;
1309                                 if(e.fire_owner != o)
1310                                 {
1311                                         e.fire_owner = o;
1312                                         e.fire_hitsound = FALSE;
1313                                 }
1314                         }
1315                         if(accuracy_isgooddamage(o, e))
1316                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1317                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1318                 }
1319                 else
1320                         return 0;
1321         }
1322         else
1323         {
1324                 e.fire_damagepersec = dps;
1325                 e.fire_endtime = time + t;
1326                 e.fire_deathtype = dt;
1327                 e.fire_owner = o;
1328                 e.fire_hitsound = FALSE;
1329                 if(accuracy_isgooddamage(o, e))
1330                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1331                 return d;
1332         }
1333 }
1334
1335 void Fire_ApplyDamage(entity e)
1336 {
1337         float t, d, hi, ty;
1338         entity o;
1339
1340         if not(Fire_IsBurning(e))
1341                 return;
1342
1343         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1344         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1345                 o = e.fire_owner;
1346
1347         // water and slime stop fire
1348         if(e.waterlevel)
1349         if(e.watertype != CONTENT_LAVA)
1350                 e.fire_endtime = 0;
1351
1352         // ice stops fire
1353         if(e.freezetag_frozen)
1354                 e.fire_endtime = 0;
1355
1356         t = min(frametime, e.fire_endtime - time);
1357         d = e.fire_damagepersec * t;
1358
1359         hi = e.fire_owner.hitsound;
1360         ty = e.fire_owner.typehitsound;
1361         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1362         if(e.fire_hitsound && e.fire_owner)
1363         {
1364                 e.fire_owner.hitsound = hi;
1365                 e.fire_owner.typehitsound = ty;
1366         }
1367         e.fire_hitsound = TRUE;
1368
1369         if not(IS_INDEPENDENT_PLAYER(e))
1370         FOR_EACH_PLAYER(other) if(e != other)
1371         {
1372                 if(other.classname == "player")
1373                 if(other.deadflag == DEAD_NO)
1374                 if not(IS_INDEPENDENT_PLAYER(other))
1375                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1376                 {
1377                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1378                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1379                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1380                 }
1381         }
1382 }
1383
1384 void Fire_ApplyEffect(entity e)
1385 {
1386         if(Fire_IsBurning(e))
1387                 e.effects |= EF_FLAME;
1388         else
1389                 e.effects &~= EF_FLAME;
1390 }
1391
1392 void fireburner_think()
1393 {
1394         // for players, this is done in the regular loop
1395         if(wasfreed(self.owner))
1396         {
1397                 remove(self);
1398                 return;
1399         }
1400         Fire_ApplyEffect(self.owner);
1401         if(!Fire_IsBurning(self.owner))
1402         {
1403                 self.owner.fire_burner = world;
1404                 remove(self);
1405                 return;
1406         }
1407         Fire_ApplyDamage(self.owner);
1408         self.nextthink = time;
1409 }