qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 /*string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }*/
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 #define INFO_NO_MSG 0
 312
 313 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 314 {
 315         float handled = 0, hits = 0;
 316         if(DEATH_ISSPECIAL(deathtype))
 317         {
 318                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 319                         { if(deathtype == max(0, name)) \
 320                         { \
 321                                 #if msg_death != NO_MSG \
 322                                         if not(murder) \
 323                                         { \
 324                                                 Send_Notification_Legacy_Wrapper(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, f1, f2, f3); \
 325                                                 Send_Notification_Legacy_Wrapper(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, f1, f2, f3); \
 326                                                 ++handled; \
 327                                         } \
 328                                 #endif \
 329                                 #if msg_death_by != NO_MSG \
 330                                         if(murder) \
 331                                         { \
 332                                                 Send_Notification_Legacy_Wrapper(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, f1, f2, f3); \
 333                                                 Send_Notification_Legacy_Wrapper(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, f1, f2, f3); \
 334                                                 ++handled; \
 335                                         } \
 336                                 #endif \
 337                                 ++hits; \
 338                         } }
 339
 340                 DEATHTYPES
 341                 #undef DEATHTYPE
 342
 343                 if not(hits)
 344                 {
 345                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 346                 }
 347                 if not(handled)
 348                 {
 349                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 350                         return;
 351                 }
 352         }
 353 }
 354
 355 float w_deathtype;
 356 float Obituary_WeaponDeath(float murder, float deathtype, string s1, string s2, float f1)
 357 {
 358         float death_weapon = DEATH_WEAPONOF(deathtype);
 359
 360         if(death_weapon)
 361         {
 362                 w_deathtype = deathtype;
 363                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 364                 w_deathtype = FALSE;
 365
 366                 if(death_message) { Send_Notification_Legacy_Wrapper(NOTIF_ANY, world, MSG_WEAPON, death_message, s1, s2, f1, NO_FL_ARG, NO_FL_ARG); }
 367                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 368
 369                 return TRUE;
 370         }
 371         return FALSE;
 372 }
 373
 374 .float FRAG_VERBOSE;
 375 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 376 {
 377         // Sanity check
 378         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 379
 380         // Declarations
 381         string s1 = NO_STR_ARG, s2 = NO_STR_ARG;
 382         float f1 = NO_FL_ARG, f2 = NO_FL_ARG, f3 = NO_FL_ARG;
 383         float notif_firstblood = FALSE;
 384
 385         //dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 386
 387         // =======
 388         // SUICIDE
 389         // =======
 390         if(targ == attacker)
 391         {
 392                 if(DEATH_ISSPECIAL(deathtype))
 393                 {
 394                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 395                         {
 396                                 s1 = targ.netname;
 397                                 f1 = targ.team;
 398                         }
 399                         else
 400                         {
 401                                 switch(deathtype)
 402                                 {
 403                                         case DEATH_MIRRORDAMAGE:
 404                                         {
 405                                                 s1 = targ.netname;
 406                                                 f1 = targ.killcount;
 407                                                 break;
 408                                         }
 409
 410                                         default:
 411                                         {
 412                                                 s1 = targ.netname;
 413                                                 f1 = targ.killcount;
 414                                                 s2 = NO_STR_ARG;
 415                                                 f2 = f3 = NO_FL_ARG;
 416                                                 break;
 417                                         }
 418                                 }
 419                                 LogDeath("suicide", deathtype, targ, targ);
 420                                 GiveFrags(attacker, targ, -1, deathtype);
 421                         }
 422
 423                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 424                 }
 425                 else if not(Obituary_WeaponDeath(FALSE, deathtype, targ.netname, NO_STR_ARG, targ.killcount))
 426                 {
 427                         backtrace("SUICIDE: what the hell happened here?\n");
 428                 }
 429         }
 430
 431         // ======
 432         // MURDER
 433         // ======
 434         else if(attacker.classname == "player")
 435         {
 436                 s1 = attacker.netname;
 437                 s2 = targ.netname;
 438
 439                 // TODO: ADD REAL CHECK HERE!
 440                 attacker.FRAG_VERBOSE = TRUE;
 441                 targ.FRAG_VERBOSE = TRUE;
 442
 443                 if(!IsDifferentTeam(attacker, targ))
 444                 {
 445                         LogDeath("tk", deathtype, attacker, targ);
 446                         GiveFrags(attacker, targ, -1, deathtype);
 447
 448                         attacker.killcount = 0;
 449
 450                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, DEATH_TEAMKILL_FRAG, s2, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 451                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, DEATH_TEAMKILL_FRAGGED, s1, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 452                         Send_Notification_Legacy_Wrapper(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 453
 454                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 455                         // No need for specific death/weapon messages...
 456                 }
 457                 else
 458                 {
 459                         LogDeath("frag", deathtype, attacker, targ);
 460                         GiveFrags(attacker, targ, 1, deathtype);
 461
 462                         attacker.taunt_soundtime = time + 1;
 463                         attacker.killcount = attacker.killcount + 1;
 464
 465                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 466                                 case numa: \
 467                                 { \
 468                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 469                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 470                                         break; \
 471                                 }
 472                         switch(attacker.killcount)
 473                         {
 474                                 ADD_ACHIEVEMENT_CASE(3, 03)
 475                                 ADD_ACHIEVEMENT_CASE(5, 05)
 476                                 ADD_ACHIEVEMENT_CASE(10, 10)
 477                                 ADD_ACHIEVEMENT_CASE(15, 15)
 478                                 ADD_ACHIEVEMENT_CASE(20, 20)
 479                                 ADD_ACHIEVEMENT_CASE(25, 25)
 480                                 ADD_ACHIEVEMENT_CASE(30, 30)
 481                                 default: break;
 482                         }
 483                         #undef ADD_ACHIEVEMENT_CASE
 484
 485                         if(!checkrules_firstblood)
 486                         {
 487                                 checkrules_firstblood = TRUE;
 488                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 489                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 490                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 491                         }
 492
 493                         if(notif_firstblood) // first blood, no kill sprees yet
 494                         {
 495                                 if(targ.istypefrag)
 496                                 {
 497                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAG_FIRST),
 498                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 499
 500                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAGGED_FIRST),
 501                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 502                                 }
 503                                 else
 504                                 {
 505                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_FIRST_VERBOSE : DEATH_MURDER_FRAG_FIRST),
 506                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 507
 508                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_FIRST_VERBOSE : DEATH_MURDER_FRAGGED_FIRST),
 509                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 510                                 }
 511                         }
 512                         else // normal frags, kill sprees listed
 513                         {
 514                                 if(targ.istypefrag)
 515                                 {
 516                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_VERBOSE : DEATH_MURDER_TYPEFRAG),
 517                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 518
 519                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_VERBOSE : DEATH_MURDER_TYPEFRAGGED),
 520                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 521                                 }
 522                                 else
 523                                 {
 524                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_VERBOSE : DEATH_MURDER_FRAG),
 525                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 526
 527                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_VERBOSE : DEATH_MURDER_FRAGGED),
 528                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 529                                 }
 530                         }
 531
 532                         //print("targ_killcount = ", ftos(targ.killcount), ", attacker_killcount = ", ftos(attacker.killcount), ".\n");
 533                         if not(Obituary_WeaponDeath(TRUE, deathtype, targ.netname, attacker.netname, targ.killcount))
 534                                 Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 535                 }
 536         }
 537
 538         // =============
 539         // ACCIDENT/TRAP
 540         // =============
 541         else
 542         {
 543                 switch(deathtype)
 544                 {
 545                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 546                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 547                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 548                         /*case DEATH_HURTTRIGGER:
 549                         {
 550                                 s1 = targ.netname;
 551                                 s2 = inflictor.message;
 552                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 553                                 break;
 554                         }*/
 555
 556                         case DEATH_CUSTOM:
 557                         {
 558                                 s1 = targ.netname;
 559                                 s2 = deathmessage;
 560                                 f1 = targ.killcount;
 561                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 562                                 f2 = f3 = NO_FL_ARG;
 563                                 break;
 564                         }
 565
 566                         default:
 567                         {
 568                                 s1 = targ.netname;
 569                                 f1 = targ.killcount;
 570                                 s2 = NO_STR_ARG;
 571                                 f2 = f3 = NO_FL_ARG;
 572                                 break;
 573                         }
 574                 }
 575
 576                 LogDeath("accident", deathtype, targ, targ);
 577                 GiveFrags(targ, targ, -1, deathtype);
 578
 579                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 580                 {
 581                         AnnounceTo(targ, "botlike");
 582                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 583                 }
 584
 585                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, f3);
 586         }
 587
 588         // Set final information for the death
 589         targ.death_origin = targ.origin;
 590         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 591         if(targ.killcount) { targ.killcount = 0; }
 592 }
 593
 594 // these are updated by each Damage call for use in button triggering and such
 595 entity damage_targ;
 596 entity damage_inflictor;
 597 entity damage_attacker;
 598
 599 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 600 {
 601         float mirrordamage;
 602         float mirrorforce;
 603         float teamdamage0;
 604         entity attacker_save;
 605         mirrordamage = 0;
 606         mirrorforce = 0;
 607
 608         if (gameover || targ.killcount == -666)
 609                 return;
 610
 611         entity oldself;
 612         oldself = self;
 613         self = targ;
 614         damage_targ = targ;
 615         damage_inflictor = inflictor;
 616         damage_attacker = attacker;
 617                 attacker_save = attacker;
 618
 619         if(targ.classname == "player")
 620                 if(targ.hook)
 621                         if(targ.hook.aiment)
 622                                 if(targ.hook.aiment == attacker)
 623                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 624
 625         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 626         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 627         {
 628                 if(targ.classname == "player")
 629                         if not(IsDifferentTeam(targ, attacker))
 630                         {
 631                                 self = oldself;
 632                                 return;
 633                         }
 634         }
 635
 636         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 637         {
 638                 // These are ALWAYS lethal
 639                 // No damage modification here
 640                 // Instead, prepare the victim for his death...
 641                 targ.armorvalue = 0;
 642                 targ.spawnshieldtime = 0;
 643                 targ.health = 0.9; // this is < 1
 644                 targ.flags -= targ.flags & FL_GODMODE;
 645                 damage = 100000;
 646         }
 647         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 648         {
 649                 // no processing
 650         }
 651         else
 652         {
 653                 /*
 654                 skill based bot damage? gtfo. (tZork)
 655                 if (targ.classname == "player")
 656                 if (attacker.classname == "player")
 657                 if (!targ.isbot)
 658                 if (attacker.isbot)
 659                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 660         */
 661
 662                 // nullify damage if teamplay is on
 663                 if(deathtype != DEATH_TELEFRAG)
 664                 if(attacker.classname == "player")
 665                 {
 666                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 667                         {
 668                                 damage = 0;
 669                                 force = '0 0 0';
 670                         }
 671                         else if(!IsDifferentTeam(attacker, targ))
 672                         {
 673                                 if(autocvar_teamplay_mode == 1)
 674                                         damage = 0;
 675                                 else if(attacker != targ)
 676                                 {
 677                                         if(autocvar_teamplay_mode == 3)
 678                                                 damage = 0;
 679                                         else if(autocvar_teamplay_mode == 4)
 680                                         {
 681                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 682                                                 {
 683                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 684                                                         attacker.dmg_team = attacker.dmg_team + damage;
 685                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 686                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 687                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 688                                                         if(g_minstagib)
 689                                                         {
 690                                                                 if(autocvar_g_friendlyfire == 0)
 691                                                                         damage = 0;
 692                                                         }
 693                                                         else if(g_ca)
 694                                                                 damage = 0;
 695                                                         else
 696                                                                 damage = autocvar_g_friendlyfire * damage;
 697                                                         // mirrordamage will be used LATER
 698
 699                                                         if(autocvar_g_mirrordamage_virtual)
 700                                                         {
 701                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 702                                                                 attacker.dmg_take += v_x;
 703                                                                 attacker.dmg_save += v_y;
 704                                                                 attacker.dmg_inflictor = inflictor;
 705                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 706                                                                 mirrorforce = 0;
 707                                                         }
 708
 709                                                         if(autocvar_g_friendlyfire_virtual)
 710                                                         {
 711                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 712                                                                 targ.dmg_take += v_x;
 713                                                                 targ.dmg_save += v_y;
 714                                                                 targ.dmg_inflictor = inflictor;
 715                                                                 damage = 0;
 716                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 717                                                                         force = '0 0 0';
 718                                                         }
 719                                                 }
 720                                                 else
 721                                                         damage = 0;
 722                                         }
 723                                 }
 724                         }
 725                 }
 726
 727                 if(targ.classname == "player")
 728                 if(attacker.classname == "player")
 729                 if(attacker != targ)
 730                 {
 731                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 732                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 733                 }
 734
 735                 if(targ.classname == "player")
 736                 if (g_minstagib)
 737                 {
 738                         if ((deathtype == DEATH_FALL)  ||
 739                                 (deathtype == DEATH_DROWN) ||
 740                                 (deathtype == DEATH_SLIME) ||
 741                                 (deathtype == DEATH_LAVA)  ||
 742                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 743                         {
 744                                 self = oldself;
 745                                 return;
 746                         }
 747                         if(damage > 0)
 748                             damage = 10000;
 749                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 750                         {
 751                                 targ.armorvalue -= 1;
 752                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 753                                 damage = 0;
 754                                 targ.hitsound += 1;
 755                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 756                         }
 757                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 758                         {
 759                                 damage = 0;
 760                                 mirrordamage = 0;
 761                                 if (targ != attacker)
 762                                 {
 763                                         if ((targ.health >= 1) && (targ.classname == "player"))
 764                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 765                                         force = '0 0 0';
 766                                         // keep mirrorforce
 767                                         attacker = targ;
 768                                 }
 769                         }
 770                 }
 771
 772                 if not(DEATH_ISSPECIAL(deathtype))
 773                 {
 774                         damage *= g_weapondamagefactor;
 775                         mirrordamage *= g_weapondamagefactor;
 776                         force = force * g_weaponforcefactor;
 777                         mirrorforce *= g_weaponforcefactor;
 778                 }
 779
 780                 // should this be changed at all? If so, in what way?
 781                 frag_attacker = attacker;
 782                 frag_target = targ;
 783                 frag_damage = damage;
 784                 frag_force = force;
 785         frag_deathtype = deathtype;
 786                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 787                 damage = frag_damage;
 788                 force = frag_force;
 789
 790                 // apply strength multiplier
 791                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 792                 {
 793                         if(targ == attacker)
 794                         {
 795                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 796                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 797                         }
 798                         else
 799                         {
 800                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 801                                 force = force * autocvar_g_balance_powerup_strength_force;
 802                         }
 803                 }
 804
 805                 // apply invincibility multiplier
 806                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 807                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 808
 809                 if (targ == attacker)
 810                 {
 811                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 812                                 damage = 0;
 813                         else
 814                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 815                 }
 816
 817                 if(g_runematch)
 818                 {
 819                         // apply strength rune
 820                         if (attacker.runes & RUNE_STRENGTH)
 821                         {
 822                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 823                                 {
 824                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 825                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 826                                 }
 827                                 else
 828                                 {
 829                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 830                                         force = force * autocvar_g_balance_rune_strength_force;
 831                                 }
 832                         }
 833                         else if (attacker.runes & CURSE_WEAK)
 834                         {
 835                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 836                                 force = force * autocvar_g_balance_curse_weak_force;
 837                         }
 838
 839                         // apply defense rune
 840                         if (targ.runes & RUNE_DEFENSE)
 841                         {
 842                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 843                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 844                                 else
 845                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 846                         }
 847                         else if (targ.runes & CURSE_VULNER)
 848                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 849                 }
 850
 851                 // count the damage
 852                 if(attacker)
 853                 if(!targ.deadflag)
 854                 if(targ.takedamage == DAMAGE_AIM)
 855                 if(targ != attacker)
 856                 {
 857                         if(damage_headshotbonus)
 858                         {
 859                                 if(targ.classname == "player")
 860                                 {
 861                                         // HEAD SHOT:
 862                                         // find height of hit on player axis
 863                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 864                                         vector headmins, headmaxs, org;
 865                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 866                                         headmins = org + GetHeadshotMins(targ);
 867                                         headmaxs = org + GetHeadshotMaxs(targ);
 868                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 869                                         {
 870                                                 deathtype |= HITTYPE_HEADSHOT;
 871                                         }
 872                                 }
 873                                 else if(targ.classname == "turret_head")
 874                                 {
 875                                         deathtype |= HITTYPE_HEADSHOT;
 876                                 }
 877                                 if(deathtype & HITTYPE_HEADSHOT)
 878                                         if(damage_headshotbonus > 0)
 879                                                 damage *= 1 + damage_headshotbonus;
 880                         }
 881
 882                         entity victim;
 883                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 884                                 victim = targ.owner;
 885                         else
 886                                 victim = targ;
 887
 888                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 889                         {
 890                                 if(IsDifferentTeam(victim, attacker))
 891                                 {
 892                                         if(damage > 0)
 893                                         {
 894                                                 if(deathtype != DEATH_FIRE)
 895                                                 {
 896                                                         if(victim.BUTTON_CHAT)
 897                                                                 attacker.typehitsound += 1;
 898                                                         else
 899                                                                 attacker.hitsound += 1;
 900                                                 }
 901
 902                                                 damage_goodhits += 1;
 903                                                 damage_gooddamage += damage;
 904
 905                                                 if not(DEATH_ISSPECIAL(deathtype))
 906                                                 {
 907                                                         if(targ.classname == "player") // don't do this for vehicles
 908                                                         if(!g_minstagib)
 909                                                         if(IsFlying(victim))
 910                                                                 yoda = 1;
 911
 912                                                         if(g_minstagib)
 913                                                         if(victim.items & IT_STRENGTH)
 914                                                                 yoda = 1;
 915
 916                                                         if(deathtype & HITTYPE_HEADSHOT)
 917                                                                 headshot = 1;
 918                                                 }
 919                                         }
 920                                 }
 921                                 else
 922                                 {
 923                                         if(deathtype != DEATH_FIRE)
 924                                         {
 925                                                 attacker.typehitsound += 1;
 926                                         }
 927                                         if(mirrordamage > 0)
 928                                                 if(time > attacker.teamkill_complain)
 929                                                 {
 930                                                         attacker.teamkill_complain = time + 5;
 931                                                         attacker.teamkill_soundtime = time + 0.4;
 932                                                         attacker.teamkill_soundsource = targ;
 933                                                 }
 934                                 }
 935                         }
 936                 }
 937         }
 938
 939         // apply push
 940         if (self.damageforcescale)
 941         if (vlen(force))
 942         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 943         {
 944                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 945                 if(self.movetype == MOVETYPE_PHYSICS)
 946                 {
 947                         entity farcent;
 948                         farcent = spawn();
 949                         farcent.classname = "farce";
 950                         farcent.enemy = self;
 951                         farcent.movedir = farce * 10;
 952                         if(self.mass)
 953                                 farcent.movedir = farcent.movedir * self.mass;
 954                         farcent.origin = hitloc;
 955                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 956                         farcent.nextthink = time + 0.1;
 957                         farcent.think = SUB_Remove;
 958                 }
 959                 else
 960                         self.velocity = self.velocity + farce;
 961                 self.flags &~= FL_ONGROUND;
 962                 UpdateCSQCProjectile(self);
 963         }
 964         // apply damage
 965         if (damage != 0 || (self.damageforcescale && vlen(force)))
 966         if (self.event_damage)
 967                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 968         self = oldself;
 969
 970         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 971         {
 972                 if(g_runematch)
 973                 {
 974                         if (attacker.runes & RUNE_VAMPIRE)
 975                         {
 976                         // apply vampire rune
 977                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 978                                 {
 979                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 980                                         attacker.health = bound(
 981                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 982                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 983                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 984                                 }
 985                                 else
 986                                 {
 987                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 988                                         attacker.health = bound(
 989                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 990                                                                                         // empathy won't let you gain health in the same way...
 991                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 992                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 993                                         }
 994                         }
 995                         // apply empathy curse
 996                         else if (attacker.runes & CURSE_EMPATHY)
 997                         {
 998                                 attacker.health = bound(
 999                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
1000                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
1001                                         attacker.health);
1002                         }
1003                 }
1004         }
1005
1006         // apply mirror damage if any
1007         if(mirrordamage > 0 || mirrorforce > 0)
1008         {
1009                 attacker = attacker_save;
1010                 if(g_minstagib)
1011                 if(mirrordamage > 0)
1012                 {
1013                         // just lose extra LIVES, don't kill the player for mirror damage
1014                         if(attacker.armorvalue > 0)
1015                         {
1016                                 attacker.armorvalue = attacker.armorvalue - 1;
1017                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
1018                                 attacker.hitsound += 1;
1019                         }
1020                         mirrordamage = 0;
1021                 }
1022
1023                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1024                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1025         }
1026 }
1027
1028 float RadiusDamage_running;
1029 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1030         // Returns total damage applies to creatures
1031 {
1032         entity  targ;
1033         vector  blastorigin;
1034         vector  force;
1035         float   total_damage_to_creatures;
1036         entity  next;
1037         float   tfloordmg;
1038         float   tfloorforce;
1039
1040         float stat_damagedone;
1041
1042         if(RadiusDamage_running)
1043         {
1044                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1045                 return 0;
1046         }
1047
1048         RadiusDamage_running = 1;
1049
1050         tfloordmg = autocvar_g_throughfloor_damage;
1051         tfloorforce = autocvar_g_throughfloor_force;
1052
1053         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1054         total_damage_to_creatures = 0;
1055
1056         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1057                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1058                 {
1059                         force = inflictor.velocity;
1060                         if(vlen(force) == 0)
1061                                 force = '0 0 -1';
1062                         else
1063                                 force = normalize(force);
1064                         if(forceintensity >= 0)
1065                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1066                         else
1067                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1068                 }
1069
1070         stat_damagedone = 0;
1071
1072         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1073         while (targ)
1074         {
1075                 next = targ.chain;
1076                 if (targ != inflictor)
1077                         if (ignore != targ) if(targ.takedamage)
1078                         {
1079                                 vector nearest;
1080                                 vector diff;
1081                                 float power;
1082
1083                                 // LordHavoc: measure distance to nearest point on target (not origin)
1084                                 // (this guarentees 100% damage on a touch impact)
1085                                 nearest = targ.WarpZone_findradius_nearest;
1086                                 diff = targ.WarpZone_findradius_dist;
1087                                 // round up a little on the damage to ensure full damage on impacts
1088                                 // and turn the distance into a fraction of the radius
1089                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1090                                 //bprint(" ");
1091                                 //bprint(ftos(power));
1092                                 //if (targ == attacker)
1093                                 //      print(ftos(power), "\n");
1094                                 if (power > 0)
1095                                 {
1096                                         float finaldmg;
1097                                         if (power > 1)
1098                                                 power = 1;
1099                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1100                                         if (finaldmg > 0)
1101                                         {
1102                                                 float a;
1103                                                 float c;
1104                                                 vector hitloc;
1105                                                 vector myblastorigin;
1106                                                 vector center;
1107
1108                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1109
1110                                                 // if it's a player, use the view origin as reference
1111                                                 center = CENTER_OR_VIEWOFS(targ);
1112
1113                                                 force = normalize(center - myblastorigin);
1114                                                 force = force * (finaldmg / coredamage) * forceintensity;
1115                                                 hitloc = nearest;
1116
1117                                                 if(targ != directhitentity)
1118                                                 {
1119                                                         float hits;
1120                                                         float total;
1121                                                         float hitratio;
1122                                                         float mininv_f, mininv_d;
1123
1124                                                         // test line of sight to multiple positions on box,
1125                                                         // and do damage if any of them hit
1126                                                         hits = 0;
1127
1128                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1129                                                         // so for a given max stddev:
1130                                                         // n = (1 / (2 * max stddev of hitratio))^2
1131
1132                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1133                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1134
1135                                                         if(autocvar_g_throughfloor_debug)
1136                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1137
1138                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1139
1140                                                         if(autocvar_g_throughfloor_debug)
1141                                                                 print(sprintf(" steps=%f", total));
1142
1143                                                         if (targ.classname == "player")
1144                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1145                                                         else
1146                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1147
1148                                                         if(autocvar_g_throughfloor_debug)
1149                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1150
1151                                                         for(c = 0; c < total; ++c)
1152                                                         {
1153                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1154                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1155                                                                 if (trace_fraction == 1 || trace_ent == targ)
1156                                                                 {
1157                                                                         ++hits;
1158                                                                         if (hits > 1)
1159                                                                                 hitloc = hitloc + nearest;
1160                                                                         else
1161                                                                                 hitloc = nearest;
1162                                                                 }
1163                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1164                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1165                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1166                                                         }
1167
1168                                                         nearest = hitloc * (1 / max(1, hits));
1169                                                         hitratio = (hits / total);
1170                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1171                                                         finaldmg = finaldmg * a;
1172                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1173                                                         force = force * a;
1174
1175                                                         if(autocvar_g_throughfloor_debug)
1176                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1177                                                 }
1178
1179                                                 // laser force adjustments :P
1180                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1181                                                 {
1182                                                         if (targ == attacker)
1183                                                         {
1184                                                                 vector vel;
1185
1186                                                                 float force_zscale;
1187                                                                 float force_velocitybiasramp;
1188                                                                 float force_velocitybias;
1189
1190                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1191                                                                 if(deathtype & HITTYPE_SECONDARY)
1192                                                                 {
1193                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1194                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1195                                                                 }
1196                                                                 else
1197                                                                 {
1198                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1199                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1200                                                                 }
1201
1202                                                                 vel = targ.velocity;
1203                                                                 vel_z = 0;
1204                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1205                                                                 force =
1206                                                                         vlen(force)
1207                                                                         *
1208                                                                         normalize(normalize(force) + vel);
1209
1210                                                                 force_z *= force_zscale;
1211                                                         }
1212                                                         else
1213                                                         {
1214                                                                 if(deathtype & HITTYPE_SECONDARY)
1215                                                                 {
1216                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1217                                                                 }
1218                                                                 else
1219                                                                 {
1220                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1221                                                                 }
1222                                                         }
1223                                                 }
1224
1225                                                 //if (targ == attacker)
1226                                                 //{
1227                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1228                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1229                                                 //      print(" (", ftos(a), ")\n");
1230                                                 //}
1231                                                 if(finaldmg || vlen(force))
1232                                                 {
1233                                                         if(targ.iscreature)
1234                                                         {
1235                                                                 total_damage_to_creatures += finaldmg;
1236
1237                                                                 if(accuracy_isgooddamage(attacker, targ))
1238                                                                         stat_damagedone += finaldmg;
1239                                                         }
1240
1241                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1242                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1243                                                         else
1244                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1245                                                 }
1246                                         }
1247                                 }
1248                         }
1249                 targ = next;
1250         }
1251
1252         RadiusDamage_running = 0;
1253
1254         if(!DEATH_ISSPECIAL(deathtype))
1255                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1256
1257         return total_damage_to_creatures;
1258 }
1259
1260 .float fire_damagepersec;
1261 .float fire_endtime;
1262 .float fire_deathtype;
1263 .entity fire_owner;
1264 .float fire_hitsound;
1265 .entity fire_burner;
1266
1267 void fireburner_think();
1268
1269 float Fire_IsBurning(entity e)
1270 {
1271         return (time < e.fire_endtime);
1272 }
1273
1274 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1275 {
1276         float dps;
1277         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1278
1279         if(e.classname == "player")
1280         {
1281                 if(e.deadflag)
1282                         return -1;
1283         }
1284         else
1285         {
1286                 if(!e.fire_burner)
1287                 {
1288                         // print("adding a fire burner to ", e.classname, "\n");
1289                         e.fire_burner = spawn();
1290                         e.fire_burner.classname = "fireburner";
1291                         e.fire_burner.think = fireburner_think;
1292                         e.fire_burner.nextthink = time;
1293                         e.fire_burner.owner = e;
1294                 }
1295         }
1296
1297         t = max(t, 0.1);
1298         dps = d / t;
1299         if(Fire_IsBurning(e))
1300         {
1301                 mintime = e.fire_endtime - time;
1302                 maxtime = max(mintime, t);
1303
1304                 mindps = e.fire_damagepersec;
1305                 maxdps = max(mindps, dps);
1306
1307                 if(maxtime > mintime || maxdps > mindps)
1308                 {
1309                         // Constraints:
1310
1311                         // damage we have right now
1312                         mindamage = mindps * mintime;
1313
1314                         // damage we want to get
1315                         maxdamage = mindamage + d;
1316
1317                         // but we can't exceed maxtime * maxdps!
1318                         totaldamage = min(maxdamage, maxtime * maxdps);
1319
1320                         // LEMMA:
1321                         // Look at:
1322                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1323                         // We see:
1324                         // totaldamage <= maxtime * maxdps
1325                         // ==> totaldamage / maxdps <= maxtime.
1326                         // We also see:
1327                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1328                         //                     >= min(mintime, maxtime)
1329                         // ==> totaldamage / maxdps >= mintime.
1330
1331                         /*
1332                         // how long do we damage then?
1333                         // at least as long as before
1334                         // but, never exceed maxdps
1335                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1336                         */
1337
1338                         // alternate:
1339                         // at most as long as maximum allowed
1340                         // but, never below mindps
1341                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1342
1343                         // assuming t > mintime, dps > mindps:
1344                         // we get d = t * dps = maxtime * maxdps
1345                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1346                         // totaldamage / maxdps = maxtime
1347                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1348                         // FROM THIS:
1349                         // a) totaltime = max(mintime, maxtime) = maxtime
1350                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1351
1352                         // assuming t <= mintime:
1353                         // we get maxtime = mintime
1354                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1355                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1356
1357                         // assuming dps <= mindps:
1358                         // we get mindps = maxdps.
1359                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1360                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1361                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1362
1363                         e.fire_damagepersec = totaldamage / totaltime;
1364                         e.fire_endtime = time + totaltime;
1365                         if(totaldamage > 1.2 * mindamage)
1366                         {
1367                                 e.fire_deathtype = dt;
1368                                 if(e.fire_owner != o)
1369                                 {
1370                                         e.fire_owner = o;
1371                                         e.fire_hitsound = FALSE;
1372                                 }
1373                         }
1374                         if(accuracy_isgooddamage(o, e))
1375                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1376                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1377                 }
1378                 else
1379                         return 0;
1380         }
1381         else
1382         {
1383                 e.fire_damagepersec = dps;
1384                 e.fire_endtime = time + t;
1385                 e.fire_deathtype = dt;
1386                 e.fire_owner = o;
1387                 e.fire_hitsound = FALSE;
1388                 if(accuracy_isgooddamage(o, e))
1389                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1390                 return d;
1391         }
1392 }
1393
1394 void Fire_ApplyDamage(entity e)
1395 {
1396         float t, d, hi, ty;
1397         entity o;
1398
1399         if not(Fire_IsBurning(e))
1400                 return;
1401
1402         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1403         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1404                 o = e.fire_owner;
1405
1406         // water and slime stop fire
1407         if(e.waterlevel)
1408         if(e.watertype != CONTENT_LAVA)
1409                 e.fire_endtime = 0;
1410
1411         // ice stops fire
1412         if(e.freezetag_frozen)
1413                 e.fire_endtime = 0;
1414
1415         t = min(frametime, e.fire_endtime - time);
1416         d = e.fire_damagepersec * t;
1417
1418         hi = e.fire_owner.hitsound;
1419         ty = e.fire_owner.typehitsound;
1420         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1421         if(e.fire_hitsound && e.fire_owner)
1422         {
1423                 e.fire_owner.hitsound = hi;
1424                 e.fire_owner.typehitsound = ty;
1425         }
1426         e.fire_hitsound = TRUE;
1427
1428         if not(IS_INDEPENDENT_PLAYER(e))
1429         FOR_EACH_PLAYER(other) if(e != other)
1430         {
1431                 if(other.classname == "player")
1432                 if(other.deadflag == DEAD_NO)
1433                 if not(IS_INDEPENDENT_PLAYER(other))
1434                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1435                 {
1436                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1437                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1438                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1439                 }
1440         }
1441 }
1442
1443 void Fire_ApplyEffect(entity e)
1444 {
1445         if(Fire_IsBurning(e))
1446                 e.effects |= EF_FLAME;
1447         else
1448                 e.effects &~= EF_FLAME;
1449 }
1450
1451 void fireburner_think()
1452 {
1453         // for players, this is done in the regular loop
1454         if(wasfreed(self.owner))
1455         {
1456                 remove(self);
1457                 return;
1458         }
1459         Fire_ApplyEffect(self.owner);
1460         if(!Fire_IsBurning(self.owner))
1461         {
1462                 self.owner.fire_burner = world;
1463                 remove(self);
1464                 return;
1465         }
1466         Fire_ApplyDamage(self.owner);
1467         self.nextthink = time;
1468 }