qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         return TRUE;
  18 }
  19
  20 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, entity dmgowner)
  21 {
  22         // TODO maybe call this from non-edgedamage too?
  23         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  24
  25         entity e;
  26
  27         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  28                 deathtype |= 0x8000;
  29
  30         e = spawn();
  31         setorigin(e, org);
  32         e.projectiledeathtype = deathtype;
  33         e.dmg = coredamage;
  34         e.dmg_edge = edgedamage;
  35         e.dmg_radius = rad;
  36         e.dmg_force = vlen(force);
  37         e.velocity = force;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  42 }
  43
  44 #define DAMAGE_CENTERPRINT_SPACER NEWLINES
  45
  46 float checkrules_firstblood;
  47
  48 float yoda;
  49 float damage_goodhits;
  50 float damage_gooddamage;
  51 float headshot;
  52 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  53
  54 .float dmg_team;
  55 .float teamkill_complain;
  56 .float teamkill_soundtime;
  57 .entity teamkill_soundsource;
  58 .entity pusher;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teams_matter)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 106 {
 107         float w;
 108
 109         // TODO route through PlayerScores instead
 110         if(gameover) return;
 111
 112         if(f < 0)
 113         {
 114                 if(targ == attacker)
 115                 {
 116                         // suicide
 117                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 118                 }
 119                 else
 120                 {
 121                         // teamkill
 122                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 123                 }
 124         }
 125         else
 126         {
 127                 // regular frag
 128                 PlayerScore_Add(attacker, SP_KILLS, 1);
 129         }
 130
 131         PlayerScore_Add(targ, SP_DEATHS, 1);
 132
 133         if(g_arena || g_ca)
 134                 if(autocvar_g_arena_roundbased)
 135                         return;
 136
 137         if(targ != attacker) // not for suicides
 138         if(g_weaponarena_random)
 139         {
 140                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 141                 float culprit;
 142                 culprit = DEATH_WEAPONOF(deathtype);
 143                 if(!culprit || !(attacker.weapons & W_WeaponBit(culprit)))
 144                         culprit = attacker.weapon;
 145
 146                 if(g_weaponarena_random_with_laser && culprit == WEPBIT_LASER)
 147                 {
 148                         // no exchange
 149                 }
 150                 else
 151                 {
 152                         if(inWarmupStage)
 153                                 w = warmup_start_weapons;
 154                         else
 155                                 w = start_weapons;
 156
 157                         // all others (including the culprit): remove
 158                         w &~= attacker.weapons;
 159
 160                         // among the remaining ones, choose one by random
 161                         w = randombits(w, 1, FALSE);
 162                         if(w)
 163                         {
 164                                 attacker.weapons |= w;
 165                                 attacker.weapons &~= W_WeaponBit(culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(attacker.weapons & W_WeaponBit(attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211                 else if(g_ctf)
 212                 {
 213                         if(g_ctf_ignore_frags)
 214                                 f = 0;
 215                 }
 216         }
 217
 218         attacker.totalfrags += f;
 219
 220         if(f)
 221                 UpdateFrags(attacker, f);
 222 }
 223
 224 string AppendItemcodes(string s, entity player)
 225 {
 226         float w;
 227         w = player.weapon;
 228         //if(w == 0)
 229         //      w = player.switchweapon;
 230         if(w == 0)
 231                 w = player.cnt; // previous weapon!
 232         s = strcat(s, ftos(w));
 233         if(time < player.strength_finished)
 234                 s = strcat(s, "S");
 235         if(time < player.invincible_finished)
 236                 s = strcat(s, "I");
 237         if(player.flagcarried != world)
 238                 s = strcat(s, "F");
 239         if(player.BUTTON_CHAT)
 240                 s = strcat(s, "T");
 241         if(player.kh_next)
 242                 s = strcat(s, "K");
 243         if(player.runes)
 244                 s = strcat(s, "|", ftos(player.runes));
 245         return s;
 246 }
 247
 248 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 249 {
 250         string s;
 251         if(!autocvar_sv_eventlog)
 252                 return;
 253         s = strcat(":kill:", mode);
 254         s = strcat(s, ":", ftos(killer.playerid));
 255         s = strcat(s, ":", ftos(killed.playerid));
 256         s = strcat(s, ":type=", ftos(deathtype));
 257         s = strcat(s, ":items=");
 258         s = AppendItemcodes(s, killer);
 259         if(killed != killer)
 260         {
 261                 s = strcat(s, ":victimitems=");
 262                 s = AppendItemcodes(s, killed);
 263         }
 264         GameLogEcho(s);
 265 }
 266
 267 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 268 {
 269         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 270         WriteByte(MSG_ALL, TE_CSQC_NOTIFY);
 271         WriteByte(MSG_ALL, CSQC_KILLNOTIFY);
 272         WriteString(MSG_ALL, s1);
 273         WriteString(MSG_ALL, s2);
 274         WriteString(MSG_ALL, s3);
 275         WriteShort(MSG_ALL, msg);
 276         WriteByte(MSG_ALL, type);
 277 }
 278
 279 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 280 void Send_CSQC_Centerprint(entity e, string s1, string s2, float msg, float type)
 281 {
 282         if (clienttype(e) == CLIENTTYPE_REAL)
 283         {
 284                 msg_entity = e;
 285                 WRITESPECTATABLE_MSG_ONE({
 286                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 287                         WriteByte(MSG_ONE, TE_CSQC_NOTIFY);
 288                         WriteByte(MSG_ONE, CSQC_CENTERPRINT);
 289                         WriteString(MSG_ONE, s1);
 290                         WriteString(MSG_ONE, s2);
 291                         WriteShort(MSG_ONE, msg);
 292                         WriteByte(MSG_ONE, type);
 293                 });
 294         }
 295 }
 296
 297 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 298 {
 299         string  s, a, msg;
 300         float w, type;
 301
 302         if (targ.classname == "player" || targ.classname == "corpse")
 303         {
 304                 if (targ.classname == "corpse")
 305                         s = "A corpse";
 306                 else
 307                         s = targ.netname;
 308
 309                 a = attacker.netname;
 310
 311                 if (targ == attacker) // suicides
 312                 {
 313                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 314                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 315             if(!g_cts) // no "killed your own dumb self" message in CTS
 316                 Send_CSQC_Centerprint(targ, msg, "", deathtype, MSG_SUICIDE);
 317
 318                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 319                         {
 320                                 LogDeath("suicide", deathtype, targ, targ);
 321                                 GiveFrags(attacker, targ, -1, deathtype);
 322                         }
 323
 324                         if (targ.killcount > 2)
 325                                 msg = ftos(targ.killcount);
 326                         if(teams_matter && deathtype == DEATH_MIRRORDAMAGE)
 327                         {
 328                                 if(attacker.team == COLOR_TEAM1)
 329                                         deathtype = KILL_TEAM_RED;
 330                                 else
 331                                         deathtype = KILL_TEAM_BLUE;
 332                         }
 333
 334                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 335                 }
 336                 else if (attacker.classname == "player" || attacker.classname == "gib")
 337                 {
 338                         if(teams_matter && attacker.team == targ.team)
 339                         {
 340                                 if(attacker.team == COLOR_TEAM1)
 341                                         type = KILL_TEAM_RED;
 342                                 else
 343                                         type = KILL_TEAM_BLUE;
 344
 345                                 GiveFrags(attacker, targ, -1, deathtype);
 346
 347                                 Send_CSQC_Centerprint(attacker, s, "", type, MSG_KILL);
 348
 349                                 if (targ.killcount > 2) {
 350                                         msg = ftos(targ.killcount);
 351                                 }
 352
 353                                 if (attacker.killcount > 2) {
 354                                         msg = ftos(attacker.killcount);
 355                                         type = KILL_TEAM_SPREE;
 356                                 }
 357                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 358
 359                                 attacker.killcount = 0;
 360
 361                                 LogDeath("tk", deathtype, attacker, targ);
 362                         }
 363                         else
 364                         {
 365                                 if (!checkrules_firstblood)
 366                                 {
 367                                         checkrules_firstblood = TRUE;
 368                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 369                                         // TODO: make these print a newline if they dont
 370                                         Send_CSQC_Centerprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 371                                         Send_CSQC_Centerprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 372                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 373                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 374                                 }
 375
 376                                 if((autocvar_sv_fragmessage_information_typefrag) && (targ.BUTTON_CHAT)) {
 377                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_TYPEFRAG, MSG_KILL);
 378                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 379                                 } else {
 380                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_FRAG, MSG_KILL);
 381                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_FRAGGED, MSG_KILL);
 382                                 }
 383
 384                                 attacker.taunt_soundtime = time + 1;
 385
 386                                 // TODO: fix this?
 387                                 if (deathtype == DEATH_CUSTOM)
 388                                         msg = deathmessage;
 389                                 else
 390                                         msg = inflictor.message2;
 391
 392                                 if(strstrofs(msg, "%", 0) < 0)
 393                                         msg = strcat("%s ", msg, " by %s");
 394
 395                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 396
 397                                 if(g_ctf && targ.flagcarried)
 398                                 {
 399                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
 400                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
 401                                         GiveFrags(attacker, targ, 0, deathtype); // for logging
 402                                 }
 403                                 else
 404                                         GiveFrags(attacker, targ, 1, deathtype);
 405
 406                                 if (targ.killcount > 2) {
 407                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 408                                 }
 409
 410                                 attacker.killcount = attacker.killcount + 1;
 411
 412                                 if (attacker.killcount > 2) {
 413                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 414                                 }
 415                                 else if (attacker.killcount == 3)
 416                                 {
 417                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 418                                         AnnounceTo(attacker, "03kills");
 419                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 420                                 }
 421                                 else if (attacker.killcount == 5)
 422                                 {
 423                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 424                                         AnnounceTo(attacker, "05kills");
 425                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 426                                 }
 427                                 else if (attacker.killcount == 10)
 428                                 {
 429                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 430                                         AnnounceTo(attacker, "10kills");
 431                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 432                                 }
 433                                 else if (attacker.killcount == 15)
 434                                 {
 435                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 436                                         AnnounceTo(attacker, "15kills");
 437                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 438                                 }
 439                                 else if (attacker.killcount == 20)
 440                                 {
 441                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 442                                         AnnounceTo(attacker, "20kills");
 443                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 444                                 }
 445                                 else if (attacker.killcount == 25)
 446                                 {
 447                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 448                                         AnnounceTo(attacker, "25kills");
 449                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 450                                 }
 451                                 else if (attacker.killcount == 30)
 452                                 {
 453                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 454                                         AnnounceTo(attacker, "30kills");
 455                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 456                                 }
 457                                 LogDeath("frag", deathtype, attacker, targ);
 458                         }
 459                 }
 460                 else
 461                 {
 462                         Send_CSQC_Centerprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 463                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 464                                 msg = inflictor.message;
 465                         else if (deathtype == DEATH_CUSTOM)
 466                                 msg = deathmessage;
 467                         if(strstrofs(msg, "%", 0) < 0)
 468                                 msg = strcat("%s ", msg);
 469
 470                         GiveFrags(targ, targ, -1, deathtype);
 471                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 472                                 AnnounceTo(targ, "botlike");
 473                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 474                         }
 475                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 476
 477                         if (targ.killcount > 2)
 478                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 479
 480                         LogDeath("accident", deathtype, targ, targ);
 481                 }
 482
 483                 targ.death_origin = targ.origin;
 484                 if(targ != attacker)
 485                         targ.killer_origin = attacker.origin;
 486
 487                 // FIXME: this should go in PutClientInServer
 488                 if (targ.killcount)
 489                         targ.killcount = 0;
 490         }
 491 }
 492
 493 // these are updated by each Damage call for use in button triggering and such
 494 entity damage_targ;
 495 entity damage_inflictor;
 496 entity damage_attacker;
 497
 498 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 499 {
 500         // if the target is a player or dead body, activate damage effects
 501         if(targ.classname == "player" || targ.classname == "body")
 502                 Violence_DamageEffect_SetRepeat(targ, damage, DEATH_WEAPONOF(deathtype));
 503
 504         float mirrordamage;
 505         float mirrorforce;
 506         float teamdamage0;
 507         entity attacker_save;
 508         mirrordamage = 0;
 509         mirrorforce = 0;
 510
 511         if (gameover || targ.killcount == -666)
 512                 return;
 513
 514         local entity oldself;
 515         oldself = self;
 516         self = targ;
 517         damage_targ = targ;
 518         damage_inflictor = inflictor;
 519         damage_attacker = attacker;
 520                 attacker_save = attacker;
 521
 522         if(targ.classname == "player")
 523                 if(targ.hook)
 524                         if(targ.hook.aiment)
 525                                 if(targ.hook.aiment == attacker)
 526                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 527
 528         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 529         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 530         {
 531                 if(targ.classname == "player")
 532                         if not(IsDifferentTeam(targ, attacker))
 533                         {
 534                                 self = oldself;
 535                                 return;
 536                         }
 537         }
 538
 539         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 540         {
 541                 // These are ALWAYS lethal
 542                 // No damage modification here
 543                 // Instead, prepare the victim for his death...
 544                 targ.armorvalue = 0;
 545                 targ.spawnshieldtime = 0;
 546                 targ.health = 0.9; // this is < 1
 547                 targ.flags -= targ.flags & FL_GODMODE;
 548                 damage = 100000;
 549         }
 550         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 551         {
 552                 // no processing
 553         }
 554         else
 555         {
 556                 if (targ.classname == "player")
 557                 if (attacker.classname == "player")
 558                 if (!targ.isbot)
 559                 if (attacker.isbot)
 560                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 561
 562                 // nullify damage if teamplay is on
 563                 if(deathtype != DEATH_TELEFRAG)
 564                 if(attacker.classname == "player")
 565                 {
 566                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 567                         {
 568                                 damage = 0;
 569                                 force = '0 0 0';
 570                         }
 571                         else if(teams_matter && attacker.team == targ.team)
 572                         {
 573                                 if(autocvar_teamplay_mode == 1)
 574                                         damage = 0;
 575                                 else if(attacker != targ)
 576                                 {
 577                                         if(autocvar_teamplay_mode == 3)
 578                                                 damage = 0;
 579                                         else if(autocvar_teamplay_mode == 4)
 580                                         {
 581                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 582                                                 {
 583                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 584                                                         attacker.dmg_team = attacker.dmg_team + damage;
 585                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 586                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 587                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 588                                                         if(g_minstagib)
 589                                                         {
 590                                                                 if(autocvar_g_friendlyfire == 0)
 591                                                                         damage = 0;
 592                                                         }
 593                                                         else if(g_ca)
 594                                                                 damage = 0;
 595                                                         else
 596                                                                 damage = autocvar_g_friendlyfire * damage;
 597                                                         // mirrordamage will be used LATER
 598
 599                                                         if(autocvar_g_mirrordamage_virtual)
 600                                                         {
 601                                                                 vector v;
 602                                                                 v = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 603                                                                 attacker.dmg_take += v_x;
 604                                                                 attacker.dmg_save += v_y;
 605                                                                 attacker.dmg_inflictor = inflictor;
 606                                                                 mirrordamage = 0;
 607                                                                 mirrorforce = 0;
 608                                                         }
 609
 610                                                         if(autocvar_g_friendlyfire_virtual)
 611                                                         {
 612                                                                 vector v;
 613                                                                 v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 614                                                                 targ.dmg_take += v_x;
 615                                                                 targ.dmg_save += v_y;
 616                                                                 targ.dmg_inflictor = inflictor;
 617                                                                 damage = 0;
 618                                 if(!autocvar_g_friendlyfire_virtual_force)
 619                                     force = '0 0 0';
 620                                                         }
 621                                                 }
 622                                                 else
 623                                                         damage = 0;
 624                                         }
 625                                 }
 626                         }
 627                 }
 628
 629                 if(targ.classname == "player")
 630                 if(attacker.classname == "player")
 631                 if(attacker != targ)
 632                 {
 633                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 634                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 635                 }
 636
 637                 if(targ.classname == "player")
 638                 if (g_minstagib)
 639                 {
 640                         if ((deathtype == DEATH_FALL)  ||
 641                                 (deathtype == DEATH_DROWN) ||
 642                                 (deathtype == DEATH_SLIME) ||
 643                                 (deathtype == DEATH_LAVA)  ||
 644                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 645                         {
 646                                 self = oldself;
 647                                 return;
 648                         }
 649                         if(damage > 0)
 650                             damage = 10000;
 651                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 652                         {
 653                                 targ.armorvalue -= 1;
 654                                 centerprint(targ, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(targ.armorvalue)));
 655                                 damage = 0;
 656                                 targ.hitsound += 1;
 657                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 658                         }
 659                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 660                         {
 661                                 damage = 0;
 662                                 mirrordamage = 0;
 663                                 if (targ != attacker)
 664                                 {
 665                                         if ((targ.health >= 1) && (targ.classname == "player"))
 666                                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "Secondary fire inflicts no damage!"));
 667                                         force = '0 0 0';
 668                                         // keep mirrorforce
 669                                         attacker = targ;
 670                                 }
 671                         }
 672                 }
 673
 674                 if not(DEATH_ISSPECIAL(deathtype))
 675                 {
 676                         damage *= g_weapondamagefactor;
 677                         mirrordamage *= g_weapondamagefactor;
 678                         force = force * g_weaponforcefactor;
 679                         mirrorforce *= g_weaponforcefactor;
 680                 }
 681
 682                 // should this be changed at all? If so, in what way?
 683                 frag_attacker = attacker;
 684                 frag_target = targ;
 685                 frag_damage = damage;
 686                 frag_force = force;
 687         frag_deathtype = deathtype;
 688                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 689                 damage = frag_damage;
 690                 force = frag_force;
 691
 692                 // apply strength multiplier
 693                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 694                 {
 695                         if(targ == attacker)
 696                         {
 697                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 698                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 699                         }
 700                         else
 701                         {
 702                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 703                                 force = force * autocvar_g_balance_powerup_strength_force;
 704                         }
 705                 }
 706
 707                 // apply invincibility multiplier
 708                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 709                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 710
 711                 if (targ == attacker)
 712                 {
 713                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 714                                 damage = 0;
 715                         else
 716                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 717                 }
 718
 719                 // CTF: reduce damage/force
 720                 if(g_ctf)
 721                 if(targ == attacker)
 722                 if(targ.flagcarried)
 723                 {
 724                         damage = damage * autocvar_g_ctf_flagcarrier_selfdamage;
 725                         force = force * autocvar_g_ctf_flagcarrier_selfforce;
 726                 }
 727
 728                 if(g_runematch)
 729                 {
 730                         // apply strength rune
 731                         if (attacker.runes & RUNE_STRENGTH)
 732                         {
 733                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 734                                 {
 735                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 736                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 737                                 }
 738                                 else
 739                                 {
 740                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 741                                         force = force * autocvar_g_balance_rune_strength_force;
 742                                 }
 743                         }
 744                         else if (attacker.runes & CURSE_WEAK)
 745                         {
 746                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 747                                 force = force * autocvar_g_balance_curse_weak_force;
 748                         }
 749
 750                         // apply defense rune
 751                         if (targ.runes & RUNE_DEFENSE)
 752                         {
 753                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 754                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 755                                 else
 756                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 757                         }
 758                         else if (targ.runes & CURSE_VULNER)
 759                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 760                 }
 761
 762                 // count the damage
 763                 if(attacker)
 764                 if(!targ.deadflag)
 765                 if(targ.takedamage == DAMAGE_AIM)
 766                 if(targ != attacker)
 767                 {
 768                         if(targ.classname == "player")
 769                         {
 770                                 // HEAD SHOT:
 771                                 // find height of hit on player axis
 772                                 // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 773                                 vector headmins, headmaxs, org;
 774                                 org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 775                                 headmins = org + GetHeadshotMins(targ);
 776                                 headmaxs = org + GetHeadshotMaxs(targ);
 777                                 if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 778                                 {
 779                                         deathtype |= HITTYPE_HEADSHOT;
 780                                 }
 781                         }
 782                         else if(targ.classname == "turret_head")
 783                         {
 784                                 deathtype |= HITTYPE_HEADSHOT;
 785                         }
 786                         if(deathtype & HITTYPE_HEADSHOT)
 787                                 damage *= 1 + damage_headshotbonus;
 788
 789                         if(targ.classname == "player")
 790                         {
 791                                 if(IsDifferentTeam(targ, attacker))
 792                                 {
 793                                         if(damage > 0)
 794                                         {
 795                                                 if(deathtype != DEATH_FIRE)
 796                                                 {
 797                                                         if(targ.BUTTON_CHAT)
 798                                                                 attacker.typehitsound += 1;
 799                                                         else
 800                                                                 attacker.hitsound += 1;
 801                                                 }
 802
 803                                                 damage_goodhits += 1;
 804                                                 damage_gooddamage += damage;
 805
 806                                                 if not(DEATH_ISSPECIAL(deathtype))
 807                                                 {
 808                                                         if(!g_minstagib)
 809                                                         if(IsFlying(targ))
 810                                                                 yoda = 1;
 811
 812                                                         if(g_minstagib)
 813                                                         if(targ.items & IT_STRENGTH)
 814                                                                 yoda = 1;
 815
 816                                                         if(deathtype & HITTYPE_HEADSHOT)
 817                                                                 headshot = 1;
 818                                                 }
 819                                                 if(g_ca)
 820                                                         PlayerScore_Add(attacker, SP_SCORE, damage * autocvar_g_ca_damage2score_multiplier);
 821                                         }
 822                                 }
 823                                 else
 824                                 {
 825                                         if(deathtype != DEATH_FIRE)
 826                                         {
 827                                                 attacker.typehitsound += 1;
 828                                         }
 829                                         if(mirrordamage > 0)
 830                                                 if(time > attacker.teamkill_complain)
 831                                                 {
 832                                                         attacker.teamkill_complain = time + 5;
 833                                                         attacker.teamkill_soundtime = time + 0.4;
 834                                                         attacker.teamkill_soundsource = targ;
 835                                                 }
 836                                 }
 837                         }
 838                 }
 839         }
 840
 841         // apply push
 842         if (self.damageforcescale)
 843         if (vlen(force))
 844         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 845         {
 846                 self.velocity = self.velocity + damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 847                 self.flags &~= FL_ONGROUND;
 848                 UpdateCSQCProjectile(self);
 849         }
 850         // apply damage
 851         if (damage != 0 || (self.damageforcescale && vlen(force)))
 852         if (self.event_damage)
 853                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 854         self = oldself;
 855
 856         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 857         {
 858                 if(g_runematch)
 859                 {
 860                         if (attacker.runes & RUNE_VAMPIRE)
 861                         {
 862                         // apply vampire rune
 863                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 864                                 {
 865                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 866                                         attacker.health = bound(
 867                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 868                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 869                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 870                                 }
 871                                 else
 872                                 {
 873                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 874                                         attacker.health = bound(
 875                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 876                                                                                         // empathy won't let you gain health in the same way...
 877                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 878                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 879                                         }
 880                         }
 881                         // apply empathy curse
 882                         else if (attacker.runes & CURSE_EMPATHY)
 883                         {
 884                                 attacker.health = bound(
 885                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 886                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 887                                         attacker.health);
 888                         }
 889                 }
 890         }
 891
 892         // apply mirror damage if any
 893         if(mirrordamage > 0 || mirrorforce > 0)
 894         {
 895                 attacker = attacker_save;
 896                 if(g_minstagib)
 897                 if(mirrordamage > 0)
 898                 {
 899                         // just lose extra LIVES, don't kill the player for mirror damage
 900                         if(attacker.armorvalue > 0)
 901                         {
 902                                 attacker.armorvalue = attacker.armorvalue - 1;
 903                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 904                                 attacker.hitsound += 1;
 905                         }
 906                         mirrordamage = 0;
 907                 }
 908
 909                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 910                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 911         }
 912 }
 913
 914 float RadiusDamage_running;
 915 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 916 // Returns total damage applies to creatures
 917 {
 918         entity  targ;
 919         float   finaldmg;
 920         float   power;
 921         vector  blastorigin;
 922         vector  force;
 923         vector  diff;
 924         vector  center;
 925         vector  nearest;
 926         float   total_damage_to_creatures;
 927         entity  next;
 928         float   tfloordmg;
 929         float   tfloorforce;
 930
 931         float stat_damagedone;
 932
 933         if(RadiusDamage_running)
 934         {
 935                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 936                 return 0;
 937         }
 938
 939         RadiusDamage_running = 1;
 940
 941         tfloordmg = autocvar_g_throughfloor_damage;
 942         tfloorforce = autocvar_g_throughfloor_force;
 943
 944         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 945         total_damage_to_creatures = 0;
 946
 947         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 948         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 949         {
 950                 force = inflictor.velocity;
 951                 if(vlen(force) == 0)
 952                         force = '0 0 -1';
 953                 else
 954                         force = normalize(force);
 955                 if(forceintensity >= 0)
 956                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, attacker);
 957                 else
 958                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, attacker);
 959         }
 960
 961         stat_damagedone = 0;
 962
 963         targ = WarpZone_FindRadius (blastorigin, rad, FALSE);
 964         while (targ)
 965         {
 966                 next = targ.chain;
 967                 if (targ != inflictor)
 968                         if (ignore != targ) if(targ.takedamage)
 969                         {
 970                                 // LordHavoc: measure distance to nearest point on target (not origin)
 971                                 // (this guarentees 100% damage on a touch impact)
 972                                 nearest = targ.WarpZone_findradius_nearest;
 973                                 diff = targ.WarpZone_findradius_dist;
 974                                 // round up a little on the damage to ensure full damage on impacts
 975                                 // and turn the distance into a fraction of the radius
 976                                 power = 1 - ((vlen (diff) - 2) / rad);
 977                                 //bprint(" ");
 978                                 //bprint(ftos(power));
 979                                 //if (targ == attacker)
 980                                 //      print(ftos(power), "\n");
 981                                 if (power > 0)
 982                                 {
 983                                         if (power > 1)
 984                                                 power = 1;
 985                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 986                                         if (finaldmg > 0)
 987                                         {
 988                                                 local float a;
 989                                                 local float c;
 990                                                 local float hits;
 991                                                 local float total;
 992                                                 local float hitratio;
 993                                                 local vector hitloc;
 994                                                 local vector myblastorigin;
 995                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 996                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
 997                                                 // if it's a player, use the view origin as reference
 998                                                 if (targ.classname == "player")
 999                                                         center = targ.origin + targ.view_ofs;
1000                                                 force = normalize(center - myblastorigin);
1001                                                 force = force * (finaldmg / coredamage) * forceintensity;
1002                                                 // test line of sight to multiple positions on box,
1003                                                 // and do damage if any of them hit
1004                                                 hits = 0;
1005                                                 if (targ.classname == "player")
1006                                                         total = ceil(bound(1, finaldmg, 50));
1007                                                 else
1008                                                         total = ceil(bound(1, finaldmg/10, 5));
1009                                                 hitloc = nearest;
1010                                                 c = 0;
1011                                                 while (c < total)
1012                                                 {
1013                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1014                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1015                                                         if (trace_fraction == 1 || trace_ent == targ)
1016                                                         {
1017                                                                 hits = hits + 1;
1018                                                                 if (hits > 1)
1019                                                                         hitloc = hitloc + nearest;
1020                                                                 else
1021                                                                         hitloc = nearest;
1022                                                         }
1023                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1024                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1025                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1026                                                         c = c + 1;
1027                                                 }
1028                                                 nearest = hitloc * (1 / max(1, hits));
1029                                                 hitratio = (hits / total);
1030                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1031                                                 finaldmg = finaldmg * a;
1032                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1033                                                 force = force * a;
1034
1035                                                 // laser force adjustments :P
1036                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1037                                                 {
1038                             if (targ == attacker)
1039                             {
1040                                 vector vel;
1041
1042                                 float force_zscale;
1043                                 float force_velocitybiasramp;
1044                                 float force_velocitybias;
1045
1046                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1047                                 if(deathtype & HITTYPE_SECONDARY)
1048                                 {
1049                                     force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1050                                     force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1051                                 }
1052                                 else
1053                                 {
1054                                     force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1055                                     force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1056                                 }
1057
1058                                 vel = targ.velocity;
1059                                 vel_z = 0;
1060                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1061                                 force =
1062                                     vlen(force)
1063                                     *
1064                                     normalize(normalize(force) + vel);
1065
1066                                 force_z *= force_zscale;
1067                             }
1068                             else
1069                             {
1070                                 if(deathtype & HITTYPE_SECONDARY)
1071                                 {
1072                                     force *= autocvar_g_balance_laser_secondary_force_other_scale;
1073                                 }
1074                                 else
1075                                 {
1076                                     force *= autocvar_g_balance_laser_primary_force_other_scale;
1077                                 }
1078                             }
1079                                                 }
1080
1081                                                 //if (targ == attacker)
1082                                                 //{
1083                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1084                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1085                                                 //      print(" (", ftos(a), ")\n");
1086                                                 //}
1087                                                 if(hits || tfloordmg || tfloorforce)
1088                                                 {
1089                                                         if(targ.iscreature)
1090                                                         {
1091                                                                 total_damage_to_creatures += finaldmg;
1092
1093                                                                 if(accuracy_isgooddamage(attacker, targ))
1094                                                                         stat_damagedone += finaldmg;
1095                                                         }
1096
1097                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1098                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1099                                                         else
1100                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1101                                                 }
1102                                         }
1103                                 }
1104                         }
1105                 targ = next;
1106         }
1107
1108         RadiusDamage_running = 0;
1109
1110         if(!DEATH_ISSPECIAL(deathtype))
1111                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1112
1113         return total_damage_to_creatures;
1114 }
1115
1116 .float fire_damagepersec;
1117 .float fire_endtime;
1118 .float fire_deathtype;
1119 .entity fire_owner;
1120 .float fire_hitsound;
1121 .entity fire_burner;
1122
1123 void fireburner_think();
1124
1125 float Fire_IsBurning(entity e)
1126 {
1127         return (time < e.fire_endtime);
1128 }
1129
1130 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1131 {
1132         float dps;
1133         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1134
1135         if(e.classname == "player")
1136         {
1137                 if(e.deadflag)
1138                         return -1;
1139         }
1140         else
1141         {
1142                 if(!e.fire_burner)
1143                 {
1144                         // print("adding a fire burner to ", e.classname, "\n");
1145                         e.fire_burner = spawn();
1146                         e.fire_burner.classname = "fireburner";
1147                         e.fire_burner.think = fireburner_think;
1148                         e.fire_burner.nextthink = time;
1149                         e.fire_burner.owner = e;
1150                 }
1151         }
1152
1153         t = max(t, 0.1);
1154         dps = d / t;
1155         if(Fire_IsBurning(e))
1156         {
1157                 mintime = e.fire_endtime - time;
1158                 maxtime = max(mintime, t);
1159
1160                 mindps = e.fire_damagepersec;
1161                 maxdps = max(mindps, dps);
1162
1163                 if(maxtime > mintime || maxdps > mindps)
1164                 {
1165                         mindamage = mindps * mintime;
1166                         maxdamage = mindamage + d;
1167
1168                         // interval [mintime, maxtime] * [mindps, maxdps]
1169                         // intersected with
1170                         // [mindamage, maxdamage]
1171                         // maximum of this!
1172
1173                         if(maxdamage >= maxtime * maxdps)
1174                         {
1175                                 totaltime = maxtime;
1176                                 totaldamage = maxtime * maxdps;
1177
1178                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1179                         }
1180                         else
1181                         {
1182                                 // maxdamage is inside the interval!
1183                                 // first, try to use mindps; only if this fails, increase dps as needed
1184                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1185                                 totaldamage = maxdamage;
1186                                 // can totaldamage / totaltime be >= maxdps?
1187                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1188                                 // we know maxdamage < maxtime * maxdps
1189                                 // so it cannot be
1190
1191                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1192                         }
1193
1194                         // total conditions for increasing:
1195                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1196                         // however:
1197                         //     if maxtime = mintime, maxdps = mindps
1198                         // then:
1199                         //     maxdamage = mindamage + d
1200                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1201                         // so the last condition is not needed
1202
1203                         e.fire_damagepersec = totaldamage / totaltime;
1204                         e.fire_endtime = time + totaltime;
1205                         if(totaldamage > 1.2 * mindamage)
1206                         {
1207                                 e.fire_deathtype = dt;
1208                                 if(e.fire_owner != o)
1209                                 {
1210                                         e.fire_owner = o;
1211                                         e.fire_hitsound = FALSE;
1212                                 }
1213                         }
1214                         if(accuracy_isgooddamage(o, e))
1215                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1216                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1217                 }
1218                 else
1219                         return 0;
1220         }
1221         else
1222         {
1223                 e.fire_damagepersec = dps;
1224                 e.fire_endtime = time + t;
1225                 e.fire_deathtype = dt;
1226                 e.fire_owner = o;
1227                 e.fire_hitsound = FALSE;
1228                 if(accuracy_isgooddamage(o, e))
1229                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1230                 return d;
1231         }
1232 }
1233
1234 void Fire_ApplyDamage(entity e)
1235 {
1236         float t, d, hi, ty;
1237         entity o;
1238
1239         if not(Fire_IsBurning(e))
1240                 return;
1241
1242         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1243         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1244                 o = e.fire_owner;
1245
1246         // water and slime stop fire
1247         if(e.waterlevel)
1248         if(e.watertype != CONTENT_LAVA)
1249                 e.fire_endtime = 0;
1250
1251         // ice stops fire
1252         if(e.freezetag_frozen)
1253                 e.fire_endtime = 0;
1254
1255         t = min(frametime, e.fire_endtime - time);
1256         d = e.fire_damagepersec * t;
1257
1258         hi = e.fire_owner.hitsound;
1259         ty = e.fire_owner.typehitsound;
1260         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1261         if(e.fire_hitsound && e.fire_owner)
1262         {
1263                 e.fire_owner.hitsound = hi;
1264                 e.fire_owner.typehitsound = ty;
1265         }
1266         e.fire_hitsound = TRUE;
1267
1268         if not(IS_INDEPENDENT_PLAYER(e))
1269         FOR_EACH_PLAYER(other) if(e != other)
1270         {
1271                 if(other.classname == "player")
1272                 if(other.deadflag == DEAD_NO)
1273                 if not(IS_INDEPENDENT_PLAYER(other))
1274                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1275                 {
1276                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1277                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1278                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1279                 }
1280         }
1281 }
1282
1283 void Fire_ApplyEffect(entity e)
1284 {
1285         if(Fire_IsBurning(e))
1286                 e.effects |= EF_FLAME;
1287         else
1288                 e.effects &~= EF_FLAME;
1289 }
1290
1291 void fireburner_think()
1292 {
1293         // for players, this is done in the regular loop
1294         if(wasfreed(self.owner))
1295         {
1296                 remove(self);
1297                 return;
1298         }
1299         Fire_ApplyEffect(self.owner);
1300         if(!Fire_IsBurning(self.owner))
1301         {
1302                 self.owner.fire_burner = world;
1303                 remove(self);
1304                 return;
1305         }
1306         Fire_ApplyDamage(self.owner);
1307         self.nextthink = time;
1308 }