make sure the SUB_CalcMove controller cannot set a velocity after the think function...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_subs.qc
1 void SUB_Null() {};
2 float SUB_True() { return 1; }
3 float SUB_False() { return 0; }
4
5 void(vector destangle, float tspeed, void() func) SUB_CalcAngleMove;
6 void()  SUB_CalcMoveDone;
7 void() SUB_CalcAngleMoveDone;
8 //void() SUB_UseTargets;
9 void() SUB_Remove;
10
11 void spawnfunc_info_null (void)
12 {
13         remove(self);
14         // if anything breaks, tell the mapper to fix his map! info_null is meant to remove itself immediately.
15 }
16
17 void setanim(entity e, vector anim, float looping, float override, float restart)
18 {
19         if (anim_x == e.animstate_startframe)
20         if (anim_y == e.animstate_numframes)
21         if (anim_z == e.animstate_framerate)
22         {
23                 if(restart)
24                 {
25                         if(restart > 0)
26                         if(anim_y == 1) // ZYM animation
27                                 BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
28                 }
29                 else
30                         return;
31         }
32         e.animstate_startframe = anim_x;
33         e.animstate_numframes = anim_y;
34         e.animstate_framerate = anim_z;
35         e.animstate_starttime = servertime - 0.1 * serverframetime; // shift it a little bit into the past to prevent float inaccuracy hiccups
36         e.animstate_endtime = e.animstate_starttime + e.animstate_numframes / e.animstate_framerate;
37         e.animstate_looping = looping;
38         e.animstate_override = override;
39         e.frame = e.animstate_startframe;
40         e.frame1time = servertime;
41 };
42
43 void updateanim(entity e)
44 {
45         if (time >= e.animstate_endtime)
46         {
47                 if (e.animstate_looping)
48                 {
49                         e.animstate_starttime = e.animstate_endtime;
50                         e.animstate_endtime = e.animstate_starttime + e.animstate_numframes / e.animstate_framerate;
51                 }
52                 e.animstate_override = FALSE;
53         }
54         e.frame = e.animstate_startframe + bound(0, (time - e.animstate_starttime) * e.animstate_framerate, e.animstate_numframes - 1);
55         //print(ftos(time), " -> ", ftos(e.frame), "\n");
56 };
57
58 float animparseerror;
59 vector animparseline(float animfile)
60 {
61         local string line;
62         local float c;
63         local vector anim;
64         if (animfile < 0)
65                 return '0 1 2';
66         line = fgets(animfile);
67         c = tokenize_console(line);
68         if (c < 3)
69         {
70                 animparseerror = TRUE;
71                 return '0 1 2';
72         }
73         anim_x = stof(argv(0));
74         anim_y = stof(argv(1));
75         anim_z = stof(argv(2));
76         // don't allow completely bogus values
77         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
78                 anim = '0 1 2';
79         return anim;
80 };
81
82 /*
83 ==================
84 SUB_Remove
85
86 Remove self
87 ==================
88 */
89 void SUB_Remove (void)
90 {
91         remove (self);
92 }
93
94 /*
95 ==================
96 SUB_Friction
97
98 Applies some friction to self
99 ==================
100 */
101 .float friction;
102 void SUB_Friction (void)
103 {
104         self.nextthink = time;
105         if(self.flags & FL_ONGROUND)
106                 self.velocity = self.velocity * (1 - frametime * self.friction);
107 }
108
109 /*
110 ==================
111 SUB_VanishOrRemove
112
113 Makes client invisible or removes non-client
114 ==================
115 */
116 void SUB_VanishOrRemove (entity ent)
117 {
118         if (ent.flags & FL_CLIENT)
119         {
120                 // vanish
121                 ent.model = "";
122                 ent.effects = 0;
123                 ent.glow_size = 0;
124                 ent.pflags = 0;
125         }
126         else
127         {
128                 // remove
129                 remove (ent);
130         }
131 }
132
133 void SUB_SetFade_Think (void)
134 {
135         self.think = SUB_SetFade_Think;
136         self.nextthink = self.fade_time;
137         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
138         if (self.alpha < 0.01)
139                 SUB_VanishOrRemove(self);
140         self.alpha = bound(0.01, self.alpha, 1);
141 }
142
143 /*
144 ==================
145 SUB_SetFade
146
147 Fade 'ent' out when time >= 'when'
148 ==================
149 */
150 void SUB_SetFade (entity ent, float when, float fadetime)
151 {
152         //if (ent.flags & FL_CLIENT) // && ent.deadflag != DEAD_NO)
153         //      return;
154         //ent.alpha = 1;
155         ent.fade_rate = 1/fadetime;
156         ent.fade_time = when;
157         ent.think = SUB_SetFade_Think;
158         ent.nextthink = when;
159 }
160
161 /*
162 =============
163 SUB_CalcMove
164
165 calculate self.velocity and self.nextthink to reach dest from
166 self.origin traveling at speed
167 ===============
168 */
169 void SUB_CalcMoveDone (void)
170 {
171         // After moving, set origin to exact final destination
172
173         setorigin (self, self.finaldest);
174         self.velocity = '0 0 0';
175         self.nextthink = -1;
176         if (self.think1)
177                 self.think1 ();
178 }
179
180 void SUB_CalcMove_controller_think (void)
181 {
182         entity oldself;
183         float movephase;
184         float traveltime;
185         float phasepos;
186         vector delta;
187         vector veloc;
188         if(time < self.animstate_endtime) {
189                 delta = self.destvec;
190                 traveltime = self.animstate_endtime - self.animstate_starttime;
191                 movephase = (time - self.animstate_starttime) / traveltime;
192
193                 //bprint(ftos(movephase));
194                 //bprint("\n");
195
196                 // TODO: Don't mess with the velocity, instead compute where
197                 // we want to be next tick and compute velocity from that
198
199                 veloc = delta * (1/traveltime); // QuakeC doesn't allow vector/float division
200
201                 // scale velocity with pi/2 so integrated over time we
202                 // still have the original velocity
203                 veloc = veloc * 1.5708;
204
205                 // scale velocity with sin(phase)
206                 phasepos = movephase * 3.1416; // phase * pi
207                 phasepos = sin(phasepos);
208                 veloc = veloc * phasepos;       
209
210                 self.owner.velocity = veloc;
211                 self.nextthink = time + 0.1;
212         } else {
213                 oldself = self;
214                 self.owner.think = self.think1;
215                 self = self.owner;
216                 remove(oldself);
217                 self.think();
218         }
219 }
220
221 void SUB_CalcMove (vector tdest, float tspeed, void() func)
222 {
223         vector  delta;
224         float   traveltime;
225         entity controller;
226
227         if (!tspeed)
228                 objerror ("No speed is defined!");
229
230         self.think1 = func;
231         self.finaldest = tdest;
232         self.think = SUB_CalcMoveDone;
233
234         if (tdest == self.origin)
235         {
236                 self.velocity = '0 0 0';
237                 self.nextthink = self.ltime + 0.1;
238                 return;
239         }
240
241         delta = tdest - self.origin;
242         traveltime = vlen (delta) / tspeed;
243
244         if (traveltime < 0.1)
245         {
246                 self.velocity = '0 0 0';
247                 self.nextthink = self.ltime + 0.1;
248                 return;
249         }
250
251         controller = spawn();
252         controller.classname = "SUB_CalcMove_controller";
253         controller.owner = self;
254         controller.origin = self.origin; // starting point
255         controller.finaldest = tdest; // where do we want to end?
256         controller.destvec = delta;
257         controller.animstate_starttime = time;
258         controller.animstate_endtime = time + traveltime;
259         controller.think = SUB_CalcMove_controller_think;
260         controller.think1 = self.think;
261
262         // let the controller handle the velocity compuation
263         //self.velocity = delta * (1/traveltime);       // QuakeC doesn't allow vector/float division
264         self.think = SUB_Null;
265         self.nextthink = self.ltime + traveltime;
266         
267         // invoke controller
268         self = controller;
269         self.think();
270 }
271
272 void SUB_CalcMoveEnt (entity ent, vector tdest, float tspeed, void() func)
273 {
274         entity  oldself;
275
276         oldself = self;
277         self = ent;
278
279         SUB_CalcMove (tdest, tspeed, func);
280
281         self = oldself;
282 }
283
284 /*
285 =============
286 SUB_CalcAngleMove
287
288 calculate self.avelocity and self.nextthink to reach destangle from
289 self.angles rotating
290
291 The calling function should make sure self.think is valid
292 ===============
293 */
294 void SUB_CalcAngleMoveDone (void)
295 {
296         // After rotating, set angle to exact final angle
297         self.angles = self.finalangle;
298         self.avelocity = '0 0 0';
299         self.nextthink = -1;
300         if (self.think1)
301                 self.think1 ();
302 }
303
304 // FIXME: I fixed this function only for rotation around the main axes
305 void SUB_CalcAngleMove (vector destangle, float tspeed, void() func)
306 {
307         vector  delta;
308         float   traveltime;
309
310         if (!tspeed)
311                 objerror ("No speed is defined!");
312
313         // take the shortest distance for the angles
314         self.angles_x -= 360 * floor((self.angles_x - destangle_x) / 360 + 0.5);
315         self.angles_y -= 360 * floor((self.angles_y - destangle_y) / 360 + 0.5);
316         self.angles_z -= 360 * floor((self.angles_z - destangle_z) / 360 + 0.5);
317         delta = destangle - self.angles;
318         traveltime = vlen (delta) / tspeed;
319
320         self.think1 = func;
321         self.finalangle = destangle;
322         self.think = SUB_CalcAngleMoveDone;
323
324         if (traveltime < 0.1)
325         {
326                 self.avelocity = '0 0 0';
327                 self.nextthink = self.ltime + 0.1;
328                 return;
329         }
330
331         self.avelocity = delta * (1 / traveltime);
332         self.nextthink = self.ltime + traveltime;
333 }
334
335 void SUB_CalcAngleMoveEnt (entity ent, vector destangle, float tspeed, void() func)
336 {
337         entity  oldself;
338
339         oldself = self;
340         self = ent;
341
342         SUB_CalcAngleMove (destangle, tspeed, func);
343
344         self = oldself;
345 }
346
347 /*
348 ==================
349 main
350
351 unused but required by the engine
352 ==================
353 */
354 void main (void)
355 {
356
357 }
358
359 // Misc
360
361 /*
362 ==================
363 traceline_antilag
364
365 A version of traceline that must be used by SOLID_SLIDEBOX things that want to hit SOLID_CORPSE things with a trace attack
366 Additionally it moves players back into the past before the trace and restores them afterward.
367 ==================
368 */
369 void tracebox_antilag_force_wz (entity source, vector v1, vector mi, vector ma, vector v2, float nomonst, entity forent, float lag, float wz)
370 {
371         local entity player;
372         local float oldsolid;
373
374         // check whether antilagged traces are enabled
375         if (lag < 0.001)
376                 lag = 0;
377         if (clienttype(forent) != CLIENTTYPE_REAL)
378                 lag = 0; // only antilag for clients
379
380         // change shooter to SOLID_BBOX so the shot can hit corpses
381         if(source)
382         {
383                 oldsolid = source.dphitcontentsmask;
384                 source.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
385         }
386
387         if (lag)
388         {
389                 // take players back into the past
390                 player = player_list;
391                 while (player)
392                 {
393                         antilag_takeback(player, time - lag);
394                         player = player.nextplayer;
395                 }
396         }
397
398         // do the trace
399         if(wz)
400                 WarpZone_TraceBox (v1, mi, ma, v2, nomonst, forent);
401         else
402                 tracebox (v1, mi, ma, v2, nomonst, forent);
403
404         // restore players to current positions
405         if (lag)
406         {
407                 player = player_list;
408                 while (player)
409                 {
410                         antilag_restore(player);
411                         player = player.nextplayer;
412                 }
413         }
414
415         // restore shooter solid type
416         if(source)
417                 source.dphitcontentsmask = oldsolid;
418 }
419 void traceline_antilag_force (entity source, vector v1, vector v2, float nomonst, entity forent, float lag)
420 {
421         tracebox_antilag_force_wz(source, v1, '0 0 0', '0 0 0', v2, nomonst, forent, lag, FALSE);
422 }
423 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag)
424 {
425         if (cvar("g_antilag") != 2 || source.cvar_cl_noantilag)
426                 lag = 0;
427         traceline_antilag_force(source, v1, v2, nomonst, forent, lag);
428 }
429 void tracebox_antilag (entity source, vector v1, vector mi, vector ma, vector v2, float nomonst, entity forent, float lag)
430 {
431         if (cvar("g_antilag") != 2 || source.cvar_cl_noantilag)
432                 lag = 0;
433         tracebox_antilag_force_wz(source, v1, mi, ma, v2, nomonst, forent, lag, FALSE);
434 }
435 void WarpZone_traceline_antilag_force (entity source, vector v1, vector v2, float nomonst, entity forent, float lag)
436 {
437         tracebox_antilag_force_wz(source, v1, '0 0 0', '0 0 0', v2, nomonst, forent, lag, TRUE);
438 }
439 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag)
440 {
441         if (cvar("g_antilag") != 2 || source.cvar_cl_noantilag)
442                 lag = 0;
443         WarpZone_traceline_antilag_force(source, v1, v2, nomonst, forent, lag);
444 }
445 void WarpZone_tracebox_antilag (entity source, vector v1, vector mi, vector ma, vector v2, float nomonst, entity forent, float lag)
446 {
447         if (cvar("g_antilag") != 2 || source.cvar_cl_noantilag)
448                 lag = 0;
449         tracebox_antilag_force_wz(source, v1, mi, ma, v2, nomonst, forent, lag, TRUE);
450 }
451
452 float tracebox_inverted (vector v1, vector mi, vector ma, vector v2, float nomonsters, entity forent) // returns the number of traces done, for benchmarking
453 {
454         vector pos, dir, t;
455         float nudge;
456
457         //nudge = 2 * cvar("collision_impactnudge"); // why not?
458         nudge = 0.5;
459
460         dir = normalize(v2 - v1);
461
462         pos = v1 + dir * nudge;
463
464         float c;
465         c = 0;
466
467         for(;;)
468         {
469                 if((pos - v1) * dir >= (v2 - v1) * dir)
470                 {
471                         // went too far
472                         trace_fraction = 1;
473                         trace_endpos = v2;
474                         return c;
475                 }
476
477                 tracebox(pos, mi, ma, v2, nomonsters, forent);
478                 ++c;
479
480                 if(c == 50)
481                 {
482                         dprint("HOLY SHIT! When tracing from ", vtos(v1), " to ", vtos(v2), "\n");
483                         dprint("  Nudging gets us nowhere at ", vtos(pos), "\n");
484                         dprint("  trace_endpos is ", vtos(trace_endpos), "\n");
485                         dprint("  trace distance is ", ftos(vlen(pos - trace_endpos)), "\n");
486                 }
487
488                 if(trace_startsolid)
489                 {
490                         // we started inside solid.
491                         // then trace from endpos to pos
492                         t = trace_endpos;
493                         tracebox(t, mi, ma, pos, nomonsters, forent);
494                         ++c;
495                         if(trace_startsolid)
496                         {
497                                 // t is still inside solid? bad
498                                 // force advance, then, and retry
499                                 pos = t + dir * nudge;
500                         }
501                         else
502                         {
503                                 // we actually LEFT solid!
504                                 trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
505                                 return c;
506                         }
507                 }
508                 else
509                 {
510                         // pos is outside solid?!? but why?!? never mind, just return it.
511                         trace_endpos = pos;
512                         trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
513                         return c;
514                 }
515         }
516 }
517
518 void traceline_inverted (vector v1, vector v2, float nomonsters, entity forent)
519 {
520 #if 0
521         vector pos, dir, t;
522         float nudge;
523
524         //nudge = 2 * cvar("collision_impactnudge"); // why not?
525         nudge = 0.5;
526
527         dir = normalize(v2 - v1);
528
529         pos = v1 + dir * nudge;
530
531         for(;;)
532         {
533                 if((pos - v1) * dir >= (v2 - v1) * dir)
534                 {
535                         // went too far
536                         trace_fraction = 1;
537                         return;
538                 }
539
540                 traceline(pos, v2, nomonsters, forent);
541
542                 if(trace_startsolid)
543                 {
544                         // we started inside solid.
545                         // then trace from endpos to pos
546                         t = trace_endpos;
547                         traceline(t, pos, nomonsters, forent);
548                         if(trace_startsolid)
549                         {
550                                 // t is inside solid? bad
551                                 // force advance, then
552                                 pos = pos + dir * nudge;
553                         }
554                         else
555                         {
556                                 // we actually LEFT solid!
557                                 trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
558                                 return;
559                         }
560                 }
561                 else
562                 {
563                         // pos is outside solid?!? but why?!? never mind, just return it.
564                         trace_endpos = pos;
565                         trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
566                         return;
567                 }
568         }
569 #else
570         tracebox_inverted(v1, '0 0 0', '0 0 0', v2, nomonsters, forent);
571 }
572
573 /*
574 ==================
575 findbetterlocation
576
577 Returns a point at least 12 units away from walls
578 (useful for explosion animations, although the blast is performed where it really happened)
579 Ripped from DPMod
580 ==================
581 */
582 vector findbetterlocation (vector org, float mindist)
583 {
584         vector  loc;
585         vector vec;
586         float c, h;
587
588         vec = mindist * '1 0 0';
589         c = 0;
590         while (c < 6)
591         {
592                 traceline (org, org + vec, TRUE, world);
593                 vec = vec * -1;
594                 if (trace_fraction < 1)
595                 {
596                         loc = trace_endpos;
597                         traceline (loc, loc + vec, TRUE, world);
598                         if (trace_fraction >= 1)
599                                 org = loc + vec;
600                 }
601                 if (c & 1)
602                 {
603                         h = vec_y;
604                         vec_y = vec_x;
605                         vec_x = vec_z;
606                         vec_z = h;
607                 }
608                 c = c + 1;
609         }
610
611         return org;
612 }
613
614 /*
615 ==================
616 crandom
617
618 Returns a random number between -1.0 and 1.0
619 ==================
620 */
621 float crandom (void)
622 {
623         return 2 * (random () - 0.5);
624 }
625
626 /*
627 ==================
628 Angc used for animations
629 ==================
630 */
631
632
633 float angc (float a1, float a2)
634 {
635         float   a;
636
637         while (a1 > 180)
638                 a1 = a1 - 360;
639         while (a1 < -179)
640                 a1 = a1 + 360;
641
642         while (a2 > 180)
643                 a2 = a2 - 360;
644         while (a2 < -179)
645                 a2 = a2 + 360;
646
647         a = a1 - a2;
648         while (a > 180)
649                 a = a - 360;
650         while (a < -179)
651                 a = a + 360;
652
653         return a;
654 }
655
656 .string lodtarget1;
657 .string lodtarget2;
658 .string lodmodel1;
659 .string lodmodel2;
660 .float lodmodelindex0;
661 .float lodmodelindex1;
662 .float lodmodelindex2;
663 .float loddistance1;
664 .float loddistance2;
665
666 float LOD_customize()
667 {
668         float d;
669
670         if(cvar("loddebug"))
671         {
672                 d = cvar("loddebug");
673                 if(d == 1)
674                         self.modelindex = self.lodmodelindex0;
675                 else if(d == 2 || !self.lodmodelindex2)
676                         self.modelindex = self.lodmodelindex1;
677                 else // if(d == 3)
678                         self.modelindex = self.lodmodelindex2;
679                 return TRUE;
680         }
681
682         // TODO csqc network this so it only gets sent once
683         d = vlen(NearestPointOnBox(self, other.origin) - other.origin);
684         if(d < self.loddistance1)
685                 self.modelindex = self.lodmodelindex0;
686         else if(!self.lodmodelindex2 || d < self.loddistance2)
687                 self.modelindex = self.lodmodelindex1;
688         else
689                 self.modelindex = self.lodmodelindex2;
690
691         return TRUE;
692 }
693
694 void LOD_uncustomize()
695 {
696         self.modelindex = self.lodmodelindex0;
697 }
698
699 void LODmodel_attach()
700 {
701         entity e;
702
703         if(!self.loddistance1)
704                 self.loddistance1 = 1000;
705         if(!self.loddistance2)
706                 self.loddistance2 = 2000;
707         self.lodmodelindex0 = self.modelindex;
708
709         if(self.lodtarget1 != "")
710         {
711                 e = find(world, targetname, self.lodtarget1);
712                 if(e)
713                 {
714                         self.lodmodel1 = e.model;
715                         remove(e);
716                 }
717         }
718         if(self.lodtarget2 != "")
719         {
720                 e = find(world, targetname, self.lodtarget2);
721                 if(e)
722                 {
723                         self.lodmodel2 = e.model;
724                         remove(e);
725                 }
726         }
727
728         if(cvar("loddebug") < 0)
729         {
730                 self.lodmodel1 = self.lodmodel2 = ""; // don't even initialize
731         }
732
733         if(self.lodmodel1 != "")
734         {
735                 vector mi, ma;
736                 mi = self.mins;
737                 ma = self.maxs;
738
739                 precache_model(self.lodmodel1);
740                 setmodel(self, self.lodmodel1);
741                 self.lodmodelindex1 = self.modelindex;
742
743                 if(self.lodmodel2 != "")
744                 {
745                         precache_model(self.lodmodel2);
746                         setmodel(self, self.lodmodel2);
747                         self.lodmodelindex2 = self.modelindex;
748                 }
749
750                 self.modelindex = self.lodmodelindex0;
751                 setsize(self, mi, ma);
752         }
753
754         if(self.lodmodelindex1)
755                 if not(self.SendEntity)
756                         SetCustomizer(self, LOD_customize, LOD_uncustomize);
757 }
758
759 void SetBrushEntityModel()
760 {
761         if(self.model != "")
762         {
763                 precache_model(self.model);
764                 setmodel(self, self.model); // no precision needed
765                 InitializeEntity(self, LODmodel_attach, INITPRIO_FINDTARGET);
766         }
767         setorigin(self, self.origin);
768         if(self.scale)
769                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
770         else
771                 setsize(self, self.mins, self.maxs);
772 }
773
774 void SetBrushEntityModelNoLOD()
775 {
776         if(self.model != "")
777         {
778                 precache_model(self.model);
779                 setmodel(self, self.model); // no precision needed
780         }
781         setorigin(self, self.origin);
782         if(self.scale)
783                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
784         else
785                 setsize(self, self.mins, self.maxs);
786 }
787
788 /*
789 ================
790 InitTrigger
791 ================
792 */
793
794 void SetMovedir()
795 {
796         if (self.movedir != '0 0 0')
797                 self.movedir = normalize(self.movedir);
798         else
799         {
800                 makevectors (self.angles);
801                 self.movedir = v_forward;
802         }
803
804         self.angles = '0 0 0';
805 };
806
807 void InitTrigger()
808 {
809 // trigger angles are used for one-way touches.  An angle of 0 is assumed
810 // to mean no restrictions, so use a yaw of 360 instead.
811         if (self.movedir == '0 0 0')
812         if (self.angles != '0 0 0')
813                 SetMovedir ();
814         self.solid = SOLID_TRIGGER;
815         SetBrushEntityModel();
816         self.movetype = MOVETYPE_NONE;
817         self.modelindex = 0;
818         self.model = "";
819 };
820
821 void InitSolidBSPTrigger()
822 {
823 // trigger angles are used for one-way touches.  An angle of 0 is assumed
824 // to mean no restrictions, so use a yaw of 360 instead.
825         if (self.movedir == '0 0 0')
826         if (self.angles != '0 0 0')
827                 SetMovedir ();
828         self.solid = SOLID_BSP;
829         SetBrushEntityModel();
830         self.movetype = MOVETYPE_NONE; // why was this PUSH? -div0
831 //      self.modelindex = 0;
832         self.model = "";
833 };
834
835 float InitMovingBrushTrigger()
836 {
837 // trigger angles are used for one-way touches.  An angle of 0 is assumed
838 // to mean no restrictions, so use a yaw of 360 instead.
839         self.solid = SOLID_BSP;
840         SetBrushEntityModel();
841         self.movetype = MOVETYPE_PUSH;
842         if(self.modelindex == 0)
843         {
844                 objerror("InitMovingBrushTrigger: no brushes found!");
845                 return 0;
846         }
847         return 1;
848 };