qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         return TRUE;
  18 }
  19
  20 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, entity dmgowner)
  21 {
  22         // TODO maybe call this from non-edgedamage too?
  23         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  24
  25         entity e;
  26
  27         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  28                 deathtype |= 0x8000;
  29
  30         e = spawn();
  31         setorigin(e, org);
  32         e.projectiledeathtype = deathtype;
  33         e.dmg = coredamage;
  34         e.dmg_edge = edgedamage;
  35         e.dmg_radius = rad;
  36         e.dmg_force = vlen(force);
  37         e.velocity = force;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  42 }
  43
  44 float checkrules_firstblood;
  45
  46 float yoda;
  47 float damage_goodhits;
  48 float damage_gooddamage;
  49 float headshot;
  50 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  51
  52 .float dmg_team;
  53 .float teamkill_complain;
  54 .float teamkill_soundtime;
  55 .entity teamkill_soundsource;
  56 .entity pusher;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 vector GetHeadshotMins(entity targ)
  88 {
  89         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  90 }
  91 vector GetHeadshotMaxs(entity targ)
  92 {
  93         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  94 }
  95
  96 void UpdateFrags(entity player, float f)
  97 {
  98         PlayerTeamScore_AddScore(player, f);
  99 }
 100
 101 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 102 void W_SwitchWeapon_Force(entity e, float w);
 103 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 104 {
 105         float w;
 106
 107         // TODO route through PlayerScores instead
 108         if(gameover) return;
 109
 110         if(f < 0)
 111         {
 112                 if(targ == attacker)
 113                 {
 114                         // suicide
 115                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 116                 }
 117                 else
 118                 {
 119                         // teamkill
 120                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 121                 }
 122         }
 123         else
 124         {
 125                 // regular frag
 126                 PlayerScore_Add(attacker, SP_KILLS, 1);
 127                 if(targ.playerid)
 128                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 129         }
 130
 131         PlayerScore_Add(targ, SP_DEATHS, 1);
 132
 133         if(g_arena || g_ca)
 134                 if(autocvar_g_arena_roundbased)
 135                         return;
 136
 137         if(targ != attacker) // not for suicides
 138         if(g_weaponarena_random)
 139         {
 140                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 141                 float culprit;
 142                 culprit = DEATH_WEAPONOF(deathtype);
 143                 if(!culprit || !(attacker.weapons & W_WeaponBit(culprit)))
 144                         culprit = attacker.weapon;
 145
 146                 if(g_weaponarena_random_with_laser && culprit == WEPBIT_LASER)
 147                 {
 148                         // no exchange
 149                 }
 150                 else
 151                 {
 152                         if(inWarmupStage)
 153                                 w = warmup_start_weapons;
 154                         else
 155                                 w = start_weapons;
 156
 157                         // all others (including the culprit): remove
 158                         w &~= attacker.weapons;
 159
 160                         // among the remaining ones, choose one by random
 161                         w = randombits(w, 1, FALSE);
 162                         if(w)
 163                         {
 164                                 attacker.weapons |= w;
 165                                 attacker.weapons &~= W_WeaponBit(culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(attacker.weapons & W_WeaponBit(attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211                 else if(g_ctf)
 212                 {
 213                         if(g_ctf_ignore_frags)
 214                                 f = 0;
 215                 }
 216         }
 217
 218         attacker.totalfrags += f;
 219
 220         if(f)
 221                 UpdateFrags(attacker, f);
 222 }
 223
 224 string AppendItemcodes(string s, entity player)
 225 {
 226         float w;
 227         w = player.weapon;
 228         //if(w == 0)
 229         //      w = player.switchweapon;
 230         if(w == 0)
 231                 w = player.cnt; // previous weapon!
 232         s = strcat(s, ftos(w));
 233         if(time < player.strength_finished)
 234                 s = strcat(s, "S");
 235         if(time < player.invincible_finished)
 236                 s = strcat(s, "I");
 237         if(player.flagcarried != world)
 238                 s = strcat(s, "F");
 239         if(player.BUTTON_CHAT)
 240                 s = strcat(s, "T");
 241         if(player.kh_next)
 242                 s = strcat(s, "K");
 243         if(player.runes)
 244                 s = strcat(s, "|", ftos(player.runes));
 245         return s;
 246 }
 247
 248 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 249 {
 250         string s;
 251         if(!autocvar_sv_eventlog)
 252                 return;
 253         s = strcat(":kill:", mode);
 254         s = strcat(s, ":", ftos(killer.playerid));
 255         s = strcat(s, ":", ftos(killed.playerid));
 256         s = strcat(s, ":type=", ftos(deathtype));
 257         s = strcat(s, ":items=");
 258         s = AppendItemcodes(s, killer);
 259         if(killed != killer)
 260         {
 261                 s = strcat(s, ":victimitems=");
 262                 s = AppendItemcodes(s, killed);
 263         }
 264         GameLogEcho(s);
 265 }
 266
 267 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 268 {
 269         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 270         WriteByte(MSG_ALL, TE_CSQC_KILLNOTIFY);
 271         WriteString(MSG_ALL, s1);
 272         WriteString(MSG_ALL, s2);
 273         WriteString(MSG_ALL, s3);
 274         WriteShort(MSG_ALL, msg);
 275         WriteByte(MSG_ALL, type);
 276 }
 277
 278 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 279 void Send_CSQC_KillCenterprint(entity e, string s1, string s2, float msg, float type)
 280 {
 281         if (clienttype(e) == CLIENTTYPE_REAL)
 282         {
 283                 msg_entity = e;
 284                 WRITESPECTATABLE_MSG_ONE({
 285                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 286                         WriteByte(MSG_ONE, TE_CSQC_KILLCENTERPRINT);
 287                         WriteString(MSG_ONE, s1);
 288                         WriteString(MSG_ONE, s2);
 289                         WriteShort(MSG_ONE, msg);
 290                         WriteByte(MSG_ONE, type);
 291                 });
 292         }
 293 }
 294
 295 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 296 {
 297         string  s, a, msg;
 298         float w, type;
 299
 300         if (targ.classname == "player")
 301         {
 302                 s = targ.netname;
 303                 a = attacker.netname;
 304
 305                 if (targ == attacker) // suicides
 306                 {
 307                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 308                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 309             if(!g_cts) // no "killed your own dumb self" message in CTS
 310                 Send_CSQC_KillCenterprint(targ, msg, "", deathtype, MSG_SUICIDE);
 311
 312                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 313                         {
 314                                 LogDeath("suicide", deathtype, targ, targ);
 315                                 GiveFrags(attacker, targ, -1, deathtype);
 316                         }
 317
 318                         if (targ.killcount > 2)
 319                                 msg = ftos(targ.killcount);
 320                         if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 321                         {
 322                                 if(attacker.team == COLOR_TEAM1)
 323                                         deathtype = KILL_TEAM_RED;
 324                                 else
 325                                         deathtype = KILL_TEAM_BLUE;
 326                         }
 327
 328                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 329                 }
 330                 else if (attacker.classname == "player")
 331                 {
 332                         if(teamplay && attacker.team == targ.team)
 333                         {
 334                                 if(attacker.team == COLOR_TEAM1)
 335                                         type = KILL_TEAM_RED;
 336                                 else
 337                                         type = KILL_TEAM_BLUE;
 338
 339                                 GiveFrags(attacker, targ, -1, deathtype);
 340
 341                                 Send_CSQC_KillCenterprint(attacker, s, "", type, MSG_KILL);
 342
 343                                 if (targ.killcount > 2) {
 344                                         msg = ftos(targ.killcount);
 345                                 }
 346
 347                                 if (attacker.killcount > 2) {
 348                                         msg = ftos(attacker.killcount);
 349                                         type = KILL_TEAM_SPREE;
 350                                 }
 351                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 352
 353                                 attacker.killcount = 0;
 354
 355                                 LogDeath("tk", deathtype, attacker, targ);
 356                         }
 357                         else
 358                         {
 359                                 if (!checkrules_firstblood)
 360                                 {
 361                                         checkrules_firstblood = TRUE;
 362                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 363                                         // TODO: make these print a newline if they dont
 364                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 365                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 366                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 367                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 368                                 }
 369
 370                                 if((autocvar_sv_fragmessage_information_typefrag) && (targ.BUTTON_CHAT)) {
 371                                         Send_CSQC_KillCenterprint(attacker, s, GetAdvancedDeathReports(targ), KILL_TYPEFRAG, MSG_KILL);
 372                                         Send_CSQC_KillCenterprint(targ, a, GetAdvancedDeathReports(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 373                                 } else {
 374                                         Send_CSQC_KillCenterprint(attacker, s, GetAdvancedDeathReports(targ), KILL_FRAG, MSG_KILL);
 375                                         Send_CSQC_KillCenterprint(targ, a, GetAdvancedDeathReports(attacker), KILL_FRAGGED, MSG_KILL);
 376                                 }
 377
 378                                 attacker.taunt_soundtime = time + 1;
 379
 380                                 // TODO: fix this?
 381                                 if (deathtype == DEATH_CUSTOM)
 382                                         msg = deathmessage;
 383                                 else
 384                                         msg = inflictor.message2;
 385
 386                                 if(strstrofs(msg, "%", 0) < 0)
 387                                         msg = strcat("%s ", msg, " by %s");
 388
 389                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 390
 391                                 if(g_ctf && targ.flagcarried)
 392                                 {
 393                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
 394                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
 395                                         GiveFrags(attacker, targ, 0, deathtype); // for logging
 396                                 }
 397                                 else
 398                                         GiveFrags(attacker, targ, 1, deathtype);
 399
 400                                 if (targ.killcount > 2) {
 401                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 402                                 }
 403
 404                                 attacker.killcount = attacker.killcount + 1;
 405
 406                                 if (attacker.killcount > 2) {
 407                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 408                                 }
 409                                 else if (attacker.killcount == 3)
 410                                 {
 411                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 412                                         AnnounceTo(attacker, "03kills");
 413                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 414                                 }
 415                                 else if (attacker.killcount == 5)
 416                                 {
 417                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 418                                         AnnounceTo(attacker, "05kills");
 419                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 420                                 }
 421                                 else if (attacker.killcount == 10)
 422                                 {
 423                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 424                                         AnnounceTo(attacker, "10kills");
 425                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 426                                 }
 427                                 else if (attacker.killcount == 15)
 428                                 {
 429                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 430                                         AnnounceTo(attacker, "15kills");
 431                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 432                                 }
 433                                 else if (attacker.killcount == 20)
 434                                 {
 435                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 436                                         AnnounceTo(attacker, "20kills");
 437                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 438                                 }
 439                                 else if (attacker.killcount == 25)
 440                                 {
 441                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 442                                         AnnounceTo(attacker, "25kills");
 443                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 444                                 }
 445                                 else if (attacker.killcount == 30)
 446                                 {
 447                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 448                                         AnnounceTo(attacker, "30kills");
 449                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 450                                 }
 451                                 LogDeath("frag", deathtype, attacker, targ);
 452                         }
 453                 }
 454                 else
 455                 {
 456                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 457                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 458                                 msg = inflictor.message;
 459                         else if (deathtype == DEATH_CUSTOM)
 460                                 msg = deathmessage;
 461                         if(strstrofs(msg, "%", 0) < 0)
 462                                 msg = strcat("%s ", msg);
 463
 464                         GiveFrags(targ, targ, -1, deathtype);
 465                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 466                                 AnnounceTo(targ, "botlike");
 467                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 468                         }
 469                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 470
 471                         if (targ.killcount > 2)
 472                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 473
 474                         LogDeath("accident", deathtype, targ, targ);
 475                 }
 476
 477                 targ.death_origin = targ.origin;
 478                 if(targ != attacker)
 479                         targ.killer_origin = attacker.origin;
 480
 481                 // FIXME: this should go in PutClientInServer
 482                 if (targ.killcount)
 483                         targ.killcount = 0;
 484         }
 485 }
 486
 487 // these are updated by each Damage call for use in button triggering and such
 488 entity damage_targ;
 489 entity damage_inflictor;
 490 entity damage_attacker;
 491
 492 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 493 {
 494         float mirrordamage;
 495         float mirrorforce;
 496         float teamdamage0;
 497         entity attacker_save;
 498         mirrordamage = 0;
 499         mirrorforce = 0;
 500
 501         if (gameover || targ.killcount == -666)
 502                 return;
 503
 504         local entity oldself;
 505         oldself = self;
 506         self = targ;
 507         damage_targ = targ;
 508         damage_inflictor = inflictor;
 509         damage_attacker = attacker;
 510                 attacker_save = attacker;
 511
 512         if(targ.classname == "player")
 513                 if(targ.hook)
 514                         if(targ.hook.aiment)
 515                                 if(targ.hook.aiment == attacker)
 516                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 517
 518         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 519         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 520         {
 521                 if(targ.classname == "player")
 522                         if not(IsDifferentTeam(targ, attacker))
 523                         {
 524                                 self = oldself;
 525                                 return;
 526                         }
 527         }
 528
 529         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 530         {
 531                 // These are ALWAYS lethal
 532                 // No damage modification here
 533                 // Instead, prepare the victim for his death...
 534                 targ.armorvalue = 0;
 535                 targ.spawnshieldtime = 0;
 536                 targ.health = 0.9; // this is < 1
 537                 targ.flags -= targ.flags & FL_GODMODE;
 538                 damage = 100000;
 539         }
 540         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 541         {
 542                 // no processing
 543         }
 544         else
 545         {
 546                 if (targ.classname == "player")
 547                 if (attacker.classname == "player")
 548                 if (!targ.isbot)
 549                 if (attacker.isbot)
 550                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 551
 552                 // nullify damage if teamplay is on
 553                 if(deathtype != DEATH_TELEFRAG)
 554                 if(attacker.classname == "player")
 555                 {
 556                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 557                         {
 558                                 damage = 0;
 559                                 force = '0 0 0';
 560                         }
 561                         else if(teamplay && attacker.team == targ.team)
 562                         {
 563                                 if(autocvar_teamplay_mode == 1)
 564                                         damage = 0;
 565                                 else if(attacker != targ)
 566                                 {
 567                                         if(autocvar_teamplay_mode == 3)
 568                                                 damage = 0;
 569                                         else if(autocvar_teamplay_mode == 4)
 570                                         {
 571                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 572                                                 {
 573                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 574                                                         attacker.dmg_team = attacker.dmg_team + damage;
 575                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 576                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 577                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 578                                                         if(g_minstagib)
 579                                                         {
 580                                                                 if(autocvar_g_friendlyfire == 0)
 581                                                                         damage = 0;
 582                                                         }
 583                                                         else if(g_ca)
 584                                                                 damage = 0;
 585                                                         else
 586                                                                 damage = autocvar_g_friendlyfire * damage;
 587                                                         // mirrordamage will be used LATER
 588
 589                                                         if(autocvar_g_mirrordamage_virtual)
 590                                                         {
 591                                                                 vector v;
 592                                                                 v = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 593                                                                 attacker.dmg_take += v_x;
 594                                                                 attacker.dmg_save += v_y;
 595                                                                 attacker.dmg_inflictor = inflictor;
 596                                                                 mirrordamage = 0;
 597                                                                 mirrorforce = 0;
 598                                                         }
 599
 600                                                         if(autocvar_g_friendlyfire_virtual)
 601                                                         {
 602                                                                 vector v;
 603                                                                 v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 604                                                                 targ.dmg_take += v_x;
 605                                                                 targ.dmg_save += v_y;
 606                                                                 targ.dmg_inflictor = inflictor;
 607                                                                 damage = 0;
 608                                 if(!autocvar_g_friendlyfire_virtual_force)
 609                                     force = '0 0 0';
 610                                                         }
 611                                                 }
 612                                                 else
 613                                                         damage = 0;
 614                                         }
 615                                 }
 616                         }
 617                 }
 618
 619                 if(targ.classname == "player")
 620                 if(attacker.classname == "player")
 621                 if(attacker != targ)
 622                 {
 623                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 624                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 625                 }
 626
 627                 if(targ.classname == "player")
 628                 if (g_minstagib)
 629                 {
 630                         if ((deathtype == DEATH_FALL)  ||
 631                                 (deathtype == DEATH_DROWN) ||
 632                                 (deathtype == DEATH_SLIME) ||
 633                                 (deathtype == DEATH_LAVA)  ||
 634                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 635                         {
 636                                 self = oldself;
 637                                 return;
 638                         }
 639                         if(damage > 0)
 640                             damage = 10000;
 641                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 642                         {
 643                                 targ.armorvalue -= 1;
 644                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 645                                 damage = 0;
 646                                 targ.hitsound += 1;
 647                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 648                         }
 649                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 650                         {
 651                                 damage = 0;
 652                                 mirrordamage = 0;
 653                                 if (targ != attacker)
 654                                 {
 655                                         if ((targ.health >= 1) && (targ.classname == "player"))
 656                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 657                                         force = '0 0 0';
 658                                         // keep mirrorforce
 659                                         attacker = targ;
 660                                 }
 661                         }
 662                 }
 663
 664                 if not(DEATH_ISSPECIAL(deathtype))
 665                 {
 666                         damage *= g_weapondamagefactor;
 667                         mirrordamage *= g_weapondamagefactor;
 668                         force = force * g_weaponforcefactor;
 669                         mirrorforce *= g_weaponforcefactor;
 670                 }
 671
 672                 // should this be changed at all? If so, in what way?
 673                 frag_attacker = attacker;
 674                 frag_target = targ;
 675                 frag_damage = damage;
 676                 frag_force = force;
 677         frag_deathtype = deathtype;
 678                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 679                 damage = frag_damage;
 680                 force = frag_force;
 681
 682                 // apply strength multiplier
 683                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 684                 {
 685                         if(targ == attacker)
 686                         {
 687                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 688                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 689                         }
 690                         else
 691                         {
 692                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 693                                 force = force * autocvar_g_balance_powerup_strength_force;
 694                         }
 695                 }
 696
 697                 // apply invincibility multiplier
 698                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 699                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 700
 701                 if (targ == attacker)
 702                 {
 703                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 704                                 damage = 0;
 705                         else
 706                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 707                 }
 708
 709                 // CTF: reduce damage/force
 710                 if(g_ctf)
 711                 if(targ == attacker)
 712                 if(targ.flagcarried)
 713                 {
 714                         damage = damage * autocvar_g_ctf_flagcarrier_selfdamage;
 715                         force = force * autocvar_g_ctf_flagcarrier_selfforce;
 716                 }
 717
 718                 if(g_runematch)
 719                 {
 720                         // apply strength rune
 721                         if (attacker.runes & RUNE_STRENGTH)
 722                         {
 723                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 724                                 {
 725                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 726                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 727                                 }
 728                                 else
 729                                 {
 730                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 731                                         force = force * autocvar_g_balance_rune_strength_force;
 732                                 }
 733                         }
 734                         else if (attacker.runes & CURSE_WEAK)
 735                         {
 736                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 737                                 force = force * autocvar_g_balance_curse_weak_force;
 738                         }
 739
 740                         // apply defense rune
 741                         if (targ.runes & RUNE_DEFENSE)
 742                         {
 743                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 744                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 745                                 else
 746                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 747                         }
 748                         else if (targ.runes & CURSE_VULNER)
 749                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 750                 }
 751
 752                 // count the damage
 753                 if(attacker)
 754                 if(!targ.deadflag)
 755                 if(targ.takedamage == DAMAGE_AIM)
 756                 if(targ != attacker)
 757                 {
 758                         if(targ.classname == "player")
 759                         {
 760                                 // HEAD SHOT:
 761                                 // find height of hit on player axis
 762                                 // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 763                                 vector headmins, headmaxs, org;
 764                                 org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 765                                 headmins = org + GetHeadshotMins(targ);
 766                                 headmaxs = org + GetHeadshotMaxs(targ);
 767                                 if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 768                                 {
 769                                         deathtype |= HITTYPE_HEADSHOT;
 770                                 }
 771                         }
 772                         else if(targ.classname == "turret_head")
 773                         {
 774                                 deathtype |= HITTYPE_HEADSHOT;
 775                         }
 776                         if(deathtype & HITTYPE_HEADSHOT)
 777                                 damage *= 1 + damage_headshotbonus;
 778
 779                         entity victim;
 780                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 781                                 victim = targ.owner;
 782                         else
 783                                 victim = targ;
 784
 785                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 786                         {
 787                                 if(IsDifferentTeam(victim, attacker))
 788                                 {
 789                                         if(damage > 0)
 790                                         {
 791                                                 if(deathtype != DEATH_FIRE)
 792                                                 {
 793                                                         if(victim.BUTTON_CHAT)
 794                                                                 attacker.typehitsound += 1;
 795                                                         else
 796                                                                 attacker.hitsound += 1;
 797                                                 }
 798
 799                                                 damage_goodhits += 1;
 800                                                 damage_gooddamage += damage;
 801
 802                                                 if not(DEATH_ISSPECIAL(deathtype))
 803                                                 {
 804                                                         if(targ.classname == "player") // don't do this for vehicles
 805                                                         if(!g_minstagib)
 806                                                         if(IsFlying(victim))
 807                                                                 yoda = 1;
 808
 809                                                         if(g_minstagib)
 810                                                         if(victim.items & IT_STRENGTH)
 811                                                                 yoda = 1;
 812
 813                                                         if(deathtype & HITTYPE_HEADSHOT)
 814                                                                 headshot = 1;
 815                                                 }
 816                                                 if(g_ca)
 817                                                         PlayerScore_Add(attacker, SP_SCORE, damage * autocvar_g_ca_damage2score_multiplier);
 818                                         }
 819                                 }
 820                                 else
 821                                 {
 822                                         if(deathtype != DEATH_FIRE)
 823                                         {
 824                                                 attacker.typehitsound += 1;
 825                                         }
 826                                         if(mirrordamage > 0)
 827                                                 if(time > attacker.teamkill_complain)
 828                                                 {
 829                                                         attacker.teamkill_complain = time + 5;
 830                                                         attacker.teamkill_soundtime = time + 0.4;
 831                                                         attacker.teamkill_soundsource = targ;
 832                                                 }
 833                                 }
 834                         }
 835                 }
 836         }
 837
 838         // apply push
 839         if (self.damageforcescale)
 840         if (vlen(force))
 841         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 842         {
 843                 self.velocity = self.velocity + damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 844                 self.flags &~= FL_ONGROUND;
 845                 UpdateCSQCProjectile(self);
 846         }
 847         // apply damage
 848         if (damage != 0 || (self.damageforcescale && vlen(force)))
 849         if (self.event_damage)
 850                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 851         self = oldself;
 852
 853         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 854         {
 855                 if(g_runematch)
 856                 {
 857                         if (attacker.runes & RUNE_VAMPIRE)
 858                         {
 859                         // apply vampire rune
 860                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 861                                 {
 862                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 863                                         attacker.health = bound(
 864                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 865                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 866                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 867                                 }
 868                                 else
 869                                 {
 870                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 871                                         attacker.health = bound(
 872                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 873                                                                                         // empathy won't let you gain health in the same way...
 874                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 875                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 876                                         }
 877                         }
 878                         // apply empathy curse
 879                         else if (attacker.runes & CURSE_EMPATHY)
 880                         {
 881                                 attacker.health = bound(
 882                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 883                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 884                                         attacker.health);
 885                         }
 886                 }
 887         }
 888
 889         // apply mirror damage if any
 890         if(mirrordamage > 0 || mirrorforce > 0)
 891         {
 892                 attacker = attacker_save;
 893                 if(g_minstagib)
 894                 if(mirrordamage > 0)
 895                 {
 896                         // just lose extra LIVES, don't kill the player for mirror damage
 897                         if(attacker.armorvalue > 0)
 898                         {
 899                                 attacker.armorvalue = attacker.armorvalue - 1;
 900                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 901                                 attacker.hitsound += 1;
 902                         }
 903                         mirrordamage = 0;
 904                 }
 905
 906                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 907                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 908         }
 909 }
 910
 911 float RadiusDamage_running;
 912 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 913 // Returns total damage applies to creatures
 914 {
 915         entity  targ;
 916         float   finaldmg;
 917         float   power;
 918         vector  blastorigin;
 919         vector  force;
 920         vector  diff;
 921         vector  center;
 922         vector  nearest;
 923         float   total_damage_to_creatures;
 924         entity  next;
 925         float   tfloordmg;
 926         float   tfloorforce;
 927
 928         float stat_damagedone;
 929
 930         if(RadiusDamage_running)
 931         {
 932                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 933                 return 0;
 934         }
 935
 936         RadiusDamage_running = 1;
 937
 938         tfloordmg = autocvar_g_throughfloor_damage;
 939         tfloorforce = autocvar_g_throughfloor_force;
 940
 941         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 942         total_damage_to_creatures = 0;
 943
 944         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 945         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 946         {
 947                 force = inflictor.velocity;
 948                 if(vlen(force) == 0)
 949                         force = '0 0 -1';
 950                 else
 951                         force = normalize(force);
 952                 if(forceintensity >= 0)
 953                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, attacker);
 954                 else
 955                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, attacker);
 956         }
 957
 958         stat_damagedone = 0;
 959
 960         targ = WarpZone_FindRadius (blastorigin, rad, FALSE);
 961         while (targ)
 962         {
 963                 next = targ.chain;
 964                 if (targ != inflictor)
 965                         if (ignore != targ) if(targ.takedamage)
 966                         {
 967                                 // LordHavoc: measure distance to nearest point on target (not origin)
 968                                 // (this guarentees 100% damage on a touch impact)
 969                                 nearest = targ.WarpZone_findradius_nearest;
 970                                 diff = targ.WarpZone_findradius_dist;
 971                                 // round up a little on the damage to ensure full damage on impacts
 972                                 // and turn the distance into a fraction of the radius
 973                                 power = 1 - ((vlen (diff) - 2) / rad);
 974                                 //bprint(" ");
 975                                 //bprint(ftos(power));
 976                                 //if (targ == attacker)
 977                                 //      print(ftos(power), "\n");
 978                                 if (power > 0)
 979                                 {
 980                                         if (power > 1)
 981                                                 power = 1;
 982                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 983                                         if (finaldmg > 0)
 984                                         {
 985                                                 local float a;
 986                                                 local float c;
 987                                                 local float hits;
 988                                                 local float total;
 989                                                 local float hitratio;
 990                                                 local vector hitloc;
 991                                                 local vector myblastorigin;
 992                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 993                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
 994                                                 // if it's a player, use the view origin as reference
 995                                                 if (targ.classname == "player")
 996                                                         center = targ.origin + targ.view_ofs;
 997                                                 force = normalize(center - myblastorigin);
 998                                                 force = force * (finaldmg / coredamage) * forceintensity;
 999                                                 // test line of sight to multiple positions on box,
1000                                                 // and do damage if any of them hit
1001                                                 hits = 0;
1002                                                 if (targ.classname == "player")
1003                                                         total = ceil(bound(1, finaldmg, 50));
1004                                                 else
1005                                                         total = ceil(bound(1, finaldmg/10, 5));
1006                                                 hitloc = nearest;
1007                                                 c = 0;
1008                                                 while (c < total)
1009                                                 {
1010                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1011                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1012                                                         if (trace_fraction == 1 || trace_ent == targ)
1013                                                         {
1014                                                                 hits = hits + 1;
1015                                                                 if (hits > 1)
1016                                                                         hitloc = hitloc + nearest;
1017                                                                 else
1018                                                                         hitloc = nearest;
1019                                                         }
1020                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1021                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1022                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1023                                                         c = c + 1;
1024                                                 }
1025                                                 nearest = hitloc * (1 / max(1, hits));
1026                                                 hitratio = (hits / total);
1027                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1028                                                 finaldmg = finaldmg * a;
1029                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1030                                                 force = force * a;
1031
1032                                                 // laser force adjustments :P
1033                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1034                                                 {
1035                             if (targ == attacker)
1036                             {
1037                                 vector vel;
1038
1039                                 float force_zscale;
1040                                 float force_velocitybiasramp;
1041                                 float force_velocitybias;
1042
1043                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1044                                 if(deathtype & HITTYPE_SECONDARY)
1045                                 {
1046                                     force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1047                                     force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1048                                 }
1049                                 else
1050                                 {
1051                                     force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1052                                     force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1053                                 }
1054
1055                                 vel = targ.velocity;
1056                                 vel_z = 0;
1057                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1058                                 force =
1059                                     vlen(force)
1060                                     *
1061                                     normalize(normalize(force) + vel);
1062
1063                                 force_z *= force_zscale;
1064                             }
1065                             else
1066                             {
1067                                 if(deathtype & HITTYPE_SECONDARY)
1068                                 {
1069                                     force *= autocvar_g_balance_laser_secondary_force_other_scale;
1070                                 }
1071                                 else
1072                                 {
1073                                     force *= autocvar_g_balance_laser_primary_force_other_scale;
1074                                 }
1075                             }
1076                                                 }
1077
1078                                                 //if (targ == attacker)
1079                                                 //{
1080                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1081                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1082                                                 //      print(" (", ftos(a), ")\n");
1083                                                 //}
1084                                                 if(hits || tfloordmg || tfloorforce)
1085                                                 {
1086                                                         if(targ.iscreature)
1087                                                         {
1088                                                                 total_damage_to_creatures += finaldmg;
1089
1090                                                                 if(accuracy_isgooddamage(attacker, targ))
1091                                                                         stat_damagedone += finaldmg;
1092                                                         }
1093
1094                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1095                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1096                                                         else
1097                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1098                                                 }
1099                                         }
1100                                 }
1101                         }
1102                 targ = next;
1103         }
1104
1105         RadiusDamage_running = 0;
1106
1107         if(!DEATH_ISSPECIAL(deathtype))
1108                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1109
1110         return total_damage_to_creatures;
1111 }
1112
1113 .float fire_damagepersec;
1114 .float fire_endtime;
1115 .float fire_deathtype;
1116 .entity fire_owner;
1117 .float fire_hitsound;
1118 .entity fire_burner;
1119
1120 void fireburner_think();
1121
1122 float Fire_IsBurning(entity e)
1123 {
1124         return (time < e.fire_endtime);
1125 }
1126
1127 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1128 {
1129         float dps;
1130         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1131
1132         if(e.classname == "player")
1133         {
1134                 if(e.deadflag)
1135                         return -1;
1136         }
1137         else
1138         {
1139                 if(!e.fire_burner)
1140                 {
1141                         // print("adding a fire burner to ", e.classname, "\n");
1142                         e.fire_burner = spawn();
1143                         e.fire_burner.classname = "fireburner";
1144                         e.fire_burner.think = fireburner_think;
1145                         e.fire_burner.nextthink = time;
1146                         e.fire_burner.owner = e;
1147                 }
1148         }
1149
1150         t = max(t, 0.1);
1151         dps = d / t;
1152         if(Fire_IsBurning(e))
1153         {
1154                 mintime = e.fire_endtime - time;
1155                 maxtime = max(mintime, t);
1156
1157                 mindps = e.fire_damagepersec;
1158                 maxdps = max(mindps, dps);
1159
1160                 if(maxtime > mintime || maxdps > mindps)
1161                 {
1162                         mindamage = mindps * mintime;
1163                         maxdamage = mindamage + d;
1164
1165                         // interval [mintime, maxtime] * [mindps, maxdps]
1166                         // intersected with
1167                         // [mindamage, maxdamage]
1168                         // maximum of this!
1169
1170                         if(maxdamage >= maxtime * maxdps)
1171                         {
1172                                 totaltime = maxtime;
1173                                 totaldamage = maxtime * maxdps;
1174
1175                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1176                         }
1177                         else
1178                         {
1179                                 // maxdamage is inside the interval!
1180                                 // first, try to use mindps; only if this fails, increase dps as needed
1181                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1182                                 totaldamage = maxdamage;
1183                                 // can totaldamage / totaltime be >= maxdps?
1184                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1185                                 // we know maxdamage < maxtime * maxdps
1186                                 // so it cannot be
1187
1188                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1189                         }
1190
1191                         // total conditions for increasing:
1192                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1193                         // however:
1194                         //     if maxtime = mintime, maxdps = mindps
1195                         // then:
1196                         //     maxdamage = mindamage + d
1197                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1198                         // so the last condition is not needed
1199
1200                         e.fire_damagepersec = totaldamage / totaltime;
1201                         e.fire_endtime = time + totaltime;
1202                         if(totaldamage > 1.2 * mindamage)
1203                         {
1204                                 e.fire_deathtype = dt;
1205                                 if(e.fire_owner != o)
1206                                 {
1207                                         e.fire_owner = o;
1208                                         e.fire_hitsound = FALSE;
1209                                 }
1210                         }
1211                         if(accuracy_isgooddamage(o, e))
1212                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1213                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1214                 }
1215                 else
1216                         return 0;
1217         }
1218         else
1219         {
1220                 e.fire_damagepersec = dps;
1221                 e.fire_endtime = time + t;
1222                 e.fire_deathtype = dt;
1223                 e.fire_owner = o;
1224                 e.fire_hitsound = FALSE;
1225                 if(accuracy_isgooddamage(o, e))
1226                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1227                 return d;
1228         }
1229 }
1230
1231 void Fire_ApplyDamage(entity e)
1232 {
1233         float t, d, hi, ty;
1234         entity o;
1235
1236         if not(Fire_IsBurning(e))
1237                 return;
1238
1239         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1240         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1241                 o = e.fire_owner;
1242
1243         // water and slime stop fire
1244         if(e.waterlevel)
1245         if(e.watertype != CONTENT_LAVA)
1246                 e.fire_endtime = 0;
1247
1248         // ice stops fire
1249         if(e.freezetag_frozen)
1250                 e.fire_endtime = 0;
1251
1252         t = min(frametime, e.fire_endtime - time);
1253         d = e.fire_damagepersec * t;
1254
1255         hi = e.fire_owner.hitsound;
1256         ty = e.fire_owner.typehitsound;
1257         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1258         if(e.fire_hitsound && e.fire_owner)
1259         {
1260                 e.fire_owner.hitsound = hi;
1261                 e.fire_owner.typehitsound = ty;
1262         }
1263         e.fire_hitsound = TRUE;
1264
1265         if not(IS_INDEPENDENT_PLAYER(e))
1266         FOR_EACH_PLAYER(other) if(e != other)
1267         {
1268                 if(other.classname == "player")
1269                 if(other.deadflag == DEAD_NO)
1270                 if not(IS_INDEPENDENT_PLAYER(other))
1271                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1272                 {
1273                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1274                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1275                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1276                 }
1277         }
1278 }
1279
1280 void Fire_ApplyEffect(entity e)
1281 {
1282         if(Fire_IsBurning(e))
1283                 e.effects |= EF_FLAME;
1284         else
1285                 e.effects &~= EF_FLAME;
1286 }
1287
1288 void fireburner_think()
1289 {
1290         // for players, this is done in the regular loop
1291         if(wasfreed(self.owner))
1292         {
1293                 remove(self);
1294                 return;
1295         }
1296         Fire_ApplyEffect(self.owner);
1297         if(!Fire_IsBurning(self.owner))
1298         {
1299                 self.owner.fire_burner = world;
1300                 remove(self);
1301                 return;
1302         }
1303         Fire_ApplyDamage(self.owner);
1304         self.nextthink = time;
1305 }