qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 #define INFO_NO_MSG 0
 263
 264 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2, float f3)
 265 {
 266         float handled = 0, hits = 0;
 267         if(DEATH_ISSPECIAL(deathtype))
 268         {
 269                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 270                         { if(deathtype == max(0, name)) \
 271                         { \
 272                                 #if msg_death != NO_MSG \
 273                                         if not(murder) \
 274                                         { \
 275                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 276                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 277                                                 ++handled; \
 278                                         } \
 279                                 #endif \
 280                                 #if msg_death_by != NO_MSG \
 281                                         if(murder) \
 282                                         { \
 283                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 284                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 285                                                 ++handled; \
 286                                         } \
 287                                 #endif \
 288                                 ++hits; \
 289                         } }
 290
 291                 DEATHTYPES
 292                 #undef DEATHTYPE
 293
 294                 if not(hits)
 295                 {
 296                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 297                 }
 298                 if not(handled)
 299                 {
 300                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 301                         return;
 302                 }
 303         }
 304 }
 305
 306 float w_deathtype;
 307 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2)
 308 {
 309         float death_weapon = DEATH_WEAPONOF(deathtype);
 310
 311         if(death_weapon)
 312         {
 313                 w_deathtype = deathtype;
 314                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 315                 w_deathtype = FALSE;
 316
 317                 if(death_message)
 318                 {
 319                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_WEAPON, death_message, s1, s2, s3, "", f1, f2, 0, 0);
 320                         Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_weapon_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, 0, 0);
 321                         //print(Get_Field_Value(F_INFVAL, MSG_WEAPON, death_message), "\n");
 322                 }
 323                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 324
 325                 return TRUE;
 326         }
 327         return FALSE;
 328 }
 329
 330 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 331 {
 332         // Sanity check
 333         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 334
 335         // Declarations
 336         float notif_firstblood = FALSE;
 337         float kill_count_to_attacker, kill_count_to_target;
 338
 339         // Set final information for the death
 340         targ.death_origin = targ.origin;
 341         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 342         string deathlocation = NearestLocation(targ.death_origin);
 343
 344         #ifdef NOTIFICATIONS_DEBUG
 345         dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 346         #endif
 347
 348         // =======
 349         // SUICIDE
 350         // =======
 351         if(targ == attacker)
 352         {
 353                 if(DEATH_ISSPECIAL(deathtype))
 354                 {
 355                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 356                         {
 357                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 358                         }
 359                         else
 360                         {
 361                                 switch(deathtype)
 362                                 {
 363                                         case DEATH_MIRRORDAMAGE:
 364                                         {
 365                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 366                                                 break;
 367                                         }
 368
 369                                         default:
 370                                         {
 371                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 372                                                 break;
 373                                         }
 374                                 }
 375                                 LogDeath("suicide", deathtype, targ, targ);
 376                                 GiveFrags(attacker, targ, -1, deathtype);
 377                         }
 378                 }
 379                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 380                 {
 381                         backtrace("SUICIDE: what the hell happened here?\n");
 382                 }
 383         }
 384
 385         // ======
 386         // MURDER
 387         // ======
 388         else if(attacker.classname == "player")
 389         {
 390                 if(!IsDifferentTeam(attacker, targ))
 391                 {
 392                         LogDeath("tk", deathtype, attacker, targ);
 393                         GiveFrags(attacker, targ, -1, deathtype);
 394
 395                         attacker.killcount = 0;
 396
 397                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 398                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 399                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 400
 401                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 402                         // No need for specific death/weapon messages...
 403                 }
 404                 else
 405                 {
 406                         LogDeath("frag", deathtype, attacker, targ);
 407                         GiveFrags(attacker, targ, 1, deathtype);
 408
 409                         attacker.taunt_soundtime = time + 1;
 410                         attacker.killcount = attacker.killcount + 1;
 411
 412                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 413                                 case counta: \
 414                                 { \
 415                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 416                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 417                                         break; \
 418                                 }
 419                         switch(attacker.killcount)
 420                         {
 421                                 KILL_SPREE_LIST
 422                                 default: break;
 423                         }
 424                         #undef SPREE_ITEM
 425
 426                         if(!checkrules_firstblood)
 427                         {
 428                                 checkrules_firstblood = TRUE;
 429                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 430                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 431                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 432
 433                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 434                                 kill_count_to_attacker = -1;
 435                                 kill_count_to_target = -2;
 436                         }
 437                         else
 438                         {
 439                                 kill_count_to_attacker = attacker.killcount;
 440                                 kill_count_to_target = 0;
 441                         }
 442
 443                         if(targ.istypefrag)
 444                         {
 445                                 if(attacker.FRAG_VERBOSE)
 446                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 447                                 else
 448                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 449
 450                                 if(targ.FRAG_VERBOSE)
 451                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 452                                 else
 453                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 454                         }
 455                         else
 456                         {
 457                                 if(attacker.FRAG_VERBOSE)
 458                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 459                                 else
 460                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 461
 462                                 if(targ.FRAG_VERBOSE)
 463                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 464                                 else
 465                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 466                         }
 467
 468                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 469                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 470                 }
 471         }
 472
 473         // =============
 474         // ACCIDENT/TRAP
 475         // =============
 476         else
 477         {
 478                 switch(deathtype)
 479                 {
 480                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 481                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 482                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 483                         /*case DEATH_HURTTRIGGER:
 484                         {
 485                                 s1 = targ.netname;
 486                                 s2 = inflictor.message;
 487                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 488                                 break;
 489                         }*/
 490
 491                         case DEATH_CUSTOM:
 492                         {
 493                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 494                                         targ.netname,
 495                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 496                                         deathlocation,
 497                                         targ.killcount,
 498                                         0,
 499                                         0);
 500                                 break;
 501                         }
 502
 503                         default:
 504                         {
 505                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 506                                 break;
 507                         }
 508                 }
 509
 510                 LogDeath("accident", deathtype, targ, targ);
 511                 GiveFrags(targ, targ, -1, deathtype);
 512
 513                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 514                 {
 515                         AnnounceTo(targ, "botlike");
 516                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 517                 }
 518         }
 519
 520         // reset target kill count
 521         if(targ.killcount) { targ.killcount = 0; }
 522 }
 523
 524 // these are updated by each Damage call for use in button triggering and such
 525 entity damage_targ;
 526 entity damage_inflictor;
 527 entity damage_attacker;
 528
 529 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 530 {
 531         float mirrordamage;
 532         float mirrorforce;
 533         float complainteamdamage = 0;
 534         entity attacker_save;
 535         mirrordamage = 0;
 536         mirrorforce = 0;
 537
 538         if (gameover || targ.killcount == -666)
 539                 return;
 540
 541         entity oldself;
 542         oldself = self;
 543         self = targ;
 544         damage_targ = targ;
 545         damage_inflictor = inflictor;
 546         damage_attacker = attacker;
 547                 attacker_save = attacker;
 548
 549         if(targ.classname == "player")
 550                 if(targ.hook)
 551                         if(targ.hook.aiment)
 552                                 if(targ.hook.aiment == attacker)
 553                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 554
 555         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 556         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 557         {
 558                 if(targ.classname == "player")
 559                         if not(IsDifferentTeam(targ, attacker))
 560                         {
 561                                 self = oldself;
 562                                 return;
 563                         }
 564         }
 565
 566         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 567         {
 568                 // These are ALWAYS lethal
 569                 // No damage modification here
 570                 // Instead, prepare the victim for his death...
 571                 targ.armorvalue = 0;
 572                 targ.spawnshieldtime = 0;
 573                 targ.health = 0.9; // this is < 1
 574                 targ.flags -= targ.flags & FL_GODMODE;
 575                 damage = 100000;
 576         }
 577         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 578         {
 579                 // no processing
 580         }
 581         else
 582         {
 583                 /*
 584                 skill based bot damage? gtfo. (tZork)
 585                 if (targ.classname == "player")
 586                 if (attacker.classname == "player")
 587                 if (!targ.isbot)
 588                 if (attacker.isbot)
 589                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 590         */
 591
 592                 // nullify damage if teamplay is on
 593                 if(deathtype != DEATH_TELEFRAG)
 594                 if(attacker.classname == "player")
 595                 {
 596                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 597                         {
 598                                 damage = 0;
 599                                 force = '0 0 0';
 600                         }
 601                         else if(!IsDifferentTeam(attacker, targ))
 602                         {
 603                                 if(autocvar_teamplay_mode == 1)
 604                                         damage = 0;
 605                                 else if(attacker != targ)
 606                                 {
 607                                         if(autocvar_teamplay_mode == 3)
 608                                                 damage = 0;
 609                                         else if(autocvar_teamplay_mode == 4)
 610                                         {
 611                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 612                                                 {
 613                                                         attacker.dmg_team = attacker.dmg_team + damage;
 614                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 615                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 616                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 617                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 618                                                         if(g_minstagib)
 619                                                         {
 620                                                                 if(autocvar_g_friendlyfire == 0)
 621                                                                         damage = 0;
 622                                                         }
 623                                                         else if(g_ca)
 624                                                                 damage = 0;
 625                                                         else
 626                                                                 damage = autocvar_g_friendlyfire * damage;
 627                                                         // mirrordamage will be used LATER
 628
 629                                                         if(autocvar_g_mirrordamage_virtual)
 630                                                         {
 631                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 632                                                                 attacker.dmg_take += v_x;
 633                                                                 attacker.dmg_save += v_y;
 634                                                                 attacker.dmg_inflictor = inflictor;
 635                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 636                                                                 mirrorforce = 0;
 637                                                         }
 638
 639                                                         if(autocvar_g_friendlyfire_virtual)
 640                                                         {
 641                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 642                                                                 targ.dmg_take += v_x;
 643                                                                 targ.dmg_save += v_y;
 644                                                                 targ.dmg_inflictor = inflictor;
 645                                                                 damage = 0;
 646                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 647                                                                         force = '0 0 0';
 648                                                         }
 649                                                 }
 650                                                 else
 651                                                         damage = 0;
 652                                         }
 653                                 }
 654                         }
 655                 }
 656
 657                 if(targ.classname == "player")
 658                 if(attacker.classname == "player")
 659                 if(attacker != targ)
 660                 {
 661                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 662                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 663                 }
 664
 665                 if(targ.classname == "player")
 666                 if (g_minstagib)
 667                 {
 668                         if ((deathtype == DEATH_FALL)  ||
 669                                 (deathtype == DEATH_DROWN) ||
 670                                 (deathtype == DEATH_SLIME) ||
 671                                 (deathtype == DEATH_LAVA)  ||
 672                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 673                         {
 674                                 self = oldself;
 675                                 return;
 676                         }
 677                         if(damage > 0)
 678                             damage = 10000;
 679                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 680                         {
 681                                 targ.armorvalue -= 1;
 682                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 683                                 damage = 0;
 684                                 targ.hitsound += 1;
 685                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 686                         }
 687                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 688                         {
 689                                 damage = 0;
 690                                 mirrordamage = 0;
 691                                 complainteamdamage = 0;
 692                                 if (targ != attacker)
 693                                 {
 694                                         if ((targ.health >= 1) && (targ.classname == "player"))
 695                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 696                                         force = '0 0 0';
 697                                         // keep mirrorforce
 698                                         attacker = targ;
 699                                 }
 700                         }
 701                 }
 702
 703                 if not(DEATH_ISSPECIAL(deathtype))
 704                 {
 705                         damage *= g_weapondamagefactor;
 706                         mirrordamage *= g_weapondamagefactor;
 707                         complainteamdamage *= g_weapondamagefactor;
 708                         force = force * g_weaponforcefactor;
 709                         mirrorforce *= g_weaponforcefactor;
 710                 }
 711
 712                 // should this be changed at all? If so, in what way?
 713                 frag_attacker = attacker;
 714                 frag_target = targ;
 715                 frag_damage = damage;
 716                 frag_force = force;
 717         frag_deathtype = deathtype;
 718                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 719                 damage = frag_damage;
 720                 force = frag_force;
 721
 722                 // apply strength multiplier
 723                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 724                 {
 725                         if(targ == attacker)
 726                         {
 727                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 728                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 729                         }
 730                         else
 731                         {
 732                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 733                                 force = force * autocvar_g_balance_powerup_strength_force;
 734                         }
 735                 }
 736
 737                 // apply invincibility multiplier
 738                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 739                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 740
 741                 if (targ == attacker)
 742                 {
 743                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 744                                 damage = 0;
 745                         else
 746                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 747                 }
 748
 749                 if(g_runematch)
 750                 {
 751                         // apply strength rune
 752                         if (attacker.runes & RUNE_STRENGTH)
 753                         {
 754                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 755                                 {
 756                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 757                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 758                                 }
 759                                 else
 760                                 {
 761                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 762                                         force = force * autocvar_g_balance_rune_strength_force;
 763                                 }
 764                         }
 765                         else if (attacker.runes & CURSE_WEAK)
 766                         {
 767                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 768                                 force = force * autocvar_g_balance_curse_weak_force;
 769                         }
 770
 771                         // apply defense rune
 772                         if (targ.runes & RUNE_DEFENSE)
 773                         {
 774                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 775                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 776                                 else
 777                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 778                         }
 779                         else if (targ.runes & CURSE_VULNER)
 780                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 781                 }
 782
 783                 // count the damage
 784                 if(attacker)
 785                 if(!targ.deadflag)
 786                 if(targ.takedamage == DAMAGE_AIM)
 787                 if(targ != attacker)
 788                 {
 789                         entity victim;
 790                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 791                                 victim = targ.owner;
 792                         else
 793                                 victim = targ;
 794
 795                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 796                         {
 797                                 if(IsDifferentTeam(victim, attacker))
 798                                 {
 799                                         if(damage > 0)
 800                                         {
 801                                                 if(deathtype != DEATH_FIRE)
 802                                                 {
 803                                                         if(victim.BUTTON_CHAT)
 804                                                                 attacker.typehitsound += 1;
 805                                                         else
 806                                                                 attacker.hitsound += 1;
 807                                                 }
 808
 809                                                 damage_goodhits += 1;
 810                                                 damage_gooddamage += damage;
 811
 812                                                 if not(DEATH_ISSPECIAL(deathtype))
 813                                                 {
 814                                                         if(targ.classname == "player") // don't do this for vehicles
 815                                                         if(!g_minstagib)
 816                                                         if(IsFlying(victim))
 817                                                                 yoda = 1;
 818
 819                                                         if(g_minstagib)
 820                                                         if(victim.items & IT_STRENGTH)
 821                                                                 yoda = 1;
 822                                                 }
 823                                         }
 824                                 }
 825                                 else
 826                                 {
 827                                         if(deathtype != DEATH_FIRE)
 828                                         {
 829                                                 attacker.typehitsound += 1;
 830                                         }
 831                                         if(complainteamdamage > 0)
 832                                                 if(time > attacker.teamkill_complain)
 833                                                 {
 834                                                         attacker.teamkill_complain = time + 5;
 835                                                         attacker.teamkill_soundtime = time + 0.4;
 836                                                         attacker.teamkill_soundsource = targ;
 837                                                 }
 838                                 }
 839                         }
 840                 }
 841         }
 842
 843         // apply push
 844         if (self.damageforcescale)
 845         if (vlen(force))
 846         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 847         {
 848                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 849                 if(self.movetype == MOVETYPE_PHYSICS)
 850                 {
 851                         entity farcent;
 852                         farcent = spawn();
 853                         farcent.classname = "farce";
 854                         farcent.enemy = self;
 855                         farcent.movedir = farce * 10;
 856                         if(self.mass)
 857                                 farcent.movedir = farcent.movedir * self.mass;
 858                         farcent.origin = hitloc;
 859                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 860                         farcent.nextthink = time + 0.1;
 861                         farcent.think = SUB_Remove;
 862                 }
 863                 else
 864                         self.velocity = self.velocity + farce;
 865                 self.flags &~= FL_ONGROUND;
 866                 UpdateCSQCProjectile(self);
 867         }
 868         // apply damage
 869         if (damage != 0 || (self.damageforcescale && vlen(force)))
 870         if (self.event_damage)
 871                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 872         self = oldself;
 873
 874         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 875         {
 876                 if(g_runematch)
 877                 {
 878                         if (attacker.runes & RUNE_VAMPIRE)
 879                         {
 880                         // apply vampire rune
 881                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 882                                 {
 883                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 884                                         attacker.health = bound(
 885                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 886                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 887                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 888                                 }
 889                                 else
 890                                 {
 891                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 892                                         attacker.health = bound(
 893                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 894                                                                                         // empathy won't let you gain health in the same way...
 895                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 896                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 897                                         }
 898                         }
 899                         // apply empathy curse
 900                         else if (attacker.runes & CURSE_EMPATHY)
 901                         {
 902                                 attacker.health = bound(
 903                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 904                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 905                                         attacker.health);
 906                         }
 907                 }
 908         }
 909
 910         // apply mirror damage if any
 911         if(mirrordamage > 0 || mirrorforce > 0)
 912         {
 913                 attacker = attacker_save;
 914                 if(g_minstagib)
 915                 if(mirrordamage > 0)
 916                 {
 917                         // just lose extra LIVES, don't kill the player for mirror damage
 918                         if(attacker.armorvalue > 0)
 919                         {
 920                                 attacker.armorvalue = attacker.armorvalue - 1;
 921                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 922                                 attacker.hitsound += 1;
 923                         }
 924                         mirrordamage = 0;
 925                 }
 926
 927                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 928                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 929         }
 930 }
 931
 932 float RadiusDamage_running;
 933 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 934         // Returns total damage applies to creatures
 935 {
 936         entity  targ;
 937         vector  blastorigin;
 938         vector  force;
 939         float   total_damage_to_creatures;
 940         entity  next;
 941         float   tfloordmg;
 942         float   tfloorforce;
 943
 944         float stat_damagedone;
 945
 946         if(RadiusDamage_running)
 947         {
 948                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 949                 return 0;
 950         }
 951
 952         RadiusDamage_running = 1;
 953
 954         tfloordmg = autocvar_g_throughfloor_damage;
 955         tfloorforce = autocvar_g_throughfloor_force;
 956
 957         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 958         total_damage_to_creatures = 0;
 959
 960         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 961                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 962                 {
 963                         force = inflictor.velocity;
 964                         if(vlen(force) == 0)
 965                                 force = '0 0 -1';
 966                         else
 967                                 force = normalize(force);
 968                         if(forceintensity >= 0)
 969                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 970                         else
 971                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 972                 }
 973
 974         stat_damagedone = 0;
 975
 976         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 977         while (targ)
 978         {
 979                 next = targ.chain;
 980                 if (targ != inflictor)
 981                         if (ignore != targ) if(targ.takedamage)
 982                         {
 983                                 vector nearest;
 984                                 vector diff;
 985                                 float power;
 986
 987                                 // LordHavoc: measure distance to nearest point on target (not origin)
 988                                 // (this guarentees 100% damage on a touch impact)
 989                                 nearest = targ.WarpZone_findradius_nearest;
 990                                 diff = targ.WarpZone_findradius_dist;
 991                                 // round up a little on the damage to ensure full damage on impacts
 992                                 // and turn the distance into a fraction of the radius
 993                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 994                                 //bprint(" ");
 995                                 //bprint(ftos(power));
 996                                 //if (targ == attacker)
 997                                 //      print(ftos(power), "\n");
 998                                 if (power > 0)
 999                                 {
1000                                         float finaldmg;
1001                                         if (power > 1)
1002                                                 power = 1;
1003                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1004                                         if (finaldmg > 0)
1005                                         {
1006                                                 float a;
1007                                                 float c;
1008                                                 vector hitloc;
1009                                                 vector myblastorigin;
1010                                                 vector center;
1011
1012                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1013
1014                                                 // if it's a player, use the view origin as reference
1015                                                 center = CENTER_OR_VIEWOFS(targ);
1016
1017                                                 force = normalize(center - myblastorigin);
1018                                                 force = force * (finaldmg / coredamage) * forceintensity;
1019                                                 hitloc = nearest;
1020
1021                                                 if(targ != directhitentity)
1022                                                 {
1023                                                         float hits;
1024                                                         float total;
1025                                                         float hitratio;
1026                                                         float mininv_f, mininv_d;
1027
1028                                                         // test line of sight to multiple positions on box,
1029                                                         // and do damage if any of them hit
1030                                                         hits = 0;
1031
1032                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1033                                                         // so for a given max stddev:
1034                                                         // n = (1 / (2 * max stddev of hitratio))^2
1035
1036                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1037                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1038
1039                                                         if(autocvar_g_throughfloor_debug)
1040                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1041
1042                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1043
1044                                                         if(autocvar_g_throughfloor_debug)
1045                                                                 print(sprintf(" steps=%f", total));
1046
1047                                                         if (targ.classname == "player")
1048                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1049                                                         else
1050                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1051
1052                                                         if(autocvar_g_throughfloor_debug)
1053                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1054
1055                                                         for(c = 0; c < total; ++c)
1056                                                         {
1057                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1058                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1059                                                                 if (trace_fraction == 1 || trace_ent == targ)
1060                                                                 {
1061                                                                         ++hits;
1062                                                                         if (hits > 1)
1063                                                                                 hitloc = hitloc + nearest;
1064                                                                         else
1065                                                                                 hitloc = nearest;
1066                                                                 }
1067                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1068                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1069                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1070                                                         }
1071
1072                                                         nearest = hitloc * (1 / max(1, hits));
1073                                                         hitratio = (hits / total);
1074                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1075                                                         finaldmg = finaldmg * a;
1076                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1077                                                         force = force * a;
1078
1079                                                         if(autocvar_g_throughfloor_debug)
1080                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1081                                                 }
1082
1083                                                 // laser force adjustments :P
1084                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1085                                                 {
1086                                                         if (targ == attacker)
1087                                                         {
1088                                                                 vector vel;
1089
1090                                                                 float force_zscale;
1091                                                                 float force_velocitybiasramp;
1092                                                                 float force_velocitybias;
1093
1094                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1095                                                                 if(deathtype & HITTYPE_SECONDARY)
1096                                                                 {
1097                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1098                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1099                                                                 }
1100                                                                 else
1101                                                                 {
1102                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1103                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1104                                                                 }
1105
1106                                                                 vel = targ.velocity;
1107                                                                 vel_z = 0;
1108                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1109                                                                 force =
1110                                                                         vlen(force)
1111                                                                         *
1112                                                                         normalize(normalize(force) + vel);
1113
1114                                                                 force_z *= force_zscale;
1115                                                         }
1116                                                         else
1117                                                         {
1118                                                                 if(deathtype & HITTYPE_SECONDARY)
1119                                                                 {
1120                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1121                                                                 }
1122                                                                 else
1123                                                                 {
1124                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1125                                                                 }
1126                                                         }
1127                                                 }
1128
1129                                                 //if (targ == attacker)
1130                                                 //{
1131                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1132                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1133                                                 //      print(" (", ftos(a), ")\n");
1134                                                 //}
1135                                                 if(finaldmg || vlen(force))
1136                                                 {
1137                                                         if(targ.iscreature)
1138                                                         {
1139                                                                 total_damage_to_creatures += finaldmg;
1140
1141                                                                 if(accuracy_isgooddamage(attacker, targ))
1142                                                                         stat_damagedone += finaldmg;
1143                                                         }
1144
1145                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1146                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1147                                                         else
1148                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1149                                                 }
1150                                         }
1151                                 }
1152                         }
1153                 targ = next;
1154         }
1155
1156         RadiusDamage_running = 0;
1157
1158         if(!DEATH_ISSPECIAL(deathtype))
1159                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1160
1161         return total_damage_to_creatures;
1162 }
1163
1164 .float fire_damagepersec;
1165 .float fire_endtime;
1166 .float fire_deathtype;
1167 .entity fire_owner;
1168 .float fire_hitsound;
1169 .entity fire_burner;
1170
1171 void fireburner_think();
1172
1173 float Fire_IsBurning(entity e)
1174 {
1175         return (time < e.fire_endtime);
1176 }
1177
1178 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1179 {
1180         float dps;
1181         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1182
1183         if(e.classname == "player")
1184         {
1185                 if(e.deadflag)
1186                         return -1;
1187         }
1188         else
1189         {
1190                 if(!e.fire_burner)
1191                 {
1192                         // print("adding a fire burner to ", e.classname, "\n");
1193                         e.fire_burner = spawn();
1194                         e.fire_burner.classname = "fireburner";
1195                         e.fire_burner.think = fireburner_think;
1196                         e.fire_burner.nextthink = time;
1197                         e.fire_burner.owner = e;
1198                 }
1199         }
1200
1201         t = max(t, 0.1);
1202         dps = d / t;
1203         if(Fire_IsBurning(e))
1204         {
1205                 mintime = e.fire_endtime - time;
1206                 maxtime = max(mintime, t);
1207
1208                 mindps = e.fire_damagepersec;
1209                 maxdps = max(mindps, dps);
1210
1211                 if(maxtime > mintime || maxdps > mindps)
1212                 {
1213                         // Constraints:
1214
1215                         // damage we have right now
1216                         mindamage = mindps * mintime;
1217
1218                         // damage we want to get
1219                         maxdamage = mindamage + d;
1220
1221                         // but we can't exceed maxtime * maxdps!
1222                         totaldamage = min(maxdamage, maxtime * maxdps);
1223
1224                         // LEMMA:
1225                         // Look at:
1226                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1227                         // We see:
1228                         // totaldamage <= maxtime * maxdps
1229                         // ==> totaldamage / maxdps <= maxtime.
1230                         // We also see:
1231                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1232                         //                     >= min(mintime, maxtime)
1233                         // ==> totaldamage / maxdps >= mintime.
1234
1235                         /*
1236                         // how long do we damage then?
1237                         // at least as long as before
1238                         // but, never exceed maxdps
1239                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1240                         */
1241
1242                         // alternate:
1243                         // at most as long as maximum allowed
1244                         // but, never below mindps
1245                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1246
1247                         // assuming t > mintime, dps > mindps:
1248                         // we get d = t * dps = maxtime * maxdps
1249                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1250                         // totaldamage / maxdps = maxtime
1251                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1252                         // FROM THIS:
1253                         // a) totaltime = max(mintime, maxtime) = maxtime
1254                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1255
1256                         // assuming t <= mintime:
1257                         // we get maxtime = mintime
1258                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1259                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1260
1261                         // assuming dps <= mindps:
1262                         // we get mindps = maxdps.
1263                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1264                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1265                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1266
1267                         e.fire_damagepersec = totaldamage / totaltime;
1268                         e.fire_endtime = time + totaltime;
1269                         if(totaldamage > 1.2 * mindamage)
1270                         {
1271                                 e.fire_deathtype = dt;
1272                                 if(e.fire_owner != o)
1273                                 {
1274                                         e.fire_owner = o;
1275                                         e.fire_hitsound = FALSE;
1276                                 }
1277                         }
1278                         if(accuracy_isgooddamage(o, e))
1279                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1280                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1281                 }
1282                 else
1283                         return 0;
1284         }
1285         else
1286         {
1287                 e.fire_damagepersec = dps;
1288                 e.fire_endtime = time + t;
1289                 e.fire_deathtype = dt;
1290                 e.fire_owner = o;
1291                 e.fire_hitsound = FALSE;
1292                 if(accuracy_isgooddamage(o, e))
1293                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1294                 return d;
1295         }
1296 }
1297
1298 void Fire_ApplyDamage(entity e)
1299 {
1300         float t, d, hi, ty;
1301         entity o;
1302
1303         if not(Fire_IsBurning(e))
1304                 return;
1305
1306         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1307         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1308                 o = e.fire_owner;
1309
1310         // water and slime stop fire
1311         if(e.waterlevel)
1312         if(e.watertype != CONTENT_LAVA)
1313                 e.fire_endtime = 0;
1314
1315         // ice stops fire
1316         if(e.freezetag_frozen)
1317                 e.fire_endtime = 0;
1318
1319         t = min(frametime, e.fire_endtime - time);
1320         d = e.fire_damagepersec * t;
1321
1322         hi = e.fire_owner.hitsound;
1323         ty = e.fire_owner.typehitsound;
1324         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1325         if(e.fire_hitsound && e.fire_owner)
1326         {
1327                 e.fire_owner.hitsound = hi;
1328                 e.fire_owner.typehitsound = ty;
1329         }
1330         e.fire_hitsound = TRUE;
1331
1332         if not(IS_INDEPENDENT_PLAYER(e))
1333         FOR_EACH_PLAYER(other) if(e != other)
1334         {
1335                 if(other.classname == "player")
1336                 if(other.deadflag == DEAD_NO)
1337                 if not(IS_INDEPENDENT_PLAYER(other))
1338                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1339                 {
1340                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1341                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1342                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1343                 }
1344         }
1345 }
1346
1347 void Fire_ApplyEffect(entity e)
1348 {
1349         if(Fire_IsBurning(e))
1350                 e.effects |= EF_FLAME;
1351         else
1352                 e.effects &~= EF_FLAME;
1353 }
1354
1355 void fireburner_think()
1356 {
1357         // for players, this is done in the regular loop
1358         if(wasfreed(self.owner))
1359         {
1360                 remove(self);
1361                 return;
1362         }
1363         Fire_ApplyEffect(self.owner);
1364         if(!Fire_IsBurning(self.owner))
1365         {
1366                 self.owner.fire_burner = world;
1367                 remove(self);
1368                 return;
1369         }
1370         Fire_ApplyDamage(self.owner);
1371         self.nextthink = time;
1372 }